moved resolve plugin from libcharon to libhydra
[strongswan.git] / configure.in
1 dnl  configure.in for linux strongSwan
2 dnl  Copyright (C) 2006 Martin Willi
3 dnl  Hochschule fuer Technik Rapperswil
4 dnl
5 dnl  This program is free software; you can redistribute it and/or modify it
6 dnl  under the terms of the GNU General Public License as published by the
7 dnl  Free Software Foundation; either version 2 of the License, or (at your
8 dnl  option) any later version.  See <http://www.fsf.org/copyleft/gpl.txt>.
9 dnl
10 dnl  This program is distributed in the hope that it will be useful, but
11 dnl  WITHOUT ANY WARRANTY; without even the implied warranty of MERCHANTABILITY
12 dnl  or FITNESS FOR A PARTICULAR PURPOSE.  See the GNU General Public License
13 dnl  for more details.
14
15 dnl ===========================
16 dnl  initialize & set some vars
17 dnl ===========================
18
19 AC_INIT(strongSwan,4.4.1)
20 AM_INIT_AUTOMAKE(tar-ustar)
21 AC_CONFIG_MACRO_DIR([m4/config])
22 PKG_PROG_PKG_CONFIG
23
24 dnl =================================
25 dnl  check --enable-xxx & --with-xxx
26 dnl =================================
27
28 m4_include(m4/macros/with.m4)
29
30 ARG_WITH_SUBST([default-pkcs11],     [/usr/lib/opensc-pkcs11.so], [set the default PKCS11 library])
31 ARG_WITH_SUBST([random-device],      [/dev/random], [set the device to read real random data from])
32 ARG_WITH_SUBST([urandom-device],     [/dev/urandom], [set the device to read pseudo random data from])
33 ARG_WITH_SUBST([strongswan-conf],    [${sysconfdir}/strongswan.conf], [set the strongswan.conf file location])
34 ARG_WITH_SUBST([resolv-conf],        [${sysconfdir}/resolv.conf], [set the file to use in DNS handler plugin])
35 ARG_WITH_SUBST([piddir],             [/var/run], [set path for PID and UNIX socket files])
36 ARG_WITH_SUBST([ipsecdir],           [${libexecdir%/}/ipsec], [set installation path for ipsec tools])
37 ARG_WITH_SUBST([plugindir],          [${ipsecdir%/}/plugins], [set the installation path of plugins])
38 ARG_WITH_SUBST([nm-ca-dir],          [/usr/share/ca-certificates], [directory the NM plugin uses to look up trusted root certificates])
39 ARG_WITH_SUBST([linux-headers],      [\${top_srcdir}/src/include], [set directory of linux header files to use])
40 ARG_WITH_SUBST([routing-table],      [220], [set routing table to use for IPsec routes])
41 ARG_WITH_SUBST([routing-table-prio], [220], [set priority for IPsec routing table])
42
43 ARG_WITH_SET([capabilities],         [no], [set capability dropping library. Currently only the value "libcap" is supported])
44 ARG_WITH_SET([mpz_powm_sec],         [yes], [use the more side-channel resistant mpz_powm_sec in libgmp, if available])
45
46 AC_ARG_WITH(
47         [xauth-module],
48         AS_HELP_STRING([--with-xauth-module=lib],[set the path to the XAUTH module]),
49         [AC_DEFINE_UNQUOTED(XAUTH_DEFAULT_LIB, "$withval")],
50 )
51
52 AC_ARG_WITH(
53         [user],
54         AS_HELP_STRING([--with-user=user],[change user of the daemons to "user" after startup (default is "root").]),
55         [AC_DEFINE_UNQUOTED(IPSEC_USER, "$withval") AC_SUBST(ipsecuser, "$withval")],
56         [AC_SUBST(ipsecuser, "root")]
57 )
58
59 AC_ARG_WITH(
60         [group],
61         AS_HELP_STRING([--with-group=group],[change group of the daemons to "group" after startup (default is "root").]),
62         [AC_DEFINE_UNQUOTED(IPSEC_GROUP, "$withval") AC_SUBST(ipsecgroup, "$withval")],
63         [AC_SUBST(ipsecgroup, "root")]
64 )
65
66 m4_include(m4/macros/enable-disable.m4)
67
68 ARG_ENABL_SET([curl],           [enable CURL fetcher plugin to fetch files via libcurl. Requires libcurl.])
69 ARG_ENABL_SET([ldap],           [enable LDAP fetching plugin to fetch files via libldap. Requires openLDAP.])
70 ARG_DISBL_SET([aes],            [disable AES software implementation plugin.])
71 ARG_DISBL_SET([des],            [disable DES/3DES software implementation plugin.])
72 ARG_ENABL_SET([blowfish],       [enable Blowfish software implementation plugin.])
73 ARG_ENABL_SET([md4],            [enable MD4 software implementation plugin.])
74 ARG_DISBL_SET([md5],            [disable MD5 software implementation plugin.])
75 ARG_DISBL_SET([sha1],           [disable SHA1 software implementation plugin.])
76 ARG_DISBL_SET([sha2],           [disable SHA256/SHA384/SHA512 software implementation plugin.])
77 ARG_DISBL_SET([fips-prf],       [disable FIPS PRF software implementation plugin.])
78 ARG_DISBL_SET([gmp],            [disable GNU MP (libgmp) based crypto implementation plugin.])
79 ARG_DISBL_SET([random],         [disable RNG implementation on top of /dev/(u)random.])
80 ARG_DISBL_SET([x509],           [disable X509 certificate implementation plugin.])
81 ARG_DISBL_SET([pubkey],         [disable RAW public key support plugin.])
82 ARG_DISBL_SET([pkcs1],          [disable PKCS1 key decoding plugin.])
83 ARG_DISBL_SET([pgp],            [disable PGP key decoding plugin.])
84 ARG_DISBL_SET([dnskey],         [disable DNS RR key decoding plugin.])
85 ARG_DISBL_SET([pem],            [disable PEM decoding plugin.])
86 ARG_DISBL_SET([hmac],           [disable HMAC crypto implementation plugin.])
87 ARG_DISBL_SET([xcbc],           [disable xcbc crypto implementation plugin.])
88 ARG_ENABL_SET([test-vectors],   [enable plugin providing crypto test vectors.])
89 ARG_ENABL_SET([mysql],          [enable MySQL database support. Requires libmysqlclient_r.])
90 ARG_ENABL_SET([sqlite],         [enable SQLite database support. Requires libsqlite3.])
91 ARG_DISBL_SET([stroke],         [disable charons stroke (pluto compatibility) configuration backend.])
92 ARG_ENABL_SET([medsrv],         [enable mediation server web frontend and daemon plugin.])
93 ARG_ENABL_SET([medcli],         [enable mediation client configuration database plugin.])
94 ARG_ENABL_SET([smp],            [enable SMP configuration and control interface. Requires libxml.])
95 ARG_ENABL_SET([sql],            [enable SQL database configuration backend.])
96 ARG_ENABL_SET([smartcard],      [enable smartcard support.])
97 ARG_ENABL_SET([cisco-quirks],   [enable support of Cisco VPN client.])
98 ARG_ENABL_SET([leak-detective], [enable malloc hooks to find memory leaks.])
99 ARG_ENABL_SET([lock-profiler],  [enable lock/mutex profiling code.])
100 ARG_ENABL_SET([unit-tests],     [enable unit tests on IKEv2 daemon startup.])
101 ARG_ENABL_SET([load-tester],    [enable load testing plugin for IKEv2 daemon.])
102 ARG_ENABL_SET([eap-sim],        [enable SIM authenication module for EAP.])
103 ARG_ENABL_SET([eap-sim-file],   [enable EAP-SIM backend based on a triplet file.])
104 ARG_ENABL_SET([eap-simaka-pseudonym], [enable EAP-SIM/AKA pseudonym storage plugin.])
105 ARG_ENABL_SET([eap-simaka-reauth],    [enable EAP-SIM/AKA reauthentication data storage plugin.])
106 ARG_ENABL_SET([eap-identity],   [enable EAP module providing EAP-Identity helper.])
107 ARG_ENABL_SET([eap-md5],        [enable EAP MD5 (CHAP) authenication module.])
108 ARG_ENABL_SET([eap-gtc],        [enable PAM based EAP GTC authenication module.])
109 ARG_ENABL_SET([eap-aka],        [enable EAP AKA authentication module.])
110 ARG_ENABL_SET([eap-aka-3gpp2],  [enable EAP AKA backend implementing 3GPP2 algorithms in software. Requires libgmp.])
111 ARG_ENABL_SET([eap-mschapv2],   [enable EAP MS-CHAPv2 authenication module.])
112 ARG_ENABL_SET([eap-radius],     [enable RADIUS proxy authenication module.])
113 ARG_DISBL_SET([kernel-netlink], [disable the netlink kernel interface.])
114 ARG_ENABL_SET([kernel-pfkey],   [enable the PF_KEY kernel interface.])
115 ARG_ENABL_SET([kernel-pfroute], [enable the PF_ROUTE kernel interface.])
116 ARG_ENABL_SET([kernel-klips],   [enable the KLIPS kernel interface.])
117 ARG_DISBL_SET([socket-default], [disable default socket implementation for charon.])
118 ARG_ENABL_SET([socket-raw],     [enable raw socket implementation of charon, enforced if pluto is enabled])
119 ARG_ENABL_SET([socket-dynamic], [enable dynamic socket implementation for charon])
120 ARG_ENABL_SET([farp],           [enable ARP faking plugin that responds to ARP requests to peers virtual IP])
121 ARG_ENABL_SET([nat-transport],  [enable NAT traversal with IPsec transport mode in pluto.])
122 ARG_DISBL_SET([vendor-id],      [disable the sending of the strongSwan vendor ID in pluto.])
123 ARG_DISBL_SET([xauth-vid],      [disable the sending of the XAUTH vendor ID.])
124 ARG_ENABL_SET([dumm],           [enable the DUMM UML test framework.])
125 ARG_ENABL_SET([fast],           [enable libfast (FastCGI Application Server w/ templates.])
126 ARG_ENABL_SET([manager],        [enable web management console (proof of concept).])
127 ARG_ENABL_SET([mediation],      [enable IKEv2 Mediation Extension.])
128 ARG_ENABL_SET([integrity-test], [enable integrity testing of libstrongswan and plugins.])
129 ARG_DISBL_SET([pluto],          [disable the IKEv1 keying daemon pluto.])
130 ARG_DISBL_SET([threads],        [disable the use of threads in pluto. Charon always uses threads.])
131 ARG_DISBL_SET([charon],         [disable the IKEv2 keying daemon charon.])
132 ARG_DISBL_SET([tools],          [disable additional utilities (openac, scepclient and pki).])
133 ARG_DISBL_SET([scripts],        [disable additional utilities (found in directory scripts).])
134 ARG_DISBL_SET([updown],         [disable updown firewall script plugin.])
135 ARG_DISBL_SET([attr],           [disable strongswan.conf based configuration attribute plugin.])
136 ARG_ENABL_SET([attr-sql],       [enable SQL based configuration attribute plugin.])
137 ARG_ENABL_SET([dhcp],           [enable DHCP based attribute provider plugin.])
138 ARG_DISBL_SET([resolve],        [disable resolve DNS handler plugin.])
139 ARG_ENABL_SET([padlock],        [enables VIA Padlock crypto plugin.])
140 ARG_ENABL_SET([openssl],        [enables the OpenSSL crypto plugin.])
141 ARG_ENABL_SET([gcrypt],         [enables the libgcrypt plugin.])
142 ARG_ENABL_SET([agent],          [enables the ssh-agent signing plugin.])
143 ARG_ENABL_SET([uci],            [enable OpenWRT UCI configuration plugin.])
144 ARG_ENABL_SET([android],        [enable Android specific plugin.])
145 ARG_ENABL_SET([nm],             [enable NetworkManager plugin.])
146 ARG_ENABL_SET([ha],             [enable high availability cluster plugin.])
147 ARG_ENABL_SET([vstr],           [enforce using the Vstr string library to replace glibc-like printf hooks.])
148 ARG_ENABL_SET([monolithic],     [build monolithic version of libstrongswan that includes all enabled plugins. Similarly, the plugins of charon are assembled in libcharon.])
149
150 dnl =========================
151 dnl  set up compiler and flags
152 dnl =========================
153
154 if test -z "$CFLAGS"; then
155         CFLAGS="-g -O2 -Wall -Wno-format -Wno-pointer-sign -Wno-strict-aliasing"
156 fi
157 AC_PROG_CC
158 AC_LIB_PREFIX
159 AC_C_BIGENDIAN
160
161 dnl =========================
162 dnl  check required programs
163 dnl =========================
164
165 AC_PROG_INSTALL
166 AC_PROG_LIBTOOL
167 AC_PROG_EGREP
168 AC_PROG_AWK
169 AC_PROG_LEX
170 AC_PROG_YACC
171 AC_PATH_PROG([PERL], [perl], [], [$PATH:/bin:/usr/bin:/usr/local/bin])
172 AC_PATH_PROG([GPERF], [gperf], [], [$PATH:/bin:/usr/bin:/usr/local/bin])
173
174 dnl because gperf is not needed by end-users we just report it but do not abort on failure
175 AC_MSG_CHECKING([gperf version >= 3.0.0])
176 if test -x "$GPERF"; then
177         if test "`$GPERF --version | $AWK -F' ' '/^GNU gperf/ { print $3 }' | $AWK -F. '{ print $1 }'`" -ge "3"; then
178                 AC_MSG_RESULT([yes])
179         else
180                 AC_MSG_RESULT([no])
181         fi
182 else
183         AC_MSG_RESULT([not found])
184 fi
185
186 dnl translate user/group to numercial ids
187 AC_MSG_CHECKING([for uid of user "$ipsecuser"])
188 ipsecuid=`id -u $ipsecuser 2>/dev/null`
189 if test -n "$ipsecuid"; then
190         AC_MSG_RESULT([$ipsecuid])
191         AC_SUBST(ipsecuid)
192 else
193         AC_MSG_ERROR([not found])
194 fi
195 AC_MSG_CHECKING([for gid of group "$ipsecgroup"])
196 ipsecgid=`$EGREP "^$ipsecgroup:" /etc/group | $AWK -F: '{ print $3 }'`
197 if test -n "$ipsecgid"; then
198         AC_MSG_RESULT([$ipsecgid])
199         AC_SUBST(ipsecgid)
200 else
201         AC_MSG_ERROR([not found])
202 fi
203
204 dnl =========================
205 dnl  dependency calculation
206 dnl =========================
207
208 if test x$eap_aka_3gpp2 = xtrue; then
209         gmp=true;
210 fi
211
212 if test x$eap_aka = xtrue; then
213         fips_prf=true;
214         simaka=true;
215 fi
216
217 if test x$eap_sim = xtrue; then
218         fips_prf=true;
219         simaka=true;
220 fi
221
222 if test x$fips_prf = xtrue; then
223         if test x$openssl = xfalse; then
224                 sha1=true;
225         fi
226 fi
227
228 if test x$smp = xtrue; then
229         xml=true
230 fi
231
232 if test x$manager = xtrue; then
233         fast=true
234 fi
235
236 if test x$medsrv = xtrue; then
237         mediation=true
238         fast=true
239 fi
240
241 if test x$medcli = xtrue; then
242         mediation=true
243 fi
244
245 if test x$pluto = xtrue; then
246         if test x$socket_raw = xfalse; then
247                 AC_MSG_NOTICE([Enforcing --enable-socket-raw, as pluto is enabled])
248                 socket_raw=true
249                 if test x$socket_default_given = xfalse; then
250                         socket_default=false
251                 fi
252         fi
253 fi
254
255 dnl ===========================================
256 dnl  check required libraries and header files
257 dnl ===========================================
258
259 AC_HEADER_STDBOOL
260 AC_FUNC_ALLOCA
261
262 dnl libraries needed on some platforms but not on others
263 dnl ====================================================
264 saved_LIBS=$LIBS
265
266 dnl FreeBSD and Mac OS X have dlopen integrated in libc, Linux needs libdl
267 LIBS=""
268 AC_SEARCH_LIBS(dlopen, dl, [DLLIB=$LIBS])
269 AC_SUBST(DLLIB)
270
271 dnl glibc's backtrace() can be replicated on FreeBSD with libexecinfo
272 LIBS=""
273 AC_SEARCH_LIBS(backtrace, execinfo, [BTLIB=$LIBS])
274 AC_CHECK_FUNCS(backtrace)
275 AC_SUBST(BTLIB)
276
277 dnl OpenSolaris needs libsocket and libnsl for socket()
278 LIBS=""
279 AC_SEARCH_LIBS(socket, socket, [SOCKLIB=$LIBS],
280         [AC_CHECK_LIB(nsl, socket, [SOCKLIB="-lsocket -lnsl"], [], [-lsocket])]
281 )
282 AC_SUBST(SOCKLIB)
283
284 dnl FreeBSD has clock_gettime in libc, Linux needs librt
285 LIBS=""
286 AC_SEARCH_LIBS(clock_gettime, rt, [RTLIB=$LIBS])
287 AC_CHECK_FUNCS(clock_gettime)
288 AC_SUBST(RTLIB)
289
290 dnl Android has pthread_* functions in bionic (libc), others need libpthread
291 LIBS=""
292 AC_SEARCH_LIBS(pthread_create, pthread, [PTHREADLIB=$LIBS])
293 AC_SUBST(PTHREADLIB)
294
295 LIBS=$saved_LIBS
296 dnl ======================
297
298 AC_MSG_CHECKING(for dladdr)
299 AC_TRY_COMPILE(
300         [#define _GNU_SOURCE
301          #include <dlfcn.h>],
302         [Dl_info* info = 0;
303          dladdr(0, info);],
304         [AC_MSG_RESULT([yes]); AC_DEFINE([HAVE_DLADDR])],
305         [AC_MSG_RESULT([no])]
306 )
307
308 dnl check if pthread_condattr_setclock(CLOCK_MONOTONE) is supported
309 saved_LIBS=$LIBS
310 LIBS=$PTHREADLIB
311 AC_MSG_CHECKING([for pthread_condattr_setclock(CLOCK_MONOTONE)])
312 AC_TRY_RUN(
313         [#include <pthread.h>
314          int main() { pthread_condattr_t attr;
315                 pthread_condattr_init(&attr);
316                 return pthread_condattr_setclock(&attr, CLOCK_MONOTONIC);}],
317         [AC_MSG_RESULT([yes]); AC_DEFINE([HAVE_CONDATTR_CLOCK_MONOTONIC])],
318         [AC_MSG_RESULT([no])],
319         dnl Check existence of pthread_condattr_setclock if cross-compiling
320         [AC_MSG_RESULT([unknown]);
321          AC_CHECK_FUNCS(pthread_condattr_setclock,
322                 [AC_DEFINE([HAVE_CONDATTR_CLOCK_MONOTONIC])]
323         )]
324 )
325 dnl check if we actually are able to configure attributes on cond vars
326 AC_CHECK_FUNCS(pthread_condattr_init)
327 dnl instead of pthread_condattr_setclock Android has this function
328 AC_CHECK_FUNCS(pthread_cond_timedwait_monotonic)
329 dnl check if we can cancel threads
330 AC_CHECK_FUNCS(pthread_cancel)
331 dnl check if native rwlocks are available
332 AC_CHECK_FUNCS(pthread_rwlock_init)
333 LIBS=$saved_LIBS
334
335 AC_CHECK_FUNCS(prctl)
336
337 AC_CHECK_HEADERS(sys/sockio.h)
338 AC_CHECK_HEADERS(net/pfkeyv2.h netipsec/ipsec.h netinet6/ipsec.h linux/udp.h)
339
340 AC_CHECK_MEMBERS([struct sockaddr.sa_len], [], [],
341 [
342         #include <sys/types.h>
343         #include <sys/socket.h>
344 ])
345
346 AC_CHECK_MEMBERS([struct sadb_x_policy.sadb_x_policy_priority], [], [],
347 [
348         #include <sys/types.h>
349         #ifdef HAVE_NET_PFKEYV2_H
350         #include <net/pfkeyv2.h>
351         #else
352         #include <stdint.h>
353         #include <linux/pfkeyv2.h>
354         #endif
355 ])
356
357 AC_MSG_CHECKING([for in6addr_any])
358 AC_TRY_COMPILE(
359         [#include <sys/types.h>
360         #include <sys/socket.h>
361         #include <netinet/in.h>],
362         [struct in6_addr in6;
363         in6 = in6addr_any;],
364         [AC_MSG_RESULT([yes]); AC_DEFINE([HAVE_IN6ADDR_ANY])],
365         [AC_MSG_RESULT([no])]
366 )
367
368 AC_MSG_CHECKING([for in6_pktinfo])
369 AC_TRY_COMPILE(
370         [#define _GNU_SOURCE
371         #include <sys/types.h>
372         #include <sys/socket.h>
373         #include <netinet/in.h>],
374         [struct in6_pktinfo pi;
375         if (pi.ipi6_ifindex)
376         {
377                 return 0;
378         }],
379         [AC_MSG_RESULT([yes]); AC_DEFINE([HAVE_IN6_PKTINFO])],
380         [AC_MSG_RESULT([no])]
381 )
382
383 AC_MSG_CHECKING([for IPSEC_MODE_BEET])
384 AC_TRY_COMPILE(
385         [#include <sys/types.h>
386         #ifdef HAVE_NETIPSEC_IPSEC_H
387         #include <netipsec/ipsec.h>
388         #elif defined(HAVE_NETINET6_IPSEC_H)
389         #include <netinet6/ipsec.h>
390         #else
391         #include <stdint.h>
392         #include <linux/ipsec.h>
393         #endif],
394         [int mode = IPSEC_MODE_BEET;
395          return mode;],
396         [AC_MSG_RESULT([yes]); AC_DEFINE([HAVE_IPSEC_MODE_BEET])],
397         [AC_MSG_RESULT([no])]
398 )
399
400 AC_MSG_CHECKING([for IPSEC_DIR_FWD])
401 AC_TRY_COMPILE(
402         [#include <sys/types.h>
403         #ifdef HAVE_NETIPSEC_IPSEC_H
404         #include <netipsec/ipsec.h>
405         #elif defined(HAVE_NETINET6_IPSEC_H)
406         #include <netinet6/ipsec.h>
407         #else
408         #include <stdint.h>
409         #include <linux/ipsec.h>
410         #endif],
411         [int dir = IPSEC_DIR_FWD;
412          return dir;],
413         [AC_MSG_RESULT([yes]); AC_DEFINE([HAVE_IPSEC_DIR_FWD])],
414         [AC_MSG_RESULT([no])]
415 )
416
417 AC_MSG_CHECKING([for gcc atomic operations])
418 AC_TRY_RUN(
419 [
420         int main() {
421                 volatile int ref = 1;
422                 __sync_fetch_and_add (&ref, 1);
423                 __sync_sub_and_fetch (&ref, 1);
424                 /* Make sure test fails if operations are not supported */
425                 __sync_val_compare_and_swap(&ref, 1, 0);
426                 return ref;
427         }
428 ],
429 [AC_MSG_RESULT([yes]); AC_DEFINE(HAVE_GCC_ATOMIC_OPERATIONS)],
430 [AC_MSG_RESULT([no])],
431 [AC_MSG_RESULT([no])])
432
433 dnl check for the new register_printf_specifier function with len argument,
434 dnl or the deprecated register_printf_function without
435 AC_CHECK_FUNC(
436         [register_printf_specifier],
437         [AC_DEFINE(HAVE_PRINTF_SPECIFIER)],
438         [AC_CHECK_FUNC(
439                 [register_printf_function],
440                 [AC_DEFINE(HAVE_PRINTF_FUNCTION)],
441                 [
442                         AC_MSG_NOTICE([printf does not support custom format specifiers!])
443                         vstr=true
444                 ]
445         )]
446 )
447
448 if test x$vstr = xtrue; then
449         AC_HAVE_LIBRARY([vstr],[LIBS="$LIBS"],[AC_MSG_ERROR([Vstr string library not found])])
450         AC_DEFINE(USE_VSTR)
451 fi
452
453 if test x$gmp = xtrue; then
454         saved_LIBS=$LIBS
455         AC_HAVE_LIBRARY([gmp],,[AC_MSG_ERROR([GNU Multi Precision library gmp not found])])
456         AC_MSG_CHECKING([mpz_powm_sec])
457         if test x$mpz_powm_sec = xyes; then
458                 AC_TRY_COMPILE(
459                         [#include "gmp.h"],
460                         [
461                                 void *x = mpz_powm_sec;
462                         ],
463                         [AC_MSG_RESULT([yes]); AC_DEFINE(HAVE_MPZ_POWM_SEC)], [AC_MSG_RESULT([no])]
464                 )
465         else
466                 AC_MSG_RESULT([disabled])
467         fi
468         LIBS=$saved_LIBS
469         AC_MSG_CHECKING([gmp.h version >= 4.1.4])
470         AC_TRY_COMPILE(
471                 [#include "gmp.h"],
472                 [
473                         #if (__GNU_MP_VERSION*100 +  __GNU_MP_VERSION_MINOR*10 + __GNU_MP_VERSION_PATCHLEVEL) < 414
474                                 #error bad gmp
475                         #endif
476                 ],
477                 [AC_MSG_RESULT([yes])], [AC_MSG_RESULT([no]); AC_MSG_ERROR([No usable gmp.h found!])]
478         )
479 fi
480
481 if test x$ldap = xtrue; then
482         AC_HAVE_LIBRARY([ldap],[LIBS="$LIBS"],[AC_MSG_ERROR([LDAP library ldap not found])])
483         AC_HAVE_LIBRARY([lber],[LIBS="$LIBS"],[AC_MSG_ERROR([LDAP library lber not found])])
484         AC_CHECK_HEADER([ldap.h],,[AC_MSG_ERROR([LDAP header ldap.h not found!])])
485 fi
486
487 if test x$curl = xtrue; then
488         AC_HAVE_LIBRARY([curl],[LIBS="$LIBS"],[AC_MSG_ERROR([CURL library curl not found])])
489         AC_CHECK_HEADER([curl/curl.h],,[AC_MSG_ERROR([CURL header curl/curl.h not found!])])
490 fi
491
492 if test x$xml = xtrue; then
493         PKG_CHECK_MODULES(xml, [libxml-2.0])
494         AC_SUBST(xml_CFLAGS)
495         AC_SUBST(xml_LIBS)
496 fi
497
498 if test x$dumm = xtrue; then
499         PKG_CHECK_MODULES(gtk, [gtk+-2.0 vte])
500         AC_SUBST(gtk_CFLAGS)
501         AC_SUBST(gtk_LIBS)
502         AC_CHECK_PROGS(RUBY, ruby)
503         AC_MSG_CHECKING([for Ruby header files])
504         if test -n "$RUBY"; then
505                 RUBYDIR=`($RUBY -rmkmf -e 'print Config::CONFIG[["archdir"]] || $archdir') 2>/dev/null`
506                 if test -n "$RUBYDIR"; then
507                         dirs="$RUBYDIR"
508                         RUBYINCLUDE=none
509                         for i in $dirs; do
510                                 if test -r $i/ruby.h; then
511                                         AC_MSG_RESULT([$i])
512                                         RUBYINCLUDE="-I$i"
513                                         break;
514                                 fi
515                         done
516                         if test x"$RUBYINCLUDE" = xnone; then
517                                 AC_MSG_ERROR([ruby.h not found])
518                         fi
519                         AC_SUBST(RUBYINCLUDE)
520                 else
521                         AC_MSG_ERROR([unable to determine ruby configuration])
522                 fi
523         else
524                 AC_MSG_ERROR([don't know how to run ruby])
525         fi
526 fi
527
528 if test x$fast = xtrue; then
529         AC_HAVE_LIBRARY([neo_cgi],[LIBS="$LIBS"],[AC_MSG_ERROR([ClearSilver library neo_cgi not found!])])
530         AC_HAVE_LIBRARY([neo_utl],[LIBS="$LIBS"],[AC_MSG_ERROR([ClearSilver library neo_utl not found!])])
531         AC_HAVE_LIBRARY([z],[LIBS="$LIBS"],[AC_MSG_ERROR([ClearSilver dependency zlib not found!])])
532 dnl autoconf does not like CamelCase!? How to fix this?
533 dnl     AC_CHECK_HEADER([ClearSilver/ClearSilver.h],,[AC_MSG_ERROR([ClearSilver header file ClearSilver/ClearSilver.h not found!])])
534
535         AC_HAVE_LIBRARY([fcgi],[LIBS="$LIBS"],[AC_MSG_ERROR([FastCGI library fcgi not found!])])
536         AC_CHECK_HEADER([fcgiapp.h],,[AC_MSG_ERROR([FastCGI header file fcgiapp.h not found!])])
537 fi
538
539 if test x$mysql = xtrue; then
540         AC_PATH_PROG([MYSQLCONFIG], [mysql_config], [], [$PATH:/bin:/usr/bin:/usr/local/bin])
541         if test x$MYSQLCONFIG = x; then
542                 AC_MSG_ERROR([mysql_config not found!])
543         fi
544         AC_SUBST(MYSQLLIB, `$MYSQLCONFIG --libs_r`)
545         AC_SUBST(MYSQLCFLAG, `$MYSQLCONFIG --cflags`)
546 fi
547
548 if test x$sqlite = xtrue; then
549         AC_HAVE_LIBRARY([sqlite3],[LIBS="$LIBS"],[AC_MSG_ERROR([SQLite library sqlite3 not found])])
550         AC_CHECK_HEADER([sqlite3.h],,[AC_MSG_ERROR([SQLite header sqlite3.h not found!])])
551         AC_MSG_CHECKING([sqlite3_prepare_v2])
552         AC_TRY_COMPILE(
553                 [#include <sqlite3.h>],
554                 [
555                         void *test = sqlite3_prepare_v2;
556                 ],
557                 [AC_MSG_RESULT([yes])]; AC_DEFINE_UNQUOTED(HAVE_SQLITE3_PREPARE_V2, 1), [AC_MSG_RESULT([no])])
558         AC_MSG_CHECKING([sqlite3.h version >= 3.3.1])
559         AC_TRY_COMPILE(
560                 [#include <sqlite3.h>],
561                 [
562                         #if SQLITE_VERSION_NUMBER < 3003001
563                                 #error bad sqlite
564                         #endif
565                 ],
566                 [AC_MSG_RESULT([yes])], [AC_MSG_RESULT([no]); AC_MSG_ERROR([SQLite version >= 3.3.1 required!])])
567 fi
568
569 if test x$openssl = xtrue; then
570         AC_HAVE_LIBRARY([crypto],[LIBS="$LIBS"],[AC_MSG_ERROR([OpenSSL crypto library not found])])
571         AC_CHECK_HEADER([openssl/evp.h],,[AC_MSG_ERROR([OpenSSL header openssl/evp.h not found!])])
572 fi
573
574 if test x$gcrypt = xtrue; then
575         AC_HAVE_LIBRARY([gcrypt],[LIBS="$LIBS"],[AC_MSG_ERROR([gcrypt library not found])])
576         AC_CHECK_HEADER([gcrypt.h],,[AC_MSG_ERROR([gcrypt header gcrypt.h not found!])])
577         AC_MSG_CHECKING([gcrypt CAMELLIA cipher])
578         AC_TRY_COMPILE(
579                 [#include <gcrypt.h>],
580                 [enum gcry_cipher_algos alg = GCRY_CIPHER_CAMELLIA128;],
581                 [AC_MSG_RESULT([yes]); AC_DEFINE([HAVE_GCRY_CIPHER_CAMELLIA])],
582                 [AC_MSG_RESULT([no])]
583         )
584 fi
585
586 if test x$uci = xtrue; then
587         AC_HAVE_LIBRARY([uci],[LIBS="$LIBS"],[AC_MSG_ERROR([UCI library libuci not found])])
588         AC_CHECK_HEADER([uci.h],,[AC_MSG_ERROR([UCI header uci.h not found!])])
589 fi
590
591 if test x$android = xtrue; then
592         AC_HAVE_LIBRARY([cutils],[LIBS="$LIBS"],[AC_MSG_ERROR([Android library libcutils not found])])
593         AC_CHECK_HEADER([cutils/properties.h],,[AC_MSG_ERROR([Android header cutils/properties.h not found!])])
594         dnl we have to force the use of libdl here because the autodetection
595         dnl above does not work correctly when cross-compiling for android.
596         DLLIB="-ldl"
597         AC_SUBST(DLLIB)
598 fi
599
600 if test x$nm = xtrue; then
601         PKG_CHECK_EXISTS([libnm-glib],
602                 [PKG_CHECK_MODULES(nm, [NetworkManager gthread-2.0 libnm-glib libnm-glib-vpn])],
603                 [PKG_CHECK_MODULES(nm, [NetworkManager gthread-2.0 libnm_glib libnm_glib_vpn])]
604         )
605         AC_SUBST(nm_CFLAGS)
606         AC_SUBST(nm_LIBS)
607 fi
608
609 if test x$eap_gtc = xtrue; then
610         AC_HAVE_LIBRARY([pam],[LIBS="$LIBS"],[AC_MSG_ERROR([PAM library not found])])
611         AC_CHECK_HEADER([security/pam_appl.h],,[AC_MSG_ERROR([PAM header security/pam_appl.h not found!])])
612 fi
613
614 if test x$capabilities = xlibcap; then
615         AC_HAVE_LIBRARY([cap],[LIBS="$LIBS"],[AC_MSG_ERROR([libcap library not found])])
616         AC_CHECK_HEADER([sys/capability.h],,[AC_MSG_ERROR([libcap header sys/capability.h not found!])])
617 fi
618
619 if test x$integrity_test = xtrue; then
620         AC_MSG_CHECKING([for dladdr()])
621         AC_TRY_COMPILE(
622                 [#define _GNU_SOURCE
623                  #include <dlfcn.h>],
624                 [Dl_info info; dladdr(main, &info);],
625                 [AC_MSG_RESULT([yes])], [AC_MSG_RESULT([no]);
626                  AC_MSG_ERROR([dladdr() not supported, required by integrity-test!])]
627         )
628         AC_MSG_CHECKING([for dl_iterate_phdr()])
629         AC_TRY_COMPILE(
630                 [#define _GNU_SOURCE
631                  #include <link.h>],
632                 [dl_iterate_phdr((void*)0, (void*)0);],
633                 [AC_MSG_RESULT([yes])], [AC_MSG_RESULT([no]);
634                  AC_MSG_ERROR([dl_iterate_phdr() not supported, required by integrity-test!])]
635         )
636 fi
637
638 dnl ==========================================================
639 dnl  collect all plugins for libstrongswan, libhydra and pluto
640 dnl ==========================================================
641
642 libstrongswan_plugins=
643 libhydra_plugins=
644 pluto_plugins=
645
646 if test x$test_vectors = xtrue; then
647         libstrongswan_plugins=${libstrongswan_plugins}" test-vectors"
648         pluto_plugins=${pluto_plugins}" test-vectors"
649 fi
650 if test x$curl = xtrue; then
651         libstrongswan_plugins=${libstrongswan_plugins}" curl"
652         pluto_plugins=${pluto_plugins}" curl"
653 fi
654 if test x$ldap = xtrue; then
655         libstrongswan_plugins=${libstrongswan_plugins}" ldap"
656         pluto_plugins=${pluto_plugins}" ldap"
657 fi
658 if test x$aes = xtrue; then
659         libstrongswan_plugins=${libstrongswan_plugins}" aes"
660         pluto_plugins=${pluto_plugins}" aes"
661 fi
662 if test x$des = xtrue; then
663         libstrongswan_plugins=${libstrongswan_plugins}" des"
664         pluto_plugins=${pluto_plugins}" des"
665 fi
666 if test x$blowfish = xtrue; then
667         libstrongswan_plugins=${libstrongswan_plugins}" blowfish"
668         pluto_plugins=${pluto_plugins}" blowfish"
669 fi
670 if test x$sha1 = xtrue; then
671         libstrongswan_plugins=${libstrongswan_plugins}" sha1"
672         pluto_plugins=${pluto_plugins}" sha1"
673 fi
674 if test x$sha2 = xtrue; then
675         libstrongswan_plugins=${libstrongswan_plugins}" sha2"
676         pluto_plugins=${pluto_plugins}" sha2"
677 fi
678 if test x$md4 = xtrue; then
679         libstrongswan_plugins=${libstrongswan_plugins}" md4"
680 fi
681 if test x$md5 = xtrue; then
682         libstrongswan_plugins=${libstrongswan_plugins}" md5"
683         pluto_plugins=${pluto_plugins}" md5"
684 fi
685 if test x$random = xtrue; then
686         libstrongswan_plugins=${libstrongswan_plugins}" random"
687         pluto_plugins=${pluto_plugins}" random"
688 fi
689 if test x$x509 = xtrue; then
690         libstrongswan_plugins=${libstrongswan_plugins}" x509"
691         pluto_plugins=${pluto_plugins}" x509"
692 fi
693 if test x$pubkey = xtrue; then
694         libstrongswan_plugins=${libstrongswan_plugins}" pubkey"
695         pluto_plugins=${pluto_plugins}" pubkey"
696 fi
697 if test x$pkcs1 = xtrue; then
698         libstrongswan_plugins=${libstrongswan_plugins}" pkcs1"
699         pluto_plugins=${pluto_plugins}" pkcs1"
700 fi
701 if test x$pgp = xtrue; then
702         libstrongswan_plugins=${libstrongswan_plugins}" pgp"
703         pluto_plugins=${pluto_plugins}" pgp"
704 fi
705 if test x$dnskey = xtrue; then
706         libstrongswan_plugins=${libstrongswan_plugins}" dnskey"
707         pluto_plugins=${pluto_plugins}" dnskey"
708 fi
709 if test x$pem = xtrue; then
710         libstrongswan_plugins=${libstrongswan_plugins}" pem"
711         pluto_plugins=${pluto_plugins}" pem"
712 fi
713 if test x$mysql = xtrue; then
714         libstrongswan_plugins=${libstrongswan_plugins}" mysql"
715         pluto_plugins=${pluto_plugins}" mysql"
716 fi
717 if test x$sqlite = xtrue; then
718         libstrongswan_plugins=${libstrongswan_plugins}" sqlite"
719         pluto_plugins=${pluto_plugins}" sqlite"
720 fi
721 if test x$padlock = xtrue; then
722         libstrongswan_plugins=${libstrongswan_plugins}" padlock"
723 fi
724 if test x$openssl = xtrue; then
725         libstrongswan_plugins=${libstrongswan_plugins}" openssl"
726         pluto_plugins=${pluto_plugins}" openssl"
727 fi
728 if test x$gcrypt = xtrue; then
729         libstrongswan_plugins=${libstrongswan_plugins}" gcrypt"
730         pluto_plugins=${pluto_plugins}" gcrypt"
731 fi
732 if test x$fips_prf = xtrue; then
733         libstrongswan_plugins=${libstrongswan_plugins}" fips-prf"
734 fi
735 if test x$xcbc = xtrue; then
736         libstrongswan_plugins=${libstrongswan_plugins}" xcbc"
737 fi
738 if test x$hmac = xtrue; then
739         libstrongswan_plugins=${libstrongswan_plugins}" hmac"
740         pluto_plugins=${pluto_plugins}" hmac"
741 fi
742 if test x$agent = xtrue; then
743         libstrongswan_plugins=${libstrongswan_plugins}" agent"
744 fi
745 if test x$gmp = xtrue; then
746         libstrongswan_plugins=${libstrongswan_plugins}" gmp"
747         pluto_plugins=${pluto_plugins}" gmp"
748 fi
749 if test x$attr = xtrue; then
750         libhydra_plugins=${libhydra_plugins}" attr"
751 fi
752 if test x$attr_sql = xtrue -o x$sql = xtrue; then
753         libhydra_plugins=${libhydra_plugins}" attr-sql"
754 fi
755 if test x$resolve = xtrue; then
756         libhydra_plugins=${libhydra_plugins}" resolve"
757 fi
758
759 AC_SUBST(libstrongswan_plugins)
760 AC_SUBST(libhydra_plugins)
761 AC_SUBST(pluto_plugins)
762
763 dnl =========================
764 dnl  set Makefile.am vars
765 dnl =========================
766
767 dnl libstrongswan plugins
768 dnl =====================
769 AM_CONDITIONAL(USE_TEST_VECTORS, test x$test_vectors = xtrue)
770 AM_CONDITIONAL(USE_CURL, test x$curl = xtrue)
771 AM_CONDITIONAL(USE_LDAP, test x$ldap = xtrue)
772 AM_CONDITIONAL(USE_AES, test x$aes = xtrue)
773 AM_CONDITIONAL(USE_DES, test x$des = xtrue)
774 AM_CONDITIONAL(USE_BLOWFISH, test x$blowfish = xtrue)
775 AM_CONDITIONAL(USE_MD4, test x$md4 = xtrue)
776 AM_CONDITIONAL(USE_MD5, test x$md5 = xtrue)
777 AM_CONDITIONAL(USE_SHA1, test x$sha1 = xtrue)
778 AM_CONDITIONAL(USE_SHA2, test x$sha2 = xtrue)
779 AM_CONDITIONAL(USE_FIPS_PRF, test x$fips_prf = xtrue)
780 AM_CONDITIONAL(USE_GMP, test x$gmp = xtrue)
781 AM_CONDITIONAL(USE_RANDOM, test x$random = xtrue)
782 AM_CONDITIONAL(USE_X509, test x$x509 = xtrue)
783 AM_CONDITIONAL(USE_PUBKEY, test x$pubkey = xtrue)
784 AM_CONDITIONAL(USE_PKCS1, test x$pkcs1 = xtrue)
785 AM_CONDITIONAL(USE_PGP, test x$pgp = xtrue)
786 AM_CONDITIONAL(USE_DNSKEY, test x$dnskey = xtrue)
787 AM_CONDITIONAL(USE_PEM, test x$pem = xtrue)
788 AM_CONDITIONAL(USE_HMAC, test x$hmac = xtrue)
789 AM_CONDITIONAL(USE_XCBC, test x$xcbc = xtrue)
790 AM_CONDITIONAL(USE_MYSQL, test x$mysql = xtrue)
791 AM_CONDITIONAL(USE_SQLITE, test x$sqlite = xtrue)
792 AM_CONDITIONAL(USE_ATTR_SQL, test x$attr_sql = xtrue -o x$sql = xtrue)
793 AM_CONDITIONAL(USE_PADLOCK, test x$padlock = xtrue)
794 AM_CONDITIONAL(USE_OPENSSL, test x$openssl = xtrue)
795 AM_CONDITIONAL(USE_GCRYPT, test x$gcrypt = xtrue)
796 AM_CONDITIONAL(USE_AGENT, test x$agent = xtrue)
797
798 dnl charon plugins
799 dnl ==============
800 AM_CONDITIONAL(USE_STROKE, test x$stroke = xtrue)
801 AM_CONDITIONAL(USE_MEDSRV, test x$medsrv = xtrue)
802 AM_CONDITIONAL(USE_MEDCLI, test x$medcli = xtrue)
803 AM_CONDITIONAL(USE_NM, test x$nm = xtrue)
804 AM_CONDITIONAL(USE_UCI, test x$uci = xtrue)
805 AM_CONDITIONAL(USE_ANDROID, test x$android = xtrue)
806 AM_CONDITIONAL(USE_SMP, test x$smp = xtrue)
807 AM_CONDITIONAL(USE_SQL, test x$sql = xtrue)
808 AM_CONDITIONAL(USE_UPDOWN, test x$updown = xtrue)
809 AM_CONDITIONAL(USE_ATTR, test x$attr = xtrue)
810 AM_CONDITIONAL(USE_DHCP, test x$dhcp = xtrue)
811 AM_CONDITIONAL(USE_RESOLVE, test x$resolve = xtrue)
812 AM_CONDITIONAL(USE_UNIT_TESTS, test x$unit_tests = xtrue)
813 AM_CONDITIONAL(USE_LOAD_TESTER, test x$load_tester = xtrue)
814 AM_CONDITIONAL(USE_HA, test x$ha = xtrue)
815 AM_CONDITIONAL(USE_EAP_SIM, test x$eap_sim = xtrue)
816 AM_CONDITIONAL(USE_EAP_SIM_FILE, test x$eap_sim_file = xtrue)
817 AM_CONDITIONAL(USE_EAP_SIMAKA_PSEUDONYM, test x$eap_simaka_pseudonym = xtrue)
818 AM_CONDITIONAL(USE_EAP_SIMAKA_REAUTH, test x$eap_simaka_reauth = xtrue)
819 AM_CONDITIONAL(USE_EAP_IDENTITY, test x$eap_identity = xtrue)
820 AM_CONDITIONAL(USE_EAP_MD5, test x$eap_md5 = xtrue)
821 AM_CONDITIONAL(USE_EAP_GTC, test x$eap_gtc = xtrue)
822 AM_CONDITIONAL(USE_EAP_AKA, test x$eap_aka = xtrue)
823 AM_CONDITIONAL(USE_EAP_AKA_3GPP2, test x$eap_aka_3gpp2 = xtrue)
824 AM_CONDITIONAL(USE_EAP_MSCHAPV2, test x$eap_mschapv2 = xtrue)
825 AM_CONDITIONAL(USE_EAP_RADIUS, test x$eap_radius = xtrue)
826 AM_CONDITIONAL(USE_KERNEL_NETLINK, test x$kernel_netlink = xtrue)
827 AM_CONDITIONAL(USE_KERNEL_PFKEY, test x$kernel_pfkey = xtrue)
828 AM_CONDITIONAL(USE_KERNEL_PFROUTE, test x$kernel_pfroute = xtrue)
829 AM_CONDITIONAL(USE_KERNEL_KLIPS, test x$kernel_klips = xtrue)
830 AM_CONDITIONAL(USE_SOCKET_DEFAULT, test x$socket_default = xtrue)
831 AM_CONDITIONAL(USE_SOCKET_RAW, test x$socket_raw = xtrue)
832 AM_CONDITIONAL(USE_SOCKET_DYNAMIC, test x$socket_dynamic = xtrue)
833 AM_CONDITIONAL(USE_FARP, test x$farp = xtrue)
834
835 dnl other options
836 dnl =============
837 AM_CONDITIONAL(USE_SMARTCARD, test x$smartcard = xtrue)
838 AM_CONDITIONAL(USE_CISCO_QUIRKS, test x$cisco_quirks = xtrue)
839 AM_CONDITIONAL(USE_LEAK_DETECTIVE, test x$leak_detective = xtrue)
840 AM_CONDITIONAL(USE_LOCK_PROFILER, test x$lock_profiler = xtrue)
841 AM_CONDITIONAL(USE_NAT_TRANSPORT, test x$nat_transport = xtrue)
842 AM_CONDITIONAL(USE_VENDORID, test x$vendor_id = xtrue)
843 AM_CONDITIONAL(USE_XAUTH_VID, test x$xauth_vid = xtrue)
844 AM_CONDITIONAL(USE_DUMM, test x$dumm = xtrue)
845 AM_CONDITIONAL(USE_FAST, test x$fast = xtrue)
846 AM_CONDITIONAL(USE_MANAGER, test x$manager = xtrue)
847 AM_CONDITIONAL(USE_ME, test x$mediation = xtrue)
848 AM_CONDITIONAL(USE_INTEGRITY_TEST, test x$integrity_test = xtrue)
849 AM_CONDITIONAL(USE_CAPABILITIES, test x$capabilities = xlibcap)
850 AM_CONDITIONAL(USE_PLUTO, test x$pluto = xtrue)
851 AM_CONDITIONAL(USE_THREADS, test x$threads = xtrue)
852 AM_CONDITIONAL(USE_CHARON, test x$charon = xtrue)
853 AM_CONDITIONAL(USE_TOOLS, test x$tools = xtrue)
854 AM_CONDITIONAL(USE_SCRIPTS, test x$scripts = xtrue)
855 AM_CONDITIONAL(USE_LIBSTRONGSWAN, test x$charon = xtrue -o x$pluto = xtrue -o x$tools = xtrue)
856 AM_CONDITIONAL(USE_LIBHYDRA, test x$charon = xtrue -o x$pluto = xtrue)
857 AM_CONDITIONAL(USE_FILE_CONFIG, test x$pluto = xtrue -o x$stroke = xtrue)
858 AM_CONDITIONAL(USE_VSTR, test x$vstr = xtrue)
859 AM_CONDITIONAL(USE_SIMAKA, test x$simaka = xtrue)
860 AM_CONDITIONAL(MONOLITHIC, test x$monolithic = xtrue)
861
862 dnl ==============================
863 dnl  set global definitions
864 dnl ==============================
865
866 if test x$mediation = xtrue; then
867         AC_DEFINE(ME)
868 fi
869 if test x$capabilities = xlibcap; then
870         AC_DEFINE(CAPABILITIES)
871 fi
872 if test x$monolithic = xtrue; then
873         AC_DEFINE(MONOLITHIC)
874 fi
875
876
877 dnl ==============================
878 dnl  build Makefiles
879 dnl ==============================
880
881 AC_OUTPUT(
882         Makefile
883         src/Makefile
884         src/include/Makefile
885         src/libstrongswan/Makefile
886         src/libstrongswan/plugins/aes/Makefile
887         src/libstrongswan/plugins/des/Makefile
888         src/libstrongswan/plugins/blowfish/Makefile
889         src/libstrongswan/plugins/md4/Makefile
890         src/libstrongswan/plugins/md5/Makefile
891         src/libstrongswan/plugins/sha1/Makefile
892         src/libstrongswan/plugins/sha2/Makefile
893         src/libstrongswan/plugins/fips_prf/Makefile
894         src/libstrongswan/plugins/gmp/Makefile
895         src/libstrongswan/plugins/random/Makefile
896         src/libstrongswan/plugins/hmac/Makefile
897         src/libstrongswan/plugins/xcbc/Makefile
898         src/libstrongswan/plugins/x509/Makefile
899         src/libstrongswan/plugins/pubkey/Makefile
900         src/libstrongswan/plugins/pkcs1/Makefile
901         src/libstrongswan/plugins/pgp/Makefile
902         src/libstrongswan/plugins/dnskey/Makefile
903         src/libstrongswan/plugins/pem/Makefile
904         src/libstrongswan/plugins/curl/Makefile
905         src/libstrongswan/plugins/ldap/Makefile
906         src/libstrongswan/plugins/mysql/Makefile
907         src/libstrongswan/plugins/sqlite/Makefile
908         src/libstrongswan/plugins/padlock/Makefile
909         src/libstrongswan/plugins/openssl/Makefile
910         src/libstrongswan/plugins/gcrypt/Makefile
911         src/libstrongswan/plugins/agent/Makefile
912         src/libstrongswan/plugins/test_vectors/Makefile
913         src/libhydra/Makefile
914         src/libhydra/plugins/attr/Makefile
915         src/libhydra/plugins/attr_sql/Makefile
916         src/libhydra/plugins/resolve/Makefile
917         src/libfreeswan/Makefile
918         src/libsimaka/Makefile
919         src/pluto/Makefile
920         src/whack/Makefile
921         src/charon/Makefile
922         src/libcharon/Makefile
923         src/libcharon/plugins/eap_aka/Makefile
924         src/libcharon/plugins/eap_aka_3gpp2/Makefile
925         src/libcharon/plugins/eap_identity/Makefile
926         src/libcharon/plugins/eap_md5/Makefile
927         src/libcharon/plugins/eap_gtc/Makefile
928         src/libcharon/plugins/eap_sim/Makefile
929         src/libcharon/plugins/eap_sim_file/Makefile
930         src/libcharon/plugins/eap_simaka_pseudonym/Makefile
931         src/libcharon/plugins/eap_simaka_reauth/Makefile
932         src/libcharon/plugins/eap_mschapv2/Makefile
933         src/libcharon/plugins/eap_radius/Makefile
934         src/libcharon/plugins/kernel_netlink/Makefile
935         src/libcharon/plugins/kernel_pfkey/Makefile
936         src/libcharon/plugins/kernel_pfroute/Makefile
937         src/libcharon/plugins/kernel_klips/Makefile
938         src/libcharon/plugins/socket_default/Makefile
939         src/libcharon/plugins/socket_raw/Makefile
940         src/libcharon/plugins/socket_dynamic/Makefile
941         src/libcharon/plugins/farp/Makefile
942         src/libcharon/plugins/smp/Makefile
943         src/libcharon/plugins/sql/Makefile
944         src/libcharon/plugins/medsrv/Makefile
945         src/libcharon/plugins/medcli/Makefile
946         src/libcharon/plugins/nm/Makefile
947         src/libcharon/plugins/uci/Makefile
948         src/libcharon/plugins/ha/Makefile
949         src/libcharon/plugins/android/Makefile
950         src/libcharon/plugins/stroke/Makefile
951         src/libcharon/plugins/updown/Makefile
952         src/libcharon/plugins/dhcp/Makefile
953         src/libcharon/plugins/unit_tester/Makefile
954         src/libcharon/plugins/load_tester/Makefile
955         src/stroke/Makefile
956         src/ipsec/Makefile
957         src/starter/Makefile
958         src/_updown/Makefile
959         src/_updown_espmark/Makefile
960         src/_copyright/Makefile
961         src/openac/Makefile
962         src/scepclient/Makefile
963         src/pki/Makefile
964         src/dumm/Makefile
965         src/dumm/ext/extconf.rb
966         src/libfast/Makefile
967         src/manager/Makefile
968         src/medsrv/Makefile
969         src/checksum/Makefile
970         scripts/Makefile
971         testing/Makefile
972 )