If cross-compiling, test for the existence of pthread_condattr_setclock only
[strongswan.git] / configure.in
1 dnl  configure.in for linux strongSwan
2 dnl  Copyright (C) 2006 Martin Willi
3 dnl  Hochschule fuer Technik Rapperswil
4 dnl
5 dnl  This program is free software; you can redistribute it and/or modify it
6 dnl  under the terms of the GNU General Public License as published by the
7 dnl  Free Software Foundation; either version 2 of the License, or (at your
8 dnl  option) any later version.  See <http://www.fsf.org/copyleft/gpl.txt>.
9 dnl
10 dnl  This program is distributed in the hope that it will be useful, but
11 dnl  WITHOUT ANY WARRANTY; without even the implied warranty of MERCHANTABILITY
12 dnl  or FITNESS FOR A PARTICULAR PURPOSE.  See the GNU General Public License
13 dnl  for more details.
14
15 dnl ===========================
16 dnl  initialize & set some vars
17 dnl ===========================
18
19 AC_INIT(strongSwan,4.3.6)
20 AM_INIT_AUTOMAKE(tar-ustar)
21 AC_CONFIG_MACRO_DIR([m4/config])
22 PKG_PROG_PKG_CONFIG
23
24 dnl =================================
25 dnl  check --enable-xxx & --with-xxx
26 dnl =================================
27
28 m4_include(m4/macros/with.m4)
29
30 ARG_WITH_SUBST([default-pkcs11],     [/usr/lib/opensc-pkcs11.so], [set the default PKCS11 library])
31 ARG_WITH_SUBST([random-device],      [/dev/random], [set the device to read real random data from])
32 ARG_WITH_SUBST([urandom-device],     [/dev/urandom], [set the device to read pseudo random data from])
33 ARG_WITH_SUBST([strongswan-conf],    [${sysconfdir}/strongswan.conf], [set the strongswan.conf file location])
34 ARG_WITH_SUBST([resolv-conf],        [${sysconfdir}/resolv.conf], [set the file to use in DNS handler plugin])
35 ARG_WITH_SUBST([piddir],             [/var/run], [set path for PID and UNIX socket files])
36 ARG_WITH_SUBST([ipsecdir],           [${libexecdir%/}/ipsec], [set installation path for ipsec tools])
37 ARG_WITH_SUBST([plugindir],          [${ipsecdir%/}/plugins], [set the installation path of plugins])
38 ARG_WITH_SUBST([nm-ca-dir],          [/usr/share/ca-certificates], [directory the NM plugin uses to look up trusted root certificates])
39 ARG_WITH_SUBST([linux-headers],      [\${top_srcdir}/src/include], [set directory of linux header files to use])
40 ARG_WITH_SUBST([routing-table],      [220], [set routing table to use for IPsec routes])
41 ARG_WITH_SUBST([routing-table-prio], [220], [set priority for IPsec routing table])
42
43 ARG_WITH_SET([capabilities],         [no], [set capability dropping library. Currently only the value "libcap" is supported])
44
45 AC_ARG_WITH(
46         [xauth-module],
47         AS_HELP_STRING([--with-xauth-module=lib],[set the path to the XAUTH module]),
48         [AC_DEFINE_UNQUOTED(XAUTH_DEFAULT_LIB, "$withval")],
49 )
50
51 AC_ARG_WITH(
52         [user],
53         AS_HELP_STRING([--with-user=user],[change user of the daemons to "user" after startup (default is "root").]),
54         [AC_DEFINE_UNQUOTED(IPSEC_USER, "$withval") AC_SUBST(ipsecuser, "$withval")],
55         [AC_SUBST(ipsecuser, "root")]
56 )
57
58 AC_ARG_WITH(
59         [group],
60         AS_HELP_STRING([--with-group=group],[change group of the daemons to "group" after startup (default is "root").]),
61         [AC_DEFINE_UNQUOTED(IPSEC_GROUP, "$withval") AC_SUBST(ipsecgroup, "$withval")],
62         [AC_SUBST(ipsecgroup, "root")]
63 )
64
65 m4_include(m4/macros/enable-disable.m4)
66
67 ARG_ENABL_SET([curl],           [enable CURL fetcher plugin to fetch files via libcurl. Requires libcurl.])
68 ARG_ENABL_SET([ldap],           [enable LDAP fetching plugin to fetch files via libldap. Requires openLDAP.])
69 ARG_DISBL_SET([aes],            [disable AES software implementation plugin.])
70 ARG_DISBL_SET([des],            [disable DES/3DES software implementation plugin.])
71 ARG_ENABL_SET([blowfish],       [enable Blowfish software implementation plugin.])
72 ARG_ENABL_SET([md4],            [enable MD4 software implementation plugin.])
73 ARG_DISBL_SET([md5],            [disable MD5 software implementation plugin.])
74 ARG_DISBL_SET([sha1],           [disable SHA1 software implementation plugin.])
75 ARG_DISBL_SET([sha2],           [disable SHA256/SHA384/SHA512 software implementation plugin.])
76 ARG_DISBL_SET([fips-prf],       [disable FIPS PRF software implementation plugin.])
77 ARG_DISBL_SET([gmp],            [disable GNU MP (libgmp) based crypto implementation plugin.])
78 ARG_DISBL_SET([random],         [disable RNG implementation on top of /dev/(u)random.])
79 ARG_DISBL_SET([x509],           [disable X509 certificate implementation plugin.])
80 ARG_DISBL_SET([pubkey],         [disable RAW public key support plugin.])
81 ARG_DISBL_SET([pkcs1],          [disable PKCS1 key decoding plugin.])
82 ARG_DISBL_SET([pgp],            [disable PGP key decoding plugin.])
83 ARG_DISBL_SET([dnskey],         [disable DNS RR key decoding plugin.])
84 ARG_DISBL_SET([pem],            [disable PEM decoding plugin.])
85 ARG_DISBL_SET([hmac],           [disable HMAC crypto implementation plugin.])
86 ARG_DISBL_SET([xcbc],           [disable xcbc crypto implementation plugin.])
87 ARG_ENABL_SET([test-vectors],   [enable plugin providing crypto test vectors.])
88 ARG_ENABL_SET([mysql],          [enable MySQL database support. Requires libmysqlclient_r.])
89 ARG_ENABL_SET([sqlite],         [enable SQLite database support. Requires libsqlite3.])
90 ARG_DISBL_SET([stroke],         [disable charons stroke (pluto compatibility) configuration backend.])
91 ARG_ENABL_SET([medsrv],         [enable mediation server web frontend and daemon plugin.])
92 ARG_ENABL_SET([medcli],         [enable mediation client configuration database plugin.])
93 ARG_ENABL_SET([smp],            [enable SMP configuration and control interface. Requires libxml.])
94 ARG_ENABL_SET([sql],            [enable SQL database configuration backend.])
95 ARG_ENABL_SET([smartcard],      [enable smartcard support.])
96 ARG_ENABL_SET([cisco-quirks],   [enable support of Cisco VPN client.])
97 ARG_ENABL_SET([leak-detective], [enable malloc hooks to find memory leaks.])
98 ARG_ENABL_SET([lock-profiler],  [enable lock/mutex profiling code.])
99 ARG_ENABL_SET([unit-tests],     [enable unit tests on IKEv2 daemon startup.])
100 ARG_ENABL_SET([load-tester],    [enable load testing plugin for IKEv2 daemon.])
101 ARG_ENABL_SET([eap-sim],        [enable SIM authenication module for EAP.])
102 ARG_ENABL_SET([eap-sim-file],   [enable EAP-SIM backend based on a triplet file.])
103 ARG_ENABL_SET([eap-identity],   [enable EAP module providing EAP-Identity helper.])
104 ARG_ENABL_SET([eap-md5],        [enable EAP MD5 (CHAP) authenication module.])
105 ARG_ENABL_SET([eap-gtc],        [enable PAM based EAP GTC authenication module.])
106 ARG_ENABL_SET([eap-aka],        [enable EAP AKA authentication module.])
107 ARG_ENABL_SET([eap-aka-3gpp2],  [enable EAP AKA backend implementing 3GPP2 algorithms in software. Requires libgmp.])
108 ARG_ENABL_SET([eap-mschapv2],   [enable EAP MS-CHAPv2 authenication module.])
109 ARG_ENABL_SET([eap-radius],     [enable RADIUS proxy authenication module.])
110 ARG_DISBL_SET([kernel-netlink], [disable the netlink kernel interface.])
111 ARG_ENABL_SET([kernel-pfkey],   [enable the PF_KEY kernel interface.])
112 ARG_ENABL_SET([kernel-pfroute], [enable the PF_ROUTE kernel interface.])
113 ARG_ENABL_SET([kernel-klips],   [enable the KLIPS kernel interface.])
114 ARG_ENABL_SET([nat-transport],  [enable NAT traversal with IPsec transport mode in pluto.])
115 ARG_DISBL_SET([vendor-id],      [disable the sending of the strongSwan vendor ID in pluto.])
116 ARG_DISBL_SET([xauth-vid],      [disable the sending of the XAUTH vendor ID.])
117 ARG_ENABL_SET([dumm],           [enable the DUMM UML test framework.])
118 ARG_ENABL_SET([fast],           [enable libfast (FastCGI Application Server w/ templates.])
119 ARG_ENABL_SET([manager],        [enable web management console (proof of concept).])
120 ARG_ENABL_SET([mediation],      [enable IKEv2 Mediation Extension.])
121 ARG_ENABL_SET([integrity-test], [enable integrity testing of libstrongswan and plugins.])
122 ARG_DISBL_SET([pluto],          [disable the IKEv1 keying daemon pluto.])
123 ARG_DISBL_SET([threads],        [disable the use of threads in pluto. Charon always uses threads.])
124 ARG_DISBL_SET([charon],         [disable the IKEv2 keying daemon charon.])
125 ARG_DISBL_SET([tools],          [disable additional utilities (openac, scepclient and pki).])
126 ARG_DISBL_SET([scripts],        [disable additional utilities (found in directory scripts).])
127 ARG_DISBL_SET([updown],         [disable updown firewall script plugin.])
128 ARG_DISBL_SET([attr],           [disable strongswan.conf based configuration attribute plugin.])
129 ARG_ENABL_SET([attr-sql],       [enable SQL based configuration attribute plugin.])
130 ARG_DISBL_SET([resolve],        [disable resolve DNS handler plugin.])
131 ARG_ENABL_SET([padlock],        [enables VIA Padlock crypto plugin.])
132 ARG_ENABL_SET([openssl],        [enables the OpenSSL crypto plugin.])
133 ARG_ENABL_SET([gcrypt],         [enables the libgcrypt plugin.])
134 ARG_ENABL_SET([agent],          [enables the ssh-agent signing plugin.])
135 ARG_ENABL_SET([uci],            [enable OpenWRT UCI configuration plugin.])
136 ARG_ENABL_SET([nm],             [enable NetworkManager plugin.])
137 ARG_ENABL_SET([vstr],           [enforce using the Vstr string library to replace glibc-like printf hooks.])
138
139 dnl =========================
140 dnl  set up compiler and flags
141 dnl =========================
142
143 if test -z "$CFLAGS"; then
144         CFLAGS="-g -O2 -Wall -Wno-format -Wno-pointer-sign -Wno-strict-aliasing"
145 fi
146 AC_PROG_CC
147 AC_LIB_PREFIX
148 AC_C_BIGENDIAN
149
150 dnl =========================
151 dnl  check required programs
152 dnl =========================
153
154 AC_PROG_INSTALL
155 AC_PROG_LIBTOOL
156 AC_PROG_EGREP
157 AC_PROG_AWK
158 AC_PROG_LEX
159 AC_PROG_YACC
160 AC_PATH_PROG([PERL], [perl], [], [$PATH:/bin:/usr/bin:/usr/local/bin])
161 AC_PATH_PROG([GPERF], [gperf], [], [$PATH:/bin:/usr/bin:/usr/local/bin])
162
163 dnl because gperf is not needed by end-users we just report it but do not abort on failure
164 AC_MSG_CHECKING([gperf version >= 3.0.0])
165 if test -x "$GPERF"; then
166         if test "`$GPERF --version | $AWK -F' ' '/^GNU gperf/ { print $3 }' | $AWK -F. '{ print $1 }'`" -ge "3"; then
167                 AC_MSG_RESULT([yes])
168         else
169                 AC_MSG_RESULT([no])
170         fi
171 else
172         AC_MSG_RESULT([not found])
173 fi
174
175 dnl translate user/group to numercial ids
176 AC_MSG_CHECKING([for uid of user "$ipsecuser"])
177 ipsecuid=`id -u $ipsecuser 2>/dev/null`
178 if test -n "$ipsecuid"; then
179         AC_MSG_RESULT([$ipsecuid])
180         AC_SUBST(ipsecuid)
181 else
182         AC_MSG_ERROR([not found])
183 fi
184 AC_MSG_CHECKING([for gid of group "$ipsecgroup"])
185 ipsecgid=`$EGREP "^$ipsecgroup:" /etc/group | $AWK -F: '{ print $3 }'`
186 if test -n "$ipsecgid"; then
187         AC_MSG_RESULT([$ipsecgid])
188         AC_SUBST(ipsecgid)
189 else
190         AC_MSG_ERROR([not found])
191 fi
192
193 dnl =========================
194 dnl  dependency calculation
195 dnl =========================
196
197 if test x$eap_aka_3gpp2 = xtrue; then
198         gmp=true;
199 fi
200
201 if test x$eap_aka = xtrue; then
202         fips_prf=true;
203         sha1=true;
204 fi
205
206 if test x$eap_sim = xtrue; then
207         fips_prf=true;
208 fi
209
210 if test x$fips_prf = xtrue; then
211         sha1=true;
212 fi
213
214 if test x$smp = xtrue; then
215         xml=true
216 fi
217
218 if test x$manager = xtrue; then
219         fast=true
220 fi
221
222 if test x$medsrv = xtrue; then
223         mediation=true
224         fast=true
225 fi
226
227 if test x$medcli = xtrue; then
228         mediation=true
229 fi
230
231 dnl ===========================================
232 dnl  check required libraries and header files
233 dnl ===========================================
234
235 AC_HEADER_STDBOOL
236 AC_FUNC_ALLOCA
237
238 dnl libraries needed on some platforms but not on others
239 dnl ====================================================
240 saved_LIBS=$LIBS
241
242 dnl FreeBSD and Mac OS X have dlopen integrated in libc, Linux needs libdl
243 LIBS=""
244 AC_SEARCH_LIBS(dlopen, dl, [DLLIB=$LIBS])
245 AC_SUBST(DLLIB)
246
247 dnl glibc's backtrace() can be replicated on FreeBSD with libexecinfo
248 LIBS=""
249 AC_SEARCH_LIBS(backtrace, execinfo, [BTLIB=$LIBS])
250 AC_CHECK_FUNCS(backtrace)
251 AC_SUBST(BTLIB)
252
253 dnl OpenSolaris needs libsocket and libnsl for socket()
254 LIBS=""
255 AC_SEARCH_LIBS(socket, socket, [SOCKLIB=$LIBS],
256         [AC_CHECK_LIB(nsl, socket, [SOCKLIB="-lsocket -lnsl"], [], [-lsocket])]
257 )
258 AC_SUBST(SOCKLIB)
259
260 dnl FreeBSD has clock_gettime in libc, Linux needs librt
261 LIBS=""
262 AC_SEARCH_LIBS(clock_gettime, rt, [RTLIB=$LIBS])
263 AC_CHECK_FUNCS(clock_gettime)
264 AC_SUBST(RTLIB)
265
266 LIBS=$saved_LIBS
267 dnl ======================
268
269 AC_MSG_CHECKING(for dladdr)
270 AC_TRY_COMPILE(
271         [#define _GNU_SOURCE
272          #include <dlfcn.h>],
273         [Dl_info* info = 0;
274          dladdr(0, info);],
275         [AC_MSG_RESULT([yes]); AC_DEFINE([HAVE_DLADDR])],
276         [AC_MSG_RESULT([no])]
277 )
278
279 dnl check if pthread_condattr_setclock(CLOCK_MONOTONE) is supported
280 saved_LIBS=$LIBS
281 LIBS="-lpthread"
282 AC_MSG_CHECKING([for pthread_condattr_setclock(CLOCK_MONOTONE)])
283 AC_TRY_RUN(
284         [#include <pthread.h>
285          int main() { pthread_condattr_t attr;
286                 pthread_condattr_init(&attr);
287                 return pthread_condattr_setclock(&attr, CLOCK_MONOTONIC);}],
288         [AC_MSG_RESULT([yes]); AC_DEFINE([HAVE_CONDATTR_CLOCK_MONOTONIC])],
289         [AC_MSG_RESULT([no])],
290         dnl Check existence of pthread_condattr_setclock if cross-compiling
291         [AC_MSG_RESULT([unknown]);
292          AC_CHECK_FUNCS(pthread_condattr_setclock,
293                 [AC_DEFINE([HAVE_CONDATTR_CLOCK_MONOTONIC])]
294         )]
295 )
296
297 LIBS=$saved_LIBS
298
299 AC_CHECK_FUNCS(prctl)
300
301 AC_CHECK_HEADERS(sys/sockio.h)
302 AC_CHECK_HEADERS(net/pfkeyv2.h netipsec/ipsec.h netinet6/ipsec.h linux/udp.h)
303
304 AC_CHECK_MEMBERS([struct sockaddr.sa_len], [], [],
305 [
306         #include <sys/types.h>
307         #include <sys/socket.h>
308 ])
309
310 AC_CHECK_MEMBERS([struct sadb_x_policy.sadb_x_policy_priority], [], [],
311 [
312         #include <sys/types.h>
313         #ifdef HAVE_NET_PFKEYV2_H
314         #include <net/pfkeyv2.h>
315         #else
316         #include <stdint.h>
317         #include <linux/pfkeyv2.h>
318         #endif
319 ])
320
321 AC_MSG_CHECKING([for IPSEC_MODE_BEET])
322 AC_TRY_COMPILE(
323         [#include <sys/types.h>
324         #ifdef HAVE_NETIPSEC_IPSEC_H
325         #include <netipsec/ipsec.h>
326         #elif defined(HAVE_NETINET6_IPSEC_H)
327         #include <netinet6/ipsec.h>
328         #else
329         #include <stdint.h>
330         #include <linux/ipsec.h>
331         #endif],
332         [int mode = IPSEC_MODE_BEET;
333          return mode;],
334         [AC_MSG_RESULT([yes]); AC_DEFINE([HAVE_IPSEC_MODE_BEET])],
335         [AC_MSG_RESULT([no])]
336 )
337
338 AC_MSG_CHECKING([for IPSEC_DIR_FWD])
339 AC_TRY_COMPILE(
340         [#include <sys/types.h>
341         #ifdef HAVE_NETIPSEC_IPSEC_H
342         #include <netipsec/ipsec.h>
343         #elif defined(HAVE_NETINET6_IPSEC_H)
344         #include <netinet6/ipsec.h>
345         #else
346         #include <stdint.h>
347         #include <linux/ipsec.h>
348         #endif],
349         [int dir = IPSEC_DIR_FWD;
350          return dir;],
351         [AC_MSG_RESULT([yes]); AC_DEFINE([HAVE_IPSEC_DIR_FWD])],
352         [AC_MSG_RESULT([no])]
353 )
354
355 AC_MSG_CHECKING([for gcc atomic operations])
356 AC_TRY_RUN(
357 [
358         int main() {
359                 volatile int ref = 1;
360                 __sync_fetch_and_add (&ref, 1);
361                 __sync_sub_and_fetch (&ref, 1);
362                 /* Make sure test fails if operations are not supported */
363                 __sync_val_compare_and_swap(&ref, 1, 0);
364                 return ref;
365         }
366 ],
367 [AC_MSG_RESULT([yes]); AC_DEFINE(HAVE_GCC_ATOMIC_OPERATIONS)],
368 [AC_MSG_RESULT([no])],
369 [AC_MSG_RESULT([no])])
370
371 AC_CHECK_FUNC(
372         [register_printf_function],
373         [AC_DEFINE(HAVE_PRINTF_HOOKS)],
374         [
375                 AC_MSG_NOTICE([printf does not support custom format specifiers!])
376                 vstr=true
377         ]
378 )
379
380 if test x$vstr = xtrue; then
381         AC_HAVE_LIBRARY([vstr],[LIBS="$LIBS"],[AC_MSG_ERROR([Vstr string library not found])])
382         AC_DEFINE(USE_VSTR)
383 fi
384
385 if test x$gmp = xtrue; then
386         AC_HAVE_LIBRARY([gmp],[LIBS="$LIBS"],[AC_MSG_ERROR([GNU Multi Precision library gmp not found])])
387         AC_MSG_CHECKING([gmp.h version >= 4.1.4])
388         AC_TRY_COMPILE(
389                 [#include "gmp.h"],
390                 [
391                         #if (__GNU_MP_VERSION*100 +  __GNU_MP_VERSION_MINOR*10 + __GNU_MP_VERSION_PATCHLEVEL) < 414
392                                 #error bad gmp
393                         #endif
394                 ],
395                 [AC_MSG_RESULT([yes])], [AC_MSG_RESULT([no]); AC_MSG_ERROR([No usable gmp.h found!])]
396         )
397 fi
398
399 if test x$ldap = xtrue; then
400         AC_HAVE_LIBRARY([ldap],[LIBS="$LIBS"],[AC_MSG_ERROR([LDAP library ldap not found])])
401         AC_HAVE_LIBRARY([lber],[LIBS="$LIBS"],[AC_MSG_ERROR([LDAP library lber not found])])
402         AC_CHECK_HEADER([ldap.h],,[AC_MSG_ERROR([LDAP header ldap.h not found!])])
403 fi
404
405 if test x$curl = xtrue; then
406         AC_HAVE_LIBRARY([curl],[LIBS="$LIBS"],[AC_MSG_ERROR([CURL library curl not found])])
407         AC_CHECK_HEADER([curl/curl.h],,[AC_MSG_ERROR([CURL header curl/curl.h not found!])])
408 fi
409
410 if test x$xml = xtrue; then
411         PKG_CHECK_MODULES(xml, [libxml-2.0])
412         AC_SUBST(xml_CFLAGS)
413         AC_SUBST(xml_LIBS)
414 fi
415
416 if test x$dumm = xtrue; then
417         PKG_CHECK_MODULES(gtk, [gtk+-2.0 vte])
418         AC_SUBST(gtk_CFLAGS)
419         AC_SUBST(gtk_LIBS)
420         AC_CHECK_PROGS(RUBY, ruby)
421         AC_MSG_CHECKING([for Ruby header files])
422         if test -n "$RUBY"; then
423                 RUBYDIR=`($RUBY -rmkmf -e 'print Config::CONFIG[["archdir"]] || $archdir') 2>/dev/null`
424                 if test -n "$RUBYDIR"; then
425                         dirs="$RUBYDIR"
426                         RUBYINCLUDE=none
427                         for i in $dirs; do
428                                 if test -r $i/ruby.h; then
429                                         AC_MSG_RESULT([$i])
430                                         RUBYINCLUDE="-I$i"
431                                         break;
432                                 fi
433                         done
434                         if test x"$RUBYINCLUDE" = xnone; then
435                                 AC_MSG_ERROR([ruby.h not found])
436                         fi
437                         AC_SUBST(RUBYINCLUDE)
438                 else
439                         AC_MSG_ERROR([unable to determine ruby configuration])
440                 fi
441         else
442                 AC_MSG_ERROR([don't know how to run ruby])
443         fi
444 fi
445
446 if test x$fast = xtrue; then
447         AC_HAVE_LIBRARY([neo_cgi],[LIBS="$LIBS"],[AC_MSG_ERROR([ClearSilver library neo_cgi not found!])])
448         AC_HAVE_LIBRARY([neo_utl],[LIBS="$LIBS"],[AC_MSG_ERROR([ClearSilver library neo_utl not found!])])
449         AC_HAVE_LIBRARY([z],[LIBS="$LIBS"],[AC_MSG_ERROR([ClearSilver dependency zlib not found!])])
450 dnl autoconf does not like CamelCase!? How to fix this?
451 dnl     AC_CHECK_HEADER([ClearSilver/ClearSilver.h],,[AC_MSG_ERROR([ClearSilver header file ClearSilver/ClearSilver.h not found!])])
452
453         AC_HAVE_LIBRARY([fcgi],[LIBS="$LIBS"],[AC_MSG_ERROR([FastCGI library fcgi not found!])])
454         AC_CHECK_HEADER([fcgiapp.h],,[AC_MSG_ERROR([FastCGI header file fcgiapp.h not found!])])
455 fi
456
457 if test x$mysql = xtrue; then
458         AC_PATH_PROG([MYSQLCONFIG], [mysql_config], [], [$PATH:/bin:/usr/bin:/usr/local/bin])
459         if test x$MYSQLCONFIG = x; then
460                 AC_MSG_ERROR([mysql_config not found!])
461         fi
462         AC_SUBST(MYSQLLIB, `$MYSQLCONFIG --libs_r`)
463         AC_SUBST(MYSQLCFLAG, `$MYSQLCONFIG --cflags`)
464 fi
465
466 if test x$sqlite = xtrue; then
467         AC_HAVE_LIBRARY([sqlite3],[LIBS="$LIBS"],[AC_MSG_ERROR([SQLite library sqlite3 not found])])
468         AC_CHECK_HEADER([sqlite3.h],,[AC_MSG_ERROR([SQLite header sqlite3.h not found!])])
469         AC_MSG_CHECKING([sqlite3_prepare_v2])
470         AC_TRY_COMPILE(
471                 [#include <sqlite3.h>],
472                 [
473                         void *test = sqlite3_prepare_v2;
474                 ],
475                 [AC_MSG_RESULT([yes])]; AC_DEFINE_UNQUOTED(HAVE_SQLITE3_PREPARE_V2, 1), [AC_MSG_RESULT([no])])
476         AC_MSG_CHECKING([sqlite3.h version >= 3.3.1])
477         AC_TRY_COMPILE(
478                 [#include <sqlite3.h>],
479                 [
480                         #if SQLITE_VERSION_NUMBER < 3003001
481                                 #error bad sqlite
482                         #endif
483                 ],
484                 [AC_MSG_RESULT([yes])], [AC_MSG_RESULT([no]); AC_MSG_ERROR([SQLite version >= 3.3.1 required!])])
485 fi
486
487 if test x$openssl = xtrue; then
488         AC_HAVE_LIBRARY([crypto],[LIBS="$LIBS"],[AC_MSG_ERROR([OpenSSL crypto library not found])])
489         AC_CHECK_HEADER([openssl/evp.h],,[AC_MSG_ERROR([OpenSSL header openssl/evp.h not found!])])
490 fi
491
492 if test x$gcrypt = xtrue; then
493         AC_HAVE_LIBRARY([gcrypt],[LIBS="$LIBS"],[AC_MSG_ERROR([gcrypt library not found])])
494         AC_CHECK_HEADER([gcrypt.h],,[AC_MSG_ERROR([gcrypt header gcrypt.h not found!])])
495         AC_MSG_CHECKING([gcrypt CAMELLIA cipher])
496         AC_TRY_COMPILE(
497                 [#include <gcrypt.h>],
498                 [enum gcry_cipher_algos alg = GCRY_CIPHER_CAMELLIA128;],
499                 [AC_MSG_RESULT([yes]); AC_DEFINE([HAVE_GCRY_CIPHER_CAMELLIA])],
500                 [AC_MSG_RESULT([no])]
501         )
502 fi
503
504 if test x$uci = xtrue; then
505         AC_HAVE_LIBRARY([uci],[LIBS="$LIBS"],[AC_MSG_ERROR([UCI library libuci not found])])
506         AC_CHECK_HEADER([uci.h],,[AC_MSG_ERROR([UCI header uci.h not found!])])
507 fi
508
509 if test x$nm = xtrue; then
510         PKG_CHECK_MODULES(nm, [NetworkManager libnm_glib_vpn gthread-2.0])
511         AC_SUBST(nm_CFLAGS)
512         AC_SUBST(nm_LIBS)
513 fi
514
515 if test x$eap_gtc = xtrue; then
516         AC_HAVE_LIBRARY([pam],[LIBS="$LIBS"],[AC_MSG_ERROR([PAM library not found])])
517         AC_CHECK_HEADER([security/pam_appl.h],,[AC_MSG_ERROR([PAM header security/pam_appl.h not found!])])
518 fi
519
520 if test x$capabilities = xlibcap; then
521         AC_HAVE_LIBRARY([cap],[LIBS="$LIBS"],[AC_MSG_ERROR([libcap library not found])])
522         AC_CHECK_HEADER([sys/capability.h],,[AC_MSG_ERROR([libcap header sys/capability.h not found!])])
523 fi
524
525 if test x$integrity_test = xtrue; then
526         AC_MSG_CHECKING([for dladdr()])
527         AC_TRY_COMPILE(
528                 [#define _GNU_SOURCE
529                  #include <dlfcn.h>],
530                 [Dl_info info; dladdr(main, &info);],
531                 [AC_MSG_RESULT([yes])], [AC_MSG_RESULT([no]);
532                  AC_MSG_ERROR([dladdr() not supported, required by integrity-test!])]
533         )
534         AC_MSG_CHECKING([for dl_iterate_phdr()])
535         AC_TRY_COMPILE(
536                 [#define _GNU_SOURCE
537                  #include <link.h>],
538                 [dl_iterate_phdr((void*)0, (void*)0);],
539                 [AC_MSG_RESULT([yes])], [AC_MSG_RESULT([no]);
540                  AC_MSG_ERROR([dl_iterate_phdr() not supported, required by integrity-test!])]
541         )
542 fi
543
544 dnl ======================================
545 dnl  collect all plugins for libstrongswan
546 dnl ======================================
547
548 libstrongswan_plugins=
549 pluto_plugins=
550
551 if test x$test_vectors = xtrue; then
552         libstrongswan_plugins=${libstrongswan_plugins}" test-vectors"
553         pluto_plugins=${pluto_plugins}" test-vectors"
554 fi
555 if test x$curl = xtrue; then
556         libstrongswan_plugins=${libstrongswan_plugins}" curl"
557         pluto_plugins=${pluto_plugins}" curl"
558 fi
559 if test x$ldap = xtrue; then
560         libstrongswan_plugins=${libstrongswan_plugins}" ldap"
561         pluto_plugins=${pluto_plugins}" ldap"
562 fi
563 if test x$aes = xtrue; then
564         libstrongswan_plugins=${libstrongswan_plugins}" aes"
565         pluto_plugins=${pluto_plugins}" aes"
566 fi
567 if test x$des = xtrue; then
568         libstrongswan_plugins=${libstrongswan_plugins}" des"
569         pluto_plugins=${pluto_plugins}" des"
570 fi
571 if test x$blowfish = xtrue; then
572         libstrongswan_plugins=${libstrongswan_plugins}" blowfish"
573         pluto_plugins=${pluto_plugins}" blowfish"
574 fi
575 if test x$sha1 = xtrue; then
576         libstrongswan_plugins=${libstrongswan_plugins}" sha1"
577         pluto_plugins=${pluto_plugins}" sha1"
578 fi
579 if test x$sha2 = xtrue; then
580         libstrongswan_plugins=${libstrongswan_plugins}" sha2"
581         pluto_plugins=${pluto_plugins}" sha2"
582 fi
583 if test x$md4 = xtrue; then
584         libstrongswan_plugins=${libstrongswan_plugins}" md4"
585 fi
586 if test x$md5 = xtrue; then
587         libstrongswan_plugins=${libstrongswan_plugins}" md5"
588         pluto_plugins=${pluto_plugins}" md5"
589 fi
590 if test x$fips_prf = xtrue; then
591         libstrongswan_plugins=${libstrongswan_plugins}" fips-prf"
592 fi
593 if test x$random = xtrue; then
594         libstrongswan_plugins=${libstrongswan_plugins}" random"
595         pluto_plugins=${pluto_plugins}" random"
596 fi
597 if test x$x509 = xtrue; then
598         libstrongswan_plugins=${libstrongswan_plugins}" x509"
599         pluto_plugins=${pluto_plugins}" x509"
600 fi
601 if test x$pubkey = xtrue; then
602         libstrongswan_plugins=${libstrongswan_plugins}" pubkey"
603         pluto_plugins=${pluto_plugins}" pubkey"
604 fi
605 if test x$pkcs1 = xtrue; then
606         libstrongswan_plugins=${libstrongswan_plugins}" pkcs1"
607         pluto_plugins=${pluto_plugins}" pkcs1"
608 fi
609 if test x$pgp = xtrue; then
610         libstrongswan_plugins=${libstrongswan_plugins}" pgp"
611         pluto_plugins=${pluto_plugins}" pgp"
612 fi
613 if test x$dnskey = xtrue; then
614         libstrongswan_plugins=${libstrongswan_plugins}" dnskey"
615         pluto_plugins=${pluto_plugins}" dnskey"
616 fi
617 if test x$pem = xtrue; then
618         libstrongswan_plugins=${libstrongswan_plugins}" pem"
619         pluto_plugins=${pluto_plugins}" pem"
620 fi
621 if test x$mysql = xtrue; then
622         libstrongswan_plugins=${libstrongswan_plugins}" mysql"
623         pluto_plugins=${pluto_plugins}" mysql"
624 fi
625 if test x$sqlite = xtrue; then
626         libstrongswan_plugins=${libstrongswan_plugins}" sqlite"
627         pluto_plugins=${pluto_plugins}" sqlite"
628 fi
629 if test x$attr_sql = xtrue -o x$sql = xtrue; then
630         libstrongswan_plugins=${libstrongswan_plugins}" attr-sql"
631         pluto_plugins=${pluto_plugins}" attr-sql"
632 fi
633 if test x$padlock = xtrue; then
634         libstrongswan_plugins=${libstrongswan_plugins}" padlock"
635 fi
636 if test x$openssl = xtrue; then
637         libstrongswan_plugins=${libstrongswan_plugins}" openssl"
638         pluto_plugins=${pluto_plugins}" openssl"
639 fi
640 if test x$gcrypt = xtrue; then
641         libstrongswan_plugins=${libstrongswan_plugins}" gcrypt"
642         pluto_plugins=${pluto_plugins}" gcrypt"
643 fi
644 if test x$xcbc = xtrue; then
645         libstrongswan_plugins=${libstrongswan_plugins}" xcbc"
646 fi
647 if test x$hmac = xtrue; then
648         libstrongswan_plugins=${libstrongswan_plugins}" hmac"
649         pluto_plugins=${pluto_plugins}" hmac"
650 fi
651 if test x$agent = xtrue; then
652         libstrongswan_plugins=${libstrongswan_plugins}" agent"
653 fi
654 if test x$gmp = xtrue; then
655         libstrongswan_plugins=${libstrongswan_plugins}" gmp"
656         pluto_plugins=${pluto_plugins}" gmp"
657 fi
658
659 AC_SUBST(libstrongswan_plugins)
660 AC_SUBST(pluto_plugins)
661
662 dnl =========================
663 dnl  set Makefile.am vars
664 dnl =========================
665
666 dnl libstrongswan plugins
667 dnl =====================
668 AM_CONDITIONAL(USE_TEST_VECTORS, test x$test_vectors = xtrue)
669 AM_CONDITIONAL(USE_CURL, test x$curl = xtrue)
670 AM_CONDITIONAL(USE_LDAP, test x$ldap = xtrue)
671 AM_CONDITIONAL(USE_AES, test x$aes = xtrue)
672 AM_CONDITIONAL(USE_DES, test x$des = xtrue)
673 AM_CONDITIONAL(USE_BLOWFISH, test x$blowfish = xtrue)
674 AM_CONDITIONAL(USE_MD4, test x$md4 = xtrue)
675 AM_CONDITIONAL(USE_MD5, test x$md5 = xtrue)
676 AM_CONDITIONAL(USE_SHA1, test x$sha1 = xtrue)
677 AM_CONDITIONAL(USE_SHA2, test x$sha2 = xtrue)
678 AM_CONDITIONAL(USE_FIPS_PRF, test x$fips_prf = xtrue)
679 AM_CONDITIONAL(USE_GMP, test x$gmp = xtrue)
680 AM_CONDITIONAL(USE_RANDOM, test x$random = xtrue)
681 AM_CONDITIONAL(USE_X509, test x$x509 = xtrue)
682 AM_CONDITIONAL(USE_PUBKEY, test x$pubkey = xtrue)
683 AM_CONDITIONAL(USE_PKCS1, test x$pkcs1 = xtrue)
684 AM_CONDITIONAL(USE_PGP, test x$pgp = xtrue)
685 AM_CONDITIONAL(USE_DNSKEY, test x$dnskey = xtrue)
686 AM_CONDITIONAL(USE_PEM, test x$pem = xtrue)
687 AM_CONDITIONAL(USE_HMAC, test x$hmac = xtrue)
688 AM_CONDITIONAL(USE_XCBC, test x$xcbc = xtrue)
689 AM_CONDITIONAL(USE_MYSQL, test x$mysql = xtrue)
690 AM_CONDITIONAL(USE_SQLITE, test x$sqlite = xtrue)
691 AM_CONDITIONAL(USE_ATTR_SQL, test x$attr_sql = xtrue -o x$sql = xtrue)
692 AM_CONDITIONAL(USE_PADLOCK, test x$padlock = xtrue)
693 AM_CONDITIONAL(USE_OPENSSL, test x$openssl = xtrue)
694 AM_CONDITIONAL(USE_GCRYPT, test x$gcrypt = xtrue)
695 AM_CONDITIONAL(USE_AGENT, test x$agent = xtrue)
696
697 dnl charon plugins
698 dnl ==============
699 AM_CONDITIONAL(USE_STROKE, test x$stroke = xtrue)
700 AM_CONDITIONAL(USE_MEDSRV, test x$medsrv = xtrue)
701 AM_CONDITIONAL(USE_MEDCLI, test x$medcli = xtrue)
702 AM_CONDITIONAL(USE_NM, test x$nm = xtrue)
703 AM_CONDITIONAL(USE_UCI, test x$uci = xtrue)
704 AM_CONDITIONAL(USE_SMP, test x$smp = xtrue)
705 AM_CONDITIONAL(USE_SQL, test x$sql = xtrue)
706 AM_CONDITIONAL(USE_UPDOWN, test x$updown = xtrue)
707 AM_CONDITIONAL(USE_ATTR, test x$attr = xtrue)
708 AM_CONDITIONAL(USE_RESOLVE, test x$resolve = xtrue)
709 AM_CONDITIONAL(USE_UNIT_TESTS, test x$unit_tests = xtrue)
710 AM_CONDITIONAL(USE_LOAD_TESTER, test x$load_tester = xtrue)
711 AM_CONDITIONAL(USE_EAP_SIM, test x$eap_sim = xtrue)
712 AM_CONDITIONAL(USE_EAP_SIM_FILE, test x$eap_sim_file = xtrue)
713 AM_CONDITIONAL(USE_EAP_IDENTITY, test x$eap_identity = xtrue)
714 AM_CONDITIONAL(USE_EAP_MD5, test x$eap_md5 = xtrue)
715 AM_CONDITIONAL(USE_EAP_GTC, test x$eap_gtc = xtrue)
716 AM_CONDITIONAL(USE_EAP_AKA, test x$eap_aka = xtrue)
717 AM_CONDITIONAL(USE_EAP_AKA_3GPP2, test x$eap_aka_3gpp2 = xtrue)
718 AM_CONDITIONAL(USE_EAP_MSCHAPV2, test x$eap_mschapv2 = xtrue)
719 AM_CONDITIONAL(USE_EAP_RADIUS, test x$eap_radius = xtrue)
720 AM_CONDITIONAL(USE_KERNEL_NETLINK, test x$kernel_netlink = xtrue)
721 AM_CONDITIONAL(USE_KERNEL_PFKEY, test x$kernel_pfkey = xtrue)
722 AM_CONDITIONAL(USE_KERNEL_PFROUTE, test x$kernel_pfroute = xtrue)
723 AM_CONDITIONAL(USE_KERNEL_KLIPS, test x$kernel_klips = xtrue)
724
725 dnl other options
726 dnl =============
727 AM_CONDITIONAL(USE_SMARTCARD, test x$smartcard = xtrue)
728 AM_CONDITIONAL(USE_CISCO_QUIRKS, test x$cisco_quirks = xtrue)
729 AM_CONDITIONAL(USE_LEAK_DETECTIVE, test x$leak_detective = xtrue)
730 AM_CONDITIONAL(USE_LOCK_PROFILER, test x$lock_profiler = xtrue)
731 AM_CONDITIONAL(USE_NAT_TRANSPORT, test x$nat_transport = xtrue)
732 AM_CONDITIONAL(USE_VENDORID, test x$vendor_id = xtrue)
733 AM_CONDITIONAL(USE_XAUTH_VID, test x$xauth_vid = xtrue)
734 AM_CONDITIONAL(USE_DUMM, test x$dumm = xtrue)
735 AM_CONDITIONAL(USE_FAST, test x$fast = xtrue)
736 AM_CONDITIONAL(USE_MANAGER, test x$manager = xtrue)
737 AM_CONDITIONAL(USE_ME, test x$mediation = xtrue)
738 AM_CONDITIONAL(USE_INTEGRITY_TEST, test x$integrity_test = xtrue)
739 AM_CONDITIONAL(USE_CAPABILITIES, test x$capabilities = xlibcap)
740 AM_CONDITIONAL(USE_PLUTO, test x$pluto = xtrue)
741 AM_CONDITIONAL(USE_THREADS, test x$threads = xtrue)
742 AM_CONDITIONAL(USE_CHARON, test x$charon = xtrue)
743 AM_CONDITIONAL(USE_TOOLS, test x$tools = xtrue)
744 AM_CONDITIONAL(USE_SCRIPTS, test x$scripts = xtrue)
745 AM_CONDITIONAL(USE_LIBSTRONGSWAN, test x$charon = xtrue -o x$pluto = xtrue -o x$tools = xtrue)
746 AM_CONDITIONAL(USE_FILE_CONFIG, test x$pluto = xtrue -o x$stroke = xtrue)
747 AM_CONDITIONAL(USE_VSTR, test x$vstr = xtrue)
748
749 dnl ==============================
750 dnl  set global definitions
751 dnl ==============================
752
753 if test x$mediation = xtrue; then
754         AC_DEFINE(ME)
755 fi
756 if test x$capabilities = xlibcap; then
757         AC_DEFINE(CAPABILITIES)
758 fi
759
760 dnl ==============================
761 dnl  build Makefiles
762 dnl ==============================
763
764 AC_OUTPUT(
765         Makefile
766         src/Makefile
767         src/include/Makefile
768         src/libstrongswan/Makefile
769         src/libstrongswan/plugins/aes/Makefile
770         src/libstrongswan/plugins/des/Makefile
771         src/libstrongswan/plugins/blowfish/Makefile
772         src/libstrongswan/plugins/md4/Makefile
773         src/libstrongswan/plugins/md5/Makefile
774         src/libstrongswan/plugins/sha1/Makefile
775         src/libstrongswan/plugins/sha2/Makefile
776         src/libstrongswan/plugins/fips_prf/Makefile
777         src/libstrongswan/plugins/gmp/Makefile
778         src/libstrongswan/plugins/random/Makefile
779         src/libstrongswan/plugins/hmac/Makefile
780         src/libstrongswan/plugins/xcbc/Makefile
781         src/libstrongswan/plugins/x509/Makefile
782         src/libstrongswan/plugins/pubkey/Makefile
783         src/libstrongswan/plugins/pkcs1/Makefile
784         src/libstrongswan/plugins/pgp/Makefile
785         src/libstrongswan/plugins/dnskey/Makefile
786         src/libstrongswan/plugins/pem/Makefile
787         src/libstrongswan/plugins/curl/Makefile
788         src/libstrongswan/plugins/ldap/Makefile
789         src/libstrongswan/plugins/mysql/Makefile
790         src/libstrongswan/plugins/sqlite/Makefile
791         src/libstrongswan/plugins/attr_sql/Makefile
792         src/libstrongswan/plugins/padlock/Makefile
793         src/libstrongswan/plugins/openssl/Makefile
794         src/libstrongswan/plugins/gcrypt/Makefile
795         src/libstrongswan/plugins/agent/Makefile
796         src/libstrongswan/plugins/test_vectors/Makefile
797         src/libfreeswan/Makefile
798         src/pluto/Makefile
799         src/whack/Makefile
800         src/charon/Makefile
801         src/charon/plugins/eap_aka/Makefile
802         src/charon/plugins/eap_aka_3gpp2/Makefile
803         src/charon/plugins/eap_identity/Makefile
804         src/charon/plugins/eap_md5/Makefile
805         src/charon/plugins/eap_gtc/Makefile
806         src/charon/plugins/eap_sim/Makefile
807         src/charon/plugins/eap_sim_file/Makefile
808         src/charon/plugins/eap_mschapv2/Makefile
809         src/charon/plugins/eap_radius/Makefile
810         src/charon/plugins/kernel_netlink/Makefile
811         src/charon/plugins/kernel_pfkey/Makefile
812         src/charon/plugins/kernel_pfroute/Makefile
813         src/charon/plugins/kernel_klips/Makefile
814         src/charon/plugins/smp/Makefile
815         src/charon/plugins/sql/Makefile
816         src/charon/plugins/medsrv/Makefile
817         src/charon/plugins/medcli/Makefile
818         src/charon/plugins/nm/Makefile
819         src/charon/plugins/uci/Makefile
820         src/charon/plugins/stroke/Makefile
821         src/charon/plugins/updown/Makefile
822         src/charon/plugins/attr/Makefile
823         src/charon/plugins/resolve/Makefile
824         src/charon/plugins/unit_tester/Makefile
825         src/charon/plugins/load_tester/Makefile
826         src/stroke/Makefile
827         src/ipsec/Makefile
828         src/starter/Makefile
829         src/_updown/Makefile
830         src/_updown_espmark/Makefile
831         src/_copyright/Makefile
832         src/openac/Makefile
833         src/scepclient/Makefile
834         src/pki/Makefile
835         src/dumm/Makefile
836         src/dumm/ext/extconf.rb
837         src/libfast/Makefile
838         src/manager/Makefile
839         src/medsrv/Makefile
840         src/checksum/Makefile
841         scripts/Makefile
842         testing/Makefile
843 )