Added unbound plugin implementing the resolver interface using libunbound
[strongswan.git] / configure.in
1 #
2 # Copyright (C) 2007-2013 Tobias Brunner
3 # Copyright (C) 2006-2013 Andreas Steffen
4 # Copyright (C) 2006-2013 Martin Willi
5 # Hochschule fuer Technik Rapperswil
6 #
7 # This program is free software; you can redistribute it and/or modify it
8 # under the terms of the GNU General Public License as published by the
9 # Free Software Foundation; either version 2 of the License, or (at your
10 # option) any later version.  See <http://www.fsf.org/copyleft/gpl.txt>.
11 #
12 # This program is distributed in the hope that it will be useful, but
13 # WITHOUT ANY WARRANTY; without even the implied warranty of MERCHANTABILITY
14 # or FITNESS FOR A PARTICULAR PURPOSE.  See the GNU General Public License
15 # for more details.
16 #
17
18 # ============================
19 #  initialize & set some vars
20 # ============================
21
22 AC_INIT([strongSwan],[5.0.3dr1])
23 AM_INIT_AUTOMAKE(tar-ustar)
24 AC_CONFIG_MACRO_DIR([m4/config])
25 AC_CONFIG_HEADERS([config.h])
26 AC_DEFINE([CONFIG_H_INCLUDED], [], [defined if config.h included])
27 PKG_PROG_PKG_CONFIG
28
29 # =================================
30 #  check --enable-xxx & --with-xxx
31 # =================================
32
33 m4_include(m4/macros/with.m4)
34
35 ARG_WITH_SUBST([random-device],      [/dev/random], [set the device to read real random data from])
36 ARG_WITH_SUBST([urandom-device],     [/dev/urandom], [set the device to read pseudo random data from])
37 ARG_WITH_SUBST([strongswan-conf],    [${sysconfdir}/strongswan.conf], [set the strongswan.conf file location])
38 ARG_WITH_SUBST([resolv-conf],        [${sysconfdir}/resolv.conf], [set the file to use in DNS handler plugin])
39 ARG_WITH_SUBST([piddir],             [/var/run], [set path for PID and UNIX socket files])
40 ARG_WITH_SUBST([ipsecdir],           [${libexecdir%/}/ipsec], [set installation path for ipsec tools])
41 ARG_WITH_SUBST([ipseclibdir],        [${libdir%/}/ipsec], [set installation path for ipsec libraries])
42 ARG_WITH_SUBST([plugindir],          [${ipseclibdir%/}/plugins], [set the installation path of plugins])
43 ARG_WITH_SUBST([imcvdir],            [${ipseclibdir%/}/imcvs], [set the installation path of IMC and IMV dynamic librariers])
44 ARG_WITH_SUBST([nm-ca-dir],          [/usr/share/ca-certificates], [directory the NM backend uses to look up trusted root certificates])
45 ARG_WITH_SUBST([linux-headers],      [\${top_srcdir}/src/include], [set directory of linux header files to use])
46 ARG_WITH_SUBST([routing-table],      [220], [set routing table to use for IPsec routes])
47 ARG_WITH_SUBST([routing-table-prio], [220], [set priority for IPsec routing table])
48 ARG_WITH_SUBST([ipsec-script],       [ipsec], [change the name of the ipsec script])
49
50 ARG_WITH_SET([tss],                  [no], [set implementation of the Trusted Computing Group's Software Stack (TSS). Currently the only supported value is "trousers"])
51 ARG_WITH_SET([capabilities],         [no], [set capability dropping library. Currently supported values are "libcap" and "native"])
52 ARG_WITH_SET([mpz_powm_sec],         [yes], [use the more side-channel resistant mpz_powm_sec in libgmp, if available])
53 ARG_WITH_SET([dev-headers],          [no], [install strongSwan development headers to directory.])
54
55 if test -n "$PKG_CONFIG"; then
56         systemdsystemunitdir_default=$($PKG_CONFIG --variable=systemdsystemunitdir systemd)
57 fi
58 ARG_WITH_SET([systemdsystemunitdir], [$systemdsystemunitdir_default], [directory for systemd service files])
59 AM_CONDITIONAL(HAVE_SYSTEMD, [test -n "$systemdsystemunitdir" -a "x$systemdsystemunitdir" != xno])
60 AC_SUBST(systemdsystemunitdir)
61
62 AC_ARG_WITH(
63         [user],
64         AS_HELP_STRING([--with-user=user],[change user of the daemons to "user" after startup (default is "root").]),
65         [AC_DEFINE_UNQUOTED([IPSEC_USER], "$withval", [username to run daemon with])
66          AC_SUBST(ipsecuser, "$withval")],
67         [AC_SUBST(ipsecuser, "root")]
68 )
69
70 AC_ARG_WITH(
71         [group],
72         AS_HELP_STRING([--with-group=group],[change group of the daemons to "group" after startup (default is "root").]),
73         [AC_DEFINE_UNQUOTED(IPSEC_GROUP, "$withval", [groupname to run daemon with])
74          AC_SUBST(ipsecgroup, "$withval")],
75         [AC_SUBST(ipsecgroup, "root")]
76 )
77
78 AC_ARG_WITH(
79         [charon-udp-port],
80         AS_HELP_STRING([--with-charon-udp-port=port],[UDP port used by charon locally (default 500). Set to 0 to allocate randomly.]),
81         [AC_DEFINE_UNQUOTED(CHARON_UDP_PORT, [$withval], [UDP port used by charon locally])
82          AC_SUBST(charon_udp_port, [$withval])],
83         [AC_SUBST(charon_udp_port, 500)]
84 )
85
86 AC_ARG_WITH(
87         [charon-natt-port],
88         AS_HELP_STRING([--with-charon-natt-port=port],[UDP port used by charon locally in case a NAT is detected (must be different from charon-udp-port, default 4500). Set to 0 to allocate randomly.]),
89         [AC_DEFINE_UNQUOTED(CHARON_NATT_PORT, [$withval], [UDP post used by charon locally in case a NAT is detected])
90          AC_SUBST(charon_natt_port, [$withval])],
91         [AC_SUBST(charon_natt_port, 4500)]
92 )
93
94 AC_MSG_CHECKING([configured UDP ports ($charon_udp_port, $charon_natt_port)])
95 if test x$charon_udp_port != x0 -a x$charon_udp_port = x$charon_natt_port; then
96         AC_MSG_ERROR(the ports have to be different)
97 else
98         AC_MSG_RESULT(ok)
99 fi
100
101 # convert script name to uppercase
102 AC_SUBST(ipsec_script_upper, [`echo -n "$ipsec_script" | tr a-z A-Z`])
103
104 m4_include(m4/macros/enable-disable.m4)
105
106 ARG_ENABL_SET([curl],           [enable CURL fetcher plugin to fetch files via libcurl. Requires libcurl.])
107 ARG_ENABL_SET([unbound],        [enable UNBOUND resolver plugin to perform DNS queries via libunbound. Requires libldns and libunbound.])
108 ARG_ENABL_SET([soup],           [enable soup fetcher plugin to fetch from HTTP via libsoup. Requires libsoup.])
109 ARG_ENABL_SET([ldap],           [enable LDAP fetching plugin to fetch files via libldap. Requires openLDAP.])
110 ARG_DISBL_SET([aes],            [disable AES software implementation plugin.])
111 ARG_DISBL_SET([des],            [disable DES/3DES software implementation plugin.])
112 ARG_ENABL_SET([blowfish],       [enable Blowfish software implementation plugin.])
113 ARG_ENABL_SET([md4],            [enable MD4 software implementation plugin.])
114 ARG_DISBL_SET([md5],            [disable MD5 software implementation plugin.])
115 ARG_DISBL_SET([sha1],           [disable SHA1 software implementation plugin.])
116 ARG_DISBL_SET([sha2],           [disable SHA256/SHA384/SHA512 software implementation plugin.])
117 ARG_DISBL_SET([fips-prf],       [disable FIPS PRF software implementation plugin.])
118 ARG_DISBL_SET([gmp],            [disable GNU MP (libgmp) based crypto implementation plugin.])
119 ARG_ENABL_SET([rdrand],         [enable Intel RDRAND random generator plugin.])
120 ARG_DISBL_SET([random],         [disable RNG implementation on top of /dev/(u)random.])
121 ARG_DISBL_SET([nonce],          [disable nonce generation plugin.])
122 ARG_DISBL_SET([x509],           [disable X509 certificate implementation plugin.])
123 ARG_DISBL_SET([revocation],     [disable X509 CRL/OCSP revocation check plugin.])
124 ARG_DISBL_SET([constraints],    [disable advanced X509 constraint checking plugin.])
125 ARG_DISBL_SET([pubkey],         [disable RAW public key support plugin.])
126 ARG_DISBL_SET([pkcs1],          [disable PKCS1 key decoding plugin.])
127 ARG_DISBL_SET([pkcs7],          [disable PKCS7 container support plugin.])
128 ARG_DISBL_SET([pkcs8],          [disable PKCS8 private key decoding plugin.])
129 ARG_DISBL_SET([pgp],            [disable PGP key decoding plugin.])
130 ARG_DISBL_SET([dnskey],         [disable DNS RR key decoding plugin.])
131 ARG_DISBL_SET([pem],            [disable PEM decoding plugin.])
132 ARG_DISBL_SET([hmac],           [disable HMAC crypto implementation plugin.])
133 ARG_DISBL_SET([cmac],           [disable CMAC crypto implementation plugin.])
134 ARG_DISBL_SET([xcbc],           [disable xcbc crypto implementation plugin.])
135 ARG_ENABL_SET([af-alg],         [enable AF_ALG crypto interface to Linux Crypto API.])
136 ARG_ENABL_SET([test-vectors],   [enable plugin providing crypto test vectors.])
137 ARG_ENABL_SET([mysql],          [enable MySQL database support. Requires libmysqlclient_r.])
138 ARG_ENABL_SET([sqlite],         [enable SQLite database support. Requires libsqlite3.])
139 ARG_DISBL_SET([stroke],         [disable charons stroke configuration backend.])
140 ARG_ENABL_SET([medsrv],         [enable mediation server web frontend and daemon plugin.])
141 ARG_ENABL_SET([medcli],         [enable mediation client configuration database plugin.])
142 ARG_ENABL_SET([smp],            [enable SMP configuration and control interface. Requires libxml.])
143 ARG_ENABL_SET([sql],            [enable SQL database configuration backend.])
144 ARG_ENABL_SET([leak-detective], [enable malloc hooks to find memory leaks.])
145 ARG_ENABL_SET([lock-profiler],  [enable lock/mutex profiling code.])
146 ARG_ENABL_SET([unit-tester],    [enable unit tests on IKEv2 daemon startup.])
147 ARG_ENABL_SET([load-tester],    [enable load testing plugin for IKEv2 daemon.])
148 ARG_ENABL_SET([eap-sim],        [enable SIM authentication module for EAP.])
149 ARG_ENABL_SET([eap-sim-file],   [enable EAP-SIM backend based on a triplet file.])
150 ARG_ENABL_SET([eap-sim-pcsc],   [enable EAP-SIM backend based on a smartcard reader. Requires libpcsclite.])
151 ARG_ENABL_SET([eap-aka],        [enable EAP AKA authentication module.])
152 ARG_ENABL_SET([eap-aka-3gpp2],  [enable EAP AKA backend implementing 3GPP2 algorithms in software. Requires libgmp.])
153 ARG_ENABL_SET([eap-simaka-sql], [enable EAP-SIM/AKA backend based on a triplet/quintuplet SQL database.])
154 ARG_ENABL_SET([eap-simaka-pseudonym], [enable EAP-SIM/AKA pseudonym storage plugin.])
155 ARG_ENABL_SET([eap-simaka-reauth],    [enable EAP-SIM/AKA reauthentication data storage plugin.])
156 ARG_ENABL_SET([eap-identity],   [enable EAP module providing EAP-Identity helper.])
157 ARG_ENABL_SET([eap-md5],        [enable EAP MD5 (CHAP) authentication module.])
158 ARG_ENABL_SET([eap-gtc],        [enable EAP GTC authentication module.])
159 ARG_ENABL_SET([eap-mschapv2],   [enable EAP MS-CHAPv2 authentication module.])
160 ARG_ENABL_SET([eap-tls],        [enable EAP TLS authentication module.])
161 ARG_ENABL_SET([eap-ttls],       [enable EAP TTLS authentication module.])
162 ARG_ENABL_SET([eap-peap],       [enable EAP PEAP authentication module.])
163 ARG_ENABL_SET([eap-tnc],        [enable EAP TNC trusted network connect module.])
164 ARG_ENABL_SET([eap-dynamic],    [enable dynamic EAP proxy module.])
165 ARG_ENABL_SET([eap-radius],     [enable RADIUS proxy authentication module.])
166 ARG_DISBL_SET([xauth-generic],  [disable generic XAuth backend.])
167 ARG_ENABL_SET([xauth-eap],      [enable XAuth backend using EAP methods to verify passwords.])
168 ARG_ENABL_SET([xauth-pam],      [enable XAuth backend using PAM to verify passwords.])
169 ARG_ENABL_SET([tnc-ifmap],      [enable TNC IF-MAP module.])
170 ARG_ENABL_SET([tnc-pdp],        [enable TNC policy decision point module.])
171 ARG_ENABL_SET([tnc-imc],        [enable TNC IMC module.])
172 ARG_ENABL_SET([tnc-imv],        [enable TNC IMV module.])
173 ARG_ENABL_SET([tnccs-11],       [enable TNCCS 1.1 protocol module.])
174 ARG_ENABL_SET([tnccs-20],       [enable TNCCS 2.0 protocol module.])
175 ARG_ENABL_SET([tnccs-dynamic],  [enable dynamic TNCCS protocol discovery module.])
176 ARG_ENABL_SET([imc-test],       [enable IMC test module.])
177 ARG_ENABL_SET([imv-test],       [enable IMV test module.])
178 ARG_ENABL_SET([imc-scanner],    [enable IMC port scanner module.])
179 ARG_ENABL_SET([imv-scanner],    [enable IMV port scanner module.])
180 ARG_ENABL_SET([imc-os],         [enable IMC operating system module.])
181 ARG_ENABL_SET([imv-os],         [enable IMV operating system module.])
182 ARG_ENABL_SET([imc-attestation],[enable IMC attestation module.])
183 ARG_ENABL_SET([imv-attestation],[enable IMV attestation module.])
184 ARG_DISBL_SET([kernel-netlink], [disable the netlink kernel interface.])
185 ARG_ENABL_SET([kernel-pfkey],   [enable the PF_KEY kernel interface.])
186 ARG_ENABL_SET([kernel-pfroute], [enable the PF_ROUTE kernel interface.])
187 ARG_ENABL_SET([kernel-klips],   [enable the KLIPS kernel interface.])
188 ARG_ENABL_SET([libipsec],       [enable user space IPsec implementation.])
189 ARG_DISBL_SET([socket-default], [disable default socket implementation for charon.])
190 ARG_ENABL_SET([socket-dynamic], [enable dynamic socket implementation for charon])
191 ARG_ENABL_SET([farp],           [enable ARP faking plugin that responds to ARP requests to peers virtual IP])
192 ARG_ENABL_SET([dumm],           [enable the DUMM UML test framework.])
193 ARG_ENABL_SET([fast],           [enable libfast (FastCGI Application Server w/ templates.])
194 ARG_ENABL_SET([manager],        [enable web management console (proof of concept).])
195 ARG_ENABL_SET([mediation],      [enable IKEv2 Mediation Extension.])
196 ARG_ENABL_SET([integrity-test], [enable integrity testing of libstrongswan and plugins.])
197 ARG_DISBL_SET([load-warning],   [disable the charon plugin load option warning in starter.])
198 ARG_DISBL_SET([ikev1],          [disable IKEv1 protocol support in charon.])
199 ARG_DISBL_SET([ikev2],          [disable IKEv2 protocol support in charon.])
200 ARG_DISBL_SET([charon],         [disable the IKEv1/IKEv2 keying daemon charon.])
201 ARG_DISBL_SET([tools],          [disable additional utilities (openac, scepclient and pki).])
202 ARG_DISBL_SET([scripts],        [disable additional utilities (found in directory scripts).])
203 ARG_ENABL_SET([conftest],       [enforce Suite B conformance test framework.])
204 ARG_DISBL_SET([updown],         [disable updown firewall script plugin.])
205 ARG_DISBL_SET([attr],           [disable strongswan.conf based configuration attribute plugin.])
206 ARG_ENABL_SET([attr-sql],       [enable SQL based configuration attribute plugin.])
207 ARG_ENABL_SET([dhcp],           [enable DHCP based attribute provider plugin.])
208 ARG_DISBL_SET([resolve],        [disable resolve DNS handler plugin.])
209 ARG_ENABL_SET([padlock],        [enables VIA Padlock crypto plugin.])
210 ARG_ENABL_SET([openssl],        [enables the OpenSSL crypto plugin.])
211 ARG_ENABL_SET([gcrypt],         [enables the libgcrypt plugin.])
212 ARG_ENABL_SET([agent],          [enables the ssh-agent signing plugin.])
213 ARG_ENABL_SET([pkcs11],         [enables the PKCS11 token support plugin.])
214 ARG_ENABL_SET([ctr],            [enables the Counter Mode wrapper crypto plugin.])
215 ARG_ENABL_SET([ccm],            [enables the CCM AEAD wrapper crypto plugin.])
216 ARG_ENABL_SET([gcm],            [enables the GCM AEAD wrapper crypto plugin.])
217 ARG_ENABL_SET([addrblock],      [enables RFC 3779 address block constraint support.])
218 ARG_ENABL_SET([unity],          [enables Cisco Unity extension plugin.])
219 ARG_ENABL_SET([uci],            [enable OpenWRT UCI configuration plugin.])
220 ARG_ENABL_SET([android],        [enable Android specific plugin.])
221 ARG_ENABL_SET([android-log],    [enable Android specific logger plugin.])
222 ARG_ENABL_SET([maemo],          [enable Maemo specific plugin.])
223 ARG_ENABL_SET([nm],             [enable NetworkManager backend.])
224 ARG_ENABL_SET([ha],             [enable high availability cluster plugin.])
225 ARG_ENABL_SET([whitelist],      [enable peer identity whitelisting plugin.])
226 ARG_ENABL_SET([lookip],         [enable fast virtual IP lookup and notification plugin.])
227 ARG_ENABL_SET([error-notify],   [enable error notification plugin.])
228 ARG_ENABL_SET([certexpire],     [enable CSV export of expiration dates of used certificates.])
229 ARG_ENABL_SET([led],            [enable plugin to control LEDs on IKEv2 activity using the Linux kernel LED subsystem.])
230 ARG_ENABL_SET([duplicheck],     [advanced duplicate checking plugin using liveness checks.])
231 ARG_ENABL_SET([coupling],       [enable IKEv2 plugin to couple peer certificates permanently to authentication.])
232 ARG_ENABL_SET([radattr],        [enable plugin to inject and process custom RADIUS attributes as IKEv2 client.])
233 ARG_ENABL_SET([vstr],           [enforce using the Vstr string library to replace glibc-like printf hooks.])
234 ARG_ENABL_SET([monolithic],     [build monolithic version of libstrongswan that includes all enabled plugins. Similarly, the plugins of charon are assembled in libcharon.])
235 ARG_ENABL_SET([bfd-backtraces], [use binutils libbfd to resolve backtraces for memory leaks and segfaults.])
236
237 # ===================================
238 #  option to disable default options
239 # ===================================
240
241 ARG_DISBL_SET([defaults],       [disable all default plugins (they can be enabled with their respective --enable options)])
242
243 if test x$defaults = xfalse; then
244         for option in $enabled_by_default; do
245                 eval test x\${${option}_given} = xtrue && continue
246                 let $option=false
247         done
248 fi
249
250 # ===========================
251 #  set up compiler and flags
252 # ===========================
253
254 if test -z "$CFLAGS"; then
255         CFLAGS="-g -O2 -Wall -Wno-format -Wno-pointer-sign"
256 fi
257 AC_PROG_CC
258 AC_LIB_PREFIX
259 AC_C_BIGENDIAN
260
261 # =========================
262 #  check required programs
263 # =========================
264
265 LT_INIT
266 AC_PROG_INSTALL
267 AC_PROG_EGREP
268 AC_PROG_AWK
269 AC_PROG_LEX
270 AC_PROG_YACC
271 AC_PATH_PROG([PERL], [perl], [], [$PATH:/bin:/usr/bin:/usr/local/bin])
272 AC_PATH_PROG([GPERF], [gperf], [], [$PATH:/bin:/usr/bin:/usr/local/bin])
273
274 # because gperf is not needed by end-users we just report it but do not abort on failure
275 AC_MSG_CHECKING([gperf version >= 3.0.0])
276 if test -x "$GPERF"; then
277         if test "`$GPERF --version | $AWK -F' ' '/^GNU gperf/ { print $3 }' | $AWK -F. '{ print $1 }'`" -ge "3"; then
278                 AC_MSG_RESULT([yes])
279         else
280                 AC_MSG_RESULT([no])
281         fi
282 else
283         AC_MSG_RESULT([not found])
284 fi
285
286 # ========================
287 #  dependency calculation
288 # ========================
289
290 if test x$xauth_generic_given = xfalse -a x$ikev1 = xfalse; then
291         xauth_generic=false;
292 fi
293
294 if test x$eap_aka_3gpp2 = xtrue; then
295         gmp=true;
296 fi
297
298 if test x$eap_aka = xtrue; then
299         fips_prf=true;
300         simaka=true;
301 fi
302
303 if test x$eap_sim = xtrue; then
304         fips_prf=true;
305         simaka=true;
306 fi
307
308 if test x$eap_tls = xtrue -o x$eap_ttls = xtrue -o x$eap_peap = xtrue; then
309         tls=true;
310 fi
311
312 if test x$eap_radius = xtrue -o x$radattr = xtrue -o x$tnc_pdp = xtrue; then
313         radius=true;
314 fi
315
316 if test x$tnc_imc = xtrue -o x$tnc_imv = xtrue -o x$tnccs_11 = xtrue -o x$tnccs_11 = xtrue -o x$tnccs_dynamic = xtrue -o x$eap_tnc = xtrue; then
317         tnc_tnccs=true;
318 fi
319
320 if test x$imc_test = xtrue -o x$imv_test = xtrue -o x$imc_scanner = xtrue -o x$imv_scanner = xtrue -o x$imc_os = xtrue -o x$imv_os = xtrue -o x$imc_attestation = xtrue -o x$imv_attestation = xtrue; then
321         imcv=true;
322 fi
323
324 if test x$imc_attestation = xtrue -o x$imv_attestation = xtrue; then
325         pts=true;
326 fi
327
328 if test x$fips_prf = xtrue; then
329         if test x$openssl = xfalse; then
330                 sha1=true;
331         fi
332 fi
333
334 if test x$smp = xtrue -o x$tnccs_11 = xtrue; then
335         xml=true
336 fi
337
338 if test x$tnc_ifmap = xtrue; then
339         axis2c=true
340 fi
341
342 if test x$manager = xtrue; then
343         fast=true
344 fi
345
346 if test x$medsrv = xtrue; then
347         mediation=true
348         fast=true
349 fi
350
351 if test x$medcli = xtrue; then
352         mediation=true
353 fi
354
355 # ===========================================
356 #  check required libraries and header files
357 # ===========================================
358
359 AC_HEADER_STDBOOL
360 AC_FUNC_ALLOCA
361 AC_FUNC_STRERROR_R
362
363 #  libraries needed on some platforms but not on others
364 # ------------------------------------------------------
365 saved_LIBS=$LIBS
366
367 # FreeBSD and Mac OS X have dlopen integrated in libc, Linux needs libdl
368 LIBS=""
369 AC_SEARCH_LIBS(dlopen, dl, [DLLIB=$LIBS])
370 AC_SUBST(DLLIB)
371
372 # glibc's backtrace() can be replicated on FreeBSD with libexecinfo
373 LIBS=""
374 AC_SEARCH_LIBS(backtrace, execinfo, [BTLIB=$LIBS])
375 AC_CHECK_FUNCS(backtrace)
376 AC_SUBST(BTLIB)
377
378 # OpenSolaris needs libsocket and libnsl for socket()
379 LIBS=""
380 AC_SEARCH_LIBS(socket, socket, [SOCKLIB=$LIBS],
381         [AC_CHECK_LIB(nsl, socket, [SOCKLIB="-lsocket -lnsl"], [], [-lsocket])]
382 )
383 AC_SUBST(SOCKLIB)
384
385 # FreeBSD has clock_gettime in libc, Linux needs librt
386 LIBS=""
387 AC_SEARCH_LIBS(clock_gettime, rt, [RTLIB=$LIBS])
388 AC_CHECK_FUNCS(clock_gettime)
389 AC_SUBST(RTLIB)
390
391 # Android has pthread_* functions in bionic (libc), others need libpthread
392 LIBS=""
393 AC_SEARCH_LIBS(pthread_create, pthread, [PTHREADLIB=$LIBS])
394 AC_SUBST(PTHREADLIB)
395
396 LIBS=$saved_LIBS
397 # ------------------------------------------------------
398
399 AC_MSG_CHECKING(for dladdr)
400 AC_COMPILE_IFELSE(
401         [AC_LANG_PROGRAM(
402                 [[#define _GNU_SOURCE
403                   #include <dlfcn.h>]],
404                 [[Dl_info* info = 0;
405                   dladdr(0, info);]])],
406         [AC_MSG_RESULT([yes]); AC_DEFINE([HAVE_DLADDR], [], [have dladdr()])],
407         [AC_MSG_RESULT([no])]
408 )
409
410 # check if pthread_condattr_setclock(CLOCK_MONOTONE) is supported
411 saved_LIBS=$LIBS
412 LIBS=$PTHREADLIB
413 AC_MSG_CHECKING([for pthread_condattr_setclock(CLOCK_MONOTONE)])
414 AC_RUN_IFELSE(
415         [AC_LANG_SOURCE(
416                 [[#include <pthread.h>
417                   int main() { pthread_condattr_t attr;
418                         pthread_condattr_init(&attr);
419                         return pthread_condattr_setclock(&attr, CLOCK_MONOTONIC);}]])],
420         [AC_MSG_RESULT([yes]);
421          AC_DEFINE([HAVE_CONDATTR_CLOCK_MONOTONIC], [],
422                            [pthread_condattr_setclock supports CLOCK_MONOTONIC])],
423         [AC_MSG_RESULT([no])],
424         # Check existence of pthread_condattr_setclock if cross-compiling
425         [AC_MSG_RESULT([unknown]);
426          AC_CHECK_FUNCS(pthread_condattr_setclock,
427                 [AC_DEFINE([HAVE_CONDATTR_CLOCK_MONOTONIC], [],
428                                    [have pthread_condattr_setclock()])]
429         )]
430 )
431 # check if we actually are able to configure attributes on cond vars
432 AC_CHECK_FUNCS(pthread_condattr_init)
433 # instead of pthread_condattr_setclock Android has this function
434 AC_CHECK_FUNCS(pthread_cond_timedwait_monotonic)
435 # check if we can cancel threads
436 AC_CHECK_FUNCS(pthread_cancel)
437 # check if native rwlocks are available
438 AC_CHECK_FUNCS(pthread_rwlock_init)
439 # check if pthread spinlocks are available
440 AC_CHECK_FUNCS(pthread_spin_init)
441 # check if we have POSIX semaphore functions, including timed-wait
442 AC_CHECK_FUNCS(sem_timedwait)
443 LIBS=$saved_LIBS
444
445 AC_CHECK_FUNC(
446         [gettid],
447         [AC_DEFINE([HAVE_GETTID], [], [have gettid()])],
448         [AC_MSG_CHECKING([for SYS_gettid])
449          AC_COMPILE_IFELSE(
450                 [AC_LANG_PROGRAM(
451                         [[#define _GNU_SOURCE
452                           #include <unistd.h>
453                           #include <sys/syscall.h>]],
454                         [[int main() {
455                           return syscall(SYS_gettid);}]])],
456                 [AC_MSG_RESULT([yes]);
457                  AC_DEFINE([HAVE_GETTID], [], [have gettid()])
458                  AC_DEFINE([HAVE_SYS_GETTID], [], [have syscall(SYS_gettid)])],
459                 [AC_MSG_RESULT([no])]
460         )]
461 )
462
463 AC_CHECK_FUNCS(prctl mallinfo getpass closefrom getpwnam_r getgrnam_r)
464
465 AC_CHECK_HEADERS(sys/sockio.h glob.h)
466 AC_CHECK_HEADERS(net/pfkeyv2.h netipsec/ipsec.h netinet6/ipsec.h linux/udp.h)
467 AC_CHECK_HEADERS(netinet/ip6.h)
468
469 AC_CHECK_MEMBERS([struct sockaddr.sa_len], [], [],
470 [
471         #include <sys/types.h>
472         #include <sys/socket.h>
473 ])
474
475 AC_CHECK_MEMBERS([struct sadb_x_policy.sadb_x_policy_priority], [], [],
476 [
477         #include <sys/types.h>
478         #ifdef HAVE_NET_PFKEYV2_H
479         #include <net/pfkeyv2.h>
480         #else
481         #include <stdint.h>
482         #include <linux/pfkeyv2.h>
483         #endif
484 ])
485
486 AC_MSG_CHECKING([for in6addr_any])
487 AC_COMPILE_IFELSE(
488         [AC_LANG_PROGRAM(
489                 [[#include <sys/types.h>
490                   #include <sys/socket.h>
491                   #include <netinet/in.h>]],
492                 [[struct in6_addr in6;
493                   in6 = in6addr_any;]])],
494         [AC_MSG_RESULT([yes]);
495          AC_DEFINE([HAVE_IN6ADDR_ANY], [], [have struct in6_addr in6addr_any])],
496         [AC_MSG_RESULT([no])]
497 )
498
499 AC_MSG_CHECKING([for in6_pktinfo])
500 AC_COMPILE_IFELSE(
501         [AC_LANG_PROGRAM(
502                 [[#define _GNU_SOURCE
503                   #include <sys/types.h>
504                   #include <sys/socket.h>
505                   #include <netinet/in.h>]],
506                 [[struct in6_pktinfo pi;
507                   if (pi.ipi6_ifindex)
508                   {
509                     return 0;
510                   }]])],
511         [AC_MSG_RESULT([yes]);
512          AC_DEFINE([HAVE_IN6_PKTINFO], [], [have struct in6_pktinfo.ipi6_ifindex])],
513         [AC_MSG_RESULT([no])]
514 )
515
516 AC_MSG_CHECKING([for IPSEC_MODE_BEET])
517 AC_COMPILE_IFELSE(
518         [AC_LANG_PROGRAM(
519                 [[#include <sys/types.h>
520                   #ifdef HAVE_NETIPSEC_IPSEC_H
521                   #include <netipsec/ipsec.h>
522                   #elif defined(HAVE_NETINET6_IPSEC_H)
523                   #include <netinet6/ipsec.h>
524                   #else
525                   #include <stdint.h>
526                   #include <linux/ipsec.h>
527                   #endif]],
528                 [[int mode = IPSEC_MODE_BEET;
529                   return mode;]])],
530         [AC_MSG_RESULT([yes]);
531          AC_DEFINE([HAVE_IPSEC_MODE_BEET], [], [have IPSEC_MODE_BEET defined])],
532         [AC_MSG_RESULT([no])]
533 )
534
535 AC_MSG_CHECKING([for IPSEC_DIR_FWD])
536 AC_COMPILE_IFELSE(
537         [AC_LANG_PROGRAM(
538                 [[#include <sys/types.h>
539                   #ifdef HAVE_NETIPSEC_IPSEC_H
540                   #include <netipsec/ipsec.h>
541                   #elif defined(HAVE_NETINET6_IPSEC_H)
542                   #include <netinet6/ipsec.h>
543                   #else
544                   #include <stdint.h>
545                   #include <linux/ipsec.h>
546                   #endif]],
547                 [[int dir = IPSEC_DIR_FWD;
548                   return dir;]])],
549         [AC_MSG_RESULT([yes]);
550          AC_DEFINE([HAVE_IPSEC_DIR_FWD], [], [have IPSEC_DIR_FWD defined])],
551         [AC_MSG_RESULT([no])]
552 )
553
554 AC_MSG_CHECKING([for RTA_TABLE])
555 AC_COMPILE_IFELSE(
556         [AC_LANG_PROGRAM(
557                 [[#include <sys/socket.h>
558                   #include <linux/netlink.h>
559                   #include <linux/rtnetlink.h>]],
560                 [[int rta_type = RTA_TABLE;
561                   return rta_type;]])],
562         [AC_MSG_RESULT([yes]);
563          AC_DEFINE([HAVE_RTA_TABLE], [], [have netlink RTA_TABLE defined])],
564         [AC_MSG_RESULT([no])]
565 )
566
567 AC_MSG_CHECKING([for gcc atomic operations])
568 AC_RUN_IFELSE([AC_LANG_SOURCE(
569         [[
570                         int main() {
571                         volatile int ref = 1;
572                         __sync_fetch_and_add (&ref, 1);
573                         __sync_sub_and_fetch (&ref, 1);
574                         /* Make sure test fails if operations are not supported */
575                         __sync_val_compare_and_swap(&ref, 1, 0);
576                         return ref;
577                 }
578         ]])],
579         [AC_MSG_RESULT([yes]);
580          AC_DEFINE([HAVE_GCC_ATOMIC_OPERATIONS], [],
581                    [have GCC __sync_* atomic operations])],
582         [AC_MSG_RESULT([no])],
583         [AC_MSG_RESULT([no])]
584 )
585
586 # check for the new register_printf_specifier function with len argument,
587 # or the deprecated register_printf_function without
588 AC_CHECK_FUNC(
589         [register_printf_specifier],
590         [AC_DEFINE([HAVE_PRINTF_SPECIFIER], [], [have register_printf_specifier()])],
591         [AC_CHECK_FUNC(
592                 [register_printf_function],
593                 [AC_DEFINE([HAVE_PRINTF_FUNCTION], [], [have register_printf_function()])],
594                 [
595                         AC_MSG_NOTICE([printf does not support custom format specifiers!])
596                         vstr=true
597                 ]
598         )]
599 )
600
601 if test x$vstr = xtrue; then
602         AC_CHECK_LIB([vstr],[main],[LIBS="$LIBS"],[AC_MSG_ERROR([Vstr string library not found])],[])
603         AC_DEFINE([USE_VSTR], [], [use vstring library for printf hooks])
604 fi
605
606 if test x$gmp = xtrue; then
607         saved_LIBS=$LIBS
608         AC_CHECK_LIB([gmp],[main],[],[AC_MSG_ERROR([GNU Multi Precision library gmp not found])],[])
609         AC_MSG_CHECKING([mpz_powm_sec])
610         if test x$mpz_powm_sec = xyes; then
611                 AC_COMPILE_IFELSE(
612                         [AC_LANG_PROGRAM(
613                                 [[#include "gmp.h"]],
614                                 [[void *x = mpz_powm_sec;]])],
615                         [AC_MSG_RESULT([yes]);
616                          AC_DEFINE([HAVE_MPZ_POWM_SEC], [], [have mpz_mown_sec()])],
617                         [AC_MSG_RESULT([no])]
618                 )
619         else
620                 AC_MSG_RESULT([disabled])
621         fi
622         LIBS=$saved_LIBS
623         AC_MSG_CHECKING([gmp.h version >= 4.1.4])
624         AC_COMPILE_IFELSE(
625                 [AC_LANG_PROGRAM(
626                         [[#include "gmp.h"]],
627                         [[
628                                 #if (__GNU_MP_VERSION*100 +  __GNU_MP_VERSION_MINOR*10 + __GNU_MP_VERSION_PATCHLEVEL) < 414
629                                         #error bad gmp
630                                 #endif]])],
631                 [AC_MSG_RESULT([yes])],
632                 [AC_MSG_RESULT([no]); AC_MSG_ERROR([No usable gmp.h found!])]
633         )
634 fi
635
636 if test x$ldap = xtrue; then
637         AC_CHECK_LIB([ldap],[main],[LIBS="$LIBS"],[AC_MSG_ERROR([LDAP library ldap not found])],[])
638         AC_CHECK_LIB([lber],[main],[LIBS="$LIBS"],[AC_MSG_ERROR([LDAP library lber not found])],[])
639         AC_CHECK_HEADER([ldap.h],,[AC_MSG_ERROR([LDAP header ldap.h not found!])])
640 fi
641
642 if test x$curl = xtrue; then
643         AC_CHECK_LIB([curl],[main],[LIBS="$LIBS"],[AC_MSG_ERROR([CURL library curl not found])],[])
644         AC_CHECK_HEADER([curl/curl.h],,[AC_MSG_ERROR([CURL header curl/curl.h not found!])])
645 fi
646
647 if test x$unbound = xtrue; then
648         AC_HAVE_LIBRARY([ldns],[LIBS="$LIBS"],[AC_MSG_ERROR([UNBOUND library ldns not found])])
649         AC_CHECK_HEADER([ldns/ldns.h],,[AC_MSG_ERROR([UNBOUND header ldns/ldns.h not found!])])
650         AC_HAVE_LIBRARY([unbound],[LIBS="$LIBS"],[AC_MSG_ERROR([UNBOUND library libunbound not found])])
651         AC_CHECK_HEADER([unbound.h],,[AC_MSG_ERROR([UNBOUND header unbound.h not found!])])
652 fi
653
654 if test x$soup = xtrue; then
655         PKG_CHECK_MODULES(soup, [libsoup-2.4])
656         AC_SUBST(soup_CFLAGS)
657         AC_SUBST(soup_LIBS)
658 fi
659
660 if test x$xml = xtrue; then
661         PKG_CHECK_MODULES(xml, [libxml-2.0])
662         AC_SUBST(xml_CFLAGS)
663         AC_SUBST(xml_LIBS)
664 fi
665
666 if test x$axis2c = xtrue; then
667         PKG_CHECK_MODULES(axis2c, [axis2c])
668         AC_SUBST(axis2c_CFLAGS)
669         AC_SUBST(axis2c_LIBS)
670 fi
671
672 if test x$tss = xtrousers; then
673         AC_CHECK_LIB([tspi],[main],[LIBS="$LIBS"],[AC_MSG_ERROR([TrouSerS library libtspi not found])],[])
674         AC_CHECK_HEADER([trousers/tss.h],,[AC_MSG_ERROR([TrouSerS header trousers/tss.h not found!])])
675         AC_DEFINE([TSS_TROUSERS], [], [use TrouSerS library libtspi as TSS implementation])
676 fi
677
678 if test x$dumm = xtrue; then
679         PKG_CHECK_MODULES(gtk, [gtk+-2.0 vte])
680         AC_SUBST(gtk_CFLAGS)
681         AC_SUBST(gtk_LIBS)
682         AC_CHECK_PROGS(RUBY, ruby)
683         AC_MSG_CHECKING([for Ruby header files])
684         if test -n "$RUBY"; then
685                 RUBYINCLUDE=
686                 RUBYDIR=`($RUBY -r rbconfig -e 'print RbConfig::CONFIG[["rubyhdrdir"]] || ""') 2>/dev/null`
687                 if test -n "$RUBYDIR" -a -r "$RUBYDIR/ruby.h"; then
688                         RUBYARCH=`($RUBY -r rbconfig -e 'print RbConfig::CONFIG[["arch"]] || ""') 2>/dev/null`
689                         if test -n "$RUBYARCH"; then
690                                 AC_MSG_RESULT([$RUBYDIR])
691                                 RUBYINCLUDE="-I$RUBYDIR -I$RUBYDIR/$RUBYARCH"
692                         fi
693                 else
694                         RUBYDIR=`($RUBY -r rbconfig -e 'print RbConfig::CONFIG[["archdir"]] || ""') 2>/dev/null`
695                         if test -n "$RUBYDIR" -a -r "$RUBYDIR/ruby.h"; then
696                                 AC_MSG_RESULT([$RUBYDIR])
697                                 RUBYINCLUDE="-I$RUBYDIR"
698                         fi
699                 fi
700                 if test -z "$RUBYINCLUDE"; then
701                         AC_MSG_ERROR([ruby.h not found])
702                 fi
703                 AC_SUBST(RUBYINCLUDE)
704         else
705                 AC_MSG_ERROR([don't know how to run ruby])
706         fi
707         AC_MSG_CHECKING([for libruby])
708         saved_LIBS=$LIBS
709         LIBS=`($RUBY -r rbconfig -e 'print RbConfig::CONFIG[["LIBRUBYARG_SHARED"]] || ""') 2>/dev/null`
710         AC_TRY_LINK_FUNC(ruby_init,
711                 [AC_MSG_RESULT([$LIBS]); RUBYLIB=$LIBS],
712                 [AC_MSG_ERROR([not found])])
713         AC_SUBST(RUBYLIB)
714         AC_CHECK_FUNCS(rb_errinfo)
715         LIBS=$saved_LIBS
716 fi
717
718 if test x$fast = xtrue; then
719         AC_CHECK_LIB([neo_cgi],[main],[LIBS="$LIBS"],[AC_MSG_ERROR([ClearSilver library neo_cgi not found!])],[])
720         AC_CHECK_LIB([neo_utl],[main],[LIBS="$LIBS"],[AC_MSG_ERROR([ClearSilver library neo_utl not found!])],[])
721         AC_MSG_CHECKING([ClearSilver requires zlib])
722         saved_CFLAGS=$CFLAGS
723         saved_LIBS=$LIBS
724         LIBS="-lneo_cgi -lneo_cs -lneo_utl"
725         CFLAGS="-I/usr/include/ClearSilver"
726         AC_LINK_IFELSE(
727                 [AC_LANG_PROGRAM(
728                         [[#include <ClearSilver.h>]],
729                         [[NEOERR *err = cgi_display(NULL, NULL);]])],
730                 [AC_MSG_RESULT([no]); clearsilver_LIBS="$LIBS"],
731                 [AC_MSG_RESULT([yes]); clearsilver_LIBS="$LIBS -lz"]
732         )
733         AC_SUBST(clearsilver_LIBS)
734         LIBS=$saved_LIBS
735         CFLAGS=$saved_CFLAGS
736 # autoconf does not like CamelCase!? How to fix this?
737 #       AC_CHECK_HEADER([ClearSilver/ClearSilver.h],,[AC_MSG_ERROR([ClearSilver header file ClearSilver/ClearSilver.h not found!])])
738
739         AC_CHECK_LIB([fcgi],[main],[LIBS="$LIBS"],[AC_MSG_ERROR([FastCGI library fcgi not found!])],[])
740         AC_CHECK_HEADER([fcgiapp.h],,[AC_MSG_ERROR([FastCGI header file fcgiapp.h not found!])])
741 fi
742
743 if test x$mysql = xtrue; then
744         AC_PATH_PROG([MYSQLCONFIG], [mysql_config], [], [$PATH:/bin:/usr/bin:/usr/local/bin])
745         if test x$MYSQLCONFIG = x; then
746                 AC_MSG_ERROR([mysql_config not found!])
747         fi
748         AC_SUBST(MYSQLLIB, `$MYSQLCONFIG --libs_r`)
749         AC_SUBST(MYSQLCFLAG, `$MYSQLCONFIG --cflags`)
750 fi
751
752 if test x$sqlite = xtrue; then
753         AC_CHECK_LIB([sqlite3],[main],[LIBS="$LIBS"],[AC_MSG_ERROR([SQLite library sqlite3 not found])],[])
754         AC_CHECK_HEADER([sqlite3.h],,[AC_MSG_ERROR([SQLite header sqlite3.h not found!])])
755         AC_MSG_CHECKING([sqlite3_prepare_v2])
756         AC_COMPILE_IFELSE(
757                 [AC_LANG_PROGRAM(
758                         [[#include <sqlite3.h>]],
759                         [[void *test = sqlite3_prepare_v2;]])],
760                 [AC_MSG_RESULT([yes]);
761                  AC_DEFINE([HAVE_SQLITE3_PREPARE_V2], [], [have sqlite3_prepare_v2()])],
762                 [AC_MSG_RESULT([no])]
763         )
764         AC_MSG_CHECKING([sqlite3.h version >= 3.3.1])
765         AC_COMPILE_IFELSE(
766                 [AC_LANG_PROGRAM(
767                         [[#include <sqlite3.h>]],
768                         [[
769                                 #if SQLITE_VERSION_NUMBER < 3003001
770                                         #error bad sqlite
771                                 #endif]])],
772                 [AC_MSG_RESULT([yes])],
773                 [AC_MSG_RESULT([no]); AC_MSG_ERROR([SQLite version >= 3.3.1 required!])]
774         )
775 fi
776
777 if test x$openssl = xtrue; then
778         AC_CHECK_LIB([crypto],[main],[LIBS="$LIBS"],[AC_MSG_ERROR([OpenSSL crypto library not found])],[])
779         AC_CHECK_HEADER([openssl/evp.h],,[AC_MSG_ERROR([OpenSSL header openssl/evp.h not found!])])
780 fi
781
782 if test x$gcrypt = xtrue; then
783         AC_CHECK_LIB([gcrypt],[main],[LIBS="$LIBS"],[AC_MSG_ERROR([gcrypt library not found])],[-lgpg-error])
784         AC_CHECK_HEADER([gcrypt.h],,[AC_MSG_ERROR([gcrypt header gcrypt.h not found!])])
785         AC_MSG_CHECKING([gcrypt CAMELLIA cipher])
786         AC_COMPILE_IFELSE(
787                 [AC_LANG_PROGRAM(
788                         [[#include <gcrypt.h>]],
789                         [[enum gcry_cipher_algos alg = GCRY_CIPHER_CAMELLIA128;]])],
790                 [AC_MSG_RESULT([yes]);
791                  AC_DEFINE([HAVE_GCRY_CIPHER_CAMELLIA], [], [have GCRY_CIPHER_CAMELLIA128])],
792                 [AC_MSG_RESULT([no])]
793         )
794 fi
795
796 if test x$uci = xtrue; then
797         AC_CHECK_LIB([uci],[main],[LIBS="$LIBS"],[AC_MSG_ERROR([UCI library libuci not found])],[])
798         AC_CHECK_HEADER([uci.h],,[AC_MSG_ERROR([UCI header uci.h not found!])])
799 fi
800
801 if test x$android = xtrue; then
802         AC_CHECK_LIB([cutils],[main],[LIBS="$LIBS"],[AC_MSG_ERROR([Android library libcutils not found])],[])
803         AC_CHECK_HEADER([cutils/properties.h],,[AC_MSG_ERROR([Android header cutils/properties.h not found!])])
804         # we have to force the use of libdl here because the autodetection
805         # above does not work correctly when cross-compiling for android.
806         DLLIB="-ldl"
807         AC_SUBST(DLLIB)
808 fi
809
810 if test x$maemo = xtrue; then
811         PKG_CHECK_MODULES(maemo, [glib-2.0 gthread-2.0 libosso osso-af-settings])
812         AC_SUBST(maemo_CFLAGS)
813         AC_SUBST(maemo_LIBS)
814         dbusservicedir="/usr/share/dbus-1/system-services"
815         AC_SUBST(dbusservicedir)
816 fi
817
818 if test x$eap_sim_pcsc = xtrue; then
819         PKG_CHECK_MODULES(pcsclite, [libpcsclite])
820         AC_SUBST(pcsclite_CFLAGS)
821         AC_SUBST(pcsclite_LIBS)
822 fi
823
824 if test x$nm = xtrue; then
825         PKG_CHECK_EXISTS([libnm-glib],
826                 [PKG_CHECK_MODULES(nm, [NetworkManager gthread-2.0 libnm-util libnm-glib libnm-glib-vpn])],
827                 [PKG_CHECK_MODULES(nm, [NetworkManager gthread-2.0 libnm_util libnm_glib libnm_glib_vpn])]
828         )
829         AC_SUBST(nm_CFLAGS)
830         AC_SUBST(nm_LIBS)
831 fi
832
833 if test x$xauth_pam = xtrue; then
834         AC_CHECK_LIB([pam],[main],[LIBS="$LIBS"],[AC_MSG_ERROR([PAM library not found])],[])
835         AC_CHECK_HEADER([security/pam_appl.h],,[AC_MSG_ERROR([PAM header security/pam_appl.h not found!])])
836 fi
837
838 if test x$capabilities = xnative; then
839         AC_MSG_NOTICE([Usage of the native Linux capabilities interface is deprecated, use libcap instead])
840         # Linux requires the following for capset(), Android does not have it,
841         # but defines capset() in unistd.h instead.
842         AC_CHECK_HEADERS([sys/capability.h])
843         AC_CHECK_FUNC(capset,,[AC_MSG_ERROR([capset() not found!])])
844         AC_DEFINE([CAPABILITIES_NATIVE], [], [have native linux capset()])
845 fi
846
847 if test x$capabilities = xlibcap; then
848         AC_CHECK_LIB([cap],[main],[LIBS="$LIBS"],[AC_MSG_ERROR([libcap library not found])],[])
849         AC_CHECK_HEADER([sys/capability.h],
850                 [AC_DEFINE([HAVE_SYS_CAPABILITY_H], [], [have sys/capability.h])],
851                 [AC_MSG_ERROR([libcap header sys/capability.h not found!])])
852         AC_DEFINE([CAPABILITIES_LIBCAP], [], [have libpcap library])
853 fi
854
855 if test x$integrity_test = xtrue; then
856         AC_MSG_CHECKING([for dladdr()])
857         AC_COMPILE_IFELSE(
858                 [AC_LANG_PROGRAM(
859                         [[#define _GNU_SOURCE
860                           #include <dlfcn.h>]],
861                         [[Dl_info info; dladdr(main, &info);]])],
862                 [AC_MSG_RESULT([yes])],
863                 [AC_MSG_RESULT([no]);
864                  AC_MSG_ERROR([dladdr() not supported, required by integrity-test!])]
865         )
866         AC_MSG_CHECKING([for dl_iterate_phdr()])
867         AC_COMPILE_IFELSE(
868                 [AC_LANG_PROGRAM(
869                         [[#define _GNU_SOURCE
870                           #include <link.h>]],
871                         [[dl_iterate_phdr((void*)0, (void*)0);]])],
872                 [AC_MSG_RESULT([yes])],
873                 [AC_MSG_RESULT([no]);
874                  AC_MSG_ERROR([dl_iterate_phdr() not supported, required by integrity-test!])]
875         )
876 fi
877
878 if test x$bfd_backtraces = xtrue; then
879         AC_CHECK_LIB([bfd],[main],[LIBS="$LIBS"],[AC_MSG_ERROR([binutils libbfd not found!])],[])
880         AC_CHECK_HEADER([bfd.h],[AC_DEFINE([HAVE_BFD_H],,[have binutils bfd.h])],
881                 [AC_MSG_ERROR([binutils bfd.h header not found!])])
882         BFDLIB="-lbfd"
883         AC_SUBST(BFDLIB)
884 fi
885
886 AM_CONDITIONAL(USE_DEV_HEADERS, [test "x$dev_headers" != xno])
887 if test x$dev_headers = xyes; then
888         dev_headers="$includedir/strongswan"
889 fi
890 AC_SUBST(dev_headers)
891
892 CFLAGS="$CFLAGS -include `pwd`/config.h"
893
894 # ===============================================
895 #  collect plugin list for strongSwan components
896 # ===============================================
897
898 m4_include(m4/macros/add-plugin.m4)
899
900 # plugin lists for all components
901 charon_plugins=
902 starter_plugins=
903 pool_plugins=
904 attest_plugins=
905 openac_plugins=
906 scepclient_plugins=
907 pki_plugins=
908 scripts_plugins=
909 manager_plugins=
910 medsrv_plugins=
911 nm_plugins=
912
913 # location specific lists for checksumming,
914 # for src/libcharon, src/libhydra and src/libstrongswan
915 c_plugins=
916 h_plugins=
917 s_plugins=
918
919 ADD_PLUGIN([test-vectors],         [s charon openac scepclient pki])
920 ADD_PLUGIN([curl],                 [s charon scepclient scripts nm])
921 ADD_PLUGIN([soup],                 [s charon scripts nm])
922 ADD_PLUGIN([unbound],              [s charon scripts])
923 ADD_PLUGIN([ldap],                 [s charon scepclient scripts nm])
924 ADD_PLUGIN([mysql],                [s charon pool manager medsrv attest])
925 ADD_PLUGIN([sqlite],               [s charon pool manager medsrv attest])
926 ADD_PLUGIN([pkcs11],               [s charon pki nm])
927 ADD_PLUGIN([aes],                  [s charon openac scepclient pki scripts nm])
928 ADD_PLUGIN([des],                  [s charon openac scepclient pki scripts nm])
929 ADD_PLUGIN([blowfish],             [s charon openac scepclient pki scripts nm])
930 ADD_PLUGIN([sha1],                 [s charon openac scepclient pki scripts medsrv attest nm])
931 ADD_PLUGIN([sha2],                 [s charon openac scepclient pki scripts medsrv attest nm])
932 ADD_PLUGIN([md4],                  [s charon openac manager scepclient pki nm])
933 ADD_PLUGIN([md5],                  [s charon openac scepclient pki scripts attest nm])
934 ADD_PLUGIN([rdrand],               [s charon openac scepclient pki scripts medsrv attest nm])
935 ADD_PLUGIN([random],               [s charon openac scepclient pki scripts medsrv attest nm])
936 ADD_PLUGIN([nonce],                [s charon nm])
937 ADD_PLUGIN([x509],                 [s charon openac scepclient pki scripts attest nm])
938 ADD_PLUGIN([revocation],           [s charon nm])
939 ADD_PLUGIN([constraints],          [s charon nm])
940 ADD_PLUGIN([pubkey],               [s charon])
941 ADD_PLUGIN([pkcs1],                [s charon openac scepclient pki scripts manager medsrv attest nm])
942 ADD_PLUGIN([pkcs7],                [s scepclient pki])
943 ADD_PLUGIN([pkcs8],                [s charon openac scepclient pki scripts manager medsrv attest nm])
944 ADD_PLUGIN([pgp],                  [s charon])
945 ADD_PLUGIN([dnskey],               [s charon])
946 ADD_PLUGIN([pem],                  [s charon openac scepclient pki scripts manager medsrv attest nm])
947 ADD_PLUGIN([padlock],              [s charon])
948 ADD_PLUGIN([openssl],              [s charon openac scepclient pki scripts manager medsrv attest nm])
949 ADD_PLUGIN([gcrypt],               [s charon openac scepclient pki scripts manager medsrv attest nm])
950 ADD_PLUGIN([af-alg],               [s charon openac scepclient pki scripts medsrv attest nm])
951 ADD_PLUGIN([fips-prf],             [s charon nm])
952 ADD_PLUGIN([gmp],                  [s charon openac scepclient pki scripts manager medsrv attest nm])
953 ADD_PLUGIN([agent],                [s charon nm])
954 ADD_PLUGIN([xcbc],                 [s charon nm])
955 ADD_PLUGIN([cmac],                 [s charon nm])
956 ADD_PLUGIN([hmac],                 [s charon scripts nm])
957 ADD_PLUGIN([ctr],                  [s charon scripts nm])
958 ADD_PLUGIN([ccm],                  [s charon scripts nm])
959 ADD_PLUGIN([gcm],                  [s charon scripts nm])
960 ADD_PLUGIN([attr],                 [h charon])
961 ADD_PLUGIN([attr-sql],             [h charon])
962 ADD_PLUGIN([load-tester],          [c charon])
963 ADD_PLUGIN([kernel-pfkey],         [h charon starter nm])
964 ADD_PLUGIN([kernel-pfroute],       [h charon starter nm])
965 ADD_PLUGIN([kernel-klips],         [h charon starter])
966 ADD_PLUGIN([kernel-netlink],       [h charon starter nm])
967 ADD_PLUGIN([resolve],              [h charon])
968 ADD_PLUGIN([socket-default],       [c charon nm])
969 ADD_PLUGIN([socket-dynamic],       [c charon])
970 ADD_PLUGIN([farp],                 [c charon])
971 ADD_PLUGIN([stroke],               [c charon])
972 ADD_PLUGIN([smp],                  [c charon])
973 ADD_PLUGIN([sql],                  [c charon])
974 ADD_PLUGIN([updown],               [c charon])
975 ADD_PLUGIN([eap-identity],         [c charon nm])
976 ADD_PLUGIN([eap-sim],              [c charon])
977 ADD_PLUGIN([eap-sim-file],         [c charon])
978 ADD_PLUGIN([eap-sim-pcsc],         [c charon])
979 ADD_PLUGIN([eap-aka],              [c charon])
980 ADD_PLUGIN([eap-aka-3gpp2],        [c charon])
981 ADD_PLUGIN([eap-simaka-sql],       [c charon])
982 ADD_PLUGIN([eap-simaka-pseudonym], [c charon])
983 ADD_PLUGIN([eap-simaka-reauth],    [c charon])
984 ADD_PLUGIN([eap-md5],              [c charon nm])
985 ADD_PLUGIN([eap-gtc],              [c charon nm])
986 ADD_PLUGIN([eap-mschapv2],         [c charon nm])
987 ADD_PLUGIN([eap-dynamic],          [c charon])
988 ADD_PLUGIN([eap-radius],           [c charon])
989 ADD_PLUGIN([eap-tls],              [c charon nm])
990 ADD_PLUGIN([eap-ttls],             [c charon nm])
991 ADD_PLUGIN([eap-peap],             [c charon nm])
992 ADD_PLUGIN([eap-tnc],              [c charon])
993 ADD_PLUGIN([xauth-generic],        [c charon])
994 ADD_PLUGIN([xauth-eap],            [c charon])
995 ADD_PLUGIN([xauth-pam],            [c charon])
996 ADD_PLUGIN([tnc-ifmap],            [c charon])
997 ADD_PLUGIN([tnc-pdp],              [c charon])
998 ADD_PLUGIN([tnc-imc],              [c charon])
999 ADD_PLUGIN([tnc-imv],              [c charon])
1000 ADD_PLUGIN([tnc-tnccs],            [c charon])
1001 ADD_PLUGIN([tnccs-20],             [c charon])
1002 ADD_PLUGIN([tnccs-11],             [c charon])
1003 ADD_PLUGIN([tnccs-dynamic],        [c charon])
1004 ADD_PLUGIN([medsrv],               [c charon])
1005 ADD_PLUGIN([medcli],               [c charon])
1006 ADD_PLUGIN([dhcp],                 [c charon])
1007 ADD_PLUGIN([android],              [c charon])
1008 ADD_PLUGIN([android-log],          [c charon])
1009 ADD_PLUGIN([ha],                   [c charon])
1010 ADD_PLUGIN([whitelist],            [c charon])
1011 ADD_PLUGIN([lookip],               [c charon])
1012 ADD_PLUGIN([error-notify],         [c charon])
1013 ADD_PLUGIN([certexpire],           [c charon])
1014 ADD_PLUGIN([led],                  [c charon])
1015 ADD_PLUGIN([duplicheck],           [c charon])
1016 ADD_PLUGIN([coupling],             [c charon])
1017 ADD_PLUGIN([radattr],              [c charon])
1018 ADD_PLUGIN([maemo],                [c charon])
1019 ADD_PLUGIN([uci],                  [c charon])
1020 ADD_PLUGIN([addrblock],            [c charon])
1021 ADD_PLUGIN([unity],                [c charon])
1022 ADD_PLUGIN([unit-tester],          [c charon])
1023
1024 AC_SUBST(charon_plugins)
1025 AC_SUBST(starter_plugins)
1026 AC_SUBST(pool_plugins)
1027 AC_SUBST(attest_plugins)
1028 AC_SUBST(openac_plugins)
1029 AC_SUBST(scepclient_plugins)
1030 AC_SUBST(pki_plugins)
1031 AC_SUBST(scripts_plugins)
1032 AC_SUBST(manager_plugins)
1033 AC_SUBST(medsrv_plugins)
1034 AC_SUBST(nm_plugins)
1035
1036 AC_SUBST(c_plugins)
1037 AC_SUBST(h_plugins)
1038 AC_SUBST(s_plugins)
1039
1040 # ======================
1041 #  set Makefile.am vars
1042 # ======================
1043
1044 #  libstrongswan plugins
1045 # -----------------------
1046 AM_CONDITIONAL(USE_TEST_VECTORS, test x$test_vectors = xtrue)
1047 AM_CONDITIONAL(USE_CURL, test x$curl = xtrue)
1048 AM_CONDITIONAL(USE_UNBOUND, test x$unbound = xtrue)
1049 AM_CONDITIONAL(USE_SOUP, test x$soup = xtrue)
1050 AM_CONDITIONAL(USE_LDAP, test x$ldap = xtrue)
1051 AM_CONDITIONAL(USE_AES, test x$aes = xtrue)
1052 AM_CONDITIONAL(USE_DES, test x$des = xtrue)
1053 AM_CONDITIONAL(USE_BLOWFISH, test x$blowfish = xtrue)
1054 AM_CONDITIONAL(USE_MD4, test x$md4 = xtrue)
1055 AM_CONDITIONAL(USE_MD5, test x$md5 = xtrue)
1056 AM_CONDITIONAL(USE_SHA1, test x$sha1 = xtrue)
1057 AM_CONDITIONAL(USE_SHA2, test x$sha2 = xtrue)
1058 AM_CONDITIONAL(USE_FIPS_PRF, test x$fips_prf = xtrue)
1059 AM_CONDITIONAL(USE_GMP, test x$gmp = xtrue)
1060 AM_CONDITIONAL(USE_RDRAND, test x$rdrand = xtrue)
1061 AM_CONDITIONAL(USE_RANDOM, test x$random = xtrue)
1062 AM_CONDITIONAL(USE_NONCE, test x$nonce = xtrue)
1063 AM_CONDITIONAL(USE_X509, test x$x509 = xtrue)
1064 AM_CONDITIONAL(USE_REVOCATION, test x$revocation = xtrue)
1065 AM_CONDITIONAL(USE_CONSTRAINTS, test x$constraints = xtrue)
1066 AM_CONDITIONAL(USE_PUBKEY, test x$pubkey = xtrue)
1067 AM_CONDITIONAL(USE_PKCS1, test x$pkcs1 = xtrue)
1068 AM_CONDITIONAL(USE_PKCS7, test x$pkcs7 = xtrue)
1069 AM_CONDITIONAL(USE_PKCS8, test x$pkcs8 = xtrue)
1070 AM_CONDITIONAL(USE_PGP, test x$pgp = xtrue)
1071 AM_CONDITIONAL(USE_DNSKEY, test x$dnskey = xtrue)
1072 AM_CONDITIONAL(USE_PEM, test x$pem = xtrue)
1073 AM_CONDITIONAL(USE_HMAC, test x$hmac = xtrue)
1074 AM_CONDITIONAL(USE_CMAC, test x$cmac = xtrue)
1075 AM_CONDITIONAL(USE_XCBC, test x$xcbc = xtrue)
1076 AM_CONDITIONAL(USE_MYSQL, test x$mysql = xtrue)
1077 AM_CONDITIONAL(USE_SQLITE, test x$sqlite = xtrue)
1078 AM_CONDITIONAL(USE_PADLOCK, test x$padlock = xtrue)
1079 AM_CONDITIONAL(USE_OPENSSL, test x$openssl = xtrue)
1080 AM_CONDITIONAL(USE_GCRYPT, test x$gcrypt = xtrue)
1081 AM_CONDITIONAL(USE_AGENT, test x$agent = xtrue)
1082 AM_CONDITIONAL(USE_PKCS11, test x$pkcs11 = xtrue)
1083 AM_CONDITIONAL(USE_CTR, test x$ctr = xtrue)
1084 AM_CONDITIONAL(USE_CCM, test x$ccm = xtrue)
1085 AM_CONDITIONAL(USE_GCM, test x$gcm = xtrue)
1086 AM_CONDITIONAL(USE_AF_ALG, test x$af_alg = xtrue)
1087
1088 #  charon plugins
1089 # ----------------
1090 AM_CONDITIONAL(USE_STROKE, test x$stroke = xtrue)
1091 AM_CONDITIONAL(USE_MEDSRV, test x$medsrv = xtrue)
1092 AM_CONDITIONAL(USE_MEDCLI, test x$medcli = xtrue)
1093 AM_CONDITIONAL(USE_UCI, test x$uci = xtrue)
1094 AM_CONDITIONAL(USE_ANDROID, test x$android = xtrue)
1095 AM_CONDITIONAL(USE_ANDROID_LOG, test x$android_log = xtrue)
1096 AM_CONDITIONAL(USE_MAEMO, test x$maemo = xtrue)
1097 AM_CONDITIONAL(USE_SMP, test x$smp = xtrue)
1098 AM_CONDITIONAL(USE_SQL, test x$sql = xtrue)
1099 AM_CONDITIONAL(USE_UPDOWN, test x$updown = xtrue)
1100 AM_CONDITIONAL(USE_DHCP, test x$dhcp = xtrue)
1101 AM_CONDITIONAL(USE_UNIT_TESTS, test x$unit_tester = xtrue)
1102 AM_CONDITIONAL(USE_LOAD_TESTER, test x$load_tester = xtrue)
1103 AM_CONDITIONAL(USE_HA, test x$ha = xtrue)
1104 AM_CONDITIONAL(USE_WHITELIST, test x$whitelist = xtrue)
1105 AM_CONDITIONAL(USE_LOOKIP, test x$lookip = xtrue)
1106 AM_CONDITIONAL(USE_ERROR_NOTIFY, test x$error_notify = xtrue)
1107 AM_CONDITIONAL(USE_CERTEXPIRE, test x$certexpire = xtrue)
1108 AM_CONDITIONAL(USE_LED, test x$led = xtrue)
1109 AM_CONDITIONAL(USE_DUPLICHECK, test x$duplicheck = xtrue)
1110 AM_CONDITIONAL(USE_COUPLING, test x$coupling = xtrue)
1111 AM_CONDITIONAL(USE_RADATTR, test x$radattr = xtrue)
1112 AM_CONDITIONAL(USE_EAP_SIM, test x$eap_sim = xtrue)
1113 AM_CONDITIONAL(USE_EAP_SIM_FILE, test x$eap_sim_file = xtrue)
1114 AM_CONDITIONAL(USE_EAP_SIM_PCSC, test x$eap_sim_pcsc = xtrue)
1115 AM_CONDITIONAL(USE_EAP_SIMAKA_SQL, test x$eap_simaka_sql = xtrue)
1116 AM_CONDITIONAL(USE_EAP_SIMAKA_PSEUDONYM, test x$eap_simaka_pseudonym = xtrue)
1117 AM_CONDITIONAL(USE_EAP_SIMAKA_REAUTH, test x$eap_simaka_reauth = xtrue)
1118 AM_CONDITIONAL(USE_EAP_IDENTITY, test x$eap_identity = xtrue)
1119 AM_CONDITIONAL(USE_EAP_MD5, test x$eap_md5 = xtrue)
1120 AM_CONDITIONAL(USE_EAP_GTC, test x$eap_gtc = xtrue)
1121 AM_CONDITIONAL(USE_EAP_AKA, test x$eap_aka = xtrue)
1122 AM_CONDITIONAL(USE_EAP_AKA_3GPP2, test x$eap_aka_3gpp2 = xtrue)
1123 AM_CONDITIONAL(USE_EAP_MSCHAPV2, test x$eap_mschapv2 = xtrue)
1124 AM_CONDITIONAL(USE_EAP_TLS, test x$eap_tls = xtrue)
1125 AM_CONDITIONAL(USE_EAP_TTLS, test x$eap_ttls = xtrue)
1126 AM_CONDITIONAL(USE_EAP_PEAP, test x$eap_peap = xtrue)
1127 AM_CONDITIONAL(USE_EAP_TNC, test x$eap_tnc = xtrue)
1128 AM_CONDITIONAL(USE_EAP_DYNAMIC, test x$eap_dynamic = xtrue)
1129 AM_CONDITIONAL(USE_EAP_RADIUS, test x$eap_radius = xtrue)
1130 AM_CONDITIONAL(USE_XAUTH_GENERIC, test x$xauth_generic = xtrue)
1131 AM_CONDITIONAL(USE_XAUTH_EAP, test x$xauth_eap = xtrue)
1132 AM_CONDITIONAL(USE_XAUTH_PAM, test x$xauth_pam = xtrue)
1133 AM_CONDITIONAL(USE_TNC_IFMAP, test x$tnc_ifmap = xtrue)
1134 AM_CONDITIONAL(USE_TNC_PDP, test x$tnc_pdp = xtrue)
1135 AM_CONDITIONAL(USE_TNC_IMC, test x$tnc_imc = xtrue)
1136 AM_CONDITIONAL(USE_TNC_IMV, test x$tnc_imv = xtrue)
1137 AM_CONDITIONAL(USE_TNC_TNCCS, test x$tnc_tnccs = xtrue)
1138 AM_CONDITIONAL(USE_TNCCS_11, test x$tnccs_11 = xtrue)
1139 AM_CONDITIONAL(USE_TNCCS_20, test x$tnccs_20 = xtrue)
1140 AM_CONDITIONAL(USE_TNCCS_DYNAMIC, test x$tnccs_dynamic = xtrue)
1141 AM_CONDITIONAL(USE_IMC_TEST, test x$imc_test = xtrue)
1142 AM_CONDITIONAL(USE_IMV_TEST, test x$imv_test = xtrue)
1143 AM_CONDITIONAL(USE_IMC_SCANNER, test x$imc_scanner = xtrue)
1144 AM_CONDITIONAL(USE_IMV_SCANNER, test x$imv_scanner = xtrue)
1145 AM_CONDITIONAL(USE_IMC_OS, test x$imc_os = xtrue)
1146 AM_CONDITIONAL(USE_IMV_OS, test x$imv_os = xtrue)
1147 AM_CONDITIONAL(USE_IMC_ATTESTATION, test x$imc_attestation = xtrue)
1148 AM_CONDITIONAL(USE_IMV_ATTESTATION, test x$imv_attestation = xtrue)
1149 AM_CONDITIONAL(USE_SOCKET_DEFAULT, test x$socket_default = xtrue)
1150 AM_CONDITIONAL(USE_SOCKET_DYNAMIC, test x$socket_dynamic = xtrue)
1151 AM_CONDITIONAL(USE_FARP, test x$farp = xtrue)
1152 AM_CONDITIONAL(USE_ADDRBLOCK, test x$addrblock = xtrue)
1153 AM_CONDITIONAL(USE_UNITY, test x$unity = xtrue)
1154
1155 #  hydra plugins
1156 # ---------------
1157 AM_CONDITIONAL(USE_ATTR, test x$attr = xtrue)
1158 AM_CONDITIONAL(USE_ATTR_SQL, test x$attr_sql = xtrue -o x$sql = xtrue)
1159 AM_CONDITIONAL(USE_KERNEL_KLIPS, test x$kernel_klips = xtrue)
1160 AM_CONDITIONAL(USE_KERNEL_NETLINK, test x$kernel_netlink = xtrue)
1161 AM_CONDITIONAL(USE_KERNEL_PFKEY, test x$kernel_pfkey = xtrue)
1162 AM_CONDITIONAL(USE_KERNEL_PFROUTE, test x$kernel_pfroute = xtrue)
1163 AM_CONDITIONAL(USE_RESOLVE, test x$resolve = xtrue)
1164
1165 #  other options
1166 # ---------------
1167 AM_CONDITIONAL(USE_LEAK_DETECTIVE, test x$leak_detective = xtrue)
1168 AM_CONDITIONAL(USE_LOCK_PROFILER, test x$lock_profiler = xtrue)
1169 AM_CONDITIONAL(USE_DUMM, test x$dumm = xtrue)
1170 AM_CONDITIONAL(USE_FAST, test x$fast = xtrue)
1171 AM_CONDITIONAL(USE_MANAGER, test x$manager = xtrue)
1172 AM_CONDITIONAL(USE_ME, test x$mediation = xtrue)
1173 AM_CONDITIONAL(USE_INTEGRITY_TEST, test x$integrity_test = xtrue)
1174 AM_CONDITIONAL(USE_LOAD_WARNING, test x$load_warning = xtrue)
1175 AM_CONDITIONAL(USE_IKEV1, test x$ikev1 = xtrue)
1176 AM_CONDITIONAL(USE_IKEV2, test x$ikev2 = xtrue)
1177 AM_CONDITIONAL(USE_THREADS, test x$threads = xtrue)
1178 AM_CONDITIONAL(USE_ADNS, test x$adns = xtrue)
1179 AM_CONDITIONAL(USE_CHARON, test x$charon = xtrue)
1180 AM_CONDITIONAL(USE_NM, test x$nm = xtrue)
1181 AM_CONDITIONAL(USE_TOOLS, test x$tools = xtrue)
1182 AM_CONDITIONAL(USE_SCRIPTS, test x$scripts = xtrue)
1183 AM_CONDITIONAL(USE_CONFTEST, test x$conftest = xtrue)
1184 AM_CONDITIONAL(USE_LIBSTRONGSWAN, test x$charon = xtrue -o x$tools = xtrue -o x$conftest = xtrue -o x$fast = xtrue -o x$imcv = xtrue -o x$nm = xtrue)
1185 AM_CONDITIONAL(USE_LIBHYDRA, test x$charon = xtrue -o x$nm = xtrue)
1186 AM_CONDITIONAL(USE_LIBCHARON, test x$charon = xtrue -o x$conftest = xtrue -o x$nm = xtrue)
1187 AM_CONDITIONAL(USE_LIBIPSEC, test x$libipsec = xtrue)
1188 AM_CONDITIONAL(USE_LIBTNCIF, test x$tnc_tnccs = xtrue -o x$imcv = xtrue)
1189 AM_CONDITIONAL(USE_LIBTNCCS, test x$tnc_tnccs = xtrue)
1190 AM_CONDITIONAL(USE_LIBPTTLS, test x$tnc_tnccs = xtrue)
1191 AM_CONDITIONAL(USE_FILE_CONFIG, test x$stroke = xtrue)
1192 AM_CONDITIONAL(USE_IPSEC_SCRIPT, test x$stroke = xtrue -o x$tools = xtrue -o x$conftest = xtrue)
1193 AM_CONDITIONAL(USE_LIBCAP, test x$capabilities = xlibcap)
1194 AM_CONDITIONAL(USE_VSTR, test x$vstr = xtrue)
1195 AM_CONDITIONAL(USE_SIMAKA, test x$simaka = xtrue)
1196 AM_CONDITIONAL(USE_TLS, test x$tls = xtrue)
1197 AM_CONDITIONAL(USE_RADIUS, test x$radius = xtrue)
1198 AM_CONDITIONAL(USE_IMCV, test x$imcv = xtrue)
1199 AM_CONDITIONAL(USE_PTS, test x$pts = xtrue)
1200 AM_CONDITIONAL(USE_TROUSERS, test x$tss = xtrousers)
1201 AM_CONDITIONAL(MONOLITHIC, test x$monolithic = xtrue)
1202
1203 # ========================
1204 #  set global definitions
1205 # ========================
1206
1207 if test x$mediation = xtrue; then
1208         AC_DEFINE([ME], [], [mediation extension support])
1209 fi
1210 if test x$capabilities = xlibcap -o x$capabilities = xnative; then
1211         AC_DEFINE([CAPABILITIES], [], [capability dropping support])
1212 fi
1213 if test x$monolithic = xtrue; then
1214         AC_DEFINE([MONOLITHIC], [], [monolithic build embedding plugins])
1215 fi
1216 if test x$ikev1 = xtrue; then
1217         AC_DEFINE([USE_IKEV1], [], [support for IKEv1 protocol])
1218 fi
1219 if test x$ikev2 = xtrue; then
1220         AC_DEFINE([USE_IKEV2], [], [support for IKEv2 protocol])
1221 fi
1222
1223 # =================
1224 #  build Makefiles
1225 # =================
1226
1227 AC_CONFIG_FILES([
1228         Makefile
1229         man/Makefile
1230         init/Makefile
1231         init/systemd/Makefile
1232         src/Makefile
1233         src/include/Makefile
1234         src/libstrongswan/Makefile
1235         src/libstrongswan/plugins/aes/Makefile
1236         src/libstrongswan/plugins/cmac/Makefile
1237         src/libstrongswan/plugins/des/Makefile
1238         src/libstrongswan/plugins/blowfish/Makefile
1239         src/libstrongswan/plugins/md4/Makefile
1240         src/libstrongswan/plugins/md5/Makefile
1241         src/libstrongswan/plugins/sha1/Makefile
1242         src/libstrongswan/plugins/sha2/Makefile
1243         src/libstrongswan/plugins/fips_prf/Makefile
1244         src/libstrongswan/plugins/gmp/Makefile
1245         src/libstrongswan/plugins/rdrand/Makefile
1246         src/libstrongswan/plugins/random/Makefile
1247         src/libstrongswan/plugins/nonce/Makefile
1248         src/libstrongswan/plugins/hmac/Makefile
1249         src/libstrongswan/plugins/xcbc/Makefile
1250         src/libstrongswan/plugins/x509/Makefile
1251         src/libstrongswan/plugins/revocation/Makefile
1252         src/libstrongswan/plugins/constraints/Makefile
1253         src/libstrongswan/plugins/pubkey/Makefile
1254         src/libstrongswan/plugins/pkcs1/Makefile
1255         src/libstrongswan/plugins/pkcs7/Makefile
1256         src/libstrongswan/plugins/pkcs8/Makefile
1257         src/libstrongswan/plugins/pgp/Makefile
1258         src/libstrongswan/plugins/dnskey/Makefile
1259         src/libstrongswan/plugins/pem/Makefile
1260         src/libstrongswan/plugins/curl/Makefile
1261         src/libstrongswan/plugins/unbound/Makefile
1262         src/libstrongswan/plugins/soup/Makefile
1263         src/libstrongswan/plugins/ldap/Makefile
1264         src/libstrongswan/plugins/mysql/Makefile
1265         src/libstrongswan/plugins/sqlite/Makefile
1266         src/libstrongswan/plugins/padlock/Makefile
1267         src/libstrongswan/plugins/openssl/Makefile
1268         src/libstrongswan/plugins/gcrypt/Makefile
1269         src/libstrongswan/plugins/agent/Makefile
1270         src/libstrongswan/plugins/pkcs11/Makefile
1271         src/libstrongswan/plugins/ctr/Makefile
1272         src/libstrongswan/plugins/ccm/Makefile
1273         src/libstrongswan/plugins/gcm/Makefile
1274         src/libstrongswan/plugins/af_alg/Makefile
1275         src/libstrongswan/plugins/test_vectors/Makefile
1276         src/libhydra/Makefile
1277         src/libhydra/plugins/attr/Makefile
1278         src/libhydra/plugins/attr_sql/Makefile
1279         src/libhydra/plugins/kernel_klips/Makefile
1280         src/libhydra/plugins/kernel_netlink/Makefile
1281         src/libhydra/plugins/kernel_pfkey/Makefile
1282         src/libhydra/plugins/kernel_pfroute/Makefile
1283         src/libhydra/plugins/resolve/Makefile
1284         src/libipsec/Makefile
1285         src/libsimaka/Makefile
1286         src/libtls/Makefile
1287         src/libradius/Makefile
1288         src/libtncif/Makefile
1289         src/libtnccs/Makefile
1290         src/libpttls/Makefile
1291         src/libpts/Makefile
1292         src/libpts/plugins/imc_attestation/Makefile
1293         src/libpts/plugins/imv_attestation/Makefile
1294         src/libimcv/Makefile
1295         src/libimcv/plugins/imc_test/Makefile
1296         src/libimcv/plugins/imv_test/Makefile
1297         src/libimcv/plugins/imc_scanner/Makefile
1298         src/libimcv/plugins/imv_scanner/Makefile
1299         src/libimcv/plugins/imc_os/Makefile
1300         src/libimcv/plugins/imv_os/Makefile
1301         src/charon/Makefile
1302         src/charon-nm/Makefile
1303         src/libcharon/Makefile
1304         src/libcharon/plugins/eap_aka/Makefile
1305         src/libcharon/plugins/eap_aka_3gpp2/Makefile
1306         src/libcharon/plugins/eap_dynamic/Makefile
1307         src/libcharon/plugins/eap_identity/Makefile
1308         src/libcharon/plugins/eap_md5/Makefile
1309         src/libcharon/plugins/eap_gtc/Makefile
1310         src/libcharon/plugins/eap_sim/Makefile
1311         src/libcharon/plugins/eap_sim_file/Makefile
1312         src/libcharon/plugins/eap_sim_pcsc/Makefile
1313         src/libcharon/plugins/eap_simaka_sql/Makefile
1314         src/libcharon/plugins/eap_simaka_pseudonym/Makefile
1315         src/libcharon/plugins/eap_simaka_reauth/Makefile
1316         src/libcharon/plugins/eap_mschapv2/Makefile
1317         src/libcharon/plugins/eap_tls/Makefile
1318         src/libcharon/plugins/eap_ttls/Makefile
1319         src/libcharon/plugins/eap_peap/Makefile
1320         src/libcharon/plugins/eap_tnc/Makefile
1321         src/libcharon/plugins/eap_radius/Makefile
1322         src/libcharon/plugins/xauth_generic/Makefile
1323         src/libcharon/plugins/xauth_eap/Makefile
1324         src/libcharon/plugins/xauth_pam/Makefile
1325         src/libcharon/plugins/tnc_ifmap/Makefile
1326         src/libcharon/plugins/tnc_pdp/Makefile
1327         src/libcharon/plugins/tnc_imc/Makefile
1328         src/libcharon/plugins/tnc_imv/Makefile
1329         src/libcharon/plugins/tnc_tnccs/Makefile
1330         src/libcharon/plugins/tnccs_11/Makefile
1331         src/libcharon/plugins/tnccs_20/Makefile
1332         src/libcharon/plugins/tnccs_dynamic/Makefile
1333         src/libcharon/plugins/socket_default/Makefile
1334         src/libcharon/plugins/socket_dynamic/Makefile
1335         src/libcharon/plugins/farp/Makefile
1336         src/libcharon/plugins/smp/Makefile
1337         src/libcharon/plugins/sql/Makefile
1338         src/libcharon/plugins/medsrv/Makefile
1339         src/libcharon/plugins/medcli/Makefile
1340         src/libcharon/plugins/addrblock/Makefile
1341         src/libcharon/plugins/unity/Makefile
1342         src/libcharon/plugins/uci/Makefile
1343         src/libcharon/plugins/ha/Makefile
1344         src/libcharon/plugins/whitelist/Makefile
1345         src/libcharon/plugins/lookip/Makefile
1346         src/libcharon/plugins/error_notify/Makefile
1347         src/libcharon/plugins/certexpire/Makefile
1348         src/libcharon/plugins/led/Makefile
1349         src/libcharon/plugins/duplicheck/Makefile
1350         src/libcharon/plugins/coupling/Makefile
1351         src/libcharon/plugins/radattr/Makefile
1352         src/libcharon/plugins/android/Makefile
1353         src/libcharon/plugins/android_log/Makefile
1354         src/libcharon/plugins/maemo/Makefile
1355         src/libcharon/plugins/stroke/Makefile
1356         src/libcharon/plugins/updown/Makefile
1357         src/libcharon/plugins/dhcp/Makefile
1358         src/libcharon/plugins/unit_tester/Makefile
1359         src/libcharon/plugins/load_tester/Makefile
1360         src/stroke/Makefile
1361         src/ipsec/Makefile
1362         src/starter/Makefile
1363         src/_updown/Makefile
1364         src/_updown_espmark/Makefile
1365         src/_copyright/Makefile
1366         src/openac/Makefile
1367         src/scepclient/Makefile
1368         src/pki/Makefile
1369         src/dumm/Makefile
1370         src/dumm/ext/extconf.rb
1371         src/libfast/Makefile
1372         src/manager/Makefile
1373         src/medsrv/Makefile
1374         src/checksum/Makefile
1375         src/conftest/Makefile
1376         scripts/Makefile
1377         testing/Makefile
1378 ])
1379 AC_OUTPUT
1380
1381 # ========================
1382 #  report enabled plugins
1383 # ========================
1384
1385 AC_MSG_RESULT([])
1386 AC_MSG_RESULT([ strongSwan will be built with the following plugins])
1387 AC_MSG_RESULT([-----------------------------------------------------])
1388
1389 AC_MSG_RESULT([libstrongswan:$s_plugins])
1390 AC_MSG_RESULT([libcharon:    $c_plugins])
1391 AC_MSG_RESULT([libhydra:     $h_plugins])
1392 AC_MSG_RESULT([])