Added a counter mode wrapper plugin operating on existing CBC crypters
[strongswan.git] / configure.in
1 dnl  configure.in for linux strongSwan
2 dnl  Copyright (C) 2006 Martin Willi
3 dnl  Hochschule fuer Technik Rapperswil
4 dnl
5 dnl  This program is free software; you can redistribute it and/or modify it
6 dnl  under the terms of the GNU General Public License as published by the
7 dnl  Free Software Foundation; either version 2 of the License, or (at your
8 dnl  option) any later version.  See <http://www.fsf.org/copyleft/gpl.txt>.
9 dnl
10 dnl  This program is distributed in the hope that it will be useful, but
11 dnl  WITHOUT ANY WARRANTY; without even the implied warranty of MERCHANTABILITY
12 dnl  or FITNESS FOR A PARTICULAR PURPOSE.  See the GNU General Public License
13 dnl  for more details.
14
15 dnl ===========================
16 dnl  initialize & set some vars
17 dnl ===========================
18
19 AC_INIT(strongSwan,4.4.2dr1)
20 AM_INIT_AUTOMAKE(tar-ustar)
21 AC_CONFIG_MACRO_DIR([m4/config])
22 PKG_PROG_PKG_CONFIG
23
24 dnl =================================
25 dnl  check --enable-xxx & --with-xxx
26 dnl =================================
27
28 m4_include(m4/macros/with.m4)
29
30 ARG_WITH_SUBST([default-pkcs11],     [/usr/lib/opensc-pkcs11.so], [set the default PKCS11 library])
31 ARG_WITH_SUBST([random-device],      [/dev/random], [set the device to read real random data from])
32 ARG_WITH_SUBST([urandom-device],     [/dev/urandom], [set the device to read pseudo random data from])
33 ARG_WITH_SUBST([strongswan-conf],    [${sysconfdir}/strongswan.conf], [set the strongswan.conf file location])
34 ARG_WITH_SUBST([resolv-conf],        [${sysconfdir}/resolv.conf], [set the file to use in DNS handler plugin])
35 ARG_WITH_SUBST([piddir],             [/var/run], [set path for PID and UNIX socket files])
36 ARG_WITH_SUBST([ipsecdir],           [${libexecdir%/}/ipsec], [set installation path for ipsec tools])
37 ARG_WITH_SUBST([plugindir],          [${ipsecdir%/}/plugins], [set the installation path of plugins])
38 ARG_WITH_SUBST([nm-ca-dir],          [/usr/share/ca-certificates], [directory the NM plugin uses to look up trusted root certificates])
39 ARG_WITH_SUBST([linux-headers],      [\${top_srcdir}/src/include], [set directory of linux header files to use])
40 ARG_WITH_SUBST([routing-table],      [220], [set routing table to use for IPsec routes])
41 ARG_WITH_SUBST([routing-table-prio], [220], [set priority for IPsec routing table])
42
43 ARG_WITH_SET([capabilities],         [no], [set capability dropping library. Currently supported values are "libcap" and "native"])
44 ARG_WITH_SET([mpz_powm_sec],         [yes], [use the more side-channel resistant mpz_powm_sec in libgmp, if available])
45
46 AC_ARG_WITH(
47         [xauth-module],
48         AS_HELP_STRING([--with-xauth-module=lib],[set the path to the XAUTH module]),
49         [AC_DEFINE_UNQUOTED(XAUTH_DEFAULT_LIB, "$withval")],
50 )
51
52 AC_ARG_WITH(
53         [user],
54         AS_HELP_STRING([--with-user=user],[change user of the daemons to "user" after startup (default is "root").]),
55         [AC_DEFINE_UNQUOTED(IPSEC_USER, "$withval") AC_SUBST(ipsecuser, "$withval")],
56         [AC_SUBST(ipsecuser, "root")]
57 )
58
59 AC_ARG_WITH(
60         [group],
61         AS_HELP_STRING([--with-group=group],[change group of the daemons to "group" after startup (default is "root").]),
62         [AC_DEFINE_UNQUOTED(IPSEC_GROUP, "$withval") AC_SUBST(ipsecgroup, "$withval")],
63         [AC_SUBST(ipsecgroup, "root")]
64 )
65
66 m4_include(m4/macros/enable-disable.m4)
67
68 ARG_ENABL_SET([curl],           [enable CURL fetcher plugin to fetch files via libcurl. Requires libcurl.])
69 ARG_ENABL_SET([ldap],           [enable LDAP fetching plugin to fetch files via libldap. Requires openLDAP.])
70 ARG_DISBL_SET([aes],            [disable AES software implementation plugin.])
71 ARG_DISBL_SET([des],            [disable DES/3DES software implementation plugin.])
72 ARG_ENABL_SET([blowfish],       [enable Blowfish software implementation plugin.])
73 ARG_ENABL_SET([md4],            [enable MD4 software implementation plugin.])
74 ARG_DISBL_SET([md5],            [disable MD5 software implementation plugin.])
75 ARG_DISBL_SET([sha1],           [disable SHA1 software implementation plugin.])
76 ARG_DISBL_SET([sha2],           [disable SHA256/SHA384/SHA512 software implementation plugin.])
77 ARG_DISBL_SET([fips-prf],       [disable FIPS PRF software implementation plugin.])
78 ARG_DISBL_SET([gmp],            [disable GNU MP (libgmp) based crypto implementation plugin.])
79 ARG_DISBL_SET([random],         [disable RNG implementation on top of /dev/(u)random.])
80 ARG_DISBL_SET([x509],           [disable X509 certificate implementation plugin.])
81 ARG_DISBL_SET([revocation],     [disable X509 CRL/OCSP revocation check plugin.])
82 ARG_DISBL_SET([pubkey],         [disable RAW public key support plugin.])
83 ARG_DISBL_SET([pkcs1],          [disable PKCS1 key decoding plugin.])
84 ARG_DISBL_SET([pgp],            [disable PGP key decoding plugin.])
85 ARG_DISBL_SET([dnskey],         [disable DNS RR key decoding plugin.])
86 ARG_DISBL_SET([pem],            [disable PEM decoding plugin.])
87 ARG_DISBL_SET([hmac],           [disable HMAC crypto implementation plugin.])
88 ARG_DISBL_SET([xcbc],           [disable xcbc crypto implementation plugin.])
89 ARG_ENABL_SET([test-vectors],   [enable plugin providing crypto test vectors.])
90 ARG_ENABL_SET([mysql],          [enable MySQL database support. Requires libmysqlclient_r.])
91 ARG_ENABL_SET([sqlite],         [enable SQLite database support. Requires libsqlite3.])
92 ARG_DISBL_SET([stroke],         [disable charons stroke (pluto compatibility) configuration backend.])
93 ARG_ENABL_SET([medsrv],         [enable mediation server web frontend and daemon plugin.])
94 ARG_ENABL_SET([medcli],         [enable mediation client configuration database plugin.])
95 ARG_ENABL_SET([smp],            [enable SMP configuration and control interface. Requires libxml.])
96 ARG_ENABL_SET([sql],            [enable SQL database configuration backend.])
97 ARG_ENABL_SET([smartcard],      [enable smartcard support.])
98 ARG_ENABL_SET([cisco-quirks],   [enable support of Cisco VPN client.])
99 ARG_ENABL_SET([leak-detective], [enable malloc hooks to find memory leaks.])
100 ARG_ENABL_SET([lock-profiler],  [enable lock/mutex profiling code.])
101 ARG_ENABL_SET([unit-tests],     [enable unit tests on IKEv2 daemon startup.])
102 ARG_ENABL_SET([load-tester],    [enable load testing plugin for IKEv2 daemon.])
103 ARG_ENABL_SET([eap-sim],        [enable SIM authenication module for EAP.])
104 ARG_ENABL_SET([eap-sim-file],   [enable EAP-SIM backend based on a triplet file.])
105 ARG_ENABL_SET([eap-simaka-sql], [enable EAP-SIM/AKA backend based on a triplet/quintuplet SQL database.])
106 ARG_ENABL_SET([eap-simaka-pseudonym], [enable EAP-SIM/AKA pseudonym storage plugin.])
107 ARG_ENABL_SET([eap-simaka-reauth],    [enable EAP-SIM/AKA reauthentication data storage plugin.])
108 ARG_ENABL_SET([eap-identity],   [enable EAP module providing EAP-Identity helper.])
109 ARG_ENABL_SET([eap-md5],        [enable EAP MD5 (CHAP) authenication module.])
110 ARG_ENABL_SET([eap-gtc],        [enable PAM based EAP GTC authenication module.])
111 ARG_ENABL_SET([eap-aka],        [enable EAP AKA authentication module.])
112 ARG_ENABL_SET([eap-aka-3gpp2],  [enable EAP AKA backend implementing 3GPP2 algorithms in software. Requires libgmp.])
113 ARG_ENABL_SET([eap-mschapv2],   [enable EAP MS-CHAPv2 authenication module.])
114 ARG_ENABL_SET([eap-tls],        [enable EAP TLS authenication module.])
115 ARG_ENABL_SET([eap-ttls],       [enable EAP TTLS authenication module.])
116 ARG_ENABL_SET([eap-radius],     [enable RADIUS proxy authenication module.])
117 ARG_DISBL_SET([kernel-netlink], [disable the netlink kernel interface.])
118 ARG_ENABL_SET([kernel-pfkey],   [enable the PF_KEY kernel interface.])
119 ARG_ENABL_SET([kernel-pfroute], [enable the PF_ROUTE kernel interface.])
120 ARG_ENABL_SET([kernel-klips],   [enable the KLIPS kernel interface.])
121 ARG_DISBL_SET([socket-default], [disable default socket implementation for charon.])
122 ARG_ENABL_SET([socket-raw],     [enable raw socket implementation of charon, enforced if pluto is enabled])
123 ARG_ENABL_SET([socket-dynamic], [enable dynamic socket implementation for charon])
124 ARG_ENABL_SET([farp],           [enable ARP faking plugin that responds to ARP requests to peers virtual IP])
125 ARG_ENABL_SET([nat-transport],  [enable NAT traversal with IPsec transport mode in pluto.])
126 ARG_DISBL_SET([vendor-id],      [disable the sending of the strongSwan vendor ID in pluto.])
127 ARG_DISBL_SET([xauth-vid],      [disable the sending of the XAUTH vendor ID.])
128 ARG_ENABL_SET([dumm],           [enable the DUMM UML test framework.])
129 ARG_ENABL_SET([fast],           [enable libfast (FastCGI Application Server w/ templates.])
130 ARG_ENABL_SET([manager],        [enable web management console (proof of concept).])
131 ARG_ENABL_SET([mediation],      [enable IKEv2 Mediation Extension.])
132 ARG_ENABL_SET([integrity-test], [enable integrity testing of libstrongswan and plugins.])
133 ARG_DISBL_SET([load-warning],   [disable the charon/pluto plugin load option warning in starter.])
134 ARG_DISBL_SET([pluto],          [disable the IKEv1 keying daemon pluto.])
135 ARG_DISBL_SET([xauth],          [disable xauth plugin.])
136 ARG_DISBL_SET([threads],        [disable the use of threads in pluto. Charon always uses threads.])
137 ARG_DISBL_SET([charon],         [disable the IKEv2 keying daemon charon.])
138 ARG_DISBL_SET([tools],          [disable additional utilities (openac, scepclient and pki).])
139 ARG_DISBL_SET([scripts],        [disable additional utilities (found in directory scripts).])
140 ARG_DISBL_SET([updown],         [disable updown firewall script plugin.])
141 ARG_DISBL_SET([attr],           [disable strongswan.conf based configuration attribute plugin.])
142 ARG_ENABL_SET([attr-sql],       [enable SQL based configuration attribute plugin.])
143 ARG_ENABL_SET([dhcp],           [enable DHCP based attribute provider plugin.])
144 ARG_DISBL_SET([resolve],        [disable resolve DNS handler plugin.])
145 ARG_ENABL_SET([padlock],        [enables VIA Padlock crypto plugin.])
146 ARG_ENABL_SET([openssl],        [enables the OpenSSL crypto plugin.])
147 ARG_ENABL_SET([gcrypt],         [enables the libgcrypt plugin.])
148 ARG_ENABL_SET([agent],          [enables the ssh-agent signing plugin.])
149 ARG_ENABL_SET([pkcs11],         [enables the PKCS11 token support plugin.])
150 ARG_ENABL_SET([ctr],            [enables the Counter Mode wrapper crypto plugin.])
151 ARG_ENABL_SET([addrblock],      [enables RFC 3779 address block constraint support.])
152 ARG_ENABL_SET([uci],            [enable OpenWRT UCI configuration plugin.])
153 ARG_ENABL_SET([android],        [enable Android specific plugin.])
154 ARG_ENABL_SET([nm],             [enable NetworkManager plugin.])
155 ARG_ENABL_SET([ha],             [enable high availability cluster plugin.])
156 ARG_ENABL_SET([vstr],           [enforce using the Vstr string library to replace glibc-like printf hooks.])
157 ARG_ENABL_SET([monolithic],     [build monolithic version of libstrongswan that includes all enabled plugins. Similarly, the plugins of charon are assembled in libcharon.])
158
159 dnl =========================
160 dnl  set up compiler and flags
161 dnl =========================
162
163 if test -z "$CFLAGS"; then
164         CFLAGS="-g -O2 -Wall -Wno-format -Wno-pointer-sign -Wno-strict-aliasing"
165 fi
166 AC_PROG_CC
167 AC_LIB_PREFIX
168 AC_C_BIGENDIAN
169
170 dnl =========================
171 dnl  check required programs
172 dnl =========================
173
174 AC_PROG_INSTALL
175 AC_PROG_LIBTOOL
176 AC_PROG_EGREP
177 AC_PROG_AWK
178 AC_PROG_LEX
179 AC_PROG_YACC
180 AC_PATH_PROG([PERL], [perl], [], [$PATH:/bin:/usr/bin:/usr/local/bin])
181 AC_PATH_PROG([GPERF], [gperf], [], [$PATH:/bin:/usr/bin:/usr/local/bin])
182
183 dnl because gperf is not needed by end-users we just report it but do not abort on failure
184 AC_MSG_CHECKING([gperf version >= 3.0.0])
185 if test -x "$GPERF"; then
186         if test "`$GPERF --version | $AWK -F' ' '/^GNU gperf/ { print $3 }' | $AWK -F. '{ print $1 }'`" -ge "3"; then
187                 AC_MSG_RESULT([yes])
188         else
189                 AC_MSG_RESULT([no])
190         fi
191 else
192         AC_MSG_RESULT([not found])
193 fi
194
195 dnl translate user/group to numercial ids
196 AC_MSG_CHECKING([for uid of user "$ipsecuser"])
197 ipsecuid=`id -u $ipsecuser 2>/dev/null`
198 if test -n "$ipsecuid"; then
199         AC_MSG_RESULT([$ipsecuid])
200         AC_SUBST(ipsecuid)
201 else
202         AC_MSG_ERROR([not found])
203 fi
204 AC_MSG_CHECKING([for gid of group "$ipsecgroup"])
205 ipsecgid=`$EGREP "^$ipsecgroup:" /etc/group | $AWK -F: '{ print $3 }'`
206 if test -n "$ipsecgid"; then
207         AC_MSG_RESULT([$ipsecgid])
208         AC_SUBST(ipsecgid)
209 else
210         AC_MSG_ERROR([not found])
211 fi
212
213 dnl =========================
214 dnl  dependency calculation
215 dnl =========================
216
217 if test x$eap_aka_3gpp2 = xtrue; then
218         gmp=true;
219 fi
220
221 if test x$eap_aka = xtrue; then
222         fips_prf=true;
223         simaka=true;
224 fi
225
226 if test x$eap_sim = xtrue; then
227         fips_prf=true;
228         simaka=true;
229 fi
230
231 if test x$eap_tls = xtrue -o x$eap_ttls = xtrue; then
232         tls=true;
233 fi
234
235 if test x$fips_prf = xtrue; then
236         if test x$openssl = xfalse; then
237                 sha1=true;
238         fi
239 fi
240
241 if test x$smp = xtrue; then
242         xml=true
243 fi
244
245 if test x$manager = xtrue; then
246         fast=true
247 fi
248
249 if test x$medsrv = xtrue; then
250         mediation=true
251         fast=true
252 fi
253
254 if test x$medcli = xtrue; then
255         mediation=true
256 fi
257
258 if test x$pluto = xtrue; then
259         if test x$socket_raw = xfalse; then
260                 AC_MSG_NOTICE([Enforcing --enable-socket-raw, as pluto is enabled])
261                 socket_raw=true
262                 if test x$socket_default_given = xfalse; then
263                         socket_default=false
264                 fi
265         fi
266 fi
267
268 dnl ===========================================
269 dnl  check required libraries and header files
270 dnl ===========================================
271
272 AC_HEADER_STDBOOL
273 AC_FUNC_ALLOCA
274
275 dnl libraries needed on some platforms but not on others
276 dnl ====================================================
277 saved_LIBS=$LIBS
278
279 dnl FreeBSD and Mac OS X have dlopen integrated in libc, Linux needs libdl
280 LIBS=""
281 AC_SEARCH_LIBS(dlopen, dl, [DLLIB=$LIBS])
282 AC_SUBST(DLLIB)
283
284 dnl glibc's backtrace() can be replicated on FreeBSD with libexecinfo
285 LIBS=""
286 AC_SEARCH_LIBS(backtrace, execinfo, [BTLIB=$LIBS])
287 AC_CHECK_FUNCS(backtrace)
288 AC_SUBST(BTLIB)
289
290 dnl OpenSolaris needs libsocket and libnsl for socket()
291 LIBS=""
292 AC_SEARCH_LIBS(socket, socket, [SOCKLIB=$LIBS],
293         [AC_CHECK_LIB(nsl, socket, [SOCKLIB="-lsocket -lnsl"], [], [-lsocket])]
294 )
295 AC_SUBST(SOCKLIB)
296
297 dnl FreeBSD has clock_gettime in libc, Linux needs librt
298 LIBS=""
299 AC_SEARCH_LIBS(clock_gettime, rt, [RTLIB=$LIBS])
300 AC_CHECK_FUNCS(clock_gettime)
301 AC_SUBST(RTLIB)
302
303 dnl Android has pthread_* functions in bionic (libc), others need libpthread
304 LIBS=""
305 AC_SEARCH_LIBS(pthread_create, pthread, [PTHREADLIB=$LIBS])
306 AC_SUBST(PTHREADLIB)
307
308 LIBS=$saved_LIBS
309 dnl ======================
310
311 AC_MSG_CHECKING(for dladdr)
312 AC_TRY_COMPILE(
313         [#define _GNU_SOURCE
314          #include <dlfcn.h>],
315         [Dl_info* info = 0;
316          dladdr(0, info);],
317         [AC_MSG_RESULT([yes]); AC_DEFINE([HAVE_DLADDR])],
318         [AC_MSG_RESULT([no])]
319 )
320
321 dnl check if pthread_condattr_setclock(CLOCK_MONOTONE) is supported
322 saved_LIBS=$LIBS
323 LIBS=$PTHREADLIB
324 AC_MSG_CHECKING([for pthread_condattr_setclock(CLOCK_MONOTONE)])
325 AC_TRY_RUN(
326         [#include <pthread.h>
327          int main() { pthread_condattr_t attr;
328                 pthread_condattr_init(&attr);
329                 return pthread_condattr_setclock(&attr, CLOCK_MONOTONIC);}],
330         [AC_MSG_RESULT([yes]); AC_DEFINE([HAVE_CONDATTR_CLOCK_MONOTONIC])],
331         [AC_MSG_RESULT([no])],
332         dnl Check existence of pthread_condattr_setclock if cross-compiling
333         [AC_MSG_RESULT([unknown]);
334          AC_CHECK_FUNCS(pthread_condattr_setclock,
335                 [AC_DEFINE([HAVE_CONDATTR_CLOCK_MONOTONIC])]
336         )]
337 )
338 dnl check if we actually are able to configure attributes on cond vars
339 AC_CHECK_FUNCS(pthread_condattr_init)
340 dnl instead of pthread_condattr_setclock Android has this function
341 AC_CHECK_FUNCS(pthread_cond_timedwait_monotonic)
342 dnl check if we can cancel threads
343 AC_CHECK_FUNCS(pthread_cancel)
344 dnl check if native rwlocks are available
345 AC_CHECK_FUNCS(pthread_rwlock_init)
346 LIBS=$saved_LIBS
347
348 AC_CHECK_FUNCS(prctl)
349
350 AC_CHECK_FUNCS(mallinfo)
351
352 AC_CHECK_HEADERS(sys/sockio.h)
353 AC_CHECK_HEADERS(net/pfkeyv2.h netipsec/ipsec.h netinet6/ipsec.h linux/udp.h)
354
355 AC_CHECK_MEMBERS([struct sockaddr.sa_len], [], [],
356 [
357         #include <sys/types.h>
358         #include <sys/socket.h>
359 ])
360
361 AC_CHECK_MEMBERS([struct sadb_x_policy.sadb_x_policy_priority], [], [],
362 [
363         #include <sys/types.h>
364         #ifdef HAVE_NET_PFKEYV2_H
365         #include <net/pfkeyv2.h>
366         #else
367         #include <stdint.h>
368         #include <linux/pfkeyv2.h>
369         #endif
370 ])
371
372 AC_MSG_CHECKING([for in6addr_any])
373 AC_TRY_COMPILE(
374         [#include <sys/types.h>
375         #include <sys/socket.h>
376         #include <netinet/in.h>],
377         [struct in6_addr in6;
378         in6 = in6addr_any;],
379         [AC_MSG_RESULT([yes]); AC_DEFINE([HAVE_IN6ADDR_ANY])],
380         [AC_MSG_RESULT([no])]
381 )
382
383 AC_MSG_CHECKING([for in6_pktinfo])
384 AC_TRY_COMPILE(
385         [#define _GNU_SOURCE
386         #include <sys/types.h>
387         #include <sys/socket.h>
388         #include <netinet/in.h>],
389         [struct in6_pktinfo pi;
390         if (pi.ipi6_ifindex)
391         {
392                 return 0;
393         }],
394         [AC_MSG_RESULT([yes]); AC_DEFINE([HAVE_IN6_PKTINFO])],
395         [AC_MSG_RESULT([no])]
396 )
397
398 AC_MSG_CHECKING([for IPSEC_MODE_BEET])
399 AC_TRY_COMPILE(
400         [#include <sys/types.h>
401         #ifdef HAVE_NETIPSEC_IPSEC_H
402         #include <netipsec/ipsec.h>
403         #elif defined(HAVE_NETINET6_IPSEC_H)
404         #include <netinet6/ipsec.h>
405         #else
406         #include <stdint.h>
407         #include <linux/ipsec.h>
408         #endif],
409         [int mode = IPSEC_MODE_BEET;
410          return mode;],
411         [AC_MSG_RESULT([yes]); AC_DEFINE([HAVE_IPSEC_MODE_BEET])],
412         [AC_MSG_RESULT([no])]
413 )
414
415 AC_MSG_CHECKING([for IPSEC_DIR_FWD])
416 AC_TRY_COMPILE(
417         [#include <sys/types.h>
418         #ifdef HAVE_NETIPSEC_IPSEC_H
419         #include <netipsec/ipsec.h>
420         #elif defined(HAVE_NETINET6_IPSEC_H)
421         #include <netinet6/ipsec.h>
422         #else
423         #include <stdint.h>
424         #include <linux/ipsec.h>
425         #endif],
426         [int dir = IPSEC_DIR_FWD;
427          return dir;],
428         [AC_MSG_RESULT([yes]); AC_DEFINE([HAVE_IPSEC_DIR_FWD])],
429         [AC_MSG_RESULT([no])]
430 )
431
432 AC_MSG_CHECKING([for gcc atomic operations])
433 AC_TRY_RUN(
434 [
435         int main() {
436                 volatile int ref = 1;
437                 __sync_fetch_and_add (&ref, 1);
438                 __sync_sub_and_fetch (&ref, 1);
439                 /* Make sure test fails if operations are not supported */
440                 __sync_val_compare_and_swap(&ref, 1, 0);
441                 return ref;
442         }
443 ],
444 [AC_MSG_RESULT([yes]); AC_DEFINE(HAVE_GCC_ATOMIC_OPERATIONS)],
445 [AC_MSG_RESULT([no])],
446 [AC_MSG_RESULT([no])])
447
448 dnl check for the new register_printf_specifier function with len argument,
449 dnl or the deprecated register_printf_function without
450 AC_CHECK_FUNC(
451         [register_printf_specifier],
452         [AC_DEFINE(HAVE_PRINTF_SPECIFIER)],
453         [AC_CHECK_FUNC(
454                 [register_printf_function],
455                 [AC_DEFINE(HAVE_PRINTF_FUNCTION)],
456                 [
457                         AC_MSG_NOTICE([printf does not support custom format specifiers!])
458                         vstr=true
459                 ]
460         )]
461 )
462
463 if test x$vstr = xtrue; then
464         AC_HAVE_LIBRARY([vstr],[LIBS="$LIBS"],[AC_MSG_ERROR([Vstr string library not found])])
465         AC_DEFINE(USE_VSTR)
466 fi
467
468 if test x$gmp = xtrue; then
469         saved_LIBS=$LIBS
470         AC_HAVE_LIBRARY([gmp],,[AC_MSG_ERROR([GNU Multi Precision library gmp not found])])
471         AC_MSG_CHECKING([mpz_powm_sec])
472         if test x$mpz_powm_sec = xyes; then
473                 AC_TRY_COMPILE(
474                         [#include "gmp.h"],
475                         [
476                                 void *x = mpz_powm_sec;
477                         ],
478                         [AC_MSG_RESULT([yes]); AC_DEFINE(HAVE_MPZ_POWM_SEC)], [AC_MSG_RESULT([no])]
479                 )
480         else
481                 AC_MSG_RESULT([disabled])
482         fi
483         LIBS=$saved_LIBS
484         AC_MSG_CHECKING([gmp.h version >= 4.1.4])
485         AC_TRY_COMPILE(
486                 [#include "gmp.h"],
487                 [
488                         #if (__GNU_MP_VERSION*100 +  __GNU_MP_VERSION_MINOR*10 + __GNU_MP_VERSION_PATCHLEVEL) < 414
489                                 #error bad gmp
490                         #endif
491                 ],
492                 [AC_MSG_RESULT([yes])], [AC_MSG_RESULT([no]); AC_MSG_ERROR([No usable gmp.h found!])]
493         )
494 fi
495
496 if test x$ldap = xtrue; then
497         AC_HAVE_LIBRARY([ldap],[LIBS="$LIBS"],[AC_MSG_ERROR([LDAP library ldap not found])])
498         AC_HAVE_LIBRARY([lber],[LIBS="$LIBS"],[AC_MSG_ERROR([LDAP library lber not found])])
499         AC_CHECK_HEADER([ldap.h],,[AC_MSG_ERROR([LDAP header ldap.h not found!])])
500 fi
501
502 if test x$curl = xtrue; then
503         AC_HAVE_LIBRARY([curl],[LIBS="$LIBS"],[AC_MSG_ERROR([CURL library curl not found])])
504         AC_CHECK_HEADER([curl/curl.h],,[AC_MSG_ERROR([CURL header curl/curl.h not found!])])
505 fi
506
507 if test x$xml = xtrue; then
508         PKG_CHECK_MODULES(xml, [libxml-2.0])
509         AC_SUBST(xml_CFLAGS)
510         AC_SUBST(xml_LIBS)
511 fi
512
513 if test x$dumm = xtrue; then
514         PKG_CHECK_MODULES(gtk, [gtk+-2.0 vte])
515         AC_SUBST(gtk_CFLAGS)
516         AC_SUBST(gtk_LIBS)
517         AC_CHECK_PROGS(RUBY, ruby)
518         AC_MSG_CHECKING([for Ruby header files])
519         if test -n "$RUBY"; then
520                 RUBYDIR=`($RUBY -rmkmf -e 'print Config::CONFIG[["archdir"]] || $archdir') 2>/dev/null`
521                 if test -n "$RUBYDIR"; then
522                         dirs="$RUBYDIR"
523                         RUBYINCLUDE=none
524                         for i in $dirs; do
525                                 if test -r $i/ruby.h; then
526                                         AC_MSG_RESULT([$i])
527                                         RUBYINCLUDE="-I$i"
528                                         break;
529                                 fi
530                         done
531                         if test x"$RUBYINCLUDE" = xnone; then
532                                 AC_MSG_ERROR([ruby.h not found])
533                         fi
534                         AC_SUBST(RUBYINCLUDE)
535                 else
536                         AC_MSG_ERROR([unable to determine ruby configuration])
537                 fi
538         else
539                 AC_MSG_ERROR([don't know how to run ruby])
540         fi
541 fi
542
543 if test x$fast = xtrue; then
544         AC_HAVE_LIBRARY([neo_cgi],[LIBS="$LIBS"],[AC_MSG_ERROR([ClearSilver library neo_cgi not found!])])
545         AC_HAVE_LIBRARY([neo_utl],[LIBS="$LIBS"],[AC_MSG_ERROR([ClearSilver library neo_utl not found!])])
546         AC_HAVE_LIBRARY([z],[LIBS="$LIBS"],[AC_MSG_ERROR([ClearSilver dependency zlib not found!])])
547 dnl autoconf does not like CamelCase!? How to fix this?
548 dnl     AC_CHECK_HEADER([ClearSilver/ClearSilver.h],,[AC_MSG_ERROR([ClearSilver header file ClearSilver/ClearSilver.h not found!])])
549
550         AC_HAVE_LIBRARY([fcgi],[LIBS="$LIBS"],[AC_MSG_ERROR([FastCGI library fcgi not found!])])
551         AC_CHECK_HEADER([fcgiapp.h],,[AC_MSG_ERROR([FastCGI header file fcgiapp.h not found!])])
552 fi
553
554 if test x$mysql = xtrue; then
555         AC_PATH_PROG([MYSQLCONFIG], [mysql_config], [], [$PATH:/bin:/usr/bin:/usr/local/bin])
556         if test x$MYSQLCONFIG = x; then
557                 AC_MSG_ERROR([mysql_config not found!])
558         fi
559         AC_SUBST(MYSQLLIB, `$MYSQLCONFIG --libs_r`)
560         AC_SUBST(MYSQLCFLAG, `$MYSQLCONFIG --cflags`)
561 fi
562
563 if test x$sqlite = xtrue; then
564         AC_HAVE_LIBRARY([sqlite3],[LIBS="$LIBS"],[AC_MSG_ERROR([SQLite library sqlite3 not found])])
565         AC_CHECK_HEADER([sqlite3.h],,[AC_MSG_ERROR([SQLite header sqlite3.h not found!])])
566         AC_MSG_CHECKING([sqlite3_prepare_v2])
567         AC_TRY_COMPILE(
568                 [#include <sqlite3.h>],
569                 [
570                         void *test = sqlite3_prepare_v2;
571                 ],
572                 [AC_MSG_RESULT([yes])]; AC_DEFINE_UNQUOTED(HAVE_SQLITE3_PREPARE_V2, 1), [AC_MSG_RESULT([no])])
573         AC_MSG_CHECKING([sqlite3.h version >= 3.3.1])
574         AC_TRY_COMPILE(
575                 [#include <sqlite3.h>],
576                 [
577                         #if SQLITE_VERSION_NUMBER < 3003001
578                                 #error bad sqlite
579                         #endif
580                 ],
581                 [AC_MSG_RESULT([yes])], [AC_MSG_RESULT([no]); AC_MSG_ERROR([SQLite version >= 3.3.1 required!])])
582 fi
583
584 if test x$openssl = xtrue; then
585         AC_HAVE_LIBRARY([crypto],[LIBS="$LIBS"],[AC_MSG_ERROR([OpenSSL crypto library not found])])
586         AC_CHECK_HEADER([openssl/evp.h],,[AC_MSG_ERROR([OpenSSL header openssl/evp.h not found!])])
587 fi
588
589 if test x$gcrypt = xtrue; then
590         AC_HAVE_LIBRARY([gcrypt],[LIBS="$LIBS"],[AC_MSG_ERROR([gcrypt library not found])],[-lgpg-error])
591         AC_CHECK_HEADER([gcrypt.h],,[AC_MSG_ERROR([gcrypt header gcrypt.h not found!])])
592         AC_MSG_CHECKING([gcrypt CAMELLIA cipher])
593         AC_TRY_COMPILE(
594                 [#include <gcrypt.h>],
595                 [enum gcry_cipher_algos alg = GCRY_CIPHER_CAMELLIA128;],
596                 [AC_MSG_RESULT([yes]); AC_DEFINE([HAVE_GCRY_CIPHER_CAMELLIA])],
597                 [AC_MSG_RESULT([no])]
598         )
599 fi
600
601 if test x$uci = xtrue; then
602         AC_HAVE_LIBRARY([uci],[LIBS="$LIBS"],[AC_MSG_ERROR([UCI library libuci not found])])
603         AC_CHECK_HEADER([uci.h],,[AC_MSG_ERROR([UCI header uci.h not found!])])
604 fi
605
606 if test x$android = xtrue; then
607         AC_HAVE_LIBRARY([cutils],[LIBS="$LIBS"],[AC_MSG_ERROR([Android library libcutils not found])])
608         AC_CHECK_HEADER([cutils/properties.h],,[AC_MSG_ERROR([Android header cutils/properties.h not found!])])
609         dnl we have to force the use of libdl here because the autodetection
610         dnl above does not work correctly when cross-compiling for android.
611         DLLIB="-ldl"
612         AC_SUBST(DLLIB)
613 fi
614
615 if test x$nm = xtrue; then
616         PKG_CHECK_EXISTS([libnm-glib],
617                 [PKG_CHECK_MODULES(nm, [NetworkManager gthread-2.0 libnm-glib libnm-glib-vpn])],
618                 [PKG_CHECK_MODULES(nm, [NetworkManager gthread-2.0 libnm_glib libnm_glib_vpn])]
619         )
620         AC_SUBST(nm_CFLAGS)
621         AC_SUBST(nm_LIBS)
622 fi
623
624 if test x$eap_gtc = xtrue; then
625         AC_HAVE_LIBRARY([pam],[LIBS="$LIBS"],[AC_MSG_ERROR([PAM library not found])])
626         AC_CHECK_HEADER([security/pam_appl.h],,[AC_MSG_ERROR([PAM header security/pam_appl.h not found!])])
627 fi
628
629 if test x$capabilities = xnative; then
630         AC_MSG_NOTICE([Usage of the native Linux capabilities interface is deprecated, use libcap instead])
631         dnl Linux requires the following for capset(), Android does not have it,
632         dnl but defines capset() in unistd.h instead.
633         AC_CHECK_HEADERS([sys/capability.h])
634         AC_CHECK_FUNC(capset,,[AC_MSG_ERROR([capset() not found!])])
635         AC_DEFINE(CAPABILITIES_NATIVE)
636 fi
637
638 if test x$capabilities = xlibcap; then
639         AC_HAVE_LIBRARY([cap],[LIBS="$LIBS"],[AC_MSG_ERROR([libcap library not found])])
640         AC_CHECK_HEADER([sys/capability.h],
641                 [AC_DEFINE(HAVE_SYS_CAPABILITY_H)],
642                 [AC_MSG_ERROR([libcap header sys/capability.h not found!])])
643         AC_DEFINE(CAPABILITIES_LIBCAP)
644 fi
645
646 if test x$integrity_test = xtrue; then
647         AC_MSG_CHECKING([for dladdr()])
648         AC_TRY_COMPILE(
649                 [#define _GNU_SOURCE
650                  #include <dlfcn.h>],
651                 [Dl_info info; dladdr(main, &info);],
652                 [AC_MSG_RESULT([yes])], [AC_MSG_RESULT([no]);
653                  AC_MSG_ERROR([dladdr() not supported, required by integrity-test!])]
654         )
655         AC_MSG_CHECKING([for dl_iterate_phdr()])
656         AC_TRY_COMPILE(
657                 [#define _GNU_SOURCE
658                  #include <link.h>],
659                 [dl_iterate_phdr((void*)0, (void*)0);],
660                 [AC_MSG_RESULT([yes])], [AC_MSG_RESULT([no]);
661                  AC_MSG_ERROR([dl_iterate_phdr() not supported, required by integrity-test!])]
662         )
663 fi
664
665 dnl ==============================================
666 dnl  collect plugin list for strongSwan components
667 dnl ==============================================
668
669 m4_include(m4/macros/add-plugin.m4)
670
671 # plugin lists for all components
672 libcharon_plugins=
673 pluto_plugins=
674 pool_plugins=
675 openac_plugins=
676 scepclient_plugins=
677 pki_plugins=
678 scripts_plugins=
679 manager_plugins=
680 medsrv_plugins=
681
682 # location specific lists for checksumming,
683 # for src/libcharon, src/pluto, src/libhydra and src/libstrongswan
684 c_plugins=
685 p_plugins=
686 h_plugins=
687 s_plugins=
688
689 ADD_PLUGIN([test-vectors],         [s libcharon pluto openac scepclient pki])
690 ADD_PLUGIN([curl],                 [s libcharon pluto scepclient])
691 ADD_PLUGIN([ldap],                 [s libcharon pluto scepclient])
692 ADD_PLUGIN([mysql],                [s libcharon pluto pool manager medsrv])
693 ADD_PLUGIN([sqlite],               [s libcharon pluto pool manager medsrv])
694 ADD_PLUGIN([aes],                  [s libcharon pluto openac scepclient pki scripts])
695 ADD_PLUGIN([des],                  [s libcharon pluto openac scepclient pki scripts])
696 ADD_PLUGIN([blowfish],             [s libcharon pluto openac scepclient pki scripts])
697 ADD_PLUGIN([sha1],                 [s libcharon pluto openac scepclient pki scripts medsrv])
698 ADD_PLUGIN([sha2],                 [s libcharon pluto openac scepclient pki scripts medsrv])
699 ADD_PLUGIN([md4],                  [s libcharon openac manager scepclient pki])
700 ADD_PLUGIN([md5],                  [s libcharon pluto openac scepclient pki])
701 ADD_PLUGIN([random],               [s libcharon pluto openac scepclient pki medsrv])
702 ADD_PLUGIN([x509],                 [s libcharon pluto openac scepclient pki])
703 ADD_PLUGIN([revocation],           [s libcharon])
704 ADD_PLUGIN([pubkey],               [s libcharon])
705 ADD_PLUGIN([pkcs1],                [s libcharon pluto openac scepclient pki scripts manager medsrv])
706 ADD_PLUGIN([pgp],                  [s libcharon pluto])
707 ADD_PLUGIN([dnskey],               [s pluto])
708 ADD_PLUGIN([pem],                  [s libcharon pluto openac scepclient pki scripts manager medsrv])
709 ADD_PLUGIN([padlock],              [s libcharon])
710 ADD_PLUGIN([openssl],              [s libcharon pluto openac scepclient pki scripts manager medsrv])
711 ADD_PLUGIN([gcrypt],               [s libcharon pluto openac scepclient pki scripts manager medsrv])
712 ADD_PLUGIN([fips-prf],             [s libcharon])
713 ADD_PLUGIN([gmp],                  [s libcharon pluto openac scepclient pki scripts manager medsrv])
714 ADD_PLUGIN([agent],                [s libcharon])
715 ADD_PLUGIN([pkcs11],               [s libcharon pki])
716 ADD_PLUGIN([xcbc],                 [s libcharon])
717 ADD_PLUGIN([hmac],                 [s libcharon pluto])
718 ADD_PLUGIN([ctr],                  [s libcharon])
719 ADD_PLUGIN([xauth],                [p pluto])
720 ADD_PLUGIN([attr],                 [h libcharon pluto])
721 ADD_PLUGIN([attr-sql],             [h libcharon pluto])
722 ADD_PLUGIN([resolve],              [h libcharon pluto])
723 ADD_PLUGIN([load-tester],          [c libcharon])
724 ADD_PLUGIN([kernel-pfkey],         [c libcharon])
725 ADD_PLUGIN([kernel-pfroute],       [c libcharon])
726 ADD_PLUGIN([kernel-klips],         [c libcharon])
727 ADD_PLUGIN([kernel-netlink],       [c libcharon])
728 ADD_PLUGIN([socket-default],       [c libcharon])
729 ADD_PLUGIN([socket-raw],           [c libcharon])
730 ADD_PLUGIN([socket-dynamic],       [c libcharon])
731 ADD_PLUGIN([farp],                 [c libcharon])
732 ADD_PLUGIN([stroke],               [c libcharon])
733 ADD_PLUGIN([smp],                  [c libcharon])
734 ADD_PLUGIN([sql],                  [c libcharon])
735 ADD_PLUGIN([updown],               [c libcharon])
736 ADD_PLUGIN([eap-identity],         [c libcharon])
737 ADD_PLUGIN([eap-sim],              [c libcharon])
738 ADD_PLUGIN([eap-sim-file],         [c libcharon])
739 ADD_PLUGIN([eap-simaka-sql],       [c libcharon])
740 ADD_PLUGIN([eap-simaka-pseudonym], [c libcharon])
741 ADD_PLUGIN([eap-simaka-reauth],    [c libcharon])
742 ADD_PLUGIN([eap-aka],              [c libcharon])
743 ADD_PLUGIN([eap-aka-3gpp2],        [c libcharon])
744 ADD_PLUGIN([eap-md5],              [c libcharon])
745 ADD_PLUGIN([eap-gtc],              [c libcharon])
746 ADD_PLUGIN([eap-mschapv2],         [c libcharon])
747 ADD_PLUGIN([eap-radius],           [c libcharon])
748 ADD_PLUGIN([eap-tls],              [c libcharon])
749 ADD_PLUGIN([eap-ttls],             [c libcharon])
750 ADD_PLUGIN([medsrv],               [c libcharon])
751 ADD_PLUGIN([medcli],               [c libcharon])
752 ADD_PLUGIN([nm],                   [c libcharon])
753 ADD_PLUGIN([dhcp],                 [c libcharon])
754 ADD_PLUGIN([android],              [c libcharon])
755 ADD_PLUGIN([ha],                   [c libcharon])
756 ADD_PLUGIN([uci],                  [c libcharon])
757 ADD_PLUGIN([addrblock],            [c libcharon])
758 ADD_PLUGIN([unit-tester],          [c libcharon])
759
760 AC_SUBST(libcharon_plugins)
761 AC_SUBST(pluto_plugins)
762 AC_SUBST(pool_plugins)
763 AC_SUBST(openac_plugins)
764 AC_SUBST(scepclient_plugins)
765 AC_SUBST(pki_plugins)
766 AC_SUBST(scripts_plugins)
767 AC_SUBST(manager_plugins)
768 AC_SUBST(medsrv_plugins)
769
770 AC_SUBST(c_plugins)
771 AC_SUBST(p_plugins)
772 AC_SUBST(h_plugins)
773 AC_SUBST(s_plugins)
774
775 dnl =========================
776 dnl  set Makefile.am vars
777 dnl =========================
778
779 dnl libstrongswan plugins
780 dnl =====================
781 AM_CONDITIONAL(USE_TEST_VECTORS, test x$test_vectors = xtrue)
782 AM_CONDITIONAL(USE_CURL, test x$curl = xtrue)
783 AM_CONDITIONAL(USE_LDAP, test x$ldap = xtrue)
784 AM_CONDITIONAL(USE_AES, test x$aes = xtrue)
785 AM_CONDITIONAL(USE_DES, test x$des = xtrue)
786 AM_CONDITIONAL(USE_BLOWFISH, test x$blowfish = xtrue)
787 AM_CONDITIONAL(USE_MD4, test x$md4 = xtrue)
788 AM_CONDITIONAL(USE_MD5, test x$md5 = xtrue)
789 AM_CONDITIONAL(USE_SHA1, test x$sha1 = xtrue)
790 AM_CONDITIONAL(USE_SHA2, test x$sha2 = xtrue)
791 AM_CONDITIONAL(USE_FIPS_PRF, test x$fips_prf = xtrue)
792 AM_CONDITIONAL(USE_GMP, test x$gmp = xtrue)
793 AM_CONDITIONAL(USE_RANDOM, test x$random = xtrue)
794 AM_CONDITIONAL(USE_X509, test x$x509 = xtrue)
795 AM_CONDITIONAL(USE_REVOCATION, test x$revocation = xtrue)
796 AM_CONDITIONAL(USE_PUBKEY, test x$pubkey = xtrue)
797 AM_CONDITIONAL(USE_PKCS1, test x$pkcs1 = xtrue)
798 AM_CONDITIONAL(USE_PGP, test x$pgp = xtrue)
799 AM_CONDITIONAL(USE_DNSKEY, test x$dnskey = xtrue)
800 AM_CONDITIONAL(USE_PEM, test x$pem = xtrue)
801 AM_CONDITIONAL(USE_HMAC, test x$hmac = xtrue)
802 AM_CONDITIONAL(USE_XCBC, test x$xcbc = xtrue)
803 AM_CONDITIONAL(USE_MYSQL, test x$mysql = xtrue)
804 AM_CONDITIONAL(USE_SQLITE, test x$sqlite = xtrue)
805 AM_CONDITIONAL(USE_PADLOCK, test x$padlock = xtrue)
806 AM_CONDITIONAL(USE_OPENSSL, test x$openssl = xtrue)
807 AM_CONDITIONAL(USE_GCRYPT, test x$gcrypt = xtrue)
808 AM_CONDITIONAL(USE_AGENT, test x$agent = xtrue)
809 AM_CONDITIONAL(USE_PKCS11, test x$pkcs11 = xtrue)
810 AM_CONDITIONAL(USE_CTR, test x$ctr = xtrue)
811
812 dnl charon plugins
813 dnl ==============
814 AM_CONDITIONAL(USE_STROKE, test x$stroke = xtrue)
815 AM_CONDITIONAL(USE_MEDSRV, test x$medsrv = xtrue)
816 AM_CONDITIONAL(USE_MEDCLI, test x$medcli = xtrue)
817 AM_CONDITIONAL(USE_NM, test x$nm = xtrue)
818 AM_CONDITIONAL(USE_UCI, test x$uci = xtrue)
819 AM_CONDITIONAL(USE_ANDROID, test x$android = xtrue)
820 AM_CONDITIONAL(USE_SMP, test x$smp = xtrue)
821 AM_CONDITIONAL(USE_SQL, test x$sql = xtrue)
822 AM_CONDITIONAL(USE_UPDOWN, test x$updown = xtrue)
823 AM_CONDITIONAL(USE_DHCP, test x$dhcp = xtrue)
824 AM_CONDITIONAL(USE_UNIT_TESTS, test x$unit_tests = xtrue)
825 AM_CONDITIONAL(USE_LOAD_TESTER, test x$load_tester = xtrue)
826 AM_CONDITIONAL(USE_HA, test x$ha = xtrue)
827 AM_CONDITIONAL(USE_EAP_SIM, test x$eap_sim = xtrue)
828 AM_CONDITIONAL(USE_EAP_SIM_FILE, test x$eap_sim_file = xtrue)
829 AM_CONDITIONAL(USE_EAP_SIMAKA_SQL, test x$eap_simaka_sql = xtrue)
830 AM_CONDITIONAL(USE_EAP_SIMAKA_PSEUDONYM, test x$eap_simaka_pseudonym = xtrue)
831 AM_CONDITIONAL(USE_EAP_SIMAKA_REAUTH, test x$eap_simaka_reauth = xtrue)
832 AM_CONDITIONAL(USE_EAP_IDENTITY, test x$eap_identity = xtrue)
833 AM_CONDITIONAL(USE_EAP_MD5, test x$eap_md5 = xtrue)
834 AM_CONDITIONAL(USE_EAP_GTC, test x$eap_gtc = xtrue)
835 AM_CONDITIONAL(USE_EAP_AKA, test x$eap_aka = xtrue)
836 AM_CONDITIONAL(USE_EAP_AKA_3GPP2, test x$eap_aka_3gpp2 = xtrue)
837 AM_CONDITIONAL(USE_EAP_MSCHAPV2, test x$eap_mschapv2 = xtrue)
838 AM_CONDITIONAL(USE_EAP_TLS, test x$eap_tls = xtrue)
839 AM_CONDITIONAL(USE_EAP_TTLS, test x$eap_ttls = xtrue)
840 AM_CONDITIONAL(USE_EAP_RADIUS, test x$eap_radius = xtrue)
841 AM_CONDITIONAL(USE_KERNEL_NETLINK, test x$kernel_netlink = xtrue)
842 AM_CONDITIONAL(USE_KERNEL_PFKEY, test x$kernel_pfkey = xtrue)
843 AM_CONDITIONAL(USE_KERNEL_PFROUTE, test x$kernel_pfroute = xtrue)
844 AM_CONDITIONAL(USE_KERNEL_KLIPS, test x$kernel_klips = xtrue)
845 AM_CONDITIONAL(USE_SOCKET_DEFAULT, test x$socket_default = xtrue)
846 AM_CONDITIONAL(USE_SOCKET_RAW, test x$socket_raw = xtrue)
847 AM_CONDITIONAL(USE_SOCKET_DYNAMIC, test x$socket_dynamic = xtrue)
848 AM_CONDITIONAL(USE_FARP, test x$farp = xtrue)
849 AM_CONDITIONAL(USE_ADDRBLOCK, test x$addrblock = xtrue)
850
851 dnl hydra plugins
852 dnl =============
853 AM_CONDITIONAL(USE_ATTR, test x$attr = xtrue)
854 AM_CONDITIONAL(USE_ATTR_SQL, test x$attr_sql = xtrue -o x$sql = xtrue)
855 AM_CONDITIONAL(USE_RESOLVE, test x$resolve = xtrue)
856
857 dnl pluto plugins
858 dnl =============
859 AM_CONDITIONAL(USE_XAUTH, test x$xauth = xtrue)
860
861 dnl other options
862 dnl =============
863 AM_CONDITIONAL(USE_SMARTCARD, test x$smartcard = xtrue)
864 AM_CONDITIONAL(USE_CISCO_QUIRKS, test x$cisco_quirks = xtrue)
865 AM_CONDITIONAL(USE_LEAK_DETECTIVE, test x$leak_detective = xtrue)
866 AM_CONDITIONAL(USE_LOCK_PROFILER, test x$lock_profiler = xtrue)
867 AM_CONDITIONAL(USE_NAT_TRANSPORT, test x$nat_transport = xtrue)
868 AM_CONDITIONAL(USE_VENDORID, test x$vendor_id = xtrue)
869 AM_CONDITIONAL(USE_XAUTH_VID, test x$xauth_vid = xtrue)
870 AM_CONDITIONAL(USE_DUMM, test x$dumm = xtrue)
871 AM_CONDITIONAL(USE_FAST, test x$fast = xtrue)
872 AM_CONDITIONAL(USE_MANAGER, test x$manager = xtrue)
873 AM_CONDITIONAL(USE_ME, test x$mediation = xtrue)
874 AM_CONDITIONAL(USE_INTEGRITY_TEST, test x$integrity_test = xtrue)
875 AM_CONDITIONAL(USE_LOAD_WARNING, test x$load_warning = xtrue)
876 AM_CONDITIONAL(USE_PLUTO, test x$pluto = xtrue)
877 AM_CONDITIONAL(USE_THREADS, test x$threads = xtrue)
878 AM_CONDITIONAL(USE_CHARON, test x$charon = xtrue)
879 AM_CONDITIONAL(USE_TOOLS, test x$tools = xtrue)
880 AM_CONDITIONAL(USE_SCRIPTS, test x$scripts = xtrue)
881 AM_CONDITIONAL(USE_LIBSTRONGSWAN, test x$charon = xtrue -o x$pluto = xtrue -o x$tools = xtrue)
882 AM_CONDITIONAL(USE_LIBHYDRA, test x$charon = xtrue -o x$pluto = xtrue)
883 AM_CONDITIONAL(USE_FILE_CONFIG, test x$pluto = xtrue -o x$stroke = xtrue)
884 AM_CONDITIONAL(USE_LIBCAP, test x$capabilities = xlibcap)
885 AM_CONDITIONAL(USE_VSTR, test x$vstr = xtrue)
886 AM_CONDITIONAL(USE_SIMAKA, test x$simaka = xtrue)
887 AM_CONDITIONAL(USE_TLS, test x$tls = xtrue)
888 AM_CONDITIONAL(MONOLITHIC, test x$monolithic = xtrue)
889
890 dnl ==============================
891 dnl  set global definitions
892 dnl ==============================
893
894 if test x$mediation = xtrue; then
895         AC_DEFINE(ME)
896 fi
897 if test x$capabilities = xlibcap -o x$capabilities = xnative; then
898         AC_DEFINE(CAPABILITIES)
899 fi
900 if test x$monolithic = xtrue; then
901         AC_DEFINE(MONOLITHIC)
902 fi
903
904
905 dnl ==============================
906 dnl  build Makefiles
907 dnl ==============================
908
909 AC_OUTPUT(
910         Makefile
911         src/Makefile
912         src/include/Makefile
913         src/libstrongswan/Makefile
914         src/libstrongswan/plugins/aes/Makefile
915         src/libstrongswan/plugins/des/Makefile
916         src/libstrongswan/plugins/blowfish/Makefile
917         src/libstrongswan/plugins/md4/Makefile
918         src/libstrongswan/plugins/md5/Makefile
919         src/libstrongswan/plugins/sha1/Makefile
920         src/libstrongswan/plugins/sha2/Makefile
921         src/libstrongswan/plugins/fips_prf/Makefile
922         src/libstrongswan/plugins/gmp/Makefile
923         src/libstrongswan/plugins/random/Makefile
924         src/libstrongswan/plugins/hmac/Makefile
925         src/libstrongswan/plugins/xcbc/Makefile
926         src/libstrongswan/plugins/x509/Makefile
927         src/libstrongswan/plugins/revocation/Makefile
928         src/libstrongswan/plugins/pubkey/Makefile
929         src/libstrongswan/plugins/pkcs1/Makefile
930         src/libstrongswan/plugins/pgp/Makefile
931         src/libstrongswan/plugins/dnskey/Makefile
932         src/libstrongswan/plugins/pem/Makefile
933         src/libstrongswan/plugins/curl/Makefile
934         src/libstrongswan/plugins/ldap/Makefile
935         src/libstrongswan/plugins/mysql/Makefile
936         src/libstrongswan/plugins/sqlite/Makefile
937         src/libstrongswan/plugins/padlock/Makefile
938         src/libstrongswan/plugins/openssl/Makefile
939         src/libstrongswan/plugins/gcrypt/Makefile
940         src/libstrongswan/plugins/agent/Makefile
941         src/libstrongswan/plugins/pkcs11/Makefile
942         src/libstrongswan/plugins/ctr/Makefile
943         src/libstrongswan/plugins/test_vectors/Makefile
944         src/libhydra/Makefile
945         src/libhydra/plugins/attr/Makefile
946         src/libhydra/plugins/attr_sql/Makefile
947         src/libhydra/plugins/resolve/Makefile
948         src/libfreeswan/Makefile
949         src/libsimaka/Makefile
950         src/libtls/Makefile
951         src/pluto/Makefile
952         src/pluto/plugins/xauth/Makefile
953         src/whack/Makefile
954         src/charon/Makefile
955         src/libcharon/Makefile
956         src/libcharon/plugins/eap_aka/Makefile
957         src/libcharon/plugins/eap_aka_3gpp2/Makefile
958         src/libcharon/plugins/eap_identity/Makefile
959         src/libcharon/plugins/eap_md5/Makefile
960         src/libcharon/plugins/eap_gtc/Makefile
961         src/libcharon/plugins/eap_sim/Makefile
962         src/libcharon/plugins/eap_sim_file/Makefile
963         src/libcharon/plugins/eap_simaka_sql/Makefile
964         src/libcharon/plugins/eap_simaka_pseudonym/Makefile
965         src/libcharon/plugins/eap_simaka_reauth/Makefile
966         src/libcharon/plugins/eap_mschapv2/Makefile
967         src/libcharon/plugins/eap_tls/Makefile
968         src/libcharon/plugins/eap_ttls/Makefile
969         src/libcharon/plugins/eap_radius/Makefile
970         src/libcharon/plugins/kernel_netlink/Makefile
971         src/libcharon/plugins/kernel_pfkey/Makefile
972         src/libcharon/plugins/kernel_pfroute/Makefile
973         src/libcharon/plugins/kernel_klips/Makefile
974         src/libcharon/plugins/socket_default/Makefile
975         src/libcharon/plugins/socket_raw/Makefile
976         src/libcharon/plugins/socket_dynamic/Makefile
977         src/libcharon/plugins/farp/Makefile
978         src/libcharon/plugins/smp/Makefile
979         src/libcharon/plugins/sql/Makefile
980         src/libcharon/plugins/medsrv/Makefile
981         src/libcharon/plugins/medcli/Makefile
982         src/libcharon/plugins/nm/Makefile
983         src/libcharon/plugins/addrblock/Makefile
984         src/libcharon/plugins/uci/Makefile
985         src/libcharon/plugins/ha/Makefile
986         src/libcharon/plugins/android/Makefile
987         src/libcharon/plugins/stroke/Makefile
988         src/libcharon/plugins/updown/Makefile
989         src/libcharon/plugins/dhcp/Makefile
990         src/libcharon/plugins/unit_tester/Makefile
991         src/libcharon/plugins/load_tester/Makefile
992         src/stroke/Makefile
993         src/ipsec/Makefile
994         src/starter/Makefile
995         src/_updown/Makefile
996         src/_updown_espmark/Makefile
997         src/_copyright/Makefile
998         src/openac/Makefile
999         src/scepclient/Makefile
1000         src/pki/Makefile
1001         src/dumm/Makefile
1002         src/dumm/ext/extconf.rb
1003         src/libfast/Makefile
1004         src/manager/Makefile
1005         src/medsrv/Makefile
1006         src/checksum/Makefile
1007         scripts/Makefile
1008         testing/Makefile
1009 )