Added a crypto transform stress test for profiling
[strongswan.git] / configure.in
1 dnl  configure.in for linux strongSwan
2 dnl  Copyright (C) 2006 Martin Willi
3 dnl  Hochschule fuer Technik Rapperswil
4 dnl
5 dnl  This program is free software; you can redistribute it and/or modify it
6 dnl  under the terms of the GNU General Public License as published by the
7 dnl  Free Software Foundation; either version 2 of the License, or (at your
8 dnl  option) any later version.  See <http://www.fsf.org/copyleft/gpl.txt>.
9 dnl
10 dnl  This program is distributed in the hope that it will be useful, but
11 dnl  WITHOUT ANY WARRANTY; without even the implied warranty of MERCHANTABILITY
12 dnl  or FITNESS FOR A PARTICULAR PURPOSE.  See the GNU General Public License
13 dnl  for more details.
14
15 dnl ===========================
16 dnl  initialize & set some vars
17 dnl ===========================
18
19 AC_INIT(strongSwan,4.4.2dr1)
20 AM_INIT_AUTOMAKE(tar-ustar)
21 AC_CONFIG_MACRO_DIR([m4/config])
22 PKG_PROG_PKG_CONFIG
23
24 dnl =================================
25 dnl  check --enable-xxx & --with-xxx
26 dnl =================================
27
28 m4_include(m4/macros/with.m4)
29
30 ARG_WITH_SUBST([default-pkcs11],     [/usr/lib/opensc-pkcs11.so], [set the default PKCS11 library])
31 ARG_WITH_SUBST([random-device],      [/dev/random], [set the device to read real random data from])
32 ARG_WITH_SUBST([urandom-device],     [/dev/urandom], [set the device to read pseudo random data from])
33 ARG_WITH_SUBST([strongswan-conf],    [${sysconfdir}/strongswan.conf], [set the strongswan.conf file location])
34 ARG_WITH_SUBST([resolv-conf],        [${sysconfdir}/resolv.conf], [set the file to use in DNS handler plugin])
35 ARG_WITH_SUBST([piddir],             [/var/run], [set path for PID and UNIX socket files])
36 ARG_WITH_SUBST([ipsecdir],           [${libexecdir%/}/ipsec], [set installation path for ipsec tools])
37 ARG_WITH_SUBST([plugindir],          [${ipsecdir%/}/plugins], [set the installation path of plugins])
38 ARG_WITH_SUBST([nm-ca-dir],          [/usr/share/ca-certificates], [directory the NM plugin uses to look up trusted root certificates])
39 ARG_WITH_SUBST([linux-headers],      [\${top_srcdir}/src/include], [set directory of linux header files to use])
40 ARG_WITH_SUBST([routing-table],      [220], [set routing table to use for IPsec routes])
41 ARG_WITH_SUBST([routing-table-prio], [220], [set priority for IPsec routing table])
42
43 ARG_WITH_SET([capabilities],         [no], [set capability dropping library. Currently supported values are "libcap" and "native"])
44 ARG_WITH_SET([mpz_powm_sec],         [yes], [use the more side-channel resistant mpz_powm_sec in libgmp, if available])
45
46 AC_ARG_WITH(
47         [xauth-module],
48         AS_HELP_STRING([--with-xauth-module=lib],[set the path to the XAUTH module]),
49         [AC_DEFINE_UNQUOTED(XAUTH_DEFAULT_LIB, "$withval")],
50 )
51
52 AC_ARG_WITH(
53         [user],
54         AS_HELP_STRING([--with-user=user],[change user of the daemons to "user" after startup (default is "root").]),
55         [AC_DEFINE_UNQUOTED(IPSEC_USER, "$withval") AC_SUBST(ipsecuser, "$withval")],
56         [AC_SUBST(ipsecuser, "root")]
57 )
58
59 AC_ARG_WITH(
60         [group],
61         AS_HELP_STRING([--with-group=group],[change group of the daemons to "group" after startup (default is "root").]),
62         [AC_DEFINE_UNQUOTED(IPSEC_GROUP, "$withval") AC_SUBST(ipsecgroup, "$withval")],
63         [AC_SUBST(ipsecgroup, "root")]
64 )
65
66 m4_include(m4/macros/enable-disable.m4)
67
68 ARG_ENABL_SET([curl],           [enable CURL fetcher plugin to fetch files via libcurl. Requires libcurl.])
69 ARG_ENABL_SET([ldap],           [enable LDAP fetching plugin to fetch files via libldap. Requires openLDAP.])
70 ARG_DISBL_SET([aes],            [disable AES software implementation plugin.])
71 ARG_DISBL_SET([des],            [disable DES/3DES software implementation plugin.])
72 ARG_ENABL_SET([blowfish],       [enable Blowfish software implementation plugin.])
73 ARG_ENABL_SET([md4],            [enable MD4 software implementation plugin.])
74 ARG_DISBL_SET([md5],            [disable MD5 software implementation plugin.])
75 ARG_DISBL_SET([sha1],           [disable SHA1 software implementation plugin.])
76 ARG_DISBL_SET([sha2],           [disable SHA256/SHA384/SHA512 software implementation plugin.])
77 ARG_DISBL_SET([fips-prf],       [disable FIPS PRF software implementation plugin.])
78 ARG_DISBL_SET([gmp],            [disable GNU MP (libgmp) based crypto implementation plugin.])
79 ARG_DISBL_SET([random],         [disable RNG implementation on top of /dev/(u)random.])
80 ARG_DISBL_SET([x509],           [disable X509 certificate implementation plugin.])
81 ARG_DISBL_SET([revocation],     [disable X509 CRL/OCSP revocation check plugin.])
82 ARG_DISBL_SET([pubkey],         [disable RAW public key support plugin.])
83 ARG_DISBL_SET([pkcs1],          [disable PKCS1 key decoding plugin.])
84 ARG_DISBL_SET([pgp],            [disable PGP key decoding plugin.])
85 ARG_DISBL_SET([dnskey],         [disable DNS RR key decoding plugin.])
86 ARG_DISBL_SET([pem],            [disable PEM decoding plugin.])
87 ARG_DISBL_SET([hmac],           [disable HMAC crypto implementation plugin.])
88 ARG_DISBL_SET([xcbc],           [disable xcbc crypto implementation plugin.])
89 ARG_ENABL_SET([test-vectors],   [enable plugin providing crypto test vectors.])
90 ARG_ENABL_SET([mysql],          [enable MySQL database support. Requires libmysqlclient_r.])
91 ARG_ENABL_SET([sqlite],         [enable SQLite database support. Requires libsqlite3.])
92 ARG_DISBL_SET([stroke],         [disable charons stroke (pluto compatibility) configuration backend.])
93 ARG_ENABL_SET([medsrv],         [enable mediation server web frontend and daemon plugin.])
94 ARG_ENABL_SET([medcli],         [enable mediation client configuration database plugin.])
95 ARG_ENABL_SET([smp],            [enable SMP configuration and control interface. Requires libxml.])
96 ARG_ENABL_SET([sql],            [enable SQL database configuration backend.])
97 ARG_ENABL_SET([smartcard],      [enable smartcard support.])
98 ARG_ENABL_SET([cisco-quirks],   [enable support of Cisco VPN client.])
99 ARG_ENABL_SET([leak-detective], [enable malloc hooks to find memory leaks.])
100 ARG_ENABL_SET([lock-profiler],  [enable lock/mutex profiling code.])
101 ARG_ENABL_SET([unit-tests],     [enable unit tests on IKEv2 daemon startup.])
102 ARG_ENABL_SET([load-tester],    [enable load testing plugin for IKEv2 daemon.])
103 ARG_ENABL_SET([eap-sim],        [enable SIM authenication module for EAP.])
104 ARG_ENABL_SET([eap-sim-file],   [enable EAP-SIM backend based on a triplet file.])
105 ARG_ENABL_SET([eap-simaka-sql], [enable EAP-SIM/AKA backend based on a triplet/quintuplet SQL database.])
106 ARG_ENABL_SET([eap-simaka-pseudonym], [enable EAP-SIM/AKA pseudonym storage plugin.])
107 ARG_ENABL_SET([eap-simaka-reauth],    [enable EAP-SIM/AKA reauthentication data storage plugin.])
108 ARG_ENABL_SET([eap-identity],   [enable EAP module providing EAP-Identity helper.])
109 ARG_ENABL_SET([eap-md5],        [enable EAP MD5 (CHAP) authenication module.])
110 ARG_ENABL_SET([eap-gtc],        [enable PAM based EAP GTC authenication module.])
111 ARG_ENABL_SET([eap-aka],        [enable EAP AKA authentication module.])
112 ARG_ENABL_SET([eap-aka-3gpp2],  [enable EAP AKA backend implementing 3GPP2 algorithms in software. Requires libgmp.])
113 ARG_ENABL_SET([eap-mschapv2],   [enable EAP MS-CHAPv2 authenication module.])
114 ARG_ENABL_SET([eap-tls],        [enable EAP TLS authenication module.])
115 ARG_ENABL_SET([eap-ttls],       [enable EAP TTLS authenication module.])
116 ARG_ENABL_SET([eap-radius],     [enable RADIUS proxy authenication module.])
117 ARG_DISBL_SET([kernel-netlink], [disable the netlink kernel interface.])
118 ARG_ENABL_SET([kernel-pfkey],   [enable the PF_KEY kernel interface.])
119 ARG_ENABL_SET([kernel-pfroute], [enable the PF_ROUTE kernel interface.])
120 ARG_ENABL_SET([kernel-klips],   [enable the KLIPS kernel interface.])
121 ARG_DISBL_SET([socket-default], [disable default socket implementation for charon.])
122 ARG_ENABL_SET([socket-raw],     [enable raw socket implementation of charon, enforced if pluto is enabled])
123 ARG_ENABL_SET([socket-dynamic], [enable dynamic socket implementation for charon])
124 ARG_ENABL_SET([farp],           [enable ARP faking plugin that responds to ARP requests to peers virtual IP])
125 ARG_ENABL_SET([nat-transport],  [enable NAT traversal with IPsec transport mode in pluto.])
126 ARG_DISBL_SET([vendor-id],      [disable the sending of the strongSwan vendor ID in pluto.])
127 ARG_DISBL_SET([xauth-vid],      [disable the sending of the XAUTH vendor ID.])
128 ARG_ENABL_SET([dumm],           [enable the DUMM UML test framework.])
129 ARG_ENABL_SET([fast],           [enable libfast (FastCGI Application Server w/ templates.])
130 ARG_ENABL_SET([manager],        [enable web management console (proof of concept).])
131 ARG_ENABL_SET([mediation],      [enable IKEv2 Mediation Extension.])
132 ARG_ENABL_SET([integrity-test], [enable integrity testing of libstrongswan and plugins.])
133 ARG_DISBL_SET([load-warning],   [disable the charon/pluto plugin load option warning in starter.])
134 ARG_DISBL_SET([pluto],          [disable the IKEv1 keying daemon pluto.])
135 ARG_DISBL_SET([xauth],          [disable xauth plugin.])
136 ARG_DISBL_SET([threads],        [disable the use of threads in pluto. Charon always uses threads.])
137 ARG_DISBL_SET([charon],         [disable the IKEv2 keying daemon charon.])
138 ARG_DISBL_SET([tools],          [disable additional utilities (openac, scepclient and pki).])
139 ARG_DISBL_SET([scripts],        [disable additional utilities (found in directory scripts).])
140 ARG_DISBL_SET([updown],         [disable updown firewall script plugin.])
141 ARG_DISBL_SET([attr],           [disable strongswan.conf based configuration attribute plugin.])
142 ARG_ENABL_SET([attr-sql],       [enable SQL based configuration attribute plugin.])
143 ARG_ENABL_SET([dhcp],           [enable DHCP based attribute provider plugin.])
144 ARG_DISBL_SET([resolve],        [disable resolve DNS handler plugin.])
145 ARG_ENABL_SET([padlock],        [enables VIA Padlock crypto plugin.])
146 ARG_ENABL_SET([openssl],        [enables the OpenSSL crypto plugin.])
147 ARG_ENABL_SET([gcrypt],         [enables the libgcrypt plugin.])
148 ARG_ENABL_SET([agent],          [enables the ssh-agent signing plugin.])
149 ARG_ENABL_SET([pkcs11],         [enables the PKCS11 token support plugin.])
150 ARG_ENABL_SET([ctr],            [enables the Counter Mode wrapper crypto plugin.])
151 ARG_ENABL_SET([ccm],            [enables the CCM AEAD wrapper crypto plugin.])
152 ARG_ENABL_SET([addrblock],      [enables RFC 3779 address block constraint support.])
153 ARG_ENABL_SET([uci],            [enable OpenWRT UCI configuration plugin.])
154 ARG_ENABL_SET([android],        [enable Android specific plugin.])
155 ARG_ENABL_SET([nm],             [enable NetworkManager plugin.])
156 ARG_ENABL_SET([ha],             [enable high availability cluster plugin.])
157 ARG_ENABL_SET([vstr],           [enforce using the Vstr string library to replace glibc-like printf hooks.])
158 ARG_ENABL_SET([monolithic],     [build monolithic version of libstrongswan that includes all enabled plugins. Similarly, the plugins of charon are assembled in libcharon.])
159
160 dnl =========================
161 dnl  set up compiler and flags
162 dnl =========================
163
164 if test -z "$CFLAGS"; then
165         CFLAGS="-g -O2 -Wall -Wno-format -Wno-pointer-sign -Wno-strict-aliasing"
166 fi
167 AC_PROG_CC
168 AC_LIB_PREFIX
169 AC_C_BIGENDIAN
170
171 dnl =========================
172 dnl  check required programs
173 dnl =========================
174
175 AC_PROG_INSTALL
176 AC_PROG_LIBTOOL
177 AC_PROG_EGREP
178 AC_PROG_AWK
179 AC_PROG_LEX
180 AC_PROG_YACC
181 AC_PATH_PROG([PERL], [perl], [], [$PATH:/bin:/usr/bin:/usr/local/bin])
182 AC_PATH_PROG([GPERF], [gperf], [], [$PATH:/bin:/usr/bin:/usr/local/bin])
183
184 dnl because gperf is not needed by end-users we just report it but do not abort on failure
185 AC_MSG_CHECKING([gperf version >= 3.0.0])
186 if test -x "$GPERF"; then
187         if test "`$GPERF --version | $AWK -F' ' '/^GNU gperf/ { print $3 }' | $AWK -F. '{ print $1 }'`" -ge "3"; then
188                 AC_MSG_RESULT([yes])
189         else
190                 AC_MSG_RESULT([no])
191         fi
192 else
193         AC_MSG_RESULT([not found])
194 fi
195
196 dnl translate user/group to numercial ids
197 AC_MSG_CHECKING([for uid of user "$ipsecuser"])
198 ipsecuid=`id -u $ipsecuser 2>/dev/null`
199 if test -n "$ipsecuid"; then
200         AC_MSG_RESULT([$ipsecuid])
201         AC_SUBST(ipsecuid)
202 else
203         AC_MSG_ERROR([not found])
204 fi
205 AC_MSG_CHECKING([for gid of group "$ipsecgroup"])
206 ipsecgid=`$EGREP "^$ipsecgroup:" /etc/group | $AWK -F: '{ print $3 }'`
207 if test -n "$ipsecgid"; then
208         AC_MSG_RESULT([$ipsecgid])
209         AC_SUBST(ipsecgid)
210 else
211         AC_MSG_ERROR([not found])
212 fi
213
214 dnl =========================
215 dnl  dependency calculation
216 dnl =========================
217
218 if test x$eap_aka_3gpp2 = xtrue; then
219         gmp=true;
220 fi
221
222 if test x$eap_aka = xtrue; then
223         fips_prf=true;
224         simaka=true;
225 fi
226
227 if test x$eap_sim = xtrue; then
228         fips_prf=true;
229         simaka=true;
230 fi
231
232 if test x$eap_tls = xtrue -o x$eap_ttls = xtrue; then
233         tls=true;
234 fi
235
236 if test x$fips_prf = xtrue; then
237         if test x$openssl = xfalse; then
238                 sha1=true;
239         fi
240 fi
241
242 if test x$smp = xtrue; then
243         xml=true
244 fi
245
246 if test x$manager = xtrue; then
247         fast=true
248 fi
249
250 if test x$medsrv = xtrue; then
251         mediation=true
252         fast=true
253 fi
254
255 if test x$medcli = xtrue; then
256         mediation=true
257 fi
258
259 if test x$pluto = xtrue; then
260         if test x$socket_raw = xfalse; then
261                 AC_MSG_NOTICE([Enforcing --enable-socket-raw, as pluto is enabled])
262                 socket_raw=true
263                 if test x$socket_default_given = xfalse; then
264                         socket_default=false
265                 fi
266         fi
267 fi
268
269 dnl ===========================================
270 dnl  check required libraries and header files
271 dnl ===========================================
272
273 AC_HEADER_STDBOOL
274 AC_FUNC_ALLOCA
275
276 dnl libraries needed on some platforms but not on others
277 dnl ====================================================
278 saved_LIBS=$LIBS
279
280 dnl FreeBSD and Mac OS X have dlopen integrated in libc, Linux needs libdl
281 LIBS=""
282 AC_SEARCH_LIBS(dlopen, dl, [DLLIB=$LIBS])
283 AC_SUBST(DLLIB)
284
285 dnl glibc's backtrace() can be replicated on FreeBSD with libexecinfo
286 LIBS=""
287 AC_SEARCH_LIBS(backtrace, execinfo, [BTLIB=$LIBS])
288 AC_CHECK_FUNCS(backtrace)
289 AC_SUBST(BTLIB)
290
291 dnl OpenSolaris needs libsocket and libnsl for socket()
292 LIBS=""
293 AC_SEARCH_LIBS(socket, socket, [SOCKLIB=$LIBS],
294         [AC_CHECK_LIB(nsl, socket, [SOCKLIB="-lsocket -lnsl"], [], [-lsocket])]
295 )
296 AC_SUBST(SOCKLIB)
297
298 dnl FreeBSD has clock_gettime in libc, Linux needs librt
299 LIBS=""
300 AC_SEARCH_LIBS(clock_gettime, rt, [RTLIB=$LIBS])
301 AC_CHECK_FUNCS(clock_gettime)
302 AC_SUBST(RTLIB)
303
304 dnl Android has pthread_* functions in bionic (libc), others need libpthread
305 LIBS=""
306 AC_SEARCH_LIBS(pthread_create, pthread, [PTHREADLIB=$LIBS])
307 AC_SUBST(PTHREADLIB)
308
309 LIBS=$saved_LIBS
310 dnl ======================
311
312 AC_MSG_CHECKING(for dladdr)
313 AC_TRY_COMPILE(
314         [#define _GNU_SOURCE
315          #include <dlfcn.h>],
316         [Dl_info* info = 0;
317          dladdr(0, info);],
318         [AC_MSG_RESULT([yes]); AC_DEFINE([HAVE_DLADDR])],
319         [AC_MSG_RESULT([no])]
320 )
321
322 dnl check if pthread_condattr_setclock(CLOCK_MONOTONE) is supported
323 saved_LIBS=$LIBS
324 LIBS=$PTHREADLIB
325 AC_MSG_CHECKING([for pthread_condattr_setclock(CLOCK_MONOTONE)])
326 AC_TRY_RUN(
327         [#include <pthread.h>
328          int main() { pthread_condattr_t attr;
329                 pthread_condattr_init(&attr);
330                 return pthread_condattr_setclock(&attr, CLOCK_MONOTONIC);}],
331         [AC_MSG_RESULT([yes]); AC_DEFINE([HAVE_CONDATTR_CLOCK_MONOTONIC])],
332         [AC_MSG_RESULT([no])],
333         dnl Check existence of pthread_condattr_setclock if cross-compiling
334         [AC_MSG_RESULT([unknown]);
335          AC_CHECK_FUNCS(pthread_condattr_setclock,
336                 [AC_DEFINE([HAVE_CONDATTR_CLOCK_MONOTONIC])]
337         )]
338 )
339 dnl check if we actually are able to configure attributes on cond vars
340 AC_CHECK_FUNCS(pthread_condattr_init)
341 dnl instead of pthread_condattr_setclock Android has this function
342 AC_CHECK_FUNCS(pthread_cond_timedwait_monotonic)
343 dnl check if we can cancel threads
344 AC_CHECK_FUNCS(pthread_cancel)
345 dnl check if native rwlocks are available
346 AC_CHECK_FUNCS(pthread_rwlock_init)
347 LIBS=$saved_LIBS
348
349 AC_CHECK_FUNCS(prctl)
350
351 AC_CHECK_FUNCS(mallinfo)
352
353 AC_CHECK_HEADERS(sys/sockio.h)
354 AC_CHECK_HEADERS(net/pfkeyv2.h netipsec/ipsec.h netinet6/ipsec.h linux/udp.h)
355
356 AC_CHECK_MEMBERS([struct sockaddr.sa_len], [], [],
357 [
358         #include <sys/types.h>
359         #include <sys/socket.h>
360 ])
361
362 AC_CHECK_MEMBERS([struct sadb_x_policy.sadb_x_policy_priority], [], [],
363 [
364         #include <sys/types.h>
365         #ifdef HAVE_NET_PFKEYV2_H
366         #include <net/pfkeyv2.h>
367         #else
368         #include <stdint.h>
369         #include <linux/pfkeyv2.h>
370         #endif
371 ])
372
373 AC_MSG_CHECKING([for in6addr_any])
374 AC_TRY_COMPILE(
375         [#include <sys/types.h>
376         #include <sys/socket.h>
377         #include <netinet/in.h>],
378         [struct in6_addr in6;
379         in6 = in6addr_any;],
380         [AC_MSG_RESULT([yes]); AC_DEFINE([HAVE_IN6ADDR_ANY])],
381         [AC_MSG_RESULT([no])]
382 )
383
384 AC_MSG_CHECKING([for in6_pktinfo])
385 AC_TRY_COMPILE(
386         [#define _GNU_SOURCE
387         #include <sys/types.h>
388         #include <sys/socket.h>
389         #include <netinet/in.h>],
390         [struct in6_pktinfo pi;
391         if (pi.ipi6_ifindex)
392         {
393                 return 0;
394         }],
395         [AC_MSG_RESULT([yes]); AC_DEFINE([HAVE_IN6_PKTINFO])],
396         [AC_MSG_RESULT([no])]
397 )
398
399 AC_MSG_CHECKING([for IPSEC_MODE_BEET])
400 AC_TRY_COMPILE(
401         [#include <sys/types.h>
402         #ifdef HAVE_NETIPSEC_IPSEC_H
403         #include <netipsec/ipsec.h>
404         #elif defined(HAVE_NETINET6_IPSEC_H)
405         #include <netinet6/ipsec.h>
406         #else
407         #include <stdint.h>
408         #include <linux/ipsec.h>
409         #endif],
410         [int mode = IPSEC_MODE_BEET;
411          return mode;],
412         [AC_MSG_RESULT([yes]); AC_DEFINE([HAVE_IPSEC_MODE_BEET])],
413         [AC_MSG_RESULT([no])]
414 )
415
416 AC_MSG_CHECKING([for IPSEC_DIR_FWD])
417 AC_TRY_COMPILE(
418         [#include <sys/types.h>
419         #ifdef HAVE_NETIPSEC_IPSEC_H
420         #include <netipsec/ipsec.h>
421         #elif defined(HAVE_NETINET6_IPSEC_H)
422         #include <netinet6/ipsec.h>
423         #else
424         #include <stdint.h>
425         #include <linux/ipsec.h>
426         #endif],
427         [int dir = IPSEC_DIR_FWD;
428          return dir;],
429         [AC_MSG_RESULT([yes]); AC_DEFINE([HAVE_IPSEC_DIR_FWD])],
430         [AC_MSG_RESULT([no])]
431 )
432
433 AC_MSG_CHECKING([for gcc atomic operations])
434 AC_TRY_RUN(
435 [
436         int main() {
437                 volatile int ref = 1;
438                 __sync_fetch_and_add (&ref, 1);
439                 __sync_sub_and_fetch (&ref, 1);
440                 /* Make sure test fails if operations are not supported */
441                 __sync_val_compare_and_swap(&ref, 1, 0);
442                 return ref;
443         }
444 ],
445 [AC_MSG_RESULT([yes]); AC_DEFINE(HAVE_GCC_ATOMIC_OPERATIONS)],
446 [AC_MSG_RESULT([no])],
447 [AC_MSG_RESULT([no])])
448
449 dnl check for the new register_printf_specifier function with len argument,
450 dnl or the deprecated register_printf_function without
451 AC_CHECK_FUNC(
452         [register_printf_specifier],
453         [AC_DEFINE(HAVE_PRINTF_SPECIFIER)],
454         [AC_CHECK_FUNC(
455                 [register_printf_function],
456                 [AC_DEFINE(HAVE_PRINTF_FUNCTION)],
457                 [
458                         AC_MSG_NOTICE([printf does not support custom format specifiers!])
459                         vstr=true
460                 ]
461         )]
462 )
463
464 if test x$vstr = xtrue; then
465         AC_HAVE_LIBRARY([vstr],[LIBS="$LIBS"],[AC_MSG_ERROR([Vstr string library not found])])
466         AC_DEFINE(USE_VSTR)
467 fi
468
469 if test x$gmp = xtrue; then
470         saved_LIBS=$LIBS
471         AC_HAVE_LIBRARY([gmp],,[AC_MSG_ERROR([GNU Multi Precision library gmp not found])])
472         AC_MSG_CHECKING([mpz_powm_sec])
473         if test x$mpz_powm_sec = xyes; then
474                 AC_TRY_COMPILE(
475                         [#include "gmp.h"],
476                         [
477                                 void *x = mpz_powm_sec;
478                         ],
479                         [AC_MSG_RESULT([yes]); AC_DEFINE(HAVE_MPZ_POWM_SEC)], [AC_MSG_RESULT([no])]
480                 )
481         else
482                 AC_MSG_RESULT([disabled])
483         fi
484         LIBS=$saved_LIBS
485         AC_MSG_CHECKING([gmp.h version >= 4.1.4])
486         AC_TRY_COMPILE(
487                 [#include "gmp.h"],
488                 [
489                         #if (__GNU_MP_VERSION*100 +  __GNU_MP_VERSION_MINOR*10 + __GNU_MP_VERSION_PATCHLEVEL) < 414
490                                 #error bad gmp
491                         #endif
492                 ],
493                 [AC_MSG_RESULT([yes])], [AC_MSG_RESULT([no]); AC_MSG_ERROR([No usable gmp.h found!])]
494         )
495 fi
496
497 if test x$ldap = xtrue; then
498         AC_HAVE_LIBRARY([ldap],[LIBS="$LIBS"],[AC_MSG_ERROR([LDAP library ldap not found])])
499         AC_HAVE_LIBRARY([lber],[LIBS="$LIBS"],[AC_MSG_ERROR([LDAP library lber not found])])
500         AC_CHECK_HEADER([ldap.h],,[AC_MSG_ERROR([LDAP header ldap.h not found!])])
501 fi
502
503 if test x$curl = xtrue; then
504         AC_HAVE_LIBRARY([curl],[LIBS="$LIBS"],[AC_MSG_ERROR([CURL library curl not found])])
505         AC_CHECK_HEADER([curl/curl.h],,[AC_MSG_ERROR([CURL header curl/curl.h not found!])])
506 fi
507
508 if test x$xml = xtrue; then
509         PKG_CHECK_MODULES(xml, [libxml-2.0])
510         AC_SUBST(xml_CFLAGS)
511         AC_SUBST(xml_LIBS)
512 fi
513
514 if test x$dumm = xtrue; then
515         PKG_CHECK_MODULES(gtk, [gtk+-2.0 vte])
516         AC_SUBST(gtk_CFLAGS)
517         AC_SUBST(gtk_LIBS)
518         AC_CHECK_PROGS(RUBY, ruby)
519         AC_MSG_CHECKING([for Ruby header files])
520         if test -n "$RUBY"; then
521                 RUBYDIR=`($RUBY -rmkmf -e 'print Config::CONFIG[["archdir"]] || $archdir') 2>/dev/null`
522                 if test -n "$RUBYDIR"; then
523                         dirs="$RUBYDIR"
524                         RUBYINCLUDE=none
525                         for i in $dirs; do
526                                 if test -r $i/ruby.h; then
527                                         AC_MSG_RESULT([$i])
528                                         RUBYINCLUDE="-I$i"
529                                         break;
530                                 fi
531                         done
532                         if test x"$RUBYINCLUDE" = xnone; then
533                                 AC_MSG_ERROR([ruby.h not found])
534                         fi
535                         AC_SUBST(RUBYINCLUDE)
536                 else
537                         AC_MSG_ERROR([unable to determine ruby configuration])
538                 fi
539         else
540                 AC_MSG_ERROR([don't know how to run ruby])
541         fi
542 fi
543
544 if test x$fast = xtrue; then
545         AC_HAVE_LIBRARY([neo_cgi],[LIBS="$LIBS"],[AC_MSG_ERROR([ClearSilver library neo_cgi not found!])])
546         AC_HAVE_LIBRARY([neo_utl],[LIBS="$LIBS"],[AC_MSG_ERROR([ClearSilver library neo_utl not found!])])
547         AC_HAVE_LIBRARY([z],[LIBS="$LIBS"],[AC_MSG_ERROR([ClearSilver dependency zlib not found!])])
548 dnl autoconf does not like CamelCase!? How to fix this?
549 dnl     AC_CHECK_HEADER([ClearSilver/ClearSilver.h],,[AC_MSG_ERROR([ClearSilver header file ClearSilver/ClearSilver.h not found!])])
550
551         AC_HAVE_LIBRARY([fcgi],[LIBS="$LIBS"],[AC_MSG_ERROR([FastCGI library fcgi not found!])])
552         AC_CHECK_HEADER([fcgiapp.h],,[AC_MSG_ERROR([FastCGI header file fcgiapp.h not found!])])
553 fi
554
555 if test x$mysql = xtrue; then
556         AC_PATH_PROG([MYSQLCONFIG], [mysql_config], [], [$PATH:/bin:/usr/bin:/usr/local/bin])
557         if test x$MYSQLCONFIG = x; then
558                 AC_MSG_ERROR([mysql_config not found!])
559         fi
560         AC_SUBST(MYSQLLIB, `$MYSQLCONFIG --libs_r`)
561         AC_SUBST(MYSQLCFLAG, `$MYSQLCONFIG --cflags`)
562 fi
563
564 if test x$sqlite = xtrue; then
565         AC_HAVE_LIBRARY([sqlite3],[LIBS="$LIBS"],[AC_MSG_ERROR([SQLite library sqlite3 not found])])
566         AC_CHECK_HEADER([sqlite3.h],,[AC_MSG_ERROR([SQLite header sqlite3.h not found!])])
567         AC_MSG_CHECKING([sqlite3_prepare_v2])
568         AC_TRY_COMPILE(
569                 [#include <sqlite3.h>],
570                 [
571                         void *test = sqlite3_prepare_v2;
572                 ],
573                 [AC_MSG_RESULT([yes])]; AC_DEFINE_UNQUOTED(HAVE_SQLITE3_PREPARE_V2, 1), [AC_MSG_RESULT([no])])
574         AC_MSG_CHECKING([sqlite3.h version >= 3.3.1])
575         AC_TRY_COMPILE(
576                 [#include <sqlite3.h>],
577                 [
578                         #if SQLITE_VERSION_NUMBER < 3003001
579                                 #error bad sqlite
580                         #endif
581                 ],
582                 [AC_MSG_RESULT([yes])], [AC_MSG_RESULT([no]); AC_MSG_ERROR([SQLite version >= 3.3.1 required!])])
583 fi
584
585 if test x$openssl = xtrue; then
586         AC_HAVE_LIBRARY([crypto],[LIBS="$LIBS"],[AC_MSG_ERROR([OpenSSL crypto library not found])])
587         AC_CHECK_HEADER([openssl/evp.h],,[AC_MSG_ERROR([OpenSSL header openssl/evp.h not found!])])
588 fi
589
590 if test x$gcrypt = xtrue; then
591         AC_HAVE_LIBRARY([gcrypt],[LIBS="$LIBS"],[AC_MSG_ERROR([gcrypt library not found])],[-lgpg-error])
592         AC_CHECK_HEADER([gcrypt.h],,[AC_MSG_ERROR([gcrypt header gcrypt.h not found!])])
593         AC_MSG_CHECKING([gcrypt CAMELLIA cipher])
594         AC_TRY_COMPILE(
595                 [#include <gcrypt.h>],
596                 [enum gcry_cipher_algos alg = GCRY_CIPHER_CAMELLIA128;],
597                 [AC_MSG_RESULT([yes]); AC_DEFINE([HAVE_GCRY_CIPHER_CAMELLIA])],
598                 [AC_MSG_RESULT([no])]
599         )
600 fi
601
602 if test x$uci = xtrue; then
603         AC_HAVE_LIBRARY([uci],[LIBS="$LIBS"],[AC_MSG_ERROR([UCI library libuci not found])])
604         AC_CHECK_HEADER([uci.h],,[AC_MSG_ERROR([UCI header uci.h not found!])])
605 fi
606
607 if test x$android = xtrue; then
608         AC_HAVE_LIBRARY([cutils],[LIBS="$LIBS"],[AC_MSG_ERROR([Android library libcutils not found])])
609         AC_CHECK_HEADER([cutils/properties.h],,[AC_MSG_ERROR([Android header cutils/properties.h not found!])])
610         dnl we have to force the use of libdl here because the autodetection
611         dnl above does not work correctly when cross-compiling for android.
612         DLLIB="-ldl"
613         AC_SUBST(DLLIB)
614 fi
615
616 if test x$nm = xtrue; then
617         PKG_CHECK_EXISTS([libnm-glib],
618                 [PKG_CHECK_MODULES(nm, [NetworkManager gthread-2.0 libnm-glib libnm-glib-vpn])],
619                 [PKG_CHECK_MODULES(nm, [NetworkManager gthread-2.0 libnm_glib libnm_glib_vpn])]
620         )
621         AC_SUBST(nm_CFLAGS)
622         AC_SUBST(nm_LIBS)
623 fi
624
625 if test x$eap_gtc = xtrue; then
626         AC_HAVE_LIBRARY([pam],[LIBS="$LIBS"],[AC_MSG_ERROR([PAM library not found])])
627         AC_CHECK_HEADER([security/pam_appl.h],,[AC_MSG_ERROR([PAM header security/pam_appl.h not found!])])
628 fi
629
630 if test x$capabilities = xnative; then
631         AC_MSG_NOTICE([Usage of the native Linux capabilities interface is deprecated, use libcap instead])
632         dnl Linux requires the following for capset(), Android does not have it,
633         dnl but defines capset() in unistd.h instead.
634         AC_CHECK_HEADERS([sys/capability.h])
635         AC_CHECK_FUNC(capset,,[AC_MSG_ERROR([capset() not found!])])
636         AC_DEFINE(CAPABILITIES_NATIVE)
637 fi
638
639 if test x$capabilities = xlibcap; then
640         AC_HAVE_LIBRARY([cap],[LIBS="$LIBS"],[AC_MSG_ERROR([libcap library not found])])
641         AC_CHECK_HEADER([sys/capability.h],
642                 [AC_DEFINE(HAVE_SYS_CAPABILITY_H)],
643                 [AC_MSG_ERROR([libcap header sys/capability.h not found!])])
644         AC_DEFINE(CAPABILITIES_LIBCAP)
645 fi
646
647 if test x$integrity_test = xtrue; then
648         AC_MSG_CHECKING([for dladdr()])
649         AC_TRY_COMPILE(
650                 [#define _GNU_SOURCE
651                  #include <dlfcn.h>],
652                 [Dl_info info; dladdr(main, &info);],
653                 [AC_MSG_RESULT([yes])], [AC_MSG_RESULT([no]);
654                  AC_MSG_ERROR([dladdr() not supported, required by integrity-test!])]
655         )
656         AC_MSG_CHECKING([for dl_iterate_phdr()])
657         AC_TRY_COMPILE(
658                 [#define _GNU_SOURCE
659                  #include <link.h>],
660                 [dl_iterate_phdr((void*)0, (void*)0);],
661                 [AC_MSG_RESULT([yes])], [AC_MSG_RESULT([no]);
662                  AC_MSG_ERROR([dl_iterate_phdr() not supported, required by integrity-test!])]
663         )
664 fi
665
666 dnl ==============================================
667 dnl  collect plugin list for strongSwan components
668 dnl ==============================================
669
670 m4_include(m4/macros/add-plugin.m4)
671
672 # plugin lists for all components
673 libcharon_plugins=
674 pluto_plugins=
675 pool_plugins=
676 openac_plugins=
677 scepclient_plugins=
678 pki_plugins=
679 scripts_plugins=
680 manager_plugins=
681 medsrv_plugins=
682
683 # location specific lists for checksumming,
684 # for src/libcharon, src/pluto, src/libhydra and src/libstrongswan
685 c_plugins=
686 p_plugins=
687 h_plugins=
688 s_plugins=
689
690 ADD_PLUGIN([test-vectors],         [s libcharon pluto openac scepclient pki])
691 ADD_PLUGIN([curl],                 [s libcharon pluto scepclient])
692 ADD_PLUGIN([ldap],                 [s libcharon pluto scepclient])
693 ADD_PLUGIN([mysql],                [s libcharon pluto pool manager medsrv])
694 ADD_PLUGIN([sqlite],               [s libcharon pluto pool manager medsrv])
695 ADD_PLUGIN([aes],                  [s libcharon pluto openac scepclient pki scripts])
696 ADD_PLUGIN([des],                  [s libcharon pluto openac scepclient pki scripts])
697 ADD_PLUGIN([blowfish],             [s libcharon pluto openac scepclient pki scripts])
698 ADD_PLUGIN([sha1],                 [s libcharon pluto openac scepclient pki scripts medsrv])
699 ADD_PLUGIN([sha2],                 [s libcharon pluto openac scepclient pki scripts medsrv])
700 ADD_PLUGIN([md4],                  [s libcharon openac manager scepclient pki])
701 ADD_PLUGIN([md5],                  [s libcharon pluto openac scepclient pki])
702 ADD_PLUGIN([random],               [s libcharon pluto openac scepclient pki medsrv])
703 ADD_PLUGIN([x509],                 [s libcharon pluto openac scepclient pki])
704 ADD_PLUGIN([revocation],           [s libcharon])
705 ADD_PLUGIN([pubkey],               [s libcharon])
706 ADD_PLUGIN([pkcs1],                [s libcharon pluto openac scepclient pki scripts manager medsrv])
707 ADD_PLUGIN([pgp],                  [s libcharon pluto])
708 ADD_PLUGIN([dnskey],               [s pluto])
709 ADD_PLUGIN([pem],                  [s libcharon pluto openac scepclient pki scripts manager medsrv])
710 ADD_PLUGIN([padlock],              [s libcharon])
711 ADD_PLUGIN([openssl],              [s libcharon pluto openac scepclient pki scripts manager medsrv])
712 ADD_PLUGIN([gcrypt],               [s libcharon pluto openac scepclient pki scripts manager medsrv])
713 ADD_PLUGIN([fips-prf],             [s libcharon])
714 ADD_PLUGIN([gmp],                  [s libcharon pluto openac scepclient pki scripts manager medsrv])
715 ADD_PLUGIN([agent],                [s libcharon])
716 ADD_PLUGIN([pkcs11],               [s libcharon pki])
717 ADD_PLUGIN([xcbc],                 [s libcharon])
718 ADD_PLUGIN([hmac],                 [s libcharon pluto])
719 ADD_PLUGIN([ctr],                  [s libcharon scripts])
720 ADD_PLUGIN([ccm],                  [s libcharon scripts])
721 ADD_PLUGIN([xauth],                [p pluto])
722 ADD_PLUGIN([attr],                 [h libcharon pluto])
723 ADD_PLUGIN([attr-sql],             [h libcharon pluto])
724 ADD_PLUGIN([resolve],              [h libcharon pluto])
725 ADD_PLUGIN([load-tester],          [c libcharon])
726 ADD_PLUGIN([kernel-pfkey],         [c libcharon])
727 ADD_PLUGIN([kernel-pfroute],       [c libcharon])
728 ADD_PLUGIN([kernel-klips],         [c libcharon])
729 ADD_PLUGIN([kernel-netlink],       [c libcharon])
730 ADD_PLUGIN([socket-default],       [c libcharon])
731 ADD_PLUGIN([socket-raw],           [c libcharon])
732 ADD_PLUGIN([socket-dynamic],       [c libcharon])
733 ADD_PLUGIN([farp],                 [c libcharon])
734 ADD_PLUGIN([stroke],               [c libcharon])
735 ADD_PLUGIN([smp],                  [c libcharon])
736 ADD_PLUGIN([sql],                  [c libcharon])
737 ADD_PLUGIN([updown],               [c libcharon])
738 ADD_PLUGIN([eap-identity],         [c libcharon])
739 ADD_PLUGIN([eap-sim],              [c libcharon])
740 ADD_PLUGIN([eap-sim-file],         [c libcharon])
741 ADD_PLUGIN([eap-simaka-sql],       [c libcharon])
742 ADD_PLUGIN([eap-simaka-pseudonym], [c libcharon])
743 ADD_PLUGIN([eap-simaka-reauth],    [c libcharon])
744 ADD_PLUGIN([eap-aka],              [c libcharon])
745 ADD_PLUGIN([eap-aka-3gpp2],        [c libcharon])
746 ADD_PLUGIN([eap-md5],              [c libcharon])
747 ADD_PLUGIN([eap-gtc],              [c libcharon])
748 ADD_PLUGIN([eap-mschapv2],         [c libcharon])
749 ADD_PLUGIN([eap-radius],           [c libcharon])
750 ADD_PLUGIN([eap-tls],              [c libcharon])
751 ADD_PLUGIN([eap-ttls],             [c libcharon])
752 ADD_PLUGIN([medsrv],               [c libcharon])
753 ADD_PLUGIN([medcli],               [c libcharon])
754 ADD_PLUGIN([nm],                   [c libcharon])
755 ADD_PLUGIN([dhcp],                 [c libcharon])
756 ADD_PLUGIN([android],              [c libcharon])
757 ADD_PLUGIN([ha],                   [c libcharon])
758 ADD_PLUGIN([uci],                  [c libcharon])
759 ADD_PLUGIN([addrblock],            [c libcharon])
760 ADD_PLUGIN([unit-tester],          [c libcharon])
761
762 AC_SUBST(libcharon_plugins)
763 AC_SUBST(pluto_plugins)
764 AC_SUBST(pool_plugins)
765 AC_SUBST(openac_plugins)
766 AC_SUBST(scepclient_plugins)
767 AC_SUBST(pki_plugins)
768 AC_SUBST(scripts_plugins)
769 AC_SUBST(manager_plugins)
770 AC_SUBST(medsrv_plugins)
771
772 AC_SUBST(c_plugins)
773 AC_SUBST(p_plugins)
774 AC_SUBST(h_plugins)
775 AC_SUBST(s_plugins)
776
777 dnl =========================
778 dnl  set Makefile.am vars
779 dnl =========================
780
781 dnl libstrongswan plugins
782 dnl =====================
783 AM_CONDITIONAL(USE_TEST_VECTORS, test x$test_vectors = xtrue)
784 AM_CONDITIONAL(USE_CURL, test x$curl = xtrue)
785 AM_CONDITIONAL(USE_LDAP, test x$ldap = xtrue)
786 AM_CONDITIONAL(USE_AES, test x$aes = xtrue)
787 AM_CONDITIONAL(USE_DES, test x$des = xtrue)
788 AM_CONDITIONAL(USE_BLOWFISH, test x$blowfish = xtrue)
789 AM_CONDITIONAL(USE_MD4, test x$md4 = xtrue)
790 AM_CONDITIONAL(USE_MD5, test x$md5 = xtrue)
791 AM_CONDITIONAL(USE_SHA1, test x$sha1 = xtrue)
792 AM_CONDITIONAL(USE_SHA2, test x$sha2 = xtrue)
793 AM_CONDITIONAL(USE_FIPS_PRF, test x$fips_prf = xtrue)
794 AM_CONDITIONAL(USE_GMP, test x$gmp = xtrue)
795 AM_CONDITIONAL(USE_RANDOM, test x$random = xtrue)
796 AM_CONDITIONAL(USE_X509, test x$x509 = xtrue)
797 AM_CONDITIONAL(USE_REVOCATION, test x$revocation = xtrue)
798 AM_CONDITIONAL(USE_PUBKEY, test x$pubkey = xtrue)
799 AM_CONDITIONAL(USE_PKCS1, test x$pkcs1 = xtrue)
800 AM_CONDITIONAL(USE_PGP, test x$pgp = xtrue)
801 AM_CONDITIONAL(USE_DNSKEY, test x$dnskey = xtrue)
802 AM_CONDITIONAL(USE_PEM, test x$pem = xtrue)
803 AM_CONDITIONAL(USE_HMAC, test x$hmac = xtrue)
804 AM_CONDITIONAL(USE_XCBC, test x$xcbc = xtrue)
805 AM_CONDITIONAL(USE_MYSQL, test x$mysql = xtrue)
806 AM_CONDITIONAL(USE_SQLITE, test x$sqlite = xtrue)
807 AM_CONDITIONAL(USE_PADLOCK, test x$padlock = xtrue)
808 AM_CONDITIONAL(USE_OPENSSL, test x$openssl = xtrue)
809 AM_CONDITIONAL(USE_GCRYPT, test x$gcrypt = xtrue)
810 AM_CONDITIONAL(USE_AGENT, test x$agent = xtrue)
811 AM_CONDITIONAL(USE_PKCS11, test x$pkcs11 = xtrue)
812 AM_CONDITIONAL(USE_CTR, test x$ctr = xtrue)
813 AM_CONDITIONAL(USE_CCM, test x$ccm = xtrue)
814
815 dnl charon plugins
816 dnl ==============
817 AM_CONDITIONAL(USE_STROKE, test x$stroke = xtrue)
818 AM_CONDITIONAL(USE_MEDSRV, test x$medsrv = xtrue)
819 AM_CONDITIONAL(USE_MEDCLI, test x$medcli = xtrue)
820 AM_CONDITIONAL(USE_NM, test x$nm = xtrue)
821 AM_CONDITIONAL(USE_UCI, test x$uci = xtrue)
822 AM_CONDITIONAL(USE_ANDROID, test x$android = xtrue)
823 AM_CONDITIONAL(USE_SMP, test x$smp = xtrue)
824 AM_CONDITIONAL(USE_SQL, test x$sql = xtrue)
825 AM_CONDITIONAL(USE_UPDOWN, test x$updown = xtrue)
826 AM_CONDITIONAL(USE_DHCP, test x$dhcp = xtrue)
827 AM_CONDITIONAL(USE_UNIT_TESTS, test x$unit_tests = xtrue)
828 AM_CONDITIONAL(USE_LOAD_TESTER, test x$load_tester = xtrue)
829 AM_CONDITIONAL(USE_HA, test x$ha = xtrue)
830 AM_CONDITIONAL(USE_EAP_SIM, test x$eap_sim = xtrue)
831 AM_CONDITIONAL(USE_EAP_SIM_FILE, test x$eap_sim_file = xtrue)
832 AM_CONDITIONAL(USE_EAP_SIMAKA_SQL, test x$eap_simaka_sql = xtrue)
833 AM_CONDITIONAL(USE_EAP_SIMAKA_PSEUDONYM, test x$eap_simaka_pseudonym = xtrue)
834 AM_CONDITIONAL(USE_EAP_SIMAKA_REAUTH, test x$eap_simaka_reauth = xtrue)
835 AM_CONDITIONAL(USE_EAP_IDENTITY, test x$eap_identity = xtrue)
836 AM_CONDITIONAL(USE_EAP_MD5, test x$eap_md5 = xtrue)
837 AM_CONDITIONAL(USE_EAP_GTC, test x$eap_gtc = xtrue)
838 AM_CONDITIONAL(USE_EAP_AKA, test x$eap_aka = xtrue)
839 AM_CONDITIONAL(USE_EAP_AKA_3GPP2, test x$eap_aka_3gpp2 = xtrue)
840 AM_CONDITIONAL(USE_EAP_MSCHAPV2, test x$eap_mschapv2 = xtrue)
841 AM_CONDITIONAL(USE_EAP_TLS, test x$eap_tls = xtrue)
842 AM_CONDITIONAL(USE_EAP_TTLS, test x$eap_ttls = xtrue)
843 AM_CONDITIONAL(USE_EAP_RADIUS, test x$eap_radius = xtrue)
844 AM_CONDITIONAL(USE_KERNEL_NETLINK, test x$kernel_netlink = xtrue)
845 AM_CONDITIONAL(USE_KERNEL_PFKEY, test x$kernel_pfkey = xtrue)
846 AM_CONDITIONAL(USE_KERNEL_PFROUTE, test x$kernel_pfroute = xtrue)
847 AM_CONDITIONAL(USE_KERNEL_KLIPS, test x$kernel_klips = xtrue)
848 AM_CONDITIONAL(USE_SOCKET_DEFAULT, test x$socket_default = xtrue)
849 AM_CONDITIONAL(USE_SOCKET_RAW, test x$socket_raw = xtrue)
850 AM_CONDITIONAL(USE_SOCKET_DYNAMIC, test x$socket_dynamic = xtrue)
851 AM_CONDITIONAL(USE_FARP, test x$farp = xtrue)
852 AM_CONDITIONAL(USE_ADDRBLOCK, test x$addrblock = xtrue)
853
854 dnl hydra plugins
855 dnl =============
856 AM_CONDITIONAL(USE_ATTR, test x$attr = xtrue)
857 AM_CONDITIONAL(USE_ATTR_SQL, test x$attr_sql = xtrue -o x$sql = xtrue)
858 AM_CONDITIONAL(USE_RESOLVE, test x$resolve = xtrue)
859
860 dnl pluto plugins
861 dnl =============
862 AM_CONDITIONAL(USE_XAUTH, test x$xauth = xtrue)
863
864 dnl other options
865 dnl =============
866 AM_CONDITIONAL(USE_SMARTCARD, test x$smartcard = xtrue)
867 AM_CONDITIONAL(USE_CISCO_QUIRKS, test x$cisco_quirks = xtrue)
868 AM_CONDITIONAL(USE_LEAK_DETECTIVE, test x$leak_detective = xtrue)
869 AM_CONDITIONAL(USE_LOCK_PROFILER, test x$lock_profiler = xtrue)
870 AM_CONDITIONAL(USE_NAT_TRANSPORT, test x$nat_transport = xtrue)
871 AM_CONDITIONAL(USE_VENDORID, test x$vendor_id = xtrue)
872 AM_CONDITIONAL(USE_XAUTH_VID, test x$xauth_vid = xtrue)
873 AM_CONDITIONAL(USE_DUMM, test x$dumm = xtrue)
874 AM_CONDITIONAL(USE_FAST, test x$fast = xtrue)
875 AM_CONDITIONAL(USE_MANAGER, test x$manager = xtrue)
876 AM_CONDITIONAL(USE_ME, test x$mediation = xtrue)
877 AM_CONDITIONAL(USE_INTEGRITY_TEST, test x$integrity_test = xtrue)
878 AM_CONDITIONAL(USE_LOAD_WARNING, test x$load_warning = xtrue)
879 AM_CONDITIONAL(USE_PLUTO, test x$pluto = xtrue)
880 AM_CONDITIONAL(USE_THREADS, test x$threads = xtrue)
881 AM_CONDITIONAL(USE_CHARON, test x$charon = xtrue)
882 AM_CONDITIONAL(USE_TOOLS, test x$tools = xtrue)
883 AM_CONDITIONAL(USE_SCRIPTS, test x$scripts = xtrue)
884 AM_CONDITIONAL(USE_LIBSTRONGSWAN, test x$charon = xtrue -o x$pluto = xtrue -o x$tools = xtrue)
885 AM_CONDITIONAL(USE_LIBHYDRA, test x$charon = xtrue -o x$pluto = xtrue)
886 AM_CONDITIONAL(USE_FILE_CONFIG, test x$pluto = xtrue -o x$stroke = xtrue)
887 AM_CONDITIONAL(USE_LIBCAP, test x$capabilities = xlibcap)
888 AM_CONDITIONAL(USE_VSTR, test x$vstr = xtrue)
889 AM_CONDITIONAL(USE_SIMAKA, test x$simaka = xtrue)
890 AM_CONDITIONAL(USE_TLS, test x$tls = xtrue)
891 AM_CONDITIONAL(MONOLITHIC, test x$monolithic = xtrue)
892
893 dnl ==============================
894 dnl  set global definitions
895 dnl ==============================
896
897 if test x$mediation = xtrue; then
898         AC_DEFINE(ME)
899 fi
900 if test x$capabilities = xlibcap -o x$capabilities = xnative; then
901         AC_DEFINE(CAPABILITIES)
902 fi
903 if test x$monolithic = xtrue; then
904         AC_DEFINE(MONOLITHIC)
905 fi
906
907
908 dnl ==============================
909 dnl  build Makefiles
910 dnl ==============================
911
912 AC_OUTPUT(
913         Makefile
914         src/Makefile
915         src/include/Makefile
916         src/libstrongswan/Makefile
917         src/libstrongswan/plugins/aes/Makefile
918         src/libstrongswan/plugins/des/Makefile
919         src/libstrongswan/plugins/blowfish/Makefile
920         src/libstrongswan/plugins/md4/Makefile
921         src/libstrongswan/plugins/md5/Makefile
922         src/libstrongswan/plugins/sha1/Makefile
923         src/libstrongswan/plugins/sha2/Makefile
924         src/libstrongswan/plugins/fips_prf/Makefile
925         src/libstrongswan/plugins/gmp/Makefile
926         src/libstrongswan/plugins/random/Makefile
927         src/libstrongswan/plugins/hmac/Makefile
928         src/libstrongswan/plugins/xcbc/Makefile
929         src/libstrongswan/plugins/x509/Makefile
930         src/libstrongswan/plugins/revocation/Makefile
931         src/libstrongswan/plugins/pubkey/Makefile
932         src/libstrongswan/plugins/pkcs1/Makefile
933         src/libstrongswan/plugins/pgp/Makefile
934         src/libstrongswan/plugins/dnskey/Makefile
935         src/libstrongswan/plugins/pem/Makefile
936         src/libstrongswan/plugins/curl/Makefile
937         src/libstrongswan/plugins/ldap/Makefile
938         src/libstrongswan/plugins/mysql/Makefile
939         src/libstrongswan/plugins/sqlite/Makefile
940         src/libstrongswan/plugins/padlock/Makefile
941         src/libstrongswan/plugins/openssl/Makefile
942         src/libstrongswan/plugins/gcrypt/Makefile
943         src/libstrongswan/plugins/agent/Makefile
944         src/libstrongswan/plugins/pkcs11/Makefile
945         src/libstrongswan/plugins/ctr/Makefile
946         src/libstrongswan/plugins/ccm/Makefile
947         src/libstrongswan/plugins/test_vectors/Makefile
948         src/libhydra/Makefile
949         src/libhydra/plugins/attr/Makefile
950         src/libhydra/plugins/attr_sql/Makefile
951         src/libhydra/plugins/resolve/Makefile
952         src/libfreeswan/Makefile
953         src/libsimaka/Makefile
954         src/libtls/Makefile
955         src/pluto/Makefile
956         src/pluto/plugins/xauth/Makefile
957         src/whack/Makefile
958         src/charon/Makefile
959         src/libcharon/Makefile
960         src/libcharon/plugins/eap_aka/Makefile
961         src/libcharon/plugins/eap_aka_3gpp2/Makefile
962         src/libcharon/plugins/eap_identity/Makefile
963         src/libcharon/plugins/eap_md5/Makefile
964         src/libcharon/plugins/eap_gtc/Makefile
965         src/libcharon/plugins/eap_sim/Makefile
966         src/libcharon/plugins/eap_sim_file/Makefile
967         src/libcharon/plugins/eap_simaka_sql/Makefile
968         src/libcharon/plugins/eap_simaka_pseudonym/Makefile
969         src/libcharon/plugins/eap_simaka_reauth/Makefile
970         src/libcharon/plugins/eap_mschapv2/Makefile
971         src/libcharon/plugins/eap_tls/Makefile
972         src/libcharon/plugins/eap_ttls/Makefile
973         src/libcharon/plugins/eap_radius/Makefile
974         src/libcharon/plugins/kernel_netlink/Makefile
975         src/libcharon/plugins/kernel_pfkey/Makefile
976         src/libcharon/plugins/kernel_pfroute/Makefile
977         src/libcharon/plugins/kernel_klips/Makefile
978         src/libcharon/plugins/socket_default/Makefile
979         src/libcharon/plugins/socket_raw/Makefile
980         src/libcharon/plugins/socket_dynamic/Makefile
981         src/libcharon/plugins/farp/Makefile
982         src/libcharon/plugins/smp/Makefile
983         src/libcharon/plugins/sql/Makefile
984         src/libcharon/plugins/medsrv/Makefile
985         src/libcharon/plugins/medcli/Makefile
986         src/libcharon/plugins/nm/Makefile
987         src/libcharon/plugins/addrblock/Makefile
988         src/libcharon/plugins/uci/Makefile
989         src/libcharon/plugins/ha/Makefile
990         src/libcharon/plugins/android/Makefile
991         src/libcharon/plugins/stroke/Makefile
992         src/libcharon/plugins/updown/Makefile
993         src/libcharon/plugins/dhcp/Makefile
994         src/libcharon/plugins/unit_tester/Makefile
995         src/libcharon/plugins/load_tester/Makefile
996         src/stroke/Makefile
997         src/ipsec/Makefile
998         src/starter/Makefile
999         src/_updown/Makefile
1000         src/_updown_espmark/Makefile
1001         src/_copyright/Makefile
1002         src/openac/Makefile
1003         src/scepclient/Makefile
1004         src/pki/Makefile
1005         src/dumm/Makefile
1006         src/dumm/ext/extconf.rb
1007         src/libfast/Makefile
1008         src/manager/Makefile
1009         src/medsrv/Makefile
1010         src/checksum/Makefile
1011         scripts/Makefile
1012         testing/Makefile
1013 )