charon-nm: Fix NM plugin utility macros
[strongswan.git] / configure.in
1 #
2 # Copyright (C) 2007-2013 Tobias Brunner
3 # Copyright (C) 2006-2013 Andreas Steffen
4 # Copyright (C) 2006-2013 Martin Willi
5 # Hochschule fuer Technik Rapperswil
6 #
7 # This program is free software; you can redistribute it and/or modify it
8 # under the terms of the GNU General Public License as published by the
9 # Free Software Foundation; either version 2 of the License, or (at your
10 # option) any later version.  See <http://www.fsf.org/copyleft/gpl.txt>.
11 #
12 # This program is distributed in the hope that it will be useful, but
13 # WITHOUT ANY WARRANTY; without even the implied warranty of MERCHANTABILITY
14 # or FITNESS FOR A PARTICULAR PURPOSE.  See the GNU General Public License
15 # for more details.
16 #
17
18 # ============================
19 #  initialize & set some vars
20 # ============================
21
22 AC_INIT([strongSwan],[5.0.3dr4])
23 AM_INIT_AUTOMAKE(tar-ustar)
24 AC_CONFIG_MACRO_DIR([m4/config])
25 AC_CONFIG_HEADERS([config.h])
26 AC_DEFINE([CONFIG_H_INCLUDED], [], [defined if config.h included])
27 PKG_PROG_PKG_CONFIG
28
29 # =================================
30 #  check --enable-xxx & --with-xxx
31 # =================================
32
33 m4_include(m4/macros/with.m4)
34
35 ARG_WITH_SUBST([random-device],      [/dev/random], [set the device to read real random data from])
36 ARG_WITH_SUBST([urandom-device],     [/dev/urandom], [set the device to read pseudo random data from])
37 ARG_WITH_SUBST([strongswan-conf],    [${sysconfdir}/strongswan.conf], [set the strongswan.conf file location])
38 ARG_WITH_SUBST([resolv-conf],        [${sysconfdir}/resolv.conf], [set the file to use in DNS handler plugin])
39 ARG_WITH_SUBST([piddir],             [/var/run], [set path for PID and UNIX socket files])
40 ARG_WITH_SUBST([ipsecdir],           [${libexecdir%/}/ipsec], [set installation path for ipsec tools])
41 ARG_WITH_SUBST([ipseclibdir],        [${libdir%/}/ipsec], [set installation path for ipsec libraries])
42 ARG_WITH_SUBST([plugindir],          [${ipseclibdir%/}/plugins], [set the installation path of plugins])
43 ARG_WITH_SUBST([imcvdir],            [${ipseclibdir%/}/imcvs], [set the installation path of IMC and IMV dynamic librariers])
44 ARG_WITH_SUBST([nm-ca-dir],          [/usr/share/ca-certificates], [directory the NM backend uses to look up trusted root certificates])
45 ARG_WITH_SUBST([linux-headers],      [\${top_srcdir}/src/include], [set directory of linux header files to use])
46 ARG_WITH_SUBST([routing-table],      [220], [set routing table to use for IPsec routes])
47 ARG_WITH_SUBST([routing-table-prio], [220], [set priority for IPsec routing table])
48 ARG_WITH_SUBST([ipsec-script],       [ipsec], [change the name of the ipsec script])
49
50 ARG_WITH_SET([tss],                  [no], [set implementation of the Trusted Computing Group's Software Stack (TSS). Currently the only supported value is "trousers"])
51 ARG_WITH_SET([capabilities],         [no], [set capability dropping library. Currently supported values are "libcap" and "native"])
52 ARG_WITH_SET([mpz_powm_sec],         [yes], [use the more side-channel resistant mpz_powm_sec in libgmp, if available])
53 ARG_WITH_SET([dev-headers],          [no], [install strongSwan development headers to directory.])
54
55 if test -n "$PKG_CONFIG"; then
56         systemdsystemunitdir_default=$($PKG_CONFIG --variable=systemdsystemunitdir systemd)
57 fi
58 ARG_WITH_SET([systemdsystemunitdir], [$systemdsystemunitdir_default], [directory for systemd service files])
59 AM_CONDITIONAL(HAVE_SYSTEMD, [test -n "$systemdsystemunitdir" -a "x$systemdsystemunitdir" != xno])
60 AC_SUBST(systemdsystemunitdir)
61
62 AC_ARG_WITH(
63         [user],
64         AS_HELP_STRING([--with-user=user],[change user of the daemons to "user" after startup (default is "root").]),
65         [AC_DEFINE_UNQUOTED([IPSEC_USER], "$withval", [username to run daemon with])
66          AC_SUBST(ipsecuser, "$withval")],
67         [AC_SUBST(ipsecuser, "root")]
68 )
69
70 AC_ARG_WITH(
71         [group],
72         AS_HELP_STRING([--with-group=group],[change group of the daemons to "group" after startup (default is "root").]),
73         [AC_DEFINE_UNQUOTED(IPSEC_GROUP, "$withval", [groupname to run daemon with])
74          AC_SUBST(ipsecgroup, "$withval")],
75         [AC_SUBST(ipsecgroup, "root")]
76 )
77
78 AC_ARG_WITH(
79         [charon-udp-port],
80         AS_HELP_STRING([--with-charon-udp-port=port],[UDP port used by charon locally (default 500). Set to 0 to allocate randomly.]),
81         [AC_DEFINE_UNQUOTED(CHARON_UDP_PORT, [$withval], [UDP port used by charon locally])
82          AC_SUBST(charon_udp_port, [$withval])],
83         [AC_SUBST(charon_udp_port, 500)]
84 )
85
86 AC_ARG_WITH(
87         [charon-natt-port],
88         AS_HELP_STRING([--with-charon-natt-port=port],[UDP port used by charon locally in case a NAT is detected (must be different from charon-udp-port, default 4500). Set to 0 to allocate randomly.]),
89         [AC_DEFINE_UNQUOTED(CHARON_NATT_PORT, [$withval], [UDP post used by charon locally in case a NAT is detected])
90          AC_SUBST(charon_natt_port, [$withval])],
91         [AC_SUBST(charon_natt_port, 4500)]
92 )
93
94 AC_MSG_CHECKING([configured UDP ports ($charon_udp_port, $charon_natt_port)])
95 if test x$charon_udp_port != x0 -a x$charon_udp_port = x$charon_natt_port; then
96         AC_MSG_ERROR(the ports have to be different)
97 else
98         AC_MSG_RESULT(ok)
99 fi
100
101 # convert script name to uppercase
102 AC_SUBST(ipsec_script_upper, [`echo -n "$ipsec_script" | tr a-z A-Z`])
103
104 m4_include(m4/macros/enable-disable.m4)
105
106 ARG_ENABL_SET([curl],           [enable CURL fetcher plugin to fetch files via libcurl. Requires libcurl.])
107 ARG_ENABL_SET([unbound],        [enable UNBOUND resolver plugin to perform DNS queries via libunbound. Requires libldns and libunbound.])
108 ARG_ENABL_SET([soup],           [enable soup fetcher plugin to fetch from HTTP via libsoup. Requires libsoup.])
109 ARG_ENABL_SET([ldap],           [enable LDAP fetching plugin to fetch files via libldap. Requires openLDAP.])
110 ARG_DISBL_SET([aes],            [disable AES software implementation plugin.])
111 ARG_DISBL_SET([des],            [disable DES/3DES software implementation plugin.])
112 ARG_ENABL_SET([blowfish],       [enable Blowfish software implementation plugin.])
113 ARG_ENABL_SET([md4],            [enable MD4 software implementation plugin.])
114 ARG_DISBL_SET([md5],            [disable MD5 software implementation plugin.])
115 ARG_DISBL_SET([sha1],           [disable SHA1 software implementation plugin.])
116 ARG_DISBL_SET([sha2],           [disable SHA256/SHA384/SHA512 software implementation plugin.])
117 ARG_DISBL_SET([fips-prf],       [disable FIPS PRF software implementation plugin.])
118 ARG_DISBL_SET([gmp],            [disable GNU MP (libgmp) based crypto implementation plugin.])
119 ARG_ENABL_SET([rdrand],         [enable Intel RDRAND random generator plugin.])
120 ARG_DISBL_SET([random],         [disable RNG implementation on top of /dev/(u)random.])
121 ARG_DISBL_SET([nonce],          [disable nonce generation plugin.])
122 ARG_DISBL_SET([x509],           [disable X509 certificate implementation plugin.])
123 ARG_DISBL_SET([revocation],     [disable X509 CRL/OCSP revocation check plugin.])
124 ARG_DISBL_SET([constraints],    [disable advanced X509 constraint checking plugin.])
125 ARG_DISBL_SET([pubkey],         [disable RAW public key support plugin.])
126 ARG_DISBL_SET([pkcs1],          [disable PKCS1 key decoding plugin.])
127 ARG_DISBL_SET([pkcs7],          [disable PKCS7 container support plugin.])
128 ARG_DISBL_SET([pkcs8],          [disable PKCS8 private key decoding plugin.])
129 ARG_DISBL_SET([pgp],            [disable PGP key decoding plugin.])
130 ARG_DISBL_SET([dnskey],         [disable DNS RR key decoding plugin.])
131 ARG_ENABL_SET([ipseckey],       [enable IPSECKEY authentication plugin.])
132 ARG_DISBL_SET([pem],            [disable PEM decoding plugin.])
133 ARG_DISBL_SET([hmac],           [disable HMAC crypto implementation plugin.])
134 ARG_DISBL_SET([cmac],           [disable CMAC crypto implementation plugin.])
135 ARG_DISBL_SET([xcbc],           [disable xcbc crypto implementation plugin.])
136 ARG_ENABL_SET([af-alg],         [enable AF_ALG crypto interface to Linux Crypto API.])
137 ARG_ENABL_SET([test-vectors],   [enable plugin providing crypto test vectors.])
138 ARG_ENABL_SET([mysql],          [enable MySQL database support. Requires libmysqlclient_r.])
139 ARG_ENABL_SET([sqlite],         [enable SQLite database support. Requires libsqlite3.])
140 ARG_DISBL_SET([stroke],         [disable charons stroke configuration backend.])
141 ARG_ENABL_SET([medsrv],         [enable mediation server web frontend and daemon plugin.])
142 ARG_ENABL_SET([medcli],         [enable mediation client configuration database plugin.])
143 ARG_ENABL_SET([smp],            [enable SMP configuration and control interface. Requires libxml.])
144 ARG_ENABL_SET([sql],            [enable SQL database configuration backend.])
145 ARG_ENABL_SET([leak-detective], [enable malloc hooks to find memory leaks.])
146 ARG_ENABL_SET([lock-profiler],  [enable lock/mutex profiling code.])
147 ARG_ENABL_SET([unit-tester],    [enable unit tests on IKEv2 daemon startup.])
148 ARG_ENABL_SET([load-tester],    [enable load testing plugin for IKEv2 daemon.])
149 ARG_ENABL_SET([eap-sim],        [enable SIM authentication module for EAP.])
150 ARG_ENABL_SET([eap-sim-file],   [enable EAP-SIM backend based on a triplet file.])
151 ARG_ENABL_SET([eap-sim-pcsc],   [enable EAP-SIM backend based on a smartcard reader. Requires libpcsclite.])
152 ARG_ENABL_SET([eap-aka],        [enable EAP AKA authentication module.])
153 ARG_ENABL_SET([eap-aka-3gpp2],  [enable EAP AKA backend implementing 3GPP2 algorithms in software. Requires libgmp.])
154 ARG_ENABL_SET([eap-simaka-sql], [enable EAP-SIM/AKA backend based on a triplet/quintuplet SQL database.])
155 ARG_ENABL_SET([eap-simaka-pseudonym], [enable EAP-SIM/AKA pseudonym storage plugin.])
156 ARG_ENABL_SET([eap-simaka-reauth],    [enable EAP-SIM/AKA reauthentication data storage plugin.])
157 ARG_ENABL_SET([eap-identity],   [enable EAP module providing EAP-Identity helper.])
158 ARG_ENABL_SET([eap-md5],        [enable EAP MD5 (CHAP) authentication module.])
159 ARG_ENABL_SET([eap-gtc],        [enable EAP GTC authentication module.])
160 ARG_ENABL_SET([eap-mschapv2],   [enable EAP MS-CHAPv2 authentication module.])
161 ARG_ENABL_SET([eap-tls],        [enable EAP TLS authentication module.])
162 ARG_ENABL_SET([eap-ttls],       [enable EAP TTLS authentication module.])
163 ARG_ENABL_SET([eap-peap],       [enable EAP PEAP authentication module.])
164 ARG_ENABL_SET([eap-tnc],        [enable EAP TNC trusted network connect module.])
165 ARG_ENABL_SET([eap-dynamic],    [enable dynamic EAP proxy module.])
166 ARG_ENABL_SET([eap-radius],     [enable RADIUS proxy authentication module.])
167 ARG_DISBL_SET([xauth-generic],  [disable generic XAuth backend.])
168 ARG_ENABL_SET([xauth-eap],      [enable XAuth backend using EAP methods to verify passwords.])
169 ARG_ENABL_SET([xauth-pam],      [enable XAuth backend using PAM to verify passwords.])
170 ARG_ENABL_SET([xauth-noauth],   [enable XAuth pseudo-backend that does not actually verify or even request any credentials.])
171 ARG_ENABL_SET([tnc-ifmap],      [enable TNC IF-MAP module.])
172 ARG_ENABL_SET([tnc-pdp],        [enable TNC policy decision point module.])
173 ARG_ENABL_SET([tnc-imc],        [enable TNC IMC module.])
174 ARG_ENABL_SET([tnc-imv],        [enable TNC IMV module.])
175 ARG_ENABL_SET([tnccs-11],       [enable TNCCS 1.1 protocol module.])
176 ARG_ENABL_SET([tnccs-20],       [enable TNCCS 2.0 protocol module.])
177 ARG_ENABL_SET([tnccs-dynamic],  [enable dynamic TNCCS protocol discovery module.])
178 ARG_ENABL_SET([imc-test],       [enable IMC test module.])
179 ARG_ENABL_SET([imv-test],       [enable IMV test module.])
180 ARG_ENABL_SET([imc-scanner],    [enable IMC port scanner module.])
181 ARG_ENABL_SET([imv-scanner],    [enable IMV port scanner module.])
182 ARG_ENABL_SET([imc-os],         [enable IMC operating system module.])
183 ARG_ENABL_SET([imv-os],         [enable IMV operating system module.])
184 ARG_ENABL_SET([imc-attestation],[enable IMC attestation module.])
185 ARG_ENABL_SET([imv-attestation],[enable IMV attestation module.])
186 ARG_DISBL_SET([kernel-netlink], [disable the netlink kernel interface.])
187 ARG_ENABL_SET([kernel-pfkey],   [enable the PF_KEY kernel interface.])
188 ARG_ENABL_SET([kernel-pfroute], [enable the PF_ROUTE kernel interface.])
189 ARG_ENABL_SET([kernel-klips],   [enable the KLIPS kernel interface.])
190 ARG_ENABL_SET([libipsec],       [enable user space IPsec implementation.])
191 ARG_DISBL_SET([socket-default], [disable default socket implementation for charon.])
192 ARG_ENABL_SET([socket-dynamic], [enable dynamic socket implementation for charon])
193 ARG_ENABL_SET([farp],           [enable ARP faking plugin that responds to ARP requests to peers virtual IP])
194 ARG_ENABL_SET([dumm],           [enable the DUMM UML test framework.])
195 ARG_ENABL_SET([fast],           [enable libfast (FastCGI Application Server w/ templates.])
196 ARG_ENABL_SET([manager],        [enable web management console (proof of concept).])
197 ARG_ENABL_SET([mediation],      [enable IKEv2 Mediation Extension.])
198 ARG_ENABL_SET([integrity-test], [enable integrity testing of libstrongswan and plugins.])
199 ARG_DISBL_SET([load-warning],   [disable the charon plugin load option warning in starter.])
200 ARG_DISBL_SET([ikev1],          [disable IKEv1 protocol support in charon.])
201 ARG_DISBL_SET([ikev2],          [disable IKEv2 protocol support in charon.])
202 ARG_DISBL_SET([charon],         [disable the IKEv1/IKEv2 keying daemon charon.])
203 ARG_DISBL_SET([tools],          [disable additional utilities (openac, scepclient and pki).])
204 ARG_DISBL_SET([scripts],        [disable additional utilities (found in directory scripts).])
205 ARG_ENABL_SET([conftest],       [enforce Suite B conformance test framework.])
206 ARG_DISBL_SET([updown],         [disable updown firewall script plugin.])
207 ARG_DISBL_SET([attr],           [disable strongswan.conf based configuration attribute plugin.])
208 ARG_ENABL_SET([attr-sql],       [enable SQL based configuration attribute plugin.])
209 ARG_ENABL_SET([dhcp],           [enable DHCP based attribute provider plugin.])
210 ARG_DISBL_SET([resolve],        [disable resolve DNS handler plugin.])
211 ARG_ENABL_SET([padlock],        [enables VIA Padlock crypto plugin.])
212 ARG_ENABL_SET([openssl],        [enables the OpenSSL crypto plugin.])
213 ARG_ENABL_SET([gcrypt],         [enables the libgcrypt plugin.])
214 ARG_ENABL_SET([agent],          [enables the ssh-agent signing plugin.])
215 ARG_ENABL_SET([pkcs11],         [enables the PKCS11 token support plugin.])
216 ARG_ENABL_SET([ctr],            [enables the Counter Mode wrapper crypto plugin.])
217 ARG_ENABL_SET([ccm],            [enables the CCM AEAD wrapper crypto plugin.])
218 ARG_ENABL_SET([gcm],            [enables the GCM AEAD wrapper crypto plugin.])
219 ARG_ENABL_SET([addrblock],      [enables RFC 3779 address block constraint support.])
220 ARG_ENABL_SET([unity],          [enables Cisco Unity extension plugin.])
221 ARG_ENABL_SET([uci],            [enable OpenWRT UCI configuration plugin.])
222 ARG_ENABL_SET([android-dns],    [enable Android specific DNS handler.])
223 ARG_ENABL_SET([android-log],    [enable Android specific logger plugin.])
224 ARG_ENABL_SET([maemo],          [enable Maemo specific plugin.])
225 ARG_ENABL_SET([nm],             [enable NetworkManager backend.])
226 ARG_ENABL_SET([ha],             [enable high availability cluster plugin.])
227 ARG_ENABL_SET([whitelist],      [enable peer identity whitelisting plugin.])
228 ARG_ENABL_SET([lookip],         [enable fast virtual IP lookup and notification plugin.])
229 ARG_ENABL_SET([error-notify],   [enable error notification plugin.])
230 ARG_ENABL_SET([certexpire],     [enable CSV export of expiration dates of used certificates.])
231 ARG_ENABL_SET([systime-fix],    [enable plugin to handle cert lifetimes with invalid system time gracefully.])
232 ARG_ENABL_SET([led],            [enable plugin to control LEDs on IKEv2 activity using the Linux kernel LED subsystem.])
233 ARG_ENABL_SET([duplicheck],     [advanced duplicate checking plugin using liveness checks.])
234 ARG_ENABL_SET([coupling],       [enable IKEv2 plugin to couple peer certificates permanently to authentication.])
235 ARG_ENABL_SET([radattr],        [enable plugin to inject and process custom RADIUS attributes as IKEv2 client.])
236 ARG_ENABL_SET([vstr],           [enforce using the Vstr string library to replace glibc-like printf hooks.])
237 ARG_ENABL_SET([monolithic],     [build monolithic version of libstrongswan that includes all enabled plugins. Similarly, the plugins of charon are assembled in libcharon.])
238 ARG_ENABL_SET([bfd-backtraces], [use binutils libbfd to resolve backtraces for memory leaks and segfaults.])
239 ARG_ENABL_SET([unit-tests],     [enable unit tests using the check test framework.])
240 ARG_ENABL_SET([tkm],            [enable Trusted Key Manager support.])
241
242 # ===================================
243 #  option to disable default options
244 # ===================================
245
246 ARG_DISBL_SET([defaults],       [disable all default plugins (they can be enabled with their respective --enable options)])
247
248 if test x$defaults = xfalse; then
249         for option in $enabled_by_default; do
250                 eval test x\${${option}_given} = xtrue && continue
251                 let $option=false
252         done
253 fi
254
255 # ===========================
256 #  set up compiler and flags
257 # ===========================
258
259 if test -z "$CFLAGS"; then
260         CFLAGS="-g -O2 -Wall -Wno-format -Wno-pointer-sign"
261 fi
262 AC_PROG_CC
263 AM_PROG_CC_C_O
264
265 AC_LIB_PREFIX
266 AC_C_BIGENDIAN
267
268 # =========================
269 #  check required programs
270 # =========================
271
272 LT_INIT
273 AC_PROG_INSTALL
274 AC_PROG_EGREP
275 AC_PROG_AWK
276 AC_PROG_LEX
277 AC_PROG_YACC
278 AC_PATH_PROG([PERL], [perl], [], [$PATH:/bin:/usr/bin:/usr/local/bin])
279 AC_PATH_PROG([GPERF], [gperf], [], [$PATH:/bin:/usr/bin:/usr/local/bin])
280
281 # because gperf is not needed by end-users we just report it but do not abort on failure
282 AC_MSG_CHECKING([gperf version >= 3.0.0])
283 if test -x "$GPERF"; then
284         if test "`$GPERF --version | $AWK -F' ' '/^GNU gperf/ { print $3 }' | $AWK -F. '{ print $1 }'`" -ge "3"; then
285                 AC_MSG_RESULT([yes])
286         else
287                 AC_MSG_RESULT([no])
288         fi
289 else
290         AC_MSG_RESULT([not found])
291 fi
292
293 # ========================
294 #  dependency calculation
295 # ========================
296
297 if test x$xauth_generic_given = xfalse -a x$ikev1 = xfalse; then
298         xauth_generic=false;
299 fi
300
301 if test x$eap_aka_3gpp2 = xtrue; then
302         gmp=true;
303 fi
304
305 if test x$eap_aka = xtrue; then
306         fips_prf=true;
307         simaka=true;
308 fi
309
310 if test x$eap_sim = xtrue; then
311         fips_prf=true;
312         simaka=true;
313 fi
314
315 if test x$eap_tls = xtrue -o x$eap_ttls = xtrue -o x$eap_peap = xtrue; then
316         tls=true;
317 fi
318
319 if test x$eap_radius = xtrue -o x$radattr = xtrue -o x$tnc_pdp = xtrue; then
320         radius=true;
321 fi
322
323 if test x$tnc_imc = xtrue -o x$tnc_imv = xtrue -o x$tnccs_11 = xtrue -o x$tnccs_11 = xtrue -o x$tnccs_dynamic = xtrue -o x$eap_tnc = xtrue; then
324         tnc_tnccs=true;
325 fi
326
327 if test x$imc_test = xtrue -o x$imv_test = xtrue -o x$imc_scanner = xtrue -o x$imv_scanner = xtrue -o x$imc_os = xtrue -o x$imv_os = xtrue -o x$imc_attestation = xtrue -o x$imv_attestation = xtrue; then
328         imcv=true;
329 fi
330
331 if test x$imc_attestation = xtrue -o x$imv_attestation = xtrue; then
332         pts=true;
333 fi
334
335 if test x$fips_prf = xtrue; then
336         if test x$openssl = xfalse; then
337                 sha1=true;
338         fi
339 fi
340
341 if test x$smp = xtrue -o x$tnccs_11 = xtrue; then
342         xml=true
343 fi
344
345 if test x$tnc_ifmap = xtrue; then
346         axis2c=true
347 fi
348
349 if test x$manager = xtrue; then
350         fast=true
351 fi
352
353 if test x$medsrv = xtrue; then
354         mediation=true
355         fast=true
356 fi
357
358 if test x$medcli = xtrue; then
359         mediation=true
360 fi
361
362 # ===========================================
363 #  check required libraries and header files
364 # ===========================================
365
366 AC_HEADER_STDBOOL
367 AC_FUNC_ALLOCA
368 AC_FUNC_STRERROR_R
369
370 #  libraries needed on some platforms but not on others
371 # ------------------------------------------------------
372 saved_LIBS=$LIBS
373
374 # FreeBSD and Mac OS X have dlopen integrated in libc, Linux needs libdl
375 LIBS=""
376 AC_SEARCH_LIBS(dlopen, dl, [DLLIB=$LIBS])
377 AC_SUBST(DLLIB)
378
379 # glibc's backtrace() can be replicated on FreeBSD with libexecinfo
380 LIBS=""
381 AC_SEARCH_LIBS(backtrace, execinfo, [BTLIB=$LIBS])
382 AC_CHECK_FUNCS(backtrace)
383 AC_SUBST(BTLIB)
384
385 # OpenSolaris needs libsocket and libnsl for socket()
386 LIBS=""
387 AC_SEARCH_LIBS(socket, socket, [SOCKLIB=$LIBS],
388         [AC_CHECK_LIB(nsl, socket, [SOCKLIB="-lsocket -lnsl"], [], [-lsocket])]
389 )
390 AC_SUBST(SOCKLIB)
391
392 # FreeBSD has clock_gettime in libc, Linux needs librt
393 LIBS=""
394 AC_SEARCH_LIBS(clock_gettime, rt, [RTLIB=$LIBS])
395 AC_CHECK_FUNCS(clock_gettime)
396 AC_SUBST(RTLIB)
397
398 # Android has pthread_* functions in bionic (libc), others need libpthread
399 LIBS=""
400 AC_SEARCH_LIBS(pthread_create, pthread, [PTHREADLIB=$LIBS])
401 AC_SUBST(PTHREADLIB)
402
403 LIBS=$saved_LIBS
404 # ------------------------------------------------------
405
406 AC_MSG_CHECKING(for dladdr)
407 AC_COMPILE_IFELSE(
408         [AC_LANG_PROGRAM(
409                 [[#define _GNU_SOURCE
410                   #include <dlfcn.h>]],
411                 [[Dl_info* info = 0;
412                   dladdr(0, info);]])],
413         [AC_MSG_RESULT([yes]); AC_DEFINE([HAVE_DLADDR], [], [have dladdr()])],
414         [AC_MSG_RESULT([no])]
415 )
416
417 # check if pthread_condattr_setclock(CLOCK_MONOTONE) is supported
418 saved_LIBS=$LIBS
419 LIBS=$PTHREADLIB
420 AC_MSG_CHECKING([for pthread_condattr_setclock(CLOCK_MONOTONE)])
421 AC_RUN_IFELSE(
422         [AC_LANG_SOURCE(
423                 [[#include <pthread.h>
424                   int main() { pthread_condattr_t attr;
425                         pthread_condattr_init(&attr);
426                         return pthread_condattr_setclock(&attr, CLOCK_MONOTONIC);}]])],
427         [AC_MSG_RESULT([yes]);
428          AC_DEFINE([HAVE_CONDATTR_CLOCK_MONOTONIC], [],
429                            [pthread_condattr_setclock supports CLOCK_MONOTONIC])],
430         [AC_MSG_RESULT([no])],
431         # Check existence of pthread_condattr_setclock if cross-compiling
432         [AC_MSG_RESULT([unknown]);
433          AC_CHECK_FUNCS(pthread_condattr_setclock,
434                 [AC_DEFINE([HAVE_CONDATTR_CLOCK_MONOTONIC], [],
435                                    [have pthread_condattr_setclock()])]
436         )]
437 )
438 # check if we actually are able to configure attributes on cond vars
439 AC_CHECK_FUNCS(pthread_condattr_init)
440 # instead of pthread_condattr_setclock Android has this function
441 AC_CHECK_FUNCS(pthread_cond_timedwait_monotonic)
442 # check if we can cancel threads
443 AC_CHECK_FUNCS(pthread_cancel)
444 # check if native rwlocks are available
445 AC_CHECK_FUNCS(pthread_rwlock_init)
446 # check if pthread spinlocks are available
447 AC_CHECK_FUNCS(pthread_spin_init)
448 # check if we have POSIX semaphore functions, including timed-wait
449 AC_CHECK_FUNCS(sem_timedwait)
450 LIBS=$saved_LIBS
451
452 AC_CHECK_FUNC(
453         [gettid],
454         [AC_DEFINE([HAVE_GETTID], [], [have gettid()])],
455         [AC_MSG_CHECKING([for SYS_gettid])
456          AC_COMPILE_IFELSE(
457                 [AC_LANG_PROGRAM(
458                         [[#define _GNU_SOURCE
459                           #include <unistd.h>
460                           #include <sys/syscall.h>]],
461                         [[int main() {
462                           return syscall(SYS_gettid);}]])],
463                 [AC_MSG_RESULT([yes]);
464                  AC_DEFINE([HAVE_GETTID], [], [have gettid()])
465                  AC_DEFINE([HAVE_SYS_GETTID], [], [have syscall(SYS_gettid)])],
466                 [AC_MSG_RESULT([no])]
467         )]
468 )
469
470 AC_CHECK_FUNCS(prctl mallinfo getpass closefrom getpwnam_r getgrnam_r getpwuid_r)
471
472 AC_CHECK_HEADERS(sys/sockio.h glob.h)
473 AC_CHECK_HEADERS(net/pfkeyv2.h netipsec/ipsec.h netinet6/ipsec.h linux/udp.h)
474 AC_CHECK_HEADERS(netinet/ip6.h)
475
476 AC_CHECK_MEMBERS([struct sockaddr.sa_len], [], [],
477 [
478         #include <sys/types.h>
479         #include <sys/socket.h>
480 ])
481
482 AC_CHECK_MEMBERS([struct sadb_x_policy.sadb_x_policy_priority], [], [],
483 [
484         #include <sys/types.h>
485         #ifdef HAVE_NET_PFKEYV2_H
486         #include <net/pfkeyv2.h>
487         #else
488         #include <stdint.h>
489         #include <linux/pfkeyv2.h>
490         #endif
491 ])
492
493 AC_MSG_CHECKING([for in6addr_any])
494 AC_COMPILE_IFELSE(
495         [AC_LANG_PROGRAM(
496                 [[#include <sys/types.h>
497                   #include <sys/socket.h>
498                   #include <netinet/in.h>]],
499                 [[struct in6_addr in6;
500                   in6 = in6addr_any;]])],
501         [AC_MSG_RESULT([yes]);
502          AC_DEFINE([HAVE_IN6ADDR_ANY], [], [have struct in6_addr in6addr_any])],
503         [AC_MSG_RESULT([no])]
504 )
505
506 AC_MSG_CHECKING([for in6_pktinfo])
507 AC_COMPILE_IFELSE(
508         [AC_LANG_PROGRAM(
509                 [[#define _GNU_SOURCE
510                   #include <sys/types.h>
511                   #include <sys/socket.h>
512                   #include <netinet/in.h>]],
513                 [[struct in6_pktinfo pi;
514                   if (pi.ipi6_ifindex)
515                   {
516                     return 0;
517                   }]])],
518         [AC_MSG_RESULT([yes]);
519          AC_DEFINE([HAVE_IN6_PKTINFO], [], [have struct in6_pktinfo.ipi6_ifindex])],
520         [AC_MSG_RESULT([no])]
521 )
522
523 AC_MSG_CHECKING([for IPSEC_MODE_BEET])
524 AC_COMPILE_IFELSE(
525         [AC_LANG_PROGRAM(
526                 [[#include <sys/types.h>
527                   #ifdef HAVE_NETIPSEC_IPSEC_H
528                   #include <netipsec/ipsec.h>
529                   #elif defined(HAVE_NETINET6_IPSEC_H)
530                   #include <netinet6/ipsec.h>
531                   #else
532                   #include <stdint.h>
533                   #include <linux/ipsec.h>
534                   #endif]],
535                 [[int mode = IPSEC_MODE_BEET;
536                   return mode;]])],
537         [AC_MSG_RESULT([yes]);
538          AC_DEFINE([HAVE_IPSEC_MODE_BEET], [], [have IPSEC_MODE_BEET defined])],
539         [AC_MSG_RESULT([no])]
540 )
541
542 AC_MSG_CHECKING([for IPSEC_DIR_FWD])
543 AC_COMPILE_IFELSE(
544         [AC_LANG_PROGRAM(
545                 [[#include <sys/types.h>
546                   #ifdef HAVE_NETIPSEC_IPSEC_H
547                   #include <netipsec/ipsec.h>
548                   #elif defined(HAVE_NETINET6_IPSEC_H)
549                   #include <netinet6/ipsec.h>
550                   #else
551                   #include <stdint.h>
552                   #include <linux/ipsec.h>
553                   #endif]],
554                 [[int dir = IPSEC_DIR_FWD;
555                   return dir;]])],
556         [AC_MSG_RESULT([yes]);
557          AC_DEFINE([HAVE_IPSEC_DIR_FWD], [], [have IPSEC_DIR_FWD defined])],
558         [AC_MSG_RESULT([no])]
559 )
560
561 AC_MSG_CHECKING([for RTA_TABLE])
562 AC_COMPILE_IFELSE(
563         [AC_LANG_PROGRAM(
564                 [[#include <sys/socket.h>
565                   #include <linux/netlink.h>
566                   #include <linux/rtnetlink.h>]],
567                 [[int rta_type = RTA_TABLE;
568                   return rta_type;]])],
569         [AC_MSG_RESULT([yes]);
570          AC_DEFINE([HAVE_RTA_TABLE], [], [have netlink RTA_TABLE defined])],
571         [AC_MSG_RESULT([no])]
572 )
573
574 AC_MSG_CHECKING([for gcc atomic operations])
575 AC_RUN_IFELSE([AC_LANG_SOURCE(
576         [[
577                         int main() {
578                         volatile int ref = 1;
579                         __sync_fetch_and_add (&ref, 1);
580                         __sync_sub_and_fetch (&ref, 1);
581                         /* Make sure test fails if operations are not supported */
582                         __sync_val_compare_and_swap(&ref, 1, 0);
583                         return ref;
584                 }
585         ]])],
586         [AC_MSG_RESULT([yes]);
587          AC_DEFINE([HAVE_GCC_ATOMIC_OPERATIONS], [],
588                    [have GCC __sync_* atomic operations])],
589         [AC_MSG_RESULT([no])],
590         [AC_MSG_RESULT([no])]
591 )
592
593 # check for the new register_printf_specifier function with len argument,
594 # or the deprecated register_printf_function without
595 AC_CHECK_FUNC(
596         [register_printf_specifier],
597         [AC_DEFINE([HAVE_PRINTF_SPECIFIER], [], [have register_printf_specifier()])],
598         [AC_CHECK_FUNC(
599                 [register_printf_function],
600                 [AC_DEFINE([HAVE_PRINTF_FUNCTION], [], [have register_printf_function()])],
601                 [
602                         AC_MSG_NOTICE([printf does not support custom format specifiers!])
603                         vstr=true
604                 ]
605         )]
606 )
607
608 if test x$vstr = xtrue; then
609         AC_CHECK_LIB([vstr],[main],[LIBS="$LIBS"],[AC_MSG_ERROR([Vstr string library not found])],[])
610         AC_DEFINE([USE_VSTR], [], [use vstring library for printf hooks])
611 fi
612
613 if test x$gmp = xtrue; then
614         saved_LIBS=$LIBS
615         AC_CHECK_LIB([gmp],[main],[],[AC_MSG_ERROR([GNU Multi Precision library gmp not found])],[])
616         AC_MSG_CHECKING([mpz_powm_sec])
617         if test x$mpz_powm_sec = xyes; then
618                 AC_COMPILE_IFELSE(
619                         [AC_LANG_PROGRAM(
620                                 [[#include "gmp.h"]],
621                                 [[void *x = mpz_powm_sec;]])],
622                         [AC_MSG_RESULT([yes]);
623                          AC_DEFINE([HAVE_MPZ_POWM_SEC], [], [have mpz_mown_sec()])],
624                         [AC_MSG_RESULT([no])]
625                 )
626         else
627                 AC_MSG_RESULT([disabled])
628         fi
629         LIBS=$saved_LIBS
630         AC_MSG_CHECKING([gmp.h version >= 4.1.4])
631         AC_COMPILE_IFELSE(
632                 [AC_LANG_PROGRAM(
633                         [[#include "gmp.h"]],
634                         [[
635                                 #if (__GNU_MP_VERSION*100 +  __GNU_MP_VERSION_MINOR*10 + __GNU_MP_VERSION_PATCHLEVEL) < 414
636                                         #error bad gmp
637                                 #endif]])],
638                 [AC_MSG_RESULT([yes])],
639                 [AC_MSG_RESULT([no]); AC_MSG_ERROR([No usable gmp.h found!])]
640         )
641 fi
642
643 if test x$ldap = xtrue; then
644         AC_CHECK_LIB([ldap],[main],[LIBS="$LIBS"],[AC_MSG_ERROR([LDAP library ldap not found])],[])
645         AC_CHECK_LIB([lber],[main],[LIBS="$LIBS"],[AC_MSG_ERROR([LDAP library lber not found])],[])
646         AC_CHECK_HEADER([ldap.h],,[AC_MSG_ERROR([LDAP header ldap.h not found!])])
647 fi
648
649 if test x$curl = xtrue; then
650         AC_CHECK_LIB([curl],[main],[LIBS="$LIBS"],[AC_MSG_ERROR([CURL library curl not found])],[])
651         AC_CHECK_HEADER([curl/curl.h],,[AC_MSG_ERROR([CURL header curl/curl.h not found!])])
652 fi
653
654 if test x$unbound = xtrue; then
655         AC_HAVE_LIBRARY([ldns],[LIBS="$LIBS"],[AC_MSG_ERROR([UNBOUND library ldns not found])])
656         AC_CHECK_HEADER([ldns/ldns.h],,[AC_MSG_ERROR([UNBOUND header ldns/ldns.h not found!])])
657         AC_HAVE_LIBRARY([unbound],[LIBS="$LIBS"],[AC_MSG_ERROR([UNBOUND library libunbound not found])])
658         AC_CHECK_HEADER([unbound.h],,[AC_MSG_ERROR([UNBOUND header unbound.h not found!])])
659 fi
660
661 if test x$soup = xtrue; then
662         PKG_CHECK_MODULES(soup, [libsoup-2.4])
663         AC_SUBST(soup_CFLAGS)
664         AC_SUBST(soup_LIBS)
665 fi
666
667 if test x$xml = xtrue; then
668         PKG_CHECK_MODULES(xml, [libxml-2.0])
669         AC_SUBST(xml_CFLAGS)
670         AC_SUBST(xml_LIBS)
671 fi
672
673 if test x$axis2c = xtrue; then
674         PKG_CHECK_MODULES(axis2c, [axis2c])
675         AC_SUBST(axis2c_CFLAGS)
676         AC_SUBST(axis2c_LIBS)
677 fi
678
679 if test x$tss = xtrousers; then
680         AC_CHECK_LIB([tspi],[main],[LIBS="$LIBS"],[AC_MSG_ERROR([TrouSerS library libtspi not found])],[])
681         AC_CHECK_HEADER([trousers/tss.h],,[AC_MSG_ERROR([TrouSerS header trousers/tss.h not found!])])
682         AC_DEFINE([TSS_TROUSERS], [], [use TrouSerS library libtspi as TSS implementation])
683 fi
684
685 if test x$dumm = xtrue; then
686         PKG_CHECK_MODULES(gtk, [gtk+-2.0 vte])
687         AC_SUBST(gtk_CFLAGS)
688         AC_SUBST(gtk_LIBS)
689         AC_CHECK_PROGS(RUBY, ruby)
690         AC_MSG_CHECKING([for Ruby header files])
691         if test -n "$RUBY"; then
692                 RUBYINCLUDE=
693                 RUBYDIR=`($RUBY -r rbconfig -e 'print RbConfig::CONFIG[["rubyhdrdir"]] || ""') 2>/dev/null`
694                 if test -n "$RUBYDIR" -a -r "$RUBYDIR/ruby.h"; then
695                         RUBYARCH=`($RUBY -r rbconfig -e 'print RbConfig::CONFIG[["arch"]] || ""') 2>/dev/null`
696                         if test -n "$RUBYARCH"; then
697                                 AC_MSG_RESULT([$RUBYDIR])
698                                 RUBYINCLUDE="-I$RUBYDIR -I$RUBYDIR/$RUBYARCH"
699                         fi
700                 else
701                         RUBYDIR=`($RUBY -r rbconfig -e 'print RbConfig::CONFIG[["archdir"]] || ""') 2>/dev/null`
702                         if test -n "$RUBYDIR" -a -r "$RUBYDIR/ruby.h"; then
703                                 AC_MSG_RESULT([$RUBYDIR])
704                                 RUBYINCLUDE="-I$RUBYDIR"
705                         fi
706                 fi
707                 if test -z "$RUBYINCLUDE"; then
708                         AC_MSG_ERROR([ruby.h not found])
709                 fi
710                 AC_SUBST(RUBYINCLUDE)
711         else
712                 AC_MSG_ERROR([don't know how to run ruby])
713         fi
714         AC_MSG_CHECKING([for libruby])
715         saved_LIBS=$LIBS
716         LIBS=`($RUBY -r rbconfig -e 'print RbConfig::CONFIG[["LIBRUBYARG_SHARED"]] || ""') 2>/dev/null`
717         AC_TRY_LINK_FUNC(ruby_init,
718                 [AC_MSG_RESULT([$LIBS]); RUBYLIB=$LIBS],
719                 [AC_MSG_ERROR([not found])])
720         AC_SUBST(RUBYLIB)
721         AC_CHECK_FUNCS(rb_errinfo)
722         LIBS=$saved_LIBS
723 fi
724
725 if test x$fast = xtrue; then
726         AC_CHECK_LIB([neo_cgi],[main],[LIBS="$LIBS"],[AC_MSG_ERROR([ClearSilver library neo_cgi not found!])],[])
727         AC_CHECK_LIB([neo_utl],[main],[LIBS="$LIBS"],[AC_MSG_ERROR([ClearSilver library neo_utl not found!])],[])
728         AC_MSG_CHECKING([ClearSilver requires zlib])
729         saved_CFLAGS=$CFLAGS
730         saved_LIBS=$LIBS
731         LIBS="-lneo_cgi -lneo_cs -lneo_utl"
732         CFLAGS="-I/usr/include/ClearSilver"
733         AC_LINK_IFELSE(
734                 [AC_LANG_PROGRAM(
735                         [[#include <ClearSilver.h>]],
736                         [[NEOERR *err = cgi_display(NULL, NULL);]])],
737                 [AC_MSG_RESULT([no]); clearsilver_LIBS="$LIBS"],
738                 [AC_MSG_RESULT([yes]); clearsilver_LIBS="$LIBS -lz"]
739         )
740         AC_SUBST(clearsilver_LIBS)
741         LIBS=$saved_LIBS
742         CFLAGS=$saved_CFLAGS
743 # autoconf does not like CamelCase!? How to fix this?
744 #       AC_CHECK_HEADER([ClearSilver/ClearSilver.h],,[AC_MSG_ERROR([ClearSilver header file ClearSilver/ClearSilver.h not found!])])
745
746         AC_CHECK_LIB([fcgi],[main],[LIBS="$LIBS"],[AC_MSG_ERROR([FastCGI library fcgi not found!])],[])
747         AC_CHECK_HEADER([fcgiapp.h],,[AC_MSG_ERROR([FastCGI header file fcgiapp.h not found!])])
748 fi
749
750 if test x$mysql = xtrue; then
751         AC_PATH_PROG([MYSQLCONFIG], [mysql_config], [], [$PATH:/bin:/usr/bin:/usr/local/bin])
752         if test x$MYSQLCONFIG = x; then
753                 AC_MSG_ERROR([mysql_config not found!])
754         fi
755         AC_SUBST(MYSQLLIB, `$MYSQLCONFIG --libs_r`)
756         AC_SUBST(MYSQLCFLAG, `$MYSQLCONFIG --cflags`)
757 fi
758
759 if test x$sqlite = xtrue; then
760         AC_CHECK_LIB([sqlite3],[main],[LIBS="$LIBS"],[AC_MSG_ERROR([SQLite library sqlite3 not found])],[])
761         AC_CHECK_HEADER([sqlite3.h],,[AC_MSG_ERROR([SQLite header sqlite3.h not found!])])
762         AC_MSG_CHECKING([sqlite3_prepare_v2])
763         AC_COMPILE_IFELSE(
764                 [AC_LANG_PROGRAM(
765                         [[#include <sqlite3.h>]],
766                         [[void *test = sqlite3_prepare_v2;]])],
767                 [AC_MSG_RESULT([yes]);
768                  AC_DEFINE([HAVE_SQLITE3_PREPARE_V2], [], [have sqlite3_prepare_v2()])],
769                 [AC_MSG_RESULT([no])]
770         )
771         AC_MSG_CHECKING([sqlite3.h version >= 3.3.1])
772         AC_COMPILE_IFELSE(
773                 [AC_LANG_PROGRAM(
774                         [[#include <sqlite3.h>]],
775                         [[
776                                 #if SQLITE_VERSION_NUMBER < 3003001
777                                         #error bad sqlite
778                                 #endif]])],
779                 [AC_MSG_RESULT([yes])],
780                 [AC_MSG_RESULT([no]); AC_MSG_ERROR([SQLite version >= 3.3.1 required!])]
781         )
782 fi
783
784 if test x$openssl = xtrue; then
785         AC_CHECK_LIB([crypto],[main],[LIBS="$LIBS"],[AC_MSG_ERROR([OpenSSL crypto library not found])],[])
786         AC_CHECK_HEADER([openssl/evp.h],,[AC_MSG_ERROR([OpenSSL header openssl/evp.h not found!])])
787 fi
788
789 if test x$gcrypt = xtrue; then
790         AC_CHECK_LIB([gcrypt],[main],[LIBS="$LIBS"],[AC_MSG_ERROR([gcrypt library not found])],[-lgpg-error])
791         AC_CHECK_HEADER([gcrypt.h],,[AC_MSG_ERROR([gcrypt header gcrypt.h not found!])])
792         AC_MSG_CHECKING([gcrypt CAMELLIA cipher])
793         AC_COMPILE_IFELSE(
794                 [AC_LANG_PROGRAM(
795                         [[#include <gcrypt.h>]],
796                         [[enum gcry_cipher_algos alg = GCRY_CIPHER_CAMELLIA128;]])],
797                 [AC_MSG_RESULT([yes]);
798                  AC_DEFINE([HAVE_GCRY_CIPHER_CAMELLIA], [], [have GCRY_CIPHER_CAMELLIA128])],
799                 [AC_MSG_RESULT([no])]
800         )
801 fi
802
803 if test x$uci = xtrue; then
804         AC_CHECK_LIB([uci],[main],[LIBS="$LIBS"],[AC_MSG_ERROR([UCI library libuci not found])],[])
805         AC_CHECK_HEADER([uci.h],,[AC_MSG_ERROR([UCI header uci.h not found!])])
806 fi
807
808 if test x$android_dns = xtrue; then
809         AC_CHECK_LIB([cutils],[main],[LIBS="$LIBS"],[AC_MSG_ERROR([Android library libcutils not found])],[])
810         AC_CHECK_HEADER([cutils/properties.h],,[AC_MSG_ERROR([Android header cutils/properties.h not found!])])
811         # we have to force the use of libdl here because the autodetection
812         # above does not work correctly when cross-compiling for android.
813         DLLIB="-ldl"
814         AC_SUBST(DLLIB)
815 fi
816
817 if test x$maemo = xtrue; then
818         PKG_CHECK_MODULES(maemo, [glib-2.0 gthread-2.0 libosso osso-af-settings])
819         AC_SUBST(maemo_CFLAGS)
820         AC_SUBST(maemo_LIBS)
821         dbusservicedir="/usr/share/dbus-1/system-services"
822         AC_SUBST(dbusservicedir)
823 fi
824
825 if test x$eap_sim_pcsc = xtrue; then
826         PKG_CHECK_MODULES(pcsclite, [libpcsclite])
827         AC_SUBST(pcsclite_CFLAGS)
828         AC_SUBST(pcsclite_LIBS)
829 fi
830
831 if test x$nm = xtrue; then
832         PKG_CHECK_EXISTS([libnm-glib],
833                 [PKG_CHECK_MODULES(nm, [NetworkManager gthread-2.0 libnm-util libnm-glib libnm-glib-vpn])],
834                 [PKG_CHECK_MODULES(nm, [NetworkManager gthread-2.0 libnm_util libnm_glib libnm_glib_vpn])]
835         )
836         AC_SUBST(nm_CFLAGS)
837         AC_SUBST(nm_LIBS)
838 fi
839
840 if test x$xauth_pam = xtrue; then
841         AC_CHECK_LIB([pam],[main],[LIBS="$LIBS"],[AC_MSG_ERROR([PAM library not found])],[])
842         AC_CHECK_HEADER([security/pam_appl.h],,[AC_MSG_ERROR([PAM header security/pam_appl.h not found!])])
843 fi
844
845 if test x$capabilities = xnative; then
846         AC_MSG_NOTICE([Usage of the native Linux capabilities interface is deprecated, use libcap instead])
847         # Linux requires the following for capset(), Android does not have it,
848         # but defines capset() in unistd.h instead.
849         AC_CHECK_HEADERS([sys/capability.h])
850         AC_CHECK_FUNC(capset,,[AC_MSG_ERROR([capset() not found!])])
851         AC_DEFINE([CAPABILITIES_NATIVE], [], [have native linux capset()])
852 fi
853
854 if test x$capabilities = xlibcap; then
855         AC_CHECK_LIB([cap],[main],[LIBS="$LIBS"],[AC_MSG_ERROR([libcap library not found])],[])
856         AC_CHECK_HEADER([sys/capability.h],
857                 [AC_DEFINE([HAVE_SYS_CAPABILITY_H], [], [have sys/capability.h])],
858                 [AC_MSG_ERROR([libcap header sys/capability.h not found!])])
859         AC_DEFINE([CAPABILITIES_LIBCAP], [], [have libpcap library])
860 fi
861
862 if test x$integrity_test = xtrue; then
863         AC_MSG_CHECKING([for dladdr()])
864         AC_COMPILE_IFELSE(
865                 [AC_LANG_PROGRAM(
866                         [[#define _GNU_SOURCE
867                           #include <dlfcn.h>]],
868                         [[Dl_info info; dladdr(main, &info);]])],
869                 [AC_MSG_RESULT([yes])],
870                 [AC_MSG_RESULT([no]);
871                  AC_MSG_ERROR([dladdr() not supported, required by integrity-test!])]
872         )
873         AC_MSG_CHECKING([for dl_iterate_phdr()])
874         AC_COMPILE_IFELSE(
875                 [AC_LANG_PROGRAM(
876                         [[#define _GNU_SOURCE
877                           #include <link.h>]],
878                         [[dl_iterate_phdr((void*)0, (void*)0);]])],
879                 [AC_MSG_RESULT([yes])],
880                 [AC_MSG_RESULT([no]);
881                  AC_MSG_ERROR([dl_iterate_phdr() not supported, required by integrity-test!])]
882         )
883 fi
884
885 if test x$bfd_backtraces = xtrue; then
886         AC_CHECK_LIB([bfd],[main],[LIBS="$LIBS"],[AC_MSG_ERROR([binutils libbfd not found!])],[])
887         AC_CHECK_HEADER([bfd.h],[AC_DEFINE([HAVE_BFD_H],,[have binutils bfd.h])],
888                 [AC_MSG_ERROR([binutils bfd.h header not found!])])
889         BFDLIB="-lbfd"
890         AC_SUBST(BFDLIB)
891 fi
892
893 AM_CONDITIONAL(USE_DEV_HEADERS, [test "x$dev_headers" != xno])
894 if test x$dev_headers = xyes; then
895         dev_headers="$includedir/strongswan"
896 fi
897 AC_SUBST(dev_headers)
898
899 CFLAGS="$CFLAGS -include `pwd`/config.h"
900
901 if test x$tkm = xtrue; then
902         AC_PATH_PROG([GPRBUILD], [gprbuild], [], [$PATH:/bin:/usr/bin:/usr/local/bin])
903 fi
904
905 if test x$unit_tests = xtrue; then
906         PKG_CHECK_MODULES(CHECK, [check >= 0.9.4])
907         AC_SUBST(CHECK_CFLAGS)
908         AC_SUBST(CHECK_LIBS)
909 fi
910
911 # ===============================================
912 #  collect plugin list for strongSwan components
913 # ===============================================
914
915 m4_include(m4/macros/add-plugin.m4)
916
917 # plugin lists for all components
918 charon_plugins=
919 starter_plugins=
920 pool_plugins=
921 attest_plugins=
922 openac_plugins=
923 scepclient_plugins=
924 pki_plugins=
925 scripts_plugins=
926 manager_plugins=
927 medsrv_plugins=
928 nm_plugins=
929
930 # location specific lists for checksumming,
931 # for src/libcharon, src/libhydra and src/libstrongswan
932 c_plugins=
933 h_plugins=
934 s_plugins=
935
936 ADD_PLUGIN([test-vectors],         [s charon openac scepclient pki])
937 ADD_PLUGIN([curl],                 [s charon scepclient scripts nm])
938 ADD_PLUGIN([soup],                 [s charon scripts nm])
939 ADD_PLUGIN([unbound],              [s charon scripts])
940 ADD_PLUGIN([ldap],                 [s charon scepclient scripts nm])
941 ADD_PLUGIN([mysql],                [s charon pool manager medsrv attest])
942 ADD_PLUGIN([sqlite],               [s charon pool manager medsrv attest])
943 ADD_PLUGIN([pkcs11],               [s charon pki nm])
944 ADD_PLUGIN([aes],                  [s charon openac scepclient pki scripts nm])
945 ADD_PLUGIN([des],                  [s charon openac scepclient pki scripts nm])
946 ADD_PLUGIN([blowfish],             [s charon openac scepclient pki scripts nm])
947 ADD_PLUGIN([sha1],                 [s charon openac scepclient pki scripts medsrv attest nm])
948 ADD_PLUGIN([sha2],                 [s charon openac scepclient pki scripts medsrv attest nm])
949 ADD_PLUGIN([md4],                  [s charon openac manager scepclient pki nm])
950 ADD_PLUGIN([md5],                  [s charon openac scepclient pki scripts attest nm])
951 ADD_PLUGIN([rdrand],               [s charon openac scepclient pki scripts medsrv attest nm])
952 ADD_PLUGIN([random],               [s charon openac scepclient pki scripts medsrv attest nm])
953 ADD_PLUGIN([nonce],                [s charon nm])
954 ADD_PLUGIN([x509],                 [s charon openac scepclient pki scripts attest nm])
955 ADD_PLUGIN([revocation],           [s charon nm])
956 ADD_PLUGIN([constraints],          [s charon nm])
957 ADD_PLUGIN([pubkey],               [s charon])
958 ADD_PLUGIN([pkcs1],                [s charon openac scepclient pki scripts manager medsrv attest nm])
959 ADD_PLUGIN([pkcs7],                [s scepclient pki])
960 ADD_PLUGIN([pkcs8],                [s charon openac scepclient pki scripts manager medsrv attest nm])
961 ADD_PLUGIN([pgp],                  [s charon])
962 ADD_PLUGIN([dnskey],               [s charon])
963 ADD_PLUGIN([ipseckey],             [c charon])
964 ADD_PLUGIN([pem],                  [s charon openac scepclient pki scripts manager medsrv attest nm])
965 ADD_PLUGIN([padlock],              [s charon])
966 ADD_PLUGIN([openssl],              [s charon openac scepclient pki scripts manager medsrv attest nm])
967 ADD_PLUGIN([gcrypt],               [s charon openac scepclient pki scripts manager medsrv attest nm])
968 ADD_PLUGIN([af-alg],               [s charon openac scepclient pki scripts medsrv attest nm])
969 ADD_PLUGIN([fips-prf],             [s charon nm])
970 ADD_PLUGIN([gmp],                  [s charon openac scepclient pki scripts manager medsrv attest nm])
971 ADD_PLUGIN([agent],                [s charon nm])
972 ADD_PLUGIN([xcbc],                 [s charon nm])
973 ADD_PLUGIN([cmac],                 [s charon nm])
974 ADD_PLUGIN([hmac],                 [s charon scripts nm])
975 ADD_PLUGIN([ctr],                  [s charon scripts nm])
976 ADD_PLUGIN([ccm],                  [s charon scripts nm])
977 ADD_PLUGIN([gcm],                  [s charon scripts nm])
978 ADD_PLUGIN([attr],                 [h charon])
979 ADD_PLUGIN([attr-sql],             [h charon])
980 ADD_PLUGIN([load-tester],          [c charon])
981 ADD_PLUGIN([kernel-pfkey],         [h charon starter nm])
982 ADD_PLUGIN([kernel-pfroute],       [h charon starter nm])
983 ADD_PLUGIN([kernel-klips],         [h charon starter])
984 ADD_PLUGIN([kernel-netlink],       [h charon starter nm])
985 ADD_PLUGIN([resolve],              [h charon])
986 ADD_PLUGIN([socket-default],       [c charon nm])
987 ADD_PLUGIN([socket-dynamic],       [c charon])
988 ADD_PLUGIN([farp],                 [c charon])
989 ADD_PLUGIN([stroke],               [c charon])
990 ADD_PLUGIN([smp],                  [c charon])
991 ADD_PLUGIN([sql],                  [c charon])
992 ADD_PLUGIN([updown],               [c charon])
993 ADD_PLUGIN([eap-identity],         [c charon nm])
994 ADD_PLUGIN([eap-sim],              [c charon])
995 ADD_PLUGIN([eap-sim-file],         [c charon])
996 ADD_PLUGIN([eap-sim-pcsc],         [c charon])
997 ADD_PLUGIN([eap-aka],              [c charon])
998 ADD_PLUGIN([eap-aka-3gpp2],        [c charon])
999 ADD_PLUGIN([eap-simaka-sql],       [c charon])
1000 ADD_PLUGIN([eap-simaka-pseudonym], [c charon])
1001 ADD_PLUGIN([eap-simaka-reauth],    [c charon])
1002 ADD_PLUGIN([eap-md5],              [c charon nm])
1003 ADD_PLUGIN([eap-gtc],              [c charon nm])
1004 ADD_PLUGIN([eap-mschapv2],         [c charon nm])
1005 ADD_PLUGIN([eap-dynamic],          [c charon])
1006 ADD_PLUGIN([eap-radius],           [c charon])
1007 ADD_PLUGIN([eap-tls],              [c charon nm])
1008 ADD_PLUGIN([eap-ttls],             [c charon nm])
1009 ADD_PLUGIN([eap-peap],             [c charon nm])
1010 ADD_PLUGIN([eap-tnc],              [c charon])
1011 ADD_PLUGIN([xauth-generic],        [c charon])
1012 ADD_PLUGIN([xauth-eap],            [c charon])
1013 ADD_PLUGIN([xauth-pam],            [c charon])
1014 ADD_PLUGIN([xauth-noauth],         [c charon])
1015 ADD_PLUGIN([tnc-ifmap],            [c charon])
1016 ADD_PLUGIN([tnc-pdp],              [c charon])
1017 ADD_PLUGIN([tnc-imc],              [c charon])
1018 ADD_PLUGIN([tnc-imv],              [c charon])
1019 ADD_PLUGIN([tnc-tnccs],            [c charon])
1020 ADD_PLUGIN([tnccs-20],             [c charon])
1021 ADD_PLUGIN([tnccs-11],             [c charon])
1022 ADD_PLUGIN([tnccs-dynamic],        [c charon])
1023 ADD_PLUGIN([medsrv],               [c charon])
1024 ADD_PLUGIN([medcli],               [c charon])
1025 ADD_PLUGIN([dhcp],                 [c charon])
1026 ADD_PLUGIN([android-dns],          [c charon])
1027 ADD_PLUGIN([android-log],          [c charon])
1028 ADD_PLUGIN([ha],                   [c charon])
1029 ADD_PLUGIN([whitelist],            [c charon])
1030 ADD_PLUGIN([lookip],               [c charon])
1031 ADD_PLUGIN([error-notify],         [c charon])
1032 ADD_PLUGIN([certexpire],           [c charon])
1033 ADD_PLUGIN([systime-fix],          [c charon])
1034 ADD_PLUGIN([led],                  [c charon])
1035 ADD_PLUGIN([duplicheck],           [c charon])
1036 ADD_PLUGIN([coupling],             [c charon])
1037 ADD_PLUGIN([radattr],              [c charon])
1038 ADD_PLUGIN([maemo],                [c charon])
1039 ADD_PLUGIN([uci],                  [c charon])
1040 ADD_PLUGIN([addrblock],            [c charon])
1041 ADD_PLUGIN([unity],                [c charon])
1042 ADD_PLUGIN([unit-tester],          [c charon])
1043
1044 AC_SUBST(charon_plugins)
1045 AC_SUBST(starter_plugins)
1046 AC_SUBST(pool_plugins)
1047 AC_SUBST(attest_plugins)
1048 AC_SUBST(openac_plugins)
1049 AC_SUBST(scepclient_plugins)
1050 AC_SUBST(pki_plugins)
1051 AC_SUBST(scripts_plugins)
1052 AC_SUBST(manager_plugins)
1053 AC_SUBST(medsrv_plugins)
1054 AC_SUBST(nm_plugins)
1055
1056 AC_SUBST(c_plugins)
1057 AC_SUBST(h_plugins)
1058 AC_SUBST(s_plugins)
1059
1060 # ======================
1061 #  set Makefile.am vars
1062 # ======================
1063
1064 #  libstrongswan plugins
1065 # -----------------------
1066 AM_CONDITIONAL(USE_TEST_VECTORS, test x$test_vectors = xtrue)
1067 AM_CONDITIONAL(USE_CURL, test x$curl = xtrue)
1068 AM_CONDITIONAL(USE_UNBOUND, test x$unbound = xtrue)
1069 AM_CONDITIONAL(USE_SOUP, test x$soup = xtrue)
1070 AM_CONDITIONAL(USE_LDAP, test x$ldap = xtrue)
1071 AM_CONDITIONAL(USE_AES, test x$aes = xtrue)
1072 AM_CONDITIONAL(USE_DES, test x$des = xtrue)
1073 AM_CONDITIONAL(USE_BLOWFISH, test x$blowfish = xtrue)
1074 AM_CONDITIONAL(USE_MD4, test x$md4 = xtrue)
1075 AM_CONDITIONAL(USE_MD5, test x$md5 = xtrue)
1076 AM_CONDITIONAL(USE_SHA1, test x$sha1 = xtrue)
1077 AM_CONDITIONAL(USE_SHA2, test x$sha2 = xtrue)
1078 AM_CONDITIONAL(USE_FIPS_PRF, test x$fips_prf = xtrue)
1079 AM_CONDITIONAL(USE_GMP, test x$gmp = xtrue)
1080 AM_CONDITIONAL(USE_RDRAND, test x$rdrand = xtrue)
1081 AM_CONDITIONAL(USE_RANDOM, test x$random = xtrue)
1082 AM_CONDITIONAL(USE_NONCE, test x$nonce = xtrue)
1083 AM_CONDITIONAL(USE_X509, test x$x509 = xtrue)
1084 AM_CONDITIONAL(USE_REVOCATION, test x$revocation = xtrue)
1085 AM_CONDITIONAL(USE_CONSTRAINTS, test x$constraints = xtrue)
1086 AM_CONDITIONAL(USE_PUBKEY, test x$pubkey = xtrue)
1087 AM_CONDITIONAL(USE_PKCS1, test x$pkcs1 = xtrue)
1088 AM_CONDITIONAL(USE_PKCS7, test x$pkcs7 = xtrue)
1089 AM_CONDITIONAL(USE_PKCS8, test x$pkcs8 = xtrue)
1090 AM_CONDITIONAL(USE_PGP, test x$pgp = xtrue)
1091 AM_CONDITIONAL(USE_DNSKEY, test x$dnskey = xtrue)
1092 AM_CONDITIONAL(USE_PEM, test x$pem = xtrue)
1093 AM_CONDITIONAL(USE_HMAC, test x$hmac = xtrue)
1094 AM_CONDITIONAL(USE_CMAC, test x$cmac = xtrue)
1095 AM_CONDITIONAL(USE_XCBC, test x$xcbc = xtrue)
1096 AM_CONDITIONAL(USE_MYSQL, test x$mysql = xtrue)
1097 AM_CONDITIONAL(USE_SQLITE, test x$sqlite = xtrue)
1098 AM_CONDITIONAL(USE_PADLOCK, test x$padlock = xtrue)
1099 AM_CONDITIONAL(USE_OPENSSL, test x$openssl = xtrue)
1100 AM_CONDITIONAL(USE_GCRYPT, test x$gcrypt = xtrue)
1101 AM_CONDITIONAL(USE_AGENT, test x$agent = xtrue)
1102 AM_CONDITIONAL(USE_PKCS11, test x$pkcs11 = xtrue)
1103 AM_CONDITIONAL(USE_CTR, test x$ctr = xtrue)
1104 AM_CONDITIONAL(USE_CCM, test x$ccm = xtrue)
1105 AM_CONDITIONAL(USE_GCM, test x$gcm = xtrue)
1106 AM_CONDITIONAL(USE_AF_ALG, test x$af_alg = xtrue)
1107
1108 #  charon plugins
1109 # ----------------
1110 AM_CONDITIONAL(USE_STROKE, test x$stroke = xtrue)
1111 AM_CONDITIONAL(USE_MEDSRV, test x$medsrv = xtrue)
1112 AM_CONDITIONAL(USE_MEDCLI, test x$medcli = xtrue)
1113 AM_CONDITIONAL(USE_UCI, test x$uci = xtrue)
1114 AM_CONDITIONAL(USE_ANDROID_DNS, test x$android_dns = xtrue)
1115 AM_CONDITIONAL(USE_ANDROID_LOG, test x$android_log = xtrue)
1116 AM_CONDITIONAL(USE_MAEMO, test x$maemo = xtrue)
1117 AM_CONDITIONAL(USE_SMP, test x$smp = xtrue)
1118 AM_CONDITIONAL(USE_SQL, test x$sql = xtrue)
1119 AM_CONDITIONAL(USE_IPSECKEY, test x$ipseckey = xtrue)
1120 AM_CONDITIONAL(USE_UPDOWN, test x$updown = xtrue)
1121 AM_CONDITIONAL(USE_DHCP, test x$dhcp = xtrue)
1122 AM_CONDITIONAL(USE_UNIT_TESTS, test x$unit_tester = xtrue)
1123 AM_CONDITIONAL(USE_LOAD_TESTER, test x$load_tester = xtrue)
1124 AM_CONDITIONAL(USE_HA, test x$ha = xtrue)
1125 AM_CONDITIONAL(USE_WHITELIST, test x$whitelist = xtrue)
1126 AM_CONDITIONAL(USE_LOOKIP, test x$lookip = xtrue)
1127 AM_CONDITIONAL(USE_ERROR_NOTIFY, test x$error_notify = xtrue)
1128 AM_CONDITIONAL(USE_CERTEXPIRE, test x$certexpire = xtrue)
1129 AM_CONDITIONAL(USE_SYSTIME_FIX, test x$systime_fix = xtrue)
1130 AM_CONDITIONAL(USE_LED, test x$led = xtrue)
1131 AM_CONDITIONAL(USE_DUPLICHECK, test x$duplicheck = xtrue)
1132 AM_CONDITIONAL(USE_COUPLING, test x$coupling = xtrue)
1133 AM_CONDITIONAL(USE_RADATTR, test x$radattr = xtrue)
1134 AM_CONDITIONAL(USE_EAP_SIM, test x$eap_sim = xtrue)
1135 AM_CONDITIONAL(USE_EAP_SIM_FILE, test x$eap_sim_file = xtrue)
1136 AM_CONDITIONAL(USE_EAP_SIM_PCSC, test x$eap_sim_pcsc = xtrue)
1137 AM_CONDITIONAL(USE_EAP_SIMAKA_SQL, test x$eap_simaka_sql = xtrue)
1138 AM_CONDITIONAL(USE_EAP_SIMAKA_PSEUDONYM, test x$eap_simaka_pseudonym = xtrue)
1139 AM_CONDITIONAL(USE_EAP_SIMAKA_REAUTH, test x$eap_simaka_reauth = xtrue)
1140 AM_CONDITIONAL(USE_EAP_IDENTITY, test x$eap_identity = xtrue)
1141 AM_CONDITIONAL(USE_EAP_MD5, test x$eap_md5 = xtrue)
1142 AM_CONDITIONAL(USE_EAP_GTC, test x$eap_gtc = xtrue)
1143 AM_CONDITIONAL(USE_EAP_AKA, test x$eap_aka = xtrue)
1144 AM_CONDITIONAL(USE_EAP_AKA_3GPP2, test x$eap_aka_3gpp2 = xtrue)
1145 AM_CONDITIONAL(USE_EAP_MSCHAPV2, test x$eap_mschapv2 = xtrue)
1146 AM_CONDITIONAL(USE_EAP_TLS, test x$eap_tls = xtrue)
1147 AM_CONDITIONAL(USE_EAP_TTLS, test x$eap_ttls = xtrue)
1148 AM_CONDITIONAL(USE_EAP_PEAP, test x$eap_peap = xtrue)
1149 AM_CONDITIONAL(USE_EAP_TNC, test x$eap_tnc = xtrue)
1150 AM_CONDITIONAL(USE_EAP_DYNAMIC, test x$eap_dynamic = xtrue)
1151 AM_CONDITIONAL(USE_EAP_RADIUS, test x$eap_radius = xtrue)
1152 AM_CONDITIONAL(USE_XAUTH_GENERIC, test x$xauth_generic = xtrue)
1153 AM_CONDITIONAL(USE_XAUTH_EAP, test x$xauth_eap = xtrue)
1154 AM_CONDITIONAL(USE_XAUTH_PAM, test x$xauth_pam = xtrue)
1155 AM_CONDITIONAL(USE_XAUTH_NOAUTH, test x$xauth_noauth = xtrue)
1156 AM_CONDITIONAL(USE_TNC_IFMAP, test x$tnc_ifmap = xtrue)
1157 AM_CONDITIONAL(USE_TNC_PDP, test x$tnc_pdp = xtrue)
1158 AM_CONDITIONAL(USE_TNC_IMC, test x$tnc_imc = xtrue)
1159 AM_CONDITIONAL(USE_TNC_IMV, test x$tnc_imv = xtrue)
1160 AM_CONDITIONAL(USE_TNC_TNCCS, test x$tnc_tnccs = xtrue)
1161 AM_CONDITIONAL(USE_TNCCS_11, test x$tnccs_11 = xtrue)
1162 AM_CONDITIONAL(USE_TNCCS_20, test x$tnccs_20 = xtrue)
1163 AM_CONDITIONAL(USE_TNCCS_DYNAMIC, test x$tnccs_dynamic = xtrue)
1164 AM_CONDITIONAL(USE_IMC_TEST, test x$imc_test = xtrue)
1165 AM_CONDITIONAL(USE_IMV_TEST, test x$imv_test = xtrue)
1166 AM_CONDITIONAL(USE_IMC_SCANNER, test x$imc_scanner = xtrue)
1167 AM_CONDITIONAL(USE_IMV_SCANNER, test x$imv_scanner = xtrue)
1168 AM_CONDITIONAL(USE_IMC_OS, test x$imc_os = xtrue)
1169 AM_CONDITIONAL(USE_IMV_OS, test x$imv_os = xtrue)
1170 AM_CONDITIONAL(USE_IMC_ATTESTATION, test x$imc_attestation = xtrue)
1171 AM_CONDITIONAL(USE_IMV_ATTESTATION, test x$imv_attestation = xtrue)
1172 AM_CONDITIONAL(USE_SOCKET_DEFAULT, test x$socket_default = xtrue)
1173 AM_CONDITIONAL(USE_SOCKET_DYNAMIC, test x$socket_dynamic = xtrue)
1174 AM_CONDITIONAL(USE_FARP, test x$farp = xtrue)
1175 AM_CONDITIONAL(USE_ADDRBLOCK, test x$addrblock = xtrue)
1176 AM_CONDITIONAL(USE_UNITY, test x$unity = xtrue)
1177
1178 #  hydra plugins
1179 # ---------------
1180 AM_CONDITIONAL(USE_ATTR, test x$attr = xtrue)
1181 AM_CONDITIONAL(USE_ATTR_SQL, test x$attr_sql = xtrue -o x$sql = xtrue)
1182 AM_CONDITIONAL(USE_KERNEL_KLIPS, test x$kernel_klips = xtrue)
1183 AM_CONDITIONAL(USE_KERNEL_NETLINK, test x$kernel_netlink = xtrue)
1184 AM_CONDITIONAL(USE_KERNEL_PFKEY, test x$kernel_pfkey = xtrue)
1185 AM_CONDITIONAL(USE_KERNEL_PFROUTE, test x$kernel_pfroute = xtrue)
1186 AM_CONDITIONAL(USE_RESOLVE, test x$resolve = xtrue)
1187
1188 #  other options
1189 # ---------------
1190 AM_CONDITIONAL(USE_LEAK_DETECTIVE, test x$leak_detective = xtrue)
1191 AM_CONDITIONAL(USE_LOCK_PROFILER, test x$lock_profiler = xtrue)
1192 AM_CONDITIONAL(USE_DUMM, test x$dumm = xtrue)
1193 AM_CONDITIONAL(USE_FAST, test x$fast = xtrue)
1194 AM_CONDITIONAL(USE_MANAGER, test x$manager = xtrue)
1195 AM_CONDITIONAL(USE_ME, test x$mediation = xtrue)
1196 AM_CONDITIONAL(USE_INTEGRITY_TEST, test x$integrity_test = xtrue)
1197 AM_CONDITIONAL(USE_LOAD_WARNING, test x$load_warning = xtrue)
1198 AM_CONDITIONAL(USE_IKEV1, test x$ikev1 = xtrue)
1199 AM_CONDITIONAL(USE_IKEV2, test x$ikev2 = xtrue)
1200 AM_CONDITIONAL(USE_THREADS, test x$threads = xtrue)
1201 AM_CONDITIONAL(USE_ADNS, test x$adns = xtrue)
1202 AM_CONDITIONAL(USE_CHARON, test x$charon = xtrue)
1203 AM_CONDITIONAL(USE_NM, test x$nm = xtrue)
1204 AM_CONDITIONAL(USE_TOOLS, test x$tools = xtrue)
1205 AM_CONDITIONAL(USE_SCRIPTS, test x$scripts = xtrue)
1206 AM_CONDITIONAL(USE_CONFTEST, test x$conftest = xtrue)
1207 AM_CONDITIONAL(USE_LIBSTRONGSWAN, test x$charon = xtrue -o x$tools = xtrue -o x$conftest = xtrue -o x$fast = xtrue -o x$imcv = xtrue -o x$nm = xtrue -o x$tkm = xtrue)
1208 AM_CONDITIONAL(USE_LIBHYDRA, test x$charon = xtrue -o x$nm = xtrue -o x$tkm = xtrue)
1209 AM_CONDITIONAL(USE_LIBCHARON, test x$charon = xtrue -o x$conftest = xtrue -o x$nm = xtrue -o x$tkm = xtrue)
1210 AM_CONDITIONAL(USE_LIBIPSEC, test x$libipsec = xtrue)
1211 AM_CONDITIONAL(USE_LIBTNCIF, test x$tnc_tnccs = xtrue -o x$imcv = xtrue)
1212 AM_CONDITIONAL(USE_LIBTNCCS, test x$tnc_tnccs = xtrue)
1213 AM_CONDITIONAL(USE_LIBPTTLS, test x$tnc_tnccs = xtrue)
1214 AM_CONDITIONAL(USE_FILE_CONFIG, test x$stroke = xtrue)
1215 AM_CONDITIONAL(USE_IPSEC_SCRIPT, test x$stroke = xtrue -o x$tools = xtrue -o x$conftest = xtrue)
1216 AM_CONDITIONAL(USE_LIBCAP, test x$capabilities = xlibcap)
1217 AM_CONDITIONAL(USE_VSTR, test x$vstr = xtrue)
1218 AM_CONDITIONAL(USE_SIMAKA, test x$simaka = xtrue)
1219 AM_CONDITIONAL(USE_TLS, test x$tls = xtrue)
1220 AM_CONDITIONAL(USE_RADIUS, test x$radius = xtrue)
1221 AM_CONDITIONAL(USE_IMCV, test x$imcv = xtrue)
1222 AM_CONDITIONAL(USE_PTS, test x$pts = xtrue)
1223 AM_CONDITIONAL(USE_TROUSERS, test x$tss = xtrousers)
1224 AM_CONDITIONAL(MONOLITHIC, test x$monolithic = xtrue)
1225 AM_CONDITIONAL(UNITTESTS, test x$unit_tests = xtrue)
1226 AM_CONDITIONAL(USE_TKM, test x$tkm = xtrue)
1227
1228 # ========================
1229 #  set global definitions
1230 # ========================
1231
1232 if test x$mediation = xtrue; then
1233         AC_DEFINE([ME], [], [mediation extension support])
1234 fi
1235 if test x$capabilities = xlibcap -o x$capabilities = xnative; then
1236         AC_DEFINE([CAPABILITIES], [], [capability dropping support])
1237 fi
1238 if test x$monolithic = xtrue; then
1239         AC_DEFINE([MONOLITHIC], [], [monolithic build embedding plugins])
1240 fi
1241 if test x$ikev1 = xtrue; then
1242         AC_DEFINE([USE_IKEV1], [], [support for IKEv1 protocol])
1243 fi
1244 if test x$ikev2 = xtrue; then
1245         AC_DEFINE([USE_IKEV2], [], [support for IKEv2 protocol])
1246 fi
1247
1248 # =================
1249 #  build Makefiles
1250 # =================
1251
1252 AC_CONFIG_FILES([
1253         Makefile
1254         man/Makefile
1255         init/Makefile
1256         init/systemd/Makefile
1257         src/Makefile
1258         src/include/Makefile
1259         src/libstrongswan/Makefile
1260         src/libstrongswan/plugins/aes/Makefile
1261         src/libstrongswan/plugins/cmac/Makefile
1262         src/libstrongswan/plugins/des/Makefile
1263         src/libstrongswan/plugins/blowfish/Makefile
1264         src/libstrongswan/plugins/md4/Makefile
1265         src/libstrongswan/plugins/md5/Makefile
1266         src/libstrongswan/plugins/sha1/Makefile
1267         src/libstrongswan/plugins/sha2/Makefile
1268         src/libstrongswan/plugins/fips_prf/Makefile
1269         src/libstrongswan/plugins/gmp/Makefile
1270         src/libstrongswan/plugins/rdrand/Makefile
1271         src/libstrongswan/plugins/random/Makefile
1272         src/libstrongswan/plugins/nonce/Makefile
1273         src/libstrongswan/plugins/hmac/Makefile
1274         src/libstrongswan/plugins/xcbc/Makefile
1275         src/libstrongswan/plugins/x509/Makefile
1276         src/libstrongswan/plugins/revocation/Makefile
1277         src/libstrongswan/plugins/constraints/Makefile
1278         src/libstrongswan/plugins/pubkey/Makefile
1279         src/libstrongswan/plugins/pkcs1/Makefile
1280         src/libstrongswan/plugins/pkcs7/Makefile
1281         src/libstrongswan/plugins/pkcs8/Makefile
1282         src/libstrongswan/plugins/pgp/Makefile
1283         src/libstrongswan/plugins/dnskey/Makefile
1284         src/libstrongswan/plugins/pem/Makefile
1285         src/libstrongswan/plugins/curl/Makefile
1286         src/libstrongswan/plugins/unbound/Makefile
1287         src/libstrongswan/plugins/soup/Makefile
1288         src/libstrongswan/plugins/ldap/Makefile
1289         src/libstrongswan/plugins/mysql/Makefile
1290         src/libstrongswan/plugins/sqlite/Makefile
1291         src/libstrongswan/plugins/padlock/Makefile
1292         src/libstrongswan/plugins/openssl/Makefile
1293         src/libstrongswan/plugins/gcrypt/Makefile
1294         src/libstrongswan/plugins/agent/Makefile
1295         src/libstrongswan/plugins/pkcs11/Makefile
1296         src/libstrongswan/plugins/ctr/Makefile
1297         src/libstrongswan/plugins/ccm/Makefile
1298         src/libstrongswan/plugins/gcm/Makefile
1299         src/libstrongswan/plugins/af_alg/Makefile
1300         src/libstrongswan/plugins/test_vectors/Makefile
1301         src/libhydra/Makefile
1302         src/libhydra/plugins/attr/Makefile
1303         src/libhydra/plugins/attr_sql/Makefile
1304         src/libhydra/plugins/kernel_klips/Makefile
1305         src/libhydra/plugins/kernel_netlink/Makefile
1306         src/libhydra/plugins/kernel_pfkey/Makefile
1307         src/libhydra/plugins/kernel_pfroute/Makefile
1308         src/libhydra/plugins/resolve/Makefile
1309         src/libipsec/Makefile
1310         src/libsimaka/Makefile
1311         src/libtls/Makefile
1312         src/libradius/Makefile
1313         src/libtncif/Makefile
1314         src/libtnccs/Makefile
1315         src/libpttls/Makefile
1316         src/libpts/Makefile
1317         src/libpts/plugins/imc_attestation/Makefile
1318         src/libpts/plugins/imv_attestation/Makefile
1319         src/libimcv/Makefile
1320         src/libimcv/plugins/imc_test/Makefile
1321         src/libimcv/plugins/imv_test/Makefile
1322         src/libimcv/plugins/imc_scanner/Makefile
1323         src/libimcv/plugins/imv_scanner/Makefile
1324         src/libimcv/plugins/imc_os/Makefile
1325         src/libimcv/plugins/imv_os/Makefile
1326         src/charon/Makefile
1327         src/charon-nm/Makefile
1328         src/charon-tkm/Makefile
1329         src/libcharon/Makefile
1330         src/libcharon/plugins/eap_aka/Makefile
1331         src/libcharon/plugins/eap_aka_3gpp2/Makefile
1332         src/libcharon/plugins/eap_dynamic/Makefile
1333         src/libcharon/plugins/eap_identity/Makefile
1334         src/libcharon/plugins/eap_md5/Makefile
1335         src/libcharon/plugins/eap_gtc/Makefile
1336         src/libcharon/plugins/eap_sim/Makefile
1337         src/libcharon/plugins/eap_sim_file/Makefile
1338         src/libcharon/plugins/eap_sim_pcsc/Makefile
1339         src/libcharon/plugins/eap_simaka_sql/Makefile
1340         src/libcharon/plugins/eap_simaka_pseudonym/Makefile
1341         src/libcharon/plugins/eap_simaka_reauth/Makefile
1342         src/libcharon/plugins/eap_mschapv2/Makefile
1343         src/libcharon/plugins/eap_tls/Makefile
1344         src/libcharon/plugins/eap_ttls/Makefile
1345         src/libcharon/plugins/eap_peap/Makefile
1346         src/libcharon/plugins/eap_tnc/Makefile
1347         src/libcharon/plugins/eap_radius/Makefile
1348         src/libcharon/plugins/xauth_generic/Makefile
1349         src/libcharon/plugins/xauth_eap/Makefile
1350         src/libcharon/plugins/xauth_pam/Makefile
1351         src/libcharon/plugins/xauth_noauth/Makefile
1352         src/libcharon/plugins/tnc_ifmap/Makefile
1353         src/libcharon/plugins/tnc_pdp/Makefile
1354         src/libcharon/plugins/tnc_imc/Makefile
1355         src/libcharon/plugins/tnc_imv/Makefile
1356         src/libcharon/plugins/tnc_tnccs/Makefile
1357         src/libcharon/plugins/tnccs_11/Makefile
1358         src/libcharon/plugins/tnccs_20/Makefile
1359         src/libcharon/plugins/tnccs_dynamic/Makefile
1360         src/libcharon/plugins/socket_default/Makefile
1361         src/libcharon/plugins/socket_dynamic/Makefile
1362         src/libcharon/plugins/farp/Makefile
1363         src/libcharon/plugins/smp/Makefile
1364         src/libcharon/plugins/sql/Makefile
1365         src/libcharon/plugins/ipseckey/Makefile
1366         src/libcharon/plugins/medsrv/Makefile
1367         src/libcharon/plugins/medcli/Makefile
1368         src/libcharon/plugins/addrblock/Makefile
1369         src/libcharon/plugins/unity/Makefile
1370         src/libcharon/plugins/uci/Makefile
1371         src/libcharon/plugins/ha/Makefile
1372         src/libcharon/plugins/whitelist/Makefile
1373         src/libcharon/plugins/lookip/Makefile
1374         src/libcharon/plugins/error_notify/Makefile
1375         src/libcharon/plugins/certexpire/Makefile
1376         src/libcharon/plugins/systime_fix/Makefile
1377         src/libcharon/plugins/led/Makefile
1378         src/libcharon/plugins/duplicheck/Makefile
1379         src/libcharon/plugins/coupling/Makefile
1380         src/libcharon/plugins/radattr/Makefile
1381         src/libcharon/plugins/android_dns/Makefile
1382         src/libcharon/plugins/android_log/Makefile
1383         src/libcharon/plugins/maemo/Makefile
1384         src/libcharon/plugins/stroke/Makefile
1385         src/libcharon/plugins/updown/Makefile
1386         src/libcharon/plugins/dhcp/Makefile
1387         src/libcharon/plugins/unit_tester/Makefile
1388         src/libcharon/plugins/load_tester/Makefile
1389         src/stroke/Makefile
1390         src/ipsec/Makefile
1391         src/starter/Makefile
1392         src/_updown/Makefile
1393         src/_updown_espmark/Makefile
1394         src/_copyright/Makefile
1395         src/openac/Makefile
1396         src/scepclient/Makefile
1397         src/pki/Makefile
1398         src/dumm/Makefile
1399         src/dumm/ext/extconf.rb
1400         src/libfast/Makefile
1401         src/manager/Makefile
1402         src/medsrv/Makefile
1403         src/checksum/Makefile
1404         src/conftest/Makefile
1405         scripts/Makefile
1406         testing/Makefile
1407 ])
1408 AC_OUTPUT
1409
1410 # ========================
1411 #  report enabled plugins
1412 # ========================
1413
1414 AC_MSG_RESULT([])
1415 AC_MSG_RESULT([ strongSwan will be built with the following plugins])
1416 AC_MSG_RESULT([-----------------------------------------------------])
1417
1418 AC_MSG_RESULT([libstrongswan:$s_plugins])
1419 AC_MSG_RESULT([libcharon:    $c_plugins])
1420 AC_MSG_RESULT([libhydra:     $h_plugins])
1421 AC_MSG_RESULT([])