started use of libtnc library
[strongswan.git] / configure.in
1 dnl  configure.in for linux strongSwan
2 dnl  Copyright (C) 2006 Martin Willi
3 dnl  Hochschule fuer Technik Rapperswil
4 dnl
5 dnl  This program is free software; you can redistribute it and/or modify it
6 dnl  under the terms of the GNU General Public License as published by the
7 dnl  Free Software Foundation; either version 2 of the License, or (at your
8 dnl  option) any later version.  See <http://www.fsf.org/copyleft/gpl.txt>.
9 dnl
10 dnl  This program is distributed in the hope that it will be useful, but
11 dnl  WITHOUT ANY WARRANTY; without even the implied warranty of MERCHANTABILITY
12 dnl  or FITNESS FOR A PARTICULAR PURPOSE.  See the GNU General Public License
13 dnl  for more details.
14
15 dnl ===========================
16 dnl  initialize & set some vars
17 dnl ===========================
18
19 AC_INIT(strongSwan,4.5.0dr4)
20 AM_INIT_AUTOMAKE(tar-ustar)
21 AC_CONFIG_MACRO_DIR([m4/config])
22 PKG_PROG_PKG_CONFIG
23
24 dnl =================================
25 dnl  check --enable-xxx & --with-xxx
26 dnl =================================
27
28 m4_include(m4/macros/with.m4)
29
30 ARG_WITH_SUBST([default-pkcs11],     [/usr/lib/opensc-pkcs11.so], [set the default PKCS11 library])
31 ARG_WITH_SUBST([random-device],      [/dev/random], [set the device to read real random data from])
32 ARG_WITH_SUBST([urandom-device],     [/dev/urandom], [set the device to read pseudo random data from])
33 ARG_WITH_SUBST([strongswan-conf],    [${sysconfdir}/strongswan.conf], [set the strongswan.conf file location])
34 ARG_WITH_SUBST([resolv-conf],        [${sysconfdir}/resolv.conf], [set the file to use in DNS handler plugin])
35 ARG_WITH_SUBST([piddir],             [/var/run], [set path for PID and UNIX socket files])
36 ARG_WITH_SUBST([ipsecdir],           [${libexecdir%/}/ipsec], [set installation path for ipsec tools])
37 ARG_WITH_SUBST([plugindir],          [${ipsecdir%/}/plugins], [set the installation path of plugins])
38 ARG_WITH_SUBST([nm-ca-dir],          [/usr/share/ca-certificates], [directory the NM plugin uses to look up trusted root certificates])
39 ARG_WITH_SUBST([linux-headers],      [\${top_srcdir}/src/include], [set directory of linux header files to use])
40 ARG_WITH_SUBST([routing-table],      [220], [set routing table to use for IPsec routes])
41 ARG_WITH_SUBST([routing-table-prio], [220], [set priority for IPsec routing table])
42
43 ARG_WITH_SET([capabilities],         [no], [set capability dropping library. Currently supported values are "libcap" and "native"])
44 ARG_WITH_SET([mpz_powm_sec],         [yes], [use the more side-channel resistant mpz_powm_sec in libgmp, if available])
45
46 AC_ARG_WITH(
47         [xauth-module],
48         AS_HELP_STRING([--with-xauth-module=lib],[set the path to the XAUTH module]),
49         [AC_DEFINE_UNQUOTED(XAUTH_DEFAULT_LIB, "$withval")],
50 )
51
52 AC_ARG_WITH(
53         [user],
54         AS_HELP_STRING([--with-user=user],[change user of the daemons to "user" after startup (default is "root").]),
55         [AC_DEFINE_UNQUOTED(IPSEC_USER, "$withval") AC_SUBST(ipsecuser, "$withval")],
56         [AC_SUBST(ipsecuser, "root")]
57 )
58
59 AC_ARG_WITH(
60         [group],
61         AS_HELP_STRING([--with-group=group],[change group of the daemons to "group" after startup (default is "root").]),
62         [AC_DEFINE_UNQUOTED(IPSEC_GROUP, "$withval") AC_SUBST(ipsecgroup, "$withval")],
63         [AC_SUBST(ipsecgroup, "root")]
64 )
65
66 m4_include(m4/macros/enable-disable.m4)
67
68 ARG_ENABL_SET([curl],           [enable CURL fetcher plugin to fetch files via libcurl. Requires libcurl.])
69 ARG_ENABL_SET([ldap],           [enable LDAP fetching plugin to fetch files via libldap. Requires openLDAP.])
70 ARG_DISBL_SET([aes],            [disable AES software implementation plugin.])
71 ARG_DISBL_SET([des],            [disable DES/3DES software implementation plugin.])
72 ARG_ENABL_SET([blowfish],       [enable Blowfish software implementation plugin.])
73 ARG_ENABL_SET([md4],            [enable MD4 software implementation plugin.])
74 ARG_DISBL_SET([md5],            [disable MD5 software implementation plugin.])
75 ARG_DISBL_SET([sha1],           [disable SHA1 software implementation plugin.])
76 ARG_DISBL_SET([sha2],           [disable SHA256/SHA384/SHA512 software implementation plugin.])
77 ARG_DISBL_SET([fips-prf],       [disable FIPS PRF software implementation plugin.])
78 ARG_DISBL_SET([gmp],            [disable GNU MP (libgmp) based crypto implementation plugin.])
79 ARG_DISBL_SET([random],         [disable RNG implementation on top of /dev/(u)random.])
80 ARG_DISBL_SET([x509],           [disable X509 certificate implementation plugin.])
81 ARG_DISBL_SET([revocation],     [disable X509 CRL/OCSP revocation check plugin.])
82 ARG_DISBL_SET([pubkey],         [disable RAW public key support plugin.])
83 ARG_DISBL_SET([pkcs1],          [disable PKCS1 key decoding plugin.])
84 ARG_DISBL_SET([pgp],            [disable PGP key decoding plugin.])
85 ARG_DISBL_SET([dnskey],         [disable DNS RR key decoding plugin.])
86 ARG_DISBL_SET([pem],            [disable PEM decoding plugin.])
87 ARG_DISBL_SET([hmac],           [disable HMAC crypto implementation plugin.])
88 ARG_DISBL_SET([xcbc],           [disable xcbc crypto implementation plugin.])
89 ARG_ENABL_SET([test-vectors],   [enable plugin providing crypto test vectors.])
90 ARG_ENABL_SET([mysql],          [enable MySQL database support. Requires libmysqlclient_r.])
91 ARG_ENABL_SET([sqlite],         [enable SQLite database support. Requires libsqlite3.])
92 ARG_DISBL_SET([stroke],         [disable charons stroke (pluto compatibility) configuration backend.])
93 ARG_ENABL_SET([medsrv],         [enable mediation server web frontend and daemon plugin.])
94 ARG_ENABL_SET([medcli],         [enable mediation client configuration database plugin.])
95 ARG_ENABL_SET([smp],            [enable SMP configuration and control interface. Requires libxml.])
96 ARG_ENABL_SET([sql],            [enable SQL database configuration backend.])
97 ARG_ENABL_SET([smartcard],      [enable smartcard support.])
98 ARG_ENABL_SET([cisco-quirks],   [enable support of Cisco VPN client.])
99 ARG_ENABL_SET([leak-detective], [enable malloc hooks to find memory leaks.])
100 ARG_ENABL_SET([lock-profiler],  [enable lock/mutex profiling code.])
101 ARG_ENABL_SET([unit-tests],     [enable unit tests on IKEv2 daemon startup.])
102 ARG_ENABL_SET([load-tester],    [enable load testing plugin for IKEv2 daemon.])
103 ARG_ENABL_SET([eap-sim],        [enable SIM authentication module for EAP.])
104 ARG_ENABL_SET([eap-sim-file],   [enable EAP-SIM backend based on a triplet file.])
105 ARG_ENABL_SET([eap-simaka-sql], [enable EAP-SIM/AKA backend based on a triplet/quintuplet SQL database.])
106 ARG_ENABL_SET([eap-simaka-pseudonym], [enable EAP-SIM/AKA pseudonym storage plugin.])
107 ARG_ENABL_SET([eap-simaka-reauth],    [enable EAP-SIM/AKA reauthentication data storage plugin.])
108 ARG_ENABL_SET([eap-identity],   [enable EAP module providing EAP-Identity helper.])
109 ARG_ENABL_SET([eap-md5],        [enable EAP MD5 (CHAP) authentication module.])
110 ARG_ENABL_SET([eap-gtc],        [enable PAM based EAP GTC authentication module.])
111 ARG_ENABL_SET([eap-aka],        [enable EAP AKA authentication module.])
112 ARG_ENABL_SET([eap-aka-3gpp2],  [enable EAP AKA backend implementing 3GPP2 algorithms in software. Requires libgmp.])
113 ARG_ENABL_SET([eap-mschapv2],   [enable EAP MS-CHAPv2 authentication module.])
114 ARG_ENABL_SET([eap-tls],        [enable EAP TLS authentication module.])
115 ARG_ENABL_SET([eap-ttls],       [enable EAP TTLS authentication module.])
116 ARG_ENABL_SET([eap-tnc],        [enable EAP TNC trusted network connect module.])
117 ARG_ENABL_SET([eap-radius],     [enable RADIUS proxy authentication module.])
118 ARG_ENABL_SET([tnccs-11],       [enable TNCCS 1.1 protocol module.])
119 ARG_DISBL_SET([kernel-netlink], [disable the netlink kernel interface.])
120 ARG_ENABL_SET([kernel-pfkey],   [enable the PF_KEY kernel interface.])
121 ARG_ENABL_SET([kernel-pfroute], [enable the PF_ROUTE kernel interface.])
122 ARG_ENABL_SET([kernel-klips],   [enable the KLIPS kernel interface.])
123 ARG_DISBL_SET([socket-default], [disable default socket implementation for charon.])
124 ARG_ENABL_SET([socket-raw],     [enable raw socket implementation of charon, enforced if pluto is enabled])
125 ARG_ENABL_SET([socket-dynamic], [enable dynamic socket implementation for charon])
126 ARG_ENABL_SET([farp],           [enable ARP faking plugin that responds to ARP requests to peers virtual IP])
127 ARG_ENABL_SET([nat-transport],  [enable NAT traversal with IPsec transport mode in pluto.])
128 ARG_DISBL_SET([vendor-id],      [disable the sending of the strongSwan vendor ID in pluto.])
129 ARG_DISBL_SET([xauth-vid],      [disable the sending of the XAUTH vendor ID.])
130 ARG_ENABL_SET([dumm],           [enable the DUMM UML test framework.])
131 ARG_ENABL_SET([fast],           [enable libfast (FastCGI Application Server w/ templates.])
132 ARG_ENABL_SET([manager],        [enable web management console (proof of concept).])
133 ARG_ENABL_SET([mediation],      [enable IKEv2 Mediation Extension.])
134 ARG_ENABL_SET([integrity-test], [enable integrity testing of libstrongswan and plugins.])
135 ARG_DISBL_SET([load-warning],   [disable the charon/pluto plugin load option warning in starter.])
136 ARG_DISBL_SET([pluto],          [disable the IKEv1 keying daemon pluto.])
137 ARG_DISBL_SET([xauth],          [disable xauth plugin.])
138 ARG_DISBL_SET([threads],        [disable the use of threads in pluto. Charon always uses threads.])
139 ARG_DISBL_SET([charon],         [disable the IKEv2 keying daemon charon.])
140 ARG_DISBL_SET([tools],          [disable additional utilities (openac, scepclient and pki).])
141 ARG_DISBL_SET([scripts],        [disable additional utilities (found in directory scripts).])
142 ARG_DISBL_SET([updown],         [disable updown firewall script plugin.])
143 ARG_DISBL_SET([attr],           [disable strongswan.conf based configuration attribute plugin.])
144 ARG_ENABL_SET([attr-sql],       [enable SQL based configuration attribute plugin.])
145 ARG_ENABL_SET([dhcp],           [enable DHCP based attribute provider plugin.])
146 ARG_DISBL_SET([resolve],        [disable resolve DNS handler plugin.])
147 ARG_ENABL_SET([padlock],        [enables VIA Padlock crypto plugin.])
148 ARG_ENABL_SET([openssl],        [enables the OpenSSL crypto plugin.])
149 ARG_ENABL_SET([gcrypt],         [enables the libgcrypt plugin.])
150 ARG_ENABL_SET([agent],          [enables the ssh-agent signing plugin.])
151 ARG_ENABL_SET([pkcs11],         [enables the PKCS11 token support plugin.])
152 ARG_ENABL_SET([ctr],            [enables the Counter Mode wrapper crypto plugin.])
153 ARG_ENABL_SET([ccm],            [enables the CCM AEAD wrapper crypto plugin.])
154 ARG_ENABL_SET([gcm],            [enables the GCM AEAD wrapper crypto plugin.])
155 ARG_ENABL_SET([addrblock],      [enables RFC 3779 address block constraint support.])
156 ARG_ENABL_SET([uci],            [enable OpenWRT UCI configuration plugin.])
157 ARG_ENABL_SET([android],        [enable Android specific plugin.])
158 ARG_ENABL_SET([nm],             [enable NetworkManager plugin.])
159 ARG_ENABL_SET([ha],             [enable high availability cluster plugin.])
160 ARG_ENABL_SET([led],            [enable plugin to control LEDs on IKEv2 activity using the Linux kernel LED subsystem.])
161 ARG_ENABL_SET([vstr],           [enforce using the Vstr string library to replace glibc-like printf hooks.])
162 ARG_ENABL_SET([monolithic],     [build monolithic version of libstrongswan that includes all enabled plugins. Similarly, the plugins of charon are assembled in libcharon.])
163
164 dnl =========================
165 dnl  set up compiler and flags
166 dnl =========================
167
168 if test -z "$CFLAGS"; then
169         CFLAGS="-g -O2 -Wall -Wno-format -Wno-pointer-sign -Wno-strict-aliasing"
170 fi
171 AC_PROG_CC
172 AC_LIB_PREFIX
173 AC_C_BIGENDIAN
174
175 dnl =========================
176 dnl  check required programs
177 dnl =========================
178
179 AC_PROG_INSTALL
180 AC_PROG_LIBTOOL
181 AC_PROG_EGREP
182 AC_PROG_AWK
183 AC_PROG_LEX
184 AC_PROG_YACC
185 AC_PATH_PROG([PERL], [perl], [], [$PATH:/bin:/usr/bin:/usr/local/bin])
186 AC_PATH_PROG([GPERF], [gperf], [], [$PATH:/bin:/usr/bin:/usr/local/bin])
187
188 dnl because gperf is not needed by end-users we just report it but do not abort on failure
189 AC_MSG_CHECKING([gperf version >= 3.0.0])
190 if test -x "$GPERF"; then
191         if test "`$GPERF --version | $AWK -F' ' '/^GNU gperf/ { print $3 }' | $AWK -F. '{ print $1 }'`" -ge "3"; then
192                 AC_MSG_RESULT([yes])
193         else
194                 AC_MSG_RESULT([no])
195         fi
196 else
197         AC_MSG_RESULT([not found])
198 fi
199
200 dnl translate user/group to numercial ids
201 AC_MSG_CHECKING([for uid of user "$ipsecuser"])
202 ipsecuid=`id -u $ipsecuser 2>/dev/null`
203 if test -n "$ipsecuid"; then
204         AC_MSG_RESULT([$ipsecuid])
205         AC_SUBST(ipsecuid)
206 else
207         AC_MSG_ERROR([not found])
208 fi
209 AC_MSG_CHECKING([for gid of group "$ipsecgroup"])
210 ipsecgid=`$EGREP "^$ipsecgroup:" /etc/group | $AWK -F: '{ print $3 }'`
211 if test -n "$ipsecgid"; then
212         AC_MSG_RESULT([$ipsecgid])
213         AC_SUBST(ipsecgid)
214 else
215         AC_MSG_ERROR([not found])
216 fi
217
218 dnl =========================
219 dnl  dependency calculation
220 dnl =========================
221
222 if test x$eap_aka_3gpp2 = xtrue; then
223         gmp=true;
224 fi
225
226 if test x$eap_aka = xtrue; then
227         fips_prf=true;
228         simaka=true;
229 fi
230
231 if test x$eap_sim = xtrue; then
232         fips_prf=true;
233         simaka=true;
234 fi
235
236 if test x$eap_tls = xtrue -o x$eap_ttls = xtrue; then
237         tls=true;
238 fi
239
240 if test x$fips_prf = xtrue; then
241         if test x$openssl = xfalse; then
242                 sha1=true;
243         fi
244 fi
245
246 if test x$smp = xtrue; then
247         xml=true
248 fi
249
250 if test x$manager = xtrue; then
251         fast=true
252 fi
253
254 if test x$medsrv = xtrue; then
255         mediation=true
256         fast=true
257 fi
258
259 if test x$medcli = xtrue; then
260         mediation=true
261 fi
262
263 if test x$pluto = xtrue; then
264         if test x$socket_raw = xfalse; then
265                 AC_MSG_NOTICE([Enforcing --enable-socket-raw, as pluto is enabled])
266                 socket_raw=true
267                 if test x$socket_default_given = xfalse; then
268                         socket_default=false
269                 fi
270         fi
271 fi
272
273 dnl ===========================================
274 dnl  check required libraries and header files
275 dnl ===========================================
276
277 AC_HEADER_STDBOOL
278 AC_FUNC_ALLOCA
279
280 dnl libraries needed on some platforms but not on others
281 dnl ====================================================
282 saved_LIBS=$LIBS
283
284 dnl FreeBSD and Mac OS X have dlopen integrated in libc, Linux needs libdl
285 LIBS=""
286 AC_SEARCH_LIBS(dlopen, dl, [DLLIB=$LIBS])
287 AC_SUBST(DLLIB)
288
289 dnl glibc's backtrace() can be replicated on FreeBSD with libexecinfo
290 LIBS=""
291 AC_SEARCH_LIBS(backtrace, execinfo, [BTLIB=$LIBS])
292 AC_CHECK_FUNCS(backtrace)
293 AC_SUBST(BTLIB)
294
295 dnl OpenSolaris needs libsocket and libnsl for socket()
296 LIBS=""
297 AC_SEARCH_LIBS(socket, socket, [SOCKLIB=$LIBS],
298         [AC_CHECK_LIB(nsl, socket, [SOCKLIB="-lsocket -lnsl"], [], [-lsocket])]
299 )
300 AC_SUBST(SOCKLIB)
301
302 dnl FreeBSD has clock_gettime in libc, Linux needs librt
303 LIBS=""
304 AC_SEARCH_LIBS(clock_gettime, rt, [RTLIB=$LIBS])
305 AC_CHECK_FUNCS(clock_gettime)
306 AC_SUBST(RTLIB)
307
308 dnl Android has pthread_* functions in bionic (libc), others need libpthread
309 LIBS=""
310 AC_SEARCH_LIBS(pthread_create, pthread, [PTHREADLIB=$LIBS])
311 AC_SUBST(PTHREADLIB)
312
313 LIBS=$saved_LIBS
314 dnl ======================
315
316 AC_MSG_CHECKING(for dladdr)
317 AC_TRY_COMPILE(
318         [#define _GNU_SOURCE
319          #include <dlfcn.h>],
320         [Dl_info* info = 0;
321          dladdr(0, info);],
322         [AC_MSG_RESULT([yes]); AC_DEFINE([HAVE_DLADDR])],
323         [AC_MSG_RESULT([no])]
324 )
325
326 dnl check if pthread_condattr_setclock(CLOCK_MONOTONE) is supported
327 saved_LIBS=$LIBS
328 LIBS=$PTHREADLIB
329 AC_MSG_CHECKING([for pthread_condattr_setclock(CLOCK_MONOTONE)])
330 AC_TRY_RUN(
331         [#include <pthread.h>
332          int main() { pthread_condattr_t attr;
333                 pthread_condattr_init(&attr);
334                 return pthread_condattr_setclock(&attr, CLOCK_MONOTONIC);}],
335         [AC_MSG_RESULT([yes]); AC_DEFINE([HAVE_CONDATTR_CLOCK_MONOTONIC])],
336         [AC_MSG_RESULT([no])],
337         dnl Check existence of pthread_condattr_setclock if cross-compiling
338         [AC_MSG_RESULT([unknown]);
339          AC_CHECK_FUNCS(pthread_condattr_setclock,
340                 [AC_DEFINE([HAVE_CONDATTR_CLOCK_MONOTONIC])]
341         )]
342 )
343 dnl check if we actually are able to configure attributes on cond vars
344 AC_CHECK_FUNCS(pthread_condattr_init)
345 dnl instead of pthread_condattr_setclock Android has this function
346 AC_CHECK_FUNCS(pthread_cond_timedwait_monotonic)
347 dnl check if we can cancel threads
348 AC_CHECK_FUNCS(pthread_cancel)
349 dnl check if native rwlocks are available
350 AC_CHECK_FUNCS(pthread_rwlock_init)
351 LIBS=$saved_LIBS
352
353 AC_CHECK_FUNCS(prctl)
354
355 AC_CHECK_FUNCS(mallinfo)
356
357 AC_CHECK_HEADERS(sys/sockio.h)
358 AC_CHECK_HEADERS(net/pfkeyv2.h netipsec/ipsec.h netinet6/ipsec.h linux/udp.h)
359
360 AC_CHECK_MEMBERS([struct sockaddr.sa_len], [], [],
361 [
362         #include <sys/types.h>
363         #include <sys/socket.h>
364 ])
365
366 AC_CHECK_MEMBERS([struct sadb_x_policy.sadb_x_policy_priority], [], [],
367 [
368         #include <sys/types.h>
369         #ifdef HAVE_NET_PFKEYV2_H
370         #include <net/pfkeyv2.h>
371         #else
372         #include <stdint.h>
373         #include <linux/pfkeyv2.h>
374         #endif
375 ])
376
377 AC_MSG_CHECKING([for in6addr_any])
378 AC_TRY_COMPILE(
379         [#include <sys/types.h>
380         #include <sys/socket.h>
381         #include <netinet/in.h>],
382         [struct in6_addr in6;
383         in6 = in6addr_any;],
384         [AC_MSG_RESULT([yes]); AC_DEFINE([HAVE_IN6ADDR_ANY])],
385         [AC_MSG_RESULT([no])]
386 )
387
388 AC_MSG_CHECKING([for in6_pktinfo])
389 AC_TRY_COMPILE(
390         [#define _GNU_SOURCE
391         #include <sys/types.h>
392         #include <sys/socket.h>
393         #include <netinet/in.h>],
394         [struct in6_pktinfo pi;
395         if (pi.ipi6_ifindex)
396         {
397                 return 0;
398         }],
399         [AC_MSG_RESULT([yes]); AC_DEFINE([HAVE_IN6_PKTINFO])],
400         [AC_MSG_RESULT([no])]
401 )
402
403 AC_MSG_CHECKING([for IPSEC_MODE_BEET])
404 AC_TRY_COMPILE(
405         [#include <sys/types.h>
406         #ifdef HAVE_NETIPSEC_IPSEC_H
407         #include <netipsec/ipsec.h>
408         #elif defined(HAVE_NETINET6_IPSEC_H)
409         #include <netinet6/ipsec.h>
410         #else
411         #include <stdint.h>
412         #include <linux/ipsec.h>
413         #endif],
414         [int mode = IPSEC_MODE_BEET;
415          return mode;],
416         [AC_MSG_RESULT([yes]); AC_DEFINE([HAVE_IPSEC_MODE_BEET])],
417         [AC_MSG_RESULT([no])]
418 )
419
420 AC_MSG_CHECKING([for IPSEC_DIR_FWD])
421 AC_TRY_COMPILE(
422         [#include <sys/types.h>
423         #ifdef HAVE_NETIPSEC_IPSEC_H
424         #include <netipsec/ipsec.h>
425         #elif defined(HAVE_NETINET6_IPSEC_H)
426         #include <netinet6/ipsec.h>
427         #else
428         #include <stdint.h>
429         #include <linux/ipsec.h>
430         #endif],
431         [int dir = IPSEC_DIR_FWD;
432          return dir;],
433         [AC_MSG_RESULT([yes]); AC_DEFINE([HAVE_IPSEC_DIR_FWD])],
434         [AC_MSG_RESULT([no])]
435 )
436
437 AC_MSG_CHECKING([for gcc atomic operations])
438 AC_TRY_RUN(
439 [
440         int main() {
441                 volatile int ref = 1;
442                 __sync_fetch_and_add (&ref, 1);
443                 __sync_sub_and_fetch (&ref, 1);
444                 /* Make sure test fails if operations are not supported */
445                 __sync_val_compare_and_swap(&ref, 1, 0);
446                 return ref;
447         }
448 ],
449 [AC_MSG_RESULT([yes]); AC_DEFINE(HAVE_GCC_ATOMIC_OPERATIONS)],
450 [AC_MSG_RESULT([no])],
451 [AC_MSG_RESULT([no])])
452
453 dnl check for the new register_printf_specifier function with len argument,
454 dnl or the deprecated register_printf_function without
455 AC_CHECK_FUNC(
456         [register_printf_specifier],
457         [AC_DEFINE(HAVE_PRINTF_SPECIFIER)],
458         [AC_CHECK_FUNC(
459                 [register_printf_function],
460                 [AC_DEFINE(HAVE_PRINTF_FUNCTION)],
461                 [
462                         AC_MSG_NOTICE([printf does not support custom format specifiers!])
463                         vstr=true
464                 ]
465         )]
466 )
467
468 if test x$vstr = xtrue; then
469         AC_HAVE_LIBRARY([vstr],[LIBS="$LIBS"],[AC_MSG_ERROR([Vstr string library not found])])
470         AC_DEFINE(USE_VSTR)
471 fi
472
473 if test x$gmp = xtrue; then
474         saved_LIBS=$LIBS
475         AC_HAVE_LIBRARY([gmp],,[AC_MSG_ERROR([GNU Multi Precision library gmp not found])])
476         AC_MSG_CHECKING([mpz_powm_sec])
477         if test x$mpz_powm_sec = xyes; then
478                 AC_TRY_COMPILE(
479                         [#include "gmp.h"],
480                         [
481                                 void *x = mpz_powm_sec;
482                         ],
483                         [AC_MSG_RESULT([yes]); AC_DEFINE(HAVE_MPZ_POWM_SEC)], [AC_MSG_RESULT([no])]
484                 )
485         else
486                 AC_MSG_RESULT([disabled])
487         fi
488         LIBS=$saved_LIBS
489         AC_MSG_CHECKING([gmp.h version >= 4.1.4])
490         AC_TRY_COMPILE(
491                 [#include "gmp.h"],
492                 [
493                         #if (__GNU_MP_VERSION*100 +  __GNU_MP_VERSION_MINOR*10 + __GNU_MP_VERSION_PATCHLEVEL) < 414
494                                 #error bad gmp
495                         #endif
496                 ],
497                 [AC_MSG_RESULT([yes])], [AC_MSG_RESULT([no]); AC_MSG_ERROR([No usable gmp.h found!])]
498         )
499 fi
500
501 if test x$ldap = xtrue; then
502         AC_HAVE_LIBRARY([ldap],[LIBS="$LIBS"],[AC_MSG_ERROR([LDAP library ldap not found])])
503         AC_HAVE_LIBRARY([lber],[LIBS="$LIBS"],[AC_MSG_ERROR([LDAP library lber not found])])
504         AC_CHECK_HEADER([ldap.h],,[AC_MSG_ERROR([LDAP header ldap.h not found!])])
505 fi
506
507 if test x$curl = xtrue; then
508         AC_HAVE_LIBRARY([curl],[LIBS="$LIBS"],[AC_MSG_ERROR([CURL library curl not found])])
509         AC_CHECK_HEADER([curl/curl.h],,[AC_MSG_ERROR([CURL header curl/curl.h not found!])])
510 fi
511
512 if test x$xml = xtrue; then
513         PKG_CHECK_MODULES(xml, [libxml-2.0])
514         AC_SUBST(xml_CFLAGS)
515         AC_SUBST(xml_LIBS)
516 fi
517
518 if test x$dumm = xtrue; then
519         PKG_CHECK_MODULES(gtk, [gtk+-2.0 vte])
520         AC_SUBST(gtk_CFLAGS)
521         AC_SUBST(gtk_LIBS)
522         AC_CHECK_PROGS(RUBY, ruby)
523         AC_MSG_CHECKING([for Ruby header files])
524         if test -n "$RUBY"; then
525                 RUBYDIR=`($RUBY -rmkmf -e 'print Config::CONFIG[["archdir"]] || $archdir') 2>/dev/null`
526                 if test -n "$RUBYDIR"; then
527                         dirs="$RUBYDIR"
528                         RUBYINCLUDE=none
529                         for i in $dirs; do
530                                 if test -r $i/ruby.h; then
531                                         AC_MSG_RESULT([$i])
532                                         RUBYINCLUDE="-I$i"
533                                         break;
534                                 fi
535                         done
536                         if test x"$RUBYINCLUDE" = xnone; then
537                                 AC_MSG_ERROR([ruby.h not found])
538                         fi
539                         AC_SUBST(RUBYINCLUDE)
540                 else
541                         AC_MSG_ERROR([unable to determine ruby configuration])
542                 fi
543         else
544                 AC_MSG_ERROR([don't know how to run ruby])
545         fi
546 fi
547
548 if test x$fast = xtrue; then
549         AC_HAVE_LIBRARY([neo_cgi],[LIBS="$LIBS"],[AC_MSG_ERROR([ClearSilver library neo_cgi not found!])])
550         AC_HAVE_LIBRARY([neo_utl],[LIBS="$LIBS"],[AC_MSG_ERROR([ClearSilver library neo_utl not found!])])
551         AC_HAVE_LIBRARY([z],[LIBS="$LIBS"],[AC_MSG_ERROR([ClearSilver dependency zlib not found!])])
552 dnl autoconf does not like CamelCase!? How to fix this?
553 dnl     AC_CHECK_HEADER([ClearSilver/ClearSilver.h],,[AC_MSG_ERROR([ClearSilver header file ClearSilver/ClearSilver.h not found!])])
554
555         AC_HAVE_LIBRARY([fcgi],[LIBS="$LIBS"],[AC_MSG_ERROR([FastCGI library fcgi not found!])])
556         AC_CHECK_HEADER([fcgiapp.h],,[AC_MSG_ERROR([FastCGI header file fcgiapp.h not found!])])
557 fi
558
559 if test x$mysql = xtrue; then
560         AC_PATH_PROG([MYSQLCONFIG], [mysql_config], [], [$PATH:/bin:/usr/bin:/usr/local/bin])
561         if test x$MYSQLCONFIG = x; then
562                 AC_MSG_ERROR([mysql_config not found!])
563         fi
564         AC_SUBST(MYSQLLIB, `$MYSQLCONFIG --libs_r`)
565         AC_SUBST(MYSQLCFLAG, `$MYSQLCONFIG --cflags`)
566 fi
567
568 if test x$sqlite = xtrue; then
569         AC_HAVE_LIBRARY([sqlite3],[LIBS="$LIBS"],[AC_MSG_ERROR([SQLite library sqlite3 not found])])
570         AC_CHECK_HEADER([sqlite3.h],,[AC_MSG_ERROR([SQLite header sqlite3.h not found!])])
571         AC_MSG_CHECKING([sqlite3_prepare_v2])
572         AC_TRY_COMPILE(
573                 [#include <sqlite3.h>],
574                 [
575                         void *test = sqlite3_prepare_v2;
576                 ],
577                 [AC_MSG_RESULT([yes])]; AC_DEFINE_UNQUOTED(HAVE_SQLITE3_PREPARE_V2, 1), [AC_MSG_RESULT([no])])
578         AC_MSG_CHECKING([sqlite3.h version >= 3.3.1])
579         AC_TRY_COMPILE(
580                 [#include <sqlite3.h>],
581                 [
582                         #if SQLITE_VERSION_NUMBER < 3003001
583                                 #error bad sqlite
584                         #endif
585                 ],
586                 [AC_MSG_RESULT([yes])], [AC_MSG_RESULT([no]); AC_MSG_ERROR([SQLite version >= 3.3.1 required!])])
587 fi
588
589 if test x$openssl = xtrue; then
590         AC_HAVE_LIBRARY([crypto],[LIBS="$LIBS"],[AC_MSG_ERROR([OpenSSL crypto library not found])])
591         AC_CHECK_HEADER([openssl/evp.h],,[AC_MSG_ERROR([OpenSSL header openssl/evp.h not found!])])
592 fi
593
594 if test x$gcrypt = xtrue; then
595         AC_HAVE_LIBRARY([gcrypt],[LIBS="$LIBS"],[AC_MSG_ERROR([gcrypt library not found])],[-lgpg-error])
596         AC_CHECK_HEADER([gcrypt.h],,[AC_MSG_ERROR([gcrypt header gcrypt.h not found!])])
597         AC_MSG_CHECKING([gcrypt CAMELLIA cipher])
598         AC_TRY_COMPILE(
599                 [#include <gcrypt.h>],
600                 [enum gcry_cipher_algos alg = GCRY_CIPHER_CAMELLIA128;],
601                 [AC_MSG_RESULT([yes]); AC_DEFINE([HAVE_GCRY_CIPHER_CAMELLIA])],
602                 [AC_MSG_RESULT([no])]
603         )
604 fi
605
606 if test x$tnccs_11 = xtrue; then
607         AC_CHECK_HEADER([libtnc.h],,[AC_MSG_ERROR([libtnc header libtnc.h not found!])])
608 fi
609
610 if test x$uci = xtrue; then
611         AC_HAVE_LIBRARY([uci],[LIBS="$LIBS"],[AC_MSG_ERROR([UCI library libuci not found])])
612         AC_CHECK_HEADER([uci.h],,[AC_MSG_ERROR([UCI header uci.h not found!])])
613 fi
614
615 if test x$android = xtrue; then
616         AC_HAVE_LIBRARY([cutils],[LIBS="$LIBS"],[AC_MSG_ERROR([Android library libcutils not found])])
617         AC_CHECK_HEADER([cutils/properties.h],,[AC_MSG_ERROR([Android header cutils/properties.h not found!])])
618         dnl we have to force the use of libdl here because the autodetection
619         dnl above does not work correctly when cross-compiling for android.
620         DLLIB="-ldl"
621         AC_SUBST(DLLIB)
622 fi
623
624 if test x$nm = xtrue; then
625         PKG_CHECK_EXISTS([libnm-glib],
626                 [PKG_CHECK_MODULES(nm, [NetworkManager gthread-2.0 libnm-glib libnm-glib-vpn])],
627                 [PKG_CHECK_MODULES(nm, [NetworkManager gthread-2.0 libnm_glib libnm_glib_vpn])]
628         )
629         AC_SUBST(nm_CFLAGS)
630         AC_SUBST(nm_LIBS)
631 fi
632
633 if test x$eap_gtc = xtrue; then
634         AC_HAVE_LIBRARY([pam],[LIBS="$LIBS"],[AC_MSG_ERROR([PAM library not found])])
635         AC_CHECK_HEADER([security/pam_appl.h],,[AC_MSG_ERROR([PAM header security/pam_appl.h not found!])])
636 fi
637
638 if test x$capabilities = xnative; then
639         AC_MSG_NOTICE([Usage of the native Linux capabilities interface is deprecated, use libcap instead])
640         dnl Linux requires the following for capset(), Android does not have it,
641         dnl but defines capset() in unistd.h instead.
642         AC_CHECK_HEADERS([sys/capability.h])
643         AC_CHECK_FUNC(capset,,[AC_MSG_ERROR([capset() not found!])])
644         AC_DEFINE(CAPABILITIES_NATIVE)
645 fi
646
647 if test x$capabilities = xlibcap; then
648         AC_HAVE_LIBRARY([cap],[LIBS="$LIBS"],[AC_MSG_ERROR([libcap library not found])])
649         AC_CHECK_HEADER([sys/capability.h],
650                 [AC_DEFINE(HAVE_SYS_CAPABILITY_H)],
651                 [AC_MSG_ERROR([libcap header sys/capability.h not found!])])
652         AC_DEFINE(CAPABILITIES_LIBCAP)
653 fi
654
655 if test x$integrity_test = xtrue; then
656         AC_MSG_CHECKING([for dladdr()])
657         AC_TRY_COMPILE(
658                 [#define _GNU_SOURCE
659                  #include <dlfcn.h>],
660                 [Dl_info info; dladdr(main, &info);],
661                 [AC_MSG_RESULT([yes])], [AC_MSG_RESULT([no]);
662                  AC_MSG_ERROR([dladdr() not supported, required by integrity-test!])]
663         )
664         AC_MSG_CHECKING([for dl_iterate_phdr()])
665         AC_TRY_COMPILE(
666                 [#define _GNU_SOURCE
667                  #include <link.h>],
668                 [dl_iterate_phdr((void*)0, (void*)0);],
669                 [AC_MSG_RESULT([yes])], [AC_MSG_RESULT([no]);
670                  AC_MSG_ERROR([dl_iterate_phdr() not supported, required by integrity-test!])]
671         )
672 fi
673
674 dnl ==============================================
675 dnl  collect plugin list for strongSwan components
676 dnl ==============================================
677
678 m4_include(m4/macros/add-plugin.m4)
679
680 # plugin lists for all components
681 libcharon_plugins=
682 pluto_plugins=
683 pool_plugins=
684 openac_plugins=
685 scepclient_plugins=
686 pki_plugins=
687 scripts_plugins=
688 manager_plugins=
689 medsrv_plugins=
690
691 # location specific lists for checksumming,
692 # for src/libcharon, src/pluto, src/libhydra and src/libstrongswan
693 c_plugins=
694 p_plugins=
695 h_plugins=
696 s_plugins=
697
698 ADD_PLUGIN([test-vectors],         [s libcharon pluto openac scepclient pki])
699 ADD_PLUGIN([curl],                 [s libcharon pluto scepclient])
700 ADD_PLUGIN([ldap],                 [s libcharon pluto scepclient])
701 ADD_PLUGIN([mysql],                [s libcharon pluto pool manager medsrv])
702 ADD_PLUGIN([sqlite],               [s libcharon pluto pool manager medsrv])
703 ADD_PLUGIN([aes],                  [s libcharon pluto openac scepclient pki scripts])
704 ADD_PLUGIN([des],                  [s libcharon pluto openac scepclient pki scripts])
705 ADD_PLUGIN([blowfish],             [s libcharon pluto openac scepclient pki scripts])
706 ADD_PLUGIN([sha1],                 [s libcharon pluto openac scepclient pki scripts medsrv])
707 ADD_PLUGIN([sha2],                 [s libcharon pluto openac scepclient pki scripts medsrv])
708 ADD_PLUGIN([md4],                  [s libcharon openac manager scepclient pki])
709 ADD_PLUGIN([md5],                  [s libcharon pluto openac scepclient pki])
710 ADD_PLUGIN([random],               [s libcharon pluto openac scepclient pki scripts medsrv])
711 ADD_PLUGIN([x509],                 [s libcharon pluto openac scepclient pki scripts])
712 ADD_PLUGIN([revocation],           [s libcharon])
713 ADD_PLUGIN([pubkey],               [s libcharon])
714 ADD_PLUGIN([pkcs1],                [s libcharon pluto openac scepclient pki scripts manager medsrv])
715 ADD_PLUGIN([pgp],                  [s libcharon pluto])
716 ADD_PLUGIN([dnskey],               [s pluto])
717 ADD_PLUGIN([pem],                  [s libcharon pluto openac scepclient pki scripts manager medsrv])
718 ADD_PLUGIN([padlock],              [s libcharon])
719 ADD_PLUGIN([openssl],              [s libcharon pluto openac scepclient pki scripts manager medsrv])
720 ADD_PLUGIN([gcrypt],               [s libcharon pluto openac scepclient pki scripts manager medsrv])
721 ADD_PLUGIN([fips-prf],             [s libcharon])
722 ADD_PLUGIN([gmp],                  [s libcharon pluto openac scepclient pki scripts manager medsrv])
723 ADD_PLUGIN([agent],                [s libcharon])
724 ADD_PLUGIN([pkcs11],               [s libcharon pki])
725 ADD_PLUGIN([xcbc],                 [s libcharon])
726 ADD_PLUGIN([hmac],                 [s libcharon pluto scripts])
727 ADD_PLUGIN([ctr],                  [s libcharon scripts])
728 ADD_PLUGIN([ccm],                  [s libcharon scripts])
729 ADD_PLUGIN([gcm],                  [s libcharon scripts])
730 ADD_PLUGIN([xauth],                [p pluto])
731 ADD_PLUGIN([attr],                 [h libcharon pluto])
732 ADD_PLUGIN([attr-sql],             [h libcharon pluto])
733 ADD_PLUGIN([kernel-pfkey],         [h libcharon pluto])
734 ADD_PLUGIN([kernel-pfroute],       [h libcharon pluto])
735 ADD_PLUGIN([kernel-klips],         [h libcharon pluto])
736 ADD_PLUGIN([kernel-netlink],       [h libcharon pluto])
737 ADD_PLUGIN([resolve],              [h libcharon pluto])
738 ADD_PLUGIN([load-tester],          [c libcharon])
739 ADD_PLUGIN([socket-default],       [c libcharon])
740 ADD_PLUGIN([socket-raw],           [c libcharon])
741 ADD_PLUGIN([socket-dynamic],       [c libcharon])
742 ADD_PLUGIN([farp],                 [c libcharon])
743 ADD_PLUGIN([stroke],               [c libcharon])
744 ADD_PLUGIN([smp],                  [c libcharon])
745 ADD_PLUGIN([sql],                  [c libcharon])
746 ADD_PLUGIN([updown],               [c libcharon])
747 ADD_PLUGIN([eap-identity],         [c libcharon])
748 ADD_PLUGIN([eap-sim],              [c libcharon])
749 ADD_PLUGIN([eap-sim-file],         [c libcharon])
750 ADD_PLUGIN([eap-simaka-sql],       [c libcharon])
751 ADD_PLUGIN([eap-simaka-pseudonym], [c libcharon])
752 ADD_PLUGIN([eap-simaka-reauth],    [c libcharon])
753 ADD_PLUGIN([eap-aka],              [c libcharon])
754 ADD_PLUGIN([eap-aka-3gpp2],        [c libcharon])
755 ADD_PLUGIN([eap-md5],              [c libcharon])
756 ADD_PLUGIN([eap-gtc],              [c libcharon])
757 ADD_PLUGIN([eap-mschapv2],         [c libcharon])
758 ADD_PLUGIN([eap-radius],           [c libcharon])
759 ADD_PLUGIN([eap-tls],              [c libcharon])
760 ADD_PLUGIN([eap-ttls],             [c libcharon])
761 ADD_PLUGIN([eap-tnc],              [c libcharon])
762 ADD_PLUGIN([tnccs-11],             [c libcharon])
763 ADD_PLUGIN([medsrv],               [c libcharon])
764 ADD_PLUGIN([medcli],               [c libcharon])
765 ADD_PLUGIN([nm],                   [c libcharon])
766 ADD_PLUGIN([dhcp],                 [c libcharon])
767 ADD_PLUGIN([android],              [c libcharon])
768 ADD_PLUGIN([ha],                   [c libcharon])
769 ADD_PLUGIN([led],                  [c libcharon])
770 ADD_PLUGIN([uci],                  [c libcharon])
771 ADD_PLUGIN([addrblock],            [c libcharon])
772 ADD_PLUGIN([unit-tester],          [c libcharon])
773
774 AC_SUBST(libcharon_plugins)
775 AC_SUBST(pluto_plugins)
776 AC_SUBST(pool_plugins)
777 AC_SUBST(openac_plugins)
778 AC_SUBST(scepclient_plugins)
779 AC_SUBST(pki_plugins)
780 AC_SUBST(scripts_plugins)
781 AC_SUBST(manager_plugins)
782 AC_SUBST(medsrv_plugins)
783
784 AC_SUBST(c_plugins)
785 AC_SUBST(p_plugins)
786 AC_SUBST(h_plugins)
787 AC_SUBST(s_plugins)
788
789 dnl =========================
790 dnl  set Makefile.am vars
791 dnl =========================
792
793 dnl libstrongswan plugins
794 dnl =====================
795 AM_CONDITIONAL(USE_TEST_VECTORS, test x$test_vectors = xtrue)
796 AM_CONDITIONAL(USE_CURL, test x$curl = xtrue)
797 AM_CONDITIONAL(USE_LDAP, test x$ldap = xtrue)
798 AM_CONDITIONAL(USE_AES, test x$aes = xtrue)
799 AM_CONDITIONAL(USE_DES, test x$des = xtrue)
800 AM_CONDITIONAL(USE_BLOWFISH, test x$blowfish = xtrue)
801 AM_CONDITIONAL(USE_MD4, test x$md4 = xtrue)
802 AM_CONDITIONAL(USE_MD5, test x$md5 = xtrue)
803 AM_CONDITIONAL(USE_SHA1, test x$sha1 = xtrue)
804 AM_CONDITIONAL(USE_SHA2, test x$sha2 = xtrue)
805 AM_CONDITIONAL(USE_FIPS_PRF, test x$fips_prf = xtrue)
806 AM_CONDITIONAL(USE_GMP, test x$gmp = xtrue)
807 AM_CONDITIONAL(USE_RANDOM, test x$random = xtrue)
808 AM_CONDITIONAL(USE_X509, test x$x509 = xtrue)
809 AM_CONDITIONAL(USE_REVOCATION, test x$revocation = xtrue)
810 AM_CONDITIONAL(USE_PUBKEY, test x$pubkey = xtrue)
811 AM_CONDITIONAL(USE_PKCS1, test x$pkcs1 = xtrue)
812 AM_CONDITIONAL(USE_PGP, test x$pgp = xtrue)
813 AM_CONDITIONAL(USE_DNSKEY, test x$dnskey = xtrue)
814 AM_CONDITIONAL(USE_PEM, test x$pem = xtrue)
815 AM_CONDITIONAL(USE_HMAC, test x$hmac = xtrue)
816 AM_CONDITIONAL(USE_XCBC, test x$xcbc = xtrue)
817 AM_CONDITIONAL(USE_MYSQL, test x$mysql = xtrue)
818 AM_CONDITIONAL(USE_SQLITE, test x$sqlite = xtrue)
819 AM_CONDITIONAL(USE_PADLOCK, test x$padlock = xtrue)
820 AM_CONDITIONAL(USE_OPENSSL, test x$openssl = xtrue)
821 AM_CONDITIONAL(USE_GCRYPT, test x$gcrypt = xtrue)
822 AM_CONDITIONAL(USE_AGENT, test x$agent = xtrue)
823 AM_CONDITIONAL(USE_PKCS11, test x$pkcs11 = xtrue)
824 AM_CONDITIONAL(USE_CTR, test x$ctr = xtrue)
825 AM_CONDITIONAL(USE_CCM, test x$ccm = xtrue)
826 AM_CONDITIONAL(USE_GCM, test x$gcm = xtrue)
827
828 dnl charon plugins
829 dnl ==============
830 AM_CONDITIONAL(USE_STROKE, test x$stroke = xtrue)
831 AM_CONDITIONAL(USE_MEDSRV, test x$medsrv = xtrue)
832 AM_CONDITIONAL(USE_MEDCLI, test x$medcli = xtrue)
833 AM_CONDITIONAL(USE_NM, test x$nm = xtrue)
834 AM_CONDITIONAL(USE_UCI, test x$uci = xtrue)
835 AM_CONDITIONAL(USE_ANDROID, test x$android = xtrue)
836 AM_CONDITIONAL(USE_SMP, test x$smp = xtrue)
837 AM_CONDITIONAL(USE_SQL, test x$sql = xtrue)
838 AM_CONDITIONAL(USE_UPDOWN, test x$updown = xtrue)
839 AM_CONDITIONAL(USE_DHCP, test x$dhcp = xtrue)
840 AM_CONDITIONAL(USE_UNIT_TESTS, test x$unit_tests = xtrue)
841 AM_CONDITIONAL(USE_LOAD_TESTER, test x$load_tester = xtrue)
842 AM_CONDITIONAL(USE_HA, test x$ha = xtrue)
843 AM_CONDITIONAL(USE_LED, test x$led = xtrue)
844 AM_CONDITIONAL(USE_EAP_SIM, test x$eap_sim = xtrue)
845 AM_CONDITIONAL(USE_EAP_SIM_FILE, test x$eap_sim_file = xtrue)
846 AM_CONDITIONAL(USE_EAP_SIMAKA_SQL, test x$eap_simaka_sql = xtrue)
847 AM_CONDITIONAL(USE_EAP_SIMAKA_PSEUDONYM, test x$eap_simaka_pseudonym = xtrue)
848 AM_CONDITIONAL(USE_EAP_SIMAKA_REAUTH, test x$eap_simaka_reauth = xtrue)
849 AM_CONDITIONAL(USE_EAP_IDENTITY, test x$eap_identity = xtrue)
850 AM_CONDITIONAL(USE_EAP_MD5, test x$eap_md5 = xtrue)
851 AM_CONDITIONAL(USE_EAP_GTC, test x$eap_gtc = xtrue)
852 AM_CONDITIONAL(USE_EAP_AKA, test x$eap_aka = xtrue)
853 AM_CONDITIONAL(USE_EAP_AKA_3GPP2, test x$eap_aka_3gpp2 = xtrue)
854 AM_CONDITIONAL(USE_EAP_MSCHAPV2, test x$eap_mschapv2 = xtrue)
855 AM_CONDITIONAL(USE_EAP_TLS, test x$eap_tls = xtrue)
856 AM_CONDITIONAL(USE_EAP_TTLS, test x$eap_ttls = xtrue)
857 AM_CONDITIONAL(USE_EAP_TNC, test x$eap_tnc = xtrue)
858 AM_CONDITIONAL(USE_EAP_RADIUS, test x$eap_radius = xtrue)
859 AM_CONDITIONAL(USE_TNCCS_11, test x$tnccs_11 = xtrue)
860 AM_CONDITIONAL(USE_SOCKET_DEFAULT, test x$socket_default = xtrue)
861 AM_CONDITIONAL(USE_SOCKET_RAW, test x$socket_raw = xtrue)
862 AM_CONDITIONAL(USE_SOCKET_DYNAMIC, test x$socket_dynamic = xtrue)
863 AM_CONDITIONAL(USE_FARP, test x$farp = xtrue)
864 AM_CONDITIONAL(USE_ADDRBLOCK, test x$addrblock = xtrue)
865
866 dnl hydra plugins
867 dnl =============
868 AM_CONDITIONAL(USE_ATTR, test x$attr = xtrue)
869 AM_CONDITIONAL(USE_ATTR_SQL, test x$attr_sql = xtrue -o x$sql = xtrue)
870 AM_CONDITIONAL(USE_KERNEL_KLIPS, test x$kernel_klips = xtrue)
871 AM_CONDITIONAL(USE_KERNEL_NETLINK, test x$kernel_netlink = xtrue)
872 AM_CONDITIONAL(USE_KERNEL_PFKEY, test x$kernel_pfkey = xtrue)
873 AM_CONDITIONAL(USE_KERNEL_PFROUTE, test x$kernel_pfroute = xtrue)
874 AM_CONDITIONAL(USE_RESOLVE, test x$resolve = xtrue)
875
876 dnl pluto plugins
877 dnl =============
878 AM_CONDITIONAL(USE_XAUTH, test x$xauth = xtrue)
879
880 dnl other options
881 dnl =============
882 AM_CONDITIONAL(USE_SMARTCARD, test x$smartcard = xtrue)
883 AM_CONDITIONAL(USE_CISCO_QUIRKS, test x$cisco_quirks = xtrue)
884 AM_CONDITIONAL(USE_LEAK_DETECTIVE, test x$leak_detective = xtrue)
885 AM_CONDITIONAL(USE_LOCK_PROFILER, test x$lock_profiler = xtrue)
886 AM_CONDITIONAL(USE_NAT_TRANSPORT, test x$nat_transport = xtrue)
887 AM_CONDITIONAL(USE_VENDORID, test x$vendor_id = xtrue)
888 AM_CONDITIONAL(USE_XAUTH_VID, test x$xauth_vid = xtrue)
889 AM_CONDITIONAL(USE_DUMM, test x$dumm = xtrue)
890 AM_CONDITIONAL(USE_FAST, test x$fast = xtrue)
891 AM_CONDITIONAL(USE_MANAGER, test x$manager = xtrue)
892 AM_CONDITIONAL(USE_ME, test x$mediation = xtrue)
893 AM_CONDITIONAL(USE_INTEGRITY_TEST, test x$integrity_test = xtrue)
894 AM_CONDITIONAL(USE_LOAD_WARNING, test x$load_warning = xtrue)
895 AM_CONDITIONAL(USE_PLUTO, test x$pluto = xtrue)
896 AM_CONDITIONAL(USE_THREADS, test x$threads = xtrue)
897 AM_CONDITIONAL(USE_CHARON, test x$charon = xtrue)
898 AM_CONDITIONAL(USE_TOOLS, test x$tools = xtrue)
899 AM_CONDITIONAL(USE_SCRIPTS, test x$scripts = xtrue)
900 AM_CONDITIONAL(USE_LIBSTRONGSWAN, test x$charon = xtrue -o x$pluto = xtrue -o x$tools = xtrue)
901 AM_CONDITIONAL(USE_LIBHYDRA, test x$charon = xtrue -o x$pluto = xtrue)
902 AM_CONDITIONAL(USE_FILE_CONFIG, test x$pluto = xtrue -o x$stroke = xtrue)
903 AM_CONDITIONAL(USE_LIBCAP, test x$capabilities = xlibcap)
904 AM_CONDITIONAL(USE_VSTR, test x$vstr = xtrue)
905 AM_CONDITIONAL(USE_SIMAKA, test x$simaka = xtrue)
906 AM_CONDITIONAL(USE_TLS, test x$tls = xtrue)
907 AM_CONDITIONAL(MONOLITHIC, test x$monolithic = xtrue)
908
909 dnl ==============================
910 dnl  set global definitions
911 dnl ==============================
912
913 if test x$mediation = xtrue; then
914         AC_DEFINE(ME)
915 fi
916 if test x$capabilities = xlibcap -o x$capabilities = xnative; then
917         AC_DEFINE(CAPABILITIES)
918 fi
919 if test x$monolithic = xtrue; then
920         AC_DEFINE(MONOLITHIC)
921 fi
922
923
924 dnl ==============================
925 dnl  build Makefiles
926 dnl ==============================
927
928 AC_OUTPUT(
929         Makefile
930         man/Makefile
931         src/Makefile
932         src/include/Makefile
933         src/libstrongswan/Makefile
934         src/libstrongswan/plugins/aes/Makefile
935         src/libstrongswan/plugins/des/Makefile
936         src/libstrongswan/plugins/blowfish/Makefile
937         src/libstrongswan/plugins/md4/Makefile
938         src/libstrongswan/plugins/md5/Makefile
939         src/libstrongswan/plugins/sha1/Makefile
940         src/libstrongswan/plugins/sha2/Makefile
941         src/libstrongswan/plugins/fips_prf/Makefile
942         src/libstrongswan/plugins/gmp/Makefile
943         src/libstrongswan/plugins/random/Makefile
944         src/libstrongswan/plugins/hmac/Makefile
945         src/libstrongswan/plugins/xcbc/Makefile
946         src/libstrongswan/plugins/x509/Makefile
947         src/libstrongswan/plugins/revocation/Makefile
948         src/libstrongswan/plugins/pubkey/Makefile
949         src/libstrongswan/plugins/pkcs1/Makefile
950         src/libstrongswan/plugins/pgp/Makefile
951         src/libstrongswan/plugins/dnskey/Makefile
952         src/libstrongswan/plugins/pem/Makefile
953         src/libstrongswan/plugins/curl/Makefile
954         src/libstrongswan/plugins/ldap/Makefile
955         src/libstrongswan/plugins/mysql/Makefile
956         src/libstrongswan/plugins/sqlite/Makefile
957         src/libstrongswan/plugins/padlock/Makefile
958         src/libstrongswan/plugins/openssl/Makefile
959         src/libstrongswan/plugins/gcrypt/Makefile
960         src/libstrongswan/plugins/agent/Makefile
961         src/libstrongswan/plugins/pkcs11/Makefile
962         src/libstrongswan/plugins/ctr/Makefile
963         src/libstrongswan/plugins/ccm/Makefile
964         src/libstrongswan/plugins/gcm/Makefile
965         src/libstrongswan/plugins/test_vectors/Makefile
966         src/libhydra/Makefile
967         src/libhydra/plugins/attr/Makefile
968         src/libhydra/plugins/attr_sql/Makefile
969         src/libhydra/plugins/kernel_klips/Makefile
970         src/libhydra/plugins/kernel_netlink/Makefile
971         src/libhydra/plugins/kernel_pfkey/Makefile
972         src/libhydra/plugins/kernel_pfroute/Makefile
973         src/libhydra/plugins/resolve/Makefile
974         src/libfreeswan/Makefile
975         src/libsimaka/Makefile
976         src/libtls/Makefile
977         src/pluto/Makefile
978         src/pluto/plugins/xauth/Makefile
979         src/whack/Makefile
980         src/charon/Makefile
981         src/libcharon/Makefile
982         src/libcharon/plugins/eap_aka/Makefile
983         src/libcharon/plugins/eap_aka_3gpp2/Makefile
984         src/libcharon/plugins/eap_identity/Makefile
985         src/libcharon/plugins/eap_md5/Makefile
986         src/libcharon/plugins/eap_gtc/Makefile
987         src/libcharon/plugins/eap_sim/Makefile
988         src/libcharon/plugins/eap_sim_file/Makefile
989         src/libcharon/plugins/eap_simaka_sql/Makefile
990         src/libcharon/plugins/eap_simaka_pseudonym/Makefile
991         src/libcharon/plugins/eap_simaka_reauth/Makefile
992         src/libcharon/plugins/eap_mschapv2/Makefile
993         src/libcharon/plugins/eap_tls/Makefile
994         src/libcharon/plugins/eap_ttls/Makefile
995         src/libcharon/plugins/eap_tnc/Makefile
996         src/libcharon/plugins/eap_radius/Makefile
997         src/libcharon/plugins/tnccs_11/Makefile
998         src/libcharon/plugins/socket_default/Makefile
999         src/libcharon/plugins/socket_raw/Makefile
1000         src/libcharon/plugins/socket_dynamic/Makefile
1001         src/libcharon/plugins/farp/Makefile
1002         src/libcharon/plugins/smp/Makefile
1003         src/libcharon/plugins/sql/Makefile
1004         src/libcharon/plugins/medsrv/Makefile
1005         src/libcharon/plugins/medcli/Makefile
1006         src/libcharon/plugins/nm/Makefile
1007         src/libcharon/plugins/addrblock/Makefile
1008         src/libcharon/plugins/uci/Makefile
1009         src/libcharon/plugins/ha/Makefile
1010         src/libcharon/plugins/led/Makefile
1011         src/libcharon/plugins/android/Makefile
1012         src/libcharon/plugins/stroke/Makefile
1013         src/libcharon/plugins/updown/Makefile
1014         src/libcharon/plugins/dhcp/Makefile
1015         src/libcharon/plugins/unit_tester/Makefile
1016         src/libcharon/plugins/load_tester/Makefile
1017         src/stroke/Makefile
1018         src/ipsec/Makefile
1019         src/starter/Makefile
1020         src/_updown/Makefile
1021         src/_updown_espmark/Makefile
1022         src/_copyright/Makefile
1023         src/openac/Makefile
1024         src/scepclient/Makefile
1025         src/pki/Makefile
1026         src/dumm/Makefile
1027         src/dumm/ext/extconf.rb
1028         src/libfast/Makefile
1029         src/manager/Makefile
1030         src/medsrv/Makefile
1031         src/checksum/Makefile
1032         scripts/Makefile
1033         testing/Makefile
1034 )