configure.in

   1 dnl  configure.in for linux strongSwan
   2 dnl  Copyright (C) 2006 Martin Willi
   3 dnl  Hochschule fuer Technik Rapperswil
   4 dnl
   5 dnl  This program is free software; you can redistribute it and/or modify it
   6 dnl  under the terms of the GNU General Public License as published by the
   7 dnl  Free Software Foundation; either version 2 of the License, or (at your
   8 dnl  option) any later version.  See <http://www.fsf.org/copyleft/gpl.txt>.
   9 dnl
  10 dnl  This program is distributed in the hope that it will be useful, but
  11 dnl  WITHOUT ANY WARRANTY; without even the implied warranty of MERCHANTABILITY
  12 dnl  or FITNESS FOR A PARTICULAR PURPOSE.  See the GNU General Public License
  13 dnl  for more details.
  14
  15 dnl ===========================
  16 dnl  initialize & set some vars
  17 dnl ===========================
  18
  19 AC_INIT(strongSwan,4.3.2)
  20 AM_INIT_AUTOMAKE(tar-ustar)
  21 AC_SUBST(confdir, '${sysconfdir}')
  22 PKG_PROG_PKG_CONFIG
  23
  24 dnl =================================
  25 dnl  check --enable-xxx & --with-xxx
  26 dnl =================================
  27
  28 AC_ARG_WITH(
  29         [default-pkcs11],
  30         AS_HELP_STRING([--with-default-pkcs11=lib],[set the default PKCS11 library other than "/usr/lib/opensc-pkcs11.so"]),
  31         [AC_DEFINE_UNQUOTED(PKCS11_DEFAULT_LIB, "$withval")],
  32         [AC_DEFINE_UNQUOTED(PKCS11_DEFAULT_LIB, "/usr/lib/opensc-pkcs11.so")]
  33 )
  34
  35 AC_ARG_WITH(
  36         [xauth-module],
  37         AS_HELP_STRING([--with-xauth-module=lib],[set the path to the XAUTH module]),
  38         [AC_DEFINE_UNQUOTED(XAUTH_DEFAULT_LIB, "$withval")],
  39 )
  40
  41 AC_ARG_WITH(
  42         [random-device],
  43         AS_HELP_STRING([--with-random-device=dev],[set the device for real random data other than "/dev/random"]),
  44         [AC_DEFINE_UNQUOTED(DEV_RANDOM, "$withval")],
  45         [AC_DEFINE_UNQUOTED(DEV_RANDOM, "/dev/random")]
  46 )
  47 AC_ARG_WITH(
  48         [resolv-conf],
  49         AS_HELP_STRING([--with-resolv-conf=file],[set the file to use in DNS handler plugin other than "sysconfdir/resolv.conf"]),
  50         [AC_SUBST(resolv_conf, "$withval")],
  51         [AC_SUBST(resolv_conf, "${sysconfdir}/resolv.conf")]
  52 )
  53
  54 AC_ARG_WITH(
  55         [strongswan-conf],
  56         AS_HELP_STRING([--with-strongswan-conf=file],[strongswan.conf file other than "sysconfdir/strongswan.conf"]),
  57         [AC_SUBST(strongswan_conf, "$withval")],
  58         [AC_SUBST(strongswan_conf, "${sysconfdir}/strongswan.conf")]
  59 )
  60
  61 AC_ARG_WITH(
  62         [urandom-device],
  63         AS_HELP_STRING([--with-urandom-device=dev],[set the device for pseudo random data other than "/dev/urandom"]),
  64         [AC_DEFINE_UNQUOTED(DEV_URANDOM, "$withval")],
  65         [AC_DEFINE_UNQUOTED(DEV_URANDOM, "/dev/urandom")]
  66 )
  67
  68 AC_ARG_WITH(
  69         [piddir],
  70         AS_HELP_STRING([--with-piddir=dir],[path for PID and UNIX socket files other than "/var/run"]),
  71         [AC_SUBST(piddir, "$withval")],
  72         [AC_SUBST(piddir, "/var/run")]
  73 )
  74
  75 AC_ARG_WITH(
  76         [ipsecdir],
  77         AS_HELP_STRING([--with-ipsecdir=dir],[installation path for ipsec tools other than "libexecdir/ipsec"]),
  78         [AC_SUBST(ipsecdir, "$withval")],
  79         [AC_SUBST(ipsecdir, "${libexecdir%/}/ipsec")]
  80 )
  81 AC_SUBST(plugindir, "${ipsecdir%/}/plugins")
  82
  83 AC_ARG_WITH(
  84         [plugindir],
  85         AS_HELP_STRING([--with-plugindir=dir],[installation path for plugins other than "ipsecdir/plugins"]),
  86         [AC_SUBST(plugindir, "$withval")],
  87         [AC_SUBST(plugindir, "${ipsecdir%/}/plugins")]
  88 )
  89
  90 AC_ARG_WITH(
  91         [sim-reader],
  92         AS_HELP_STRING([--with-sim-reader=library.so],[library containing the sim_run_alg()/sim_get_triplet() function for EAP-SIM]),
  93         [AC_SUBST(simreader, "$withval")],
  94         [AC_SUBST(simreader, "${plugindir%/}/libeapsim-file.so")]
  95 )
  96
  97 AC_ARG_WITH(
  98         [linux-headers],
  99         AS_HELP_STRING([--with-linux-headers=dir],[use the linux header files in dir instead of the supplied ones in "src/include"]),
 100         [AC_SUBST(linuxdir, "$withval")], [AC_SUBST(linuxdir, "\${top_srcdir}/src/include")]
 101 )
 102 AC_SUBST(LINUX_HEADERS)
 103
 104 AC_ARG_WITH(
 105         [routing-table],
 106         AS_HELP_STRING([--with-routing-table=num],[use routing table for IPsec routes (default: 220)]),
 107         [AC_DEFINE_UNQUOTED(IPSEC_ROUTING_TABLE, $withval) AC_SUBST(IPSEC_ROUTING_TABLE, "$withval")],
 108         [AC_DEFINE_UNQUOTED(IPSEC_ROUTING_TABLE, 220) AC_SUBST(IPSEC_ROUTING_TABLE, "220")]
 109 )
 110
 111 AC_ARG_WITH(
 112         [routing-table-prio],
 113         AS_HELP_STRING([--with-routing-table-prio=prio],[priority for IPsec routing table (default: 220)]),
 114         [AC_DEFINE_UNQUOTED(IPSEC_ROUTING_TABLE_PRIO, $withval) AC_SUBST(IPSEC_ROUTING_TABLE_PRIO, "$withval")],
 115         [AC_DEFINE_UNQUOTED(IPSEC_ROUTING_TABLE_PRIO, 220) AC_SUBST(IPSEC_ROUTING_TABLE_PRIO, "220")]
 116 )
 117
 118 AC_ARG_WITH(
 119         [uid],,[AC_MSG_ERROR([--with-uid is gone, use --with-user instead!])]
 120 )
 121
 122 AC_ARG_WITH(
 123         [gid],,[AC_MSG_ERROR([--with-gid is gone, use --with-group instead!])]
 124 )
 125
 126 AC_ARG_WITH(
 127         [user],
 128         AS_HELP_STRING([--with-user=user],[change user of the daemons to "user" after startup (default is 0).]),
 129         [AC_DEFINE_UNQUOTED(IPSEC_USER, "$withval") AC_SUBST(ipsecuser, "$withval")],
 130         [AC_SUBST(ipsecuser, "root")]
 131 )
 132
 133 AC_ARG_WITH(
 134         [group],
 135         AS_HELP_STRING([--with-group=group],[change group of the daemons to "group" after startup (default is 0).]),
 136         [AC_DEFINE_UNQUOTED(IPSEC_GROUP, "$withval") AC_SUBST(ipsecgroup, "$withval")],
 137         [AC_SUBST(ipsecgroup, "root")]
 138 )
 139
 140 dnl Will be extended to --with-capabilities=libcap|libcap2
 141 AC_ARG_WITH(
 142         [capabilities],
 143         AS_HELP_STRING([--with-capabilities=libcap],[capability dropping using libcap. Currenlty only the value "libcap" is supported (default is NO).]),
 144         [capabilities="$withval"],
 145         [capabilities=no]
 146 )
 147
 148 AC_ARG_ENABLE(
 149         [curl],
 150         AS_HELP_STRING([--enable-curl],[enable CURL fetcher plugin to fetch files via libcurl (default is NO). Requires libcurl.]),
 151         [if test x$enableval = xyes; then
 152                 curl=true
 153         fi]
 154 )
 155
 156 AC_ARG_ENABLE(
 157         [ldap],
 158         AS_HELP_STRING([--enable-ldap],[enable LDAP fetching plugin to fetch files via libldap (default is NO). Requires openLDAP.]),
 159         [if test x$enableval = xyes; then
 160                 ldap=true
 161         fi]
 162 )
 163
 164 AC_ARG_ENABLE(
 165         [aes],
 166         AS_HELP_STRING([--disable-aes],[disable own AES software implementation plugin. (default is NO).]),
 167         [if test x$enableval = xyes; then
 168                 aes=true
 169          else
 170                 aes=false
 171         fi],
 172         aes=true
 173 )
 174
 175 AC_ARG_ENABLE(
 176         [des],
 177         AS_HELP_STRING([--disable-des],[disable own DES/3DES software implementation plugin. (default is NO).]),
 178         [if test x$enableval = xyes; then
 179                 des=true
 180          else
 181                 des=false
 182         fi],
 183         des=true
 184 )
 185
 186 AC_ARG_ENABLE(
 187         [blowfish],
 188         AS_HELP_STRING([--enable-blowfish],[enable Blowfish software implementation plugin (default is NO).]),
 189         [if test x$enableval = xyes; then
 190                 blowfish=true
 191         fi]
 192 )
 193
 194 AC_ARG_ENABLE(
 195         [serpent],
 196         AS_HELP_STRING([--enable-serpent],[enable Serpent software implementation plugin (default is NO).]),
 197         [if test x$enableval = xyes; then
 198                 serpent=true
 199         fi]
 200 )
 201
 202 AC_ARG_ENABLE(
 203         [twofish],
 204         AS_HELP_STRING([--enable-twofish],[enable Twofish software implementation plugin (default is NO).]),
 205         [if test x$enableval = xyes; then
 206                 twofish=true
 207         fi]
 208 )
 209
 210 AC_ARG_ENABLE(
 211         [md4],
 212         AS_HELP_STRING([--enable-md4],[enable MD4 software implementation plugin (default is NO).]),
 213         [if test x$enableval = xyes; then
 214                 md4=true
 215         fi]
 216 )
 217
 218 AC_ARG_ENABLE(
 219         [md5],
 220         AS_HELP_STRING([--disable-md5],[disable own MD5 software implementation plugin. (default is NO).]),
 221         [if test x$enableval = xyes; then
 222                 md5=true
 223          else
 224                 md5=false
 225         fi],
 226         md5=true
 227 )
 228
 229 AC_ARG_ENABLE(
 230         [sha1],
 231         AS_HELP_STRING([--disable-sha1],[disable own SHA1 software implementation plugin. (default is NO).]),
 232         [if test x$enableval = xyes; then
 233                 sha1=true
 234          else
 235                 sha1=false
 236         fi],
 237         sha1=true
 238 )
 239
 240 AC_ARG_ENABLE(
 241         [sha2],
 242         AS_HELP_STRING([--disable-sha2],[disable own SHA256/SHA384/SHA512 software implementation plugin. (default is NO).]),
 243         [if test x$enableval = xyes; then
 244                 sha2=true
 245          else
 246                 sha2=false
 247         fi],
 248         sha2=true
 249 )
 250
 251 AC_ARG_ENABLE(
 252         [fips-prf],
 253         AS_HELP_STRING([--disable-fips-prf],[disable FIPS PRF software implementation plugin. (default is NO).]),
 254         [if test x$enableval = xyes; then
 255                 fips_prf=true
 256          else
 257                 fips_prf=false
 258         fi],
 259         fips_prf=true
 260 )
 261
 262 AC_ARG_ENABLE(
 263         [gmp],
 264         AS_HELP_STRING([--disable-gmp],[disable own GNU MP (libgmp) based crypto implementation plugin. (default is NO).]),
 265         [if test x$enableval = xyes; then
 266                 gmp=true
 267          else
 268                 gmp=false
 269         fi],
 270         gmp=true
 271 )
 272
 273 AC_ARG_ENABLE(
 274         [random],
 275         AS_HELP_STRING([--disable-random],[disable RNG implementation on top of /dev/(u)random. (default is NO).]),
 276         [if test x$enableval = xyes; then
 277                 random=true
 278          else
 279                 random=false
 280         fi],
 281         random=true
 282 )
 283
 284 AC_ARG_ENABLE(
 285         [x509],
 286         AS_HELP_STRING([--disable-x509],[disable own X509 certificate implementation plugin. (default is NO).]),
 287         [if test x$enableval = xyes; then
 288                 x509=true
 289          else
 290                 x509=false
 291         fi],
 292         x509=true
 293 )
 294
 295 AC_ARG_ENABLE(
 296         [pubkey],
 297         AS_HELP_STRING([--disable-pubkey],[disable RAW public key support plugin. (default is NO).]),
 298         [if test x$enableval = xyes; then
 299                 pubkey=true
 300          else
 301                 pubkey=false
 302         fi],
 303         pubkey=true
 304 )
 305
 306 AC_ARG_ENABLE(
 307         [hmac],
 308         AS_HELP_STRING([--disable-hmac],[disable HMAC crypto implementation plugin. (default is NO).]),
 309         [if test x$enableval = xyes; then
 310                 hmac=true
 311          else
 312                 hmac=false
 313         fi],
 314         hmac=true
 315 )
 316
 317 AC_ARG_ENABLE(
 318         [xcbc],
 319         AS_HELP_STRING([--disable-xcbc],[disable xcbc crypto implementation plugin. (default is NO).]),
 320         [if test x$enableval = xyes; then
 321                 xcbc=true
 322          else
 323                 xcbc=false
 324         fi],
 325         xcbc=true
 326 )
 327
 328 AC_ARG_ENABLE(
 329         [mysql],
 330         AS_HELP_STRING([--enable-mysql],[enable MySQL database support (default is NO). Requires libmysqlclient_r.]),
 331         [if test x$enableval = xyes; then
 332                 mysql=true
 333         fi]
 334 )
 335
 336 AC_ARG_ENABLE(
 337         [sqlite],
 338         AS_HELP_STRING([--enable-sqlite],[enable SQLite database support (default is NO). Requires libsqlite3.]),
 339         [if test x$enableval = xyes; then
 340                 sqlite=true
 341         fi]
 342 )
 343
 344 AC_ARG_ENABLE(
 345         [stroke],
 346         AS_HELP_STRING([--disable-stroke],[disable charons stroke (pluto compatibility) configuration backend. (default is NO).]),
 347         [if test x$enableval = xyes; then
 348                 stroke=true
 349          else
 350                 stroke=false
 351         fi],
 352         stroke=true
 353 )
 354
 355 AC_ARG_ENABLE(
 356         [medsrv],
 357         AS_HELP_STRING([--enable-medsrv],[enable mediation server web frontend and daemon plugin (default is NO).]),
 358         [if test x$enableval = xyes; then
 359                 medsrv=true
 360         fi]
 361 )
 362
 363 AC_ARG_ENABLE(
 364         [medcli],
 365         AS_HELP_STRING([--enable-medcli],[enable mediation client configuration database plugin (default is NO).]),
 366         [if test x$enableval = xyes; then
 367                 medcli=true
 368         fi]
 369 )
 370
 371 AC_ARG_ENABLE(
 372         [smp],
 373         AS_HELP_STRING([--enable-smp],[enable SMP configuration and control interface (default is NO). Requires libxml.]),
 374         [if test x$enableval = xyes; then
 375                 smp=true
 376         fi]
 377 )
 378
 379 AC_ARG_ENABLE(
 380         [sql],
 381         AS_HELP_STRING([--enable-sql],[enable SQL database configuration backend (default is NO).]),
 382         [if test x$enableval = xyes; then
 383                 sql=true
 384         fi]
 385 )
 386
 387 AC_ARG_ENABLE(
 388         [smartcard],
 389         AS_HELP_STRING([--enable-smartcard],[enable smartcard support (default is NO).]),
 390         [if test x$enableval = xyes; then
 391                 smartcard=true
 392         fi]
 393 )
 394
 395 AC_ARG_ENABLE(
 396         [cisco-quirks],
 397         AS_HELP_STRING([--enable-cisco-quirks],[enable support of Cisco VPN client (default is NO).]),
 398         [if test x$enableval = xyes; then
 399                 cisco_quirks=true
 400         fi]
 401 )
 402
 403 AC_ARG_ENABLE(
 404         [leak-detective],
 405         AS_HELP_STRING([--enable-leak-detective],[enable malloc hooks to find memory leaks (default is NO).]),
 406         [if test x$enableval = xyes; then
 407                 leak_detective=true
 408         fi]
 409 )
 410
 411 AC_ARG_ENABLE(
 412         [lock-profiler],
 413         AS_HELP_STRING([--enable-lock-profiler],[enable lock/mutex profiling code (default is NO).]),
 414         [if test x$enableval = xyes; then
 415                 lock_profiler=true
 416         fi]
 417 )
 418
 419 AC_ARG_ENABLE(
 420         [unit-tests],
 421         AS_HELP_STRING([--enable-unit-tests],[enable unit tests on IKEv2 daemon startup (default is NO).]),
 422         [if test x$enableval = xyes; then
 423                 unittest=true
 424         fi]
 425 )
 426
 427 AC_ARG_ENABLE(
 428         [load-tests],
 429         AS_HELP_STRING([--enable-load-tests],[enable load testing plugin for IKEv2 daemon (default is NO).]),
 430         [if test x$enableval = xyes; then
 431                 loadtest=true
 432         fi]
 433 )
 434
 435 AC_ARG_ENABLE(
 436         [eap-sim],
 437         AS_HELP_STRING([--enable-eap-sim],[build SIM authenication module for EAP (default is NO).]),
 438         [if test x$enableval = xyes; then
 439                 eap_sim=true
 440         fi]
 441 )
 442
 443 AC_ARG_ENABLE(
 444         [eap-sim-file],
 445         AS_HELP_STRING([--enable-eap-sim-file],[build EAP-SIM backend based on a triplet file (default is NO).]),
 446         [if test x$enableval = xyes; then
 447                 eap_sim_file=true
 448         fi]
 449 )
 450
 451 AC_ARG_ENABLE(
 452         [eap-identity],
 453         AS_HELP_STRING([--enable-eap-identity],[build EAP module providing EAP-Identity helper (default is NO).]),
 454         [if test x$enableval = xyes; then
 455                 eap_identity=true
 456         fi]
 457 )
 458
 459 AC_ARG_ENABLE(
 460         [eap-md5],
 461         AS_HELP_STRING([--enable-eap-md5],[build MD5 (CHAP) authenication module for EAP (default is NO).]),
 462         [if test x$enableval = xyes; then
 463                 eap_md5=true
 464         fi]
 465 )
 466
 467 AC_ARG_ENABLE(
 468         [eap-gtc],
 469         AS_HELP_STRING([--enable-eap-gtc],[build PAM based GTC authenication module for EAP (default is NO).]),
 470         [if test x$enableval = xyes; then
 471                 eap_gtc=true
 472         fi]
 473 )
 474
 475 AC_ARG_ENABLE(
 476         [eap-aka],
 477         AS_HELP_STRING([--enable-eap-aka],[build AKA authentication module for EAP (default is NO).]),
 478         [if test x$enableval = xyes; then
 479                 eap_aka=true
 480         fi]
 481 )
 482
 483 AC_ARG_ENABLE(
 484         [eap-mschapv2],
 485         AS_HELP_STRING([--enable-eap-mschapv2],[build MS-CHAPv2 authenication module for EAP (default is NO).]),
 486         [if test x$enableval = xyes; then
 487                 eap_mschapv2=true
 488         fi]
 489 )
 490
 491 AC_ARG_ENABLE(
 492         [eap-radius],
 493         AS_HELP_STRING([--enable-eap-radius],[build RADIUS proxy authenication module for EAP (default is NO).]),
 494         [if test x$enableval = xyes; then
 495                 eap_radius=true
 496         fi]
 497 )
 498
 499 AC_ARG_ENABLE(
 500         [kernel-netlink],
 501         AS_HELP_STRING([--disable-kernel-netlink],[disable the netlink kernel interface. (default is NO).]),
 502         [if test x$enableval = xyes; then
 503                 kernel_netlink=true
 504          else
 505                 kernel_netlink=false
 506         fi],
 507         kernel_netlink=true
 508 )
 509
 510 AC_ARG_ENABLE(
 511         [kernel-pfkey],
 512         AS_HELP_STRING([--enable-kernel-pfkey],[enable the PF_KEY kernel interface. (default is NO).]),
 513         [if test x$enableval = xyes; then
 514                 kernel_pfkey=true
 515         fi]
 516 )
 517
 518 AC_ARG_ENABLE(
 519         [kernel-pfroute],
 520         AS_HELP_STRING([--enable-kernel-pfroute],[enable the PF_ROUTE kernel interface. (default is NO).]),
 521         [if test x$enableval = xyes; then
 522                 kernel_pfroute=true
 523         fi]
 524 )
 525
 526 AC_ARG_ENABLE(
 527         [kernel-klips],
 528         AS_HELP_STRING([--enable-kernel-klips],[enable the KLIPS kernel interface. (default is NO).]),
 529         [if test x$enableval = xyes; then
 530                 kernel_klips=true
 531         fi]
 532 )
 533
 534 AC_ARG_ENABLE(
 535         [nat-transport],
 536         AS_HELP_STRING([--enable-nat-transport],[enable NAT traversal with IPsec transport mode (default is NO).]),
 537         [if test x$enableval = xyes; then
 538                 nat_transport=true
 539         fi]
 540 )
 541
 542 AC_ARG_ENABLE(
 543         [vendor-id],
 544         AS_HELP_STRING([--disable-vendor-id],[disable the sending of the strongSwan vendor ID (default is NO).]),
 545         [if test x$enableval = xyes; then
 546                 vendor_id=true
 547          else
 548                 vendor_id=false
 549         fi],
 550         vendor_id=true
 551 )
 552
 553 AC_ARG_ENABLE(
 554         [xauth-vid],
 555         AS_HELP_STRING([--disable-xauth-vid],[disable the sending of the XAUTH vendor ID (default is NO).]),
 556         [if test x$enableval = xyes; then
 557                 xauth_vid=true
 558          else
 559                 xauth_vid=false
 560         fi],
 561         xauth_vid=true
 562 )
 563
 564 AC_ARG_ENABLE(
 565         [dumm],
 566         AS_HELP_STRING([--enable-dumm],[build the DUMM UML test framework (default is NO).]),
 567         [if test x$enableval = xyes; then
 568                 dumm=true
 569         fi]
 570 )
 571
 572 AC_ARG_ENABLE(
 573         [fast],
 574         AS_HELP_STRING([--enable-fast],[build libfast (FastCGI Application Server w/ templates (default is NO).]),
 575         [if test x$enableval = xyes; then
 576                 fast=true
 577         fi]
 578 )
 579
 580 AC_ARG_ENABLE(
 581         [manager],
 582         AS_HELP_STRING([--enable-manager],[build web management console (default is NO).]),
 583         [if test x$enableval = xyes; then
 584                 manager=true
 585                 xml=true
 586         fi]
 587 )
 588
 589 AC_ARG_ENABLE(
 590         [mediation],
 591         AS_HELP_STRING([--enable-mediation],[enable IKEv2 Mediation Extension (default is NO).]),
 592         [if test x$enableval = xyes; then
 593                 me=true
 594         fi]
 595 )
 596
 597 AC_ARG_ENABLE(
 598         [integrity-test],
 599         AS_HELP_STRING([--enable-integrity-test],[enable the integrity test of the crypto library (default is NO).]),
 600         [if test x$enableval = xyes; then
 601                 integrity_test=true
 602         fi]
 603 )
 604
 605 AC_ARG_ENABLE(
 606         [self-test],
 607         AS_HELP_STRING([--disable-self-test],[disable the self-test of the crypto library (default is NO).]),
 608         [if test x$enableval = xyes; then
 609                 self_test=true
 610          else
 611                 self_test=false
 612         fi],
 613         self_test=true
 614 )
 615
 616 AC_ARG_ENABLE(
 617         [pluto],
 618         AS_HELP_STRING([--disable-pluto],[disable the IKEv1 keying daemon pluto. (default is NO).]),
 619         [if test x$enableval = xyes; then
 620                 pluto=true
 621          else
 622                 pluto=false
 623         fi],
 624         pluto=true
 625 )
 626
 627 AC_ARG_ENABLE(
 628         [threads],
 629         AS_HELP_STRING([--disable-threads],[disable the use of threads in pluto. Charon always uses threads. (default is NO).]),
 630         [if test x$enableval = xyes; then
 631                 threads=true
 632          else
 633                 threads=false
 634         fi],
 635         threads=true
 636 )
 637
 638 AC_ARG_ENABLE(
 639         [charon],
 640         AS_HELP_STRING([--disable-charon],[disable the IKEv2 keying daemon charon. (default is NO).]),
 641         [if test x$enableval = xyes; then
 642                 charon=true
 643          else
 644                 charon=false
 645         fi],
 646         charon=true
 647 )
 648
 649 AC_ARG_ENABLE(
 650         [tools],
 651         AS_HELP_STRING([--disable-tools],[disable additional utilities (openac and scepclient). (default is NO).]),
 652         [if test x$enableval = xyes; then
 653                 tools=true
 654          else
 655                 tools=false
 656         fi],
 657         tools=true
 658 )
 659
 660 AC_ARG_ENABLE(
 661         [updown],
 662         AS_HELP_STRING([--disable-updown],[disable updown firewall script plugin. (default is NO).]),
 663         [if test x$enableval = xyes; then
 664                 updown=true
 665          else
 666                 updown=false
 667         fi],
 668         updown=true
 669 )
 670
 671 AC_ARG_ENABLE(
 672         [attr],
 673         AS_HELP_STRING([--disable-attr],[disable strongswan.conf based configuration attribute plugin. (default is NO).]),
 674         [if test x$enableval = xyes; then
 675                 attr=true
 676          else
 677                 attr=false
 678         fi],
 679         attr=true
 680 )
 681
 682 AC_ARG_ENABLE(
 683         [resolv-conf],
 684         AS_HELP_STRING([--disable-resolv-conf],[disable resolv.conf DNS handler plugin. (default is NO).]),
 685         [if test x$enableval = xyes; then
 686                 resolvconf=true
 687          else
 688                 resolvconf=false
 689         fi],
 690         resolvconf=true
 691 )
 692
 693 AC_ARG_ENABLE(
 694         [padlock],
 695         AS_HELP_STRING([--enable-padlock],[enables VIA Padlock crypto plugin. (default is NO).]),
 696         [if test x$enableval = xyes; then
 697                 padlock=true
 698          else
 699                 padlock=false
 700         fi],
 701 )
 702
 703 AC_ARG_ENABLE(
 704         [openssl],
 705         AS_HELP_STRING([--enable-openssl],[enables the OpenSSL crypto plugin. (default is NO).]),
 706         [if test x$enableval = xyes; then
 707                 openssl=true
 708          else
 709                 openssl=false
 710         fi],
 711 )
 712
 713 AC_ARG_ENABLE(
 714         [gcrypt],
 715         AS_HELP_STRING([--enable-gcrypt],[enables the libgcrypt plugin. (default is NO).]),
 716         [if test x$enableval = xyes; then
 717                 gcrypt=true
 718          else
 719                 gcrypt=false
 720         fi],
 721 )
 722
 723 AC_ARG_ENABLE(
 724         [agent],
 725         AS_HELP_STRING([--enable-agent],[enables the ssh-agent signing plugin. (default is NO).]),
 726         [if test x$enableval = xyes; then
 727                 agent=true
 728          else
 729                 agent=false
 730         fi],
 731 )
 732
 733 AC_ARG_ENABLE(
 734         [uci],
 735         AS_HELP_STRING([--enable-uci],[enable OpenWRT UCI configuration plugin (default is NO).]),
 736         [if test x$enableval = xyes; then
 737                 uci=true
 738         fi]
 739 )
 740
 741 AC_ARG_ENABLE(
 742         [nm],
 743         AS_HELP_STRING([--enable-nm],[enable NetworkManager plugin (default is NO).]),
 744         [if test x$enableval = xyes; then
 745                 nm=true
 746         fi]
 747 )
 748
 749 AC_ARG_ENABLE(
 750         [vstr],
 751         AS_HELP_STRING([--enable-vstr],[enforce using the Vstr string library to replace glibc-like printf hooks (default is NO).]),
 752         [if test x$enableval = xyes; then
 753                 vstr=true
 754         fi]
 755 )
 756
 757 dnl =========================
 758 dnl  set up compiler and flags
 759 dnl =========================
 760
 761 if test -z "$CFLAGS"; then
 762         AC_SUBST(CFLAGS, "-g -O2 -Wall -Wno-format -Wno-pointer-sign -Wno-strict-aliasing")
 763 fi
 764 AC_PROG_CC
 765 AC_C_BIGENDIAN
 766
 767 dnl =========================
 768 dnl  check required programs
 769 dnl =========================
 770
 771 AC_PROG_INSTALL
 772 AC_PROG_LIBTOOL
 773 AC_PROG_LEX
 774 AC_PROG_YACC
 775 AC_PATH_PROG([GPERF], [gperf], [], [$PATH:/bin:/usr/bin:/usr/local/bin])
 776 AC_PATH_PROG([PERL], [perl], [], [$PATH:/bin:/usr/bin:/usr/local/bin])
 777
 778 dnl =========================
 779 dnl  dependency calculation
 780 dnl =========================
 781
 782 if test x$pluto = xtrue; then
 783         gmp=true;
 784 fi
 785
 786 if test x$tools = xtrue; then
 787         gmp=true;
 788 fi
 789
 790 if test x$smp = xtrue; then
 791         xml=true
 792 fi
 793
 794 if test x$manager = xtrue; then
 795         fast=true
 796 fi
 797
 798 if test x$medsrv = xtrue; then
 799         me=true
 800         fast=true
 801 fi
 802
 803 if test x$medcli = xtrue; then
 804         me=true
 805 fi
 806
 807 dnl ===========================================
 808 dnl  check required libraries and header files
 809 dnl ===========================================
 810
 811 AC_HEADER_STDBOOL
 812
 813 saved_LIBS=$LIBS
 814 LIBS=""
 815 AC_SEARCH_LIBS(dlopen, dl, [DLLIB=$LIBS])
 816 LIBS=$saved_LIBS
 817 AC_SUBST(DLLIB)
 818
 819 AC_MSG_CHECKING(for dladdr)
 820 AC_TRY_COMPILE(
 821         [#define _GNU_SOURCE
 822          #include <dlfcn.h>],
 823         [Dl_info* info = 0;
 824          dladdr(0, info);],
 825         [AC_MSG_RESULT([yes]); AC_DEFINE([HAVE_DLADDR])],
 826         [AC_MSG_RESULT([no])]
 827 )
 828
 829 AC_CHECK_FUNCS(backtrace)
 830 AC_CHECK_FUNCS(prctl)
 831 AC_CHECK_FUNCS(gethostbyname_r)
 832
 833 AC_CHECK_HEADERS(net/pfkeyv2.h netipsec/ipsec.h netinet6/ipsec.h)
 834
 835 AC_CHECK_MEMBERS([struct sockaddr.sa_len], [], [],
 836 [
 837         #include <sys/types.h>
 838         #include <sys/socket.h>
 839 ])
 840
 841 AC_CHECK_MEMBERS([struct sadb_x_policy.sadb_x_policy_priority], [], [],
 842 [
 843         #include <sys/types.h>
 844         #ifdef HAVE_NET_PFKEYV2_H
 845         #include <net/pfkeyv2.h>
 846         #else
 847         #include <stdint.h>
 848         #include <linux/pfkeyv2.h>
 849         #endif
 850 ])
 851
 852 AC_MSG_CHECKING([for IPSEC_MODE_BEET])
 853 AC_TRY_COMPILE(
 854         [#include <sys/types.h>
 855         #ifdef HAVE_NETIPSEC_IPSEC_H
 856         #include <netipsec/ipsec.h>
 857         #elif defined(HAVE_NETINET6_IPSEC_H)
 858         #include <netinet6/ipsec.h>
 859         #else
 860         #include <stdint.h>
 861         #include <linux/ipsec.h>
 862         #endif],
 863         [int mode = IPSEC_MODE_BEET;
 864          return mode;],
 865         [AC_MSG_RESULT([yes]); AC_DEFINE([HAVE_IPSEC_MODE_BEET])],
 866         [AC_MSG_RESULT([no])]
 867 )
 868
 869 AC_MSG_CHECKING([for IPSEC_DIR_FWD])
 870 AC_TRY_COMPILE(
 871         [#include <sys/types.h>
 872         #ifdef HAVE_NETIPSEC_IPSEC_H
 873         #include <netipsec/ipsec.h>
 874         #elif defined(HAVE_NETINET6_IPSEC_H)
 875         #include <netinet6/ipsec.h>
 876         #else
 877         #include <stdint.h>
 878         #include <linux/ipsec.h>
 879         #endif],
 880         [int dir = IPSEC_DIR_FWD;
 881          return dir;],
 882         [AC_MSG_RESULT([yes]); AC_DEFINE([HAVE_IPSEC_DIR_FWD])],
 883         [AC_MSG_RESULT([no])]
 884 )
 885
 886 AC_MSG_CHECKING([for gcc atomic operations])
 887 AC_TRY_RUN(
 888 [
 889         int main() {
 890                 volatile int ref = 1;
 891                 __sync_fetch_and_add (&ref, 1);
 892                 __sync_sub_and_fetch (&ref, 1);
 893                 /* Make sure test fails if operations are not supported */
 894                 __sync_val_compare_and_swap(&ref, 1, 0);
 895                 return ref;
 896         }
 897 ],
 898 [AC_MSG_RESULT([yes]); AC_DEFINE(HAVE_GCC_ATOMIC_OPERATIONS)],
 899 [AC_MSG_RESULT([no])],
 900 [AC_MSG_RESULT([no])])
 901
 902 AC_CHECK_FUNC(
 903         [register_printf_function],
 904         [AC_DEFINE(HAVE_PRINTF_HOOKS)],
 905         [
 906                 AC_MSG_NOTICE([printf does not support custom format specifiers!])
 907                 vstr=true
 908         ]
 909 )
 910
 911 if test x$vstr = xtrue; then
 912         AC_HAVE_LIBRARY([vstr],[LIBS="$LIBS"],[AC_MSG_ERROR([Vstr string library not found])])
 913         AC_DEFINE(USE_VSTR)
 914 fi
 915
 916 if test x$gmp = xtrue; then
 917         AC_HAVE_LIBRARY([gmp],[LIBS="$LIBS"],[AC_MSG_ERROR([GNU Multi Precision library gmp not found])])
 918         AC_MSG_CHECKING([gmp.h version >= 4.1.4])
 919         AC_TRY_COMPILE(
 920                 [#include "gmp.h"],
 921                 [
 922                         #if (__GNU_MP_VERSION*100 +  __GNU_MP_VERSION_MINOR*10 + __GNU_MP_VERSION_PATCHLEVEL) < 414
 923                                 #error bad gmp
 924                         #endif
 925                 ],
 926                 [AC_MSG_RESULT([yes])], [AC_MSG_RESULT([no]); AC_MSG_ERROR([No usable gmp.h found!])]
 927         )
 928 fi
 929
 930 if test x$ldap = xtrue; then
 931         AC_HAVE_LIBRARY([ldap],[LIBS="$LIBS"],[AC_MSG_ERROR([LDAP library ldap not found])])
 932         AC_HAVE_LIBRARY([lber],[LIBS="$LIBS"],[AC_MSG_ERROR([LDAP library lber not found])])
 933         AC_CHECK_HEADER([ldap.h],,[AC_MSG_ERROR([LDAP header ldap.h not found!])])
 934 fi
 935
 936 if test x$curl = xtrue; then
 937         AC_HAVE_LIBRARY([curl],[LIBS="$LIBS"],[AC_MSG_ERROR([CURL library curl not found])])
 938         AC_CHECK_HEADER([curl/curl.h],,[AC_MSG_ERROR([CURL header curl/curl.h not found!])])
 939 fi
 940
 941 if test x$xml = xtrue; then
 942         PKG_CHECK_MODULES(xml, [libxml-2.0])
 943         AC_SUBST(xml_CFLAGS)
 944         AC_SUBST(xml_LIBS)
 945 fi
 946
 947 if test x$dumm = xtrue; then
 948         PKG_CHECK_MODULES(gtk, [gtk+-2.0 vte])
 949         AC_SUBST(gtk_CFLAGS)
 950         AC_SUBST(gtk_LIBS)
 951         AC_CHECK_PROGS(RUBY, ruby)
 952         AC_MSG_CHECKING([for Ruby header files])
 953         if test -n "$RUBY"; then
 954                 RUBYDIR=`($RUBY -rmkmf -e 'print Config::CONFIG[["archdir"]] || $archdir') 2>/dev/null`
 955                 if test -n "$RUBYDIR"; then
 956                         dirs="$RUBYDIR"
 957                         RUBYINCLUDE=none
 958                         for i in $dirs; do
 959                                 if test -r $i/ruby.h; then
 960                                         AC_MSG_RESULT([$i])
 961                                         RUBYINCLUDE="-I$i"
 962                                         break;
 963                                 fi
 964                         done
 965                         if test x"$RUBYINCLUDE" = xnone; then
 966                                 AC_MSG_ERROR([ruby.h not found])
 967                         fi
 968                         AC_SUBST(RUBYINCLUDE)
 969                 else
 970                         AC_MSG_ERROR([unable to determine ruby configuration])
 971                 fi
 972         else
 973                 AC_MSG_ERROR([don't know how to run ruby])
 974         fi
 975 fi
 976
 977 if test x$fast = xtrue; then
 978         AC_HAVE_LIBRARY([neo_cgi],[LIBS="$LIBS"],[AC_MSG_ERROR([ClearSilver library neo_cgi not found!])])
 979         AC_HAVE_LIBRARY([neo_utl],[LIBS="$LIBS"],[AC_MSG_ERROR([ClearSilver library neo_utl not found!])])
 980         AC_HAVE_LIBRARY([z],[LIBS="$LIBS"],[AC_MSG_ERROR([ClearSilver dependency zlib not found!])])
 981 dnl autoconf does not like CamelCase!? How to fix this?
 982 dnl     AC_CHECK_HEADER([ClearSilver/ClearSilver.h],,[AC_MSG_ERROR([ClearSilver header file ClearSilver/ClearSilver.h not found!])])
 983
 984         AC_HAVE_LIBRARY([fcgi],[LIBS="$LIBS"],[AC_MSG_ERROR([FastCGI library fcgi not found!])])
 985         AC_CHECK_HEADER([fcgiapp.h],,[AC_MSG_ERROR([FastCGI header file fcgiapp.h not found!])])
 986 fi
 987
 988 if test x$mysql = xtrue; then
 989         AC_HAVE_LIBRARY([mysqlclient_r],[LIBS="$LIBS"],[AC_MSG_ERROR([MySQL library mysqlclient_r not found])])
 990         AC_CHECK_HEADER([mysql/mysql.h],,[AC_MSG_ERROR([MySQL header mysql/mysql.h not found!])])
 991 fi
 992
 993 if test x$sqlite = xtrue; then
 994         AC_HAVE_LIBRARY([sqlite3],[LIBS="$LIBS"],[AC_MSG_ERROR([SQLite library sqlite3 not found])])
 995         AC_CHECK_HEADER([sqlite3.h],,[AC_MSG_ERROR([SQLite header sqlite3.h not found!])])
 996         AC_MSG_CHECKING([sqlite3_prepare_v2])
 997         AC_TRY_COMPILE(
 998                 [#include <sqlite3.h>],
 999                 [
1000                         void *test = sqlite3_prepare_v2;
1001                 ],
1002                 [AC_MSG_RESULT([yes])]; AC_DEFINE_UNQUOTED(HAVE_SQLITE3_PREPARE_V2, 1), [AC_MSG_RESULT([no])])
1003         AC_MSG_CHECKING([sqlite3.h version >= 3.3.1])
1004         AC_TRY_COMPILE(
1005                 [#include <sqlite3.h>],
1006                 [
1007                         #if SQLITE_VERSION_NUMBER < 3003001
1008                                 #error bad sqlite
1009                         #endif
1010                 ],
1011                 [AC_MSG_RESULT([yes])], [AC_MSG_RESULT([no]); AC_MSG_ERROR([SQLite version >= 3.3.1 required!])])
1012 fi
1013
1014 if test x$openssl = xtrue; then
1015         AC_HAVE_LIBRARY([crypto],[LIBS="$LIBS"],[AC_MSG_ERROR([OpenSSL crypto library not found])])
1016         AC_CHECK_HEADER([openssl/evp.h],,[AC_MSG_ERROR([OpenSSL header openssl/evp.h not found!])])
1017 fi
1018
1019 if test x$gcrypt = xtrue; then
1020         AM_PATH_LIBGCRYPT(,,[AC_MSG_ERROR([libgcrypt not found!])])
1021 fi
1022
1023 if test x$uci = xtrue; then
1024         AC_HAVE_LIBRARY([uci],[LIBS="$LIBS"],[AC_MSG_ERROR([UCI library libuci not found])])
1025         AC_CHECK_HEADER([uci.h],,[AC_MSG_ERROR([UCI header uci.h not found!])])
1026 fi
1027
1028 if test x$nm = xtrue; then
1029         PKG_CHECK_MODULES(nm, [NetworkManager libnm_glib_vpn gthread-2.0])
1030         AC_SUBST(nm_CFLAGS)
1031         AC_SUBST(nm_LIBS)
1032 fi
1033
1034 if test x$eap_gtc = xtrue; then
1035         AC_HAVE_LIBRARY([pam],[LIBS="$LIBS"],[AC_MSG_ERROR([PAM library not found])])
1036         AC_CHECK_HEADER([security/pam_appl.h],,[AC_MSG_ERROR([PAM header security/pam_appl.h not found!])])
1037 fi
1038
1039 if test x$capabilities = xlibcap; then
1040         AC_HAVE_LIBRARY([cap],[LIBS="$LIBS"],[AC_MSG_ERROR([libcap library not found])])
1041         AC_CHECK_HEADER([sys/capability.h],,[AC_MSG_ERROR([libcap header sys/capability.h not found!])])
1042 fi
1043
1044 dnl ======================================
1045 dnl  collect all plugins for libstrongswan
1046 dnl ======================================
1047
1048 libstrongswan_plugins=
1049 pluto_plugins=
1050
1051 if test x$curl = xtrue; then
1052         libstrongswan_plugins=${libstrongswan_plugins}" curl"
1053         pluto_plugins=${pluto_plugins}" curl"
1054 fi
1055 if test x$ldap = xtrue; then
1056         libstrongswan_plugins=${libstrongswan_plugins}" ldap"
1057         pluto_plugins=${pluto_plugins}" ldap"
1058 fi
1059 if test x$aes = xtrue; then
1060         libstrongswan_plugins=${libstrongswan_plugins}" aes"
1061         pluto_plugins=${pluto_plugins}" aes"
1062 fi
1063 if test x$des = xtrue; then
1064         libstrongswan_plugins=${libstrongswan_plugins}" des"
1065         pluto_plugins=${pluto_plugins}" des"
1066 fi
1067 if test x$blowfish = xtrue; then
1068         libstrongswan_plugins=${libstrongswan_plugins}" blowfish"
1069         pluto_plugins=${pluto_plugins}" blowfish"
1070 fi
1071 if test x$serpent = xtrue; then
1072         pluto_plugins=${pluto_plugins}" serpent"
1073 fi
1074 if test x$twofish = xtrue; then
1075         pluto_plugins=${pluto_plugins}" twofish"
1076 fi
1077 if test x$sha1 = xtrue; then
1078         libstrongswan_plugins=${libstrongswan_plugins}" sha1"
1079         pluto_plugins=${pluto_plugins}" sha1"
1080 fi
1081 if test x$sha2 = xtrue; then
1082         libstrongswan_plugins=${libstrongswan_plugins}" sha2"
1083         pluto_plugins=${pluto_plugins}" sha2"
1084 fi
1085 if test x$md4 = xtrue; then
1086         libstrongswan_plugins=${libstrongswan_plugins}" md4"
1087 fi
1088 if test x$md5 = xtrue; then
1089         libstrongswan_plugins=${libstrongswan_plugins}" md5"
1090         pluto_plugins=${pluto_plugins}" md5"
1091 fi
1092 if test x$fips_prf = xtrue; then
1093         libstrongswan_plugins=${libstrongswan_plugins}" fips-prf"
1094 fi
1095 if test x$random = xtrue; then
1096         libstrongswan_plugins=${libstrongswan_plugins}" random"
1097         pluto_plugins=${pluto_plugins}" random"
1098 fi
1099 if test x$x509 = xtrue; then
1100         libstrongswan_plugins=${libstrongswan_plugins}" x509"
1101 fi
1102 if test x$pubkey = xtrue; then
1103         libstrongswan_plugins=${libstrongswan_plugins}" pubkey"
1104         pluto_plugins=${pluto_plugins}" pubkey"
1105 fi
1106 if test x$xcbc = xtrue; then
1107         libstrongswan_plugins=${libstrongswan_plugins}" xcbc"
1108 fi
1109 if test x$hmac = xtrue; then
1110         libstrongswan_plugins=${libstrongswan_plugins}" hmac"
1111         pluto_plugins=${pluto_plugins}" hmac"
1112 fi
1113 if test x$mysql = xtrue; then
1114         libstrongswan_plugins=${libstrongswan_plugins}" mysql"
1115 fi
1116 if test x$sqlite = xtrue; then
1117         libstrongswan_plugins=${libstrongswan_plugins}" sqlite"
1118 fi
1119 if test x$padlock = xtrue; then
1120         libstrongswan_plugins=${libstrongswan_plugins}" padlock"
1121 fi
1122 if test x$openssl = xtrue; then
1123         libstrongswan_plugins=${libstrongswan_plugins}" openssl"
1124         pluto_plugins=${pluto_plugins}" openssl"
1125 fi
1126 if test x$gcrypt = xtrue; then
1127         libstrongswan_plugins=${libstrongswan_plugins}" gcrypt"
1128         pluto_plugins=${pluto_plugins}" gcrypt"
1129 fi
1130 if test x$agent = xtrue; then
1131         libstrongswan_plugins=${libstrongswan_plugins}" agent"
1132 fi
1133 if test x$gmp = xtrue; then
1134         libstrongswan_plugins=${libstrongswan_plugins}" gmp"
1135         pluto_plugins=${pluto_plugins}" gmp"
1136 fi
1137
1138 AC_SUBST(libstrongswan_plugins)
1139 AC_SUBST(pluto_plugins)
1140
1141 dnl =========================
1142 dnl  set Makefile.am vars
1143 dnl =========================
1144
1145 dnl libstrongswan plugins
1146 dnl =====================
1147 AM_CONDITIONAL(USE_CURL, test x$curl = xtrue)
1148 AM_CONDITIONAL(USE_LDAP, test x$ldap = xtrue)
1149 AM_CONDITIONAL(USE_AES, test x$aes = xtrue)
1150 AM_CONDITIONAL(USE_DES, test x$des = xtrue)
1151 AM_CONDITIONAL(USE_BLOWFISH, test x$blowfish = xtrue)
1152 AM_CONDITIONAL(USE_SERPENT, test x$serpent = xtrue)
1153 AM_CONDITIONAL(USE_TWOFISH, test x$twofish = xtrue)
1154 AM_CONDITIONAL(USE_MD4, test x$md4 = xtrue)
1155 AM_CONDITIONAL(USE_MD5, test x$md5 = xtrue)
1156 AM_CONDITIONAL(USE_SHA1, test x$sha1 = xtrue)
1157 AM_CONDITIONAL(USE_SHA2, test x$sha2 = xtrue)
1158 AM_CONDITIONAL(USE_FIPS_PRF, test x$fips_prf = xtrue)
1159 AM_CONDITIONAL(USE_GMP, test x$gmp = xtrue)
1160 AM_CONDITIONAL(USE_RANDOM, test x$random = xtrue)
1161 AM_CONDITIONAL(USE_X509, test x$x509 = xtrue)
1162 AM_CONDITIONAL(USE_PUBKEY, test x$pubkey = xtrue)
1163 AM_CONDITIONAL(USE_HMAC, test x$hmac = xtrue)
1164 AM_CONDITIONAL(USE_XCBC, test x$xcbc = xtrue)
1165 AM_CONDITIONAL(USE_MYSQL, test x$mysql = xtrue)
1166 AM_CONDITIONAL(USE_SQLITE, test x$sqlite = xtrue)
1167 AM_CONDITIONAL(USE_PADLOCK, test x$padlock = xtrue)
1168 AM_CONDITIONAL(USE_OPENSSL, test x$openssl = xtrue)
1169 AM_CONDITIONAL(USE_GCRYPT, test x$gcrypt = xtrue)
1170 AM_CONDITIONAL(USE_AGENT, test x$agent = xtrue)
1171
1172 dnl charon plugins
1173 dnl ==============
1174 AM_CONDITIONAL(USE_STROKE, test x$stroke = xtrue)
1175 AM_CONDITIONAL(USE_MEDSRV, test x$medsrv = xtrue)
1176 AM_CONDITIONAL(USE_MEDCLI, test x$medcli = xtrue)
1177 AM_CONDITIONAL(USE_NM, test x$nm = xtrue)
1178 AM_CONDITIONAL(USE_UCI, test x$uci = xtrue)
1179 AM_CONDITIONAL(USE_SMP, test x$smp = xtrue)
1180 AM_CONDITIONAL(USE_SQL, test x$sql = xtrue)
1181 AM_CONDITIONAL(USE_UPDOWN, test x$updown = xtrue)
1182 AM_CONDITIONAL(USE_ATTR, test x$attr = xtrue)
1183 AM_CONDITIONAL(USE_RESOLV_CONF, test x$resolvconf = xtrue)
1184 AM_CONDITIONAL(USE_UNIT_TESTS, test x$unittest = xtrue)
1185 AM_CONDITIONAL(USE_LOAD_TESTS, test x$loadtest = xtrue)
1186 AM_CONDITIONAL(USE_EAP_SIM, test x$eap_sim = xtrue)
1187 AM_CONDITIONAL(USE_EAP_SIM_FILE, test x$eap_sim_file = xtrue)
1188 AM_CONDITIONAL(USE_EAP_IDENTITY, test x$eap_identity = xtrue)
1189 AM_CONDITIONAL(USE_EAP_MD5, test x$eap_md5 = xtrue)
1190 AM_CONDITIONAL(USE_EAP_GTC, test x$eap_gtc = xtrue)
1191 AM_CONDITIONAL(USE_EAP_AKA, test x$eap_aka = xtrue)
1192 AM_CONDITIONAL(USE_EAP_MSCHAPV2, test x$eap_mschapv2 = xtrue)
1193 AM_CONDITIONAL(USE_EAP_RADIUS, test x$eap_radius = xtrue)
1194 AM_CONDITIONAL(USE_KERNEL_NETLINK, test x$kernel_netlink = xtrue)
1195 AM_CONDITIONAL(USE_KERNEL_PFKEY, test x$kernel_pfkey = xtrue)
1196 AM_CONDITIONAL(USE_KERNEL_PFROUTE, test x$kernel_pfroute = xtrue)
1197 AM_CONDITIONAL(USE_KERNEL_KLIPS, test x$kernel_klips = xtrue)
1198
1199 dnl other options
1200 dnl =============
1201 AM_CONDITIONAL(USE_SMARTCARD, test x$smartcard = xtrue)
1202 AM_CONDITIONAL(USE_CISCO_QUIRKS, test x$cisco_quirks = xtrue)
1203 AM_CONDITIONAL(USE_LEAK_DETECTIVE, test x$leak_detective = xtrue)
1204 AM_CONDITIONAL(USE_LOCK_PROFILER, test x$lock_profiler = xtrue)
1205 AM_CONDITIONAL(USE_NAT_TRANSPORT, test x$nat_transport = xtrue)
1206 AM_CONDITIONAL(USE_VENDORID, test x$vendor_id = xtrue)
1207 AM_CONDITIONAL(USE_XAUTH_VID, test x$xauth_vid = xtrue)
1208 AM_CONDITIONAL(USE_DUMM, test x$dumm = xtrue)
1209 AM_CONDITIONAL(USE_FAST, test x$fast = xtrue)
1210 AM_CONDITIONAL(USE_MANAGER, test x$manager = xtrue)
1211 AM_CONDITIONAL(USE_ME, test x$me = xtrue)
1212 AM_CONDITIONAL(USE_INTEGRITY_TEST, test x$integrity_test = xtrue)
1213 AM_CONDITIONAL(USE_SELF_TEST, test x$self_test = xtrue)
1214 AM_CONDITIONAL(USE_CAPABILITIES, test x$capabilities = xlibcap)
1215 AM_CONDITIONAL(USE_PLUTO, test x$pluto = xtrue)
1216 AM_CONDITIONAL(USE_THREADS, test x$threads = xtrue)
1217 AM_CONDITIONAL(USE_CHARON, test x$charon = xtrue)
1218 AM_CONDITIONAL(USE_TOOLS, test x$tools = xtrue)
1219 AM_CONDITIONAL(USE_LIBSTRONGSWAN, test x$charon = xtrue -o x$pluto = xtrue -o x$tools = xtrue)
1220 AM_CONDITIONAL(USE_FILE_CONFIG, test x$pluto = xtrue -o x$stroke = xtrue)
1221 AM_CONDITIONAL(USE_VSTR, test x$vstr = xtrue)
1222
1223 dnl ==============================
1224 dnl  set global definitions
1225 dnl ==============================
1226
1227 if test x$me = xtrue; then
1228         AC_DEFINE(ME)
1229 fi
1230 if test x$capabilities = xlibcap; then
1231         AC_DEFINE(CAPABILITIES)
1232 fi
1233
1234 dnl ==============================
1235 dnl  build Makefiles
1236 dnl ==============================
1237
1238 AC_OUTPUT(
1239         Makefile
1240         src/Makefile
1241         src/include/Makefile
1242         src/libstrongswan/Makefile
1243         src/libstrongswan/plugins/aes/Makefile
1244         src/libstrongswan/plugins/des/Makefile
1245         src/libstrongswan/plugins/blowfish/Makefile
1246         src/libstrongswan/plugins/serpent/Makefile
1247         src/libstrongswan/plugins/twofish/Makefile
1248         src/libstrongswan/plugins/md4/Makefile
1249         src/libstrongswan/plugins/md5/Makefile
1250         src/libstrongswan/plugins/sha1/Makefile
1251         src/libstrongswan/plugins/sha2/Makefile
1252         src/libstrongswan/plugins/fips_prf/Makefile
1253         src/libstrongswan/plugins/gmp/Makefile
1254         src/libstrongswan/plugins/random/Makefile
1255         src/libstrongswan/plugins/hmac/Makefile
1256         src/libstrongswan/plugins/xcbc/Makefile
1257         src/libstrongswan/plugins/x509/Makefile
1258         src/libstrongswan/plugins/pubkey/Makefile
1259         src/libstrongswan/plugins/curl/Makefile
1260         src/libstrongswan/plugins/ldap/Makefile
1261         src/libstrongswan/plugins/mysql/Makefile
1262         src/libstrongswan/plugins/sqlite/Makefile
1263         src/libstrongswan/plugins/padlock/Makefile
1264         src/libstrongswan/plugins/openssl/Makefile
1265         src/libstrongswan/plugins/gcrypt/Makefile
1266         src/libstrongswan/plugins/agent/Makefile
1267         src/libstrongswan/fips/Makefile
1268         src/libfreeswan/Makefile
1269         src/pluto/Makefile
1270         src/whack/Makefile
1271         src/charon/Makefile
1272         src/charon/plugins/eap_aka/Makefile
1273         src/charon/plugins/eap_identity/Makefile
1274         src/charon/plugins/eap_md5/Makefile
1275         src/charon/plugins/eap_gtc/Makefile
1276         src/charon/plugins/eap_sim/Makefile
1277         src/charon/plugins/eap_sim_file/Makefile
1278         src/charon/plugins/eap_mschapv2/Makefile
1279         src/charon/plugins/eap_radius/Makefile
1280         src/charon/plugins/kernel_netlink/Makefile
1281         src/charon/plugins/kernel_pfkey/Makefile
1282         src/charon/plugins/kernel_pfroute/Makefile
1283         src/charon/plugins/kernel_klips/Makefile
1284         src/charon/plugins/smp/Makefile
1285         src/charon/plugins/sql/Makefile
1286         src/charon/plugins/medsrv/Makefile
1287         src/charon/plugins/medcli/Makefile
1288         src/charon/plugins/nm/Makefile
1289         src/charon/plugins/uci/Makefile
1290         src/charon/plugins/stroke/Makefile
1291         src/charon/plugins/updown/Makefile
1292         src/charon/plugins/attr/Makefile
1293         src/charon/plugins/resolv_conf/Makefile
1294         src/charon/plugins/unit_tester/Makefile
1295         src/charon/plugins/load_tester/Makefile
1296         src/stroke/Makefile
1297         src/ipsec/Makefile
1298         src/starter/Makefile
1299         src/_updown/Makefile
1300         src/_updown_espmark/Makefile
1301         src/_copyright/Makefile
1302         src/openac/Makefile
1303         src/scepclient/Makefile
1304         src/dumm/Makefile
1305         src/dumm/ext/extconf.rb
1306         src/libfast/Makefile
1307         src/manager/Makefile
1308         src/medsrv/Makefile
1309         scripts/Makefile
1310         testing/Makefile
1311 )