Merge branch 'nat-transport'
[strongswan.git] / configure.in
1 #
2 # Copyright (C) 2007-2013 Tobias Brunner
3 # Copyright (C) 2006-2013 Andreas Steffen
4 # Copyright (C) 2006-2013 Martin Willi
5 # Hochschule fuer Technik Rapperswil
6 #
7 # This program is free software; you can redistribute it and/or modify it
8 # under the terms of the GNU General Public License as published by the
9 # Free Software Foundation; either version 2 of the License, or (at your
10 # option) any later version.  See <http://www.fsf.org/copyleft/gpl.txt>.
11 #
12 # This program is distributed in the hope that it will be useful, but
13 # WITHOUT ANY WARRANTY; without even the implied warranty of MERCHANTABILITY
14 # or FITNESS FOR A PARTICULAR PURPOSE.  See the GNU General Public License
15 # for more details.
16 #
17
18 # ============================
19 #  initialize & set some vars
20 # ============================
21
22 AC_INIT([strongSwan],[5.0.4])
23 AM_INIT_AUTOMAKE(tar-ustar)
24 m4_ifdef([AM_SILENT_RULES], [AM_SILENT_RULES])
25 AC_CONFIG_MACRO_DIR([m4/config])
26 AC_CONFIG_HEADERS([config.h])
27 AC_DEFINE([CONFIG_H_INCLUDED], [], [defined if config.h included])
28 PKG_PROG_PKG_CONFIG
29
30 # =================================
31 #  check --enable-xxx & --with-xxx
32 # =================================
33
34 m4_include(m4/macros/with.m4)
35
36 ARG_WITH_SUBST([random-device],      [/dev/random], [set the device to read real random data from])
37 ARG_WITH_SUBST([urandom-device],     [/dev/urandom], [set the device to read pseudo random data from])
38 ARG_WITH_SUBST([strongswan-conf],    [${sysconfdir}/strongswan.conf], [set the strongswan.conf file location])
39 ARG_WITH_SUBST([resolv-conf],        [${sysconfdir}/resolv.conf], [set the file to use in DNS handler plugin])
40 ARG_WITH_SUBST([piddir],             [/var/run], [set path for PID and UNIX socket files])
41 ARG_WITH_SUBST([ipsecdir],           [${libexecdir%/}/ipsec], [set installation path for ipsec tools])
42 ARG_WITH_SUBST([ipseclibdir],        [${libdir%/}/ipsec], [set installation path for ipsec libraries])
43 ARG_WITH_SUBST([plugindir],          [${ipseclibdir%/}/plugins], [set the installation path of plugins])
44 ARG_WITH_SUBST([imcvdir],            [${ipseclibdir%/}/imcvs], [set the installation path of IMC and IMV dynamic librariers])
45 ARG_WITH_SUBST([nm-ca-dir],          [/usr/share/ca-certificates], [directory the NM backend uses to look up trusted root certificates])
46 ARG_WITH_SUBST([linux-headers],      [\${top_srcdir}/src/include], [set directory of linux header files to use])
47 ARG_WITH_SUBST([routing-table],      [220], [set routing table to use for IPsec routes])
48 ARG_WITH_SUBST([routing-table-prio], [220], [set priority for IPsec routing table])
49 ARG_WITH_SUBST([ipsec-script],       [ipsec], [change the name of the ipsec script])
50 ARG_WITH_SUBST([fips-mode],          [0], [set openssl FIPS mode: disabled(0), enabled(1), Suite B enabled(2)])
51
52 ARG_WITH_SET([tss],                  [no], [set implementation of the Trusted Computing Group's Software Stack (TSS). Currently the only supported value is "trousers"])
53 ARG_WITH_SET([capabilities],         [no], [set capability dropping library. Currently supported values are "libcap" and "native"])
54 ARG_WITH_SET([mpz_powm_sec],         [yes], [use the more side-channel resistant mpz_powm_sec in libgmp, if available])
55 ARG_WITH_SET([dev-headers],          [no], [install strongSwan development headers to directory.])
56
57 if test -n "$PKG_CONFIG"; then
58         systemdsystemunitdir_default=$($PKG_CONFIG --variable=systemdsystemunitdir systemd)
59 fi
60 ARG_WITH_SET([systemdsystemunitdir], [$systemdsystemunitdir_default], [directory for systemd service files])
61 AM_CONDITIONAL(HAVE_SYSTEMD, [test -n "$systemdsystemunitdir" -a "x$systemdsystemunitdir" != xno])
62 AC_SUBST(systemdsystemunitdir)
63
64 AC_ARG_WITH(
65         [user],
66         AS_HELP_STRING([--with-user=user],[change user of the daemons to "user" after startup (default is "root").]),
67         [AC_DEFINE_UNQUOTED([IPSEC_USER], "$withval", [username to run daemon with])
68          AC_SUBST(ipsecuser, "$withval")],
69         [AC_SUBST(ipsecuser, "root")]
70 )
71
72 AC_ARG_WITH(
73         [group],
74         AS_HELP_STRING([--with-group=group],[change group of the daemons to "group" after startup (default is "root").]),
75         [AC_DEFINE_UNQUOTED(IPSEC_GROUP, "$withval", [groupname to run daemon with])
76          AC_SUBST(ipsecgroup, "$withval")],
77         [AC_SUBST(ipsecgroup, "root")]
78 )
79
80 AC_ARG_WITH(
81         [charon-udp-port],
82         AS_HELP_STRING([--with-charon-udp-port=port],[UDP port used by charon locally (default 500). Set to 0 to allocate randomly.]),
83         [AC_DEFINE_UNQUOTED(CHARON_UDP_PORT, [$withval], [UDP port used by charon locally])
84          AC_SUBST(charon_udp_port, [$withval])],
85         [AC_SUBST(charon_udp_port, 500)]
86 )
87
88 AC_ARG_WITH(
89         [charon-natt-port],
90         AS_HELP_STRING([--with-charon-natt-port=port],[UDP port used by charon locally in case a NAT is detected (must be different from charon-udp-port, default 4500). Set to 0 to allocate randomly.]),
91         [AC_DEFINE_UNQUOTED(CHARON_NATT_PORT, [$withval], [UDP post used by charon locally in case a NAT is detected])
92          AC_SUBST(charon_natt_port, [$withval])],
93         [AC_SUBST(charon_natt_port, 4500)]
94 )
95
96 AC_MSG_CHECKING([configured UDP ports ($charon_udp_port, $charon_natt_port)])
97 if test x$charon_udp_port != x0 -a x$charon_udp_port = x$charon_natt_port; then
98         AC_MSG_ERROR(the ports have to be different)
99 else
100         AC_MSG_RESULT(ok)
101 fi
102
103 # convert script name to uppercase
104 AC_SUBST(ipsec_script_upper, [`echo -n "$ipsec_script" | tr a-z A-Z`])
105
106 m4_include(m4/macros/enable-disable.m4)
107
108 ARG_ENABL_SET([curl],           [enable CURL fetcher plugin to fetch files via libcurl. Requires libcurl.])
109 ARG_ENABL_SET([unbound],        [enable UNBOUND resolver plugin to perform DNS queries via libunbound. Requires libldns and libunbound.])
110 ARG_ENABL_SET([soup],           [enable soup fetcher plugin to fetch from HTTP via libsoup. Requires libsoup.])
111 ARG_ENABL_SET([ldap],           [enable LDAP fetching plugin to fetch files via libldap. Requires openLDAP.])
112 ARG_DISBL_SET([aes],            [disable AES software implementation plugin.])
113 ARG_DISBL_SET([des],            [disable DES/3DES software implementation plugin.])
114 ARG_ENABL_SET([blowfish],       [enable Blowfish software implementation plugin.])
115 ARG_DISBL_SET([rc2],            [disable RC2 software implementation plugin.])
116 ARG_ENABL_SET([md4],            [enable MD4 software implementation plugin.])
117 ARG_DISBL_SET([md5],            [disable MD5 software implementation plugin.])
118 ARG_DISBL_SET([sha1],           [disable SHA1 software implementation plugin.])
119 ARG_DISBL_SET([sha2],           [disable SHA256/SHA384/SHA512 software implementation plugin.])
120 ARG_DISBL_SET([fips-prf],       [disable FIPS PRF software implementation plugin.])
121 ARG_DISBL_SET([gmp],            [disable GNU MP (libgmp) based crypto implementation plugin.])
122 ARG_ENABL_SET([rdrand],         [enable Intel RDRAND random generator plugin.])
123 ARG_DISBL_SET([random],         [disable RNG implementation on top of /dev/(u)random.])
124 ARG_DISBL_SET([nonce],          [disable nonce generation plugin.])
125 ARG_DISBL_SET([x509],           [disable X509 certificate implementation plugin.])
126 ARG_DISBL_SET([revocation],     [disable X509 CRL/OCSP revocation check plugin.])
127 ARG_DISBL_SET([constraints],    [disable advanced X509 constraint checking plugin.])
128 ARG_DISBL_SET([pubkey],         [disable RAW public key support plugin.])
129 ARG_DISBL_SET([pkcs1],          [disable PKCS1 key decoding plugin.])
130 ARG_DISBL_SET([pkcs7],          [disable PKCS7 container support plugin.])
131 ARG_DISBL_SET([pkcs8],          [disable PKCS8 private key decoding plugin.])
132 ARG_DISBL_SET([pkcs12],         [disable PKCS12 container support plugin.])
133 ARG_DISBL_SET([pgp],            [disable PGP key decoding plugin.])
134 ARG_DISBL_SET([dnskey],         [disable DNS RR key decoding plugin.])
135 ARG_DISBL_SET([sshkey],         [disable SSH key decoding plugin.])
136 ARG_ENABL_SET([ipseckey],       [enable IPSECKEY authentication plugin.])
137 ARG_DISBL_SET([pem],            [disable PEM decoding plugin.])
138 ARG_DISBL_SET([hmac],           [disable HMAC crypto implementation plugin.])
139 ARG_DISBL_SET([cmac],           [disable CMAC crypto implementation plugin.])
140 ARG_DISBL_SET([xcbc],           [disable xcbc crypto implementation plugin.])
141 ARG_ENABL_SET([af-alg],         [enable AF_ALG crypto interface to Linux Crypto API.])
142 ARG_ENABL_SET([test-vectors],   [enable plugin providing crypto test vectors.])
143 ARG_ENABL_SET([mysql],          [enable MySQL database support. Requires libmysqlclient_r.])
144 ARG_ENABL_SET([sqlite],         [enable SQLite database support. Requires libsqlite3.])
145 ARG_DISBL_SET([stroke],         [disable charons stroke configuration backend.])
146 ARG_ENABL_SET([medsrv],         [enable mediation server web frontend and daemon plugin.])
147 ARG_ENABL_SET([medcli],         [enable mediation client configuration database plugin.])
148 ARG_ENABL_SET([smp],            [enable SMP configuration and control interface. Requires libxml.])
149 ARG_ENABL_SET([sql],            [enable SQL database configuration backend.])
150 ARG_ENABL_SET([leak-detective], [enable malloc hooks to find memory leaks.])
151 ARG_ENABL_SET([lock-profiler],  [enable lock/mutex profiling code.])
152 ARG_ENABL_SET([unit-tester],    [enable unit tests on IKEv2 daemon startup.])
153 ARG_ENABL_SET([load-tester],    [enable load testing plugin for IKEv2 daemon.])
154 ARG_ENABL_SET([eap-sim],        [enable SIM authentication module for EAP.])
155 ARG_ENABL_SET([eap-sim-file],   [enable EAP-SIM backend based on a triplet file.])
156 ARG_ENABL_SET([eap-sim-pcsc],   [enable EAP-SIM backend based on a smartcard reader. Requires libpcsclite.])
157 ARG_ENABL_SET([eap-aka],        [enable EAP AKA authentication module.])
158 ARG_ENABL_SET([eap-aka-3gpp2],  [enable EAP AKA backend implementing 3GPP2 algorithms in software. Requires libgmp.])
159 ARG_ENABL_SET([eap-simaka-sql], [enable EAP-SIM/AKA backend based on a triplet/quintuplet SQL database.])
160 ARG_ENABL_SET([eap-simaka-pseudonym], [enable EAP-SIM/AKA pseudonym storage plugin.])
161 ARG_ENABL_SET([eap-simaka-reauth],    [enable EAP-SIM/AKA reauthentication data storage plugin.])
162 ARG_ENABL_SET([eap-identity],   [enable EAP module providing EAP-Identity helper.])
163 ARG_ENABL_SET([eap-md5],        [enable EAP MD5 (CHAP) authentication module.])
164 ARG_ENABL_SET([eap-gtc],        [enable EAP GTC authentication module.])
165 ARG_ENABL_SET([eap-mschapv2],   [enable EAP MS-CHAPv2 authentication module.])
166 ARG_ENABL_SET([eap-tls],        [enable EAP TLS authentication module.])
167 ARG_ENABL_SET([eap-ttls],       [enable EAP TTLS authentication module.])
168 ARG_ENABL_SET([eap-peap],       [enable EAP PEAP authentication module.])
169 ARG_ENABL_SET([eap-tnc],        [enable EAP TNC trusted network connect module.])
170 ARG_ENABL_SET([eap-dynamic],    [enable dynamic EAP proxy module.])
171 ARG_ENABL_SET([eap-radius],     [enable RADIUS proxy authentication module.])
172 ARG_DISBL_SET([xauth-generic],  [disable generic XAuth backend.])
173 ARG_ENABL_SET([xauth-eap],      [enable XAuth backend using EAP methods to verify passwords.])
174 ARG_ENABL_SET([xauth-pam],      [enable XAuth backend using PAM to verify passwords.])
175 ARG_ENABL_SET([xauth-noauth],   [enable XAuth pseudo-backend that does not actually verify or even request any credentials.])
176 ARG_ENABL_SET([tnc-ifmap],      [enable TNC IF-MAP module. Requires libxml])
177 ARG_ENABL_SET([tnc-pdp],        [enable TNC policy decision point module.])
178 ARG_ENABL_SET([tnc-imc],        [enable TNC IMC module.])
179 ARG_ENABL_SET([tnc-imv],        [enable TNC IMV module.])
180 ARG_ENABL_SET([tnccs-11],       [enable TNCCS 1.1 protocol module. Requires libxml])
181 ARG_ENABL_SET([tnccs-20],       [enable TNCCS 2.0 protocol module.])
182 ARG_ENABL_SET([tnccs-dynamic],  [enable dynamic TNCCS protocol discovery module.])
183 ARG_ENABL_SET([imc-test],       [enable IMC test module.])
184 ARG_ENABL_SET([imv-test],       [enable IMV test module.])
185 ARG_ENABL_SET([imc-scanner],    [enable IMC port scanner module.])
186 ARG_ENABL_SET([imv-scanner],    [enable IMV port scanner module.])
187 ARG_ENABL_SET([imc-os],         [enable IMC operating system module.])
188 ARG_ENABL_SET([imv-os],         [enable IMV operating system module.])
189 ARG_ENABL_SET([imc-attestation],[enable IMC attestation module.])
190 ARG_ENABL_SET([imv-attestation],[enable IMV attestation module.])
191 ARG_DISBL_SET([kernel-netlink], [disable the netlink kernel interface.])
192 ARG_ENABL_SET([kernel-pfkey],   [enable the PF_KEY kernel interface.])
193 ARG_ENABL_SET([kernel-pfroute], [enable the PF_ROUTE kernel interface.])
194 ARG_ENABL_SET([kernel-klips],   [enable the KLIPS kernel interface.])
195 ARG_ENABL_SET([libipsec],       [enable user space IPsec implementation.])
196 ARG_DISBL_SET([socket-default], [disable default socket implementation for charon.])
197 ARG_ENABL_SET([socket-dynamic], [enable dynamic socket implementation for charon])
198 ARG_ENABL_SET([farp],           [enable ARP faking plugin that responds to ARP requests to peers virtual IP])
199 ARG_ENABL_SET([dumm],           [enable the DUMM UML test framework.])
200 ARG_ENABL_SET([fast],           [enable libfast (FastCGI Application Server w/ templates.])
201 ARG_ENABL_SET([manager],        [enable web management console (proof of concept).])
202 ARG_ENABL_SET([mediation],      [enable IKEv2 Mediation Extension.])
203 ARG_ENABL_SET([integrity-test], [enable integrity testing of libstrongswan and plugins.])
204 ARG_DISBL_SET([load-warning],   [disable the charon plugin load option warning in starter.])
205 ARG_DISBL_SET([ikev1],          [disable IKEv1 protocol support in charon.])
206 ARG_DISBL_SET([ikev2],          [disable IKEv2 protocol support in charon.])
207 ARG_DISBL_SET([charon],         [disable the IKEv1/IKEv2 keying daemon charon.])
208 ARG_DISBL_SET([tools],          [disable additional utilities (openac, scepclient and pki).])
209 ARG_DISBL_SET([scripts],        [disable additional utilities (found in directory scripts).])
210 ARG_ENABL_SET([conftest],       [enforce Suite B conformance test framework.])
211 ARG_DISBL_SET([updown],         [disable updown firewall script plugin.])
212 ARG_DISBL_SET([attr],           [disable strongswan.conf based configuration attribute plugin.])
213 ARG_ENABL_SET([attr-sql],       [enable SQL based configuration attribute plugin.])
214 ARG_ENABL_SET([dhcp],           [enable DHCP based attribute provider plugin.])
215 ARG_DISBL_SET([resolve],        [disable resolve DNS handler plugin.])
216 ARG_ENABL_SET([padlock],        [enables VIA Padlock crypto plugin.])
217 ARG_ENABL_SET([openssl],        [enables the OpenSSL crypto plugin.])
218 ARG_ENABL_SET([gcrypt],         [enables the libgcrypt plugin.])
219 ARG_ENABL_SET([agent],          [enables the ssh-agent signing plugin.])
220 ARG_ENABL_SET([pkcs11],         [enables the PKCS11 token support plugin.])
221 ARG_ENABL_SET([ctr],            [enables the Counter Mode wrapper crypto plugin.])
222 ARG_ENABL_SET([ccm],            [enables the CCM AEAD wrapper crypto plugin.])
223 ARG_ENABL_SET([gcm],            [enables the GCM AEAD wrapper crypto plugin.])
224 ARG_ENABL_SET([addrblock],      [enables RFC 3779 address block constraint support.])
225 ARG_ENABL_SET([unity],          [enables Cisco Unity extension plugin.])
226 ARG_ENABL_SET([uci],            [enable OpenWRT UCI configuration plugin.])
227 ARG_ENABL_SET([android-dns],    [enable Android specific DNS handler.])
228 ARG_ENABL_SET([android-log],    [enable Android specific logger plugin.])
229 ARG_ENABL_SET([maemo],          [enable Maemo specific plugin.])
230 ARG_ENABL_SET([nm],             [enable NetworkManager backend.])
231 ARG_ENABL_SET([ha],             [enable high availability cluster plugin.])
232 ARG_ENABL_SET([whitelist],      [enable peer identity whitelisting plugin.])
233 ARG_ENABL_SET([lookip],         [enable fast virtual IP lookup and notification plugin.])
234 ARG_ENABL_SET([error-notify],   [enable error notification plugin.])
235 ARG_ENABL_SET([certexpire],     [enable CSV export of expiration dates of used certificates.])
236 ARG_ENABL_SET([systime-fix],    [enable plugin to handle cert lifetimes with invalid system time gracefully.])
237 ARG_ENABL_SET([led],            [enable plugin to control LEDs on IKEv2 activity using the Linux kernel LED subsystem.])
238 ARG_ENABL_SET([duplicheck],     [advanced duplicate checking plugin using liveness checks.])
239 ARG_ENABL_SET([coupling],       [enable IKEv2 plugin to couple peer certificates permanently to authentication.])
240 ARG_ENABL_SET([radattr],        [enable plugin to inject and process custom RADIUS attributes as IKEv2 client.])
241 ARG_ENABL_SET([vstr],           [enforce using the Vstr string library to replace glibc-like printf hooks.])
242 ARG_ENABL_SET([monolithic],     [build monolithic version of libstrongswan that includes all enabled plugins. Similarly, the plugins of charon are assembled in libcharon.])
243 ARG_ENABL_SET([bfd-backtraces], [use binutils libbfd to resolve backtraces for memory leaks and segfaults.])
244 ARG_ENABL_SET([unwind-backtraces],[use libunwind to create backtraces for memory leaks and segfaults.])
245 ARG_ENABL_SET([unit-tests],     [enable unit tests using the check test framework.])
246 ARG_ENABL_SET([coverage],       [enable lcov coverage report generation.])
247 ARG_ENABL_SET([tkm],            [enable Trusted Key Manager support.])
248 ARG_ENABL_SET([cmd],            [enable the command line IKE client charon-cmd.])
249
250 # ===================================
251 #  option to disable default options
252 # ===================================
253
254 ARG_DISBL_SET([defaults],       [disable all default plugins (they can be enabled with their respective --enable options)])
255
256 if test x$defaults = xfalse; then
257         for option in $enabled_by_default; do
258                 eval test x\${${option}_given} = xtrue && continue
259                 let $option=false
260         done
261 fi
262
263 # ===========================
264 #  set up compiler and flags
265 # ===========================
266
267 if test -z "$CFLAGS"; then
268         CFLAGS="-g -O2 -Wall -Wno-format -Wno-pointer-sign"
269 fi
270 AC_PROG_CC
271 AM_PROG_CC_C_O
272
273 AC_LIB_PREFIX
274 AC_C_BIGENDIAN
275
276 # =========================
277 #  check required programs
278 # =========================
279
280 LT_INIT
281 AC_PROG_INSTALL
282 AC_PROG_EGREP
283 AC_PROG_AWK
284 AC_PROG_LEX
285 AC_PROG_YACC
286 AC_PATH_PROG([PERL], [perl], [], [$PATH:/bin:/usr/bin:/usr/local/bin])
287 AC_PATH_PROG([GPERF], [gperf], [], [$PATH:/bin:/usr/bin:/usr/local/bin])
288
289 # because gperf is not needed by end-users we just report it but do not abort on failure
290 AC_MSG_CHECKING([gperf version >= 3.0.0])
291 if test -x "$GPERF"; then
292         if test "`$GPERF --version | $AWK -F' ' '/^GNU gperf/ { print $3 }' | $AWK -F. '{ print $1 }'`" -ge "3"; then
293                 AC_MSG_RESULT([yes])
294         else
295                 AC_MSG_RESULT([no])
296         fi
297 else
298         AC_MSG_RESULT([not found])
299 fi
300
301 # ========================
302 #  dependency calculation
303 # ========================
304
305 if test x$xauth_generic_given = xfalse -a x$ikev1 = xfalse; then
306         xauth_generic=false;
307 fi
308
309 if test x$eap_aka_3gpp2 = xtrue; then
310         gmp=true;
311 fi
312
313 if test x$eap_aka = xtrue; then
314         fips_prf=true;
315         simaka=true;
316 fi
317
318 if test x$eap_sim = xtrue; then
319         fips_prf=true;
320         simaka=true;
321 fi
322
323 if test x$eap_tls = xtrue -o x$eap_ttls = xtrue -o x$eap_peap = xtrue; then
324         tls=true;
325 fi
326
327 if test x$eap_radius = xtrue -o x$radattr = xtrue -o x$tnc_pdp = xtrue; then
328         radius=true;
329 fi
330
331 if test x$tnc_imc = xtrue -o x$tnc_imv = xtrue -o x$tnccs_11 = xtrue -o x$tnccs_11 = xtrue -o x$tnccs_dynamic = xtrue -o x$eap_tnc = xtrue; then
332         tnc_tnccs=true;
333 fi
334
335 if test x$imc_test = xtrue -o x$imv_test = xtrue -o x$imc_scanner = xtrue -o x$imv_scanner = xtrue -o x$imc_os = xtrue -o x$imv_os = xtrue -o x$imc_attestation = xtrue -o x$imv_attestation = xtrue; then
336         imcv=true;
337 fi
338
339 if test x$imc_attestation = xtrue -o x$imv_attestation = xtrue; then
340         pts=true;
341 fi
342
343 if test x$fips_prf = xtrue; then
344         if test x$openssl = xfalse; then
345                 sha1=true;
346         fi
347 fi
348
349 if test x$smp = xtrue -o x$tnccs_11 = xtrue -o x$tnc_ifmap = xtrue; then
350         xml=true
351 fi
352
353 if test x$manager = xtrue; then
354         fast=true
355 fi
356
357 if test x$medsrv = xtrue; then
358         mediation=true
359         fast=true
360 fi
361
362 if test x$medcli = xtrue; then
363         mediation=true
364 fi
365
366 if test x$coverage = xtrue; then
367         unit_tests=true
368 fi
369
370 # ===========================================
371 #  check required libraries and header files
372 # ===========================================
373
374 AC_HEADER_STDBOOL
375 AC_FUNC_ALLOCA
376 AC_FUNC_STRERROR_R
377
378 #  libraries needed on some platforms but not on others
379 # ------------------------------------------------------
380 saved_LIBS=$LIBS
381
382 # FreeBSD and Mac OS X have dlopen integrated in libc, Linux needs libdl
383 LIBS=""
384 AC_SEARCH_LIBS(dlopen, dl, [DLLIB=$LIBS])
385 AC_SUBST(DLLIB)
386
387 # glibc's backtrace() can be replicated on FreeBSD with libexecinfo
388 LIBS=""
389 AC_SEARCH_LIBS(backtrace, execinfo, [BTLIB=$LIBS])
390 AC_CHECK_FUNCS(backtrace)
391 AC_SUBST(BTLIB)
392
393 # OpenSolaris needs libsocket and libnsl for socket()
394 LIBS=""
395 AC_SEARCH_LIBS(socket, socket, [SOCKLIB=$LIBS],
396         [AC_CHECK_LIB(nsl, socket, [SOCKLIB="-lsocket -lnsl"], [], [-lsocket])]
397 )
398 AC_SUBST(SOCKLIB)
399
400 # FreeBSD has clock_gettime in libc, Linux needs librt
401 LIBS=""
402 AC_SEARCH_LIBS(clock_gettime, rt, [RTLIB=$LIBS])
403 AC_CHECK_FUNCS(clock_gettime)
404 AC_SUBST(RTLIB)
405
406 # Android has pthread_* functions in bionic (libc), others need libpthread
407 LIBS=""
408 AC_SEARCH_LIBS(pthread_create, pthread, [PTHREADLIB=$LIBS])
409 AC_SUBST(PTHREADLIB)
410
411 LIBS=$saved_LIBS
412 # ------------------------------------------------------
413
414 AC_MSG_CHECKING(for dladdr)
415 AC_COMPILE_IFELSE(
416         [AC_LANG_PROGRAM(
417                 [[#define _GNU_SOURCE
418                   #include <dlfcn.h>]],
419                 [[Dl_info* info = 0;
420                   dladdr(0, info);]])],
421         [AC_MSG_RESULT([yes]); AC_DEFINE([HAVE_DLADDR], [], [have dladdr()])],
422         [AC_MSG_RESULT([no])]
423 )
424
425 # check if pthread_condattr_setclock(CLOCK_MONOTONE) is supported
426 saved_LIBS=$LIBS
427 LIBS=$PTHREADLIB
428 AC_MSG_CHECKING([for pthread_condattr_setclock(CLOCK_MONOTONE)])
429 AC_RUN_IFELSE(
430         [AC_LANG_SOURCE(
431                 [[#include <pthread.h>
432                   int main() { pthread_condattr_t attr;
433                         pthread_condattr_init(&attr);
434                         return pthread_condattr_setclock(&attr, CLOCK_MONOTONIC);}]])],
435         [AC_MSG_RESULT([yes]);
436          AC_DEFINE([HAVE_CONDATTR_CLOCK_MONOTONIC], [],
437                            [pthread_condattr_setclock supports CLOCK_MONOTONIC])],
438         [AC_MSG_RESULT([no])],
439         # Check existence of pthread_condattr_setclock if cross-compiling
440         [AC_MSG_RESULT([unknown]);
441          AC_CHECK_FUNCS(pthread_condattr_setclock,
442                 [AC_DEFINE([HAVE_CONDATTR_CLOCK_MONOTONIC], [],
443                                    [have pthread_condattr_setclock()])]
444         )]
445 )
446 # check if we actually are able to configure attributes on cond vars
447 AC_CHECK_FUNCS(pthread_condattr_init)
448 # instead of pthread_condattr_setclock Android has this function
449 AC_CHECK_FUNCS(pthread_cond_timedwait_monotonic)
450 # check if we can cancel threads
451 AC_CHECK_FUNCS(pthread_cancel)
452 # check if native rwlocks are available
453 AC_CHECK_FUNCS(pthread_rwlock_init)
454 # check if pthread spinlocks are available
455 AC_CHECK_FUNCS(pthread_spin_init)
456 # check if we have POSIX semaphore functions, including timed-wait
457 AC_CHECK_FUNCS(sem_timedwait)
458 LIBS=$saved_LIBS
459
460 AC_CHECK_FUNC(
461         [gettid],
462         [AC_DEFINE([HAVE_GETTID], [], [have gettid()])],
463         [AC_MSG_CHECKING([for SYS_gettid])
464          AC_COMPILE_IFELSE(
465                 [AC_LANG_PROGRAM(
466                         [[#define _GNU_SOURCE
467                           #include <unistd.h>
468                           #include <sys/syscall.h>]],
469                         [[int main() {
470                           return syscall(SYS_gettid);}]])],
471                 [AC_MSG_RESULT([yes]);
472                  AC_DEFINE([HAVE_GETTID], [], [have gettid()])
473                  AC_DEFINE([HAVE_SYS_GETTID], [], [have syscall(SYS_gettid)])],
474                 [AC_MSG_RESULT([no])]
475         )]
476 )
477
478 AC_CHECK_FUNCS(prctl mallinfo getpass closefrom getpwnam_r getgrnam_r getpwuid_r)
479
480 AC_CHECK_HEADERS(sys/sockio.h glob.h)
481 AC_CHECK_HEADERS(net/pfkeyv2.h netipsec/ipsec.h netinet6/ipsec.h linux/udp.h)
482 AC_CHECK_HEADERS(netinet/ip6.h, [], [],
483 [
484         #include <sys/types.h>
485         #include <netinet/in.h>
486 ])
487
488 AC_CHECK_MEMBERS([struct sockaddr.sa_len], [], [],
489 [
490         #include <sys/types.h>
491         #include <sys/socket.h>
492 ])
493
494 AC_CHECK_MEMBERS([struct sadb_x_policy.sadb_x_policy_priority], [], [],
495 [
496         #include <sys/types.h>
497         #ifdef HAVE_NET_PFKEYV2_H
498         #include <net/pfkeyv2.h>
499         #else
500         #include <stdint.h>
501         #include <linux/pfkeyv2.h>
502         #endif
503 ])
504
505 AC_MSG_CHECKING([for in6addr_any])
506 AC_COMPILE_IFELSE(
507         [AC_LANG_PROGRAM(
508                 [[#include <sys/types.h>
509                   #include <sys/socket.h>
510                   #include <netinet/in.h>]],
511                 [[struct in6_addr in6;
512                   in6 = in6addr_any;]])],
513         [AC_MSG_RESULT([yes]);
514          AC_DEFINE([HAVE_IN6ADDR_ANY], [], [have struct in6_addr in6addr_any])],
515         [AC_MSG_RESULT([no])]
516 )
517
518 AC_MSG_CHECKING([for in6_pktinfo])
519 AC_COMPILE_IFELSE(
520         [AC_LANG_PROGRAM(
521                 [[#define _GNU_SOURCE
522                   #include <sys/types.h>
523                   #include <sys/socket.h>
524                   #include <netinet/in.h>]],
525                 [[struct in6_pktinfo pi;
526                   if (pi.ipi6_ifindex)
527                   {
528                     return 0;
529                   }]])],
530         [AC_MSG_RESULT([yes]);
531          AC_DEFINE([HAVE_IN6_PKTINFO], [], [have struct in6_pktinfo.ipi6_ifindex])],
532         [AC_MSG_RESULT([no])]
533 )
534
535 AC_MSG_CHECKING([for IPSEC_MODE_BEET])
536 AC_COMPILE_IFELSE(
537         [AC_LANG_PROGRAM(
538                 [[#include <sys/types.h>
539                   #ifdef HAVE_NETIPSEC_IPSEC_H
540                   #include <netipsec/ipsec.h>
541                   #elif defined(HAVE_NETINET6_IPSEC_H)
542                   #include <netinet6/ipsec.h>
543                   #else
544                   #include <stdint.h>
545                   #include <linux/ipsec.h>
546                   #endif]],
547                 [[int mode = IPSEC_MODE_BEET;
548                   return mode;]])],
549         [AC_MSG_RESULT([yes]);
550          AC_DEFINE([HAVE_IPSEC_MODE_BEET], [], [have IPSEC_MODE_BEET defined])],
551         [AC_MSG_RESULT([no])]
552 )
553
554 AC_MSG_CHECKING([for IPSEC_DIR_FWD])
555 AC_COMPILE_IFELSE(
556         [AC_LANG_PROGRAM(
557                 [[#include <sys/types.h>
558                   #ifdef HAVE_NETIPSEC_IPSEC_H
559                   #include <netipsec/ipsec.h>
560                   #elif defined(HAVE_NETINET6_IPSEC_H)
561                   #include <netinet6/ipsec.h>
562                   #else
563                   #include <stdint.h>
564                   #include <linux/ipsec.h>
565                   #endif]],
566                 [[int dir = IPSEC_DIR_FWD;
567                   return dir;]])],
568         [AC_MSG_RESULT([yes]);
569          AC_DEFINE([HAVE_IPSEC_DIR_FWD], [], [have IPSEC_DIR_FWD defined])],
570         [AC_MSG_RESULT([no])]
571 )
572
573 AC_MSG_CHECKING([for RTA_TABLE])
574 AC_COMPILE_IFELSE(
575         [AC_LANG_PROGRAM(
576                 [[#include <sys/socket.h>
577                   #include <linux/netlink.h>
578                   #include <linux/rtnetlink.h>]],
579                 [[int rta_type = RTA_TABLE;
580                   return rta_type;]])],
581         [AC_MSG_RESULT([yes]);
582          AC_DEFINE([HAVE_RTA_TABLE], [], [have netlink RTA_TABLE defined])],
583         [AC_MSG_RESULT([no])]
584 )
585
586 AC_MSG_CHECKING([for gcc atomic operations])
587 AC_RUN_IFELSE([AC_LANG_SOURCE(
588         [[
589                         int main() {
590                         volatile int ref = 1;
591                         __sync_fetch_and_add (&ref, 1);
592                         __sync_sub_and_fetch (&ref, 1);
593                         /* Make sure test fails if operations are not supported */
594                         __sync_val_compare_and_swap(&ref, 1, 0);
595                         return ref;
596                 }
597         ]])],
598         [AC_MSG_RESULT([yes]);
599          AC_DEFINE([HAVE_GCC_ATOMIC_OPERATIONS], [],
600                    [have GCC __sync_* atomic operations])],
601         [AC_MSG_RESULT([no])],
602         [AC_MSG_RESULT([no])]
603 )
604
605 # check for the new register_printf_specifier function with len argument,
606 # or the deprecated register_printf_function without
607 AC_CHECK_FUNC(
608         [register_printf_specifier],
609         [AC_DEFINE([HAVE_PRINTF_SPECIFIER], [], [have register_printf_specifier()])],
610         [AC_CHECK_FUNC(
611                 [register_printf_function],
612                 [AC_DEFINE([HAVE_PRINTF_FUNCTION], [], [have register_printf_function()])],
613                 [
614                         AC_MSG_NOTICE([printf does not support custom format specifiers!])
615                         vstr=true
616                 ]
617         )]
618 )
619
620 if test x$vstr = xtrue; then
621         AC_CHECK_LIB([vstr],[main],[LIBS="$LIBS"],[AC_MSG_ERROR([Vstr string library not found])],[])
622         AC_DEFINE([USE_VSTR], [], [use vstring library for printf hooks])
623 fi
624
625 if test x$gmp = xtrue; then
626         saved_LIBS=$LIBS
627         AC_CHECK_LIB([gmp],[main],[],[AC_MSG_ERROR([GNU Multi Precision library gmp not found])],[])
628         AC_MSG_CHECKING([mpz_powm_sec])
629         if test x$mpz_powm_sec = xyes; then
630                 AC_COMPILE_IFELSE(
631                         [AC_LANG_PROGRAM(
632                                 [[#include "gmp.h"]],
633                                 [[void *x = mpz_powm_sec;]])],
634                         [AC_MSG_RESULT([yes]);
635                          AC_DEFINE([HAVE_MPZ_POWM_SEC], [], [have mpz_mown_sec()])],
636                         [AC_MSG_RESULT([no])]
637                 )
638         else
639                 AC_MSG_RESULT([disabled])
640         fi
641         LIBS=$saved_LIBS
642         AC_MSG_CHECKING([gmp.h version >= 4.1.4])
643         AC_COMPILE_IFELSE(
644                 [AC_LANG_PROGRAM(
645                         [[#include "gmp.h"]],
646                         [[
647                                 #if (__GNU_MP_VERSION*100 +  __GNU_MP_VERSION_MINOR*10 + __GNU_MP_VERSION_PATCHLEVEL) < 414
648                                         #error bad gmp
649                                 #endif]])],
650                 [AC_MSG_RESULT([yes])],
651                 [AC_MSG_RESULT([no]); AC_MSG_ERROR([No usable gmp.h found!])]
652         )
653 fi
654
655 if test x$ldap = xtrue; then
656         AC_CHECK_LIB([ldap],[main],[LIBS="$LIBS"],[AC_MSG_ERROR([LDAP library ldap not found])],[])
657         AC_CHECK_LIB([lber],[main],[LIBS="$LIBS"],[AC_MSG_ERROR([LDAP library lber not found])],[])
658         AC_CHECK_HEADER([ldap.h],,[AC_MSG_ERROR([LDAP header ldap.h not found!])])
659 fi
660
661 if test x$curl = xtrue; then
662         AC_CHECK_LIB([curl],[main],[LIBS="$LIBS"],[AC_MSG_ERROR([CURL library curl not found])],[])
663         AC_CHECK_HEADER([curl/curl.h],,[AC_MSG_ERROR([CURL header curl/curl.h not found!])])
664 fi
665
666 if test x$unbound = xtrue; then
667         AC_HAVE_LIBRARY([ldns],[LIBS="$LIBS"],[AC_MSG_ERROR([UNBOUND library ldns not found])])
668         AC_CHECK_HEADER([ldns/ldns.h],,[AC_MSG_ERROR([UNBOUND header ldns/ldns.h not found!])])
669         AC_HAVE_LIBRARY([unbound],[LIBS="$LIBS"],[AC_MSG_ERROR([UNBOUND library libunbound not found])])
670         AC_CHECK_HEADER([unbound.h],,[AC_MSG_ERROR([UNBOUND header unbound.h not found!])])
671 fi
672
673 if test x$soup = xtrue; then
674         PKG_CHECK_MODULES(soup, [libsoup-2.4])
675         AC_SUBST(soup_CFLAGS)
676         AC_SUBST(soup_LIBS)
677 fi
678
679 if test x$xml = xtrue; then
680         PKG_CHECK_MODULES(xml, [libxml-2.0])
681         AC_SUBST(xml_CFLAGS)
682         AC_SUBST(xml_LIBS)
683 fi
684
685 if test x$tss = xtrousers; then
686         AC_CHECK_LIB([tspi],[main],[LIBS="$LIBS"],[AC_MSG_ERROR([TrouSerS library libtspi not found])],[])
687         AC_CHECK_HEADER([trousers/tss.h],,[AC_MSG_ERROR([TrouSerS header trousers/tss.h not found!])])
688         AC_DEFINE([TSS_TROUSERS], [], [use TrouSerS library libtspi as TSS implementation])
689 fi
690
691 if test x$dumm = xtrue; then
692         PKG_CHECK_MODULES(gtk, [gtk+-2.0 vte])
693         AC_SUBST(gtk_CFLAGS)
694         AC_SUBST(gtk_LIBS)
695         AC_CHECK_PROGS(RUBY, ruby)
696         AC_MSG_CHECKING([for Ruby header files])
697         if test -n "$RUBY"; then
698                 RUBYINCLUDE=
699                 RUBYDIR=`($RUBY -r rbconfig -e 'print RbConfig::CONFIG[["rubyhdrdir"]] || ""') 2>/dev/null`
700                 if test -n "$RUBYDIR" -a -r "$RUBYDIR/ruby.h"; then
701                         RUBYARCH=`($RUBY -r rbconfig -e 'print RbConfig::CONFIG[["arch"]] || ""') 2>/dev/null`
702                         if test -n "$RUBYARCH"; then
703                                 AC_MSG_RESULT([$RUBYDIR])
704                                 RUBYINCLUDE="-I$RUBYDIR -I$RUBYDIR/$RUBYARCH"
705                         fi
706                 else
707                         RUBYDIR=`($RUBY -r rbconfig -e 'print RbConfig::CONFIG[["archdir"]] || ""') 2>/dev/null`
708                         if test -n "$RUBYDIR" -a -r "$RUBYDIR/ruby.h"; then
709                                 AC_MSG_RESULT([$RUBYDIR])
710                                 RUBYINCLUDE="-I$RUBYDIR"
711                         fi
712                 fi
713                 if test -z "$RUBYINCLUDE"; then
714                         AC_MSG_ERROR([ruby.h not found])
715                 fi
716                 AC_SUBST(RUBYINCLUDE)
717         else
718                 AC_MSG_ERROR([don't know how to run ruby])
719         fi
720         AC_MSG_CHECKING([for libruby])
721         saved_LIBS=$LIBS
722         LIBS=`($RUBY -r rbconfig -e 'print RbConfig::CONFIG[["LIBRUBYARG_SHARED"]] || ""') 2>/dev/null`
723         AC_TRY_LINK_FUNC(ruby_init,
724                 [AC_MSG_RESULT([$LIBS]); RUBYLIB=$LIBS],
725                 [AC_MSG_ERROR([not found])])
726         AC_SUBST(RUBYLIB)
727         AC_CHECK_FUNCS(rb_errinfo)
728         LIBS=$saved_LIBS
729 fi
730
731 if test x$fast = xtrue; then
732         AC_CHECK_LIB([neo_cgi],[main],[LIBS="$LIBS"],[AC_MSG_ERROR([ClearSilver library neo_cgi not found!])],[])
733         AC_CHECK_LIB([neo_utl],[main],[LIBS="$LIBS"],[AC_MSG_ERROR([ClearSilver library neo_utl not found!])],[])
734         AC_MSG_CHECKING([ClearSilver requires zlib])
735         saved_CFLAGS=$CFLAGS
736         saved_LIBS=$LIBS
737         LIBS="-lneo_cgi -lneo_cs -lneo_utl"
738         CFLAGS="-I/usr/include/ClearSilver"
739         AC_LINK_IFELSE(
740                 [AC_LANG_PROGRAM(
741                         [[#include <ClearSilver.h>]],
742                         [[NEOERR *err = cgi_display(NULL, NULL);]])],
743                 [AC_MSG_RESULT([no]); clearsilver_LIBS="$LIBS"],
744                 [AC_MSG_RESULT([yes]); clearsilver_LIBS="$LIBS -lz"]
745         )
746         AC_SUBST(clearsilver_LIBS)
747         LIBS=$saved_LIBS
748         CFLAGS=$saved_CFLAGS
749 # autoconf does not like CamelCase!? How to fix this?
750 #       AC_CHECK_HEADER([ClearSilver/ClearSilver.h],,[AC_MSG_ERROR([ClearSilver header file ClearSilver/ClearSilver.h not found!])])
751
752         AC_CHECK_LIB([fcgi],[main],[LIBS="$LIBS"],[AC_MSG_ERROR([FastCGI library fcgi not found!])],[])
753         AC_CHECK_HEADER([fcgiapp.h],,[AC_MSG_ERROR([FastCGI header file fcgiapp.h not found!])])
754 fi
755
756 if test x$mysql = xtrue; then
757         AC_PATH_PROG([MYSQLCONFIG], [mysql_config], [], [$PATH:/bin:/usr/bin:/usr/local/bin])
758         if test x$MYSQLCONFIG = x; then
759                 AC_MSG_ERROR([mysql_config not found!])
760         fi
761         AC_SUBST(MYSQLLIB, `$MYSQLCONFIG --libs_r`)
762         AC_SUBST(MYSQLCFLAG, `$MYSQLCONFIG --cflags`)
763 fi
764
765 if test x$sqlite = xtrue; then
766         AC_CHECK_LIB([sqlite3],[main],[LIBS="$LIBS"],[AC_MSG_ERROR([SQLite library sqlite3 not found])],[])
767         AC_CHECK_HEADER([sqlite3.h],,[AC_MSG_ERROR([SQLite header sqlite3.h not found!])])
768         AC_MSG_CHECKING([sqlite3_prepare_v2])
769         AC_COMPILE_IFELSE(
770                 [AC_LANG_PROGRAM(
771                         [[#include <sqlite3.h>]],
772                         [[void *test = sqlite3_prepare_v2;]])],
773                 [AC_MSG_RESULT([yes]);
774                  AC_DEFINE([HAVE_SQLITE3_PREPARE_V2], [], [have sqlite3_prepare_v2()])],
775                 [AC_MSG_RESULT([no])]
776         )
777         AC_MSG_CHECKING([sqlite3.h version >= 3.3.1])
778         AC_COMPILE_IFELSE(
779                 [AC_LANG_PROGRAM(
780                         [[#include <sqlite3.h>]],
781                         [[
782                                 #if SQLITE_VERSION_NUMBER < 3003001
783                                         #error bad sqlite
784                                 #endif]])],
785                 [AC_MSG_RESULT([yes])],
786                 [AC_MSG_RESULT([no]); AC_MSG_ERROR([SQLite version >= 3.3.1 required!])]
787         )
788 fi
789
790 if test x$openssl = xtrue; then
791         AC_CHECK_LIB([crypto],[main],[LIBS="$LIBS"],[AC_MSG_ERROR([OpenSSL crypto library not found])],[])
792         AC_CHECK_HEADER([openssl/evp.h],,[AC_MSG_ERROR([OpenSSL header openssl/evp.h not found!])])
793 fi
794
795 if test x$gcrypt = xtrue; then
796         AC_CHECK_LIB([gcrypt],[main],[LIBS="$LIBS"],[AC_MSG_ERROR([gcrypt library not found])],[-lgpg-error])
797         AC_CHECK_HEADER([gcrypt.h],,[AC_MSG_ERROR([gcrypt header gcrypt.h not found!])])
798         AC_MSG_CHECKING([gcrypt CAMELLIA cipher])
799         AC_COMPILE_IFELSE(
800                 [AC_LANG_PROGRAM(
801                         [[#include <gcrypt.h>]],
802                         [[enum gcry_cipher_algos alg = GCRY_CIPHER_CAMELLIA128;]])],
803                 [AC_MSG_RESULT([yes]);
804                  AC_DEFINE([HAVE_GCRY_CIPHER_CAMELLIA], [], [have GCRY_CIPHER_CAMELLIA128])],
805                 [AC_MSG_RESULT([no])]
806         )
807 fi
808
809 if test x$uci = xtrue; then
810         AC_CHECK_LIB([uci],[main],[LIBS="$LIBS"],[AC_MSG_ERROR([UCI library libuci not found])],[])
811         AC_CHECK_HEADER([uci.h],,[AC_MSG_ERROR([UCI header uci.h not found!])])
812 fi
813
814 if test x$android_dns = xtrue; then
815         AC_CHECK_LIB([cutils],[main],[LIBS="$LIBS"],[AC_MSG_ERROR([Android library libcutils not found])],[])
816         AC_CHECK_HEADER([cutils/properties.h],,[AC_MSG_ERROR([Android header cutils/properties.h not found!])])
817         # we have to force the use of libdl here because the autodetection
818         # above does not work correctly when cross-compiling for android.
819         DLLIB="-ldl"
820         AC_SUBST(DLLIB)
821 fi
822
823 if test x$maemo = xtrue; then
824         PKG_CHECK_MODULES(maemo, [glib-2.0 gthread-2.0 libosso osso-af-settings])
825         AC_SUBST(maemo_CFLAGS)
826         AC_SUBST(maemo_LIBS)
827         dbusservicedir="/usr/share/dbus-1/system-services"
828         AC_SUBST(dbusservicedir)
829 fi
830
831 if test x$eap_sim_pcsc = xtrue; then
832         PKG_CHECK_MODULES(pcsclite, [libpcsclite])
833         AC_SUBST(pcsclite_CFLAGS)
834         AC_SUBST(pcsclite_LIBS)
835 fi
836
837 if test x$nm = xtrue; then
838         PKG_CHECK_EXISTS([libnm-glib],
839                 [PKG_CHECK_MODULES(nm, [NetworkManager gthread-2.0 libnm-util libnm-glib libnm-glib-vpn])],
840                 [PKG_CHECK_MODULES(nm, [NetworkManager gthread-2.0 libnm_util libnm_glib libnm_glib_vpn])]
841         )
842         AC_SUBST(nm_CFLAGS)
843         AC_SUBST(nm_LIBS)
844 fi
845
846 if test x$xauth_pam = xtrue; then
847         AC_CHECK_LIB([pam],[main],[LIBS="$LIBS"],[AC_MSG_ERROR([PAM library not found])],[])
848         AC_CHECK_HEADER([security/pam_appl.h],,[AC_MSG_ERROR([PAM header security/pam_appl.h not found!])])
849 fi
850
851 if test x$capabilities = xnative; then
852         AC_MSG_NOTICE([Usage of the native Linux capabilities interface is deprecated, use libcap instead])
853         # Linux requires the following for capset(), Android does not have it,
854         # but defines capset() in unistd.h instead.
855         AC_CHECK_HEADERS([sys/capability.h])
856         AC_CHECK_FUNC(capset,,[AC_MSG_ERROR([capset() not found!])])
857         AC_DEFINE([CAPABILITIES_NATIVE], [], [have native linux capset()])
858 fi
859
860 if test x$capabilities = xlibcap; then
861         AC_CHECK_LIB([cap],[main],[LIBS="$LIBS"],[AC_MSG_ERROR([libcap library not found])],[])
862         AC_CHECK_HEADER([sys/capability.h],
863                 [AC_DEFINE([HAVE_SYS_CAPABILITY_H], [], [have sys/capability.h])],
864                 [AC_MSG_ERROR([libcap header sys/capability.h not found!])])
865         AC_DEFINE([CAPABILITIES_LIBCAP], [], [have libpcap library])
866 fi
867
868 if test x$integrity_test = xtrue; then
869         AC_MSG_CHECKING([for dladdr()])
870         AC_COMPILE_IFELSE(
871                 [AC_LANG_PROGRAM(
872                         [[#define _GNU_SOURCE
873                           #include <dlfcn.h>]],
874                         [[Dl_info info; dladdr(main, &info);]])],
875                 [AC_MSG_RESULT([yes])],
876                 [AC_MSG_RESULT([no]);
877                  AC_MSG_ERROR([dladdr() not supported, required by integrity-test!])]
878         )
879         AC_MSG_CHECKING([for dl_iterate_phdr()])
880         AC_COMPILE_IFELSE(
881                 [AC_LANG_PROGRAM(
882                         [[#define _GNU_SOURCE
883                           #include <link.h>]],
884                         [[dl_iterate_phdr((void*)0, (void*)0);]])],
885                 [AC_MSG_RESULT([yes])],
886                 [AC_MSG_RESULT([no]);
887                  AC_MSG_ERROR([dl_iterate_phdr() not supported, required by integrity-test!])]
888         )
889 fi
890
891 if test x$bfd_backtraces = xtrue; then
892         AC_CHECK_LIB([bfd],[main],[LIBS="$LIBS"],[AC_MSG_ERROR([binutils libbfd not found!])],[])
893         AC_CHECK_HEADER([bfd.h],[AC_DEFINE([HAVE_BFD_H],,[have binutils bfd.h])],
894                 [AC_MSG_ERROR([binutils bfd.h header not found!])])
895         BFDLIB="-lbfd"
896         AC_SUBST(BFDLIB)
897 fi
898
899 if test x$unwind_backtraces = xtrue; then
900         AC_CHECK_LIB([unwind],[main],[LIBS="$LIBS"],[AC_MSG_ERROR([libunwind not found!])],[])
901         AC_CHECK_HEADER([libunwind.h],[AC_DEFINE([HAVE_LIBUNWIND_H],,[have libunwind.h])],
902                 [AC_MSG_ERROR([libunwind.h header not found!])])
903         UNWINDLIB="-lunwind"
904         AC_SUBST(UNWINDLIB)
905 fi
906
907 AM_CONDITIONAL(USE_DEV_HEADERS, [test "x$dev_headers" != xno])
908 if test x$dev_headers = xyes; then
909         dev_headers="$includedir/strongswan"
910 fi
911 AC_SUBST(dev_headers)
912
913 CFLAGS="$CFLAGS -include `pwd`/config.h"
914
915 if test x$tkm = xtrue; then
916         AC_PATH_PROG([GPRBUILD], [gprbuild], [], [$PATH:/bin:/usr/bin:/usr/local/bin])
917 fi
918
919 if test x$unit_tests = xtrue; then
920         PKG_CHECK_MODULES(CHECK, [check >= 0.9.4])
921         AC_SUBST(CHECK_CFLAGS)
922         AC_SUBST(CHECK_LIBS)
923 fi
924
925 if test x$coverage = xtrue; then
926         AC_PATH_PROG([LCOV], [lcov], [], [$PATH:/bin:/usr/bin:/usr/local/bin])
927         if test x$LCOV = x; then
928                 AC_MSG_ERROR([lcov not found])
929         fi
930         AC_PATH_PROG([GENHTML], [genhtml], [], [$PATH:/bin:/usr/bin:/usr/local/bin])
931         if test x$GENHTML = x; then
932                 AC_MSG_ERROR([genhtml not found])
933         fi
934
935         COVERAGE_CFLAGS="-fprofile-arcs -ftest-coverage"
936         COVERAGE_LDFLAGS="-fprofile-arcs"
937         AC_SUBST(COVERAGE_CFLAGS)
938         AC_SUBST(COVERAGE_LDFLAGS)
939
940         AC_MSG_NOTICE([coverage enabled, adding "-g -O0" to CFLAGS])
941         CFLAGS="${CFLAGS} -g -O0"
942 fi
943
944 # ===============================================
945 #  collect plugin list for strongSwan components
946 # ===============================================
947
948 m4_include(m4/macros/add-plugin.m4)
949
950 # plugin lists for all components
951 charon_plugins=
952 starter_plugins=
953 pool_plugins=
954 attest_plugins=
955 openac_plugins=
956 scepclient_plugins=
957 pki_plugins=
958 scripts_plugins=
959 manager_plugins=
960 medsrv_plugins=
961 nm_plugins=
962 cmd_plugins=
963
964 # location specific lists for checksumming,
965 # for src/libcharon, src/libhydra and src/libstrongswan
966 c_plugins=
967 h_plugins=
968 s_plugins=
969
970 ADD_PLUGIN([test-vectors],         [s charon openac scepclient pki])
971 ADD_PLUGIN([curl],                 [s charon scepclient scripts nm cmd])
972 ADD_PLUGIN([soup],                 [s charon scripts nm cmd])
973 ADD_PLUGIN([unbound],              [s charon scripts])
974 ADD_PLUGIN([ldap],                 [s charon scepclient scripts nm cmd])
975 ADD_PLUGIN([mysql],                [s charon pool manager medsrv attest])
976 ADD_PLUGIN([sqlite],               [s charon pool manager medsrv attest])
977 ADD_PLUGIN([pkcs11],               [s charon pki nm cmd])
978 ADD_PLUGIN([aes],                  [s charon openac scepclient pki scripts nm cmd])
979 ADD_PLUGIN([des],                  [s charon openac scepclient pki scripts nm cmd])
980 ADD_PLUGIN([blowfish],             [s charon openac scepclient pki scripts nm cmd])
981 ADD_PLUGIN([rc2],                  [s charon openac scepclient pki scripts nm cmd])
982 ADD_PLUGIN([sha1],                 [s charon openac scepclient pki scripts medsrv attest nm cmd])
983 ADD_PLUGIN([sha2],                 [s charon openac scepclient pki scripts medsrv attest nm cmd])
984 ADD_PLUGIN([md4],                  [s charon openac manager scepclient pki nm cmd])
985 ADD_PLUGIN([md5],                  [s charon openac scepclient pki scripts attest nm cmd])
986 ADD_PLUGIN([rdrand],               [s charon openac scepclient pki scripts medsrv attest nm cmd])
987 ADD_PLUGIN([random],               [s charon openac scepclient pki scripts medsrv attest nm cmd])
988 ADD_PLUGIN([nonce],                [s charon nm cmd])
989 ADD_PLUGIN([x509],                 [s charon openac scepclient pki scripts attest nm cmd])
990 ADD_PLUGIN([revocation],           [s charon nm cmd])
991 ADD_PLUGIN([constraints],          [s charon nm cmd])
992 ADD_PLUGIN([pubkey],               [s charon cmd])
993 ADD_PLUGIN([pkcs1],                [s charon openac scepclient pki scripts manager medsrv attest nm cmd])
994 ADD_PLUGIN([pkcs7],                [s charon scepclient pki scripts nm cmd])
995 ADD_PLUGIN([pkcs8],                [s charon openac scepclient pki scripts manager medsrv attest nm cmd])
996 ADD_PLUGIN([pkcs12],               [s charon scepclient pki scripts cmd])
997 ADD_PLUGIN([pgp],                  [s charon])
998 ADD_PLUGIN([dnskey],               [s charon])
999 ADD_PLUGIN([sshkey],               [s charon nm cmd])
1000 ADD_PLUGIN([ipseckey],             [c charon])
1001 ADD_PLUGIN([pem],                  [s charon openac scepclient pki scripts manager medsrv attest nm cmd])
1002 ADD_PLUGIN([padlock],              [s charon])
1003 ADD_PLUGIN([openssl],              [s charon openac scepclient pki scripts manager medsrv attest nm cmd])
1004 ADD_PLUGIN([gcrypt],               [s charon openac scepclient pki scripts manager medsrv attest nm cmd])
1005 ADD_PLUGIN([af-alg],               [s charon openac scepclient pki scripts medsrv attest nm cmd])
1006 ADD_PLUGIN([fips-prf],             [s charon nm cmd])
1007 ADD_PLUGIN([gmp],                  [s charon openac scepclient pki scripts manager medsrv attest nm cmd])
1008 ADD_PLUGIN([agent],                [s charon nm cmd])
1009 ADD_PLUGIN([xcbc],                 [s charon nm cmd])
1010 ADD_PLUGIN([cmac],                 [s charon nm cmd])
1011 ADD_PLUGIN([hmac],                 [s charon scripts nm cmd])
1012 ADD_PLUGIN([ctr],                  [s charon scripts nm cmd])
1013 ADD_PLUGIN([ccm],                  [s charon scripts nm cmd])
1014 ADD_PLUGIN([gcm],                  [s charon scripts nm cmd])
1015 ADD_PLUGIN([attr],                 [h charon])
1016 ADD_PLUGIN([attr-sql],             [h charon])
1017 ADD_PLUGIN([load-tester],          [c charon])
1018 ADD_PLUGIN([kernel-pfkey],         [h charon starter nm cmd])
1019 ADD_PLUGIN([kernel-pfroute],       [h charon starter nm cmd])
1020 ADD_PLUGIN([kernel-klips],         [h charon starter])
1021 ADD_PLUGIN([kernel-netlink],       [h charon starter nm cmd])
1022 ADD_PLUGIN([resolve],              [h charon cmd])
1023 ADD_PLUGIN([socket-default],       [c charon nm cmd])
1024 ADD_PLUGIN([socket-dynamic],       [c charon cmd])
1025 ADD_PLUGIN([farp],                 [c charon])
1026 ADD_PLUGIN([stroke],               [c charon])
1027 ADD_PLUGIN([smp],                  [c charon])
1028 ADD_PLUGIN([sql],                  [c charon])
1029 ADD_PLUGIN([updown],               [c charon])
1030 ADD_PLUGIN([eap-identity],         [c charon nm cmd])
1031 ADD_PLUGIN([eap-sim],              [c charon])
1032 ADD_PLUGIN([eap-sim-file],         [c charon])
1033 ADD_PLUGIN([eap-sim-pcsc],         [c charon])
1034 ADD_PLUGIN([eap-aka],              [c charon])
1035 ADD_PLUGIN([eap-aka-3gpp2],        [c charon])
1036 ADD_PLUGIN([eap-simaka-sql],       [c charon])
1037 ADD_PLUGIN([eap-simaka-pseudonym], [c charon])
1038 ADD_PLUGIN([eap-simaka-reauth],    [c charon])
1039 ADD_PLUGIN([eap-md5],              [c charon nm cmd])
1040 ADD_PLUGIN([eap-gtc],              [c charon nm cmd])
1041 ADD_PLUGIN([eap-mschapv2],         [c charon nm cmd])
1042 ADD_PLUGIN([eap-dynamic],          [c charon])
1043 ADD_PLUGIN([eap-radius],           [c charon])
1044 ADD_PLUGIN([eap-tls],              [c charon nm cmd])
1045 ADD_PLUGIN([eap-ttls],             [c charon nm cmd])
1046 ADD_PLUGIN([eap-peap],             [c charon nm cmd])
1047 ADD_PLUGIN([eap-tnc],              [c charon])
1048 ADD_PLUGIN([xauth-generic],        [c charon cmd])
1049 ADD_PLUGIN([xauth-eap],            [c charon])
1050 ADD_PLUGIN([xauth-pam],            [c charon])
1051 ADD_PLUGIN([xauth-noauth],         [c charon])
1052 ADD_PLUGIN([tnc-ifmap],            [c charon])
1053 ADD_PLUGIN([tnc-pdp],              [c charon])
1054 ADD_PLUGIN([tnc-imc],              [c charon])
1055 ADD_PLUGIN([tnc-imv],              [c charon])
1056 ADD_PLUGIN([tnc-tnccs],            [c charon])
1057 ADD_PLUGIN([tnccs-20],             [c charon])
1058 ADD_PLUGIN([tnccs-11],             [c charon])
1059 ADD_PLUGIN([tnccs-dynamic],        [c charon])
1060 ADD_PLUGIN([medsrv],               [c charon])
1061 ADD_PLUGIN([medcli],               [c charon])
1062 ADD_PLUGIN([dhcp],                 [c charon])
1063 ADD_PLUGIN([android-dns],          [c charon])
1064 ADD_PLUGIN([android-log],          [c charon])
1065 ADD_PLUGIN([ha],                   [c charon])
1066 ADD_PLUGIN([whitelist],            [c charon])
1067 ADD_PLUGIN([lookip],               [c charon])
1068 ADD_PLUGIN([error-notify],         [c charon])
1069 ADD_PLUGIN([certexpire],           [c charon])
1070 ADD_PLUGIN([systime-fix],          [c charon])
1071 ADD_PLUGIN([led],                  [c charon])
1072 ADD_PLUGIN([duplicheck],           [c charon])
1073 ADD_PLUGIN([coupling],             [c charon])
1074 ADD_PLUGIN([radattr],              [c charon])
1075 ADD_PLUGIN([maemo],                [c charon])
1076 ADD_PLUGIN([uci],                  [c charon])
1077 ADD_PLUGIN([addrblock],            [c charon])
1078 ADD_PLUGIN([unity],                [c charon])
1079 ADD_PLUGIN([unit-tester],          [c charon])
1080
1081 AC_SUBST(charon_plugins)
1082 AC_SUBST(starter_plugins)
1083 AC_SUBST(pool_plugins)
1084 AC_SUBST(attest_plugins)
1085 AC_SUBST(openac_plugins)
1086 AC_SUBST(scepclient_plugins)
1087 AC_SUBST(pki_plugins)
1088 AC_SUBST(scripts_plugins)
1089 AC_SUBST(manager_plugins)
1090 AC_SUBST(medsrv_plugins)
1091 AC_SUBST(nm_plugins)
1092 AC_SUBST(cmd_plugins)
1093
1094 AC_SUBST(c_plugins)
1095 AC_SUBST(h_plugins)
1096 AC_SUBST(s_plugins)
1097
1098 # ======================
1099 #  set Makefile.am vars
1100 # ======================
1101
1102 #  libstrongswan plugins
1103 # -----------------------
1104 AM_CONDITIONAL(USE_TEST_VECTORS, test x$test_vectors = xtrue)
1105 AM_CONDITIONAL(USE_CURL, test x$curl = xtrue)
1106 AM_CONDITIONAL(USE_UNBOUND, test x$unbound = xtrue)
1107 AM_CONDITIONAL(USE_SOUP, test x$soup = xtrue)
1108 AM_CONDITIONAL(USE_LDAP, test x$ldap = xtrue)
1109 AM_CONDITIONAL(USE_AES, test x$aes = xtrue)
1110 AM_CONDITIONAL(USE_DES, test x$des = xtrue)
1111 AM_CONDITIONAL(USE_BLOWFISH, test x$blowfish = xtrue)
1112 AM_CONDITIONAL(USE_RC2, test x$rc2 = xtrue)
1113 AM_CONDITIONAL(USE_MD4, test x$md4 = xtrue)
1114 AM_CONDITIONAL(USE_MD5, test x$md5 = xtrue)
1115 AM_CONDITIONAL(USE_SHA1, test x$sha1 = xtrue)
1116 AM_CONDITIONAL(USE_SHA2, test x$sha2 = xtrue)
1117 AM_CONDITIONAL(USE_FIPS_PRF, test x$fips_prf = xtrue)
1118 AM_CONDITIONAL(USE_GMP, test x$gmp = xtrue)
1119 AM_CONDITIONAL(USE_RDRAND, test x$rdrand = xtrue)
1120 AM_CONDITIONAL(USE_RANDOM, test x$random = xtrue)
1121 AM_CONDITIONAL(USE_NONCE, test x$nonce = xtrue)
1122 AM_CONDITIONAL(USE_X509, test x$x509 = xtrue)
1123 AM_CONDITIONAL(USE_REVOCATION, test x$revocation = xtrue)
1124 AM_CONDITIONAL(USE_CONSTRAINTS, test x$constraints = xtrue)
1125 AM_CONDITIONAL(USE_PUBKEY, test x$pubkey = xtrue)
1126 AM_CONDITIONAL(USE_PKCS1, test x$pkcs1 = xtrue)
1127 AM_CONDITIONAL(USE_PKCS7, test x$pkcs7 = xtrue)
1128 AM_CONDITIONAL(USE_PKCS8, test x$pkcs8 = xtrue)
1129 AM_CONDITIONAL(USE_PKCS12, test x$pkcs12 = xtrue)
1130 AM_CONDITIONAL(USE_PGP, test x$pgp = xtrue)
1131 AM_CONDITIONAL(USE_DNSKEY, test x$dnskey = xtrue)
1132 AM_CONDITIONAL(USE_SSHKEY, test x$sshkey = xtrue)
1133 AM_CONDITIONAL(USE_PEM, test x$pem = xtrue)
1134 AM_CONDITIONAL(USE_HMAC, test x$hmac = xtrue)
1135 AM_CONDITIONAL(USE_CMAC, test x$cmac = xtrue)
1136 AM_CONDITIONAL(USE_XCBC, test x$xcbc = xtrue)
1137 AM_CONDITIONAL(USE_MYSQL, test x$mysql = xtrue)
1138 AM_CONDITIONAL(USE_SQLITE, test x$sqlite = xtrue)
1139 AM_CONDITIONAL(USE_PADLOCK, test x$padlock = xtrue)
1140 AM_CONDITIONAL(USE_OPENSSL, test x$openssl = xtrue)
1141 AM_CONDITIONAL(USE_GCRYPT, test x$gcrypt = xtrue)
1142 AM_CONDITIONAL(USE_AGENT, test x$agent = xtrue)
1143 AM_CONDITIONAL(USE_PKCS11, test x$pkcs11 = xtrue)
1144 AM_CONDITIONAL(USE_CTR, test x$ctr = xtrue)
1145 AM_CONDITIONAL(USE_CCM, test x$ccm = xtrue)
1146 AM_CONDITIONAL(USE_GCM, test x$gcm = xtrue)
1147 AM_CONDITIONAL(USE_AF_ALG, test x$af_alg = xtrue)
1148
1149 #  charon plugins
1150 # ----------------
1151 AM_CONDITIONAL(USE_STROKE, test x$stroke = xtrue)
1152 AM_CONDITIONAL(USE_MEDSRV, test x$medsrv = xtrue)
1153 AM_CONDITIONAL(USE_MEDCLI, test x$medcli = xtrue)
1154 AM_CONDITIONAL(USE_UCI, test x$uci = xtrue)
1155 AM_CONDITIONAL(USE_ANDROID_DNS, test x$android_dns = xtrue)
1156 AM_CONDITIONAL(USE_ANDROID_LOG, test x$android_log = xtrue)
1157 AM_CONDITIONAL(USE_MAEMO, test x$maemo = xtrue)
1158 AM_CONDITIONAL(USE_SMP, test x$smp = xtrue)
1159 AM_CONDITIONAL(USE_SQL, test x$sql = xtrue)
1160 AM_CONDITIONAL(USE_IPSECKEY, test x$ipseckey = xtrue)
1161 AM_CONDITIONAL(USE_UPDOWN, test x$updown = xtrue)
1162 AM_CONDITIONAL(USE_DHCP, test x$dhcp = xtrue)
1163 AM_CONDITIONAL(USE_UNIT_TESTS, test x$unit_tester = xtrue)
1164 AM_CONDITIONAL(USE_LOAD_TESTER, test x$load_tester = xtrue)
1165 AM_CONDITIONAL(USE_HA, test x$ha = xtrue)
1166 AM_CONDITIONAL(USE_WHITELIST, test x$whitelist = xtrue)
1167 AM_CONDITIONAL(USE_LOOKIP, test x$lookip = xtrue)
1168 AM_CONDITIONAL(USE_ERROR_NOTIFY, test x$error_notify = xtrue)
1169 AM_CONDITIONAL(USE_CERTEXPIRE, test x$certexpire = xtrue)
1170 AM_CONDITIONAL(USE_SYSTIME_FIX, test x$systime_fix = xtrue)
1171 AM_CONDITIONAL(USE_LED, test x$led = xtrue)
1172 AM_CONDITIONAL(USE_DUPLICHECK, test x$duplicheck = xtrue)
1173 AM_CONDITIONAL(USE_COUPLING, test x$coupling = xtrue)
1174 AM_CONDITIONAL(USE_RADATTR, test x$radattr = xtrue)
1175 AM_CONDITIONAL(USE_EAP_SIM, test x$eap_sim = xtrue)
1176 AM_CONDITIONAL(USE_EAP_SIM_FILE, test x$eap_sim_file = xtrue)
1177 AM_CONDITIONAL(USE_EAP_SIM_PCSC, test x$eap_sim_pcsc = xtrue)
1178 AM_CONDITIONAL(USE_EAP_SIMAKA_SQL, test x$eap_simaka_sql = xtrue)
1179 AM_CONDITIONAL(USE_EAP_SIMAKA_PSEUDONYM, test x$eap_simaka_pseudonym = xtrue)
1180 AM_CONDITIONAL(USE_EAP_SIMAKA_REAUTH, test x$eap_simaka_reauth = xtrue)
1181 AM_CONDITIONAL(USE_EAP_IDENTITY, test x$eap_identity = xtrue)
1182 AM_CONDITIONAL(USE_EAP_MD5, test x$eap_md5 = xtrue)
1183 AM_CONDITIONAL(USE_EAP_GTC, test x$eap_gtc = xtrue)
1184 AM_CONDITIONAL(USE_EAP_AKA, test x$eap_aka = xtrue)
1185 AM_CONDITIONAL(USE_EAP_AKA_3GPP2, test x$eap_aka_3gpp2 = xtrue)
1186 AM_CONDITIONAL(USE_EAP_MSCHAPV2, test x$eap_mschapv2 = xtrue)
1187 AM_CONDITIONAL(USE_EAP_TLS, test x$eap_tls = xtrue)
1188 AM_CONDITIONAL(USE_EAP_TTLS, test x$eap_ttls = xtrue)
1189 AM_CONDITIONAL(USE_EAP_PEAP, test x$eap_peap = xtrue)
1190 AM_CONDITIONAL(USE_EAP_TNC, test x$eap_tnc = xtrue)
1191 AM_CONDITIONAL(USE_EAP_DYNAMIC, test x$eap_dynamic = xtrue)
1192 AM_CONDITIONAL(USE_EAP_RADIUS, test x$eap_radius = xtrue)
1193 AM_CONDITIONAL(USE_XAUTH_GENERIC, test x$xauth_generic = xtrue)
1194 AM_CONDITIONAL(USE_XAUTH_EAP, test x$xauth_eap = xtrue)
1195 AM_CONDITIONAL(USE_XAUTH_PAM, test x$xauth_pam = xtrue)
1196 AM_CONDITIONAL(USE_XAUTH_NOAUTH, test x$xauth_noauth = xtrue)
1197 AM_CONDITIONAL(USE_TNC_IFMAP, test x$tnc_ifmap = xtrue)
1198 AM_CONDITIONAL(USE_TNC_PDP, test x$tnc_pdp = xtrue)
1199 AM_CONDITIONAL(USE_TNC_IMC, test x$tnc_imc = xtrue)
1200 AM_CONDITIONAL(USE_TNC_IMV, test x$tnc_imv = xtrue)
1201 AM_CONDITIONAL(USE_TNC_TNCCS, test x$tnc_tnccs = xtrue)
1202 AM_CONDITIONAL(USE_TNCCS_11, test x$tnccs_11 = xtrue)
1203 AM_CONDITIONAL(USE_TNCCS_20, test x$tnccs_20 = xtrue)
1204 AM_CONDITIONAL(USE_TNCCS_DYNAMIC, test x$tnccs_dynamic = xtrue)
1205 AM_CONDITIONAL(USE_IMC_TEST, test x$imc_test = xtrue)
1206 AM_CONDITIONAL(USE_IMV_TEST, test x$imv_test = xtrue)
1207 AM_CONDITIONAL(USE_IMC_SCANNER, test x$imc_scanner = xtrue)
1208 AM_CONDITIONAL(USE_IMV_SCANNER, test x$imv_scanner = xtrue)
1209 AM_CONDITIONAL(USE_IMC_OS, test x$imc_os = xtrue)
1210 AM_CONDITIONAL(USE_IMV_OS, test x$imv_os = xtrue)
1211 AM_CONDITIONAL(USE_IMC_ATTESTATION, test x$imc_attestation = xtrue)
1212 AM_CONDITIONAL(USE_IMV_ATTESTATION, test x$imv_attestation = xtrue)
1213 AM_CONDITIONAL(USE_SOCKET_DEFAULT, test x$socket_default = xtrue)
1214 AM_CONDITIONAL(USE_SOCKET_DYNAMIC, test x$socket_dynamic = xtrue)
1215 AM_CONDITIONAL(USE_FARP, test x$farp = xtrue)
1216 AM_CONDITIONAL(USE_ADDRBLOCK, test x$addrblock = xtrue)
1217 AM_CONDITIONAL(USE_UNITY, test x$unity = xtrue)
1218
1219 #  hydra plugins
1220 # ---------------
1221 AM_CONDITIONAL(USE_ATTR, test x$attr = xtrue)
1222 AM_CONDITIONAL(USE_ATTR_SQL, test x$attr_sql = xtrue)
1223 AM_CONDITIONAL(USE_KERNEL_KLIPS, test x$kernel_klips = xtrue)
1224 AM_CONDITIONAL(USE_KERNEL_NETLINK, test x$kernel_netlink = xtrue)
1225 AM_CONDITIONAL(USE_KERNEL_PFKEY, test x$kernel_pfkey = xtrue)
1226 AM_CONDITIONAL(USE_KERNEL_PFROUTE, test x$kernel_pfroute = xtrue)
1227 AM_CONDITIONAL(USE_RESOLVE, test x$resolve = xtrue)
1228
1229 #  other options
1230 # ---------------
1231 AM_CONDITIONAL(USE_LEAK_DETECTIVE, test x$leak_detective = xtrue)
1232 AM_CONDITIONAL(USE_LOCK_PROFILER, test x$lock_profiler = xtrue)
1233 AM_CONDITIONAL(USE_DUMM, test x$dumm = xtrue)
1234 AM_CONDITIONAL(USE_FAST, test x$fast = xtrue)
1235 AM_CONDITIONAL(USE_MANAGER, test x$manager = xtrue)
1236 AM_CONDITIONAL(USE_ME, test x$mediation = xtrue)
1237 AM_CONDITIONAL(USE_INTEGRITY_TEST, test x$integrity_test = xtrue)
1238 AM_CONDITIONAL(USE_LOAD_WARNING, test x$load_warning = xtrue)
1239 AM_CONDITIONAL(USE_IKEV1, test x$ikev1 = xtrue)
1240 AM_CONDITIONAL(USE_IKEV2, test x$ikev2 = xtrue)
1241 AM_CONDITIONAL(USE_THREADS, test x$threads = xtrue)
1242 AM_CONDITIONAL(USE_ADNS, test x$adns = xtrue)
1243 AM_CONDITIONAL(USE_CHARON, test x$charon = xtrue)
1244 AM_CONDITIONAL(USE_NM, test x$nm = xtrue)
1245 AM_CONDITIONAL(USE_TOOLS, test x$tools = xtrue)
1246 AM_CONDITIONAL(USE_SCRIPTS, test x$scripts = xtrue)
1247 AM_CONDITIONAL(USE_CONFTEST, test x$conftest = xtrue)
1248 AM_CONDITIONAL(USE_LIBSTRONGSWAN, test x$charon = xtrue -o x$tools = xtrue -o x$conftest = xtrue -o x$fast = xtrue -o x$imcv = xtrue -o x$nm = xtrue -o x$tkm = xtrue -o x$cmd = xtrue)
1249 AM_CONDITIONAL(USE_LIBHYDRA, test x$charon = xtrue -o x$nm = xtrue -o x$tkm = xtrue -o x$cmd = xtrue)
1250 AM_CONDITIONAL(USE_LIBCHARON, test x$charon = xtrue -o x$conftest = xtrue -o x$nm = xtrue -o x$tkm = xtrue -o x$cmd = xtrue)
1251 AM_CONDITIONAL(USE_LIBIPSEC, test x$libipsec = xtrue)
1252 AM_CONDITIONAL(USE_LIBTNCIF, test x$tnc_tnccs = xtrue -o x$imcv = xtrue)
1253 AM_CONDITIONAL(USE_LIBTNCCS, test x$tnc_tnccs = xtrue)
1254 AM_CONDITIONAL(USE_LIBPTTLS, test x$tnc_tnccs = xtrue)
1255 AM_CONDITIONAL(USE_FILE_CONFIG, test x$stroke = xtrue)
1256 AM_CONDITIONAL(USE_IPSEC_SCRIPT, test x$stroke = xtrue -o x$tools = xtrue -o x$conftest = xtrue)
1257 AM_CONDITIONAL(USE_LIBCAP, test x$capabilities = xlibcap)
1258 AM_CONDITIONAL(USE_VSTR, test x$vstr = xtrue)
1259 AM_CONDITIONAL(USE_SIMAKA, test x$simaka = xtrue)
1260 AM_CONDITIONAL(USE_TLS, test x$tls = xtrue)
1261 AM_CONDITIONAL(USE_RADIUS, test x$radius = xtrue)
1262 AM_CONDITIONAL(USE_IMCV, test x$imcv = xtrue)
1263 AM_CONDITIONAL(USE_PTS, test x$pts = xtrue)
1264 AM_CONDITIONAL(USE_TROUSERS, test x$tss = xtrousers)
1265 AM_CONDITIONAL(MONOLITHIC, test x$monolithic = xtrue)
1266 AM_CONDITIONAL(USE_SILENT_RULES, test x$enable_silent_rules = xyes)
1267 AM_CONDITIONAL(UNITTESTS, test x$unit_tests = xtrue)
1268 AM_CONDITIONAL(COVERAGE, test x$coverage = xtrue)
1269 AM_CONDITIONAL(USE_TKM, test x$tkm = xtrue)
1270 AM_CONDITIONAL(USE_CMD, test x$cmd = xtrue)
1271
1272 # ========================
1273 #  set global definitions
1274 # ========================
1275
1276 if test x$mediation = xtrue; then
1277         AC_DEFINE([ME], [], [mediation extension support])
1278 fi
1279 if test x$capabilities = xlibcap -o x$capabilities = xnative; then
1280         AC_DEFINE([CAPABILITIES], [], [capability dropping support])
1281 fi
1282 if test x$monolithic = xtrue; then
1283         AC_DEFINE([MONOLITHIC], [], [monolithic build embedding plugins])
1284 fi
1285 if test x$ikev1 = xtrue; then
1286         AC_DEFINE([USE_IKEV1], [], [support for IKEv1 protocol])
1287 fi
1288 if test x$ikev2 = xtrue; then
1289         AC_DEFINE([USE_IKEV2], [], [support for IKEv2 protocol])
1290 fi
1291
1292 # =================
1293 #  build Makefiles
1294 # =================
1295
1296 AC_CONFIG_FILES([
1297         Makefile
1298         man/Makefile
1299         init/Makefile
1300         init/systemd/Makefile
1301         src/Makefile
1302         src/include/Makefile
1303         src/libstrongswan/Makefile
1304         src/libstrongswan/plugins/aes/Makefile
1305         src/libstrongswan/plugins/cmac/Makefile
1306         src/libstrongswan/plugins/des/Makefile
1307         src/libstrongswan/plugins/blowfish/Makefile
1308         src/libstrongswan/plugins/rc2/Makefile
1309         src/libstrongswan/plugins/md4/Makefile
1310         src/libstrongswan/plugins/md5/Makefile
1311         src/libstrongswan/plugins/sha1/Makefile
1312         src/libstrongswan/plugins/sha2/Makefile
1313         src/libstrongswan/plugins/fips_prf/Makefile
1314         src/libstrongswan/plugins/gmp/Makefile
1315         src/libstrongswan/plugins/rdrand/Makefile
1316         src/libstrongswan/plugins/random/Makefile
1317         src/libstrongswan/plugins/nonce/Makefile
1318         src/libstrongswan/plugins/hmac/Makefile
1319         src/libstrongswan/plugins/xcbc/Makefile
1320         src/libstrongswan/plugins/x509/Makefile
1321         src/libstrongswan/plugins/revocation/Makefile
1322         src/libstrongswan/plugins/constraints/Makefile
1323         src/libstrongswan/plugins/pubkey/Makefile
1324         src/libstrongswan/plugins/pkcs1/Makefile
1325         src/libstrongswan/plugins/pkcs7/Makefile
1326         src/libstrongswan/plugins/pkcs8/Makefile
1327         src/libstrongswan/plugins/pkcs12/Makefile
1328         src/libstrongswan/plugins/pgp/Makefile
1329         src/libstrongswan/plugins/dnskey/Makefile
1330         src/libstrongswan/plugins/sshkey/Makefile
1331         src/libstrongswan/plugins/pem/Makefile
1332         src/libstrongswan/plugins/curl/Makefile
1333         src/libstrongswan/plugins/unbound/Makefile
1334         src/libstrongswan/plugins/soup/Makefile
1335         src/libstrongswan/plugins/ldap/Makefile
1336         src/libstrongswan/plugins/mysql/Makefile
1337         src/libstrongswan/plugins/sqlite/Makefile
1338         src/libstrongswan/plugins/padlock/Makefile
1339         src/libstrongswan/plugins/openssl/Makefile
1340         src/libstrongswan/plugins/gcrypt/Makefile
1341         src/libstrongswan/plugins/agent/Makefile
1342         src/libstrongswan/plugins/pkcs11/Makefile
1343         src/libstrongswan/plugins/ctr/Makefile
1344         src/libstrongswan/plugins/ccm/Makefile
1345         src/libstrongswan/plugins/gcm/Makefile
1346         src/libstrongswan/plugins/af_alg/Makefile
1347         src/libstrongswan/plugins/test_vectors/Makefile
1348         src/libstrongswan/tests/Makefile
1349         src/libhydra/Makefile
1350         src/libhydra/plugins/attr/Makefile
1351         src/libhydra/plugins/attr_sql/Makefile
1352         src/libhydra/plugins/kernel_klips/Makefile
1353         src/libhydra/plugins/kernel_netlink/Makefile
1354         src/libhydra/plugins/kernel_pfkey/Makefile
1355         src/libhydra/plugins/kernel_pfroute/Makefile
1356         src/libhydra/plugins/resolve/Makefile
1357         src/libipsec/Makefile
1358         src/libsimaka/Makefile
1359         src/libtls/Makefile
1360         src/libradius/Makefile
1361         src/libtncif/Makefile
1362         src/libtnccs/Makefile
1363         src/libpttls/Makefile
1364         src/libpts/Makefile
1365         src/libpts/plugins/imc_attestation/Makefile
1366         src/libpts/plugins/imv_attestation/Makefile
1367         src/libimcv/Makefile
1368         src/libimcv/plugins/imc_test/Makefile
1369         src/libimcv/plugins/imv_test/Makefile
1370         src/libimcv/plugins/imc_scanner/Makefile
1371         src/libimcv/plugins/imv_scanner/Makefile
1372         src/libimcv/plugins/imc_os/Makefile
1373         src/libimcv/plugins/imv_os/Makefile
1374         src/charon/Makefile
1375         src/charon-nm/Makefile
1376         src/charon-tkm/Makefile
1377         src/charon-cmd/Makefile
1378         src/libcharon/Makefile
1379         src/libcharon/plugins/eap_aka/Makefile
1380         src/libcharon/plugins/eap_aka_3gpp2/Makefile
1381         src/libcharon/plugins/eap_dynamic/Makefile
1382         src/libcharon/plugins/eap_identity/Makefile
1383         src/libcharon/plugins/eap_md5/Makefile
1384         src/libcharon/plugins/eap_gtc/Makefile
1385         src/libcharon/plugins/eap_sim/Makefile
1386         src/libcharon/plugins/eap_sim_file/Makefile
1387         src/libcharon/plugins/eap_sim_pcsc/Makefile
1388         src/libcharon/plugins/eap_simaka_sql/Makefile
1389         src/libcharon/plugins/eap_simaka_pseudonym/Makefile
1390         src/libcharon/plugins/eap_simaka_reauth/Makefile
1391         src/libcharon/plugins/eap_mschapv2/Makefile
1392         src/libcharon/plugins/eap_tls/Makefile
1393         src/libcharon/plugins/eap_ttls/Makefile
1394         src/libcharon/plugins/eap_peap/Makefile
1395         src/libcharon/plugins/eap_tnc/Makefile
1396         src/libcharon/plugins/eap_radius/Makefile
1397         src/libcharon/plugins/xauth_generic/Makefile
1398         src/libcharon/plugins/xauth_eap/Makefile
1399         src/libcharon/plugins/xauth_pam/Makefile
1400         src/libcharon/plugins/xauth_noauth/Makefile
1401         src/libcharon/plugins/tnc_ifmap/Makefile
1402         src/libcharon/plugins/tnc_pdp/Makefile
1403         src/libcharon/plugins/tnc_imc/Makefile
1404         src/libcharon/plugins/tnc_imv/Makefile
1405         src/libcharon/plugins/tnc_tnccs/Makefile
1406         src/libcharon/plugins/tnccs_11/Makefile
1407         src/libcharon/plugins/tnccs_20/Makefile
1408         src/libcharon/plugins/tnccs_dynamic/Makefile
1409         src/libcharon/plugins/socket_default/Makefile
1410         src/libcharon/plugins/socket_dynamic/Makefile
1411         src/libcharon/plugins/farp/Makefile
1412         src/libcharon/plugins/smp/Makefile
1413         src/libcharon/plugins/sql/Makefile
1414         src/libcharon/plugins/ipseckey/Makefile
1415         src/libcharon/plugins/medsrv/Makefile
1416         src/libcharon/plugins/medcli/Makefile
1417         src/libcharon/plugins/addrblock/Makefile
1418         src/libcharon/plugins/unity/Makefile
1419         src/libcharon/plugins/uci/Makefile
1420         src/libcharon/plugins/ha/Makefile
1421         src/libcharon/plugins/whitelist/Makefile
1422         src/libcharon/plugins/lookip/Makefile
1423         src/libcharon/plugins/error_notify/Makefile
1424         src/libcharon/plugins/certexpire/Makefile
1425         src/libcharon/plugins/systime_fix/Makefile
1426         src/libcharon/plugins/led/Makefile
1427         src/libcharon/plugins/duplicheck/Makefile
1428         src/libcharon/plugins/coupling/Makefile
1429         src/libcharon/plugins/radattr/Makefile
1430         src/libcharon/plugins/android_dns/Makefile
1431         src/libcharon/plugins/android_log/Makefile
1432         src/libcharon/plugins/maemo/Makefile
1433         src/libcharon/plugins/stroke/Makefile
1434         src/libcharon/plugins/updown/Makefile
1435         src/libcharon/plugins/dhcp/Makefile
1436         src/libcharon/plugins/unit_tester/Makefile
1437         src/libcharon/plugins/load_tester/Makefile
1438         src/stroke/Makefile
1439         src/ipsec/Makefile
1440         src/starter/Makefile
1441         src/_updown/Makefile
1442         src/_updown_espmark/Makefile
1443         src/_copyright/Makefile
1444         src/openac/Makefile
1445         src/scepclient/Makefile
1446         src/pki/Makefile
1447         src/dumm/Makefile
1448         src/dumm/ext/extconf.rb
1449         src/libfast/Makefile
1450         src/manager/Makefile
1451         src/medsrv/Makefile
1452         src/checksum/Makefile
1453         src/conftest/Makefile
1454         scripts/Makefile
1455         testing/Makefile
1456 ])
1457 AC_OUTPUT
1458
1459 # ========================
1460 #  report enabled plugins
1461 # ========================
1462
1463 AC_MSG_RESULT([])
1464 AC_MSG_RESULT([ strongSwan will be built with the following plugins])
1465 AC_MSG_RESULT([-----------------------------------------------------])
1466
1467 AC_MSG_RESULT([libstrongswan:$s_plugins])
1468 AC_MSG_RESULT([libcharon:    $c_plugins])
1469 AC_MSG_RESULT([libhydra:     $h_plugins])
1470 AC_MSG_RESULT([])