restructuring of configuration backends
[strongswan.git] / configure.in
1 dnl  configure.in for linux strongSwan
2 dnl  Copyright (C) 2006 Martin Willi
3 dnl  Hochschule fuer Technik Rapperswil
4 dnl 
5 dnl  This program is free software; you can redistribute it and/or modify it
6 dnl  under the terms of the GNU General Public License as published by the
7 dnl  Free Software Foundation; either version 2 of the License, or (at your
8 dnl  option) any later version.  See <http://www.fsf.org/copyleft/gpl.txt>.
9 dnl 
10 dnl  This program is distributed in the hope that it will be useful, but
11 dnl  WITHOUT ANY WARRANTY; without even the implied warranty of MERCHANTABILITY
12 dnl  or FITNESS FOR A PARTICULAR PURPOSE.  See the GNU General Public License
13 dnl  for more details.
14
15 dnl ===========================
16 dnl  initialize & set some vars
17 dnl ===========================
18
19 AC_INIT(strongSwan,4.1.2)
20 AM_INIT_AUTOMAKE(tar-ustar)
21 AC_C_BIGENDIAN
22 AC_SUBST(confdir, '${sysconfdir}')
23
24 dnl =================================
25 dnl  check --enable-xxx & --with-xxx
26 dnl =================================
27
28
29 AC_ARG_WITH(
30     [default-pkcs11],
31     AS_HELP_STRING([--with-default-pkcs11=lib],[set the default PKCS11 library other than "/usr/lib/opensc-pkcs11.so"]),
32     [AC_DEFINE_UNQUOTED(PKCS11_DEFAULT_LIB, "$withval")],
33     [AC_DEFINE_UNQUOTED(PKCS11_DEFAULT_LIB, "/usr/lib/opensc-pkcs11.so")]
34 )
35
36 AC_ARG_WITH(
37     [xauth-module],
38     AS_HELP_STRING([--with-xauth-module=lib],[set the path to the XAUTH module]),
39     [AC_DEFINE_UNQUOTED(XAUTH_DEFAULT_LIB, "$withval")],
40 )
41
42 AC_ARG_WITH(
43     [random-device],
44     AS_HELP_STRING([--with-random-device=dev],[set the device for real random data other than "/dev/random"]),
45     [AC_DEFINE_UNQUOTED(DEV_RANDOM, "$withval")],
46     [AC_DEFINE_UNQUOTED(DEV_RANDOM, "/dev/random")]
47 )
48 AC_ARG_WITH(
49     [resolv-conf],
50     AS_HELP_STRING([--with-resolv-conf=file],[set the file to store DNS server information other than "sysconfdir/resolv.conf"]),
51     [AC_DEFINE_UNQUOTED(RESOLV_CONF, "$withval")],
52     [AC_DEFINE_UNQUOTED(RESOLV_CONF, "${sysconfdir}/resolv.conf")]
53 )
54
55 AC_ARG_WITH(
56     [urandom-device],
57     AS_HELP_STRING([--with-urandom-device=dev],[set the device for pseudo random data other than "/dev/urandom"]),
58     [AC_DEFINE_UNQUOTED(DEV_URANDOM, "$withval")],
59     [AC_DEFINE_UNQUOTED(DEV_URANDOM, "/dev/urandom")]
60 )
61
62 AC_ARG_WITH(
63     [ipsecdir],
64     AS_HELP_STRING([--with-ipsecdir=dir],[installation path for ipsec tools other than "libexecdir/ipsec"]),
65     [AC_SUBST(ipsecdir, "$withval")],
66     [AC_SUBST(ipsecdir, "${libexecdir}/ipsec")]
67 )
68
69 AC_ARG_WITH(
70     [piddir],
71     AS_HELP_STRING([--with-piddir=dir],[path for PID and UNIX socket files other than "/var/run"]),
72     [AC_SUBST(piddir, "$withval")],
73     [AC_SUBST(piddir, "/var/run")]
74 )
75
76 AC_ARG_WITH(
77     [eapdir],
78     AS_HELP_STRING([--with-eapdir=dir],[path for pluggable EAP modules other than "ipsecdir/plugins/eap"]),
79     [AC_SUBST(eapdir, "$withval")],
80     [AC_SUBST(eapdir, "${ipsecdir}/plugins/eap")]
81 )
82
83 AC_ARG_WITH(
84     [backenddir],
85     AS_HELP_STRING([--with-backenddir=dir],[path for pluggable configuration backend modules other than "ipsecdir/plugins/backends"]),
86     [AC_SUBST(backenddir, "$withval")],
87     [AC_SUBST(backenddir, "${ipsecdir}/plugins/backends")]
88 )
89
90 AC_ARG_WITH(
91     [interfacedir],
92     AS_HELP_STRING([--with-interfacedir=dir],[path for pluggable control interface modules other than "ipsecdir/plugins/interfaces"]),
93     [AC_SUBST(interfacedir, "$withval")],
94     [AC_SUBST(interfacedir, "${ipsecdir}/plugins/interfaces")]
95 )
96
97 AC_ARG_WITH(
98     [sim-reader],
99     AS_HELP_STRING([--with-sim-reader=library.so],[library containing the sim_run_alg() function for EAP-SIM]),
100     [AC_DEFINE_UNQUOTED(SIM_READER_LIB, "$withval")]
101 )
102
103 AC_ARG_WITH(
104     [linux-headers],
105     AS_HELP_STRING([--with-linux-headers=dir],[use the linux header files in dir instead of the supplied ones in "src/include"]),
106     [AC_SUBST(linuxdir, "$withval")], [AC_SUBST(linuxdir, "../include")]
107 )
108 AC_SUBST(LINUX_HEADERS)
109
110 AC_ARG_ENABLE(
111     [http],
112     AS_HELP_STRING([--enable-http],[enable OCSP and fetching of Certificates and CRLs over HTTP (default is NO). Requires libcurl.]),
113     [if test x$enableval = xyes; then
114         http=true
115         AC_DEFINE(LIBCURL)
116     fi]
117 )
118 AM_CONDITIONAL(USE_LIBCURL, test x$http = xtrue)
119
120 AC_ARG_ENABLE(
121     [ldap],
122     AS_HELP_STRING([--enable-ldap],[enable fetching of CRLs from LDAP (default is NO). Requires openLDAP.]),
123     [if test x$enableval = xyes; then
124         ldap=true
125         AC_DEFINE(LIBLDAP)
126     fi]
127 )
128 AM_CONDITIONAL(USE_LIBLDAP, test x$ldap = xtrue)
129
130 AC_ARG_ENABLE(
131     [dbus],
132     AS_HELP_STRING([--enable-dbus],[enable DBUS configuration and control interface (default is NO). Requires libdbus.]),
133     [if test x$enableval = xyes; then
134         dbus=true
135         AC_DEFINE(LIBDBUS)
136     fi]
137 )
138 AM_CONDITIONAL(USE_LIBDBUS, test x$dbus = xtrue)
139
140 AC_ARG_ENABLE(
141     [xml],
142     AS_HELP_STRING([--enable-xml],[enable XML configuration and control interface (default is NO). Requires libxml.]),
143     [if test x$enableval = xyes; then
144         xml=true
145         AC_DEFINE(LIBXML)
146     fi]
147 )
148 AM_CONDITIONAL(USE_LIBXML, test x$xml = xtrue)
149
150 AC_ARG_ENABLE(
151     [smartcard],
152     AS_HELP_STRING([--enable-smartcard],[enable smartcard support (default is NO).]),
153     [if test x$enableval = xyes; then
154         smartcard=true
155         AC_DEFINE(SMARTCARD)
156     fi]
157 )
158 AM_CONDITIONAL(USE_SMARTCARD, test x$smartcard = xtrue)
159
160 AC_ARG_ENABLE(
161     [cisco-quirks],
162     AS_HELP_STRING([--enable-cisco-quirks],[enable support of Cisco VPN client (default is NO).]),
163     [if test x$enableval = xyes; then
164         cisco_quirks=true
165     fi]
166 )
167 AM_CONDITIONAL(USE_CISCO_QUIRKS, test x$cisco_quirks = xtrue)
168
169 AC_ARG_ENABLE(
170     [leak-detective],
171     AS_HELP_STRING([--enable-leak-detective],[enable malloc hooks to find memory leaks (default is NO).]),
172     [if test x$enableval = xyes; then
173         leak_detective=true
174     fi]
175 )
176 AM_CONDITIONAL(USE_LEAK_DETECTIVE, test x$leak_detective = xtrue)
177
178 AC_ARG_ENABLE(
179     [eap-sim],
180     AS_HELP_STRING([--enable-eap-sim],[build SIM authenication module for EAP (default is NO).]),
181     [if test x$enableval = xyes; then
182         eap_sim=true
183     fi]
184 )
185 AM_CONDITIONAL(BUILD_EAP_SIM, test x$eap_sim = xtrue)
186
187 AC_ARG_ENABLE(
188     [nat-transport],
189     AS_HELP_STRING([--enable-nat-transport],[enable NAT traversal with IPsec transport mode (default is NO).]),
190     [if test x$enableval = xyes; then
191         nat_transport=true
192     fi]
193 )
194 AM_CONDITIONAL(USE_NAT_TRANSPORT, test x$nat_transport = xtrue)
195
196 AC_ARG_ENABLE(
197     [vendor-id],
198     AS_HELP_STRING([--disable-vendor-id],[disable the sending of the strongSwan vendor ID (default is NO).]),
199     [if test x$enableval = xyes; then
200         vendor_id=true
201      else
202         vendor_id=false
203     fi],
204     vendor_id=true
205 )
206 AM_CONDITIONAL(USE_VENDORID, test x$vendor_id = xtrue)
207
208 dnl =========================
209 dnl  check required programs
210 dnl =========================
211
212 AC_PROG_INSTALL
213 AC_PROG_LIBTOOL
214 AC_PROG_LEX
215 AC_PROG_YACC
216 AC_PROG_CC()
217 AC_PATH_PROG([GPERF], [gperf], [], [$PATH:/bin:/usr/bin:/usr/local/bin])
218 AC_PATH_PROG([PERL], [perl], [], [$PATH:/bin:/usr/bin:/usr/local/bin])
219
220 dnl ==========================
221 dnl  check required libraries
222 dnl ==========================
223
224 AC_CHECK_FUNCS(backtrace)
225 AC_CHECK_FUNCS(getifaddrs)
226
227 AC_HAVE_LIBRARY([gmp],[LIBS="$LIBS"],[AC_MSG_ERROR([GNU Multi Precision library gmp not found])])       
228 if test "$ldap" = "true"; then
229     AC_HAVE_LIBRARY([ldap],[LIBS="$LIBS"],[AC_MSG_ERROR([LDAP enabled, but library ldap not found])])
230     AC_HAVE_LIBRARY([lber],[LIBS="$LIBS"],[AC_MSG_ERROR([LDAP enabled, but library lber not found])])
231 fi
232 if test "$http" = "true"; then
233     AC_HAVE_LIBRARY([curl],[LIBS="$LIBS"],[AC_MSG_ERROR([HTTP enabled, but library curl not found])])
234 fi
235
236 if test "$dbus" = "true"; then
237         PKG_CHECK_MODULES(dbus, dbus-1,, AC_MSG_ERROR([No libdbus package information found]))
238         AC_SUBST(dbus_CFLAGS)
239         AC_SUBST(dbus_LIBS)
240 fi
241
242 if test "$xml" = "true"; then
243         PKG_CHECK_MODULES(xml, libxml-2.0,, AC_MSG_ERROR([No libxml2 package information found]))
244         AC_SUBST(xml_CFLAGS)
245         AC_SUBST(xml_LIBS)
246 fi
247
248 dnl =============================
249 dnl  check required header files
250 dnl =============================
251
252
253 AC_MSG_CHECKING([gmp.h version >= 4.1.4])
254 AC_TRY_COMPILE(
255     [#include "gmp.h"],
256     [
257         #if (__GNU_MP_VERSION*100 +  __GNU_MP_VERSION_MINOR*10 + __GNU_MP_VERSION_PATCHLEVEL) < 414
258             #error bad gmp
259         #endif
260     ], 
261     [AC_MSG_RESULT([yes])], [AC_MSG_RESULT([no]); AC_MSG_ERROR([No usable gmp.h found!])]
262 )
263 if test "$ldap" = "true"; then
264     AC_CHECK_HEADER([ldap.h],,[AC_MSG_ERROR([LDAP enabled, but ldap.h not found!])])
265 fi
266 if test "$http" = "true"; then
267     AC_CHECK_HEADER([curl/curl.h],,[AC_MSG_ERROR([HTTP enabled, but curl.h not found!])])
268 fi
269
270 dnl ==============================
271 dnl  build Makefiles
272 dnl ==============================
273
274 AC_OUTPUT(
275         Makefile
276         src/Makefile
277         src/include/Makefile
278         src/libstrongswan/Makefile
279         src/libcrypto/Makefile
280         src/libfreeswan/Makefile
281         src/pluto/Makefile
282         src/whack/Makefile
283         src/charon/Makefile
284         src/stroke/Makefile
285         src/ipsec/Makefile
286         src/starter/Makefile
287         src/_updown/Makefile
288         src/_updown_espmark/Makefile
289         src/_copyright/Makefile
290         src/openac/Makefile
291         src/scepclient/Makefile
292 )