detect fragmentation of PB-TNC batch
[strongswan.git] / configure.in
1 dnl  configure.in for linux strongSwan
2 dnl  Copyright (C) 2006 Martin Willi
3 dnl  Hochschule fuer Technik Rapperswil
4 dnl
5 dnl  This program is free software; you can redistribute it and/or modify it
6 dnl  under the terms of the GNU General Public License as published by the
7 dnl  Free Software Foundation; either version 2 of the License, or (at your
8 dnl  option) any later version.  See <http://www.fsf.org/copyleft/gpl.txt>.
9 dnl
10 dnl  This program is distributed in the hope that it will be useful, but
11 dnl  WITHOUT ANY WARRANTY; without even the implied warranty of MERCHANTABILITY
12 dnl  or FITNESS FOR A PARTICULAR PURPOSE.  See the GNU General Public License
13 dnl  for more details.
14
15 dnl ===========================
16 dnl  initialize & set some vars
17 dnl ===========================
18
19 AC_INIT(strongSwan,4.5.1dr5)
20 AM_INIT_AUTOMAKE(tar-ustar)
21 AC_CONFIG_MACRO_DIR([m4/config])
22 PKG_PROG_PKG_CONFIG
23
24 dnl =================================
25 dnl  check --enable-xxx & --with-xxx
26 dnl =================================
27
28 m4_include(m4/macros/with.m4)
29
30 ARG_WITH_SUBST([default-pkcs11],     [/usr/lib/opensc-pkcs11.so], [set the default PKCS11 library])
31 ARG_WITH_SUBST([random-device],      [/dev/random], [set the device to read real random data from])
32 ARG_WITH_SUBST([urandom-device],     [/dev/urandom], [set the device to read pseudo random data from])
33 ARG_WITH_SUBST([strongswan-conf],    [${sysconfdir}/strongswan.conf], [set the strongswan.conf file location])
34 ARG_WITH_SUBST([resolv-conf],        [${sysconfdir}/resolv.conf], [set the file to use in DNS handler plugin])
35 ARG_WITH_SUBST([piddir],             [/var/run], [set path for PID and UNIX socket files])
36 ARG_WITH_SUBST([ipsecdir],           [${libexecdir%/}/ipsec], [set installation path for ipsec tools])
37 ARG_WITH_SUBST([plugindir],          [${ipsecdir%/}/plugins], [set the installation path of plugins])
38 ARG_WITH_SUBST([nm-ca-dir],          [/usr/share/ca-certificates], [directory the NM plugin uses to look up trusted root certificates])
39 ARG_WITH_SUBST([linux-headers],      [\${top_srcdir}/src/include], [set directory of linux header files to use])
40 ARG_WITH_SUBST([routing-table],      [220], [set routing table to use for IPsec routes])
41 ARG_WITH_SUBST([routing-table-prio], [220], [set priority for IPsec routing table])
42
43 ARG_WITH_SET([capabilities],         [no], [set capability dropping library. Currently supported values are "libcap" and "native"])
44 ARG_WITH_SET([mpz_powm_sec],         [yes], [use the more side-channel resistant mpz_powm_sec in libgmp, if available])
45
46 AC_ARG_WITH(
47         [xauth-module],
48         AS_HELP_STRING([--with-xauth-module=lib],[set the path to the XAUTH module]),
49         [AC_DEFINE_UNQUOTED(XAUTH_DEFAULT_LIB, "$withval")],
50 )
51
52 AC_ARG_WITH(
53         [user],
54         AS_HELP_STRING([--with-user=user],[change user of the daemons to "user" after startup (default is "root").]),
55         [AC_DEFINE_UNQUOTED(IPSEC_USER, "$withval") AC_SUBST(ipsecuser, "$withval")],
56         [AC_SUBST(ipsecuser, "root")]
57 )
58
59 AC_ARG_WITH(
60         [group],
61         AS_HELP_STRING([--with-group=group],[change group of the daemons to "group" after startup (default is "root").]),
62         [AC_DEFINE_UNQUOTED(IPSEC_GROUP, "$withval") AC_SUBST(ipsecgroup, "$withval")],
63         [AC_SUBST(ipsecgroup, "root")]
64 )
65
66 m4_include(m4/macros/enable-disable.m4)
67
68 ARG_ENABL_SET([curl],           [enable CURL fetcher plugin to fetch files via libcurl. Requires libcurl.])
69 ARG_ENABL_SET([ldap],           [enable LDAP fetching plugin to fetch files via libldap. Requires openLDAP.])
70 ARG_DISBL_SET([aes],            [disable AES software implementation plugin.])
71 ARG_DISBL_SET([des],            [disable DES/3DES software implementation plugin.])
72 ARG_ENABL_SET([blowfish],       [enable Blowfish software implementation plugin.])
73 ARG_ENABL_SET([md4],            [enable MD4 software implementation plugin.])
74 ARG_DISBL_SET([md5],            [disable MD5 software implementation plugin.])
75 ARG_DISBL_SET([sha1],           [disable SHA1 software implementation plugin.])
76 ARG_DISBL_SET([sha2],           [disable SHA256/SHA384/SHA512 software implementation plugin.])
77 ARG_DISBL_SET([fips-prf],       [disable FIPS PRF software implementation plugin.])
78 ARG_DISBL_SET([gmp],            [disable GNU MP (libgmp) based crypto implementation plugin.])
79 ARG_DISBL_SET([random],         [disable RNG implementation on top of /dev/(u)random.])
80 ARG_DISBL_SET([x509],           [disable X509 certificate implementation plugin.])
81 ARG_DISBL_SET([revocation],     [disable X509 CRL/OCSP revocation check plugin.])
82 ARG_DISBL_SET([pubkey],         [disable RAW public key support plugin.])
83 ARG_DISBL_SET([pkcs1],          [disable PKCS1 key decoding plugin.])
84 ARG_DISBL_SET([pgp],            [disable PGP key decoding plugin.])
85 ARG_DISBL_SET([dnskey],         [disable DNS RR key decoding plugin.])
86 ARG_DISBL_SET([pem],            [disable PEM decoding plugin.])
87 ARG_DISBL_SET([hmac],           [disable HMAC crypto implementation plugin.])
88 ARG_DISBL_SET([xcbc],           [disable xcbc crypto implementation plugin.])
89 ARG_ENABL_SET([af-alg],         [enable AF_ALG crypto interface to Linux Crypto API.])
90 ARG_ENABL_SET([test-vectors],   [enable plugin providing crypto test vectors.])
91 ARG_ENABL_SET([mysql],          [enable MySQL database support. Requires libmysqlclient_r.])
92 ARG_ENABL_SET([sqlite],         [enable SQLite database support. Requires libsqlite3.])
93 ARG_DISBL_SET([stroke],         [disable charons stroke (pluto compatibility) configuration backend.])
94 ARG_ENABL_SET([medsrv],         [enable mediation server web frontend and daemon plugin.])
95 ARG_ENABL_SET([medcli],         [enable mediation client configuration database plugin.])
96 ARG_ENABL_SET([smp],            [enable SMP configuration and control interface. Requires libxml.])
97 ARG_ENABL_SET([sql],            [enable SQL database configuration backend.])
98 ARG_ENABL_SET([smartcard],      [enable smartcard support.])
99 ARG_ENABL_SET([cisco-quirks],   [enable support of Cisco VPN client.])
100 ARG_ENABL_SET([leak-detective], [enable malloc hooks to find memory leaks.])
101 ARG_ENABL_SET([lock-profiler],  [enable lock/mutex profiling code.])
102 ARG_ENABL_SET([unit-tests],     [enable unit tests on IKEv2 daemon startup.])
103 ARG_ENABL_SET([load-tester],    [enable load testing plugin for IKEv2 daemon.])
104 ARG_ENABL_SET([eap-sim],        [enable SIM authentication module for EAP.])
105 ARG_ENABL_SET([eap-sim-file],   [enable EAP-SIM backend based on a triplet file.])
106 ARG_ENABL_SET([eap-simaka-sql], [enable EAP-SIM/AKA backend based on a triplet/quintuplet SQL database.])
107 ARG_ENABL_SET([eap-simaka-pseudonym], [enable EAP-SIM/AKA pseudonym storage plugin.])
108 ARG_ENABL_SET([eap-simaka-reauth],    [enable EAP-SIM/AKA reauthentication data storage plugin.])
109 ARG_ENABL_SET([eap-identity],   [enable EAP module providing EAP-Identity helper.])
110 ARG_ENABL_SET([eap-md5],        [enable EAP MD5 (CHAP) authentication module.])
111 ARG_ENABL_SET([eap-gtc],        [enable PAM based EAP GTC authentication module.])
112 ARG_ENABL_SET([eap-aka],        [enable EAP AKA authentication module.])
113 ARG_ENABL_SET([eap-aka-3gpp2],  [enable EAP AKA backend implementing 3GPP2 algorithms in software. Requires libgmp.])
114 ARG_ENABL_SET([eap-mschapv2],   [enable EAP MS-CHAPv2 authentication module.])
115 ARG_ENABL_SET([eap-tls],        [enable EAP TLS authentication module.])
116 ARG_ENABL_SET([eap-ttls],       [enable EAP TTLS authentication module.])
117 ARG_ENABL_SET([eap-tnc],        [enable EAP TNC trusted network connect module.])
118 ARG_ENABL_SET([eap-radius],     [enable RADIUS proxy authentication module.])
119 ARG_ENABL_SET([tnc-imc],        [enable TNC IMC module.])
120 ARG_ENABL_SET([tnc-imv],        [enable TNC IMV module.])
121 ARG_ENABL_SET([tnccs-11],       [enable TNCCS 1.1 protocol module.])
122 ARG_ENABL_SET([tnccs-20],       [enable TNCCS 2.0 protocol module.])
123 ARG_DISBL_SET([kernel-netlink], [disable the netlink kernel interface.])
124 ARG_ENABL_SET([kernel-pfkey],   [enable the PF_KEY kernel interface.])
125 ARG_ENABL_SET([kernel-pfroute], [enable the PF_ROUTE kernel interface.])
126 ARG_ENABL_SET([kernel-klips],   [enable the KLIPS kernel interface.])
127 ARG_DISBL_SET([socket-default], [disable default socket implementation for charon.])
128 ARG_ENABL_SET([socket-raw],     [enable raw socket implementation of charon, enforced if pluto is enabled])
129 ARG_ENABL_SET([socket-dynamic], [enable dynamic socket implementation for charon])
130 ARG_ENABL_SET([farp],           [enable ARP faking plugin that responds to ARP requests to peers virtual IP])
131 ARG_ENABL_SET([nat-transport],  [enable NAT traversal with IPsec transport mode in pluto.])
132 ARG_DISBL_SET([vendor-id],      [disable the sending of the strongSwan vendor ID in pluto.])
133 ARG_DISBL_SET([xauth-vid],      [disable the sending of the XAUTH vendor ID.])
134 ARG_ENABL_SET([dumm],           [enable the DUMM UML test framework.])
135 ARG_ENABL_SET([fast],           [enable libfast (FastCGI Application Server w/ templates.])
136 ARG_ENABL_SET([manager],        [enable web management console (proof of concept).])
137 ARG_ENABL_SET([mediation],      [enable IKEv2 Mediation Extension.])
138 ARG_ENABL_SET([integrity-test], [enable integrity testing of libstrongswan and plugins.])
139 ARG_DISBL_SET([load-warning],   [disable the charon/pluto plugin load option warning in starter.])
140 ARG_DISBL_SET([pluto],          [disable the IKEv1 keying daemon pluto.])
141 ARG_DISBL_SET([xauth],          [disable xauth plugin.])
142 ARG_DISBL_SET([threads],        [disable the use of threads in pluto. Charon always uses threads.])
143 ARG_DISBL_SET([charon],         [disable the IKEv2 keying daemon charon.])
144 ARG_DISBL_SET([tools],          [disable additional utilities (openac, scepclient and pki).])
145 ARG_DISBL_SET([scripts],        [disable additional utilities (found in directory scripts).])
146 ARG_DISBL_SET([updown],         [disable updown firewall script plugin.])
147 ARG_DISBL_SET([attr],           [disable strongswan.conf based configuration attribute plugin.])
148 ARG_ENABL_SET([attr-sql],       [enable SQL based configuration attribute plugin.])
149 ARG_ENABL_SET([dhcp],           [enable DHCP based attribute provider plugin.])
150 ARG_DISBL_SET([resolve],        [disable resolve DNS handler plugin.])
151 ARG_ENABL_SET([padlock],        [enables VIA Padlock crypto plugin.])
152 ARG_ENABL_SET([openssl],        [enables the OpenSSL crypto plugin.])
153 ARG_ENABL_SET([gcrypt],         [enables the libgcrypt plugin.])
154 ARG_ENABL_SET([agent],          [enables the ssh-agent signing plugin.])
155 ARG_ENABL_SET([pkcs11],         [enables the PKCS11 token support plugin.])
156 ARG_ENABL_SET([ctr],            [enables the Counter Mode wrapper crypto plugin.])
157 ARG_ENABL_SET([ccm],            [enables the CCM AEAD wrapper crypto plugin.])
158 ARG_ENABL_SET([gcm],            [enables the GCM AEAD wrapper crypto plugin.])
159 ARG_ENABL_SET([addrblock],      [enables RFC 3779 address block constraint support.])
160 ARG_ENABL_SET([uci],            [enable OpenWRT UCI configuration plugin.])
161 ARG_ENABL_SET([android],        [enable Android specific plugin.])
162 ARG_ENABL_SET([maemo],          [enable Maemo specific plugin.])
163 ARG_ENABL_SET([nm],             [enable NetworkManager plugin.])
164 ARG_ENABL_SET([ha],             [enable high availability cluster plugin.])
165 ARG_ENABL_SET([led],            [enable plugin to control LEDs on IKEv2 activity using the Linux kernel LED subsystem.])
166 ARG_ENABL_SET([vstr],           [enforce using the Vstr string library to replace glibc-like printf hooks.])
167 ARG_ENABL_SET([monolithic],     [build monolithic version of libstrongswan that includes all enabled plugins. Similarly, the plugins of charon are assembled in libcharon.])
168
169 dnl =========================
170 dnl  set up compiler and flags
171 dnl =========================
172
173 if test -z "$CFLAGS"; then
174         CFLAGS="-g -O2 -Wall -Wno-format -Wno-pointer-sign -Wno-strict-aliasing"
175 fi
176 AC_PROG_CC
177 AC_LIB_PREFIX
178 AC_C_BIGENDIAN
179
180 dnl =========================
181 dnl  check required programs
182 dnl =========================
183
184 AC_PROG_INSTALL
185 AC_PROG_LIBTOOL
186 AC_PROG_EGREP
187 AC_PROG_AWK
188 AC_PROG_LEX
189 AC_PROG_YACC
190 AC_PATH_PROG([PERL], [perl], [], [$PATH:/bin:/usr/bin:/usr/local/bin])
191 AC_PATH_PROG([GPERF], [gperf], [], [$PATH:/bin:/usr/bin:/usr/local/bin])
192
193 dnl because gperf is not needed by end-users we just report it but do not abort on failure
194 AC_MSG_CHECKING([gperf version >= 3.0.0])
195 if test -x "$GPERF"; then
196         if test "`$GPERF --version | $AWK -F' ' '/^GNU gperf/ { print $3 }' | $AWK -F. '{ print $1 }'`" -ge "3"; then
197                 AC_MSG_RESULT([yes])
198         else
199                 AC_MSG_RESULT([no])
200         fi
201 else
202         AC_MSG_RESULT([not found])
203 fi
204
205 dnl translate user/group to numercial ids
206 AC_MSG_CHECKING([for uid of user "$ipsecuser"])
207 ipsecuid=`id -u $ipsecuser 2>/dev/null`
208 if test -n "$ipsecuid"; then
209         AC_MSG_RESULT([$ipsecuid])
210         AC_SUBST(ipsecuid)
211 else
212         AC_MSG_ERROR([not found])
213 fi
214 AC_MSG_CHECKING([for gid of group "$ipsecgroup"])
215 ipsecgid=`$EGREP "^$ipsecgroup:" /etc/group | $AWK -F: '{ print $3 }'`
216 if test -n "$ipsecgid"; then
217         AC_MSG_RESULT([$ipsecgid])
218         AC_SUBST(ipsecgid)
219 else
220         AC_MSG_ERROR([not found])
221 fi
222
223 dnl =========================
224 dnl  dependency calculation
225 dnl =========================
226
227 if test x$eap_aka_3gpp2 = xtrue; then
228         gmp=true;
229 fi
230
231 if test x$eap_aka = xtrue; then
232         fips_prf=true;
233         simaka=true;
234 fi
235
236 if test x$eap_sim = xtrue; then
237         fips_prf=true;
238         simaka=true;
239 fi
240
241 if test x$eap_tls = xtrue -o x$eap_ttls = xtrue; then
242         tls=true;
243 fi
244
245 if test x$fips_prf = xtrue; then
246         if test x$openssl = xfalse; then
247                 sha1=true;
248         fi
249 fi
250
251 if test x$smp = xtrue; then
252         xml=true
253 fi
254
255 if test x$manager = xtrue; then
256         fast=true
257 fi
258
259 if test x$medsrv = xtrue; then
260         mediation=true
261         fast=true
262 fi
263
264 if test x$medcli = xtrue; then
265         mediation=true
266 fi
267
268 if test x$pluto = xtrue; then
269         if test x$socket_raw = xfalse; then
270                 AC_MSG_NOTICE([Enforcing --enable-socket-raw, as pluto is enabled])
271                 socket_raw=true
272                 if test x$socket_default_given = xfalse; then
273                         socket_default=false
274                 fi
275         fi
276 fi
277
278 dnl ===========================================
279 dnl  check required libraries and header files
280 dnl ===========================================
281
282 AC_HEADER_STDBOOL
283 AC_FUNC_ALLOCA
284
285 dnl libraries needed on some platforms but not on others
286 dnl ====================================================
287 saved_LIBS=$LIBS
288
289 dnl FreeBSD and Mac OS X have dlopen integrated in libc, Linux needs libdl
290 LIBS=""
291 AC_SEARCH_LIBS(dlopen, dl, [DLLIB=$LIBS])
292 AC_SUBST(DLLIB)
293
294 dnl glibc's backtrace() can be replicated on FreeBSD with libexecinfo
295 LIBS=""
296 AC_SEARCH_LIBS(backtrace, execinfo, [BTLIB=$LIBS])
297 AC_CHECK_FUNCS(backtrace)
298 AC_SUBST(BTLIB)
299
300 dnl OpenSolaris needs libsocket and libnsl for socket()
301 LIBS=""
302 AC_SEARCH_LIBS(socket, socket, [SOCKLIB=$LIBS],
303         [AC_CHECK_LIB(nsl, socket, [SOCKLIB="-lsocket -lnsl"], [], [-lsocket])]
304 )
305 AC_SUBST(SOCKLIB)
306
307 dnl FreeBSD has clock_gettime in libc, Linux needs librt
308 LIBS=""
309 AC_SEARCH_LIBS(clock_gettime, rt, [RTLIB=$LIBS])
310 AC_CHECK_FUNCS(clock_gettime)
311 AC_SUBST(RTLIB)
312
313 dnl Android has pthread_* functions in bionic (libc), others need libpthread
314 LIBS=""
315 AC_SEARCH_LIBS(pthread_create, pthread, [PTHREADLIB=$LIBS])
316 AC_SUBST(PTHREADLIB)
317
318 LIBS=$saved_LIBS
319 dnl ======================
320
321 AC_MSG_CHECKING(for dladdr)
322 AC_TRY_COMPILE(
323         [#define _GNU_SOURCE
324          #include <dlfcn.h>],
325         [Dl_info* info = 0;
326          dladdr(0, info);],
327         [AC_MSG_RESULT([yes]); AC_DEFINE([HAVE_DLADDR])],
328         [AC_MSG_RESULT([no])]
329 )
330
331 dnl check if pthread_condattr_setclock(CLOCK_MONOTONE) is supported
332 saved_LIBS=$LIBS
333 LIBS=$PTHREADLIB
334 AC_MSG_CHECKING([for pthread_condattr_setclock(CLOCK_MONOTONE)])
335 AC_TRY_RUN(
336         [#include <pthread.h>
337          int main() { pthread_condattr_t attr;
338                 pthread_condattr_init(&attr);
339                 return pthread_condattr_setclock(&attr, CLOCK_MONOTONIC);}],
340         [AC_MSG_RESULT([yes]); AC_DEFINE([HAVE_CONDATTR_CLOCK_MONOTONIC])],
341         [AC_MSG_RESULT([no])],
342         dnl Check existence of pthread_condattr_setclock if cross-compiling
343         [AC_MSG_RESULT([unknown]);
344          AC_CHECK_FUNCS(pthread_condattr_setclock,
345                 [AC_DEFINE([HAVE_CONDATTR_CLOCK_MONOTONIC])]
346         )]
347 )
348 dnl check if we actually are able to configure attributes on cond vars
349 AC_CHECK_FUNCS(pthread_condattr_init)
350 dnl instead of pthread_condattr_setclock Android has this function
351 AC_CHECK_FUNCS(pthread_cond_timedwait_monotonic)
352 dnl check if we can cancel threads
353 AC_CHECK_FUNCS(pthread_cancel)
354 dnl check if native rwlocks are available
355 AC_CHECK_FUNCS(pthread_rwlock_init)
356 LIBS=$saved_LIBS
357
358 AC_CHECK_FUNCS(prctl)
359
360 AC_CHECK_FUNCS(mallinfo)
361
362 AC_CHECK_HEADERS(sys/sockio.h)
363 AC_CHECK_HEADERS(net/pfkeyv2.h netipsec/ipsec.h netinet6/ipsec.h linux/udp.h)
364
365 AC_CHECK_MEMBERS([struct sockaddr.sa_len], [], [],
366 [
367         #include <sys/types.h>
368         #include <sys/socket.h>
369 ])
370
371 AC_CHECK_MEMBERS([struct sadb_x_policy.sadb_x_policy_priority], [], [],
372 [
373         #include <sys/types.h>
374         #ifdef HAVE_NET_PFKEYV2_H
375         #include <net/pfkeyv2.h>
376         #else
377         #include <stdint.h>
378         #include <linux/pfkeyv2.h>
379         #endif
380 ])
381
382 AC_MSG_CHECKING([for in6addr_any])
383 AC_TRY_COMPILE(
384         [#include <sys/types.h>
385         #include <sys/socket.h>
386         #include <netinet/in.h>],
387         [struct in6_addr in6;
388         in6 = in6addr_any;],
389         [AC_MSG_RESULT([yes]); AC_DEFINE([HAVE_IN6ADDR_ANY])],
390         [AC_MSG_RESULT([no])]
391 )
392
393 AC_MSG_CHECKING([for in6_pktinfo])
394 AC_TRY_COMPILE(
395         [#define _GNU_SOURCE
396         #include <sys/types.h>
397         #include <sys/socket.h>
398         #include <netinet/in.h>],
399         [struct in6_pktinfo pi;
400         if (pi.ipi6_ifindex)
401         {
402                 return 0;
403         }],
404         [AC_MSG_RESULT([yes]); AC_DEFINE([HAVE_IN6_PKTINFO])],
405         [AC_MSG_RESULT([no])]
406 )
407
408 AC_MSG_CHECKING([for IPSEC_MODE_BEET])
409 AC_TRY_COMPILE(
410         [#include <sys/types.h>
411         #ifdef HAVE_NETIPSEC_IPSEC_H
412         #include <netipsec/ipsec.h>
413         #elif defined(HAVE_NETINET6_IPSEC_H)
414         #include <netinet6/ipsec.h>
415         #else
416         #include <stdint.h>
417         #include <linux/ipsec.h>
418         #endif],
419         [int mode = IPSEC_MODE_BEET;
420          return mode;],
421         [AC_MSG_RESULT([yes]); AC_DEFINE([HAVE_IPSEC_MODE_BEET])],
422         [AC_MSG_RESULT([no])]
423 )
424
425 AC_MSG_CHECKING([for IPSEC_DIR_FWD])
426 AC_TRY_COMPILE(
427         [#include <sys/types.h>
428         #ifdef HAVE_NETIPSEC_IPSEC_H
429         #include <netipsec/ipsec.h>
430         #elif defined(HAVE_NETINET6_IPSEC_H)
431         #include <netinet6/ipsec.h>
432         #else
433         #include <stdint.h>
434         #include <linux/ipsec.h>
435         #endif],
436         [int dir = IPSEC_DIR_FWD;
437          return dir;],
438         [AC_MSG_RESULT([yes]); AC_DEFINE([HAVE_IPSEC_DIR_FWD])],
439         [AC_MSG_RESULT([no])]
440 )
441
442 AC_MSG_CHECKING([for gcc atomic operations])
443 AC_TRY_RUN(
444 [
445         int main() {
446                 volatile int ref = 1;
447                 __sync_fetch_and_add (&ref, 1);
448                 __sync_sub_and_fetch (&ref, 1);
449                 /* Make sure test fails if operations are not supported */
450                 __sync_val_compare_and_swap(&ref, 1, 0);
451                 return ref;
452         }
453 ],
454 [AC_MSG_RESULT([yes]); AC_DEFINE(HAVE_GCC_ATOMIC_OPERATIONS)],
455 [AC_MSG_RESULT([no])],
456 [AC_MSG_RESULT([no])])
457
458 dnl check for the new register_printf_specifier function with len argument,
459 dnl or the deprecated register_printf_function without
460 AC_CHECK_FUNC(
461         [register_printf_specifier],
462         [AC_DEFINE(HAVE_PRINTF_SPECIFIER)],
463         [AC_CHECK_FUNC(
464                 [register_printf_function],
465                 [AC_DEFINE(HAVE_PRINTF_FUNCTION)],
466                 [
467                         AC_MSG_NOTICE([printf does not support custom format specifiers!])
468                         vstr=true
469                 ]
470         )]
471 )
472
473 if test x$vstr = xtrue; then
474         AC_HAVE_LIBRARY([vstr],[LIBS="$LIBS"],[AC_MSG_ERROR([Vstr string library not found])])
475         AC_DEFINE(USE_VSTR)
476 fi
477
478 if test x$gmp = xtrue; then
479         saved_LIBS=$LIBS
480         AC_HAVE_LIBRARY([gmp],,[AC_MSG_ERROR([GNU Multi Precision library gmp not found])])
481         AC_MSG_CHECKING([mpz_powm_sec])
482         if test x$mpz_powm_sec = xyes; then
483                 AC_TRY_COMPILE(
484                         [#include "gmp.h"],
485                         [
486                                 void *x = mpz_powm_sec;
487                         ],
488                         [AC_MSG_RESULT([yes]); AC_DEFINE(HAVE_MPZ_POWM_SEC)], [AC_MSG_RESULT([no])]
489                 )
490         else
491                 AC_MSG_RESULT([disabled])
492         fi
493         LIBS=$saved_LIBS
494         AC_MSG_CHECKING([gmp.h version >= 4.1.4])
495         AC_TRY_COMPILE(
496                 [#include "gmp.h"],
497                 [
498                         #if (__GNU_MP_VERSION*100 +  __GNU_MP_VERSION_MINOR*10 + __GNU_MP_VERSION_PATCHLEVEL) < 414
499                                 #error bad gmp
500                         #endif
501                 ],
502                 [AC_MSG_RESULT([yes])], [AC_MSG_RESULT([no]); AC_MSG_ERROR([No usable gmp.h found!])]
503         )
504 fi
505
506 if test x$ldap = xtrue; then
507         AC_HAVE_LIBRARY([ldap],[LIBS="$LIBS"],[AC_MSG_ERROR([LDAP library ldap not found])])
508         AC_HAVE_LIBRARY([lber],[LIBS="$LIBS"],[AC_MSG_ERROR([LDAP library lber not found])])
509         AC_CHECK_HEADER([ldap.h],,[AC_MSG_ERROR([LDAP header ldap.h not found!])])
510 fi
511
512 if test x$curl = xtrue; then
513         AC_HAVE_LIBRARY([curl],[LIBS="$LIBS"],[AC_MSG_ERROR([CURL library curl not found])])
514         AC_CHECK_HEADER([curl/curl.h],,[AC_MSG_ERROR([CURL header curl/curl.h not found!])])
515 fi
516
517 if test x$xml = xtrue; then
518         PKG_CHECK_MODULES(xml, [libxml-2.0])
519         AC_SUBST(xml_CFLAGS)
520         AC_SUBST(xml_LIBS)
521 fi
522
523 if test x$dumm = xtrue; then
524         PKG_CHECK_MODULES(gtk, [gtk+-2.0 vte])
525         AC_SUBST(gtk_CFLAGS)
526         AC_SUBST(gtk_LIBS)
527         AC_CHECK_PROGS(RUBY, ruby)
528         AC_MSG_CHECKING([for Ruby header files])
529         if test -n "$RUBY"; then
530                 RUBYDIR=`($RUBY -rmkmf -e 'print Config::CONFIG[["archdir"]] || $archdir') 2>/dev/null`
531                 if test -n "$RUBYDIR"; then
532                         dirs="$RUBYDIR"
533                         RUBYINCLUDE=none
534                         for i in $dirs; do
535                                 if test -r $i/ruby.h; then
536                                         AC_MSG_RESULT([$i])
537                                         RUBYINCLUDE="-I$i"
538                                         break;
539                                 fi
540                         done
541                         if test x"$RUBYINCLUDE" = xnone; then
542                                 AC_MSG_ERROR([ruby.h not found])
543                         fi
544                         AC_SUBST(RUBYINCLUDE)
545                 else
546                         AC_MSG_ERROR([unable to determine ruby configuration])
547                 fi
548         else
549                 AC_MSG_ERROR([don't know how to run ruby])
550         fi
551 fi
552
553 if test x$fast = xtrue; then
554         AC_HAVE_LIBRARY([neo_cgi],[LIBS="$LIBS"],[AC_MSG_ERROR([ClearSilver library neo_cgi not found!])])
555         AC_HAVE_LIBRARY([neo_utl],[LIBS="$LIBS"],[AC_MSG_ERROR([ClearSilver library neo_utl not found!])])
556         AC_HAVE_LIBRARY([z],[LIBS="$LIBS"],[AC_MSG_ERROR([ClearSilver dependency zlib not found!])])
557 dnl autoconf does not like CamelCase!? How to fix this?
558 dnl     AC_CHECK_HEADER([ClearSilver/ClearSilver.h],,[AC_MSG_ERROR([ClearSilver header file ClearSilver/ClearSilver.h not found!])])
559
560         AC_HAVE_LIBRARY([fcgi],[LIBS="$LIBS"],[AC_MSG_ERROR([FastCGI library fcgi not found!])])
561         AC_CHECK_HEADER([fcgiapp.h],,[AC_MSG_ERROR([FastCGI header file fcgiapp.h not found!])])
562 fi
563
564 if test x$mysql = xtrue; then
565         AC_PATH_PROG([MYSQLCONFIG], [mysql_config], [], [$PATH:/bin:/usr/bin:/usr/local/bin])
566         if test x$MYSQLCONFIG = x; then
567                 AC_MSG_ERROR([mysql_config not found!])
568         fi
569         AC_SUBST(MYSQLLIB, `$MYSQLCONFIG --libs_r`)
570         AC_SUBST(MYSQLCFLAG, `$MYSQLCONFIG --cflags`)
571 fi
572
573 if test x$sqlite = xtrue; then
574         AC_HAVE_LIBRARY([sqlite3],[LIBS="$LIBS"],[AC_MSG_ERROR([SQLite library sqlite3 not found])])
575         AC_CHECK_HEADER([sqlite3.h],,[AC_MSG_ERROR([SQLite header sqlite3.h not found!])])
576         AC_MSG_CHECKING([sqlite3_prepare_v2])
577         AC_TRY_COMPILE(
578                 [#include <sqlite3.h>],
579                 [
580                         void *test = sqlite3_prepare_v2;
581                 ],
582                 [AC_MSG_RESULT([yes])]; AC_DEFINE_UNQUOTED(HAVE_SQLITE3_PREPARE_V2, 1), [AC_MSG_RESULT([no])])
583         AC_MSG_CHECKING([sqlite3.h version >= 3.3.1])
584         AC_TRY_COMPILE(
585                 [#include <sqlite3.h>],
586                 [
587                         #if SQLITE_VERSION_NUMBER < 3003001
588                                 #error bad sqlite
589                         #endif
590                 ],
591                 [AC_MSG_RESULT([yes])], [AC_MSG_RESULT([no]); AC_MSG_ERROR([SQLite version >= 3.3.1 required!])])
592 fi
593
594 if test x$openssl = xtrue; then
595         AC_HAVE_LIBRARY([crypto],[LIBS="$LIBS"],[AC_MSG_ERROR([OpenSSL crypto library not found])])
596         AC_CHECK_HEADER([openssl/evp.h],,[AC_MSG_ERROR([OpenSSL header openssl/evp.h not found!])])
597 fi
598
599 if test x$gcrypt = xtrue; then
600         AC_HAVE_LIBRARY([gcrypt],[LIBS="$LIBS"],[AC_MSG_ERROR([gcrypt library not found])],[-lgpg-error])
601         AC_CHECK_HEADER([gcrypt.h],,[AC_MSG_ERROR([gcrypt header gcrypt.h not found!])])
602         AC_MSG_CHECKING([gcrypt CAMELLIA cipher])
603         AC_TRY_COMPILE(
604                 [#include <gcrypt.h>],
605                 [enum gcry_cipher_algos alg = GCRY_CIPHER_CAMELLIA128;],
606                 [AC_MSG_RESULT([yes]); AC_DEFINE([HAVE_GCRY_CIPHER_CAMELLIA])],
607                 [AC_MSG_RESULT([no])]
608         )
609 fi
610
611 if test x$uci = xtrue; then
612         AC_HAVE_LIBRARY([uci],[LIBS="$LIBS"],[AC_MSG_ERROR([UCI library libuci not found])])
613         AC_CHECK_HEADER([uci.h],,[AC_MSG_ERROR([UCI header uci.h not found!])])
614 fi
615
616 if test x$android = xtrue; then
617         AC_HAVE_LIBRARY([cutils],[LIBS="$LIBS"],[AC_MSG_ERROR([Android library libcutils not found])])
618         AC_CHECK_HEADER([cutils/properties.h],,[AC_MSG_ERROR([Android header cutils/properties.h not found!])])
619         dnl we have to force the use of libdl here because the autodetection
620         dnl above does not work correctly when cross-compiling for android.
621         DLLIB="-ldl"
622         AC_SUBST(DLLIB)
623 fi
624
625 if test x$maemo = xtrue; then
626         PKG_CHECK_MODULES(maemo, [glib-2.0 gthread-2.0 libosso osso-af-settings])
627         AC_SUBST(maemo_CFLAGS)
628         AC_SUBST(maemo_LIBS)
629         dbusservicedir="/usr/share/dbus-1/system-services"
630         AC_SUBST(dbusservicedir)
631 fi
632
633 if test x$nm = xtrue; then
634         PKG_CHECK_EXISTS([libnm-glib],
635                 [PKG_CHECK_MODULES(nm, [NetworkManager gthread-2.0 libnm-glib libnm-glib-vpn])],
636                 [PKG_CHECK_MODULES(nm, [NetworkManager gthread-2.0 libnm_glib libnm_glib_vpn])]
637         )
638         AC_SUBST(nm_CFLAGS)
639         AC_SUBST(nm_LIBS)
640 fi
641
642 if test x$eap_gtc = xtrue; then
643         AC_HAVE_LIBRARY([pam],[LIBS="$LIBS"],[AC_MSG_ERROR([PAM library not found])])
644         AC_CHECK_HEADER([security/pam_appl.h],,[AC_MSG_ERROR([PAM header security/pam_appl.h not found!])])
645 fi
646
647 if test x$capabilities = xnative; then
648         AC_MSG_NOTICE([Usage of the native Linux capabilities interface is deprecated, use libcap instead])
649         dnl Linux requires the following for capset(), Android does not have it,
650         dnl but defines capset() in unistd.h instead.
651         AC_CHECK_HEADERS([sys/capability.h])
652         AC_CHECK_FUNC(capset,,[AC_MSG_ERROR([capset() not found!])])
653         AC_DEFINE(CAPABILITIES_NATIVE)
654 fi
655
656 if test x$capabilities = xlibcap; then
657         AC_HAVE_LIBRARY([cap],[LIBS="$LIBS"],[AC_MSG_ERROR([libcap library not found])])
658         AC_CHECK_HEADER([sys/capability.h],
659                 [AC_DEFINE(HAVE_SYS_CAPABILITY_H)],
660                 [AC_MSG_ERROR([libcap header sys/capability.h not found!])])
661         AC_DEFINE(CAPABILITIES_LIBCAP)
662 fi
663
664 if test x$integrity_test = xtrue; then
665         AC_MSG_CHECKING([for dladdr()])
666         AC_TRY_COMPILE(
667                 [#define _GNU_SOURCE
668                  #include <dlfcn.h>],
669                 [Dl_info info; dladdr(main, &info);],
670                 [AC_MSG_RESULT([yes])], [AC_MSG_RESULT([no]);
671                  AC_MSG_ERROR([dladdr() not supported, required by integrity-test!])]
672         )
673         AC_MSG_CHECKING([for dl_iterate_phdr()])
674         AC_TRY_COMPILE(
675                 [#define _GNU_SOURCE
676                  #include <link.h>],
677                 [dl_iterate_phdr((void*)0, (void*)0);],
678                 [AC_MSG_RESULT([yes])], [AC_MSG_RESULT([no]);
679                  AC_MSG_ERROR([dl_iterate_phdr() not supported, required by integrity-test!])]
680         )
681 fi
682
683 dnl ==============================================
684 dnl  collect plugin list for strongSwan components
685 dnl ==============================================
686
687 m4_include(m4/macros/add-plugin.m4)
688
689 # plugin lists for all components
690 libcharon_plugins=
691 pluto_plugins=
692 pool_plugins=
693 openac_plugins=
694 scepclient_plugins=
695 pki_plugins=
696 scripts_plugins=
697 manager_plugins=
698 medsrv_plugins=
699
700 # location specific lists for checksumming,
701 # for src/libcharon, src/pluto, src/libhydra and src/libstrongswan
702 c_plugins=
703 p_plugins=
704 h_plugins=
705 s_plugins=
706
707 ADD_PLUGIN([test-vectors],         [s libcharon pluto openac scepclient pki])
708 ADD_PLUGIN([curl],                 [s libcharon pluto scepclient])
709 ADD_PLUGIN([ldap],                 [s libcharon pluto scepclient])
710 ADD_PLUGIN([mysql],                [s libcharon pluto pool manager medsrv])
711 ADD_PLUGIN([sqlite],               [s libcharon pluto pool manager medsrv])
712 ADD_PLUGIN([aes],                  [s libcharon pluto openac scepclient pki scripts])
713 ADD_PLUGIN([des],                  [s libcharon pluto openac scepclient pki scripts])
714 ADD_PLUGIN([blowfish],             [s libcharon pluto openac scepclient pki scripts])
715 ADD_PLUGIN([sha1],                 [s libcharon pluto openac scepclient pki scripts medsrv])
716 ADD_PLUGIN([sha2],                 [s libcharon pluto openac scepclient pki scripts medsrv])
717 ADD_PLUGIN([md4],                  [s libcharon openac manager scepclient pki])
718 ADD_PLUGIN([md5],                  [s libcharon pluto openac scepclient pki])
719 ADD_PLUGIN([random],               [s libcharon pluto openac scepclient pki scripts medsrv])
720 ADD_PLUGIN([x509],                 [s libcharon pluto openac scepclient pki scripts])
721 ADD_PLUGIN([revocation],           [s libcharon])
722 ADD_PLUGIN([pubkey],               [s libcharon])
723 ADD_PLUGIN([pkcs1],                [s libcharon pluto openac scepclient pki scripts manager medsrv])
724 ADD_PLUGIN([pgp],                  [s libcharon pluto])
725 ADD_PLUGIN([dnskey],               [s pluto])
726 ADD_PLUGIN([pem],                  [s libcharon pluto openac scepclient pki scripts manager medsrv])
727 ADD_PLUGIN([padlock],              [s libcharon])
728 ADD_PLUGIN([openssl],              [s libcharon pluto openac scepclient pki scripts manager medsrv])
729 ADD_PLUGIN([gcrypt],               [s libcharon pluto openac scepclient pki scripts manager medsrv])
730 ADD_PLUGIN([fips-prf],             [s libcharon])
731 ADD_PLUGIN([gmp],                  [s libcharon pluto openac scepclient pki scripts manager medsrv])
732 ADD_PLUGIN([agent],                [s libcharon])
733 ADD_PLUGIN([pkcs11],               [s libcharon pki])
734 ADD_PLUGIN([xcbc],                 [s libcharon])
735 ADD_PLUGIN([hmac],                 [s libcharon pluto scripts])
736 ADD_PLUGIN([ctr],                  [s libcharon scripts])
737 ADD_PLUGIN([ccm],                  [s libcharon scripts])
738 ADD_PLUGIN([gcm],                  [s libcharon scripts])
739 ADD_PLUGIN([af-alg],               [s libcharon pluto openac scepclient pki scripts medsrv])
740 ADD_PLUGIN([xauth],                [p pluto])
741 ADD_PLUGIN([attr],                 [h libcharon pluto])
742 ADD_PLUGIN([attr-sql],             [h libcharon pluto])
743 ADD_PLUGIN([kernel-pfkey],         [h libcharon pluto])
744 ADD_PLUGIN([kernel-pfroute],       [h libcharon pluto])
745 ADD_PLUGIN([kernel-klips],         [h libcharon pluto])
746 ADD_PLUGIN([kernel-netlink],       [h libcharon pluto])
747 ADD_PLUGIN([resolve],              [h libcharon pluto])
748 ADD_PLUGIN([load-tester],          [c libcharon])
749 ADD_PLUGIN([socket-default],       [c libcharon])
750 ADD_PLUGIN([socket-raw],           [c libcharon])
751 ADD_PLUGIN([socket-dynamic],       [c libcharon])
752 ADD_PLUGIN([farp],                 [c libcharon])
753 ADD_PLUGIN([stroke],               [c libcharon])
754 ADD_PLUGIN([smp],                  [c libcharon])
755 ADD_PLUGIN([sql],                  [c libcharon])
756 ADD_PLUGIN([updown],               [c libcharon])
757 ADD_PLUGIN([eap-identity],         [c libcharon])
758 ADD_PLUGIN([eap-sim],              [c libcharon])
759 ADD_PLUGIN([eap-sim-file],         [c libcharon])
760 ADD_PLUGIN([eap-simaka-sql],       [c libcharon])
761 ADD_PLUGIN([eap-simaka-pseudonym], [c libcharon])
762 ADD_PLUGIN([eap-simaka-reauth],    [c libcharon])
763 ADD_PLUGIN([eap-aka],              [c libcharon])
764 ADD_PLUGIN([eap-aka-3gpp2],        [c libcharon])
765 ADD_PLUGIN([eap-md5],              [c libcharon])
766 ADD_PLUGIN([eap-gtc],              [c libcharon])
767 ADD_PLUGIN([eap-mschapv2],         [c libcharon])
768 ADD_PLUGIN([eap-radius],           [c libcharon])
769 ADD_PLUGIN([eap-tls],              [c libcharon])
770 ADD_PLUGIN([eap-ttls],             [c libcharon])
771 ADD_PLUGIN([eap-tnc],              [c libcharon])
772 ADD_PLUGIN([tnccs-20],             [c libcharon])
773 ADD_PLUGIN([tnccs-11],             [c libcharon])
774 ADD_PLUGIN([tnc-imc],              [c libcharon])
775 ADD_PLUGIN([tnc-imv],              [c libcharon])
776 ADD_PLUGIN([medsrv],               [c libcharon])
777 ADD_PLUGIN([medcli],               [c libcharon])
778 ADD_PLUGIN([nm],                   [c libcharon])
779 ADD_PLUGIN([dhcp],                 [c libcharon])
780 ADD_PLUGIN([android],              [c libcharon])
781 ADD_PLUGIN([ha],                   [c libcharon])
782 ADD_PLUGIN([led],                  [c libcharon])
783 ADD_PLUGIN([maemo],                [c libcharon])
784 ADD_PLUGIN([uci],                  [c libcharon])
785 ADD_PLUGIN([addrblock],            [c libcharon])
786 ADD_PLUGIN([unit-tester],          [c libcharon])
787
788 AC_SUBST(libcharon_plugins)
789 AC_SUBST(pluto_plugins)
790 AC_SUBST(pool_plugins)
791 AC_SUBST(openac_plugins)
792 AC_SUBST(scepclient_plugins)
793 AC_SUBST(pki_plugins)
794 AC_SUBST(scripts_plugins)
795 AC_SUBST(manager_plugins)
796 AC_SUBST(medsrv_plugins)
797
798 AC_SUBST(c_plugins)
799 AC_SUBST(p_plugins)
800 AC_SUBST(h_plugins)
801 AC_SUBST(s_plugins)
802
803 dnl =========================
804 dnl  set Makefile.am vars
805 dnl =========================
806
807 dnl libstrongswan plugins
808 dnl =====================
809 AM_CONDITIONAL(USE_TEST_VECTORS, test x$test_vectors = xtrue)
810 AM_CONDITIONAL(USE_CURL, test x$curl = xtrue)
811 AM_CONDITIONAL(USE_LDAP, test x$ldap = xtrue)
812 AM_CONDITIONAL(USE_AES, test x$aes = xtrue)
813 AM_CONDITIONAL(USE_DES, test x$des = xtrue)
814 AM_CONDITIONAL(USE_BLOWFISH, test x$blowfish = xtrue)
815 AM_CONDITIONAL(USE_MD4, test x$md4 = xtrue)
816 AM_CONDITIONAL(USE_MD5, test x$md5 = xtrue)
817 AM_CONDITIONAL(USE_SHA1, test x$sha1 = xtrue)
818 AM_CONDITIONAL(USE_SHA2, test x$sha2 = xtrue)
819 AM_CONDITIONAL(USE_FIPS_PRF, test x$fips_prf = xtrue)
820 AM_CONDITIONAL(USE_GMP, test x$gmp = xtrue)
821 AM_CONDITIONAL(USE_RANDOM, test x$random = xtrue)
822 AM_CONDITIONAL(USE_X509, test x$x509 = xtrue)
823 AM_CONDITIONAL(USE_REVOCATION, test x$revocation = xtrue)
824 AM_CONDITIONAL(USE_PUBKEY, test x$pubkey = xtrue)
825 AM_CONDITIONAL(USE_PKCS1, test x$pkcs1 = xtrue)
826 AM_CONDITIONAL(USE_PGP, test x$pgp = xtrue)
827 AM_CONDITIONAL(USE_DNSKEY, test x$dnskey = xtrue)
828 AM_CONDITIONAL(USE_PEM, test x$pem = xtrue)
829 AM_CONDITIONAL(USE_HMAC, test x$hmac = xtrue)
830 AM_CONDITIONAL(USE_XCBC, test x$xcbc = xtrue)
831 AM_CONDITIONAL(USE_MYSQL, test x$mysql = xtrue)
832 AM_CONDITIONAL(USE_SQLITE, test x$sqlite = xtrue)
833 AM_CONDITIONAL(USE_PADLOCK, test x$padlock = xtrue)
834 AM_CONDITIONAL(USE_OPENSSL, test x$openssl = xtrue)
835 AM_CONDITIONAL(USE_GCRYPT, test x$gcrypt = xtrue)
836 AM_CONDITIONAL(USE_AGENT, test x$agent = xtrue)
837 AM_CONDITIONAL(USE_PKCS11, test x$pkcs11 = xtrue)
838 AM_CONDITIONAL(USE_CTR, test x$ctr = xtrue)
839 AM_CONDITIONAL(USE_CCM, test x$ccm = xtrue)
840 AM_CONDITIONAL(USE_GCM, test x$gcm = xtrue)
841 AM_CONDITIONAL(USE_AF_ALG, test x$af_alg = xtrue)
842
843 dnl charon plugins
844 dnl ==============
845 AM_CONDITIONAL(USE_STROKE, test x$stroke = xtrue)
846 AM_CONDITIONAL(USE_MEDSRV, test x$medsrv = xtrue)
847 AM_CONDITIONAL(USE_MEDCLI, test x$medcli = xtrue)
848 AM_CONDITIONAL(USE_NM, test x$nm = xtrue)
849 AM_CONDITIONAL(USE_UCI, test x$uci = xtrue)
850 AM_CONDITIONAL(USE_ANDROID, test x$android = xtrue)
851 AM_CONDITIONAL(USE_MAEMO, test x$maemo = xtrue)
852 AM_CONDITIONAL(USE_SMP, test x$smp = xtrue)
853 AM_CONDITIONAL(USE_SQL, test x$sql = xtrue)
854 AM_CONDITIONAL(USE_UPDOWN, test x$updown = xtrue)
855 AM_CONDITIONAL(USE_DHCP, test x$dhcp = xtrue)
856 AM_CONDITIONAL(USE_UNIT_TESTS, test x$unit_tests = xtrue)
857 AM_CONDITIONAL(USE_LOAD_TESTER, test x$load_tester = xtrue)
858 AM_CONDITIONAL(USE_HA, test x$ha = xtrue)
859 AM_CONDITIONAL(USE_LED, test x$led = xtrue)
860 AM_CONDITIONAL(USE_EAP_SIM, test x$eap_sim = xtrue)
861 AM_CONDITIONAL(USE_EAP_SIM_FILE, test x$eap_sim_file = xtrue)
862 AM_CONDITIONAL(USE_EAP_SIMAKA_SQL, test x$eap_simaka_sql = xtrue)
863 AM_CONDITIONAL(USE_EAP_SIMAKA_PSEUDONYM, test x$eap_simaka_pseudonym = xtrue)
864 AM_CONDITIONAL(USE_EAP_SIMAKA_REAUTH, test x$eap_simaka_reauth = xtrue)
865 AM_CONDITIONAL(USE_EAP_IDENTITY, test x$eap_identity = xtrue)
866 AM_CONDITIONAL(USE_EAP_MD5, test x$eap_md5 = xtrue)
867 AM_CONDITIONAL(USE_EAP_GTC, test x$eap_gtc = xtrue)
868 AM_CONDITIONAL(USE_EAP_AKA, test x$eap_aka = xtrue)
869 AM_CONDITIONAL(USE_EAP_AKA_3GPP2, test x$eap_aka_3gpp2 = xtrue)
870 AM_CONDITIONAL(USE_EAP_MSCHAPV2, test x$eap_mschapv2 = xtrue)
871 AM_CONDITIONAL(USE_EAP_TLS, test x$eap_tls = xtrue)
872 AM_CONDITIONAL(USE_EAP_TTLS, test x$eap_ttls = xtrue)
873 AM_CONDITIONAL(USE_EAP_TNC, test x$eap_tnc = xtrue)
874 AM_CONDITIONAL(USE_EAP_RADIUS, test x$eap_radius = xtrue)
875 AM_CONDITIONAL(USE_TNC_IMC, test x$tnc_imc = xtrue)
876 AM_CONDITIONAL(USE_TNC_IMV, test x$tnc_imv = xtrue)
877 AM_CONDITIONAL(USE_TNCCS_11, test x$tnccs_11 = xtrue)
878 AM_CONDITIONAL(USE_TNCCS_20, test x$tnccs_20 = xtrue)
879 AM_CONDITIONAL(USE_SOCKET_DEFAULT, test x$socket_default = xtrue)
880 AM_CONDITIONAL(USE_SOCKET_RAW, test x$socket_raw = xtrue)
881 AM_CONDITIONAL(USE_SOCKET_DYNAMIC, test x$socket_dynamic = xtrue)
882 AM_CONDITIONAL(USE_FARP, test x$farp = xtrue)
883 AM_CONDITIONAL(USE_ADDRBLOCK, test x$addrblock = xtrue)
884
885 dnl hydra plugins
886 dnl =============
887 AM_CONDITIONAL(USE_ATTR, test x$attr = xtrue)
888 AM_CONDITIONAL(USE_ATTR_SQL, test x$attr_sql = xtrue -o x$sql = xtrue)
889 AM_CONDITIONAL(USE_KERNEL_KLIPS, test x$kernel_klips = xtrue)
890 AM_CONDITIONAL(USE_KERNEL_NETLINK, test x$kernel_netlink = xtrue)
891 AM_CONDITIONAL(USE_KERNEL_PFKEY, test x$kernel_pfkey = xtrue)
892 AM_CONDITIONAL(USE_KERNEL_PFROUTE, test x$kernel_pfroute = xtrue)
893 AM_CONDITIONAL(USE_RESOLVE, test x$resolve = xtrue)
894
895 dnl pluto plugins
896 dnl =============
897 AM_CONDITIONAL(USE_XAUTH, test x$xauth = xtrue)
898
899 dnl other options
900 dnl =============
901 AM_CONDITIONAL(USE_SMARTCARD, test x$smartcard = xtrue)
902 AM_CONDITIONAL(USE_CISCO_QUIRKS, test x$cisco_quirks = xtrue)
903 AM_CONDITIONAL(USE_LEAK_DETECTIVE, test x$leak_detective = xtrue)
904 AM_CONDITIONAL(USE_LOCK_PROFILER, test x$lock_profiler = xtrue)
905 AM_CONDITIONAL(USE_NAT_TRANSPORT, test x$nat_transport = xtrue)
906 AM_CONDITIONAL(USE_VENDORID, test x$vendor_id = xtrue)
907 AM_CONDITIONAL(USE_XAUTH_VID, test x$xauth_vid = xtrue)
908 AM_CONDITIONAL(USE_DUMM, test x$dumm = xtrue)
909 AM_CONDITIONAL(USE_FAST, test x$fast = xtrue)
910 AM_CONDITIONAL(USE_MANAGER, test x$manager = xtrue)
911 AM_CONDITIONAL(USE_ME, test x$mediation = xtrue)
912 AM_CONDITIONAL(USE_INTEGRITY_TEST, test x$integrity_test = xtrue)
913 AM_CONDITIONAL(USE_LOAD_WARNING, test x$load_warning = xtrue)
914 AM_CONDITIONAL(USE_PLUTO, test x$pluto = xtrue)
915 AM_CONDITIONAL(USE_THREADS, test x$threads = xtrue)
916 AM_CONDITIONAL(USE_CHARON, test x$charon = xtrue)
917 AM_CONDITIONAL(USE_TOOLS, test x$tools = xtrue)
918 AM_CONDITIONAL(USE_SCRIPTS, test x$scripts = xtrue)
919 AM_CONDITIONAL(USE_LIBSTRONGSWAN, test x$charon = xtrue -o x$pluto = xtrue -o x$tools = xtrue)
920 AM_CONDITIONAL(USE_LIBHYDRA, test x$charon = xtrue -o x$pluto = xtrue)
921 AM_CONDITIONAL(USE_FILE_CONFIG, test x$pluto = xtrue -o x$stroke = xtrue)
922 AM_CONDITIONAL(USE_LIBCAP, test x$capabilities = xlibcap)
923 AM_CONDITIONAL(USE_VSTR, test x$vstr = xtrue)
924 AM_CONDITIONAL(USE_SIMAKA, test x$simaka = xtrue)
925 AM_CONDITIONAL(USE_TLS, test x$tls = xtrue)
926 AM_CONDITIONAL(MONOLITHIC, test x$monolithic = xtrue)
927
928 dnl ==============================
929 dnl  set global definitions
930 dnl ==============================
931
932 if test x$mediation = xtrue; then
933         AC_DEFINE(ME)
934 fi
935 if test x$capabilities = xlibcap -o x$capabilities = xnative; then
936         AC_DEFINE(CAPABILITIES)
937 fi
938 if test x$monolithic = xtrue; then
939         AC_DEFINE(MONOLITHIC)
940 fi
941
942
943 dnl ==============================
944 dnl  build Makefiles
945 dnl ==============================
946
947 AC_OUTPUT(
948         Makefile
949         man/Makefile
950         src/Makefile
951         src/include/Makefile
952         src/libstrongswan/Makefile
953         src/libstrongswan/plugins/aes/Makefile
954         src/libstrongswan/plugins/des/Makefile
955         src/libstrongswan/plugins/blowfish/Makefile
956         src/libstrongswan/plugins/md4/Makefile
957         src/libstrongswan/plugins/md5/Makefile
958         src/libstrongswan/plugins/sha1/Makefile
959         src/libstrongswan/plugins/sha2/Makefile
960         src/libstrongswan/plugins/fips_prf/Makefile
961         src/libstrongswan/plugins/gmp/Makefile
962         src/libstrongswan/plugins/random/Makefile
963         src/libstrongswan/plugins/hmac/Makefile
964         src/libstrongswan/plugins/xcbc/Makefile
965         src/libstrongswan/plugins/x509/Makefile
966         src/libstrongswan/plugins/revocation/Makefile
967         src/libstrongswan/plugins/pubkey/Makefile
968         src/libstrongswan/plugins/pkcs1/Makefile
969         src/libstrongswan/plugins/pgp/Makefile
970         src/libstrongswan/plugins/dnskey/Makefile
971         src/libstrongswan/plugins/pem/Makefile
972         src/libstrongswan/plugins/curl/Makefile
973         src/libstrongswan/plugins/ldap/Makefile
974         src/libstrongswan/plugins/mysql/Makefile
975         src/libstrongswan/plugins/sqlite/Makefile
976         src/libstrongswan/plugins/padlock/Makefile
977         src/libstrongswan/plugins/openssl/Makefile
978         src/libstrongswan/plugins/gcrypt/Makefile
979         src/libstrongswan/plugins/agent/Makefile
980         src/libstrongswan/plugins/pkcs11/Makefile
981         src/libstrongswan/plugins/ctr/Makefile
982         src/libstrongswan/plugins/ccm/Makefile
983         src/libstrongswan/plugins/gcm/Makefile
984         src/libstrongswan/plugins/af_alg/Makefile
985         src/libstrongswan/plugins/test_vectors/Makefile
986         src/libhydra/Makefile
987         src/libhydra/plugins/attr/Makefile
988         src/libhydra/plugins/attr_sql/Makefile
989         src/libhydra/plugins/kernel_klips/Makefile
990         src/libhydra/plugins/kernel_netlink/Makefile
991         src/libhydra/plugins/kernel_pfkey/Makefile
992         src/libhydra/plugins/kernel_pfroute/Makefile
993         src/libhydra/plugins/resolve/Makefile
994         src/libfreeswan/Makefile
995         src/libsimaka/Makefile
996         src/libtls/Makefile
997         src/pluto/Makefile
998         src/pluto/plugins/xauth/Makefile
999         src/whack/Makefile
1000         src/charon/Makefile
1001         src/libcharon/Makefile
1002         src/libcharon/plugins/eap_aka/Makefile
1003         src/libcharon/plugins/eap_aka_3gpp2/Makefile
1004         src/libcharon/plugins/eap_identity/Makefile
1005         src/libcharon/plugins/eap_md5/Makefile
1006         src/libcharon/plugins/eap_gtc/Makefile
1007         src/libcharon/plugins/eap_sim/Makefile
1008         src/libcharon/plugins/eap_sim_file/Makefile
1009         src/libcharon/plugins/eap_simaka_sql/Makefile
1010         src/libcharon/plugins/eap_simaka_pseudonym/Makefile
1011         src/libcharon/plugins/eap_simaka_reauth/Makefile
1012         src/libcharon/plugins/eap_mschapv2/Makefile
1013         src/libcharon/plugins/eap_tls/Makefile
1014         src/libcharon/plugins/eap_ttls/Makefile
1015         src/libcharon/plugins/eap_tnc/Makefile
1016         src/libcharon/plugins/eap_radius/Makefile
1017         src/libcharon/plugins/tnc_imc/Makefile
1018         src/libcharon/plugins/tnc_imv/Makefile
1019         src/libcharon/plugins/tnccs_11/Makefile
1020         src/libcharon/plugins/tnccs_20/Makefile
1021         src/libcharon/plugins/socket_default/Makefile
1022         src/libcharon/plugins/socket_raw/Makefile
1023         src/libcharon/plugins/socket_dynamic/Makefile
1024         src/libcharon/plugins/farp/Makefile
1025         src/libcharon/plugins/smp/Makefile
1026         src/libcharon/plugins/sql/Makefile
1027         src/libcharon/plugins/medsrv/Makefile
1028         src/libcharon/plugins/medcli/Makefile
1029         src/libcharon/plugins/nm/Makefile
1030         src/libcharon/plugins/addrblock/Makefile
1031         src/libcharon/plugins/uci/Makefile
1032         src/libcharon/plugins/ha/Makefile
1033         src/libcharon/plugins/led/Makefile
1034         src/libcharon/plugins/android/Makefile
1035         src/libcharon/plugins/maemo/Makefile
1036         src/libcharon/plugins/stroke/Makefile
1037         src/libcharon/plugins/updown/Makefile
1038         src/libcharon/plugins/dhcp/Makefile
1039         src/libcharon/plugins/unit_tester/Makefile
1040         src/libcharon/plugins/load_tester/Makefile
1041         src/stroke/Makefile
1042         src/ipsec/Makefile
1043         src/starter/Makefile
1044         src/_updown/Makefile
1045         src/_updown_espmark/Makefile
1046         src/_copyright/Makefile
1047         src/openac/Makefile
1048         src/scepclient/Makefile
1049         src/pki/Makefile
1050         src/dumm/Makefile
1051         src/dumm/ext/extconf.rb
1052         src/libfast/Makefile
1053         src/manager/Makefile
1054         src/medsrv/Makefile
1055         src/checksum/Makefile
1056         scripts/Makefile
1057         testing/Makefile
1058 )