configure.in

   1 dnl  configure.in for linux strongSwan
   2 dnl  Copyright (C) 2006 Martin Willi
   3 dnl  Hochschule fuer Technik Rapperswil
   4 dnl
   5 dnl  This program is free software; you can redistribute it and/or modify it
   6 dnl  under the terms of the GNU General Public License as published by the
   7 dnl  Free Software Foundation; either version 2 of the License, or (at your
   8 dnl  option) any later version.  See <http://www.fsf.org/copyleft/gpl.txt>.
   9 dnl
  10 dnl  This program is distributed in the hope that it will be useful, but
  11 dnl  WITHOUT ANY WARRANTY; without even the implied warranty of MERCHANTABILITY
  12 dnl  or FITNESS FOR A PARTICULAR PURPOSE.  See the GNU General Public License
  13 dnl  for more details.
  14
  15 dnl ===========================
  16 dnl  initialize & set some vars
  17 dnl ===========================
  18
  19 AC_INIT(strongSwan,5.0.3dr1)
  20 AM_INIT_AUTOMAKE(tar-ustar)
  21 AC_CONFIG_MACRO_DIR([m4/config])
  22 AC_CONFIG_HEADERS([config.h])
  23 AC_DEFINE([CONFIG_H_INCLUDED], [], [defined if config.h included])
  24 PKG_PROG_PKG_CONFIG
  25
  26 dnl =================================
  27 dnl  check --enable-xxx & --with-xxx
  28 dnl =================================
  29
  30 m4_include(m4/macros/with.m4)
  31
  32 ARG_WITH_SUBST([random-device],      [/dev/random], [set the device to read real random data from])
  33 ARG_WITH_SUBST([urandom-device],     [/dev/urandom], [set the device to read pseudo random data from])
  34 ARG_WITH_SUBST([strongswan-conf],    [${sysconfdir}/strongswan.conf], [set the strongswan.conf file location])
  35 ARG_WITH_SUBST([resolv-conf],        [${sysconfdir}/resolv.conf], [set the file to use in DNS handler plugin])
  36 ARG_WITH_SUBST([piddir],             [/var/run], [set path for PID and UNIX socket files])
  37 ARG_WITH_SUBST([ipsecdir],           [${libexecdir%/}/ipsec], [set installation path for ipsec tools])
  38 ARG_WITH_SUBST([ipseclibdir],        [${libdir%/}/ipsec], [set installation path for ipsec libraries])
  39 ARG_WITH_SUBST([plugindir],          [${ipseclibdir%/}/plugins], [set the installation path of plugins])
  40 ARG_WITH_SUBST([imcvdir],            [${ipseclibdir%/}/imcvs], [set the installation path of IMC and IMV dynamic librariers])
  41 ARG_WITH_SUBST([nm-ca-dir],          [/usr/share/ca-certificates], [directory the NM backend uses to look up trusted root certificates])
  42 ARG_WITH_SUBST([linux-headers],      [\${top_srcdir}/src/include], [set directory of linux header files to use])
  43 ARG_WITH_SUBST([routing-table],      [220], [set routing table to use for IPsec routes])
  44 ARG_WITH_SUBST([routing-table-prio], [220], [set priority for IPsec routing table])
  45 ARG_WITH_SUBST([ipsec-script],       [ipsec], [change the name of the ipsec script])
  46
  47 ARG_WITH_SET([tss],                  [no], [set implementation of the Trusted Computing Group's Software Stack (TSS). Currently the only supported value is "trousers"])
  48 ARG_WITH_SET([capabilities],         [no], [set capability dropping library. Currently supported values are "libcap" and "native"])
  49 ARG_WITH_SET([mpz_powm_sec],         [yes], [use the more side-channel resistant mpz_powm_sec in libgmp, if available])
  50 ARG_WITH_SET([dev-headers],          [no], [install strongSwan development headers to directory.])
  51
  52 if test -n "$PKG_CONFIG"; then
  53         systemdsystemunitdir_default=$($PKG_CONFIG --variable=systemdsystemunitdir systemd)
  54 fi
  55 ARG_WITH_SET([systemdsystemunitdir], [$systemdsystemunitdir_default], [directory for systemd service files])
  56 AM_CONDITIONAL(HAVE_SYSTEMD, [test -n "$systemdsystemunitdir" -a "x$systemdsystemunitdir" != xno])
  57 AC_SUBST(systemdsystemunitdir)
  58
  59 AC_ARG_WITH(
  60         [user],
  61         AS_HELP_STRING([--with-user=user],[change user of the daemons to "user" after startup (default is "root").]),
  62         [AC_DEFINE_UNQUOTED([IPSEC_USER], "$withval", [username to run daemon with])
  63          AC_SUBST(ipsecuser, "$withval")],
  64         [AC_SUBST(ipsecuser, "root")]
  65 )
  66
  67 AC_ARG_WITH(
  68         [group],
  69         AS_HELP_STRING([--with-group=group],[change group of the daemons to "group" after startup (default is "root").]),
  70         [AC_DEFINE_UNQUOTED(IPSEC_GROUP, "$withval", [groupname to run daemon with])
  71          AC_SUBST(ipsecgroup, "$withval")],
  72         [AC_SUBST(ipsecgroup, "root")]
  73 )
  74
  75 AC_ARG_WITH(
  76         [charon-udp-port],
  77         AS_HELP_STRING([--with-charon-udp-port=port],[UDP port used by charon locally (default 500). Set to 0 to allocate randomly.]),
  78         [AC_DEFINE_UNQUOTED(CHARON_UDP_PORT, [$withval], [UDP port used by charon locally])
  79          AC_SUBST(charon_udp_port, [$withval])],
  80         [AC_SUBST(charon_udp_port, 500)]
  81 )
  82
  83 AC_ARG_WITH(
  84         [charon-natt-port],
  85         AS_HELP_STRING([--with-charon-natt-port=port],[UDP port used by charon locally in case a NAT is detected (must be different from charon-udp-port, default 4500). Set to 0 to allocate randomly.]),
  86         [AC_DEFINE_UNQUOTED(CHARON_NATT_PORT, [$withval], [UDP post used by charon locally in case a NAT is detected])
  87          AC_SUBST(charon_natt_port, [$withval])],
  88         [AC_SUBST(charon_natt_port, 4500)]
  89 )
  90
  91 AC_MSG_CHECKING([configured UDP ports ($charon_udp_port, $charon_natt_port)])
  92 if test x$charon_udp_port != x0 -a x$charon_udp_port = x$charon_natt_port; then
  93         AC_MSG_ERROR(the ports have to be different)
  94 else
  95         AC_MSG_RESULT(ok)
  96 fi
  97
  98 # convert script name to uppercase
  99 AC_SUBST(ipsec_script_upper, [`echo -n "$ipsec_script" | tr a-z A-Z`])
 100
 101 m4_include(m4/macros/enable-disable.m4)
 102
 103 ARG_ENABL_SET([curl],           [enable CURL fetcher plugin to fetch files via libcurl. Requires libcurl.])
 104 ARG_ENABL_SET([soup],           [enable soup fetcher plugin to fetch from HTTP via libsoup. Requires libsoup.])
 105 ARG_ENABL_SET([ldap],           [enable LDAP fetching plugin to fetch files via libldap. Requires openLDAP.])
 106 ARG_DISBL_SET([aes],            [disable AES software implementation plugin.])
 107 ARG_DISBL_SET([des],            [disable DES/3DES software implementation plugin.])
 108 ARG_ENABL_SET([blowfish],       [enable Blowfish software implementation plugin.])
 109 ARG_ENABL_SET([md4],            [enable MD4 software implementation plugin.])
 110 ARG_DISBL_SET([md5],            [disable MD5 software implementation plugin.])
 111 ARG_DISBL_SET([sha1],           [disable SHA1 software implementation plugin.])
 112 ARG_DISBL_SET([sha2],           [disable SHA256/SHA384/SHA512 software implementation plugin.])
 113 ARG_DISBL_SET([fips-prf],       [disable FIPS PRF software implementation plugin.])
 114 ARG_DISBL_SET([gmp],            [disable GNU MP (libgmp) based crypto implementation plugin.])
 115 ARG_ENABL_SET([rdrand],         [enable Intel RDRAND random generator plugin.])
 116 ARG_DISBL_SET([random],         [disable RNG implementation on top of /dev/(u)random.])
 117 ARG_DISBL_SET([nonce],          [disable nonce generation plugin.])
 118 ARG_DISBL_SET([x509],           [disable X509 certificate implementation plugin.])
 119 ARG_DISBL_SET([revocation],     [disable X509 CRL/OCSP revocation check plugin.])
 120 ARG_DISBL_SET([constraints],    [disable advanced X509 constraint checking plugin.])
 121 ARG_DISBL_SET([pubkey],         [disable RAW public key support plugin.])
 122 ARG_DISBL_SET([pkcs1],          [disable PKCS1 key decoding plugin.])
 123 ARG_DISBL_SET([pkcs7],          [disable PKCS7 container support plugin.])
 124 ARG_DISBL_SET([pkcs8],          [disable PKCS8 private key decoding plugin.])
 125 ARG_DISBL_SET([pgp],            [disable PGP key decoding plugin.])
 126 ARG_DISBL_SET([dnskey],         [disable DNS RR key decoding plugin.])
 127 ARG_DISBL_SET([pem],            [disable PEM decoding plugin.])
 128 ARG_DISBL_SET([hmac],           [disable HMAC crypto implementation plugin.])
 129 ARG_DISBL_SET([cmac],           [disable CMAC crypto implementation plugin.])
 130 ARG_DISBL_SET([xcbc],           [disable xcbc crypto implementation plugin.])
 131 ARG_ENABL_SET([af-alg],         [enable AF_ALG crypto interface to Linux Crypto API.])
 132 ARG_ENABL_SET([test-vectors],   [enable plugin providing crypto test vectors.])
 133 ARG_ENABL_SET([mysql],          [enable MySQL database support. Requires libmysqlclient_r.])
 134 ARG_ENABL_SET([sqlite],         [enable SQLite database support. Requires libsqlite3.])
 135 ARG_DISBL_SET([stroke],         [disable charons stroke configuration backend.])
 136 ARG_ENABL_SET([medsrv],         [enable mediation server web frontend and daemon plugin.])
 137 ARG_ENABL_SET([medcli],         [enable mediation client configuration database plugin.])
 138 ARG_ENABL_SET([smp],            [enable SMP configuration and control interface. Requires libxml.])
 139 ARG_ENABL_SET([sql],            [enable SQL database configuration backend.])
 140 ARG_ENABL_SET([leak-detective], [enable malloc hooks to find memory leaks.])
 141 ARG_ENABL_SET([lock-profiler],  [enable lock/mutex profiling code.])
 142 ARG_ENABL_SET([unit-tester],    [enable unit tests on IKEv2 daemon startup.])
 143 ARG_ENABL_SET([load-tester],    [enable load testing plugin for IKEv2 daemon.])
 144 ARG_ENABL_SET([eap-sim],        [enable SIM authentication module for EAP.])
 145 ARG_ENABL_SET([eap-sim-file],   [enable EAP-SIM backend based on a triplet file.])
 146 ARG_ENABL_SET([eap-sim-pcsc],   [enable EAP-SIM backend based on a smartcard reader. Requires libpcsclite.])
 147 ARG_ENABL_SET([eap-aka],        [enable EAP AKA authentication module.])
 148 ARG_ENABL_SET([eap-aka-3gpp2],  [enable EAP AKA backend implementing 3GPP2 algorithms in software. Requires libgmp.])
 149 ARG_ENABL_SET([eap-simaka-sql], [enable EAP-SIM/AKA backend based on a triplet/quintuplet SQL database.])
 150 ARG_ENABL_SET([eap-simaka-pseudonym], [enable EAP-SIM/AKA pseudonym storage plugin.])
 151 ARG_ENABL_SET([eap-simaka-reauth],    [enable EAP-SIM/AKA reauthentication data storage plugin.])
 152 ARG_ENABL_SET([eap-identity],   [enable EAP module providing EAP-Identity helper.])
 153 ARG_ENABL_SET([eap-md5],        [enable EAP MD5 (CHAP) authentication module.])
 154 ARG_ENABL_SET([eap-gtc],        [enable EAP GTC authentication module.])
 155 ARG_ENABL_SET([eap-mschapv2],   [enable EAP MS-CHAPv2 authentication module.])
 156 ARG_ENABL_SET([eap-tls],        [enable EAP TLS authentication module.])
 157 ARG_ENABL_SET([eap-ttls],       [enable EAP TTLS authentication module.])
 158 ARG_ENABL_SET([eap-peap],       [enable EAP PEAP authentication module.])
 159 ARG_ENABL_SET([eap-tnc],        [enable EAP TNC trusted network connect module.])
 160 ARG_ENABL_SET([eap-dynamic],    [enable dynamic EAP proxy module.])
 161 ARG_ENABL_SET([eap-radius],     [enable RADIUS proxy authentication module.])
 162 ARG_DISBL_SET([xauth-generic],  [disable generic XAuth backend.])
 163 ARG_ENABL_SET([xauth-eap],      [enable XAuth backend using EAP methods to verify passwords.])
 164 ARG_ENABL_SET([xauth-pam],      [enable XAuth backend using PAM to verify passwords.])
 165 ARG_ENABL_SET([tnc-ifmap],      [enable TNC IF-MAP module.])
 166 ARG_ENABL_SET([tnc-pdp],        [enable TNC policy decision point module.])
 167 ARG_ENABL_SET([tnc-imc],        [enable TNC IMC module.])
 168 ARG_ENABL_SET([tnc-imv],        [enable TNC IMV module.])
 169 ARG_ENABL_SET([tnccs-11],       [enable TNCCS 1.1 protocol module.])
 170 ARG_ENABL_SET([tnccs-20],       [enable TNCCS 2.0 protocol module.])
 171 ARG_ENABL_SET([tnccs-dynamic],  [enable dynamic TNCCS protocol discovery module.])
 172 ARG_ENABL_SET([imc-test],       [enable IMC test module.])
 173 ARG_ENABL_SET([imv-test],       [enable IMV test module.])
 174 ARG_ENABL_SET([imc-scanner],    [enable IMC port scanner module.])
 175 ARG_ENABL_SET([imv-scanner],    [enable IMV port scanner module.])
 176 ARG_ENABL_SET([imc-os],         [enable IMC operating system module.])
 177 ARG_ENABL_SET([imv-os],         [enable IMV operating system module.])
 178 ARG_ENABL_SET([imc-attestation],[enable IMC attestation module.])
 179 ARG_ENABL_SET([imv-attestation],[enable IMV attestation module.])
 180 ARG_DISBL_SET([kernel-netlink], [disable the netlink kernel interface.])
 181 ARG_ENABL_SET([kernel-pfkey],   [enable the PF_KEY kernel interface.])
 182 ARG_ENABL_SET([kernel-pfroute], [enable the PF_ROUTE kernel interface.])
 183 ARG_ENABL_SET([kernel-klips],   [enable the KLIPS kernel interface.])
 184 ARG_ENABL_SET([libipsec],       [enable user space IPsec implementation.])
 185 ARG_DISBL_SET([socket-default], [disable default socket implementation for charon.])
 186 ARG_ENABL_SET([socket-dynamic], [enable dynamic socket implementation for charon])
 187 ARG_ENABL_SET([farp],           [enable ARP faking plugin that responds to ARP requests to peers virtual IP])
 188 ARG_ENABL_SET([dumm],           [enable the DUMM UML test framework.])
 189 ARG_ENABL_SET([fast],           [enable libfast (FastCGI Application Server w/ templates.])
 190 ARG_ENABL_SET([manager],        [enable web management console (proof of concept).])
 191 ARG_ENABL_SET([mediation],      [enable IKEv2 Mediation Extension.])
 192 ARG_ENABL_SET([integrity-test], [enable integrity testing of libstrongswan and plugins.])
 193 ARG_DISBL_SET([load-warning],   [disable the charon plugin load option warning in starter.])
 194 ARG_DISBL_SET([ikev1],          [disable IKEv1 protocol support in charon.])
 195 ARG_DISBL_SET([ikev2],          [disable IKEv2 protocol support in charon.])
 196 ARG_DISBL_SET([charon],         [disable the IKEv1/IKEv2 keying daemon charon.])
 197 ARG_DISBL_SET([tools],          [disable additional utilities (openac, scepclient and pki).])
 198 ARG_DISBL_SET([scripts],        [disable additional utilities (found in directory scripts).])
 199 ARG_ENABL_SET([conftest],       [enforce Suite B conformance test framework.])
 200 ARG_DISBL_SET([updown],         [disable updown firewall script plugin.])
 201 ARG_DISBL_SET([attr],           [disable strongswan.conf based configuration attribute plugin.])
 202 ARG_ENABL_SET([attr-sql],       [enable SQL based configuration attribute plugin.])
 203 ARG_ENABL_SET([dhcp],           [enable DHCP based attribute provider plugin.])
 204 ARG_DISBL_SET([resolve],        [disable resolve DNS handler plugin.])
 205 ARG_ENABL_SET([padlock],        [enables VIA Padlock crypto plugin.])
 206 ARG_ENABL_SET([openssl],        [enables the OpenSSL crypto plugin.])
 207 ARG_ENABL_SET([gcrypt],         [enables the libgcrypt plugin.])
 208 ARG_ENABL_SET([agent],          [enables the ssh-agent signing plugin.])
 209 ARG_ENABL_SET([pkcs11],         [enables the PKCS11 token support plugin.])
 210 ARG_ENABL_SET([ctr],            [enables the Counter Mode wrapper crypto plugin.])
 211 ARG_ENABL_SET([ccm],            [enables the CCM AEAD wrapper crypto plugin.])
 212 ARG_ENABL_SET([gcm],            [enables the GCM AEAD wrapper crypto plugin.])
 213 ARG_ENABL_SET([addrblock],      [enables RFC 3779 address block constraint support.])
 214 ARG_ENABL_SET([unity],          [enables Cisco Unity extension plugin.])
 215 ARG_ENABL_SET([uci],            [enable OpenWRT UCI configuration plugin.])
 216 ARG_ENABL_SET([android],        [enable Android specific plugin.])
 217 ARG_ENABL_SET([android-log],    [enable Android specific logger plugin.])
 218 ARG_ENABL_SET([maemo],          [enable Maemo specific plugin.])
 219 ARG_ENABL_SET([nm],             [enable NetworkManager backend.])
 220 ARG_ENABL_SET([ha],             [enable high availability cluster plugin.])
 221 ARG_ENABL_SET([whitelist],      [enable peer identity whitelisting plugin.])
 222 ARG_ENABL_SET([lookip],         [enable fast virtual IP lookup and notification plugin.])
 223 ARG_ENABL_SET([error-notify],   [enable error notification plugin.])
 224 ARG_ENABL_SET([certexpire],     [enable CSV export of expiration dates of used certificates.])
 225 ARG_ENABL_SET([led],            [enable plugin to control LEDs on IKEv2 activity using the Linux kernel LED subsystem.])
 226 ARG_ENABL_SET([duplicheck],     [advanced duplicate checking plugin using liveness checks.])
 227 ARG_ENABL_SET([coupling],       [enable IKEv2 plugin to couple peer certificates permanently to authentication.])
 228 ARG_ENABL_SET([radattr],        [enable plugin to inject and process custom RADIUS attributes as IKEv2 client.])
 229 ARG_ENABL_SET([vstr],           [enforce using the Vstr string library to replace glibc-like printf hooks.])
 230 ARG_ENABL_SET([monolithic],     [build monolithic version of libstrongswan that includes all enabled plugins. Similarly, the plugins of charon are assembled in libcharon.])
 231 ARG_ENABL_SET([bfd-backtraces], [use binutils libbfd to resolve backtraces for memory leaks and segfaults.])
 232
 233 dnl ===================================
 234 dnl  option to disable default options
 235 dnl ===================================
 236
 237 ARG_DISBL_SET([defaults],       [disable all default plugins (they can be enabled with their respective --enable options)])
 238
 239 if test x$defaults = xfalse; then
 240         for option in $enabled_by_default; do
 241                 eval test x\${${option}_given} = xtrue && continue
 242                 let $option=false
 243         done
 244 fi
 245
 246 dnl =========================
 247 dnl  set up compiler and flags
 248 dnl =========================
 249
 250 if test -z "$CFLAGS"; then
 251         CFLAGS="-g -O2 -Wall -Wno-format -Wno-pointer-sign"
 252 fi
 253 AC_PROG_CC
 254 AC_LIB_PREFIX
 255 AC_C_BIGENDIAN
 256
 257 dnl =========================
 258 dnl  check required programs
 259 dnl =========================
 260
 261 AC_PROG_INSTALL
 262 AC_PROG_LIBTOOL
 263 AC_PROG_EGREP
 264 AC_PROG_AWK
 265 AC_PROG_LEX
 266 AC_PROG_YACC
 267 AC_PATH_PROG([PERL], [perl], [], [$PATH:/bin:/usr/bin:/usr/local/bin])
 268 AC_PATH_PROG([GPERF], [gperf], [], [$PATH:/bin:/usr/bin:/usr/local/bin])
 269
 270 dnl because gperf is not needed by end-users we just report it but do not abort on failure
 271 AC_MSG_CHECKING([gperf version >= 3.0.0])
 272 if test -x "$GPERF"; then
 273         if test "`$GPERF --version | $AWK -F' ' '/^GNU gperf/ { print $3 }' | $AWK -F. '{ print $1 }'`" -ge "3"; then
 274                 AC_MSG_RESULT([yes])
 275         else
 276                 AC_MSG_RESULT([no])
 277         fi
 278 else
 279         AC_MSG_RESULT([not found])
 280 fi
 281
 282 dnl =========================
 283 dnl  dependency calculation
 284 dnl =========================
 285
 286 if test x$xauth_generic_given = xfalse -a x$ikev1 = xfalse; then
 287         xauth_generic=false;
 288 fi
 289
 290 if test x$eap_aka_3gpp2 = xtrue; then
 291         gmp=true;
 292 fi
 293
 294 if test x$eap_aka = xtrue; then
 295         fips_prf=true;
 296         simaka=true;
 297 fi
 298
 299 if test x$eap_sim = xtrue; then
 300         fips_prf=true;
 301         simaka=true;
 302 fi
 303
 304 if test x$eap_tls = xtrue -o x$eap_ttls = xtrue -o x$eap_peap = xtrue; then
 305         tls=true;
 306 fi
 307
 308 if test x$eap_radius = xtrue -o x$radattr = xtrue -o x$tnc_pdp = xtrue; then
 309         radius=true;
 310 fi
 311
 312 if test x$tnc_imc = xtrue -o x$tnc_imv = xtrue -o x$tnccs_11 = xtrue -o x$tnccs_11 = xtrue -o x$tnccs_dynamic = xtrue -o x$eap_tnc = xtrue; then
 313         tnc_tnccs=true;
 314 fi
 315
 316 if test x$imc_test = xtrue -o x$imv_test = xtrue -o x$imc_scanner = xtrue -o x$imv_scanner = xtrue -o x$imc_os = xtrue -o x$imv_os = xtrue -o x$imc_attestation = xtrue -o x$imv_attestation = xtrue; then
 317         imcv=true;
 318 fi
 319
 320 if test x$imc_attestation = xtrue -o x$imv_attestation = xtrue; then
 321         pts=true;
 322 fi
 323
 324 if test x$fips_prf = xtrue; then
 325         if test x$openssl = xfalse; then
 326                 sha1=true;
 327         fi
 328 fi
 329
 330 if test x$smp = xtrue -o x$tnccs_11 = xtrue; then
 331         xml=true
 332 fi
 333
 334 if test x$tnc_ifmap = xtrue; then
 335         axis2c=true
 336 fi
 337
 338 if test x$manager = xtrue; then
 339         fast=true
 340 fi
 341
 342 if test x$medsrv = xtrue; then
 343         mediation=true
 344         fast=true
 345 fi
 346
 347 if test x$medcli = xtrue; then
 348         mediation=true
 349 fi
 350
 351 dnl ===========================================
 352 dnl  check required libraries and header files
 353 dnl ===========================================
 354
 355 AC_HEADER_STDBOOL
 356 AC_FUNC_ALLOCA
 357 AC_FUNC_STRERROR_R
 358
 359 dnl libraries needed on some platforms but not on others
 360 dnl ====================================================
 361 saved_LIBS=$LIBS
 362
 363 dnl FreeBSD and Mac OS X have dlopen integrated in libc, Linux needs libdl
 364 LIBS=""
 365 AC_SEARCH_LIBS(dlopen, dl, [DLLIB=$LIBS])
 366 AC_SUBST(DLLIB)
 367
 368 dnl glibc's backtrace() can be replicated on FreeBSD with libexecinfo
 369 LIBS=""
 370 AC_SEARCH_LIBS(backtrace, execinfo, [BTLIB=$LIBS])
 371 AC_CHECK_FUNCS(backtrace)
 372 AC_SUBST(BTLIB)
 373
 374 dnl OpenSolaris needs libsocket and libnsl for socket()
 375 LIBS=""
 376 AC_SEARCH_LIBS(socket, socket, [SOCKLIB=$LIBS],
 377         [AC_CHECK_LIB(nsl, socket, [SOCKLIB="-lsocket -lnsl"], [], [-lsocket])]
 378 )
 379 AC_SUBST(SOCKLIB)
 380
 381 dnl FreeBSD has clock_gettime in libc, Linux needs librt
 382 LIBS=""
 383 AC_SEARCH_LIBS(clock_gettime, rt, [RTLIB=$LIBS])
 384 AC_CHECK_FUNCS(clock_gettime)
 385 AC_SUBST(RTLIB)
 386
 387 dnl Android has pthread_* functions in bionic (libc), others need libpthread
 388 LIBS=""
 389 AC_SEARCH_LIBS(pthread_create, pthread, [PTHREADLIB=$LIBS])
 390 AC_SUBST(PTHREADLIB)
 391
 392 LIBS=$saved_LIBS
 393 dnl ======================
 394
 395 AC_MSG_CHECKING(for dladdr)
 396 AC_TRY_COMPILE(
 397         [#define _GNU_SOURCE
 398          #include <dlfcn.h>],
 399         [Dl_info* info = 0;
 400          dladdr(0, info);],
 401         [AC_MSG_RESULT([yes]); AC_DEFINE([HAVE_DLADDR], [], [have dladdr()])],
 402         [AC_MSG_RESULT([no])]
 403 )
 404
 405 dnl check if pthread_condattr_setclock(CLOCK_MONOTONE) is supported
 406 saved_LIBS=$LIBS
 407 LIBS=$PTHREADLIB
 408 AC_MSG_CHECKING([for pthread_condattr_setclock(CLOCK_MONOTONE)])
 409 AC_TRY_RUN(
 410         [#include <pthread.h>
 411          int main() { pthread_condattr_t attr;
 412                 pthread_condattr_init(&attr);
 413                 return pthread_condattr_setclock(&attr, CLOCK_MONOTONIC);}],
 414         [AC_MSG_RESULT([yes]);
 415          AC_DEFINE([HAVE_CONDATTR_CLOCK_MONOTONIC], [],
 416                            [pthread_condattr_setclock supports CLOCK_MONOTONIC])],
 417         [AC_MSG_RESULT([no])],
 418         dnl Check existence of pthread_condattr_setclock if cross-compiling
 419         [AC_MSG_RESULT([unknown]);
 420          AC_CHECK_FUNCS(pthread_condattr_setclock,
 421                 [AC_DEFINE([HAVE_CONDATTR_CLOCK_MONOTONIC], [],
 422                                    [have pthread_condattr_setclock()])]
 423         )]
 424 )
 425 dnl check if we actually are able to configure attributes on cond vars
 426 AC_CHECK_FUNCS(pthread_condattr_init)
 427 dnl instead of pthread_condattr_setclock Android has this function
 428 AC_CHECK_FUNCS(pthread_cond_timedwait_monotonic)
 429 dnl check if we can cancel threads
 430 AC_CHECK_FUNCS(pthread_cancel)
 431 dnl check if native rwlocks are available
 432 AC_CHECK_FUNCS(pthread_rwlock_init)
 433 dnl check if pthread spinlocks are available
 434 AC_CHECK_FUNCS(pthread_spin_init)
 435 dnl check if we have POSIX semaphore functions, including timed-wait
 436 AC_CHECK_FUNCS(sem_timedwait)
 437 LIBS=$saved_LIBS
 438
 439 AC_CHECK_FUNC(
 440         [gettid],
 441         [AC_DEFINE([HAVE_GETTID], [], [have gettid()])],
 442         [AC_MSG_CHECKING([for SYS_gettid])
 443          AC_TRY_COMPILE(
 444                 [#define _GNU_SOURCE
 445                  #include <unistd.h>
 446                  #include <sys/syscall.h>],
 447                 [int main() {
 448                         return syscall(SYS_gettid);}],
 449                 [AC_MSG_RESULT([yes]);
 450                  AC_DEFINE([HAVE_GETTID], [], [have gettid()])
 451                  AC_DEFINE([HAVE_SYS_GETTID], [], [have syscall(SYS_gettid)])],
 452                 [AC_MSG_RESULT([no])]
 453         )]
 454 )
 455
 456 AC_CHECK_FUNCS(prctl mallinfo getpass closefrom getpwnam_r getgrnam_r)
 457
 458 AC_CHECK_HEADERS(sys/sockio.h glob.h)
 459 AC_CHECK_HEADERS(net/pfkeyv2.h netipsec/ipsec.h netinet6/ipsec.h linux/udp.h)
 460 AC_CHECK_HEADERS(netinet/ip6.h)
 461
 462 AC_CHECK_MEMBERS([struct sockaddr.sa_len], [], [],
 463 [
 464         #include <sys/types.h>
 465         #include <sys/socket.h>
 466 ])
 467
 468 AC_CHECK_MEMBERS([struct sadb_x_policy.sadb_x_policy_priority], [], [],
 469 [
 470         #include <sys/types.h>
 471         #ifdef HAVE_NET_PFKEYV2_H
 472         #include <net/pfkeyv2.h>
 473         #else
 474         #include <stdint.h>
 475         #include <linux/pfkeyv2.h>
 476         #endif
 477 ])
 478
 479 AC_MSG_CHECKING([for in6addr_any])
 480 AC_TRY_COMPILE(
 481         [#include <sys/types.h>
 482         #include <sys/socket.h>
 483         #include <netinet/in.h>],
 484         [struct in6_addr in6;
 485         in6 = in6addr_any;],
 486         [AC_MSG_RESULT([yes]);
 487          AC_DEFINE([HAVE_IN6ADDR_ANY], [], [have struct in6_addr in6addr_any])],
 488         [AC_MSG_RESULT([no])]
 489 )
 490
 491 AC_MSG_CHECKING([for in6_pktinfo])
 492 AC_TRY_COMPILE(
 493         [#define _GNU_SOURCE
 494         #include <sys/types.h>
 495         #include <sys/socket.h>
 496         #include <netinet/in.h>],
 497         [struct in6_pktinfo pi;
 498         if (pi.ipi6_ifindex)
 499         {
 500                 return 0;
 501         }],
 502         [AC_MSG_RESULT([yes]);
 503          AC_DEFINE([HAVE_IN6_PKTINFO], [], [have struct in6_pktinfo.ipi6_ifindex])],
 504         [AC_MSG_RESULT([no])]
 505 )
 506
 507 AC_MSG_CHECKING([for IPSEC_MODE_BEET])
 508 AC_TRY_COMPILE(
 509         [#include <sys/types.h>
 510         #ifdef HAVE_NETIPSEC_IPSEC_H
 511         #include <netipsec/ipsec.h>
 512         #elif defined(HAVE_NETINET6_IPSEC_H)
 513         #include <netinet6/ipsec.h>
 514         #else
 515         #include <stdint.h>
 516         #include <linux/ipsec.h>
 517         #endif],
 518         [int mode = IPSEC_MODE_BEET;
 519          return mode;],
 520         [AC_MSG_RESULT([yes]);
 521          AC_DEFINE([HAVE_IPSEC_MODE_BEET], [], [have IPSEC_MODE_BEET defined])],
 522         [AC_MSG_RESULT([no])]
 523 )
 524
 525 AC_MSG_CHECKING([for IPSEC_DIR_FWD])
 526 AC_TRY_COMPILE(
 527         [#include <sys/types.h>
 528         #ifdef HAVE_NETIPSEC_IPSEC_H
 529         #include <netipsec/ipsec.h>
 530         #elif defined(HAVE_NETINET6_IPSEC_H)
 531         #include <netinet6/ipsec.h>
 532         #else
 533         #include <stdint.h>
 534         #include <linux/ipsec.h>
 535         #endif],
 536         [int dir = IPSEC_DIR_FWD;
 537          return dir;],
 538         [AC_MSG_RESULT([yes]);
 539          AC_DEFINE([HAVE_IPSEC_DIR_FWD], [], [have IPSEC_DIR_FWD defined])],
 540         [AC_MSG_RESULT([no])]
 541 )
 542
 543 AC_MSG_CHECKING([for RTA_TABLE])
 544 AC_TRY_COMPILE(
 545         [#include <sys/socket.h>
 546         #include <linux/netlink.h>
 547         #include <linux/rtnetlink.h>],
 548         [int rta_type = RTA_TABLE;
 549          return rta_type;],
 550         [AC_MSG_RESULT([yes]);
 551          AC_DEFINE([HAVE_RTA_TABLE], [], [have netlink RTA_TABLE defined])],
 552         [AC_MSG_RESULT([no])]
 553 )
 554
 555 AC_MSG_CHECKING([for gcc atomic operations])
 556 AC_TRY_RUN(
 557 [
 558         int main() {
 559                 volatile int ref = 1;
 560                 __sync_fetch_and_add (&ref, 1);
 561                 __sync_sub_and_fetch (&ref, 1);
 562                 /* Make sure test fails if operations are not supported */
 563                 __sync_val_compare_and_swap(&ref, 1, 0);
 564                 return ref;
 565         }
 566 ],
 567 [AC_MSG_RESULT([yes]);
 568  AC_DEFINE([HAVE_GCC_ATOMIC_OPERATIONS], [],
 569                    [have GCC __sync_* atomic operations])],
 570 [AC_MSG_RESULT([no])],
 571 [AC_MSG_RESULT([no])])
 572
 573 dnl check for the new register_printf_specifier function with len argument,
 574 dnl or the deprecated register_printf_function without
 575 AC_CHECK_FUNC(
 576         [register_printf_specifier],
 577         [AC_DEFINE([HAVE_PRINTF_SPECIFIER], [], [have register_printf_specifier()])],
 578         [AC_CHECK_FUNC(
 579                 [register_printf_function],
 580                 [AC_DEFINE([HAVE_PRINTF_FUNCTION], [], [have register_printf_function()])],
 581                 [
 582                         AC_MSG_NOTICE([printf does not support custom format specifiers!])
 583                         vstr=true
 584                 ]
 585         )]
 586 )
 587
 588 if test x$vstr = xtrue; then
 589         AC_HAVE_LIBRARY([vstr],[LIBS="$LIBS"],[AC_MSG_ERROR([Vstr string library not found])])
 590         AC_DEFINE([USE_VSTR], [], [use vstring library for printf hooks])
 591 fi
 592
 593 if test x$gmp = xtrue; then
 594         saved_LIBS=$LIBS
 595         AC_HAVE_LIBRARY([gmp],,[AC_MSG_ERROR([GNU Multi Precision library gmp not found])])
 596         AC_MSG_CHECKING([mpz_powm_sec])
 597         if test x$mpz_powm_sec = xyes; then
 598                 AC_TRY_COMPILE(
 599                         [#include "gmp.h"],
 600                         [
 601                                 void *x = mpz_powm_sec;
 602                         ],
 603                         [AC_MSG_RESULT([yes]);
 604                          AC_DEFINE([HAVE_MPZ_POWM_SEC], [], [have mpz_mown_sec()])],
 605                         [AC_MSG_RESULT([no])]
 606                 )
 607         else
 608                 AC_MSG_RESULT([disabled])
 609         fi
 610         LIBS=$saved_LIBS
 611         AC_MSG_CHECKING([gmp.h version >= 4.1.4])
 612         AC_TRY_COMPILE(
 613                 [#include "gmp.h"],
 614                 [
 615                         #if (__GNU_MP_VERSION*100 +  __GNU_MP_VERSION_MINOR*10 + __GNU_MP_VERSION_PATCHLEVEL) < 414
 616                                 #error bad gmp
 617                         #endif
 618                 ],
 619                 [AC_MSG_RESULT([yes])], [AC_MSG_RESULT([no]); AC_MSG_ERROR([No usable gmp.h found!])]
 620         )
 621 fi
 622
 623 if test x$ldap = xtrue; then
 624         AC_HAVE_LIBRARY([ldap],[LIBS="$LIBS"],[AC_MSG_ERROR([LDAP library ldap not found])])
 625         AC_HAVE_LIBRARY([lber],[LIBS="$LIBS"],[AC_MSG_ERROR([LDAP library lber not found])])
 626         AC_CHECK_HEADER([ldap.h],,[AC_MSG_ERROR([LDAP header ldap.h not found!])])
 627 fi
 628
 629 if test x$curl = xtrue; then
 630         AC_HAVE_LIBRARY([curl],[LIBS="$LIBS"],[AC_MSG_ERROR([CURL library curl not found])])
 631         AC_CHECK_HEADER([curl/curl.h],,[AC_MSG_ERROR([CURL header curl/curl.h not found!])])
 632 fi
 633
 634 if test x$soup = xtrue; then
 635         PKG_CHECK_MODULES(soup, [libsoup-2.4])
 636         AC_SUBST(soup_CFLAGS)
 637         AC_SUBST(soup_LIBS)
 638 fi
 639
 640 if test x$xml = xtrue; then
 641         PKG_CHECK_MODULES(xml, [libxml-2.0])
 642         AC_SUBST(xml_CFLAGS)
 643         AC_SUBST(xml_LIBS)
 644 fi
 645
 646 if test x$axis2c = xtrue; then
 647         PKG_CHECK_MODULES(axis2c, [axis2c])
 648         AC_SUBST(axis2c_CFLAGS)
 649         AC_SUBST(axis2c_LIBS)
 650 fi
 651
 652 if test x$tss = xtrousers; then
 653         AC_HAVE_LIBRARY([tspi],[LIBS="$LIBS"],[AC_MSG_ERROR([TrouSerS library libtspi not found])])
 654         AC_CHECK_HEADER([trousers/tss.h],,[AC_MSG_ERROR([TrouSerS header trousers/tss.h not found!])])
 655         AC_DEFINE([TSS_TROUSERS], [], [use TrouSerS library libtspi as TSS implementation])
 656 fi
 657
 658 if test x$dumm = xtrue; then
 659         PKG_CHECK_MODULES(gtk, [gtk+-2.0 vte])
 660         AC_SUBST(gtk_CFLAGS)
 661         AC_SUBST(gtk_LIBS)
 662         AC_CHECK_PROGS(RUBY, ruby)
 663         AC_MSG_CHECKING([for Ruby header files])
 664         if test -n "$RUBY"; then
 665                 RUBYINCLUDE=
 666                 RUBYDIR=`($RUBY -r rbconfig -e 'print RbConfig::CONFIG[["rubyhdrdir"]] || ""') 2>/dev/null`
 667                 if test -n "$RUBYDIR" -a -r "$RUBYDIR/ruby.h"; then
 668                         RUBYARCH=`($RUBY -r rbconfig -e 'print RbConfig::CONFIG[["arch"]] || ""') 2>/dev/null`
 669                         if test -n "$RUBYARCH"; then
 670                                 AC_MSG_RESULT([$RUBYDIR])
 671                                 RUBYINCLUDE="-I$RUBYDIR -I$RUBYDIR/$RUBYARCH"
 672                         fi
 673                 else
 674                         RUBYDIR=`($RUBY -r rbconfig -e 'print RbConfig::CONFIG[["archdir"]] || ""') 2>/dev/null`
 675                         if test -n "$RUBYDIR" -a -r "$RUBYDIR/ruby.h"; then
 676                                 AC_MSG_RESULT([$RUBYDIR])
 677                                 RUBYINCLUDE="-I$RUBYDIR"
 678                         fi
 679                 fi
 680                 if test -z "$RUBYINCLUDE"; then
 681                         AC_MSG_ERROR([ruby.h not found])
 682                 fi
 683                 AC_SUBST(RUBYINCLUDE)
 684         else
 685                 AC_MSG_ERROR([don't know how to run ruby])
 686         fi
 687         AC_MSG_CHECKING([for libruby])
 688         saved_LIBS=$LIBS
 689         LIBS=`($RUBY -r rbconfig -e 'print RbConfig::CONFIG[["LIBRUBYARG_SHARED"]] || ""') 2>/dev/null`
 690         AC_TRY_LINK_FUNC(ruby_init,
 691                 [AC_MSG_RESULT([$LIBS]); RUBYLIB=$LIBS],
 692                 [AC_MSG_ERROR([not found])])
 693         AC_SUBST(RUBYLIB)
 694         AC_CHECK_FUNCS(rb_errinfo)
 695         LIBS=$saved_LIBS
 696 fi
 697
 698 if test x$fast = xtrue; then
 699         AC_HAVE_LIBRARY([neo_cgi],[LIBS="$LIBS"],[AC_MSG_ERROR([ClearSilver library neo_cgi not found!])])
 700         AC_HAVE_LIBRARY([neo_utl],[LIBS="$LIBS"],[AC_MSG_ERROR([ClearSilver library neo_utl not found!])])
 701         AC_MSG_CHECKING([ClearSilver requires zlib])
 702         saved_CFLAGS=$CFLAGS
 703         saved_LIBS=$LIBS
 704         LIBS="-lneo_cgi -lneo_cs -lneo_utl"
 705         CFLAGS="-I/usr/include/ClearSilver"
 706         AC_TRY_LINK(
 707                 [#include <ClearSilver.h>],
 708                 [
 709                         NEOERR *err = cgi_display(NULL, NULL);
 710                 ],
 711                 [AC_MSG_RESULT([no]); clearsilver_LIBS="$LIBS"],
 712                 [AC_MSG_RESULT([yes]); clearsilver_LIBS="$LIBS -lz"]
 713         )
 714         AC_SUBST(clearsilver_LIBS)
 715         LIBS=$saved_LIBS
 716         CFLAGS=$saved_CFLAGS
 717 dnl autoconf does not like CamelCase!? How to fix this?
 718 dnl     AC_CHECK_HEADER([ClearSilver/ClearSilver.h],,[AC_MSG_ERROR([ClearSilver header file ClearSilver/ClearSilver.h not found!])])
 719
 720         AC_HAVE_LIBRARY([fcgi],[LIBS="$LIBS"],[AC_MSG_ERROR([FastCGI library fcgi not found!])])
 721         AC_CHECK_HEADER([fcgiapp.h],,[AC_MSG_ERROR([FastCGI header file fcgiapp.h not found!])])
 722 fi
 723
 724 if test x$mysql = xtrue; then
 725         AC_PATH_PROG([MYSQLCONFIG], [mysql_config], [], [$PATH:/bin:/usr/bin:/usr/local/bin])
 726         if test x$MYSQLCONFIG = x; then
 727                 AC_MSG_ERROR([mysql_config not found!])
 728         fi
 729         AC_SUBST(MYSQLLIB, `$MYSQLCONFIG --libs_r`)
 730         AC_SUBST(MYSQLCFLAG, `$MYSQLCONFIG --cflags`)
 731 fi
 732
 733 if test x$sqlite = xtrue; then
 734         AC_HAVE_LIBRARY([sqlite3],[LIBS="$LIBS"],[AC_MSG_ERROR([SQLite library sqlite3 not found])])
 735         AC_CHECK_HEADER([sqlite3.h],,[AC_MSG_ERROR([SQLite header sqlite3.h not found!])])
 736         AC_MSG_CHECKING([sqlite3_prepare_v2])
 737         AC_TRY_COMPILE(
 738                 [#include <sqlite3.h>],
 739                 [
 740                         void *test = sqlite3_prepare_v2;
 741                 ],
 742                 [AC_MSG_RESULT([yes])];
 743                  AC_DEFINE([HAVE_SQLITE3_PREPARE_V2], [], [have sqlite3_prepare_v2()]),
 744                 [AC_MSG_RESULT([no])])
 745         AC_MSG_CHECKING([sqlite3.h version >= 3.3.1])
 746         AC_TRY_COMPILE(
 747                 [#include <sqlite3.h>],
 748                 [
 749                         #if SQLITE_VERSION_NUMBER < 3003001
 750                                 #error bad sqlite
 751                         #endif
 752                 ],
 753                 [AC_MSG_RESULT([yes])], [AC_MSG_RESULT([no]); AC_MSG_ERROR([SQLite version >= 3.3.1 required!])])
 754 fi
 755
 756 if test x$openssl = xtrue; then
 757         AC_HAVE_LIBRARY([crypto],[LIBS="$LIBS"],[AC_MSG_ERROR([OpenSSL crypto library not found])])
 758         AC_CHECK_HEADER([openssl/evp.h],,[AC_MSG_ERROR([OpenSSL header openssl/evp.h not found!])])
 759 fi
 760
 761 if test x$gcrypt = xtrue; then
 762         AC_HAVE_LIBRARY([gcrypt],[LIBS="$LIBS"],[AC_MSG_ERROR([gcrypt library not found])],[-lgpg-error])
 763         AC_CHECK_HEADER([gcrypt.h],,[AC_MSG_ERROR([gcrypt header gcrypt.h not found!])])
 764         AC_MSG_CHECKING([gcrypt CAMELLIA cipher])
 765         AC_TRY_COMPILE(
 766                 [#include <gcrypt.h>],
 767                 [enum gcry_cipher_algos alg = GCRY_CIPHER_CAMELLIA128;],
 768                 [AC_MSG_RESULT([yes]);
 769                  AC_DEFINE([HAVE_GCRY_CIPHER_CAMELLIA], [], [have GCRY_CIPHER_CAMELLIA128])],
 770                 [AC_MSG_RESULT([no])]
 771         )
 772 fi
 773
 774 if test x$uci = xtrue; then
 775         AC_HAVE_LIBRARY([uci],[LIBS="$LIBS"],[AC_MSG_ERROR([UCI library libuci not found])])
 776         AC_CHECK_HEADER([uci.h],,[AC_MSG_ERROR([UCI header uci.h not found!])])
 777 fi
 778
 779 if test x$android = xtrue; then
 780         AC_HAVE_LIBRARY([cutils],[LIBS="$LIBS"],[AC_MSG_ERROR([Android library libcutils not found])])
 781         AC_CHECK_HEADER([cutils/properties.h],,[AC_MSG_ERROR([Android header cutils/properties.h not found!])])
 782         dnl we have to force the use of libdl here because the autodetection
 783         dnl above does not work correctly when cross-compiling for android.
 784         DLLIB="-ldl"
 785         AC_SUBST(DLLIB)
 786 fi
 787
 788 if test x$maemo = xtrue; then
 789         PKG_CHECK_MODULES(maemo, [glib-2.0 gthread-2.0 libosso osso-af-settings])
 790         AC_SUBST(maemo_CFLAGS)
 791         AC_SUBST(maemo_LIBS)
 792         dbusservicedir="/usr/share/dbus-1/system-services"
 793         AC_SUBST(dbusservicedir)
 794 fi
 795
 796 if test x$eap_sim_pcsc = xtrue; then
 797         PKG_CHECK_MODULES(pcsclite, [libpcsclite])
 798         AC_SUBST(pcsclite_CFLAGS)
 799         AC_SUBST(pcsclite_LIBS)
 800 fi
 801
 802 if test x$nm = xtrue; then
 803         PKG_CHECK_EXISTS([libnm-glib],
 804                 [PKG_CHECK_MODULES(nm, [NetworkManager gthread-2.0 libnm-util libnm-glib libnm-glib-vpn])],
 805                 [PKG_CHECK_MODULES(nm, [NetworkManager gthread-2.0 libnm_util libnm_glib libnm_glib_vpn])]
 806         )
 807         AC_SUBST(nm_CFLAGS)
 808         AC_SUBST(nm_LIBS)
 809 fi
 810
 811 if test x$xauth_pam = xtrue; then
 812         AC_HAVE_LIBRARY([pam],[LIBS="$LIBS"],[AC_MSG_ERROR([PAM library not found])])
 813         AC_CHECK_HEADER([security/pam_appl.h],,[AC_MSG_ERROR([PAM header security/pam_appl.h not found!])])
 814 fi
 815
 816 if test x$capabilities = xnative; then
 817         AC_MSG_NOTICE([Usage of the native Linux capabilities interface is deprecated, use libcap instead])
 818         dnl Linux requires the following for capset(), Android does not have it,
 819         dnl but defines capset() in unistd.h instead.
 820         AC_CHECK_HEADERS([sys/capability.h])
 821         AC_CHECK_FUNC(capset,,[AC_MSG_ERROR([capset() not found!])])
 822         AC_DEFINE([CAPABILITIES_NATIVE], [], [have native linux capset()])
 823 fi
 824
 825 if test x$capabilities = xlibcap; then
 826         AC_HAVE_LIBRARY([cap],[LIBS="$LIBS"],[AC_MSG_ERROR([libcap library not found])])
 827         AC_CHECK_HEADER([sys/capability.h],
 828                 [AC_DEFINE([HAVE_SYS_CAPABILITY_H], [], [have sys/capability.h])],
 829                 [AC_MSG_ERROR([libcap header sys/capability.h not found!])])
 830         AC_DEFINE([CAPABILITIES_LIBCAP], [], [have libpcap library])
 831 fi
 832
 833 if test x$integrity_test = xtrue; then
 834         AC_MSG_CHECKING([for dladdr()])
 835         AC_TRY_COMPILE(
 836                 [#define _GNU_SOURCE
 837                  #include <dlfcn.h>],
 838                 [Dl_info info; dladdr(main, &info);],
 839                 [AC_MSG_RESULT([yes])], [AC_MSG_RESULT([no]);
 840                  AC_MSG_ERROR([dladdr() not supported, required by integrity-test!])]
 841         )
 842         AC_MSG_CHECKING([for dl_iterate_phdr()])
 843         AC_TRY_COMPILE(
 844                 [#define _GNU_SOURCE
 845                  #include <link.h>],
 846                 [dl_iterate_phdr((void*)0, (void*)0);],
 847                 [AC_MSG_RESULT([yes])], [AC_MSG_RESULT([no]);
 848                  AC_MSG_ERROR([dl_iterate_phdr() not supported, required by integrity-test!])]
 849         )
 850 fi
 851
 852 if test x$bfd_backtraces = xtrue; then
 853         AC_HAVE_LIBRARY([bfd],[LIBS="$LIBS"],[AC_MSG_ERROR([binutils libbfd not found!])])
 854         AC_CHECK_HEADER([bfd.h],[AC_DEFINE([HAVE_BFD_H],,[have binutils bfd.h])],
 855                 [AC_MSG_ERROR([binutils bfd.h header not found!])])
 856         BFDLIB="-lbfd"
 857         AC_SUBST(BFDLIB)
 858 fi
 859
 860 AM_CONDITIONAL(USE_DEV_HEADERS, [test "x$dev_headers" != xno])
 861 if test x$dev_headers = xyes; then
 862         dev_headers="$includedir/strongswan"
 863 fi
 864 AC_SUBST(dev_headers)
 865
 866 CFLAGS="$CFLAGS -include `pwd`/config.h"
 867
 868 dnl ==============================================
 869 dnl  collect plugin list for strongSwan components
 870 dnl ==============================================
 871
 872 m4_include(m4/macros/add-plugin.m4)
 873
 874 # plugin lists for all components
 875 charon_plugins=
 876 starter_plugins=
 877 pool_plugins=
 878 attest_plugins=
 879 openac_plugins=
 880 scepclient_plugins=
 881 pki_plugins=
 882 scripts_plugins=
 883 manager_plugins=
 884 medsrv_plugins=
 885 nm_plugins=
 886
 887 # location specific lists for checksumming,
 888 # for src/libcharon, src/libhydra and src/libstrongswan
 889 c_plugins=
 890 h_plugins=
 891 s_plugins=
 892
 893 ADD_PLUGIN([test-vectors],         [s charon openac scepclient pki])
 894 ADD_PLUGIN([curl],                 [s charon scepclient scripts nm])
 895 ADD_PLUGIN([soup],                 [s charon scripts nm])
 896 ADD_PLUGIN([ldap],                 [s charon scepclient scripts nm])
 897 ADD_PLUGIN([mysql],                [s charon pool manager medsrv attest])
 898 ADD_PLUGIN([sqlite],               [s charon pool manager medsrv attest])
 899 ADD_PLUGIN([pkcs11],               [s charon pki nm])
 900 ADD_PLUGIN([aes],                  [s charon openac scepclient pki scripts nm])
 901 ADD_PLUGIN([des],                  [s charon openac scepclient pki scripts nm])
 902 ADD_PLUGIN([blowfish],             [s charon openac scepclient pki scripts nm])
 903 ADD_PLUGIN([sha1],                 [s charon openac scepclient pki scripts medsrv attest nm])
 904 ADD_PLUGIN([sha2],                 [s charon openac scepclient pki scripts medsrv attest nm])
 905 ADD_PLUGIN([md4],                  [s charon openac manager scepclient pki nm])
 906 ADD_PLUGIN([md5],                  [s charon openac scepclient pki scripts attest nm])
 907 ADD_PLUGIN([rdrand],               [s charon openac scepclient pki scripts medsrv attest nm])
 908 ADD_PLUGIN([random],               [s charon openac scepclient pki scripts medsrv attest nm])
 909 ADD_PLUGIN([nonce],                [s charon nm])
 910 ADD_PLUGIN([x509],                 [s charon openac scepclient pki scripts attest nm])
 911 ADD_PLUGIN([revocation],           [s charon nm])
 912 ADD_PLUGIN([constraints],          [s charon nm])
 913 ADD_PLUGIN([pubkey],               [s charon])
 914 ADD_PLUGIN([pkcs1],                [s charon openac scepclient pki scripts manager medsrv attest nm])
 915 ADD_PLUGIN([pkcs7],                [s scepclient pki])
 916 ADD_PLUGIN([pkcs8],                [s charon openac scepclient pki scripts manager medsrv attest nm])
 917 ADD_PLUGIN([pgp],                  [s charon])
 918 ADD_PLUGIN([dnskey],               [s charon])
 919 ADD_PLUGIN([pem],                  [s charon openac scepclient pki scripts manager medsrv attest nm])
 920 ADD_PLUGIN([padlock],              [s charon])
 921 ADD_PLUGIN([openssl],              [s charon openac scepclient pki scripts manager medsrv attest nm])
 922 ADD_PLUGIN([gcrypt],               [s charon openac scepclient pki scripts manager medsrv attest nm])
 923 ADD_PLUGIN([af-alg],               [s charon openac scepclient pki scripts medsrv attest nm])
 924 ADD_PLUGIN([fips-prf],             [s charon nm])
 925 ADD_PLUGIN([gmp],                  [s charon openac scepclient pki scripts manager medsrv attest nm])
 926 ADD_PLUGIN([agent],                [s charon nm])
 927 ADD_PLUGIN([xcbc],                 [s charon nm])
 928 ADD_PLUGIN([cmac],                 [s charon nm])
 929 ADD_PLUGIN([hmac],                 [s charon scripts nm])
 930 ADD_PLUGIN([ctr],                  [s charon scripts nm])
 931 ADD_PLUGIN([ccm],                  [s charon scripts nm])
 932 ADD_PLUGIN([gcm],                  [s charon scripts nm])
 933 ADD_PLUGIN([attr],                 [h charon])
 934 ADD_PLUGIN([attr-sql],             [h charon])
 935 ADD_PLUGIN([load-tester],          [c charon])
 936 ADD_PLUGIN([kernel-pfkey],         [h charon starter nm])
 937 ADD_PLUGIN([kernel-pfroute],       [h charon starter nm])
 938 ADD_PLUGIN([kernel-klips],         [h charon starter])
 939 ADD_PLUGIN([kernel-netlink],       [h charon starter nm])
 940 ADD_PLUGIN([resolve],              [h charon])
 941 ADD_PLUGIN([socket-default],       [c charon nm])
 942 ADD_PLUGIN([socket-dynamic],       [c charon])
 943 ADD_PLUGIN([farp],                 [c charon])
 944 ADD_PLUGIN([stroke],               [c charon])
 945 ADD_PLUGIN([smp],                  [c charon])
 946 ADD_PLUGIN([sql],                  [c charon])
 947 ADD_PLUGIN([updown],               [c charon])
 948 ADD_PLUGIN([eap-identity],         [c charon nm])
 949 ADD_PLUGIN([eap-sim],              [c charon])
 950 ADD_PLUGIN([eap-sim-file],         [c charon])
 951 ADD_PLUGIN([eap-sim-pcsc],         [c charon])
 952 ADD_PLUGIN([eap-aka],              [c charon])
 953 ADD_PLUGIN([eap-aka-3gpp2],        [c charon])
 954 ADD_PLUGIN([eap-simaka-sql],       [c charon])
 955 ADD_PLUGIN([eap-simaka-pseudonym], [c charon])
 956 ADD_PLUGIN([eap-simaka-reauth],    [c charon])
 957 ADD_PLUGIN([eap-md5],              [c charon nm])
 958 ADD_PLUGIN([eap-gtc],              [c charon nm])
 959 ADD_PLUGIN([eap-mschapv2],         [c charon nm])
 960 ADD_PLUGIN([eap-dynamic],          [c charon])
 961 ADD_PLUGIN([eap-radius],           [c charon])
 962 ADD_PLUGIN([eap-tls],              [c charon nm])
 963 ADD_PLUGIN([eap-ttls],             [c charon nm])
 964 ADD_PLUGIN([eap-peap],             [c charon nm])
 965 ADD_PLUGIN([eap-tnc],              [c charon])
 966 ADD_PLUGIN([xauth-generic],        [c charon])
 967 ADD_PLUGIN([xauth-eap],            [c charon])
 968 ADD_PLUGIN([xauth-pam],            [c charon])
 969 ADD_PLUGIN([tnc-ifmap],            [c charon])
 970 ADD_PLUGIN([tnc-pdp],              [c charon])
 971 ADD_PLUGIN([tnc-imc],              [c charon])
 972 ADD_PLUGIN([tnc-imv],              [c charon])
 973 ADD_PLUGIN([tnc-tnccs],            [c charon])
 974 ADD_PLUGIN([tnccs-20],             [c charon])
 975 ADD_PLUGIN([tnccs-11],             [c charon])
 976 ADD_PLUGIN([tnccs-dynamic],        [c charon])
 977 ADD_PLUGIN([medsrv],               [c charon])
 978 ADD_PLUGIN([medcli],               [c charon])
 979 ADD_PLUGIN([dhcp],                 [c charon])
 980 ADD_PLUGIN([android],              [c charon])
 981 ADD_PLUGIN([android-log],          [c charon])
 982 ADD_PLUGIN([ha],                   [c charon])
 983 ADD_PLUGIN([whitelist],            [c charon])
 984 ADD_PLUGIN([lookip],               [c charon])
 985 ADD_PLUGIN([error-notify],         [c charon])
 986 ADD_PLUGIN([certexpire],           [c charon])
 987 ADD_PLUGIN([led],                  [c charon])
 988 ADD_PLUGIN([duplicheck],           [c charon])
 989 ADD_PLUGIN([coupling],             [c charon])
 990 ADD_PLUGIN([radattr],              [c charon])
 991 ADD_PLUGIN([maemo],                [c charon])
 992 ADD_PLUGIN([uci],                  [c charon])
 993 ADD_PLUGIN([addrblock],            [c charon])
 994 ADD_PLUGIN([unity],                [c charon])
 995 ADD_PLUGIN([unit-tester],          [c charon])
 996
 997 AC_SUBST(charon_plugins)
 998 AC_SUBST(starter_plugins)
 999 AC_SUBST(pool_plugins)
1000 AC_SUBST(attest_plugins)
1001 AC_SUBST(openac_plugins)
1002 AC_SUBST(scepclient_plugins)
1003 AC_SUBST(pki_plugins)
1004 AC_SUBST(scripts_plugins)
1005 AC_SUBST(manager_plugins)
1006 AC_SUBST(medsrv_plugins)
1007 AC_SUBST(nm_plugins)
1008
1009 AC_SUBST(c_plugins)
1010 AC_SUBST(h_plugins)
1011 AC_SUBST(s_plugins)
1012
1013 dnl =========================
1014 dnl  set Makefile.am vars
1015 dnl =========================
1016
1017 dnl libstrongswan plugins
1018 dnl =====================
1019 AM_CONDITIONAL(USE_TEST_VECTORS, test x$test_vectors = xtrue)
1020 AM_CONDITIONAL(USE_CURL, test x$curl = xtrue)
1021 AM_CONDITIONAL(USE_SOUP, test x$soup = xtrue)
1022 AM_CONDITIONAL(USE_LDAP, test x$ldap = xtrue)
1023 AM_CONDITIONAL(USE_AES, test x$aes = xtrue)
1024 AM_CONDITIONAL(USE_DES, test x$des = xtrue)
1025 AM_CONDITIONAL(USE_BLOWFISH, test x$blowfish = xtrue)
1026 AM_CONDITIONAL(USE_MD4, test x$md4 = xtrue)
1027 AM_CONDITIONAL(USE_MD5, test x$md5 = xtrue)
1028 AM_CONDITIONAL(USE_SHA1, test x$sha1 = xtrue)
1029 AM_CONDITIONAL(USE_SHA2, test x$sha2 = xtrue)
1030 AM_CONDITIONAL(USE_FIPS_PRF, test x$fips_prf = xtrue)
1031 AM_CONDITIONAL(USE_GMP, test x$gmp = xtrue)
1032 AM_CONDITIONAL(USE_RDRAND, test x$rdrand = xtrue)
1033 AM_CONDITIONAL(USE_RANDOM, test x$random = xtrue)
1034 AM_CONDITIONAL(USE_NONCE, test x$nonce = xtrue)
1035 AM_CONDITIONAL(USE_X509, test x$x509 = xtrue)
1036 AM_CONDITIONAL(USE_REVOCATION, test x$revocation = xtrue)
1037 AM_CONDITIONAL(USE_CONSTRAINTS, test x$constraints = xtrue)
1038 AM_CONDITIONAL(USE_PUBKEY, test x$pubkey = xtrue)
1039 AM_CONDITIONAL(USE_PKCS1, test x$pkcs1 = xtrue)
1040 AM_CONDITIONAL(USE_PKCS7, test x$pkcs7 = xtrue)
1041 AM_CONDITIONAL(USE_PKCS8, test x$pkcs8 = xtrue)
1042 AM_CONDITIONAL(USE_PGP, test x$pgp = xtrue)
1043 AM_CONDITIONAL(USE_DNSKEY, test x$dnskey = xtrue)
1044 AM_CONDITIONAL(USE_PEM, test x$pem = xtrue)
1045 AM_CONDITIONAL(USE_HMAC, test x$hmac = xtrue)
1046 AM_CONDITIONAL(USE_CMAC, test x$cmac = xtrue)
1047 AM_CONDITIONAL(USE_XCBC, test x$xcbc = xtrue)
1048 AM_CONDITIONAL(USE_MYSQL, test x$mysql = xtrue)
1049 AM_CONDITIONAL(USE_SQLITE, test x$sqlite = xtrue)
1050 AM_CONDITIONAL(USE_PADLOCK, test x$padlock = xtrue)
1051 AM_CONDITIONAL(USE_OPENSSL, test x$openssl = xtrue)
1052 AM_CONDITIONAL(USE_GCRYPT, test x$gcrypt = xtrue)
1053 AM_CONDITIONAL(USE_AGENT, test x$agent = xtrue)
1054 AM_CONDITIONAL(USE_PKCS11, test x$pkcs11 = xtrue)
1055 AM_CONDITIONAL(USE_CTR, test x$ctr = xtrue)
1056 AM_CONDITIONAL(USE_CCM, test x$ccm = xtrue)
1057 AM_CONDITIONAL(USE_GCM, test x$gcm = xtrue)
1058 AM_CONDITIONAL(USE_AF_ALG, test x$af_alg = xtrue)
1059
1060 dnl charon plugins
1061 dnl ==============
1062 AM_CONDITIONAL(USE_STROKE, test x$stroke = xtrue)
1063 AM_CONDITIONAL(USE_MEDSRV, test x$medsrv = xtrue)
1064 AM_CONDITIONAL(USE_MEDCLI, test x$medcli = xtrue)
1065 AM_CONDITIONAL(USE_UCI, test x$uci = xtrue)
1066 AM_CONDITIONAL(USE_ANDROID, test x$android = xtrue)
1067 AM_CONDITIONAL(USE_ANDROID_LOG, test x$android_log = xtrue)
1068 AM_CONDITIONAL(USE_MAEMO, test x$maemo = xtrue)
1069 AM_CONDITIONAL(USE_SMP, test x$smp = xtrue)
1070 AM_CONDITIONAL(USE_SQL, test x$sql = xtrue)
1071 AM_CONDITIONAL(USE_UPDOWN, test x$updown = xtrue)
1072 AM_CONDITIONAL(USE_DHCP, test x$dhcp = xtrue)
1073 AM_CONDITIONAL(USE_UNIT_TESTS, test x$unit_tester = xtrue)
1074 AM_CONDITIONAL(USE_LOAD_TESTER, test x$load_tester = xtrue)
1075 AM_CONDITIONAL(USE_HA, test x$ha = xtrue)
1076 AM_CONDITIONAL(USE_WHITELIST, test x$whitelist = xtrue)
1077 AM_CONDITIONAL(USE_LOOKIP, test x$lookip = xtrue)
1078 AM_CONDITIONAL(USE_ERROR_NOTIFY, test x$error_notify = xtrue)
1079 AM_CONDITIONAL(USE_CERTEXPIRE, test x$certexpire = xtrue)
1080 AM_CONDITIONAL(USE_LED, test x$led = xtrue)
1081 AM_CONDITIONAL(USE_DUPLICHECK, test x$duplicheck = xtrue)
1082 AM_CONDITIONAL(USE_COUPLING, test x$coupling = xtrue)
1083 AM_CONDITIONAL(USE_RADATTR, test x$radattr = xtrue)
1084 AM_CONDITIONAL(USE_EAP_SIM, test x$eap_sim = xtrue)
1085 AM_CONDITIONAL(USE_EAP_SIM_FILE, test x$eap_sim_file = xtrue)
1086 AM_CONDITIONAL(USE_EAP_SIM_PCSC, test x$eap_sim_pcsc = xtrue)
1087 AM_CONDITIONAL(USE_EAP_SIMAKA_SQL, test x$eap_simaka_sql = xtrue)
1088 AM_CONDITIONAL(USE_EAP_SIMAKA_PSEUDONYM, test x$eap_simaka_pseudonym = xtrue)
1089 AM_CONDITIONAL(USE_EAP_SIMAKA_REAUTH, test x$eap_simaka_reauth = xtrue)
1090 AM_CONDITIONAL(USE_EAP_IDENTITY, test x$eap_identity = xtrue)
1091 AM_CONDITIONAL(USE_EAP_MD5, test x$eap_md5 = xtrue)
1092 AM_CONDITIONAL(USE_EAP_GTC, test x$eap_gtc = xtrue)
1093 AM_CONDITIONAL(USE_EAP_AKA, test x$eap_aka = xtrue)
1094 AM_CONDITIONAL(USE_EAP_AKA_3GPP2, test x$eap_aka_3gpp2 = xtrue)
1095 AM_CONDITIONAL(USE_EAP_MSCHAPV2, test x$eap_mschapv2 = xtrue)
1096 AM_CONDITIONAL(USE_EAP_TLS, test x$eap_tls = xtrue)
1097 AM_CONDITIONAL(USE_EAP_TTLS, test x$eap_ttls = xtrue)
1098 AM_CONDITIONAL(USE_EAP_PEAP, test x$eap_peap = xtrue)
1099 AM_CONDITIONAL(USE_EAP_TNC, test x$eap_tnc = xtrue)
1100 AM_CONDITIONAL(USE_EAP_DYNAMIC, test x$eap_dynamic = xtrue)
1101 AM_CONDITIONAL(USE_EAP_RADIUS, test x$eap_radius = xtrue)
1102 AM_CONDITIONAL(USE_XAUTH_GENERIC, test x$xauth_generic = xtrue)
1103 AM_CONDITIONAL(USE_XAUTH_EAP, test x$xauth_eap = xtrue)
1104 AM_CONDITIONAL(USE_XAUTH_PAM, test x$xauth_pam = xtrue)
1105 AM_CONDITIONAL(USE_TNC_IFMAP, test x$tnc_ifmap = xtrue)
1106 AM_CONDITIONAL(USE_TNC_PDP, test x$tnc_pdp = xtrue)
1107 AM_CONDITIONAL(USE_TNC_IMC, test x$tnc_imc = xtrue)
1108 AM_CONDITIONAL(USE_TNC_IMV, test x$tnc_imv = xtrue)
1109 AM_CONDITIONAL(USE_TNC_TNCCS, test x$tnc_tnccs = xtrue)
1110 AM_CONDITIONAL(USE_TNCCS_11, test x$tnccs_11 = xtrue)
1111 AM_CONDITIONAL(USE_TNCCS_20, test x$tnccs_20 = xtrue)
1112 AM_CONDITIONAL(USE_TNCCS_DYNAMIC, test x$tnccs_dynamic = xtrue)
1113 AM_CONDITIONAL(USE_IMC_TEST, test x$imc_test = xtrue)
1114 AM_CONDITIONAL(USE_IMV_TEST, test x$imv_test = xtrue)
1115 AM_CONDITIONAL(USE_IMC_SCANNER, test x$imc_scanner = xtrue)
1116 AM_CONDITIONAL(USE_IMV_SCANNER, test x$imv_scanner = xtrue)
1117 AM_CONDITIONAL(USE_IMC_OS, test x$imc_os = xtrue)
1118 AM_CONDITIONAL(USE_IMV_OS, test x$imv_os = xtrue)
1119 AM_CONDITIONAL(USE_IMC_ATTESTATION, test x$imc_attestation = xtrue)
1120 AM_CONDITIONAL(USE_IMV_ATTESTATION, test x$imv_attestation = xtrue)
1121 AM_CONDITIONAL(USE_SOCKET_DEFAULT, test x$socket_default = xtrue)
1122 AM_CONDITIONAL(USE_SOCKET_DYNAMIC, test x$socket_dynamic = xtrue)
1123 AM_CONDITIONAL(USE_FARP, test x$farp = xtrue)
1124 AM_CONDITIONAL(USE_ADDRBLOCK, test x$addrblock = xtrue)
1125 AM_CONDITIONAL(USE_UNITY, test x$unity = xtrue)
1126
1127 dnl hydra plugins
1128 dnl =============
1129 AM_CONDITIONAL(USE_ATTR, test x$attr = xtrue)
1130 AM_CONDITIONAL(USE_ATTR_SQL, test x$attr_sql = xtrue -o x$sql = xtrue)
1131 AM_CONDITIONAL(USE_KERNEL_KLIPS, test x$kernel_klips = xtrue)
1132 AM_CONDITIONAL(USE_KERNEL_NETLINK, test x$kernel_netlink = xtrue)
1133 AM_CONDITIONAL(USE_KERNEL_PFKEY, test x$kernel_pfkey = xtrue)
1134 AM_CONDITIONAL(USE_KERNEL_PFROUTE, test x$kernel_pfroute = xtrue)
1135 AM_CONDITIONAL(USE_RESOLVE, test x$resolve = xtrue)
1136
1137 dnl other options
1138 dnl =============
1139 AM_CONDITIONAL(USE_LEAK_DETECTIVE, test x$leak_detective = xtrue)
1140 AM_CONDITIONAL(USE_LOCK_PROFILER, test x$lock_profiler = xtrue)
1141 AM_CONDITIONAL(USE_DUMM, test x$dumm = xtrue)
1142 AM_CONDITIONAL(USE_FAST, test x$fast = xtrue)
1143 AM_CONDITIONAL(USE_MANAGER, test x$manager = xtrue)
1144 AM_CONDITIONAL(USE_ME, test x$mediation = xtrue)
1145 AM_CONDITIONAL(USE_INTEGRITY_TEST, test x$integrity_test = xtrue)
1146 AM_CONDITIONAL(USE_LOAD_WARNING, test x$load_warning = xtrue)
1147 AM_CONDITIONAL(USE_IKEV1, test x$ikev1 = xtrue)
1148 AM_CONDITIONAL(USE_IKEV2, test x$ikev2 = xtrue)
1149 AM_CONDITIONAL(USE_THREADS, test x$threads = xtrue)
1150 AM_CONDITIONAL(USE_ADNS, test x$adns = xtrue)
1151 AM_CONDITIONAL(USE_CHARON, test x$charon = xtrue)
1152 AM_CONDITIONAL(USE_NM, test x$nm = xtrue)
1153 AM_CONDITIONAL(USE_TOOLS, test x$tools = xtrue)
1154 AM_CONDITIONAL(USE_SCRIPTS, test x$scripts = xtrue)
1155 AM_CONDITIONAL(USE_CONFTEST, test x$conftest = xtrue)
1156 AM_CONDITIONAL(USE_LIBSTRONGSWAN, test x$charon = xtrue -o x$tools = xtrue -o x$conftest = xtrue -o x$fast = xtrue -o x$imcv = xtrue -o x$nm = xtrue)
1157 AM_CONDITIONAL(USE_LIBHYDRA, test x$charon = xtrue -o x$nm = xtrue)
1158 AM_CONDITIONAL(USE_LIBCHARON, test x$charon = xtrue -o x$conftest = xtrue -o x$nm = xtrue)
1159 AM_CONDITIONAL(USE_LIBIPSEC, test x$libipsec = xtrue)
1160 AM_CONDITIONAL(USE_LIBTNCIF, test x$tnc_tnccs = xtrue -o x$imcv = xtrue)
1161 AM_CONDITIONAL(USE_LIBTNCCS, test x$tnc_tnccs = xtrue)
1162 AM_CONDITIONAL(USE_FILE_CONFIG, test x$stroke = xtrue)
1163 AM_CONDITIONAL(USE_IPSEC_SCRIPT, test x$stroke = xtrue -o x$tools = xtrue -o x$conftest = xtrue)
1164 AM_CONDITIONAL(USE_LIBCAP, test x$capabilities = xlibcap)
1165 AM_CONDITIONAL(USE_VSTR, test x$vstr = xtrue)
1166 AM_CONDITIONAL(USE_SIMAKA, test x$simaka = xtrue)
1167 AM_CONDITIONAL(USE_TLS, test x$tls = xtrue)
1168 AM_CONDITIONAL(USE_RADIUS, test x$radius = xtrue)
1169 AM_CONDITIONAL(USE_IMCV, test x$imcv = xtrue)
1170 AM_CONDITIONAL(USE_PTS, test x$pts = xtrue)
1171 AM_CONDITIONAL(USE_TROUSERS, test x$tss = xtrousers)
1172 AM_CONDITIONAL(MONOLITHIC, test x$monolithic = xtrue)
1173
1174 dnl ==============================
1175 dnl  set global definitions
1176 dnl ==============================
1177
1178 if test x$mediation = xtrue; then
1179         AC_DEFINE([ME], [], [mediation extension support])
1180 fi
1181 if test x$capabilities = xlibcap -o x$capabilities = xnative; then
1182         AC_DEFINE([CAPABILITIES], [], [capability dropping support])
1183 fi
1184 if test x$monolithic = xtrue; then
1185         AC_DEFINE([MONOLITHIC], [], [monolithic build embedding plugins])
1186 fi
1187 if test x$ikev1 = xtrue; then
1188         AC_DEFINE([USE_IKEV1], [], [support for IKEv1 protocol])
1189 fi
1190 if test x$ikev2 = xtrue; then
1191         AC_DEFINE([USE_IKEV2], [], [support for IKEv2 protocol])
1192 fi
1193
1194 dnl ==============================
1195 dnl  build Makefiles
1196 dnl ==============================
1197
1198 AC_OUTPUT(
1199         Makefile
1200         man/Makefile
1201         init/Makefile
1202         init/systemd/Makefile
1203         src/Makefile
1204         src/include/Makefile
1205         src/libstrongswan/Makefile
1206         src/libstrongswan/plugins/aes/Makefile
1207         src/libstrongswan/plugins/cmac/Makefile
1208         src/libstrongswan/plugins/des/Makefile
1209         src/libstrongswan/plugins/blowfish/Makefile
1210         src/libstrongswan/plugins/md4/Makefile
1211         src/libstrongswan/plugins/md5/Makefile
1212         src/libstrongswan/plugins/sha1/Makefile
1213         src/libstrongswan/plugins/sha2/Makefile
1214         src/libstrongswan/plugins/fips_prf/Makefile
1215         src/libstrongswan/plugins/gmp/Makefile
1216         src/libstrongswan/plugins/rdrand/Makefile
1217         src/libstrongswan/plugins/random/Makefile
1218         src/libstrongswan/plugins/nonce/Makefile
1219         src/libstrongswan/plugins/hmac/Makefile
1220         src/libstrongswan/plugins/xcbc/Makefile
1221         src/libstrongswan/plugins/x509/Makefile
1222         src/libstrongswan/plugins/revocation/Makefile
1223         src/libstrongswan/plugins/constraints/Makefile
1224         src/libstrongswan/plugins/pubkey/Makefile
1225         src/libstrongswan/plugins/pkcs1/Makefile
1226         src/libstrongswan/plugins/pkcs7/Makefile
1227         src/libstrongswan/plugins/pkcs8/Makefile
1228         src/libstrongswan/plugins/pgp/Makefile
1229         src/libstrongswan/plugins/dnskey/Makefile
1230         src/libstrongswan/plugins/pem/Makefile
1231         src/libstrongswan/plugins/curl/Makefile
1232         src/libstrongswan/plugins/soup/Makefile
1233         src/libstrongswan/plugins/ldap/Makefile
1234         src/libstrongswan/plugins/mysql/Makefile
1235         src/libstrongswan/plugins/sqlite/Makefile
1236         src/libstrongswan/plugins/padlock/Makefile
1237         src/libstrongswan/plugins/openssl/Makefile
1238         src/libstrongswan/plugins/gcrypt/Makefile
1239         src/libstrongswan/plugins/agent/Makefile
1240         src/libstrongswan/plugins/pkcs11/Makefile
1241         src/libstrongswan/plugins/ctr/Makefile
1242         src/libstrongswan/plugins/ccm/Makefile
1243         src/libstrongswan/plugins/gcm/Makefile
1244         src/libstrongswan/plugins/af_alg/Makefile
1245         src/libstrongswan/plugins/test_vectors/Makefile
1246         src/libhydra/Makefile
1247         src/libhydra/plugins/attr/Makefile
1248         src/libhydra/plugins/attr_sql/Makefile
1249         src/libhydra/plugins/kernel_klips/Makefile
1250         src/libhydra/plugins/kernel_netlink/Makefile
1251         src/libhydra/plugins/kernel_pfkey/Makefile
1252         src/libhydra/plugins/kernel_pfroute/Makefile
1253         src/libhydra/plugins/resolve/Makefile
1254         src/libipsec/Makefile
1255         src/libsimaka/Makefile
1256         src/libtls/Makefile
1257         src/libradius/Makefile
1258         src/libtncif/Makefile
1259         src/libtnccs/Makefile
1260         src/libpts/Makefile
1261         src/libpts/plugins/imc_attestation/Makefile
1262         src/libpts/plugins/imv_attestation/Makefile
1263         src/libimcv/Makefile
1264         src/libimcv/plugins/imc_test/Makefile
1265         src/libimcv/plugins/imv_test/Makefile
1266         src/libimcv/plugins/imc_scanner/Makefile
1267         src/libimcv/plugins/imv_scanner/Makefile
1268         src/libimcv/plugins/imc_os/Makefile
1269         src/libimcv/plugins/imv_os/Makefile
1270         src/charon/Makefile
1271         src/charon-nm/Makefile
1272         src/libcharon/Makefile
1273         src/libcharon/plugins/eap_aka/Makefile
1274         src/libcharon/plugins/eap_aka_3gpp2/Makefile
1275         src/libcharon/plugins/eap_dynamic/Makefile
1276         src/libcharon/plugins/eap_identity/Makefile
1277         src/libcharon/plugins/eap_md5/Makefile
1278         src/libcharon/plugins/eap_gtc/Makefile
1279         src/libcharon/plugins/eap_sim/Makefile
1280         src/libcharon/plugins/eap_sim_file/Makefile
1281         src/libcharon/plugins/eap_sim_pcsc/Makefile
1282         src/libcharon/plugins/eap_simaka_sql/Makefile
1283         src/libcharon/plugins/eap_simaka_pseudonym/Makefile
1284         src/libcharon/plugins/eap_simaka_reauth/Makefile
1285         src/libcharon/plugins/eap_mschapv2/Makefile
1286         src/libcharon/plugins/eap_tls/Makefile
1287         src/libcharon/plugins/eap_ttls/Makefile
1288         src/libcharon/plugins/eap_peap/Makefile
1289         src/libcharon/plugins/eap_tnc/Makefile
1290         src/libcharon/plugins/eap_radius/Makefile
1291         src/libcharon/plugins/xauth_generic/Makefile
1292         src/libcharon/plugins/xauth_eap/Makefile
1293         src/libcharon/plugins/xauth_pam/Makefile
1294         src/libcharon/plugins/tnc_ifmap/Makefile
1295         src/libcharon/plugins/tnc_pdp/Makefile
1296         src/libcharon/plugins/tnc_imc/Makefile
1297         src/libcharon/plugins/tnc_imv/Makefile
1298         src/libcharon/plugins/tnc_tnccs/Makefile
1299         src/libcharon/plugins/tnccs_11/Makefile
1300         src/libcharon/plugins/tnccs_20/Makefile
1301         src/libcharon/plugins/tnccs_dynamic/Makefile
1302         src/libcharon/plugins/socket_default/Makefile
1303         src/libcharon/plugins/socket_dynamic/Makefile
1304         src/libcharon/plugins/farp/Makefile
1305         src/libcharon/plugins/smp/Makefile
1306         src/libcharon/plugins/sql/Makefile
1307         src/libcharon/plugins/medsrv/Makefile
1308         src/libcharon/plugins/medcli/Makefile
1309         src/libcharon/plugins/addrblock/Makefile
1310         src/libcharon/plugins/unity/Makefile
1311         src/libcharon/plugins/uci/Makefile
1312         src/libcharon/plugins/ha/Makefile
1313         src/libcharon/plugins/whitelist/Makefile
1314         src/libcharon/plugins/lookip/Makefile
1315         src/libcharon/plugins/error_notify/Makefile
1316         src/libcharon/plugins/certexpire/Makefile
1317         src/libcharon/plugins/led/Makefile
1318         src/libcharon/plugins/duplicheck/Makefile
1319         src/libcharon/plugins/coupling/Makefile
1320         src/libcharon/plugins/radattr/Makefile
1321         src/libcharon/plugins/android/Makefile
1322         src/libcharon/plugins/android_log/Makefile
1323         src/libcharon/plugins/maemo/Makefile
1324         src/libcharon/plugins/stroke/Makefile
1325         src/libcharon/plugins/updown/Makefile
1326         src/libcharon/plugins/dhcp/Makefile
1327         src/libcharon/plugins/unit_tester/Makefile
1328         src/libcharon/plugins/load_tester/Makefile
1329         src/stroke/Makefile
1330         src/ipsec/Makefile
1331         src/starter/Makefile
1332         src/_updown/Makefile
1333         src/_updown_espmark/Makefile
1334         src/_copyright/Makefile
1335         src/openac/Makefile
1336         src/scepclient/Makefile
1337         src/pki/Makefile
1338         src/dumm/Makefile
1339         src/dumm/ext/extconf.rb
1340         src/libfast/Makefile
1341         src/manager/Makefile
1342         src/medsrv/Makefile
1343         src/checksum/Makefile
1344         src/conftest/Makefile
1345         scripts/Makefile
1346         testing/Makefile
1347 )