1986158571855a7f110bdd8cb8fc4a71ffae1cb1
[strongswan.git] / src / frontends / android / app / build.gradle
1 apply plugin: 'com.android.application'
2
3 android {
4     compileSdkVersion 26
5
6     defaultConfig {
7         applicationId "org.strongswan.android"
8         minSdkVersion 15
9         targetSdkVersion 26
10         versionCode 63
11         versionName "2.1.0"
12     }
13
14     sourceSets.main {
15         jni.srcDirs = [] // disables the default ndk-build call (with on-the-fly Android.mk files)
16         jniLibs.srcDir 'src/main/libs'
17     }
18
19     task buildNative(type: Exec) {
20         workingDir 'src/main/jni'
21         commandLine "${android.ndkDirectory}/ndk-build", '-j', Runtime.runtime.availableProcessors()
22     }
23
24     task cleanNative(type: Exec) {
25         workingDir 'src/main/jni'
26         commandLine "${android.ndkDirectory}/ndk-build", 'clean'
27     }
28
29     tasks.withType(JavaCompile) {
30         compileTask -> compileTask.dependsOn buildNative
31         options.compilerArgs << "-Xlint:unchecked" << "-Xlint:deprecation"
32     }
33
34     clean.dependsOn 'cleanNative'
35
36     buildTypes {
37         release {
38             minifyEnabled false
39             proguardFiles getDefaultProguardFile('proguard-android.txt'), 'proguard-rules.txt'
40         }
41     }
42     compileOptions {
43         targetCompatibility 1.8
44         sourceCompatibility 1.8
45     }
46 }
47
48 dependencies {
49     implementation 'com.android.support:appcompat-v7:26.0.2'
50     implementation 'com.android.support:design:26.0.2'
51     implementation 'com.android.support:preference-v7:26.0.2'
52     implementation 'com.android.support:support-v4:26.0.2'
53     testImplementation 'junit:junit:4.12'
54 }