Moved all kernel plugins to libhydra.
[strongswan.git] / configure.in
1 dnl  configure.in for linux strongSwan
2 dnl  Copyright (C) 2006 Martin Willi
3 dnl  Hochschule fuer Technik Rapperswil
4 dnl
5 dnl  This program is free software; you can redistribute it and/or modify it
6 dnl  under the terms of the GNU General Public License as published by the
7 dnl  Free Software Foundation; either version 2 of the License, or (at your
8 dnl  option) any later version.  See <http://www.fsf.org/copyleft/gpl.txt>.
9 dnl
10 dnl  This program is distributed in the hope that it will be useful, but
11 dnl  WITHOUT ANY WARRANTY; without even the implied warranty of MERCHANTABILITY
12 dnl  or FITNESS FOR A PARTICULAR PURPOSE.  See the GNU General Public License
13 dnl  for more details.
14
15 dnl ===========================
16 dnl  initialize & set some vars
17 dnl ===========================
18
19 AC_INIT(strongSwan,4.4.2dr1)
20 AM_INIT_AUTOMAKE(tar-ustar)
21 AC_CONFIG_MACRO_DIR([m4/config])
22 PKG_PROG_PKG_CONFIG
23
24 dnl =================================
25 dnl  check --enable-xxx & --with-xxx
26 dnl =================================
27
28 m4_include(m4/macros/with.m4)
29
30 ARG_WITH_SUBST([default-pkcs11],     [/usr/lib/opensc-pkcs11.so], [set the default PKCS11 library])
31 ARG_WITH_SUBST([random-device],      [/dev/random], [set the device to read real random data from])
32 ARG_WITH_SUBST([urandom-device],     [/dev/urandom], [set the device to read pseudo random data from])
33 ARG_WITH_SUBST([strongswan-conf],    [${sysconfdir}/strongswan.conf], [set the strongswan.conf file location])
34 ARG_WITH_SUBST([resolv-conf],        [${sysconfdir}/resolv.conf], [set the file to use in DNS handler plugin])
35 ARG_WITH_SUBST([piddir],             [/var/run], [set path for PID and UNIX socket files])
36 ARG_WITH_SUBST([ipsecdir],           [${libexecdir%/}/ipsec], [set installation path for ipsec tools])
37 ARG_WITH_SUBST([plugindir],          [${ipsecdir%/}/plugins], [set the installation path of plugins])
38 ARG_WITH_SUBST([nm-ca-dir],          [/usr/share/ca-certificates], [directory the NM plugin uses to look up trusted root certificates])
39 ARG_WITH_SUBST([linux-headers],      [\${top_srcdir}/src/include], [set directory of linux header files to use])
40 ARG_WITH_SUBST([routing-table],      [220], [set routing table to use for IPsec routes])
41 ARG_WITH_SUBST([routing-table-prio], [220], [set priority for IPsec routing table])
42
43 ARG_WITH_SET([capabilities],         [no], [set capability dropping library. Currently supported values are "libcap" and "native"])
44 ARG_WITH_SET([mpz_powm_sec],         [yes], [use the more side-channel resistant mpz_powm_sec in libgmp, if available])
45
46 AC_ARG_WITH(
47         [xauth-module],
48         AS_HELP_STRING([--with-xauth-module=lib],[set the path to the XAUTH module]),
49         [AC_DEFINE_UNQUOTED(XAUTH_DEFAULT_LIB, "$withval")],
50 )
51
52 AC_ARG_WITH(
53         [user],
54         AS_HELP_STRING([--with-user=user],[change user of the daemons to "user" after startup (default is "root").]),
55         [AC_DEFINE_UNQUOTED(IPSEC_USER, "$withval") AC_SUBST(ipsecuser, "$withval")],
56         [AC_SUBST(ipsecuser, "root")]
57 )
58
59 AC_ARG_WITH(
60         [group],
61         AS_HELP_STRING([--with-group=group],[change group of the daemons to "group" after startup (default is "root").]),
62         [AC_DEFINE_UNQUOTED(IPSEC_GROUP, "$withval") AC_SUBST(ipsecgroup, "$withval")],
63         [AC_SUBST(ipsecgroup, "root")]
64 )
65
66 m4_include(m4/macros/enable-disable.m4)
67
68 ARG_ENABL_SET([curl],           [enable CURL fetcher plugin to fetch files via libcurl. Requires libcurl.])
69 ARG_ENABL_SET([ldap],           [enable LDAP fetching plugin to fetch files via libldap. Requires openLDAP.])
70 ARG_DISBL_SET([aes],            [disable AES software implementation plugin.])
71 ARG_DISBL_SET([des],            [disable DES/3DES software implementation plugin.])
72 ARG_ENABL_SET([blowfish],       [enable Blowfish software implementation plugin.])
73 ARG_ENABL_SET([md4],            [enable MD4 software implementation plugin.])
74 ARG_DISBL_SET([md5],            [disable MD5 software implementation plugin.])
75 ARG_DISBL_SET([sha1],           [disable SHA1 software implementation plugin.])
76 ARG_DISBL_SET([sha2],           [disable SHA256/SHA384/SHA512 software implementation plugin.])
77 ARG_DISBL_SET([fips-prf],       [disable FIPS PRF software implementation plugin.])
78 ARG_DISBL_SET([gmp],            [disable GNU MP (libgmp) based crypto implementation plugin.])
79 ARG_DISBL_SET([random],         [disable RNG implementation on top of /dev/(u)random.])
80 ARG_DISBL_SET([x509],           [disable X509 certificate implementation plugin.])
81 ARG_DISBL_SET([revocation],     [disable X509 CRL/OCSP revocation check plugin.])
82 ARG_DISBL_SET([pubkey],         [disable RAW public key support plugin.])
83 ARG_DISBL_SET([pkcs1],          [disable PKCS1 key decoding plugin.])
84 ARG_DISBL_SET([pgp],            [disable PGP key decoding plugin.])
85 ARG_DISBL_SET([dnskey],         [disable DNS RR key decoding plugin.])
86 ARG_DISBL_SET([pem],            [disable PEM decoding plugin.])
87 ARG_DISBL_SET([hmac],           [disable HMAC crypto implementation plugin.])
88 ARG_DISBL_SET([xcbc],           [disable xcbc crypto implementation plugin.])
89 ARG_ENABL_SET([test-vectors],   [enable plugin providing crypto test vectors.])
90 ARG_ENABL_SET([mysql],          [enable MySQL database support. Requires libmysqlclient_r.])
91 ARG_ENABL_SET([sqlite],         [enable SQLite database support. Requires libsqlite3.])
92 ARG_DISBL_SET([stroke],         [disable charons stroke (pluto compatibility) configuration backend.])
93 ARG_ENABL_SET([medsrv],         [enable mediation server web frontend and daemon plugin.])
94 ARG_ENABL_SET([medcli],         [enable mediation client configuration database plugin.])
95 ARG_ENABL_SET([smp],            [enable SMP configuration and control interface. Requires libxml.])
96 ARG_ENABL_SET([sql],            [enable SQL database configuration backend.])
97 ARG_ENABL_SET([smartcard],      [enable smartcard support.])
98 ARG_ENABL_SET([cisco-quirks],   [enable support of Cisco VPN client.])
99 ARG_ENABL_SET([leak-detective], [enable malloc hooks to find memory leaks.])
100 ARG_ENABL_SET([lock-profiler],  [enable lock/mutex profiling code.])
101 ARG_ENABL_SET([unit-tests],     [enable unit tests on IKEv2 daemon startup.])
102 ARG_ENABL_SET([load-tester],    [enable load testing plugin for IKEv2 daemon.])
103 ARG_ENABL_SET([eap-sim],        [enable SIM authentication module for EAP.])
104 ARG_ENABL_SET([eap-sim-file],   [enable EAP-SIM backend based on a triplet file.])
105 ARG_ENABL_SET([eap-simaka-sql], [enable EAP-SIM/AKA backend based on a triplet/quintuplet SQL database.])
106 ARG_ENABL_SET([eap-simaka-pseudonym], [enable EAP-SIM/AKA pseudonym storage plugin.])
107 ARG_ENABL_SET([eap-simaka-reauth],    [enable EAP-SIM/AKA reauthentication data storage plugin.])
108 ARG_ENABL_SET([eap-identity],   [enable EAP module providing EAP-Identity helper.])
109 ARG_ENABL_SET([eap-md5],        [enable EAP MD5 (CHAP) authentication module.])
110 ARG_ENABL_SET([eap-gtc],        [enable PAM based EAP GTC authentication module.])
111 ARG_ENABL_SET([eap-aka],        [enable EAP AKA authentication module.])
112 ARG_ENABL_SET([eap-aka-3gpp2],  [enable EAP AKA backend implementing 3GPP2 algorithms in software. Requires libgmp.])
113 ARG_ENABL_SET([eap-mschapv2],   [enable EAP MS-CHAPv2 authentication module.])
114 ARG_ENABL_SET([eap-tls],        [enable EAP TLS authentication module.])
115 ARG_ENABL_SET([eap-ttls],       [enable EAP TTLS authentication module.])
116 ARG_ENABL_SET([eap-tnc],        [enable EAP TNC trusted network connect module.])
117 ARG_ENABL_SET([eap-radius],     [enable RADIUS proxy authentication module.])
118 ARG_DISBL_SET([kernel-netlink], [disable the netlink kernel interface.])
119 ARG_ENABL_SET([kernel-pfkey],   [enable the PF_KEY kernel interface.])
120 ARG_ENABL_SET([kernel-pfroute], [enable the PF_ROUTE kernel interface.])
121 ARG_ENABL_SET([kernel-klips],   [enable the KLIPS kernel interface.])
122 ARG_DISBL_SET([socket-default], [disable default socket implementation for charon.])
123 ARG_ENABL_SET([socket-raw],     [enable raw socket implementation of charon, enforced if pluto is enabled])
124 ARG_ENABL_SET([socket-dynamic], [enable dynamic socket implementation for charon])
125 ARG_ENABL_SET([farp],           [enable ARP faking plugin that responds to ARP requests to peers virtual IP])
126 ARG_ENABL_SET([nat-transport],  [enable NAT traversal with IPsec transport mode in pluto.])
127 ARG_DISBL_SET([vendor-id],      [disable the sending of the strongSwan vendor ID in pluto.])
128 ARG_DISBL_SET([xauth-vid],      [disable the sending of the XAUTH vendor ID.])
129 ARG_ENABL_SET([dumm],           [enable the DUMM UML test framework.])
130 ARG_ENABL_SET([fast],           [enable libfast (FastCGI Application Server w/ templates.])
131 ARG_ENABL_SET([manager],        [enable web management console (proof of concept).])
132 ARG_ENABL_SET([mediation],      [enable IKEv2 Mediation Extension.])
133 ARG_ENABL_SET([integrity-test], [enable integrity testing of libstrongswan and plugins.])
134 ARG_DISBL_SET([load-warning],   [disable the charon/pluto plugin load option warning in starter.])
135 ARG_DISBL_SET([pluto],          [disable the IKEv1 keying daemon pluto.])
136 ARG_DISBL_SET([xauth],          [disable xauth plugin.])
137 ARG_DISBL_SET([threads],        [disable the use of threads in pluto. Charon always uses threads.])
138 ARG_DISBL_SET([charon],         [disable the IKEv2 keying daemon charon.])
139 ARG_DISBL_SET([tools],          [disable additional utilities (openac, scepclient and pki).])
140 ARG_DISBL_SET([scripts],        [disable additional utilities (found in directory scripts).])
141 ARG_DISBL_SET([updown],         [disable updown firewall script plugin.])
142 ARG_DISBL_SET([attr],           [disable strongswan.conf based configuration attribute plugin.])
143 ARG_ENABL_SET([attr-sql],       [enable SQL based configuration attribute plugin.])
144 ARG_ENABL_SET([dhcp],           [enable DHCP based attribute provider plugin.])
145 ARG_DISBL_SET([resolve],        [disable resolve DNS handler plugin.])
146 ARG_ENABL_SET([padlock],        [enables VIA Padlock crypto plugin.])
147 ARG_ENABL_SET([openssl],        [enables the OpenSSL crypto plugin.])
148 ARG_ENABL_SET([gcrypt],         [enables the libgcrypt plugin.])
149 ARG_ENABL_SET([agent],          [enables the ssh-agent signing plugin.])
150 ARG_ENABL_SET([pkcs11],         [enables the PKCS11 token support plugin.])
151 ARG_ENABL_SET([ctr],            [enables the Counter Mode wrapper crypto plugin.])
152 ARG_ENABL_SET([ccm],            [enables the CCM AEAD wrapper crypto plugin.])
153 ARG_ENABL_SET([gcm],            [enables the GCM AEAD wrapper crypto plugin.])
154 ARG_ENABL_SET([addrblock],      [enables RFC 3779 address block constraint support.])
155 ARG_ENABL_SET([uci],            [enable OpenWRT UCI configuration plugin.])
156 ARG_ENABL_SET([android],        [enable Android specific plugin.])
157 ARG_ENABL_SET([nm],             [enable NetworkManager plugin.])
158 ARG_ENABL_SET([ha],             [enable high availability cluster plugin.])
159 ARG_ENABL_SET([vstr],           [enforce using the Vstr string library to replace glibc-like printf hooks.])
160 ARG_ENABL_SET([monolithic],     [build monolithic version of libstrongswan that includes all enabled plugins. Similarly, the plugins of charon are assembled in libcharon.])
161
162 dnl =========================
163 dnl  set up compiler and flags
164 dnl =========================
165
166 if test -z "$CFLAGS"; then
167         CFLAGS="-g -O2 -Wall -Wno-format -Wno-pointer-sign -Wno-strict-aliasing"
168 fi
169 AC_PROG_CC
170 AC_LIB_PREFIX
171 AC_C_BIGENDIAN
172
173 dnl =========================
174 dnl  check required programs
175 dnl =========================
176
177 AC_PROG_INSTALL
178 AC_PROG_LIBTOOL
179 AC_PROG_EGREP
180 AC_PROG_AWK
181 AC_PROG_LEX
182 AC_PROG_YACC
183 AC_PATH_PROG([PERL], [perl], [], [$PATH:/bin:/usr/bin:/usr/local/bin])
184 AC_PATH_PROG([GPERF], [gperf], [], [$PATH:/bin:/usr/bin:/usr/local/bin])
185
186 dnl because gperf is not needed by end-users we just report it but do not abort on failure
187 AC_MSG_CHECKING([gperf version >= 3.0.0])
188 if test -x "$GPERF"; then
189         if test "`$GPERF --version | $AWK -F' ' '/^GNU gperf/ { print $3 }' | $AWK -F. '{ print $1 }'`" -ge "3"; then
190                 AC_MSG_RESULT([yes])
191         else
192                 AC_MSG_RESULT([no])
193         fi
194 else
195         AC_MSG_RESULT([not found])
196 fi
197
198 dnl translate user/group to numercial ids
199 AC_MSG_CHECKING([for uid of user "$ipsecuser"])
200 ipsecuid=`id -u $ipsecuser 2>/dev/null`
201 if test -n "$ipsecuid"; then
202         AC_MSG_RESULT([$ipsecuid])
203         AC_SUBST(ipsecuid)
204 else
205         AC_MSG_ERROR([not found])
206 fi
207 AC_MSG_CHECKING([for gid of group "$ipsecgroup"])
208 ipsecgid=`$EGREP "^$ipsecgroup:" /etc/group | $AWK -F: '{ print $3 }'`
209 if test -n "$ipsecgid"; then
210         AC_MSG_RESULT([$ipsecgid])
211         AC_SUBST(ipsecgid)
212 else
213         AC_MSG_ERROR([not found])
214 fi
215
216 dnl =========================
217 dnl  dependency calculation
218 dnl =========================
219
220 if test x$eap_aka_3gpp2 = xtrue; then
221         gmp=true;
222 fi
223
224 if test x$eap_aka = xtrue; then
225         fips_prf=true;
226         simaka=true;
227 fi
228
229 if test x$eap_sim = xtrue; then
230         fips_prf=true;
231         simaka=true;
232 fi
233
234 if test x$eap_tls = xtrue -o x$eap_ttls = xtrue; then
235         tls=true;
236 fi
237
238 if test x$fips_prf = xtrue; then
239         if test x$openssl = xfalse; then
240                 sha1=true;
241         fi
242 fi
243
244 if test x$smp = xtrue; then
245         xml=true
246 fi
247
248 if test x$manager = xtrue; then
249         fast=true
250 fi
251
252 if test x$medsrv = xtrue; then
253         mediation=true
254         fast=true
255 fi
256
257 if test x$medcli = xtrue; then
258         mediation=true
259 fi
260
261 if test x$pluto = xtrue; then
262         if test x$socket_raw = xfalse; then
263                 AC_MSG_NOTICE([Enforcing --enable-socket-raw, as pluto is enabled])
264                 socket_raw=true
265                 if test x$socket_default_given = xfalse; then
266                         socket_default=false
267                 fi
268         fi
269 fi
270
271 dnl ===========================================
272 dnl  check required libraries and header files
273 dnl ===========================================
274
275 AC_HEADER_STDBOOL
276 AC_FUNC_ALLOCA
277
278 dnl libraries needed on some platforms but not on others
279 dnl ====================================================
280 saved_LIBS=$LIBS
281
282 dnl FreeBSD and Mac OS X have dlopen integrated in libc, Linux needs libdl
283 LIBS=""
284 AC_SEARCH_LIBS(dlopen, dl, [DLLIB=$LIBS])
285 AC_SUBST(DLLIB)
286
287 dnl glibc's backtrace() can be replicated on FreeBSD with libexecinfo
288 LIBS=""
289 AC_SEARCH_LIBS(backtrace, execinfo, [BTLIB=$LIBS])
290 AC_CHECK_FUNCS(backtrace)
291 AC_SUBST(BTLIB)
292
293 dnl OpenSolaris needs libsocket and libnsl for socket()
294 LIBS=""
295 AC_SEARCH_LIBS(socket, socket, [SOCKLIB=$LIBS],
296         [AC_CHECK_LIB(nsl, socket, [SOCKLIB="-lsocket -lnsl"], [], [-lsocket])]
297 )
298 AC_SUBST(SOCKLIB)
299
300 dnl FreeBSD has clock_gettime in libc, Linux needs librt
301 LIBS=""
302 AC_SEARCH_LIBS(clock_gettime, rt, [RTLIB=$LIBS])
303 AC_CHECK_FUNCS(clock_gettime)
304 AC_SUBST(RTLIB)
305
306 dnl Android has pthread_* functions in bionic (libc), others need libpthread
307 LIBS=""
308 AC_SEARCH_LIBS(pthread_create, pthread, [PTHREADLIB=$LIBS])
309 AC_SUBST(PTHREADLIB)
310
311 LIBS=$saved_LIBS
312 dnl ======================
313
314 AC_MSG_CHECKING(for dladdr)
315 AC_TRY_COMPILE(
316         [#define _GNU_SOURCE
317          #include <dlfcn.h>],
318         [Dl_info* info = 0;
319          dladdr(0, info);],
320         [AC_MSG_RESULT([yes]); AC_DEFINE([HAVE_DLADDR])],
321         [AC_MSG_RESULT([no])]
322 )
323
324 dnl check if pthread_condattr_setclock(CLOCK_MONOTONE) is supported
325 saved_LIBS=$LIBS
326 LIBS=$PTHREADLIB
327 AC_MSG_CHECKING([for pthread_condattr_setclock(CLOCK_MONOTONE)])
328 AC_TRY_RUN(
329         [#include <pthread.h>
330          int main() { pthread_condattr_t attr;
331                 pthread_condattr_init(&attr);
332                 return pthread_condattr_setclock(&attr, CLOCK_MONOTONIC);}],
333         [AC_MSG_RESULT([yes]); AC_DEFINE([HAVE_CONDATTR_CLOCK_MONOTONIC])],
334         [AC_MSG_RESULT([no])],
335         dnl Check existence of pthread_condattr_setclock if cross-compiling
336         [AC_MSG_RESULT([unknown]);
337          AC_CHECK_FUNCS(pthread_condattr_setclock,
338                 [AC_DEFINE([HAVE_CONDATTR_CLOCK_MONOTONIC])]
339         )]
340 )
341 dnl check if we actually are able to configure attributes on cond vars
342 AC_CHECK_FUNCS(pthread_condattr_init)
343 dnl instead of pthread_condattr_setclock Android has this function
344 AC_CHECK_FUNCS(pthread_cond_timedwait_monotonic)
345 dnl check if we can cancel threads
346 AC_CHECK_FUNCS(pthread_cancel)
347 dnl check if native rwlocks are available
348 AC_CHECK_FUNCS(pthread_rwlock_init)
349 LIBS=$saved_LIBS
350
351 AC_CHECK_FUNCS(prctl)
352
353 AC_CHECK_FUNCS(mallinfo)
354
355 AC_CHECK_HEADERS(sys/sockio.h)
356 AC_CHECK_HEADERS(net/pfkeyv2.h netipsec/ipsec.h netinet6/ipsec.h linux/udp.h)
357
358 AC_CHECK_MEMBERS([struct sockaddr.sa_len], [], [],
359 [
360         #include <sys/types.h>
361         #include <sys/socket.h>
362 ])
363
364 AC_CHECK_MEMBERS([struct sadb_x_policy.sadb_x_policy_priority], [], [],
365 [
366         #include <sys/types.h>
367         #ifdef HAVE_NET_PFKEYV2_H
368         #include <net/pfkeyv2.h>
369         #else
370         #include <stdint.h>
371         #include <linux/pfkeyv2.h>
372         #endif
373 ])
374
375 AC_MSG_CHECKING([for in6addr_any])
376 AC_TRY_COMPILE(
377         [#include <sys/types.h>
378         #include <sys/socket.h>
379         #include <netinet/in.h>],
380         [struct in6_addr in6;
381         in6 = in6addr_any;],
382         [AC_MSG_RESULT([yes]); AC_DEFINE([HAVE_IN6ADDR_ANY])],
383         [AC_MSG_RESULT([no])]
384 )
385
386 AC_MSG_CHECKING([for in6_pktinfo])
387 AC_TRY_COMPILE(
388         [#define _GNU_SOURCE
389         #include <sys/types.h>
390         #include <sys/socket.h>
391         #include <netinet/in.h>],
392         [struct in6_pktinfo pi;
393         if (pi.ipi6_ifindex)
394         {
395                 return 0;
396         }],
397         [AC_MSG_RESULT([yes]); AC_DEFINE([HAVE_IN6_PKTINFO])],
398         [AC_MSG_RESULT([no])]
399 )
400
401 AC_MSG_CHECKING([for IPSEC_MODE_BEET])
402 AC_TRY_COMPILE(
403         [#include <sys/types.h>
404         #ifdef HAVE_NETIPSEC_IPSEC_H
405         #include <netipsec/ipsec.h>
406         #elif defined(HAVE_NETINET6_IPSEC_H)
407         #include <netinet6/ipsec.h>
408         #else
409         #include <stdint.h>
410         #include <linux/ipsec.h>
411         #endif],
412         [int mode = IPSEC_MODE_BEET;
413          return mode;],
414         [AC_MSG_RESULT([yes]); AC_DEFINE([HAVE_IPSEC_MODE_BEET])],
415         [AC_MSG_RESULT([no])]
416 )
417
418 AC_MSG_CHECKING([for IPSEC_DIR_FWD])
419 AC_TRY_COMPILE(
420         [#include <sys/types.h>
421         #ifdef HAVE_NETIPSEC_IPSEC_H
422         #include <netipsec/ipsec.h>
423         #elif defined(HAVE_NETINET6_IPSEC_H)
424         #include <netinet6/ipsec.h>
425         #else
426         #include <stdint.h>
427         #include <linux/ipsec.h>
428         #endif],
429         [int dir = IPSEC_DIR_FWD;
430          return dir;],
431         [AC_MSG_RESULT([yes]); AC_DEFINE([HAVE_IPSEC_DIR_FWD])],
432         [AC_MSG_RESULT([no])]
433 )
434
435 AC_MSG_CHECKING([for gcc atomic operations])
436 AC_TRY_RUN(
437 [
438         int main() {
439                 volatile int ref = 1;
440                 __sync_fetch_and_add (&ref, 1);
441                 __sync_sub_and_fetch (&ref, 1);
442                 /* Make sure test fails if operations are not supported */
443                 __sync_val_compare_and_swap(&ref, 1, 0);
444                 return ref;
445         }
446 ],
447 [AC_MSG_RESULT([yes]); AC_DEFINE(HAVE_GCC_ATOMIC_OPERATIONS)],
448 [AC_MSG_RESULT([no])],
449 [AC_MSG_RESULT([no])])
450
451 dnl check for the new register_printf_specifier function with len argument,
452 dnl or the deprecated register_printf_function without
453 AC_CHECK_FUNC(
454         [register_printf_specifier],
455         [AC_DEFINE(HAVE_PRINTF_SPECIFIER)],
456         [AC_CHECK_FUNC(
457                 [register_printf_function],
458                 [AC_DEFINE(HAVE_PRINTF_FUNCTION)],
459                 [
460                         AC_MSG_NOTICE([printf does not support custom format specifiers!])
461                         vstr=true
462                 ]
463         )]
464 )
465
466 if test x$vstr = xtrue; then
467         AC_HAVE_LIBRARY([vstr],[LIBS="$LIBS"],[AC_MSG_ERROR([Vstr string library not found])])
468         AC_DEFINE(USE_VSTR)
469 fi
470
471 if test x$gmp = xtrue; then
472         saved_LIBS=$LIBS
473         AC_HAVE_LIBRARY([gmp],,[AC_MSG_ERROR([GNU Multi Precision library gmp not found])])
474         AC_MSG_CHECKING([mpz_powm_sec])
475         if test x$mpz_powm_sec = xyes; then
476                 AC_TRY_COMPILE(
477                         [#include "gmp.h"],
478                         [
479                                 void *x = mpz_powm_sec;
480                         ],
481                         [AC_MSG_RESULT([yes]); AC_DEFINE(HAVE_MPZ_POWM_SEC)], [AC_MSG_RESULT([no])]
482                 )
483         else
484                 AC_MSG_RESULT([disabled])
485         fi
486         LIBS=$saved_LIBS
487         AC_MSG_CHECKING([gmp.h version >= 4.1.4])
488         AC_TRY_COMPILE(
489                 [#include "gmp.h"],
490                 [
491                         #if (__GNU_MP_VERSION*100 +  __GNU_MP_VERSION_MINOR*10 + __GNU_MP_VERSION_PATCHLEVEL) < 414
492                                 #error bad gmp
493                         #endif
494                 ],
495                 [AC_MSG_RESULT([yes])], [AC_MSG_RESULT([no]); AC_MSG_ERROR([No usable gmp.h found!])]
496         )
497 fi
498
499 if test x$ldap = xtrue; then
500         AC_HAVE_LIBRARY([ldap],[LIBS="$LIBS"],[AC_MSG_ERROR([LDAP library ldap not found])])
501         AC_HAVE_LIBRARY([lber],[LIBS="$LIBS"],[AC_MSG_ERROR([LDAP library lber not found])])
502         AC_CHECK_HEADER([ldap.h],,[AC_MSG_ERROR([LDAP header ldap.h not found!])])
503 fi
504
505 if test x$curl = xtrue; then
506         AC_HAVE_LIBRARY([curl],[LIBS="$LIBS"],[AC_MSG_ERROR([CURL library curl not found])])
507         AC_CHECK_HEADER([curl/curl.h],,[AC_MSG_ERROR([CURL header curl/curl.h not found!])])
508 fi
509
510 if test x$xml = xtrue; then
511         PKG_CHECK_MODULES(xml, [libxml-2.0])
512         AC_SUBST(xml_CFLAGS)
513         AC_SUBST(xml_LIBS)
514 fi
515
516 if test x$dumm = xtrue; then
517         PKG_CHECK_MODULES(gtk, [gtk+-2.0 vte])
518         AC_SUBST(gtk_CFLAGS)
519         AC_SUBST(gtk_LIBS)
520         AC_CHECK_PROGS(RUBY, ruby)
521         AC_MSG_CHECKING([for Ruby header files])
522         if test -n "$RUBY"; then
523                 RUBYDIR=`($RUBY -rmkmf -e 'print Config::CONFIG[["archdir"]] || $archdir') 2>/dev/null`
524                 if test -n "$RUBYDIR"; then
525                         dirs="$RUBYDIR"
526                         RUBYINCLUDE=none
527                         for i in $dirs; do
528                                 if test -r $i/ruby.h; then
529                                         AC_MSG_RESULT([$i])
530                                         RUBYINCLUDE="-I$i"
531                                         break;
532                                 fi
533                         done
534                         if test x"$RUBYINCLUDE" = xnone; then
535                                 AC_MSG_ERROR([ruby.h not found])
536                         fi
537                         AC_SUBST(RUBYINCLUDE)
538                 else
539                         AC_MSG_ERROR([unable to determine ruby configuration])
540                 fi
541         else
542                 AC_MSG_ERROR([don't know how to run ruby])
543         fi
544 fi
545
546 if test x$fast = xtrue; then
547         AC_HAVE_LIBRARY([neo_cgi],[LIBS="$LIBS"],[AC_MSG_ERROR([ClearSilver library neo_cgi not found!])])
548         AC_HAVE_LIBRARY([neo_utl],[LIBS="$LIBS"],[AC_MSG_ERROR([ClearSilver library neo_utl not found!])])
549         AC_HAVE_LIBRARY([z],[LIBS="$LIBS"],[AC_MSG_ERROR([ClearSilver dependency zlib not found!])])
550 dnl autoconf does not like CamelCase!? How to fix this?
551 dnl     AC_CHECK_HEADER([ClearSilver/ClearSilver.h],,[AC_MSG_ERROR([ClearSilver header file ClearSilver/ClearSilver.h not found!])])
552
553         AC_HAVE_LIBRARY([fcgi],[LIBS="$LIBS"],[AC_MSG_ERROR([FastCGI library fcgi not found!])])
554         AC_CHECK_HEADER([fcgiapp.h],,[AC_MSG_ERROR([FastCGI header file fcgiapp.h not found!])])
555 fi
556
557 if test x$mysql = xtrue; then
558         AC_PATH_PROG([MYSQLCONFIG], [mysql_config], [], [$PATH:/bin:/usr/bin:/usr/local/bin])
559         if test x$MYSQLCONFIG = x; then
560                 AC_MSG_ERROR([mysql_config not found!])
561         fi
562         AC_SUBST(MYSQLLIB, `$MYSQLCONFIG --libs_r`)
563         AC_SUBST(MYSQLCFLAG, `$MYSQLCONFIG --cflags`)
564 fi
565
566 if test x$sqlite = xtrue; then
567         AC_HAVE_LIBRARY([sqlite3],[LIBS="$LIBS"],[AC_MSG_ERROR([SQLite library sqlite3 not found])])
568         AC_CHECK_HEADER([sqlite3.h],,[AC_MSG_ERROR([SQLite header sqlite3.h not found!])])
569         AC_MSG_CHECKING([sqlite3_prepare_v2])
570         AC_TRY_COMPILE(
571                 [#include <sqlite3.h>],
572                 [
573                         void *test = sqlite3_prepare_v2;
574                 ],
575                 [AC_MSG_RESULT([yes])]; AC_DEFINE_UNQUOTED(HAVE_SQLITE3_PREPARE_V2, 1), [AC_MSG_RESULT([no])])
576         AC_MSG_CHECKING([sqlite3.h version >= 3.3.1])
577         AC_TRY_COMPILE(
578                 [#include <sqlite3.h>],
579                 [
580                         #if SQLITE_VERSION_NUMBER < 3003001
581                                 #error bad sqlite
582                         #endif
583                 ],
584                 [AC_MSG_RESULT([yes])], [AC_MSG_RESULT([no]); AC_MSG_ERROR([SQLite version >= 3.3.1 required!])])
585 fi
586
587 if test x$openssl = xtrue; then
588         AC_HAVE_LIBRARY([crypto],[LIBS="$LIBS"],[AC_MSG_ERROR([OpenSSL crypto library not found])])
589         AC_CHECK_HEADER([openssl/evp.h],,[AC_MSG_ERROR([OpenSSL header openssl/evp.h not found!])])
590 fi
591
592 if test x$gcrypt = xtrue; then
593         AC_HAVE_LIBRARY([gcrypt],[LIBS="$LIBS"],[AC_MSG_ERROR([gcrypt library not found])],[-lgpg-error])
594         AC_CHECK_HEADER([gcrypt.h],,[AC_MSG_ERROR([gcrypt header gcrypt.h not found!])])
595         AC_MSG_CHECKING([gcrypt CAMELLIA cipher])
596         AC_TRY_COMPILE(
597                 [#include <gcrypt.h>],
598                 [enum gcry_cipher_algos alg = GCRY_CIPHER_CAMELLIA128;],
599                 [AC_MSG_RESULT([yes]); AC_DEFINE([HAVE_GCRY_CIPHER_CAMELLIA])],
600                 [AC_MSG_RESULT([no])]
601         )
602 fi
603
604 if test x$uci = xtrue; then
605         AC_HAVE_LIBRARY([uci],[LIBS="$LIBS"],[AC_MSG_ERROR([UCI library libuci not found])])
606         AC_CHECK_HEADER([uci.h],,[AC_MSG_ERROR([UCI header uci.h not found!])])
607 fi
608
609 if test x$android = xtrue; then
610         AC_HAVE_LIBRARY([cutils],[LIBS="$LIBS"],[AC_MSG_ERROR([Android library libcutils not found])])
611         AC_CHECK_HEADER([cutils/properties.h],,[AC_MSG_ERROR([Android header cutils/properties.h not found!])])
612         dnl we have to force the use of libdl here because the autodetection
613         dnl above does not work correctly when cross-compiling for android.
614         DLLIB="-ldl"
615         AC_SUBST(DLLIB)
616 fi
617
618 if test x$nm = xtrue; then
619         PKG_CHECK_EXISTS([libnm-glib],
620                 [PKG_CHECK_MODULES(nm, [NetworkManager gthread-2.0 libnm-glib libnm-glib-vpn])],
621                 [PKG_CHECK_MODULES(nm, [NetworkManager gthread-2.0 libnm_glib libnm_glib_vpn])]
622         )
623         AC_SUBST(nm_CFLAGS)
624         AC_SUBST(nm_LIBS)
625 fi
626
627 if test x$eap_gtc = xtrue; then
628         AC_HAVE_LIBRARY([pam],[LIBS="$LIBS"],[AC_MSG_ERROR([PAM library not found])])
629         AC_CHECK_HEADER([security/pam_appl.h],,[AC_MSG_ERROR([PAM header security/pam_appl.h not found!])])
630 fi
631
632 if test x$capabilities = xnative; then
633         AC_MSG_NOTICE([Usage of the native Linux capabilities interface is deprecated, use libcap instead])
634         dnl Linux requires the following for capset(), Android does not have it,
635         dnl but defines capset() in unistd.h instead.
636         AC_CHECK_HEADERS([sys/capability.h])
637         AC_CHECK_FUNC(capset,,[AC_MSG_ERROR([capset() not found!])])
638         AC_DEFINE(CAPABILITIES_NATIVE)
639 fi
640
641 if test x$capabilities = xlibcap; then
642         AC_HAVE_LIBRARY([cap],[LIBS="$LIBS"],[AC_MSG_ERROR([libcap library not found])])
643         AC_CHECK_HEADER([sys/capability.h],
644                 [AC_DEFINE(HAVE_SYS_CAPABILITY_H)],
645                 [AC_MSG_ERROR([libcap header sys/capability.h not found!])])
646         AC_DEFINE(CAPABILITIES_LIBCAP)
647 fi
648
649 if test x$integrity_test = xtrue; then
650         AC_MSG_CHECKING([for dladdr()])
651         AC_TRY_COMPILE(
652                 [#define _GNU_SOURCE
653                  #include <dlfcn.h>],
654                 [Dl_info info; dladdr(main, &info);],
655                 [AC_MSG_RESULT([yes])], [AC_MSG_RESULT([no]);
656                  AC_MSG_ERROR([dladdr() not supported, required by integrity-test!])]
657         )
658         AC_MSG_CHECKING([for dl_iterate_phdr()])
659         AC_TRY_COMPILE(
660                 [#define _GNU_SOURCE
661                  #include <link.h>],
662                 [dl_iterate_phdr((void*)0, (void*)0);],
663                 [AC_MSG_RESULT([yes])], [AC_MSG_RESULT([no]);
664                  AC_MSG_ERROR([dl_iterate_phdr() not supported, required by integrity-test!])]
665         )
666 fi
667
668 dnl ==============================================
669 dnl  collect plugin list for strongSwan components
670 dnl ==============================================
671
672 m4_include(m4/macros/add-plugin.m4)
673
674 # plugin lists for all components
675 libcharon_plugins=
676 pluto_plugins=
677 pool_plugins=
678 openac_plugins=
679 scepclient_plugins=
680 pki_plugins=
681 scripts_plugins=
682 manager_plugins=
683 medsrv_plugins=
684
685 # location specific lists for checksumming,
686 # for src/libcharon, src/pluto, src/libhydra and src/libstrongswan
687 c_plugins=
688 p_plugins=
689 h_plugins=
690 s_plugins=
691
692 ADD_PLUGIN([test-vectors],         [s libcharon pluto openac scepclient pki])
693 ADD_PLUGIN([curl],                 [s libcharon pluto scepclient])
694 ADD_PLUGIN([ldap],                 [s libcharon pluto scepclient])
695 ADD_PLUGIN([mysql],                [s libcharon pluto pool manager medsrv])
696 ADD_PLUGIN([sqlite],               [s libcharon pluto pool manager medsrv])
697 ADD_PLUGIN([aes],                  [s libcharon pluto openac scepclient pki scripts])
698 ADD_PLUGIN([des],                  [s libcharon pluto openac scepclient pki scripts])
699 ADD_PLUGIN([blowfish],             [s libcharon pluto openac scepclient pki scripts])
700 ADD_PLUGIN([sha1],                 [s libcharon pluto openac scepclient pki scripts medsrv])
701 ADD_PLUGIN([sha2],                 [s libcharon pluto openac scepclient pki scripts medsrv])
702 ADD_PLUGIN([md4],                  [s libcharon openac manager scepclient pki])
703 ADD_PLUGIN([md5],                  [s libcharon pluto openac scepclient pki])
704 ADD_PLUGIN([random],               [s libcharon pluto openac scepclient pki medsrv])
705 ADD_PLUGIN([x509],                 [s libcharon pluto openac scepclient pki scripts])
706 ADD_PLUGIN([revocation],           [s libcharon])
707 ADD_PLUGIN([pubkey],               [s libcharon])
708 ADD_PLUGIN([pkcs1],                [s libcharon pluto openac scepclient pki scripts manager medsrv])
709 ADD_PLUGIN([pgp],                  [s libcharon pluto])
710 ADD_PLUGIN([dnskey],               [s pluto])
711 ADD_PLUGIN([pem],                  [s libcharon pluto openac scepclient pki scripts manager medsrv])
712 ADD_PLUGIN([padlock],              [s libcharon])
713 ADD_PLUGIN([openssl],              [s libcharon pluto openac scepclient pki scripts manager medsrv])
714 ADD_PLUGIN([gcrypt],               [s libcharon pluto openac scepclient pki scripts manager medsrv])
715 ADD_PLUGIN([fips-prf],             [s libcharon])
716 ADD_PLUGIN([gmp],                  [s libcharon pluto openac scepclient pki scripts manager medsrv])
717 ADD_PLUGIN([agent],                [s libcharon])
718 ADD_PLUGIN([pkcs11],               [s libcharon pki])
719 ADD_PLUGIN([xcbc],                 [s libcharon])
720 ADD_PLUGIN([hmac],                 [s libcharon pluto scripts])
721 ADD_PLUGIN([ctr],                  [s libcharon scripts])
722 ADD_PLUGIN([ccm],                  [s libcharon scripts])
723 ADD_PLUGIN([gcm],                  [s libcharon scripts])
724 ADD_PLUGIN([xauth],                [p pluto])
725 ADD_PLUGIN([attr],                 [h libcharon pluto])
726 ADD_PLUGIN([attr-sql],             [h libcharon pluto])
727 ADD_PLUGIN([kernel-pfkey],         [h libcharon pluto])
728 ADD_PLUGIN([kernel-pfroute],       [h libcharon pluto])
729 ADD_PLUGIN([kernel-klips],         [h libcharon pluto])
730 ADD_PLUGIN([kernel-netlink],       [h libcharon pluto])
731 ADD_PLUGIN([resolve],              [h libcharon pluto])
732 ADD_PLUGIN([load-tester],          [c libcharon])
733 ADD_PLUGIN([socket-default],       [c libcharon])
734 ADD_PLUGIN([socket-raw],           [c libcharon])
735 ADD_PLUGIN([socket-dynamic],       [c libcharon])
736 ADD_PLUGIN([farp],                 [c libcharon])
737 ADD_PLUGIN([stroke],               [c libcharon])
738 ADD_PLUGIN([smp],                  [c libcharon])
739 ADD_PLUGIN([sql],                  [c libcharon])
740 ADD_PLUGIN([updown],               [c libcharon])
741 ADD_PLUGIN([eap-identity],         [c libcharon])
742 ADD_PLUGIN([eap-sim],              [c libcharon])
743 ADD_PLUGIN([eap-sim-file],         [c libcharon])
744 ADD_PLUGIN([eap-simaka-sql],       [c libcharon])
745 ADD_PLUGIN([eap-simaka-pseudonym], [c libcharon])
746 ADD_PLUGIN([eap-simaka-reauth],    [c libcharon])
747 ADD_PLUGIN([eap-aka],              [c libcharon])
748 ADD_PLUGIN([eap-aka-3gpp2],        [c libcharon])
749 ADD_PLUGIN([eap-md5],              [c libcharon])
750 ADD_PLUGIN([eap-gtc],              [c libcharon])
751 ADD_PLUGIN([eap-mschapv2],         [c libcharon])
752 ADD_PLUGIN([eap-radius],           [c libcharon])
753 ADD_PLUGIN([eap-tls],              [c libcharon])
754 ADD_PLUGIN([eap-ttls],             [c libcharon])
755 ADD_PLUGIN([eap-tnc],              [c libcharon])
756 ADD_PLUGIN([medsrv],               [c libcharon])
757 ADD_PLUGIN([medcli],               [c libcharon])
758 ADD_PLUGIN([nm],                   [c libcharon])
759 ADD_PLUGIN([dhcp],                 [c libcharon])
760 ADD_PLUGIN([android],              [c libcharon])
761 ADD_PLUGIN([ha],                   [c libcharon])
762 ADD_PLUGIN([uci],                  [c libcharon])
763 ADD_PLUGIN([addrblock],            [c libcharon])
764 ADD_PLUGIN([unit-tester],          [c libcharon])
765
766 AC_SUBST(libcharon_plugins)
767 AC_SUBST(pluto_plugins)
768 AC_SUBST(pool_plugins)
769 AC_SUBST(openac_plugins)
770 AC_SUBST(scepclient_plugins)
771 AC_SUBST(pki_plugins)
772 AC_SUBST(scripts_plugins)
773 AC_SUBST(manager_plugins)
774 AC_SUBST(medsrv_plugins)
775
776 AC_SUBST(c_plugins)
777 AC_SUBST(p_plugins)
778 AC_SUBST(h_plugins)
779 AC_SUBST(s_plugins)
780
781 dnl =========================
782 dnl  set Makefile.am vars
783 dnl =========================
784
785 dnl libstrongswan plugins
786 dnl =====================
787 AM_CONDITIONAL(USE_TEST_VECTORS, test x$test_vectors = xtrue)
788 AM_CONDITIONAL(USE_CURL, test x$curl = xtrue)
789 AM_CONDITIONAL(USE_LDAP, test x$ldap = xtrue)
790 AM_CONDITIONAL(USE_AES, test x$aes = xtrue)
791 AM_CONDITIONAL(USE_DES, test x$des = xtrue)
792 AM_CONDITIONAL(USE_BLOWFISH, test x$blowfish = xtrue)
793 AM_CONDITIONAL(USE_MD4, test x$md4 = xtrue)
794 AM_CONDITIONAL(USE_MD5, test x$md5 = xtrue)
795 AM_CONDITIONAL(USE_SHA1, test x$sha1 = xtrue)
796 AM_CONDITIONAL(USE_SHA2, test x$sha2 = xtrue)
797 AM_CONDITIONAL(USE_FIPS_PRF, test x$fips_prf = xtrue)
798 AM_CONDITIONAL(USE_GMP, test x$gmp = xtrue)
799 AM_CONDITIONAL(USE_RANDOM, test x$random = xtrue)
800 AM_CONDITIONAL(USE_X509, test x$x509 = xtrue)
801 AM_CONDITIONAL(USE_REVOCATION, test x$revocation = xtrue)
802 AM_CONDITIONAL(USE_PUBKEY, test x$pubkey = xtrue)
803 AM_CONDITIONAL(USE_PKCS1, test x$pkcs1 = xtrue)
804 AM_CONDITIONAL(USE_PGP, test x$pgp = xtrue)
805 AM_CONDITIONAL(USE_DNSKEY, test x$dnskey = xtrue)
806 AM_CONDITIONAL(USE_PEM, test x$pem = xtrue)
807 AM_CONDITIONAL(USE_HMAC, test x$hmac = xtrue)
808 AM_CONDITIONAL(USE_XCBC, test x$xcbc = xtrue)
809 AM_CONDITIONAL(USE_MYSQL, test x$mysql = xtrue)
810 AM_CONDITIONAL(USE_SQLITE, test x$sqlite = xtrue)
811 AM_CONDITIONAL(USE_PADLOCK, test x$padlock = xtrue)
812 AM_CONDITIONAL(USE_OPENSSL, test x$openssl = xtrue)
813 AM_CONDITIONAL(USE_GCRYPT, test x$gcrypt = xtrue)
814 AM_CONDITIONAL(USE_AGENT, test x$agent = xtrue)
815 AM_CONDITIONAL(USE_PKCS11, test x$pkcs11 = xtrue)
816 AM_CONDITIONAL(USE_CTR, test x$ctr = xtrue)
817 AM_CONDITIONAL(USE_CCM, test x$ccm = xtrue)
818 AM_CONDITIONAL(USE_GCM, test x$gcm = xtrue)
819
820 dnl charon plugins
821 dnl ==============
822 AM_CONDITIONAL(USE_STROKE, test x$stroke = xtrue)
823 AM_CONDITIONAL(USE_MEDSRV, test x$medsrv = xtrue)
824 AM_CONDITIONAL(USE_MEDCLI, test x$medcli = xtrue)
825 AM_CONDITIONAL(USE_NM, test x$nm = xtrue)
826 AM_CONDITIONAL(USE_UCI, test x$uci = xtrue)
827 AM_CONDITIONAL(USE_ANDROID, test x$android = xtrue)
828 AM_CONDITIONAL(USE_SMP, test x$smp = xtrue)
829 AM_CONDITIONAL(USE_SQL, test x$sql = xtrue)
830 AM_CONDITIONAL(USE_UPDOWN, test x$updown = xtrue)
831 AM_CONDITIONAL(USE_DHCP, test x$dhcp = xtrue)
832 AM_CONDITIONAL(USE_UNIT_TESTS, test x$unit_tests = xtrue)
833 AM_CONDITIONAL(USE_LOAD_TESTER, test x$load_tester = xtrue)
834 AM_CONDITIONAL(USE_HA, test x$ha = xtrue)
835 AM_CONDITIONAL(USE_EAP_SIM, test x$eap_sim = xtrue)
836 AM_CONDITIONAL(USE_EAP_SIM_FILE, test x$eap_sim_file = xtrue)
837 AM_CONDITIONAL(USE_EAP_SIMAKA_SQL, test x$eap_simaka_sql = xtrue)
838 AM_CONDITIONAL(USE_EAP_SIMAKA_PSEUDONYM, test x$eap_simaka_pseudonym = xtrue)
839 AM_CONDITIONAL(USE_EAP_SIMAKA_REAUTH, test x$eap_simaka_reauth = xtrue)
840 AM_CONDITIONAL(USE_EAP_IDENTITY, test x$eap_identity = xtrue)
841 AM_CONDITIONAL(USE_EAP_MD5, test x$eap_md5 = xtrue)
842 AM_CONDITIONAL(USE_EAP_GTC, test x$eap_gtc = xtrue)
843 AM_CONDITIONAL(USE_EAP_AKA, test x$eap_aka = xtrue)
844 AM_CONDITIONAL(USE_EAP_AKA_3GPP2, test x$eap_aka_3gpp2 = xtrue)
845 AM_CONDITIONAL(USE_EAP_MSCHAPV2, test x$eap_mschapv2 = xtrue)
846 AM_CONDITIONAL(USE_EAP_TLS, test x$eap_tls = xtrue)
847 AM_CONDITIONAL(USE_EAP_TTLS, test x$eap_ttls = xtrue)
848 AM_CONDITIONAL(USE_EAP_TNC, test x$eap_tnc = xtrue)
849 AM_CONDITIONAL(USE_EAP_RADIUS, test x$eap_radius = xtrue)
850 AM_CONDITIONAL(USE_SOCKET_DEFAULT, test x$socket_default = xtrue)
851 AM_CONDITIONAL(USE_SOCKET_RAW, test x$socket_raw = xtrue)
852 AM_CONDITIONAL(USE_SOCKET_DYNAMIC, test x$socket_dynamic = xtrue)
853 AM_CONDITIONAL(USE_FARP, test x$farp = xtrue)
854 AM_CONDITIONAL(USE_ADDRBLOCK, test x$addrblock = xtrue)
855
856 dnl hydra plugins
857 dnl =============
858 AM_CONDITIONAL(USE_ATTR, test x$attr = xtrue)
859 AM_CONDITIONAL(USE_ATTR_SQL, test x$attr_sql = xtrue -o x$sql = xtrue)
860 AM_CONDITIONAL(USE_KERNEL_KLIPS, test x$kernel_klips = xtrue)
861 AM_CONDITIONAL(USE_KERNEL_NETLINK, test x$kernel_netlink = xtrue)
862 AM_CONDITIONAL(USE_KERNEL_PFKEY, test x$kernel_pfkey = xtrue)
863 AM_CONDITIONAL(USE_KERNEL_PFROUTE, test x$kernel_pfroute = xtrue)
864 AM_CONDITIONAL(USE_RESOLVE, test x$resolve = xtrue)
865
866 dnl pluto plugins
867 dnl =============
868 AM_CONDITIONAL(USE_XAUTH, test x$xauth = xtrue)
869
870 dnl other options
871 dnl =============
872 AM_CONDITIONAL(USE_SMARTCARD, test x$smartcard = xtrue)
873 AM_CONDITIONAL(USE_CISCO_QUIRKS, test x$cisco_quirks = xtrue)
874 AM_CONDITIONAL(USE_LEAK_DETECTIVE, test x$leak_detective = xtrue)
875 AM_CONDITIONAL(USE_LOCK_PROFILER, test x$lock_profiler = xtrue)
876 AM_CONDITIONAL(USE_NAT_TRANSPORT, test x$nat_transport = xtrue)
877 AM_CONDITIONAL(USE_VENDORID, test x$vendor_id = xtrue)
878 AM_CONDITIONAL(USE_XAUTH_VID, test x$xauth_vid = xtrue)
879 AM_CONDITIONAL(USE_DUMM, test x$dumm = xtrue)
880 AM_CONDITIONAL(USE_FAST, test x$fast = xtrue)
881 AM_CONDITIONAL(USE_MANAGER, test x$manager = xtrue)
882 AM_CONDITIONAL(USE_ME, test x$mediation = xtrue)
883 AM_CONDITIONAL(USE_INTEGRITY_TEST, test x$integrity_test = xtrue)
884 AM_CONDITIONAL(USE_LOAD_WARNING, test x$load_warning = xtrue)
885 AM_CONDITIONAL(USE_PLUTO, test x$pluto = xtrue)
886 AM_CONDITIONAL(USE_THREADS, test x$threads = xtrue)
887 AM_CONDITIONAL(USE_CHARON, test x$charon = xtrue)
888 AM_CONDITIONAL(USE_TOOLS, test x$tools = xtrue)
889 AM_CONDITIONAL(USE_SCRIPTS, test x$scripts = xtrue)
890 AM_CONDITIONAL(USE_LIBSTRONGSWAN, test x$charon = xtrue -o x$pluto = xtrue -o x$tools = xtrue)
891 AM_CONDITIONAL(USE_LIBHYDRA, test x$charon = xtrue -o x$pluto = xtrue)
892 AM_CONDITIONAL(USE_FILE_CONFIG, test x$pluto = xtrue -o x$stroke = xtrue)
893 AM_CONDITIONAL(USE_LIBCAP, test x$capabilities = xlibcap)
894 AM_CONDITIONAL(USE_VSTR, test x$vstr = xtrue)
895 AM_CONDITIONAL(USE_SIMAKA, test x$simaka = xtrue)
896 AM_CONDITIONAL(USE_TLS, test x$tls = xtrue)
897 AM_CONDITIONAL(MONOLITHIC, test x$monolithic = xtrue)
898
899 dnl ==============================
900 dnl  set global definitions
901 dnl ==============================
902
903 if test x$mediation = xtrue; then
904         AC_DEFINE(ME)
905 fi
906 if test x$capabilities = xlibcap -o x$capabilities = xnative; then
907         AC_DEFINE(CAPABILITIES)
908 fi
909 if test x$monolithic = xtrue; then
910         AC_DEFINE(MONOLITHIC)
911 fi
912
913
914 dnl ==============================
915 dnl  build Makefiles
916 dnl ==============================
917
918 AC_OUTPUT(
919         Makefile
920         src/Makefile
921         src/include/Makefile
922         src/libstrongswan/Makefile
923         src/libstrongswan/plugins/aes/Makefile
924         src/libstrongswan/plugins/des/Makefile
925         src/libstrongswan/plugins/blowfish/Makefile
926         src/libstrongswan/plugins/md4/Makefile
927         src/libstrongswan/plugins/md5/Makefile
928         src/libstrongswan/plugins/sha1/Makefile
929         src/libstrongswan/plugins/sha2/Makefile
930         src/libstrongswan/plugins/fips_prf/Makefile
931         src/libstrongswan/plugins/gmp/Makefile
932         src/libstrongswan/plugins/random/Makefile
933         src/libstrongswan/plugins/hmac/Makefile
934         src/libstrongswan/plugins/xcbc/Makefile
935         src/libstrongswan/plugins/x509/Makefile
936         src/libstrongswan/plugins/revocation/Makefile
937         src/libstrongswan/plugins/pubkey/Makefile
938         src/libstrongswan/plugins/pkcs1/Makefile
939         src/libstrongswan/plugins/pgp/Makefile
940         src/libstrongswan/plugins/dnskey/Makefile
941         src/libstrongswan/plugins/pem/Makefile
942         src/libstrongswan/plugins/curl/Makefile
943         src/libstrongswan/plugins/ldap/Makefile
944         src/libstrongswan/plugins/mysql/Makefile
945         src/libstrongswan/plugins/sqlite/Makefile
946         src/libstrongswan/plugins/padlock/Makefile
947         src/libstrongswan/plugins/openssl/Makefile
948         src/libstrongswan/plugins/gcrypt/Makefile
949         src/libstrongswan/plugins/agent/Makefile
950         src/libstrongswan/plugins/pkcs11/Makefile
951         src/libstrongswan/plugins/ctr/Makefile
952         src/libstrongswan/plugins/ccm/Makefile
953         src/libstrongswan/plugins/gcm/Makefile
954         src/libstrongswan/plugins/test_vectors/Makefile
955         src/libhydra/Makefile
956         src/libhydra/plugins/attr/Makefile
957         src/libhydra/plugins/attr_sql/Makefile
958         src/libhydra/plugins/kernel_klips/Makefile
959         src/libhydra/plugins/kernel_netlink/Makefile
960         src/libhydra/plugins/kernel_pfkey/Makefile
961         src/libhydra/plugins/kernel_pfroute/Makefile
962         src/libhydra/plugins/resolve/Makefile
963         src/libfreeswan/Makefile
964         src/libsimaka/Makefile
965         src/libtls/Makefile
966         src/pluto/Makefile
967         src/pluto/plugins/xauth/Makefile
968         src/whack/Makefile
969         src/charon/Makefile
970         src/libcharon/Makefile
971         src/libcharon/plugins/eap_aka/Makefile
972         src/libcharon/plugins/eap_aka_3gpp2/Makefile
973         src/libcharon/plugins/eap_identity/Makefile
974         src/libcharon/plugins/eap_md5/Makefile
975         src/libcharon/plugins/eap_gtc/Makefile
976         src/libcharon/plugins/eap_sim/Makefile
977         src/libcharon/plugins/eap_sim_file/Makefile
978         src/libcharon/plugins/eap_simaka_sql/Makefile
979         src/libcharon/plugins/eap_simaka_pseudonym/Makefile
980         src/libcharon/plugins/eap_simaka_reauth/Makefile
981         src/libcharon/plugins/eap_mschapv2/Makefile
982         src/libcharon/plugins/eap_tls/Makefile
983         src/libcharon/plugins/eap_ttls/Makefile
984         src/libcharon/plugins/eap_tnc/Makefile
985         src/libcharon/plugins/eap_radius/Makefile
986         src/libcharon/plugins/socket_default/Makefile
987         src/libcharon/plugins/socket_raw/Makefile
988         src/libcharon/plugins/socket_dynamic/Makefile
989         src/libcharon/plugins/farp/Makefile
990         src/libcharon/plugins/smp/Makefile
991         src/libcharon/plugins/sql/Makefile
992         src/libcharon/plugins/medsrv/Makefile
993         src/libcharon/plugins/medcli/Makefile
994         src/libcharon/plugins/nm/Makefile
995         src/libcharon/plugins/addrblock/Makefile
996         src/libcharon/plugins/uci/Makefile
997         src/libcharon/plugins/ha/Makefile
998         src/libcharon/plugins/android/Makefile
999         src/libcharon/plugins/stroke/Makefile
1000         src/libcharon/plugins/updown/Makefile
1001         src/libcharon/plugins/dhcp/Makefile
1002         src/libcharon/plugins/unit_tester/Makefile
1003         src/libcharon/plugins/load_tester/Makefile
1004         src/stroke/Makefile
1005         src/ipsec/Makefile
1006         src/starter/Makefile
1007         src/_updown/Makefile
1008         src/_updown_espmark/Makefile
1009         src/_copyright/Makefile
1010         src/openac/Makefile
1011         src/scepclient/Makefile
1012         src/pki/Makefile
1013         src/dumm/Makefile
1014         src/dumm/ext/extconf.rb
1015         src/libfast/Makefile
1016         src/manager/Makefile
1017         src/medsrv/Makefile
1018         src/checksum/Makefile
1019         scripts/Makefile
1020         testing/Makefile
1021 )