fixed pluto crash caused by expired leftcert and rightca=%same
[strongswan.git] / configure.in
1 dnl  configure.in for linux strongSwan
2 dnl  Copyright (C) 2006 Martin Willi
3 dnl  Hochschule fuer Technik Rapperswil
4 dnl
5 dnl  This program is free software; you can redistribute it and/or modify it
6 dnl  under the terms of the GNU General Public License as published by the
7 dnl  Free Software Foundation; either version 2 of the License, or (at your
8 dnl  option) any later version.  See <http://www.fsf.org/copyleft/gpl.txt>.
9 dnl
10 dnl  This program is distributed in the hope that it will be useful, but
11 dnl  WITHOUT ANY WARRANTY; without even the implied warranty of MERCHANTABILITY
12 dnl  or FITNESS FOR A PARTICULAR PURPOSE.  See the GNU General Public License
13 dnl  for more details.
14
15 dnl ===========================
16 dnl  initialize & set some vars
17 dnl ===========================
18
19 AC_INIT(strongSwan,4.4.0)
20 AM_INIT_AUTOMAKE(tar-ustar)
21 AC_CONFIG_MACRO_DIR([m4/config])
22 PKG_PROG_PKG_CONFIG
23
24 dnl =================================
25 dnl  check --enable-xxx & --with-xxx
26 dnl =================================
27
28 m4_include(m4/macros/with.m4)
29
30 ARG_WITH_SUBST([default-pkcs11],     [/usr/lib/opensc-pkcs11.so], [set the default PKCS11 library])
31 ARG_WITH_SUBST([random-device],      [/dev/random], [set the device to read real random data from])
32 ARG_WITH_SUBST([urandom-device],     [/dev/urandom], [set the device to read pseudo random data from])
33 ARG_WITH_SUBST([strongswan-conf],    [${sysconfdir}/strongswan.conf], [set the strongswan.conf file location])
34 ARG_WITH_SUBST([resolv-conf],        [${sysconfdir}/resolv.conf], [set the file to use in DNS handler plugin])
35 ARG_WITH_SUBST([piddir],             [/var/run], [set path for PID and UNIX socket files])
36 ARG_WITH_SUBST([ipsecdir],           [${libexecdir%/}/ipsec], [set installation path for ipsec tools])
37 ARG_WITH_SUBST([plugindir],          [${ipsecdir%/}/plugins], [set the installation path of plugins])
38 ARG_WITH_SUBST([nm-ca-dir],          [/usr/share/ca-certificates], [directory the NM plugin uses to look up trusted root certificates])
39 ARG_WITH_SUBST([linux-headers],      [\${top_srcdir}/src/include], [set directory of linux header files to use])
40 ARG_WITH_SUBST([routing-table],      [220], [set routing table to use for IPsec routes])
41 ARG_WITH_SUBST([routing-table-prio], [220], [set priority for IPsec routing table])
42
43 ARG_WITH_SET([capabilities],         [no], [set capability dropping library. Currently only the value "libcap" is supported])
44 ARG_WITH_SET([mpz_powm_sec],         [yes], [use the more side-channel resistant mpz_powm_sec in libgmp, if available])
45
46 AC_ARG_WITH(
47         [xauth-module],
48         AS_HELP_STRING([--with-xauth-module=lib],[set the path to the XAUTH module]),
49         [AC_DEFINE_UNQUOTED(XAUTH_DEFAULT_LIB, "$withval")],
50 )
51
52 AC_ARG_WITH(
53         [user],
54         AS_HELP_STRING([--with-user=user],[change user of the daemons to "user" after startup (default is "root").]),
55         [AC_DEFINE_UNQUOTED(IPSEC_USER, "$withval") AC_SUBST(ipsecuser, "$withval")],
56         [AC_SUBST(ipsecuser, "root")]
57 )
58
59 AC_ARG_WITH(
60         [group],
61         AS_HELP_STRING([--with-group=group],[change group of the daemons to "group" after startup (default is "root").]),
62         [AC_DEFINE_UNQUOTED(IPSEC_GROUP, "$withval") AC_SUBST(ipsecgroup, "$withval")],
63         [AC_SUBST(ipsecgroup, "root")]
64 )
65
66 m4_include(m4/macros/enable-disable.m4)
67
68 ARG_ENABL_SET([curl],           [enable CURL fetcher plugin to fetch files via libcurl. Requires libcurl.])
69 ARG_ENABL_SET([ldap],           [enable LDAP fetching plugin to fetch files via libldap. Requires openLDAP.])
70 ARG_DISBL_SET([aes],            [disable AES software implementation plugin.])
71 ARG_DISBL_SET([des],            [disable DES/3DES software implementation plugin.])
72 ARG_ENABL_SET([blowfish],       [enable Blowfish software implementation plugin.])
73 ARG_ENABL_SET([md4],            [enable MD4 software implementation plugin.])
74 ARG_DISBL_SET([md5],            [disable MD5 software implementation plugin.])
75 ARG_DISBL_SET([sha1],           [disable SHA1 software implementation plugin.])
76 ARG_DISBL_SET([sha2],           [disable SHA256/SHA384/SHA512 software implementation plugin.])
77 ARG_DISBL_SET([fips-prf],       [disable FIPS PRF software implementation plugin.])
78 ARG_DISBL_SET([gmp],            [disable GNU MP (libgmp) based crypto implementation plugin.])
79 ARG_DISBL_SET([random],         [disable RNG implementation on top of /dev/(u)random.])
80 ARG_DISBL_SET([x509],           [disable X509 certificate implementation plugin.])
81 ARG_DISBL_SET([pubkey],         [disable RAW public key support plugin.])
82 ARG_DISBL_SET([pkcs1],          [disable PKCS1 key decoding plugin.])
83 ARG_DISBL_SET([pgp],            [disable PGP key decoding plugin.])
84 ARG_DISBL_SET([dnskey],         [disable DNS RR key decoding plugin.])
85 ARG_DISBL_SET([pem],            [disable PEM decoding plugin.])
86 ARG_DISBL_SET([hmac],           [disable HMAC crypto implementation plugin.])
87 ARG_DISBL_SET([xcbc],           [disable xcbc crypto implementation plugin.])
88 ARG_ENABL_SET([test-vectors],   [enable plugin providing crypto test vectors.])
89 ARG_ENABL_SET([mysql],          [enable MySQL database support. Requires libmysqlclient_r.])
90 ARG_ENABL_SET([sqlite],         [enable SQLite database support. Requires libsqlite3.])
91 ARG_DISBL_SET([stroke],         [disable charons stroke (pluto compatibility) configuration backend.])
92 ARG_ENABL_SET([medsrv],         [enable mediation server web frontend and daemon plugin.])
93 ARG_ENABL_SET([medcli],         [enable mediation client configuration database plugin.])
94 ARG_ENABL_SET([smp],            [enable SMP configuration and control interface. Requires libxml.])
95 ARG_ENABL_SET([sql],            [enable SQL database configuration backend.])
96 ARG_ENABL_SET([smartcard],      [enable smartcard support.])
97 ARG_ENABL_SET([cisco-quirks],   [enable support of Cisco VPN client.])
98 ARG_ENABL_SET([leak-detective], [enable malloc hooks to find memory leaks.])
99 ARG_ENABL_SET([lock-profiler],  [enable lock/mutex profiling code.])
100 ARG_ENABL_SET([unit-tests],     [enable unit tests on IKEv2 daemon startup.])
101 ARG_ENABL_SET([load-tester],    [enable load testing plugin for IKEv2 daemon.])
102 ARG_ENABL_SET([eap-sim],        [enable SIM authenication module for EAP.])
103 ARG_ENABL_SET([eap-sim-file],   [enable EAP-SIM backend based on a triplet file.])
104 ARG_ENABL_SET([eap-simaka-pseudonym], [enable EAP-SIM/AKA pseudonym storage plugin.])
105 ARG_ENABL_SET([eap-simaka-reauth],    [enable EAP-SIM/AKA reauthentication data storage plugin.])
106 ARG_ENABL_SET([eap-identity],   [enable EAP module providing EAP-Identity helper.])
107 ARG_ENABL_SET([eap-md5],        [enable EAP MD5 (CHAP) authenication module.])
108 ARG_ENABL_SET([eap-gtc],        [enable PAM based EAP GTC authenication module.])
109 ARG_ENABL_SET([eap-aka],        [enable EAP AKA authentication module.])
110 ARG_ENABL_SET([eap-aka-3gpp2],  [enable EAP AKA backend implementing 3GPP2 algorithms in software. Requires libgmp.])
111 ARG_ENABL_SET([eap-mschapv2],   [enable EAP MS-CHAPv2 authenication module.])
112 ARG_ENABL_SET([eap-radius],     [enable RADIUS proxy authenication module.])
113 ARG_DISBL_SET([kernel-netlink], [disable the netlink kernel interface.])
114 ARG_ENABL_SET([kernel-pfkey],   [enable the PF_KEY kernel interface.])
115 ARG_ENABL_SET([kernel-pfroute], [enable the PF_ROUTE kernel interface.])
116 ARG_ENABL_SET([kernel-klips],   [enable the KLIPS kernel interface.])
117 ARG_DISBL_SET([socket-default], [disable default socket implementation for charon.])
118 ARG_ENABL_SET([socket-raw],     [enable raw socket implementation of charon, enforced if pluto is enabled])
119 ARG_ENABL_SET([socket-dynamic], [enable dynamic socket implementation for charon])
120 ARG_ENABL_SET([farp],           [enable ARP faking plugin that responds to ARP requests to peers virtual IP])
121 ARG_ENABL_SET([nat-transport],  [enable NAT traversal with IPsec transport mode in pluto.])
122 ARG_DISBL_SET([vendor-id],      [disable the sending of the strongSwan vendor ID in pluto.])
123 ARG_DISBL_SET([xauth-vid],      [disable the sending of the XAUTH vendor ID.])
124 ARG_ENABL_SET([dumm],           [enable the DUMM UML test framework.])
125 ARG_ENABL_SET([fast],           [enable libfast (FastCGI Application Server w/ templates.])
126 ARG_ENABL_SET([manager],        [enable web management console (proof of concept).])
127 ARG_ENABL_SET([mediation],      [enable IKEv2 Mediation Extension.])
128 ARG_ENABL_SET([integrity-test], [enable integrity testing of libstrongswan and plugins.])
129 ARG_DISBL_SET([pluto],          [disable the IKEv1 keying daemon pluto.])
130 ARG_DISBL_SET([threads],        [disable the use of threads in pluto. Charon always uses threads.])
131 ARG_DISBL_SET([charon],         [disable the IKEv2 keying daemon charon.])
132 ARG_DISBL_SET([tools],          [disable additional utilities (openac, scepclient and pki).])
133 ARG_DISBL_SET([scripts],        [disable additional utilities (found in directory scripts).])
134 ARG_DISBL_SET([updown],         [disable updown firewall script plugin.])
135 ARG_DISBL_SET([attr],           [disable strongswan.conf based configuration attribute plugin.])
136 ARG_ENABL_SET([attr-sql],       [enable SQL based configuration attribute plugin.])
137 ARG_ENABL_SET([dhcp],           [enable DHCP based attribute provider plugin.])
138 ARG_DISBL_SET([resolve],        [disable resolve DNS handler plugin.])
139 ARG_ENABL_SET([padlock],        [enables VIA Padlock crypto plugin.])
140 ARG_ENABL_SET([openssl],        [enables the OpenSSL crypto plugin.])
141 ARG_ENABL_SET([gcrypt],         [enables the libgcrypt plugin.])
142 ARG_ENABL_SET([agent],          [enables the ssh-agent signing plugin.])
143 ARG_ENABL_SET([uci],            [enable OpenWRT UCI configuration plugin.])
144 ARG_ENABL_SET([android],        [enable Android specific plugin.])
145 ARG_ENABL_SET([nm],             [enable NetworkManager plugin.])
146 ARG_ENABL_SET([vstr],           [enforce using the Vstr string library to replace glibc-like printf hooks.])
147 ARG_ENABL_SET([monolithic],     [build monolithic version of libstrongswan that includes all enabled plugins. Similarly, the plugins of charon are assembled in libcharon.])
148
149 dnl =========================
150 dnl  set up compiler and flags
151 dnl =========================
152
153 if test -z "$CFLAGS"; then
154         CFLAGS="-g -O2 -Wall -Wno-format -Wno-pointer-sign -Wno-strict-aliasing"
155 fi
156 AC_PROG_CC
157 AC_LIB_PREFIX
158 AC_C_BIGENDIAN
159
160 dnl =========================
161 dnl  check required programs
162 dnl =========================
163
164 AC_PROG_INSTALL
165 AC_PROG_LIBTOOL
166 AC_PROG_EGREP
167 AC_PROG_AWK
168 AC_PROG_LEX
169 AC_PROG_YACC
170 AC_PATH_PROG([PERL], [perl], [], [$PATH:/bin:/usr/bin:/usr/local/bin])
171 AC_PATH_PROG([GPERF], [gperf], [], [$PATH:/bin:/usr/bin:/usr/local/bin])
172
173 dnl because gperf is not needed by end-users we just report it but do not abort on failure
174 AC_MSG_CHECKING([gperf version >= 3.0.0])
175 if test -x "$GPERF"; then
176         if test "`$GPERF --version | $AWK -F' ' '/^GNU gperf/ { print $3 }' | $AWK -F. '{ print $1 }'`" -ge "3"; then
177                 AC_MSG_RESULT([yes])
178         else
179                 AC_MSG_RESULT([no])
180         fi
181 else
182         AC_MSG_RESULT([not found])
183 fi
184
185 dnl translate user/group to numercial ids
186 AC_MSG_CHECKING([for uid of user "$ipsecuser"])
187 ipsecuid=`id -u $ipsecuser 2>/dev/null`
188 if test -n "$ipsecuid"; then
189         AC_MSG_RESULT([$ipsecuid])
190         AC_SUBST(ipsecuid)
191 else
192         AC_MSG_ERROR([not found])
193 fi
194 AC_MSG_CHECKING([for gid of group "$ipsecgroup"])
195 ipsecgid=`$EGREP "^$ipsecgroup:" /etc/group | $AWK -F: '{ print $3 }'`
196 if test -n "$ipsecgid"; then
197         AC_MSG_RESULT([$ipsecgid])
198         AC_SUBST(ipsecgid)
199 else
200         AC_MSG_ERROR([not found])
201 fi
202
203 dnl =========================
204 dnl  dependency calculation
205 dnl =========================
206
207 if test x$eap_aka_3gpp2 = xtrue; then
208         gmp=true;
209 fi
210
211 if test x$eap_aka = xtrue; then
212         fips_prf=true;
213         simaka=true;
214 fi
215
216 if test x$eap_sim = xtrue; then
217         fips_prf=true;
218         simaka=true;
219 fi
220
221 if test x$fips_prf = xtrue; then
222         if test x$openssl = xfalse; then
223                 sha1=true;
224         fi
225 fi
226
227 if test x$smp = xtrue; then
228         xml=true
229 fi
230
231 if test x$manager = xtrue; then
232         fast=true
233 fi
234
235 if test x$medsrv = xtrue; then
236         mediation=true
237         fast=true
238 fi
239
240 if test x$medcli = xtrue; then
241         mediation=true
242 fi
243
244 if test x$pluto = xtrue; then
245         if test x$socket_raw = xfalse; then
246                 AC_MSG_NOTICE([Enforcing --enable-socket-raw, as pluto is enabled])
247                 socket_raw=true
248                 if test x$socket_default_given = xfalse; then
249                         socket_default=false
250                 fi
251         fi
252 fi
253
254 dnl ===========================================
255 dnl  check required libraries and header files
256 dnl ===========================================
257
258 AC_HEADER_STDBOOL
259 AC_FUNC_ALLOCA
260
261 dnl libraries needed on some platforms but not on others
262 dnl ====================================================
263 saved_LIBS=$LIBS
264
265 dnl FreeBSD and Mac OS X have dlopen integrated in libc, Linux needs libdl
266 LIBS=""
267 AC_SEARCH_LIBS(dlopen, dl, [DLLIB=$LIBS])
268 AC_SUBST(DLLIB)
269
270 dnl glibc's backtrace() can be replicated on FreeBSD with libexecinfo
271 LIBS=""
272 AC_SEARCH_LIBS(backtrace, execinfo, [BTLIB=$LIBS])
273 AC_CHECK_FUNCS(backtrace)
274 AC_SUBST(BTLIB)
275
276 dnl OpenSolaris needs libsocket and libnsl for socket()
277 LIBS=""
278 AC_SEARCH_LIBS(socket, socket, [SOCKLIB=$LIBS],
279         [AC_CHECK_LIB(nsl, socket, [SOCKLIB="-lsocket -lnsl"], [], [-lsocket])]
280 )
281 AC_SUBST(SOCKLIB)
282
283 dnl FreeBSD has clock_gettime in libc, Linux needs librt
284 LIBS=""
285 AC_SEARCH_LIBS(clock_gettime, rt, [RTLIB=$LIBS])
286 AC_CHECK_FUNCS(clock_gettime)
287 AC_SUBST(RTLIB)
288
289 dnl Android has pthread_* functions in bionic (libc), others need libpthread
290 LIBS=""
291 AC_SEARCH_LIBS(pthread_create, pthread, [PTHREADLIB=$LIBS])
292 AC_SUBST(PTHREADLIB)
293
294 LIBS=$saved_LIBS
295 dnl ======================
296
297 AC_MSG_CHECKING(for dladdr)
298 AC_TRY_COMPILE(
299         [#define _GNU_SOURCE
300          #include <dlfcn.h>],
301         [Dl_info* info = 0;
302          dladdr(0, info);],
303         [AC_MSG_RESULT([yes]); AC_DEFINE([HAVE_DLADDR])],
304         [AC_MSG_RESULT([no])]
305 )
306
307 dnl check if pthread_condattr_setclock(CLOCK_MONOTONE) is supported
308 saved_LIBS=$LIBS
309 LIBS=$PTHREADLIB
310 AC_MSG_CHECKING([for pthread_condattr_setclock(CLOCK_MONOTONE)])
311 AC_TRY_RUN(
312         [#include <pthread.h>
313          int main() { pthread_condattr_t attr;
314                 pthread_condattr_init(&attr);
315                 return pthread_condattr_setclock(&attr, CLOCK_MONOTONIC);}],
316         [AC_MSG_RESULT([yes]); AC_DEFINE([HAVE_CONDATTR_CLOCK_MONOTONIC])],
317         [AC_MSG_RESULT([no])],
318         dnl Check existence of pthread_condattr_setclock if cross-compiling
319         [AC_MSG_RESULT([unknown]);
320          AC_CHECK_FUNCS(pthread_condattr_setclock,
321                 [AC_DEFINE([HAVE_CONDATTR_CLOCK_MONOTONIC])]
322         )]
323 )
324 dnl check if we actually are able to configure attributes on cond vars
325 AC_CHECK_FUNCS(pthread_condattr_init)
326 dnl instead of pthread_condattr_setclock Android has this function
327 AC_CHECK_FUNCS(pthread_cond_timedwait_monotonic)
328 dnl check if we can cancel threads
329 AC_CHECK_FUNCS(pthread_cancel)
330 dnl check if native rwlocks are available
331 AC_CHECK_FUNCS(pthread_rwlock_init)
332 LIBS=$saved_LIBS
333
334 AC_CHECK_FUNCS(prctl)
335
336 AC_CHECK_HEADERS(sys/sockio.h)
337 AC_CHECK_HEADERS(net/pfkeyv2.h netipsec/ipsec.h netinet6/ipsec.h linux/udp.h)
338
339 AC_CHECK_MEMBERS([struct sockaddr.sa_len], [], [],
340 [
341         #include <sys/types.h>
342         #include <sys/socket.h>
343 ])
344
345 AC_CHECK_MEMBERS([struct sadb_x_policy.sadb_x_policy_priority], [], [],
346 [
347         #include <sys/types.h>
348         #ifdef HAVE_NET_PFKEYV2_H
349         #include <net/pfkeyv2.h>
350         #else
351         #include <stdint.h>
352         #include <linux/pfkeyv2.h>
353         #endif
354 ])
355
356 AC_MSG_CHECKING([for in6addr_any])
357 AC_TRY_COMPILE(
358         [#include <sys/types.h>
359         #include <sys/socket.h>
360         #include <netinet/in.h>],
361         [struct in6_addr in6;
362         in6 = in6addr_any;],
363         [AC_MSG_RESULT([yes]); AC_DEFINE([HAVE_IN6ADDR_ANY])],
364         [AC_MSG_RESULT([no])]
365 )
366
367 AC_MSG_CHECKING([for in6_pktinfo])
368 AC_TRY_COMPILE(
369         [#define _GNU_SOURCE
370         #include <sys/types.h>
371         #include <sys/socket.h>
372         #include <netinet/in.h>],
373         [struct in6_pktinfo pi;
374         if (pi.ipi6_ifindex)
375         {
376                 return 0;
377         }],
378         [AC_MSG_RESULT([yes]); AC_DEFINE([HAVE_IN6_PKTINFO])],
379         [AC_MSG_RESULT([no])]
380 )
381
382 AC_MSG_CHECKING([for IPSEC_MODE_BEET])
383 AC_TRY_COMPILE(
384         [#include <sys/types.h>
385         #ifdef HAVE_NETIPSEC_IPSEC_H
386         #include <netipsec/ipsec.h>
387         #elif defined(HAVE_NETINET6_IPSEC_H)
388         #include <netinet6/ipsec.h>
389         #else
390         #include <stdint.h>
391         #include <linux/ipsec.h>
392         #endif],
393         [int mode = IPSEC_MODE_BEET;
394          return mode;],
395         [AC_MSG_RESULT([yes]); AC_DEFINE([HAVE_IPSEC_MODE_BEET])],
396         [AC_MSG_RESULT([no])]
397 )
398
399 AC_MSG_CHECKING([for IPSEC_DIR_FWD])
400 AC_TRY_COMPILE(
401         [#include <sys/types.h>
402         #ifdef HAVE_NETIPSEC_IPSEC_H
403         #include <netipsec/ipsec.h>
404         #elif defined(HAVE_NETINET6_IPSEC_H)
405         #include <netinet6/ipsec.h>
406         #else
407         #include <stdint.h>
408         #include <linux/ipsec.h>
409         #endif],
410         [int dir = IPSEC_DIR_FWD;
411          return dir;],
412         [AC_MSG_RESULT([yes]); AC_DEFINE([HAVE_IPSEC_DIR_FWD])],
413         [AC_MSG_RESULT([no])]
414 )
415
416 AC_MSG_CHECKING([for gcc atomic operations])
417 AC_TRY_RUN(
418 [
419         int main() {
420                 volatile int ref = 1;
421                 __sync_fetch_and_add (&ref, 1);
422                 __sync_sub_and_fetch (&ref, 1);
423                 /* Make sure test fails if operations are not supported */
424                 __sync_val_compare_and_swap(&ref, 1, 0);
425                 return ref;
426         }
427 ],
428 [AC_MSG_RESULT([yes]); AC_DEFINE(HAVE_GCC_ATOMIC_OPERATIONS)],
429 [AC_MSG_RESULT([no])],
430 [AC_MSG_RESULT([no])])
431
432 dnl check for the new register_printf_specifier function with len argument,
433 dnl or the deprecated register_printf_function without
434 AC_CHECK_FUNC(
435         [register_printf_specifier],
436         [AC_DEFINE(HAVE_PRINTF_SPECIFIER)],
437         [AC_CHECK_FUNC(
438                 [register_printf_function],
439                 [AC_DEFINE(HAVE_PRINTF_FUNCTION)],
440                 [
441                         AC_MSG_NOTICE([printf does not support custom format specifiers!])
442                         vstr=true
443                 ]
444         )]
445 )
446
447 if test x$vstr = xtrue; then
448         AC_HAVE_LIBRARY([vstr],[LIBS="$LIBS"],[AC_MSG_ERROR([Vstr string library not found])])
449         AC_DEFINE(USE_VSTR)
450 fi
451
452 if test x$gmp = xtrue; then
453         saved_LIBS=$LIBS
454         AC_HAVE_LIBRARY([gmp],,[AC_MSG_ERROR([GNU Multi Precision library gmp not found])])
455         AC_MSG_CHECKING([mpz_powm_sec])
456         if test x$mpz_powm_sec = xyes; then
457                 AC_TRY_COMPILE(
458                         [#include "gmp.h"],
459                         [
460                                 void *x = mpz_powm_sec;
461                         ],
462                         [AC_MSG_RESULT([yes]); AC_DEFINE(HAVE_MPZ_POWM_SEC)], [AC_MSG_RESULT([no])]
463                 )
464         else
465                 AC_MSG_RESULT([disabled])
466         fi
467         LIBS=$saved_LIBS
468         AC_MSG_CHECKING([gmp.h version >= 4.1.4])
469         AC_TRY_COMPILE(
470                 [#include "gmp.h"],
471                 [
472                         #if (__GNU_MP_VERSION*100 +  __GNU_MP_VERSION_MINOR*10 + __GNU_MP_VERSION_PATCHLEVEL) < 414
473                                 #error bad gmp
474                         #endif
475                 ],
476                 [AC_MSG_RESULT([yes])], [AC_MSG_RESULT([no]); AC_MSG_ERROR([No usable gmp.h found!])]
477         )
478 fi
479
480 if test x$ldap = xtrue; then
481         AC_HAVE_LIBRARY([ldap],[LIBS="$LIBS"],[AC_MSG_ERROR([LDAP library ldap not found])])
482         AC_HAVE_LIBRARY([lber],[LIBS="$LIBS"],[AC_MSG_ERROR([LDAP library lber not found])])
483         AC_CHECK_HEADER([ldap.h],,[AC_MSG_ERROR([LDAP header ldap.h not found!])])
484 fi
485
486 if test x$curl = xtrue; then
487         AC_HAVE_LIBRARY([curl],[LIBS="$LIBS"],[AC_MSG_ERROR([CURL library curl not found])])
488         AC_CHECK_HEADER([curl/curl.h],,[AC_MSG_ERROR([CURL header curl/curl.h not found!])])
489 fi
490
491 if test x$xml = xtrue; then
492         PKG_CHECK_MODULES(xml, [libxml-2.0])
493         AC_SUBST(xml_CFLAGS)
494         AC_SUBST(xml_LIBS)
495 fi
496
497 if test x$dumm = xtrue; then
498         PKG_CHECK_MODULES(gtk, [gtk+-2.0 vte])
499         AC_SUBST(gtk_CFLAGS)
500         AC_SUBST(gtk_LIBS)
501         AC_CHECK_PROGS(RUBY, ruby)
502         AC_MSG_CHECKING([for Ruby header files])
503         if test -n "$RUBY"; then
504                 RUBYDIR=`($RUBY -rmkmf -e 'print Config::CONFIG[["archdir"]] || $archdir') 2>/dev/null`
505                 if test -n "$RUBYDIR"; then
506                         dirs="$RUBYDIR"
507                         RUBYINCLUDE=none
508                         for i in $dirs; do
509                                 if test -r $i/ruby.h; then
510                                         AC_MSG_RESULT([$i])
511                                         RUBYINCLUDE="-I$i"
512                                         break;
513                                 fi
514                         done
515                         if test x"$RUBYINCLUDE" = xnone; then
516                                 AC_MSG_ERROR([ruby.h not found])
517                         fi
518                         AC_SUBST(RUBYINCLUDE)
519                 else
520                         AC_MSG_ERROR([unable to determine ruby configuration])
521                 fi
522         else
523                 AC_MSG_ERROR([don't know how to run ruby])
524         fi
525 fi
526
527 if test x$fast = xtrue; then
528         AC_HAVE_LIBRARY([neo_cgi],[LIBS="$LIBS"],[AC_MSG_ERROR([ClearSilver library neo_cgi not found!])])
529         AC_HAVE_LIBRARY([neo_utl],[LIBS="$LIBS"],[AC_MSG_ERROR([ClearSilver library neo_utl not found!])])
530         AC_HAVE_LIBRARY([z],[LIBS="$LIBS"],[AC_MSG_ERROR([ClearSilver dependency zlib not found!])])
531 dnl autoconf does not like CamelCase!? How to fix this?
532 dnl     AC_CHECK_HEADER([ClearSilver/ClearSilver.h],,[AC_MSG_ERROR([ClearSilver header file ClearSilver/ClearSilver.h not found!])])
533
534         AC_HAVE_LIBRARY([fcgi],[LIBS="$LIBS"],[AC_MSG_ERROR([FastCGI library fcgi not found!])])
535         AC_CHECK_HEADER([fcgiapp.h],,[AC_MSG_ERROR([FastCGI header file fcgiapp.h not found!])])
536 fi
537
538 if test x$mysql = xtrue; then
539         AC_PATH_PROG([MYSQLCONFIG], [mysql_config], [], [$PATH:/bin:/usr/bin:/usr/local/bin])
540         if test x$MYSQLCONFIG = x; then
541                 AC_MSG_ERROR([mysql_config not found!])
542         fi
543         AC_SUBST(MYSQLLIB, `$MYSQLCONFIG --libs_r`)
544         AC_SUBST(MYSQLCFLAG, `$MYSQLCONFIG --cflags`)
545 fi
546
547 if test x$sqlite = xtrue; then
548         AC_HAVE_LIBRARY([sqlite3],[LIBS="$LIBS"],[AC_MSG_ERROR([SQLite library sqlite3 not found])])
549         AC_CHECK_HEADER([sqlite3.h],,[AC_MSG_ERROR([SQLite header sqlite3.h not found!])])
550         AC_MSG_CHECKING([sqlite3_prepare_v2])
551         AC_TRY_COMPILE(
552                 [#include <sqlite3.h>],
553                 [
554                         void *test = sqlite3_prepare_v2;
555                 ],
556                 [AC_MSG_RESULT([yes])]; AC_DEFINE_UNQUOTED(HAVE_SQLITE3_PREPARE_V2, 1), [AC_MSG_RESULT([no])])
557         AC_MSG_CHECKING([sqlite3.h version >= 3.3.1])
558         AC_TRY_COMPILE(
559                 [#include <sqlite3.h>],
560                 [
561                         #if SQLITE_VERSION_NUMBER < 3003001
562                                 #error bad sqlite
563                         #endif
564                 ],
565                 [AC_MSG_RESULT([yes])], [AC_MSG_RESULT([no]); AC_MSG_ERROR([SQLite version >= 3.3.1 required!])])
566 fi
567
568 if test x$openssl = xtrue; then
569         AC_HAVE_LIBRARY([crypto],[LIBS="$LIBS"],[AC_MSG_ERROR([OpenSSL crypto library not found])])
570         AC_CHECK_HEADER([openssl/evp.h],,[AC_MSG_ERROR([OpenSSL header openssl/evp.h not found!])])
571 fi
572
573 if test x$gcrypt = xtrue; then
574         AC_HAVE_LIBRARY([gcrypt],[LIBS="$LIBS"],[AC_MSG_ERROR([gcrypt library not found])])
575         AC_CHECK_HEADER([gcrypt.h],,[AC_MSG_ERROR([gcrypt header gcrypt.h not found!])])
576         AC_MSG_CHECKING([gcrypt CAMELLIA cipher])
577         AC_TRY_COMPILE(
578                 [#include <gcrypt.h>],
579                 [enum gcry_cipher_algos alg = GCRY_CIPHER_CAMELLIA128;],
580                 [AC_MSG_RESULT([yes]); AC_DEFINE([HAVE_GCRY_CIPHER_CAMELLIA])],
581                 [AC_MSG_RESULT([no])]
582         )
583 fi
584
585 if test x$uci = xtrue; then
586         AC_HAVE_LIBRARY([uci],[LIBS="$LIBS"],[AC_MSG_ERROR([UCI library libuci not found])])
587         AC_CHECK_HEADER([uci.h],,[AC_MSG_ERROR([UCI header uci.h not found!])])
588 fi
589
590 if test x$android = xtrue; then
591         AC_HAVE_LIBRARY([cutils],[LIBS="$LIBS"],[AC_MSG_ERROR([Android library libcutils not found])])
592         AC_CHECK_HEADER([cutils/properties.h],,[AC_MSG_ERROR([Android header cutils/properties.h not found!])])
593         dnl we have to force the use of libdl here because the autodetection
594         dnl above does not work correctly when cross-compiling for android.
595         DLLIB="-ldl"
596         AC_SUBST(DLLIB)
597 fi
598
599 if test x$nm = xtrue; then
600         PKG_CHECK_EXISTS([libnm-glib],
601                 [PKG_CHECK_MODULES(nm, [NetworkManager gthread-2.0 libnm-glib libnm-glib-vpn])],
602                 [PKG_CHECK_MODULES(nm, [NetworkManager gthread-2.0 libnm_glib libnm_glib_vpn])]
603         )
604         AC_SUBST(nm_CFLAGS)
605         AC_SUBST(nm_LIBS)
606 fi
607
608 if test x$eap_gtc = xtrue; then
609         AC_HAVE_LIBRARY([pam],[LIBS="$LIBS"],[AC_MSG_ERROR([PAM library not found])])
610         AC_CHECK_HEADER([security/pam_appl.h],,[AC_MSG_ERROR([PAM header security/pam_appl.h not found!])])
611 fi
612
613 if test x$capabilities = xlibcap; then
614         AC_HAVE_LIBRARY([cap],[LIBS="$LIBS"],[AC_MSG_ERROR([libcap library not found])])
615         AC_CHECK_HEADER([sys/capability.h],,[AC_MSG_ERROR([libcap header sys/capability.h not found!])])
616 fi
617
618 if test x$integrity_test = xtrue; then
619         AC_MSG_CHECKING([for dladdr()])
620         AC_TRY_COMPILE(
621                 [#define _GNU_SOURCE
622                  #include <dlfcn.h>],
623                 [Dl_info info; dladdr(main, &info);],
624                 [AC_MSG_RESULT([yes])], [AC_MSG_RESULT([no]);
625                  AC_MSG_ERROR([dladdr() not supported, required by integrity-test!])]
626         )
627         AC_MSG_CHECKING([for dl_iterate_phdr()])
628         AC_TRY_COMPILE(
629                 [#define _GNU_SOURCE
630                  #include <link.h>],
631                 [dl_iterate_phdr((void*)0, (void*)0);],
632                 [AC_MSG_RESULT([yes])], [AC_MSG_RESULT([no]);
633                  AC_MSG_ERROR([dl_iterate_phdr() not supported, required by integrity-test!])]
634         )
635 fi
636
637 dnl ==========================================================
638 dnl  collect all plugins for libstrongswan, libhydra and pluto
639 dnl ==========================================================
640
641 libstrongswan_plugins=
642 libhydra_plugins=
643 pluto_plugins=
644
645 if test x$test_vectors = xtrue; then
646         libstrongswan_plugins=${libstrongswan_plugins}" test-vectors"
647         pluto_plugins=${pluto_plugins}" test-vectors"
648 fi
649 if test x$curl = xtrue; then
650         libstrongswan_plugins=${libstrongswan_plugins}" curl"
651         pluto_plugins=${pluto_plugins}" curl"
652 fi
653 if test x$ldap = xtrue; then
654         libstrongswan_plugins=${libstrongswan_plugins}" ldap"
655         pluto_plugins=${pluto_plugins}" ldap"
656 fi
657 if test x$aes = xtrue; then
658         libstrongswan_plugins=${libstrongswan_plugins}" aes"
659         pluto_plugins=${pluto_plugins}" aes"
660 fi
661 if test x$des = xtrue; then
662         libstrongswan_plugins=${libstrongswan_plugins}" des"
663         pluto_plugins=${pluto_plugins}" des"
664 fi
665 if test x$blowfish = xtrue; then
666         libstrongswan_plugins=${libstrongswan_plugins}" blowfish"
667         pluto_plugins=${pluto_plugins}" blowfish"
668 fi
669 if test x$sha1 = xtrue; then
670         libstrongswan_plugins=${libstrongswan_plugins}" sha1"
671         pluto_plugins=${pluto_plugins}" sha1"
672 fi
673 if test x$sha2 = xtrue; then
674         libstrongswan_plugins=${libstrongswan_plugins}" sha2"
675         pluto_plugins=${pluto_plugins}" sha2"
676 fi
677 if test x$md4 = xtrue; then
678         libstrongswan_plugins=${libstrongswan_plugins}" md4"
679 fi
680 if test x$md5 = xtrue; then
681         libstrongswan_plugins=${libstrongswan_plugins}" md5"
682         pluto_plugins=${pluto_plugins}" md5"
683 fi
684 if test x$random = xtrue; then
685         libstrongswan_plugins=${libstrongswan_plugins}" random"
686         pluto_plugins=${pluto_plugins}" random"
687 fi
688 if test x$x509 = xtrue; then
689         libstrongswan_plugins=${libstrongswan_plugins}" x509"
690         pluto_plugins=${pluto_plugins}" x509"
691 fi
692 if test x$pubkey = xtrue; then
693         libstrongswan_plugins=${libstrongswan_plugins}" pubkey"
694         pluto_plugins=${pluto_plugins}" pubkey"
695 fi
696 if test x$pkcs1 = xtrue; then
697         libstrongswan_plugins=${libstrongswan_plugins}" pkcs1"
698         pluto_plugins=${pluto_plugins}" pkcs1"
699 fi
700 if test x$pgp = xtrue; then
701         libstrongswan_plugins=${libstrongswan_plugins}" pgp"
702         pluto_plugins=${pluto_plugins}" pgp"
703 fi
704 if test x$dnskey = xtrue; then
705         libstrongswan_plugins=${libstrongswan_plugins}" dnskey"
706         pluto_plugins=${pluto_plugins}" dnskey"
707 fi
708 if test x$pem = xtrue; then
709         libstrongswan_plugins=${libstrongswan_plugins}" pem"
710         pluto_plugins=${pluto_plugins}" pem"
711 fi
712 if test x$mysql = xtrue; then
713         libstrongswan_plugins=${libstrongswan_plugins}" mysql"
714         pluto_plugins=${pluto_plugins}" mysql"
715 fi
716 if test x$sqlite = xtrue; then
717         libstrongswan_plugins=${libstrongswan_plugins}" sqlite"
718         pluto_plugins=${pluto_plugins}" sqlite"
719 fi
720 if test x$padlock = xtrue; then
721         libstrongswan_plugins=${libstrongswan_plugins}" padlock"
722 fi
723 if test x$openssl = xtrue; then
724         libstrongswan_plugins=${libstrongswan_plugins}" openssl"
725         pluto_plugins=${pluto_plugins}" openssl"
726 fi
727 if test x$gcrypt = xtrue; then
728         libstrongswan_plugins=${libstrongswan_plugins}" gcrypt"
729         pluto_plugins=${pluto_plugins}" gcrypt"
730 fi
731 if test x$fips_prf = xtrue; then
732         libstrongswan_plugins=${libstrongswan_plugins}" fips-prf"
733 fi
734 if test x$xcbc = xtrue; then
735         libstrongswan_plugins=${libstrongswan_plugins}" xcbc"
736 fi
737 if test x$hmac = xtrue; then
738         libstrongswan_plugins=${libstrongswan_plugins}" hmac"
739         pluto_plugins=${pluto_plugins}" hmac"
740 fi
741 if test x$agent = xtrue; then
742         libstrongswan_plugins=${libstrongswan_plugins}" agent"
743 fi
744 if test x$gmp = xtrue; then
745         libstrongswan_plugins=${libstrongswan_plugins}" gmp"
746         pluto_plugins=${pluto_plugins}" gmp"
747 fi
748 if test x$attr_sql = xtrue -o x$sql = xtrue; then
749         libhydra_plugins=${libhydra_plugins}" attr-sql"
750         pluto_plugins=${pluto_plugins}" attr-sql"
751 fi
752
753 AC_SUBST(libstrongswan_plugins)
754 AC_SUBST(libhydra_plugins)
755 AC_SUBST(pluto_plugins)
756
757 dnl =========================
758 dnl  set Makefile.am vars
759 dnl =========================
760
761 dnl libstrongswan plugins
762 dnl =====================
763 AM_CONDITIONAL(USE_TEST_VECTORS, test x$test_vectors = xtrue)
764 AM_CONDITIONAL(USE_CURL, test x$curl = xtrue)
765 AM_CONDITIONAL(USE_LDAP, test x$ldap = xtrue)
766 AM_CONDITIONAL(USE_AES, test x$aes = xtrue)
767 AM_CONDITIONAL(USE_DES, test x$des = xtrue)
768 AM_CONDITIONAL(USE_BLOWFISH, test x$blowfish = xtrue)
769 AM_CONDITIONAL(USE_MD4, test x$md4 = xtrue)
770 AM_CONDITIONAL(USE_MD5, test x$md5 = xtrue)
771 AM_CONDITIONAL(USE_SHA1, test x$sha1 = xtrue)
772 AM_CONDITIONAL(USE_SHA2, test x$sha2 = xtrue)
773 AM_CONDITIONAL(USE_FIPS_PRF, test x$fips_prf = xtrue)
774 AM_CONDITIONAL(USE_GMP, test x$gmp = xtrue)
775 AM_CONDITIONAL(USE_RANDOM, test x$random = xtrue)
776 AM_CONDITIONAL(USE_X509, test x$x509 = xtrue)
777 AM_CONDITIONAL(USE_PUBKEY, test x$pubkey = xtrue)
778 AM_CONDITIONAL(USE_PKCS1, test x$pkcs1 = xtrue)
779 AM_CONDITIONAL(USE_PGP, test x$pgp = xtrue)
780 AM_CONDITIONAL(USE_DNSKEY, test x$dnskey = xtrue)
781 AM_CONDITIONAL(USE_PEM, test x$pem = xtrue)
782 AM_CONDITIONAL(USE_HMAC, test x$hmac = xtrue)
783 AM_CONDITIONAL(USE_XCBC, test x$xcbc = xtrue)
784 AM_CONDITIONAL(USE_MYSQL, test x$mysql = xtrue)
785 AM_CONDITIONAL(USE_SQLITE, test x$sqlite = xtrue)
786 AM_CONDITIONAL(USE_ATTR_SQL, test x$attr_sql = xtrue -o x$sql = xtrue)
787 AM_CONDITIONAL(USE_PADLOCK, test x$padlock = xtrue)
788 AM_CONDITIONAL(USE_OPENSSL, test x$openssl = xtrue)
789 AM_CONDITIONAL(USE_GCRYPT, test x$gcrypt = xtrue)
790 AM_CONDITIONAL(USE_AGENT, test x$agent = xtrue)
791
792 dnl charon plugins
793 dnl ==============
794 AM_CONDITIONAL(USE_STROKE, test x$stroke = xtrue)
795 AM_CONDITIONAL(USE_MEDSRV, test x$medsrv = xtrue)
796 AM_CONDITIONAL(USE_MEDCLI, test x$medcli = xtrue)
797 AM_CONDITIONAL(USE_NM, test x$nm = xtrue)
798 AM_CONDITIONAL(USE_UCI, test x$uci = xtrue)
799 AM_CONDITIONAL(USE_ANDROID, test x$android = xtrue)
800 AM_CONDITIONAL(USE_SMP, test x$smp = xtrue)
801 AM_CONDITIONAL(USE_SQL, test x$sql = xtrue)
802 AM_CONDITIONAL(USE_UPDOWN, test x$updown = xtrue)
803 AM_CONDITIONAL(USE_ATTR, test x$attr = xtrue)
804 AM_CONDITIONAL(USE_DHCP, test x$dhcp = xtrue)
805 AM_CONDITIONAL(USE_RESOLVE, test x$resolve = xtrue)
806 AM_CONDITIONAL(USE_UNIT_TESTS, test x$unit_tests = xtrue)
807 AM_CONDITIONAL(USE_LOAD_TESTER, test x$load_tester = xtrue)
808 AM_CONDITIONAL(USE_EAP_SIM, test x$eap_sim = xtrue)
809 AM_CONDITIONAL(USE_EAP_SIM_FILE, test x$eap_sim_file = xtrue)
810 AM_CONDITIONAL(USE_EAP_SIMAKA_PSEUDONYM, test x$eap_simaka_pseudonym = xtrue)
811 AM_CONDITIONAL(USE_EAP_SIMAKA_REAUTH, test x$eap_simaka_reauth = xtrue)
812 AM_CONDITIONAL(USE_EAP_IDENTITY, test x$eap_identity = xtrue)
813 AM_CONDITIONAL(USE_EAP_MD5, test x$eap_md5 = xtrue)
814 AM_CONDITIONAL(USE_EAP_GTC, test x$eap_gtc = xtrue)
815 AM_CONDITIONAL(USE_EAP_AKA, test x$eap_aka = xtrue)
816 AM_CONDITIONAL(USE_EAP_AKA_3GPP2, test x$eap_aka_3gpp2 = xtrue)
817 AM_CONDITIONAL(USE_EAP_MSCHAPV2, test x$eap_mschapv2 = xtrue)
818 AM_CONDITIONAL(USE_EAP_RADIUS, test x$eap_radius = xtrue)
819 AM_CONDITIONAL(USE_KERNEL_NETLINK, test x$kernel_netlink = xtrue)
820 AM_CONDITIONAL(USE_KERNEL_PFKEY, test x$kernel_pfkey = xtrue)
821 AM_CONDITIONAL(USE_KERNEL_PFROUTE, test x$kernel_pfroute = xtrue)
822 AM_CONDITIONAL(USE_KERNEL_KLIPS, test x$kernel_klips = xtrue)
823 AM_CONDITIONAL(USE_SOCKET_DEFAULT, test x$socket_default = xtrue)
824 AM_CONDITIONAL(USE_SOCKET_RAW, test x$socket_raw = xtrue)
825 AM_CONDITIONAL(USE_SOCKET_DYNAMIC, test x$socket_dynamic = xtrue)
826 AM_CONDITIONAL(USE_FARP, test x$farp = xtrue)
827
828 dnl other options
829 dnl =============
830 AM_CONDITIONAL(USE_SMARTCARD, test x$smartcard = xtrue)
831 AM_CONDITIONAL(USE_CISCO_QUIRKS, test x$cisco_quirks = xtrue)
832 AM_CONDITIONAL(USE_LEAK_DETECTIVE, test x$leak_detective = xtrue)
833 AM_CONDITIONAL(USE_LOCK_PROFILER, test x$lock_profiler = xtrue)
834 AM_CONDITIONAL(USE_NAT_TRANSPORT, test x$nat_transport = xtrue)
835 AM_CONDITIONAL(USE_VENDORID, test x$vendor_id = xtrue)
836 AM_CONDITIONAL(USE_XAUTH_VID, test x$xauth_vid = xtrue)
837 AM_CONDITIONAL(USE_DUMM, test x$dumm = xtrue)
838 AM_CONDITIONAL(USE_FAST, test x$fast = xtrue)
839 AM_CONDITIONAL(USE_MANAGER, test x$manager = xtrue)
840 AM_CONDITIONAL(USE_ME, test x$mediation = xtrue)
841 AM_CONDITIONAL(USE_INTEGRITY_TEST, test x$integrity_test = xtrue)
842 AM_CONDITIONAL(USE_CAPABILITIES, test x$capabilities = xlibcap)
843 AM_CONDITIONAL(USE_PLUTO, test x$pluto = xtrue)
844 AM_CONDITIONAL(USE_THREADS, test x$threads = xtrue)
845 AM_CONDITIONAL(USE_CHARON, test x$charon = xtrue)
846 AM_CONDITIONAL(USE_TOOLS, test x$tools = xtrue)
847 AM_CONDITIONAL(USE_SCRIPTS, test x$scripts = xtrue)
848 AM_CONDITIONAL(USE_LIBSTRONGSWAN, test x$charon = xtrue -o x$pluto = xtrue -o x$tools = xtrue)
849 AM_CONDITIONAL(USE_LIBHYDRA, test x$charon = xtrue -o x$pluto = xtrue)
850 AM_CONDITIONAL(USE_FILE_CONFIG, test x$pluto = xtrue -o x$stroke = xtrue)
851 AM_CONDITIONAL(USE_VSTR, test x$vstr = xtrue)
852 AM_CONDITIONAL(USE_SIMAKA, test x$simaka = xtrue)
853 AM_CONDITIONAL(MONOLITHIC, test x$monolithic = xtrue)
854
855 dnl ==============================
856 dnl  set global definitions
857 dnl ==============================
858
859 if test x$mediation = xtrue; then
860         AC_DEFINE(ME)
861 fi
862 if test x$capabilities = xlibcap; then
863         AC_DEFINE(CAPABILITIES)
864 fi
865 if test x$monolithic = xtrue; then
866         AC_DEFINE(MONOLITHIC)
867 fi
868
869
870 dnl ==============================
871 dnl  build Makefiles
872 dnl ==============================
873
874 AC_OUTPUT(
875         Makefile
876         src/Makefile
877         src/include/Makefile
878         src/libstrongswan/Makefile
879         src/libstrongswan/plugins/aes/Makefile
880         src/libstrongswan/plugins/des/Makefile
881         src/libstrongswan/plugins/blowfish/Makefile
882         src/libstrongswan/plugins/md4/Makefile
883         src/libstrongswan/plugins/md5/Makefile
884         src/libstrongswan/plugins/sha1/Makefile
885         src/libstrongswan/plugins/sha2/Makefile
886         src/libstrongswan/plugins/fips_prf/Makefile
887         src/libstrongswan/plugins/gmp/Makefile
888         src/libstrongswan/plugins/random/Makefile
889         src/libstrongswan/plugins/hmac/Makefile
890         src/libstrongswan/plugins/xcbc/Makefile
891         src/libstrongswan/plugins/x509/Makefile
892         src/libstrongswan/plugins/pubkey/Makefile
893         src/libstrongswan/plugins/pkcs1/Makefile
894         src/libstrongswan/plugins/pgp/Makefile
895         src/libstrongswan/plugins/dnskey/Makefile
896         src/libstrongswan/plugins/pem/Makefile
897         src/libstrongswan/plugins/curl/Makefile
898         src/libstrongswan/plugins/ldap/Makefile
899         src/libstrongswan/plugins/mysql/Makefile
900         src/libstrongswan/plugins/sqlite/Makefile
901         src/libstrongswan/plugins/padlock/Makefile
902         src/libstrongswan/plugins/openssl/Makefile
903         src/libstrongswan/plugins/gcrypt/Makefile
904         src/libstrongswan/plugins/agent/Makefile
905         src/libstrongswan/plugins/test_vectors/Makefile
906         src/libhydra/Makefile
907         src/libhydra/plugins/attr_sql/Makefile
908         src/libfreeswan/Makefile
909         src/libsimaka/Makefile
910         src/pluto/Makefile
911         src/whack/Makefile
912         src/charon/Makefile
913         src/libcharon/Makefile
914         src/libcharon/plugins/eap_aka/Makefile
915         src/libcharon/plugins/eap_aka_3gpp2/Makefile
916         src/libcharon/plugins/eap_identity/Makefile
917         src/libcharon/plugins/eap_md5/Makefile
918         src/libcharon/plugins/eap_gtc/Makefile
919         src/libcharon/plugins/eap_sim/Makefile
920         src/libcharon/plugins/eap_sim_file/Makefile
921         src/libcharon/plugins/eap_simaka_pseudonym/Makefile
922         src/libcharon/plugins/eap_simaka_reauth/Makefile
923         src/libcharon/plugins/eap_mschapv2/Makefile
924         src/libcharon/plugins/eap_radius/Makefile
925         src/libcharon/plugins/kernel_netlink/Makefile
926         src/libcharon/plugins/kernel_pfkey/Makefile
927         src/libcharon/plugins/kernel_pfroute/Makefile
928         src/libcharon/plugins/kernel_klips/Makefile
929         src/libcharon/plugins/socket_default/Makefile
930         src/libcharon/plugins/socket_raw/Makefile
931         src/libcharon/plugins/socket_dynamic/Makefile
932         src/libcharon/plugins/farp/Makefile
933         src/libcharon/plugins/smp/Makefile
934         src/libcharon/plugins/sql/Makefile
935         src/libcharon/plugins/medsrv/Makefile
936         src/libcharon/plugins/medcli/Makefile
937         src/libcharon/plugins/nm/Makefile
938         src/libcharon/plugins/uci/Makefile
939         src/libcharon/plugins/android/Makefile
940         src/libcharon/plugins/stroke/Makefile
941         src/libcharon/plugins/updown/Makefile
942         src/libcharon/plugins/attr/Makefile
943         src/libcharon/plugins/dhcp/Makefile
944         src/libcharon/plugins/resolve/Makefile
945         src/libcharon/plugins/unit_tester/Makefile
946         src/libcharon/plugins/load_tester/Makefile
947         src/stroke/Makefile
948         src/ipsec/Makefile
949         src/starter/Makefile
950         src/_updown/Makefile
951         src/_updown_espmark/Makefile
952         src/_copyright/Makefile
953         src/openac/Makefile
954         src/scepclient/Makefile
955         src/pki/Makefile
956         src/dumm/Makefile
957         src/dumm/ext/extconf.rb
958         src/libfast/Makefile
959         src/manager/Makefile
960         src/medsrv/Makefile
961         src/checksum/Makefile
962         scripts/Makefile
963         testing/Makefile
964 )