libipsec: Properly handle expiration if no lifetime is set
[strongswan.git] / configure.in
1 #
2 # Copyright (C) 2007-2013 Tobias Brunner
3 # Copyright (C) 2006-2013 Andreas Steffen
4 # Copyright (C) 2006-2013 Martin Willi
5 # Hochschule fuer Technik Rapperswil
6 #
7 # This program is free software; you can redistribute it and/or modify it
8 # under the terms of the GNU General Public License as published by the
9 # Free Software Foundation; either version 2 of the License, or (at your
10 # option) any later version.  See <http://www.fsf.org/copyleft/gpl.txt>.
11 #
12 # This program is distributed in the hope that it will be useful, but
13 # WITHOUT ANY WARRANTY; without even the implied warranty of MERCHANTABILITY
14 # or FITNESS FOR A PARTICULAR PURPOSE.  See the GNU General Public License
15 # for more details.
16 #
17
18 # ============================
19 #  initialize & set some vars
20 # ============================
21
22 AC_INIT([strongSwan],[5.1.0dr1])
23 AM_INIT_AUTOMAKE(tar-ustar)
24 m4_ifdef([AM_SILENT_RULES], [AM_SILENT_RULES])
25 AC_CONFIG_MACRO_DIR([m4/config])
26 AC_CONFIG_HEADERS([config.h])
27 AC_DEFINE([CONFIG_H_INCLUDED], [], [defined if config.h included])
28 PKG_PROG_PKG_CONFIG
29
30 # =================================
31 #  check --enable-xxx & --with-xxx
32 # =================================
33
34 m4_include(m4/macros/with.m4)
35
36 ARG_WITH_SUBST([random-device],      [/dev/random], [set the device to read real random data from])
37 ARG_WITH_SUBST([urandom-device],     [/dev/urandom], [set the device to read pseudo random data from])
38 ARG_WITH_SUBST([strongswan-conf],    [${sysconfdir}/strongswan.conf], [set the strongswan.conf file location])
39 ARG_WITH_SUBST([resolv-conf],        [${sysconfdir}/resolv.conf], [set the file to use in DNS handler plugin])
40 ARG_WITH_SUBST([piddir],             [/var/run], [set path for PID and UNIX socket files])
41 ARG_WITH_SUBST([ipsecdir],           [${libexecdir%/}/ipsec], [set installation path for ipsec tools])
42 ARG_WITH_SUBST([ipseclibdir],        [${libdir%/}/ipsec], [set installation path for ipsec libraries])
43 ARG_WITH_SUBST([plugindir],          [${ipseclibdir%/}/plugins], [set the installation path of plugins])
44 ARG_WITH_SUBST([imcvdir],            [${ipseclibdir%/}/imcvs], [set the installation path of IMC and IMV dynamic librariers])
45 ARG_WITH_SUBST([nm-ca-dir],          [/usr/share/ca-certificates], [directory the NM backend uses to look up trusted root certificates])
46 ARG_WITH_SUBST([linux-headers],      [\${top_srcdir}/src/include], [set directory of linux header files to use])
47 ARG_WITH_SUBST([routing-table],      [220], [set routing table to use for IPsec routes])
48 ARG_WITH_SUBST([routing-table-prio], [220], [set priority for IPsec routing table])
49 ARG_WITH_SUBST([ipsec-script],       [ipsec], [change the name of the ipsec script])
50 ARG_WITH_SUBST([fips-mode],          [0], [set openssl FIPS mode: disabled(0), enabled(1), Suite B enabled(2)])
51
52 ARG_WITH_SET([tss],                  [no], [set implementation of the Trusted Computing Group's Software Stack (TSS). Currently the only supported value is "trousers"])
53 ARG_WITH_SET([capabilities],         [no], [set capability dropping library. Currently supported values are "libcap" and "native"])
54 ARG_WITH_SET([mpz_powm_sec],         [yes], [use the more side-channel resistant mpz_powm_sec in libgmp, if available])
55 ARG_WITH_SET([dev-headers],          [no], [install strongSwan development headers to directory.])
56
57 if test -n "$PKG_CONFIG"; then
58         systemdsystemunitdir_default=$($PKG_CONFIG --variable=systemdsystemunitdir systemd)
59 fi
60 ARG_WITH_SET([systemdsystemunitdir], [$systemdsystemunitdir_default], [directory for systemd service files])
61 AM_CONDITIONAL(HAVE_SYSTEMD, [test -n "$systemdsystemunitdir" -a "x$systemdsystemunitdir" != xno])
62 AC_SUBST(systemdsystemunitdir)
63
64 AC_ARG_WITH(
65         [user],
66         AS_HELP_STRING([--with-user=user],[change user of the daemons to "user" after startup (default is "root").]),
67         [AC_DEFINE_UNQUOTED([IPSEC_USER], "$withval", [username to run daemon with])
68          AC_SUBST(ipsecuser, "$withval")],
69         [AC_SUBST(ipsecuser, "root")]
70 )
71
72 AC_ARG_WITH(
73         [group],
74         AS_HELP_STRING([--with-group=group],[change group of the daemons to "group" after startup (default is "root").]),
75         [AC_DEFINE_UNQUOTED(IPSEC_GROUP, "$withval", [groupname to run daemon with])
76          AC_SUBST(ipsecgroup, "$withval")],
77         [AC_SUBST(ipsecgroup, "root")]
78 )
79
80 AC_ARG_WITH(
81         [charon-udp-port],
82         AS_HELP_STRING([--with-charon-udp-port=port],[UDP port used by charon locally (default 500). Set to 0 to allocate randomly.]),
83         [AC_DEFINE_UNQUOTED(CHARON_UDP_PORT, [$withval], [UDP port used by charon locally])
84          AC_SUBST(charon_udp_port, [$withval])],
85         [AC_SUBST(charon_udp_port, 500)]
86 )
87
88 AC_ARG_WITH(
89         [charon-natt-port],
90         AS_HELP_STRING([--with-charon-natt-port=port],[UDP port used by charon locally in case a NAT is detected (must be different from charon-udp-port, default 4500). Set to 0 to allocate randomly.]),
91         [AC_DEFINE_UNQUOTED(CHARON_NATT_PORT, [$withval], [UDP post used by charon locally in case a NAT is detected])
92          AC_SUBST(charon_natt_port, [$withval])],
93         [AC_SUBST(charon_natt_port, 4500)]
94 )
95
96 AC_MSG_CHECKING([configured UDP ports ($charon_udp_port, $charon_natt_port)])
97 if test x$charon_udp_port != x0 -a x$charon_udp_port = x$charon_natt_port; then
98         AC_MSG_ERROR(the ports have to be different)
99 else
100         AC_MSG_RESULT(ok)
101 fi
102
103 # convert script name to uppercase
104 AC_SUBST(ipsec_script_upper, [`echo -n "$ipsec_script" | tr a-z A-Z`])
105
106 m4_include(m4/macros/enable-disable.m4)
107
108 ARG_ENABL_SET([curl],           [enable CURL fetcher plugin to fetch files via libcurl. Requires libcurl.])
109 ARG_ENABL_SET([unbound],        [enable UNBOUND resolver plugin to perform DNS queries via libunbound. Requires libldns and libunbound.])
110 ARG_ENABL_SET([soup],           [enable soup fetcher plugin to fetch from HTTP via libsoup. Requires libsoup.])
111 ARG_ENABL_SET([ldap],           [enable LDAP fetching plugin to fetch files via libldap. Requires openLDAP.])
112 ARG_DISBL_SET([aes],            [disable AES software implementation plugin.])
113 ARG_DISBL_SET([des],            [disable DES/3DES software implementation plugin.])
114 ARG_ENABL_SET([blowfish],       [enable Blowfish software implementation plugin.])
115 ARG_DISBL_SET([rc2],            [disable RC2 software implementation plugin.])
116 ARG_ENABL_SET([md4],            [enable MD4 software implementation plugin.])
117 ARG_DISBL_SET([md5],            [disable MD5 software implementation plugin.])
118 ARG_DISBL_SET([sha1],           [disable SHA1 software implementation plugin.])
119 ARG_DISBL_SET([sha2],           [disable SHA256/SHA384/SHA512 software implementation plugin.])
120 ARG_DISBL_SET([fips-prf],       [disable FIPS PRF software implementation plugin.])
121 ARG_DISBL_SET([gmp],            [disable GNU MP (libgmp) based crypto implementation plugin.])
122 ARG_ENABL_SET([rdrand],         [enable Intel RDRAND random generator plugin.])
123 ARG_DISBL_SET([random],         [disable RNG implementation on top of /dev/(u)random.])
124 ARG_DISBL_SET([nonce],          [disable nonce generation plugin.])
125 ARG_DISBL_SET([x509],           [disable X509 certificate implementation plugin.])
126 ARG_DISBL_SET([revocation],     [disable X509 CRL/OCSP revocation check plugin.])
127 ARG_DISBL_SET([constraints],    [disable advanced X509 constraint checking plugin.])
128 ARG_DISBL_SET([pubkey],         [disable RAW public key support plugin.])
129 ARG_DISBL_SET([pkcs1],          [disable PKCS1 key decoding plugin.])
130 ARG_DISBL_SET([pkcs7],          [disable PKCS7 container support plugin.])
131 ARG_DISBL_SET([pkcs8],          [disable PKCS8 private key decoding plugin.])
132 ARG_DISBL_SET([pkcs12],         [disable PKCS12 container support plugin.])
133 ARG_DISBL_SET([pgp],            [disable PGP key decoding plugin.])
134 ARG_DISBL_SET([dnskey],         [disable DNS RR key decoding plugin.])
135 ARG_DISBL_SET([sshkey],         [disable SSH key decoding plugin.])
136 ARG_ENABL_SET([ipseckey],       [enable IPSECKEY authentication plugin.])
137 ARG_DISBL_SET([pem],            [disable PEM decoding plugin.])
138 ARG_DISBL_SET([hmac],           [disable HMAC crypto implementation plugin.])
139 ARG_DISBL_SET([cmac],           [disable CMAC crypto implementation plugin.])
140 ARG_DISBL_SET([xcbc],           [disable xcbc crypto implementation plugin.])
141 ARG_ENABL_SET([af-alg],         [enable AF_ALG crypto interface to Linux Crypto API.])
142 ARG_ENABL_SET([test-vectors],   [enable plugin providing crypto test vectors.])
143 ARG_ENABL_SET([mysql],          [enable MySQL database support. Requires libmysqlclient_r.])
144 ARG_ENABL_SET([sqlite],         [enable SQLite database support. Requires libsqlite3.])
145 ARG_DISBL_SET([stroke],         [disable charons stroke configuration backend.])
146 ARG_ENABL_SET([medsrv],         [enable mediation server web frontend and daemon plugin.])
147 ARG_ENABL_SET([medcli],         [enable mediation client configuration database plugin.])
148 ARG_ENABL_SET([smp],            [enable SMP configuration and control interface. Requires libxml.])
149 ARG_ENABL_SET([sql],            [enable SQL database configuration backend.])
150 ARG_ENABL_SET([leak-detective], [enable malloc hooks to find memory leaks.])
151 ARG_ENABL_SET([lock-profiler],  [enable lock/mutex profiling code.])
152 ARG_ENABL_SET([unit-tester],    [enable unit tests on IKEv2 daemon startup.])
153 ARG_ENABL_SET([load-tester],    [enable load testing plugin for IKEv2 daemon.])
154 ARG_ENABL_SET([eap-sim],        [enable SIM authentication module for EAP.])
155 ARG_ENABL_SET([eap-sim-file],   [enable EAP-SIM backend based on a triplet file.])
156 ARG_ENABL_SET([eap-sim-pcsc],   [enable EAP-SIM backend based on a smartcard reader. Requires libpcsclite.])
157 ARG_ENABL_SET([eap-aka],        [enable EAP AKA authentication module.])
158 ARG_ENABL_SET([eap-aka-3gpp2],  [enable EAP AKA backend implementing 3GPP2 algorithms in software. Requires libgmp.])
159 ARG_ENABL_SET([eap-simaka-sql], [enable EAP-SIM/AKA backend based on a triplet/quintuplet SQL database.])
160 ARG_ENABL_SET([eap-simaka-pseudonym], [enable EAP-SIM/AKA pseudonym storage plugin.])
161 ARG_ENABL_SET([eap-simaka-reauth],    [enable EAP-SIM/AKA reauthentication data storage plugin.])
162 ARG_ENABL_SET([eap-identity],   [enable EAP module providing EAP-Identity helper.])
163 ARG_ENABL_SET([eap-md5],        [enable EAP MD5 (CHAP) authentication module.])
164 ARG_ENABL_SET([eap-gtc],        [enable EAP GTC authentication module.])
165 ARG_ENABL_SET([eap-mschapv2],   [enable EAP MS-CHAPv2 authentication module.])
166 ARG_ENABL_SET([eap-tls],        [enable EAP TLS authentication module.])
167 ARG_ENABL_SET([eap-ttls],       [enable EAP TTLS authentication module.])
168 ARG_ENABL_SET([eap-peap],       [enable EAP PEAP authentication module.])
169 ARG_ENABL_SET([eap-tnc],        [enable EAP TNC trusted network connect module.])
170 ARG_ENABL_SET([eap-dynamic],    [enable dynamic EAP proxy module.])
171 ARG_ENABL_SET([eap-radius],     [enable RADIUS proxy authentication module.])
172 ARG_DISBL_SET([xauth-generic],  [disable generic XAuth backend.])
173 ARG_ENABL_SET([xauth-eap],      [enable XAuth backend using EAP methods to verify passwords.])
174 ARG_ENABL_SET([xauth-pam],      [enable XAuth backend using PAM to verify passwords.])
175 ARG_ENABL_SET([xauth-noauth],   [enable XAuth pseudo-backend that does not actually verify or even request any credentials.])
176 ARG_ENABL_SET([tnc-ifmap],      [enable TNC IF-MAP module. Requires libxml])
177 ARG_ENABL_SET([tnc-pdp],        [enable TNC policy decision point module.])
178 ARG_ENABL_SET([tnc-imc],        [enable TNC IMC module.])
179 ARG_ENABL_SET([tnc-imv],        [enable TNC IMV module.])
180 ARG_ENABL_SET([tnccs-11],       [enable TNCCS 1.1 protocol module. Requires libxml])
181 ARG_ENABL_SET([tnccs-20],       [enable TNCCS 2.0 protocol module.])
182 ARG_ENABL_SET([tnccs-dynamic],  [enable dynamic TNCCS protocol discovery module.])
183 ARG_ENABL_SET([imc-test],       [enable IMC test module.])
184 ARG_ENABL_SET([imv-test],       [enable IMV test module.])
185 ARG_ENABL_SET([imc-scanner],    [enable IMC port scanner module.])
186 ARG_ENABL_SET([imv-scanner],    [enable IMV port scanner module.])
187 ARG_ENABL_SET([imc-os],         [enable IMC operating system module.])
188 ARG_ENABL_SET([imv-os],         [enable IMV operating system module.])
189 ARG_ENABL_SET([imc-attestation],[enable IMC attestation module.])
190 ARG_ENABL_SET([imv-attestation],[enable IMV attestation module.])
191 ARG_DISBL_SET([kernel-netlink], [disable the netlink kernel interface.])
192 ARG_ENABL_SET([kernel-pfkey],   [enable the PF_KEY kernel interface.])
193 ARG_ENABL_SET([kernel-pfroute], [enable the PF_ROUTE kernel interface.])
194 ARG_ENABL_SET([kernel-klips],   [enable the KLIPS kernel interface.])
195 ARG_ENABL_SET([kernel-libipsec],[enable the libipsec kernel interface.])
196 ARG_ENABL_SET([libipsec],       [enable user space IPsec implementation.])
197 ARG_DISBL_SET([socket-default], [disable default socket implementation for charon.])
198 ARG_ENABL_SET([socket-dynamic], [enable dynamic socket implementation for charon])
199 ARG_ENABL_SET([farp],           [enable ARP faking plugin that responds to ARP requests to peers virtual IP])
200 ARG_ENABL_SET([dumm],           [enable the DUMM UML test framework.])
201 ARG_ENABL_SET([fast],           [enable libfast (FastCGI Application Server w/ templates.])
202 ARG_ENABL_SET([manager],        [enable web management console (proof of concept).])
203 ARG_ENABL_SET([mediation],      [enable IKEv2 Mediation Extension.])
204 ARG_ENABL_SET([integrity-test], [enable integrity testing of libstrongswan and plugins.])
205 ARG_DISBL_SET([load-warning],   [disable the charon plugin load option warning in starter.])
206 ARG_DISBL_SET([ikev1],          [disable IKEv1 protocol support in charon.])
207 ARG_DISBL_SET([ikev2],          [disable IKEv2 protocol support in charon.])
208 ARG_DISBL_SET([charon],         [disable the IKEv1/IKEv2 keying daemon charon.])
209 ARG_DISBL_SET([tools],          [disable additional utilities (openac, scepclient and pki).])
210 ARG_DISBL_SET([scripts],        [disable additional utilities (found in directory scripts).])
211 ARG_ENABL_SET([conftest],       [enforce Suite B conformance test framework.])
212 ARG_DISBL_SET([updown],         [disable updown firewall script plugin.])
213 ARG_DISBL_SET([attr],           [disable strongswan.conf based configuration attribute plugin.])
214 ARG_ENABL_SET([attr-sql],       [enable SQL based configuration attribute plugin.])
215 ARG_ENABL_SET([dhcp],           [enable DHCP based attribute provider plugin.])
216 ARG_DISBL_SET([resolve],        [disable resolve DNS handler plugin.])
217 ARG_ENABL_SET([padlock],        [enables VIA Padlock crypto plugin.])
218 ARG_ENABL_SET([openssl],        [enables the OpenSSL crypto plugin.])
219 ARG_ENABL_SET([gcrypt],         [enables the libgcrypt plugin.])
220 ARG_ENABL_SET([agent],          [enables the ssh-agent signing plugin.])
221 ARG_ENABL_SET([pkcs11],         [enables the PKCS11 token support plugin.])
222 ARG_ENABL_SET([ctr],            [enables the Counter Mode wrapper crypto plugin.])
223 ARG_ENABL_SET([ccm],            [enables the CCM AEAD wrapper crypto plugin.])
224 ARG_ENABL_SET([gcm],            [enables the GCM AEAD wrapper crypto plugin.])
225 ARG_ENABL_SET([addrblock],      [enables RFC 3779 address block constraint support.])
226 ARG_ENABL_SET([unity],          [enables Cisco Unity extension plugin.])
227 ARG_ENABL_SET([uci],            [enable OpenWRT UCI configuration plugin.])
228 ARG_ENABL_SET([osx-attr],       [enable OS X SystemConfiguration attribute handler.])
229 ARG_ENABL_SET([android-dns],    [enable Android specific DNS handler.])
230 ARG_ENABL_SET([android-log],    [enable Android specific logger plugin.])
231 ARG_ENABL_SET([maemo],          [enable Maemo specific plugin.])
232 ARG_ENABL_SET([nm],             [enable NetworkManager backend.])
233 ARG_ENABL_SET([ha],             [enable high availability cluster plugin.])
234 ARG_ENABL_SET([whitelist],      [enable peer identity whitelisting plugin.])
235 ARG_ENABL_SET([lookip],         [enable fast virtual IP lookup and notification plugin.])
236 ARG_ENABL_SET([error-notify],   [enable error notification plugin.])
237 ARG_ENABL_SET([certexpire],     [enable CSV export of expiration dates of used certificates.])
238 ARG_ENABL_SET([systime-fix],    [enable plugin to handle cert lifetimes with invalid system time gracefully.])
239 ARG_ENABL_SET([led],            [enable plugin to control LEDs on IKEv2 activity using the Linux kernel LED subsystem.])
240 ARG_ENABL_SET([duplicheck],     [advanced duplicate checking plugin using liveness checks.])
241 ARG_ENABL_SET([coupling],       [enable IKEv2 plugin to couple peer certificates permanently to authentication.])
242 ARG_ENABL_SET([radattr],        [enable plugin to inject and process custom RADIUS attributes as IKEv2 client.])
243 ARG_ENABL_SET([vstr],           [enforce using the Vstr string library to replace glibc-like printf hooks.])
244 ARG_ENABL_SET([monolithic],     [build monolithic version of libstrongswan that includes all enabled plugins. Similarly, the plugins of charon are assembled in libcharon.])
245 ARG_ENABL_SET([bfd-backtraces], [use binutils libbfd to resolve backtraces for memory leaks and segfaults.])
246 ARG_ENABL_SET([unwind-backtraces],[use libunwind to create backtraces for memory leaks and segfaults.])
247 ARG_ENABL_SET([unit-tests],     [enable unit tests using the check test framework.])
248 ARG_ENABL_SET([coverage],       [enable lcov coverage report generation.])
249 ARG_ENABL_SET([tkm],            [enable Trusted Key Manager support.])
250 ARG_ENABL_SET([cmd],            [enable the command line IKE client charon-cmd.])
251
252 # ===================================
253 #  option to disable default options
254 # ===================================
255
256 ARG_DISBL_SET([defaults],       [disable all default plugins (they can be enabled with their respective --enable options)])
257
258 if test x$defaults = xfalse; then
259         for option in $enabled_by_default; do
260                 eval test x\${${option}_given} = xtrue && continue
261                 let $option=false
262         done
263 fi
264
265 # ===========================
266 #  set up compiler and flags
267 # ===========================
268
269 if test -z "$CFLAGS"; then
270         CFLAGS="-g -O2 -Wall -Wno-format -Wno-pointer-sign"
271 fi
272 AC_PROG_CC
273 AM_PROG_CC_C_O
274
275 AC_LIB_PREFIX
276 AC_C_BIGENDIAN
277
278 # =========================
279 #  check required programs
280 # =========================
281
282 LT_INIT
283 AC_PROG_INSTALL
284 AC_PROG_EGREP
285 AC_PROG_AWK
286 AC_PROG_LEX
287 AC_PROG_YACC
288 AC_PATH_PROG([PERL], [perl], [], [$PATH:/bin:/usr/bin:/usr/local/bin])
289 AC_PATH_PROG([GPERF], [gperf], [], [$PATH:/bin:/usr/bin:/usr/local/bin])
290
291 # because gperf is not needed by end-users we just report it but do not abort on failure
292 AC_MSG_CHECKING([gperf version >= 3.0.0])
293 if test -x "$GPERF"; then
294         if test "`$GPERF --version | $AWK -F' ' '/^GNU gperf/ { print $3 }' | $AWK -F. '{ print $1 }'`" -ge "3"; then
295                 AC_MSG_RESULT([yes])
296         else
297                 AC_MSG_RESULT([no])
298         fi
299 else
300         AC_MSG_RESULT([not found])
301 fi
302
303 # ========================
304 #  dependency calculation
305 # ========================
306
307 if test x$xauth_generic_given = xfalse -a x$ikev1 = xfalse; then
308         xauth_generic=false;
309 fi
310
311 if test x$kernel_libipsec = xtrue; then
312         libipsec=true;
313 fi
314
315 if test x$eap_aka_3gpp2 = xtrue; then
316         gmp=true;
317 fi
318
319 if test x$eap_aka = xtrue; then
320         fips_prf=true;
321         simaka=true;
322 fi
323
324 if test x$eap_sim = xtrue; then
325         fips_prf=true;
326         simaka=true;
327 fi
328
329 if test x$eap_tls = xtrue -o x$eap_ttls = xtrue -o x$eap_peap = xtrue; then
330         tls=true;
331 fi
332
333 if test x$eap_radius = xtrue -o x$radattr = xtrue -o x$tnc_pdp = xtrue; then
334         radius=true;
335 fi
336
337 if test x$tnc_imc = xtrue -o x$tnc_imv = xtrue -o x$tnccs_11 = xtrue -o x$tnccs_11 = xtrue -o x$tnccs_dynamic = xtrue -o x$eap_tnc = xtrue; then
338         tnc_tnccs=true;
339 fi
340
341 if test x$imc_test = xtrue -o x$imv_test = xtrue -o x$imc_scanner = xtrue -o x$imv_scanner = xtrue -o x$imc_os = xtrue -o x$imv_os = xtrue -o x$imc_attestation = xtrue -o x$imv_attestation = xtrue; then
342         imcv=true;
343 fi
344
345 if test x$imc_attestation = xtrue -o x$imv_attestation = xtrue; then
346         pts=true;
347 fi
348
349 if test x$fips_prf = xtrue; then
350         if test x$openssl = xfalse; then
351                 sha1=true;
352         fi
353 fi
354
355 if test x$smp = xtrue -o x$tnccs_11 = xtrue -o x$tnc_ifmap = xtrue; then
356         xml=true
357 fi
358
359 if test x$manager = xtrue; then
360         fast=true
361 fi
362
363 if test x$medsrv = xtrue; then
364         mediation=true
365         fast=true
366 fi
367
368 if test x$medcli = xtrue; then
369         mediation=true
370 fi
371
372 if test x$coverage = xtrue; then
373         unit_tests=true
374 fi
375
376 # ===========================================
377 #  check required libraries and header files
378 # ===========================================
379
380 AC_HEADER_STDBOOL
381 AC_FUNC_ALLOCA
382 AC_FUNC_STRERROR_R
383
384 #  libraries needed on some platforms but not on others
385 # ------------------------------------------------------
386 saved_LIBS=$LIBS
387
388 # FreeBSD and Mac OS X have dlopen integrated in libc, Linux needs libdl
389 LIBS=""
390 AC_SEARCH_LIBS(dlopen, dl, [DLLIB=$LIBS])
391 AC_SUBST(DLLIB)
392
393 # glibc's backtrace() can be replicated on FreeBSD with libexecinfo
394 LIBS=""
395 AC_SEARCH_LIBS(backtrace, execinfo, [BTLIB=$LIBS])
396 AC_CHECK_FUNCS(backtrace)
397 AC_SUBST(BTLIB)
398
399 # OpenSolaris needs libsocket and libnsl for socket()
400 LIBS=""
401 AC_SEARCH_LIBS(socket, socket, [SOCKLIB=$LIBS],
402         [AC_CHECK_LIB(nsl, socket, [SOCKLIB="-lsocket -lnsl"], [], [-lsocket])]
403 )
404 AC_SUBST(SOCKLIB)
405
406 # FreeBSD has clock_gettime in libc, Linux needs librt
407 LIBS=""
408 AC_SEARCH_LIBS(clock_gettime, rt, [RTLIB=$LIBS])
409 AC_CHECK_FUNCS(clock_gettime)
410 AC_SUBST(RTLIB)
411
412 # Android has pthread_* functions in bionic (libc), others need libpthread
413 LIBS=""
414 AC_SEARCH_LIBS(pthread_create, pthread, [PTHREADLIB=$LIBS])
415 AC_SUBST(PTHREADLIB)
416
417 LIBS=$saved_LIBS
418 # ------------------------------------------------------
419
420 AC_MSG_CHECKING(for dladdr)
421 AC_COMPILE_IFELSE(
422         [AC_LANG_PROGRAM(
423                 [[#define _GNU_SOURCE
424                   #include <dlfcn.h>]],
425                 [[Dl_info* info = 0;
426                   dladdr(0, info);]])],
427         [AC_MSG_RESULT([yes]); AC_DEFINE([HAVE_DLADDR], [], [have dladdr()])],
428         [AC_MSG_RESULT([no])]
429 )
430
431 # check if pthread_condattr_setclock(CLOCK_MONOTONE) is supported
432 saved_LIBS=$LIBS
433 LIBS=$PTHREADLIB
434 AC_MSG_CHECKING([for pthread_condattr_setclock(CLOCK_MONOTONE)])
435 AC_RUN_IFELSE(
436         [AC_LANG_SOURCE(
437                 [[#include <pthread.h>
438                   int main() { pthread_condattr_t attr;
439                         pthread_condattr_init(&attr);
440                         return pthread_condattr_setclock(&attr, CLOCK_MONOTONIC);}]])],
441         [AC_MSG_RESULT([yes]);
442          AC_DEFINE([HAVE_CONDATTR_CLOCK_MONOTONIC], [],
443                            [pthread_condattr_setclock supports CLOCK_MONOTONIC])],
444         [AC_MSG_RESULT([no])],
445         # Check existence of pthread_condattr_setclock if cross-compiling
446         [AC_MSG_RESULT([unknown]);
447          AC_CHECK_FUNCS(pthread_condattr_setclock,
448                 [AC_DEFINE([HAVE_CONDATTR_CLOCK_MONOTONIC], [],
449                                    [have pthread_condattr_setclock()])]
450         )]
451 )
452 # check if we actually are able to configure attributes on cond vars
453 AC_CHECK_FUNCS(pthread_condattr_init)
454 # instead of pthread_condattr_setclock Android has this function
455 AC_CHECK_FUNCS(pthread_cond_timedwait_monotonic)
456 # check if we can cancel threads
457 AC_CHECK_FUNCS(pthread_cancel)
458 # check if native rwlocks are available
459 AC_CHECK_FUNCS(pthread_rwlock_init)
460 # check if pthread spinlocks are available
461 AC_CHECK_FUNCS(pthread_spin_init)
462 # check if we have POSIX semaphore functions, including timed-wait
463 AC_CHECK_FUNCS(sem_timedwait)
464 LIBS=$saved_LIBS
465
466 AC_CHECK_FUNC(
467         [gettid],
468         [AC_DEFINE([HAVE_GETTID], [], [have gettid()])],
469         [AC_MSG_CHECKING([for SYS_gettid])
470          AC_COMPILE_IFELSE(
471                 [AC_LANG_PROGRAM(
472                         [[#define _GNU_SOURCE
473                           #include <unistd.h>
474                           #include <sys/syscall.h>]],
475                         [[int main() {
476                           return syscall(SYS_gettid);}]])],
477                 [AC_MSG_RESULT([yes]);
478                  AC_DEFINE([HAVE_GETTID], [], [have gettid()])
479                  AC_DEFINE([HAVE_SYS_GETTID], [], [have syscall(SYS_gettid)])],
480                 [AC_MSG_RESULT([no])]
481         )]
482 )
483
484 AC_CHECK_FUNCS(prctl mallinfo getpass closefrom getpwnam_r getgrnam_r getpwuid_r)
485
486 AC_CHECK_HEADERS(sys/sockio.h glob.h)
487 AC_CHECK_HEADERS(net/pfkeyv2.h netipsec/ipsec.h netinet6/ipsec.h linux/udp.h)
488 AC_CHECK_HEADERS(netinet/ip6.h, [], [],
489 [
490         #include <sys/types.h>
491         #include <netinet/in.h>
492 ])
493
494 AC_CHECK_MEMBERS([struct sockaddr.sa_len], [], [],
495 [
496         #include <sys/types.h>
497         #include <sys/socket.h>
498 ])
499
500 AC_CHECK_MEMBERS([struct sadb_x_policy.sadb_x_policy_priority], [], [],
501 [
502         #include <sys/types.h>
503         #ifdef HAVE_NET_PFKEYV2_H
504         #include <net/pfkeyv2.h>
505         #else
506         #include <stdint.h>
507         #include <linux/pfkeyv2.h>
508         #endif
509 ])
510
511 AC_MSG_CHECKING([for in6addr_any])
512 AC_COMPILE_IFELSE(
513         [AC_LANG_PROGRAM(
514                 [[#include <sys/types.h>
515                   #include <sys/socket.h>
516                   #include <netinet/in.h>]],
517                 [[struct in6_addr in6;
518                   in6 = in6addr_any;]])],
519         [AC_MSG_RESULT([yes]);
520          AC_DEFINE([HAVE_IN6ADDR_ANY], [], [have struct in6_addr in6addr_any])],
521         [AC_MSG_RESULT([no])]
522 )
523
524 AC_MSG_CHECKING([for in6_pktinfo])
525 AC_COMPILE_IFELSE(
526         [AC_LANG_PROGRAM(
527                 [[#define _GNU_SOURCE
528                   #include <sys/types.h>
529                   #include <sys/socket.h>
530                   #include <netinet/in.h>]],
531                 [[struct in6_pktinfo pi;
532                   if (pi.ipi6_ifindex)
533                   {
534                     return 0;
535                   }]])],
536         [AC_MSG_RESULT([yes]);
537          AC_DEFINE([HAVE_IN6_PKTINFO], [], [have struct in6_pktinfo.ipi6_ifindex])],
538         [AC_MSG_RESULT([no])]
539 )
540
541 AC_MSG_CHECKING([for IPSEC_MODE_BEET])
542 AC_COMPILE_IFELSE(
543         [AC_LANG_PROGRAM(
544                 [[#include <sys/types.h>
545                   #ifdef HAVE_NETIPSEC_IPSEC_H
546                   #include <netipsec/ipsec.h>
547                   #elif defined(HAVE_NETINET6_IPSEC_H)
548                   #include <netinet6/ipsec.h>
549                   #else
550                   #include <stdint.h>
551                   #include <linux/ipsec.h>
552                   #endif]],
553                 [[int mode = IPSEC_MODE_BEET;
554                   return mode;]])],
555         [AC_MSG_RESULT([yes]);
556          AC_DEFINE([HAVE_IPSEC_MODE_BEET], [], [have IPSEC_MODE_BEET defined])],
557         [AC_MSG_RESULT([no])]
558 )
559
560 AC_MSG_CHECKING([for IPSEC_DIR_FWD])
561 AC_COMPILE_IFELSE(
562         [AC_LANG_PROGRAM(
563                 [[#include <sys/types.h>
564                   #ifdef HAVE_NETIPSEC_IPSEC_H
565                   #include <netipsec/ipsec.h>
566                   #elif defined(HAVE_NETINET6_IPSEC_H)
567                   #include <netinet6/ipsec.h>
568                   #else
569                   #include <stdint.h>
570                   #include <linux/ipsec.h>
571                   #endif]],
572                 [[int dir = IPSEC_DIR_FWD;
573                   return dir;]])],
574         [AC_MSG_RESULT([yes]);
575          AC_DEFINE([HAVE_IPSEC_DIR_FWD], [], [have IPSEC_DIR_FWD defined])],
576         [AC_MSG_RESULT([no])]
577 )
578
579 AC_MSG_CHECKING([for RTA_TABLE])
580 AC_COMPILE_IFELSE(
581         [AC_LANG_PROGRAM(
582                 [[#include <sys/socket.h>
583                   #include <linux/netlink.h>
584                   #include <linux/rtnetlink.h>]],
585                 [[int rta_type = RTA_TABLE;
586                   return rta_type;]])],
587         [AC_MSG_RESULT([yes]);
588          AC_DEFINE([HAVE_RTA_TABLE], [], [have netlink RTA_TABLE defined])],
589         [AC_MSG_RESULT([no])]
590 )
591
592 AC_MSG_CHECKING([for gcc atomic operations])
593 AC_RUN_IFELSE([AC_LANG_SOURCE(
594         [[
595                         int main() {
596                         volatile int ref = 1;
597                         __sync_fetch_and_add (&ref, 1);
598                         __sync_sub_and_fetch (&ref, 1);
599                         /* Make sure test fails if operations are not supported */
600                         __sync_val_compare_and_swap(&ref, 1, 0);
601                         return ref;
602                 }
603         ]])],
604         [AC_MSG_RESULT([yes]);
605          AC_DEFINE([HAVE_GCC_ATOMIC_OPERATIONS], [],
606                    [have GCC __sync_* atomic operations])],
607         [AC_MSG_RESULT([no])],
608         [AC_MSG_RESULT([no])]
609 )
610
611 # check for the new register_printf_specifier function with len argument,
612 # or the deprecated register_printf_function without
613 AC_CHECK_FUNC(
614         [register_printf_specifier],
615         [AC_DEFINE([HAVE_PRINTF_SPECIFIER], [], [have register_printf_specifier()])],
616         [AC_CHECK_FUNC(
617                 [register_printf_function],
618                 [AC_DEFINE([HAVE_PRINTF_FUNCTION], [], [have register_printf_function()])],
619                 [
620                         AC_MSG_NOTICE([printf does not support custom format specifiers!])
621                         vstr=true
622                 ]
623         )]
624 )
625
626 if test x$vstr = xtrue; then
627         AC_CHECK_LIB([vstr],[main],[LIBS="$LIBS"],[AC_MSG_ERROR([Vstr string library not found])],[])
628         AC_DEFINE([USE_VSTR], [], [use vstring library for printf hooks])
629 fi
630
631 if test x$gmp = xtrue; then
632         saved_LIBS=$LIBS
633         AC_CHECK_LIB([gmp],[main],[],[AC_MSG_ERROR([GNU Multi Precision library gmp not found])],[])
634         AC_MSG_CHECKING([mpz_powm_sec])
635         if test x$mpz_powm_sec = xyes; then
636                 AC_COMPILE_IFELSE(
637                         [AC_LANG_PROGRAM(
638                                 [[#include "gmp.h"]],
639                                 [[void *x = mpz_powm_sec;]])],
640                         [AC_MSG_RESULT([yes]);
641                          AC_DEFINE([HAVE_MPZ_POWM_SEC], [], [have mpz_mown_sec()])],
642                         [AC_MSG_RESULT([no])]
643                 )
644         else
645                 AC_MSG_RESULT([disabled])
646         fi
647         LIBS=$saved_LIBS
648         AC_MSG_CHECKING([gmp.h version >= 4.1.4])
649         AC_COMPILE_IFELSE(
650                 [AC_LANG_PROGRAM(
651                         [[#include "gmp.h"]],
652                         [[
653                                 #if (__GNU_MP_VERSION*100 +  __GNU_MP_VERSION_MINOR*10 + __GNU_MP_VERSION_PATCHLEVEL) < 414
654                                         #error bad gmp
655                                 #endif]])],
656                 [AC_MSG_RESULT([yes])],
657                 [AC_MSG_RESULT([no]); AC_MSG_ERROR([No usable gmp.h found!])]
658         )
659 fi
660
661 if test x$ldap = xtrue; then
662         AC_CHECK_LIB([ldap],[main],[LIBS="$LIBS"],[AC_MSG_ERROR([LDAP library ldap not found])],[])
663         AC_CHECK_LIB([lber],[main],[LIBS="$LIBS"],[AC_MSG_ERROR([LDAP library lber not found])],[])
664         AC_CHECK_HEADER([ldap.h],,[AC_MSG_ERROR([LDAP header ldap.h not found!])])
665 fi
666
667 if test x$curl = xtrue; then
668         AC_CHECK_LIB([curl],[main],[LIBS="$LIBS"],[AC_MSG_ERROR([CURL library curl not found])],[])
669         AC_CHECK_HEADER([curl/curl.h],,[AC_MSG_ERROR([CURL header curl/curl.h not found!])])
670 fi
671
672 if test x$unbound = xtrue; then
673         AC_HAVE_LIBRARY([ldns],[LIBS="$LIBS"],[AC_MSG_ERROR([UNBOUND library ldns not found])])
674         AC_CHECK_HEADER([ldns/ldns.h],,[AC_MSG_ERROR([UNBOUND header ldns/ldns.h not found!])])
675         AC_HAVE_LIBRARY([unbound],[LIBS="$LIBS"],[AC_MSG_ERROR([UNBOUND library libunbound not found])])
676         AC_CHECK_HEADER([unbound.h],,[AC_MSG_ERROR([UNBOUND header unbound.h not found!])])
677 fi
678
679 if test x$soup = xtrue; then
680         PKG_CHECK_MODULES(soup, [libsoup-2.4])
681         AC_SUBST(soup_CFLAGS)
682         AC_SUBST(soup_LIBS)
683 fi
684
685 if test x$xml = xtrue; then
686         PKG_CHECK_MODULES(xml, [libxml-2.0])
687         AC_SUBST(xml_CFLAGS)
688         AC_SUBST(xml_LIBS)
689 fi
690
691 if test x$tss = xtrousers; then
692         AC_CHECK_LIB([tspi],[main],[LIBS="$LIBS"],[AC_MSG_ERROR([TrouSerS library libtspi not found])],[])
693         AC_CHECK_HEADER([trousers/tss.h],,[AC_MSG_ERROR([TrouSerS header trousers/tss.h not found!])])
694         AC_DEFINE([TSS_TROUSERS], [], [use TrouSerS library libtspi as TSS implementation])
695 fi
696
697 if test x$dumm = xtrue; then
698         PKG_CHECK_MODULES(gtk, [gtk+-2.0 vte])
699         AC_SUBST(gtk_CFLAGS)
700         AC_SUBST(gtk_LIBS)
701         AC_CHECK_PROGS(RUBY, ruby)
702         AC_MSG_CHECKING([for Ruby header files])
703         if test -n "$RUBY"; then
704                 RUBYINCLUDE=
705                 RUBYDIR=`($RUBY -r rbconfig -e 'print RbConfig::CONFIG[["rubyhdrdir"]] || ""') 2>/dev/null`
706                 if test -n "$RUBYDIR" -a -r "$RUBYDIR/ruby.h"; then
707                         RUBYARCH=`($RUBY -r rbconfig -e 'print RbConfig::CONFIG[["arch"]] || ""') 2>/dev/null`
708                         if test -n "$RUBYARCH"; then
709                                 AC_MSG_RESULT([$RUBYDIR])
710                                 RUBYINCLUDE="-I$RUBYDIR -I$RUBYDIR/$RUBYARCH"
711                         fi
712                 else
713                         RUBYDIR=`($RUBY -r rbconfig -e 'print RbConfig::CONFIG[["archdir"]] || ""') 2>/dev/null`
714                         if test -n "$RUBYDIR" -a -r "$RUBYDIR/ruby.h"; then
715                                 AC_MSG_RESULT([$RUBYDIR])
716                                 RUBYINCLUDE="-I$RUBYDIR"
717                         fi
718                 fi
719                 if test -z "$RUBYINCLUDE"; then
720                         AC_MSG_ERROR([ruby.h not found])
721                 fi
722                 AC_SUBST(RUBYINCLUDE)
723         else
724                 AC_MSG_ERROR([don't know how to run ruby])
725         fi
726         AC_MSG_CHECKING([for libruby])
727         saved_LIBS=$LIBS
728         LIBS=`($RUBY -r rbconfig -e 'print RbConfig::CONFIG[["LIBRUBYARG_SHARED"]] || ""') 2>/dev/null`
729         AC_TRY_LINK_FUNC(ruby_init,
730                 [AC_MSG_RESULT([$LIBS]); RUBYLIB=$LIBS],
731                 [AC_MSG_ERROR([not found])])
732         AC_SUBST(RUBYLIB)
733         AC_CHECK_FUNCS(rb_errinfo)
734         LIBS=$saved_LIBS
735 fi
736
737 if test x$fast = xtrue; then
738         AC_CHECK_LIB([neo_cgi],[main],[LIBS="$LIBS"],[AC_MSG_ERROR([ClearSilver library neo_cgi not found!])],[])
739         AC_CHECK_LIB([neo_utl],[main],[LIBS="$LIBS"],[AC_MSG_ERROR([ClearSilver library neo_utl not found!])],[])
740         AC_MSG_CHECKING([ClearSilver requires zlib])
741         saved_CFLAGS=$CFLAGS
742         saved_LIBS=$LIBS
743         LIBS="-lneo_cgi -lneo_cs -lneo_utl"
744         CFLAGS="-I/usr/include/ClearSilver"
745         AC_LINK_IFELSE(
746                 [AC_LANG_PROGRAM(
747                         [[#include <ClearSilver.h>]],
748                         [[NEOERR *err = cgi_display(NULL, NULL);]])],
749                 [AC_MSG_RESULT([no]); clearsilver_LIBS="$LIBS"],
750                 [AC_MSG_RESULT([yes]); clearsilver_LIBS="$LIBS -lz"]
751         )
752         AC_SUBST(clearsilver_LIBS)
753         LIBS=$saved_LIBS
754         CFLAGS=$saved_CFLAGS
755 # autoconf does not like CamelCase!? How to fix this?
756 #       AC_CHECK_HEADER([ClearSilver/ClearSilver.h],,[AC_MSG_ERROR([ClearSilver header file ClearSilver/ClearSilver.h not found!])])
757
758         AC_CHECK_LIB([fcgi],[main],[LIBS="$LIBS"],[AC_MSG_ERROR([FastCGI library fcgi not found!])],[])
759         AC_CHECK_HEADER([fcgiapp.h],,[AC_MSG_ERROR([FastCGI header file fcgiapp.h not found!])])
760 fi
761
762 if test x$mysql = xtrue; then
763         AC_PATH_PROG([MYSQLCONFIG], [mysql_config], [], [$PATH:/bin:/usr/bin:/usr/local/bin])
764         if test x$MYSQLCONFIG = x; then
765                 AC_MSG_ERROR([mysql_config not found!])
766         fi
767         AC_SUBST(MYSQLLIB, `$MYSQLCONFIG --libs_r`)
768         AC_SUBST(MYSQLCFLAG, `$MYSQLCONFIG --cflags`)
769 fi
770
771 if test x$sqlite = xtrue; then
772         AC_CHECK_LIB([sqlite3],[main],[LIBS="$LIBS"],[AC_MSG_ERROR([SQLite library sqlite3 not found])],[])
773         AC_CHECK_HEADER([sqlite3.h],,[AC_MSG_ERROR([SQLite header sqlite3.h not found!])])
774         AC_MSG_CHECKING([sqlite3_prepare_v2])
775         AC_COMPILE_IFELSE(
776                 [AC_LANG_PROGRAM(
777                         [[#include <sqlite3.h>]],
778                         [[void *test = sqlite3_prepare_v2;]])],
779                 [AC_MSG_RESULT([yes]);
780                  AC_DEFINE([HAVE_SQLITE3_PREPARE_V2], [], [have sqlite3_prepare_v2()])],
781                 [AC_MSG_RESULT([no])]
782         )
783         AC_MSG_CHECKING([sqlite3.h version >= 3.3.1])
784         AC_COMPILE_IFELSE(
785                 [AC_LANG_PROGRAM(
786                         [[#include <sqlite3.h>]],
787                         [[
788                                 #if SQLITE_VERSION_NUMBER < 3003001
789                                         #error bad sqlite
790                                 #endif]])],
791                 [AC_MSG_RESULT([yes])],
792                 [AC_MSG_RESULT([no]); AC_MSG_ERROR([SQLite version >= 3.3.1 required!])]
793         )
794 fi
795
796 if test x$openssl = xtrue; then
797         AC_CHECK_LIB([crypto],[main],[LIBS="$LIBS"],[AC_MSG_ERROR([OpenSSL crypto library not found])],[])
798         AC_CHECK_HEADER([openssl/evp.h],,[AC_MSG_ERROR([OpenSSL header openssl/evp.h not found!])])
799 fi
800
801 if test x$gcrypt = xtrue; then
802         AC_CHECK_LIB([gcrypt],[main],[LIBS="$LIBS"],[AC_MSG_ERROR([gcrypt library not found])],[-lgpg-error])
803         AC_CHECK_HEADER([gcrypt.h],,[AC_MSG_ERROR([gcrypt header gcrypt.h not found!])])
804         AC_MSG_CHECKING([gcrypt CAMELLIA cipher])
805         AC_COMPILE_IFELSE(
806                 [AC_LANG_PROGRAM(
807                         [[#include <gcrypt.h>]],
808                         [[enum gcry_cipher_algos alg = GCRY_CIPHER_CAMELLIA128;]])],
809                 [AC_MSG_RESULT([yes]);
810                  AC_DEFINE([HAVE_GCRY_CIPHER_CAMELLIA], [], [have GCRY_CIPHER_CAMELLIA128])],
811                 [AC_MSG_RESULT([no])]
812         )
813 fi
814
815 if test x$uci = xtrue; then
816         AC_CHECK_LIB([uci],[main],[LIBS="$LIBS"],[AC_MSG_ERROR([UCI library libuci not found])],[])
817         AC_CHECK_HEADER([uci.h],,[AC_MSG_ERROR([UCI header uci.h not found!])])
818 fi
819
820 if test x$android_dns = xtrue; then
821         AC_CHECK_LIB([cutils],[main],[LIBS="$LIBS"],[AC_MSG_ERROR([Android library libcutils not found])],[])
822         AC_CHECK_HEADER([cutils/properties.h],,[AC_MSG_ERROR([Android header cutils/properties.h not found!])])
823         # we have to force the use of libdl here because the autodetection
824         # above does not work correctly when cross-compiling for android.
825         DLLIB="-ldl"
826         AC_SUBST(DLLIB)
827 fi
828
829 if test x$maemo = xtrue; then
830         PKG_CHECK_MODULES(maemo, [glib-2.0 gthread-2.0 libosso osso-af-settings])
831         AC_SUBST(maemo_CFLAGS)
832         AC_SUBST(maemo_LIBS)
833         dbusservicedir="/usr/share/dbus-1/system-services"
834         AC_SUBST(dbusservicedir)
835 fi
836
837 if test x$eap_sim_pcsc = xtrue; then
838         PKG_CHECK_MODULES(pcsclite, [libpcsclite])
839         AC_SUBST(pcsclite_CFLAGS)
840         AC_SUBST(pcsclite_LIBS)
841 fi
842
843 if test x$nm = xtrue; then
844         PKG_CHECK_EXISTS([libnm-glib],
845                 [PKG_CHECK_MODULES(nm, [NetworkManager gthread-2.0 libnm-util libnm-glib libnm-glib-vpn])],
846                 [PKG_CHECK_MODULES(nm, [NetworkManager gthread-2.0 libnm_util libnm_glib libnm_glib_vpn])]
847         )
848         AC_SUBST(nm_CFLAGS)
849         AC_SUBST(nm_LIBS)
850 fi
851
852 if test x$xauth_pam = xtrue; then
853         AC_CHECK_LIB([pam],[main],[LIBS="$LIBS"],[AC_MSG_ERROR([PAM library not found])],[])
854         AC_CHECK_HEADER([security/pam_appl.h],,[AC_MSG_ERROR([PAM header security/pam_appl.h not found!])])
855 fi
856
857 if test x$capabilities = xnative; then
858         AC_MSG_NOTICE([Usage of the native Linux capabilities interface is deprecated, use libcap instead])
859         # Linux requires the following for capset(), Android does not have it,
860         # but defines capset() in unistd.h instead.
861         AC_CHECK_HEADERS([sys/capability.h])
862         AC_CHECK_FUNC(capset,,[AC_MSG_ERROR([capset() not found!])])
863         AC_DEFINE([CAPABILITIES_NATIVE], [], [have native linux capset()])
864 fi
865
866 if test x$capabilities = xlibcap; then
867         AC_CHECK_LIB([cap],[main],[LIBS="$LIBS"],[AC_MSG_ERROR([libcap library not found])],[])
868         AC_CHECK_HEADER([sys/capability.h],
869                 [AC_DEFINE([HAVE_SYS_CAPABILITY_H], [], [have sys/capability.h])],
870                 [AC_MSG_ERROR([libcap header sys/capability.h not found!])])
871         AC_DEFINE([CAPABILITIES_LIBCAP], [], [have libpcap library])
872 fi
873
874 if test x$integrity_test = xtrue; then
875         AC_MSG_CHECKING([for dladdr()])
876         AC_COMPILE_IFELSE(
877                 [AC_LANG_PROGRAM(
878                         [[#define _GNU_SOURCE
879                           #include <dlfcn.h>]],
880                         [[Dl_info info; dladdr(main, &info);]])],
881                 [AC_MSG_RESULT([yes])],
882                 [AC_MSG_RESULT([no]);
883                  AC_MSG_ERROR([dladdr() not supported, required by integrity-test!])]
884         )
885         AC_MSG_CHECKING([for dl_iterate_phdr()])
886         AC_COMPILE_IFELSE(
887                 [AC_LANG_PROGRAM(
888                         [[#define _GNU_SOURCE
889                           #include <link.h>]],
890                         [[dl_iterate_phdr((void*)0, (void*)0);]])],
891                 [AC_MSG_RESULT([yes])],
892                 [AC_MSG_RESULT([no]);
893                  AC_MSG_ERROR([dl_iterate_phdr() not supported, required by integrity-test!])]
894         )
895 fi
896
897 if test x$bfd_backtraces = xtrue; then
898         AC_CHECK_LIB([bfd],[main],[LIBS="$LIBS"],[AC_MSG_ERROR([binutils libbfd not found!])],[])
899         AC_CHECK_HEADER([bfd.h],[AC_DEFINE([HAVE_BFD_H],,[have binutils bfd.h])],
900                 [AC_MSG_ERROR([binutils bfd.h header not found!])])
901         BFDLIB="-lbfd"
902         AC_SUBST(BFDLIB)
903 fi
904
905 if test x$unwind_backtraces = xtrue; then
906         AC_CHECK_LIB([unwind],[main],[LIBS="$LIBS"],[AC_MSG_ERROR([libunwind not found!])],[])
907         AC_CHECK_HEADER([libunwind.h],[AC_DEFINE([HAVE_LIBUNWIND_H],,[have libunwind.h])],
908                 [AC_MSG_ERROR([libunwind.h header not found!])])
909         UNWINDLIB="-lunwind"
910         AC_SUBST(UNWINDLIB)
911 fi
912
913 AM_CONDITIONAL(USE_DEV_HEADERS, [test "x$dev_headers" != xno])
914 if test x$dev_headers = xyes; then
915         dev_headers="$includedir/strongswan"
916 fi
917 AC_SUBST(dev_headers)
918
919 CFLAGS="$CFLAGS -include `pwd`/config.h"
920
921 if test x$tkm = xtrue; then
922         AC_PATH_PROG([GPRBUILD], [gprbuild], [], [$PATH:/bin:/usr/bin:/usr/local/bin])
923 fi
924
925 if test x$unit_tests = xtrue; then
926         PKG_CHECK_MODULES(CHECK, [check >= 0.9.4])
927         AC_SUBST(CHECK_CFLAGS)
928         AC_SUBST(CHECK_LIBS)
929 fi
930
931 if test x$coverage = xtrue; then
932         AC_PATH_PROG([LCOV], [lcov], [], [$PATH:/bin:/usr/bin:/usr/local/bin])
933         if test x$LCOV = x; then
934                 AC_MSG_ERROR([lcov not found])
935         fi
936         AC_PATH_PROG([GENHTML], [genhtml], [], [$PATH:/bin:/usr/bin:/usr/local/bin])
937         if test x$GENHTML = x; then
938                 AC_MSG_ERROR([genhtml not found])
939         fi
940
941         COVERAGE_CFLAGS="-fprofile-arcs -ftest-coverage"
942         COVERAGE_LDFLAGS="-fprofile-arcs"
943         AC_SUBST(COVERAGE_CFLAGS)
944         AC_SUBST(COVERAGE_LDFLAGS)
945
946         AC_MSG_NOTICE([coverage enabled, adding "-g -O0" to CFLAGS])
947         CFLAGS="${CFLAGS} -g -O0"
948 fi
949
950 # ===============================================
951 #  collect plugin list for strongSwan components
952 # ===============================================
953
954 m4_include(m4/macros/add-plugin.m4)
955
956 # plugin lists for all components
957 charon_plugins=
958 starter_plugins=
959 pool_plugins=
960 attest_plugins=
961 openac_plugins=
962 scepclient_plugins=
963 pki_plugins=
964 scripts_plugins=
965 manager_plugins=
966 medsrv_plugins=
967 nm_plugins=
968 cmd_plugins=
969
970 # location specific lists for checksumming,
971 # for src/libcharon, src/libhydra and src/libstrongswan
972 c_plugins=
973 h_plugins=
974 s_plugins=
975
976 ADD_PLUGIN([test-vectors],         [s charon openac scepclient pki])
977 ADD_PLUGIN([curl],                 [s charon scepclient scripts nm cmd])
978 ADD_PLUGIN([soup],                 [s charon scripts nm cmd])
979 ADD_PLUGIN([unbound],              [s charon scripts])
980 ADD_PLUGIN([ldap],                 [s charon scepclient scripts nm cmd])
981 ADD_PLUGIN([mysql],                [s charon pool manager medsrv attest])
982 ADD_PLUGIN([sqlite],               [s charon pool manager medsrv attest])
983 ADD_PLUGIN([pkcs11],               [s charon pki nm cmd])
984 ADD_PLUGIN([aes],                  [s charon openac scepclient pki scripts nm cmd])
985 ADD_PLUGIN([des],                  [s charon openac scepclient pki scripts nm cmd])
986 ADD_PLUGIN([blowfish],             [s charon openac scepclient pki scripts nm cmd])
987 ADD_PLUGIN([rc2],                  [s charon openac scepclient pki scripts nm cmd])
988 ADD_PLUGIN([sha1],                 [s charon openac scepclient pki scripts medsrv attest nm cmd])
989 ADD_PLUGIN([sha2],                 [s charon openac scepclient pki scripts medsrv attest nm cmd])
990 ADD_PLUGIN([md4],                  [s charon openac manager scepclient pki nm cmd])
991 ADD_PLUGIN([md5],                  [s charon openac scepclient pki scripts attest nm cmd])
992 ADD_PLUGIN([rdrand],               [s charon openac scepclient pki scripts medsrv attest nm cmd])
993 ADD_PLUGIN([random],               [s charon openac scepclient pki scripts medsrv attest nm cmd])
994 ADD_PLUGIN([nonce],                [s charon nm cmd])
995 ADD_PLUGIN([x509],                 [s charon openac scepclient pki scripts attest nm cmd])
996 ADD_PLUGIN([revocation],           [s charon nm cmd])
997 ADD_PLUGIN([constraints],          [s charon nm cmd])
998 ADD_PLUGIN([pubkey],               [s charon cmd])
999 ADD_PLUGIN([pkcs1],                [s charon openac scepclient pki scripts manager medsrv attest nm cmd])
1000 ADD_PLUGIN([pkcs7],                [s charon scepclient pki scripts nm cmd])
1001 ADD_PLUGIN([pkcs8],                [s charon openac scepclient pki scripts manager medsrv attest nm cmd])
1002 ADD_PLUGIN([pkcs12],               [s charon scepclient pki scripts cmd])
1003 ADD_PLUGIN([pgp],                  [s charon])
1004 ADD_PLUGIN([dnskey],               [s charon])
1005 ADD_PLUGIN([sshkey],               [s charon nm cmd])
1006 ADD_PLUGIN([ipseckey],             [c charon])
1007 ADD_PLUGIN([pem],                  [s charon openac scepclient pki scripts manager medsrv attest nm cmd])
1008 ADD_PLUGIN([padlock],              [s charon])
1009 ADD_PLUGIN([openssl],              [s charon openac scepclient pki scripts manager medsrv attest nm cmd])
1010 ADD_PLUGIN([gcrypt],               [s charon openac scepclient pki scripts manager medsrv attest nm cmd])
1011 ADD_PLUGIN([af-alg],               [s charon openac scepclient pki scripts medsrv attest nm cmd])
1012 ADD_PLUGIN([fips-prf],             [s charon nm cmd])
1013 ADD_PLUGIN([gmp],                  [s charon openac scepclient pki scripts manager medsrv attest nm cmd])
1014 ADD_PLUGIN([agent],                [s charon nm cmd])
1015 ADD_PLUGIN([xcbc],                 [s charon nm cmd])
1016 ADD_PLUGIN([cmac],                 [s charon nm cmd])
1017 ADD_PLUGIN([hmac],                 [s charon scripts nm cmd])
1018 ADD_PLUGIN([ctr],                  [s charon scripts nm cmd])
1019 ADD_PLUGIN([ccm],                  [s charon scripts nm cmd])
1020 ADD_PLUGIN([gcm],                  [s charon scripts nm cmd])
1021 ADD_PLUGIN([attr],                 [h charon])
1022 ADD_PLUGIN([attr-sql],             [h charon])
1023 ADD_PLUGIN([load-tester],          [c charon])
1024 ADD_PLUGIN([kernel-libipsec],      [c charon cmd])
1025 ADD_PLUGIN([kernel-pfkey],         [h charon starter nm cmd])
1026 ADD_PLUGIN([kernel-pfroute],       [h charon starter nm cmd])
1027 ADD_PLUGIN([kernel-klips],         [h charon starter])
1028 ADD_PLUGIN([kernel-netlink],       [h charon starter nm cmd])
1029 ADD_PLUGIN([resolve],              [h charon cmd])
1030 ADD_PLUGIN([socket-default],       [c charon nm cmd])
1031 ADD_PLUGIN([socket-dynamic],       [c charon cmd])
1032 ADD_PLUGIN([farp],                 [c charon])
1033 ADD_PLUGIN([stroke],               [c charon])
1034 ADD_PLUGIN([smp],                  [c charon])
1035 ADD_PLUGIN([sql],                  [c charon])
1036 ADD_PLUGIN([updown],               [c charon])
1037 ADD_PLUGIN([eap-identity],         [c charon nm cmd])
1038 ADD_PLUGIN([eap-sim],              [c charon])
1039 ADD_PLUGIN([eap-sim-file],         [c charon])
1040 ADD_PLUGIN([eap-sim-pcsc],         [c charon])
1041 ADD_PLUGIN([eap-aka],              [c charon])
1042 ADD_PLUGIN([eap-aka-3gpp2],        [c charon])
1043 ADD_PLUGIN([eap-simaka-sql],       [c charon])
1044 ADD_PLUGIN([eap-simaka-pseudonym], [c charon])
1045 ADD_PLUGIN([eap-simaka-reauth],    [c charon])
1046 ADD_PLUGIN([eap-md5],              [c charon nm cmd])
1047 ADD_PLUGIN([eap-gtc],              [c charon nm cmd])
1048 ADD_PLUGIN([eap-mschapv2],         [c charon nm cmd])
1049 ADD_PLUGIN([eap-dynamic],          [c charon])
1050 ADD_PLUGIN([eap-radius],           [c charon])
1051 ADD_PLUGIN([eap-tls],              [c charon nm cmd])
1052 ADD_PLUGIN([eap-ttls],             [c charon nm cmd])
1053 ADD_PLUGIN([eap-peap],             [c charon nm cmd])
1054 ADD_PLUGIN([eap-tnc],              [c charon])
1055 ADD_PLUGIN([xauth-generic],        [c charon cmd])
1056 ADD_PLUGIN([xauth-eap],            [c charon])
1057 ADD_PLUGIN([xauth-pam],            [c charon])
1058 ADD_PLUGIN([xauth-noauth],         [c charon])
1059 ADD_PLUGIN([tnc-ifmap],            [c charon])
1060 ADD_PLUGIN([tnc-pdp],              [c charon])
1061 ADD_PLUGIN([tnc-imc],              [c charon])
1062 ADD_PLUGIN([tnc-imv],              [c charon])
1063 ADD_PLUGIN([tnc-tnccs],            [c charon])
1064 ADD_PLUGIN([tnccs-20],             [c charon])
1065 ADD_PLUGIN([tnccs-11],             [c charon])
1066 ADD_PLUGIN([tnccs-dynamic],        [c charon])
1067 ADD_PLUGIN([medsrv],               [c charon])
1068 ADD_PLUGIN([medcli],               [c charon])
1069 ADD_PLUGIN([dhcp],                 [c charon])
1070 ADD_PLUGIN([osx-attr],             [c charon cmd])
1071 ADD_PLUGIN([android-dns],          [c charon])
1072 ADD_PLUGIN([android-log],          [c charon])
1073 ADD_PLUGIN([ha],                   [c charon])
1074 ADD_PLUGIN([whitelist],            [c charon])
1075 ADD_PLUGIN([lookip],               [c charon])
1076 ADD_PLUGIN([error-notify],         [c charon])
1077 ADD_PLUGIN([certexpire],           [c charon])
1078 ADD_PLUGIN([systime-fix],          [c charon])
1079 ADD_PLUGIN([led],                  [c charon])
1080 ADD_PLUGIN([duplicheck],           [c charon])
1081 ADD_PLUGIN([coupling],             [c charon])
1082 ADD_PLUGIN([radattr],              [c charon])
1083 ADD_PLUGIN([maemo],                [c charon])
1084 ADD_PLUGIN([uci],                  [c charon])
1085 ADD_PLUGIN([addrblock],            [c charon])
1086 ADD_PLUGIN([unity],                [c charon])
1087 ADD_PLUGIN([unit-tester],          [c charon])
1088
1089 AC_SUBST(charon_plugins)
1090 AC_SUBST(starter_plugins)
1091 AC_SUBST(pool_plugins)
1092 AC_SUBST(attest_plugins)
1093 AC_SUBST(openac_plugins)
1094 AC_SUBST(scepclient_plugins)
1095 AC_SUBST(pki_plugins)
1096 AC_SUBST(scripts_plugins)
1097 AC_SUBST(manager_plugins)
1098 AC_SUBST(medsrv_plugins)
1099 AC_SUBST(nm_plugins)
1100 AC_SUBST(cmd_plugins)
1101
1102 AC_SUBST(c_plugins)
1103 AC_SUBST(h_plugins)
1104 AC_SUBST(s_plugins)
1105
1106 # ======================
1107 #  set Makefile.am vars
1108 # ======================
1109
1110 #  libstrongswan plugins
1111 # -----------------------
1112 AM_CONDITIONAL(USE_TEST_VECTORS, test x$test_vectors = xtrue)
1113 AM_CONDITIONAL(USE_CURL, test x$curl = xtrue)
1114 AM_CONDITIONAL(USE_UNBOUND, test x$unbound = xtrue)
1115 AM_CONDITIONAL(USE_SOUP, test x$soup = xtrue)
1116 AM_CONDITIONAL(USE_LDAP, test x$ldap = xtrue)
1117 AM_CONDITIONAL(USE_AES, test x$aes = xtrue)
1118 AM_CONDITIONAL(USE_DES, test x$des = xtrue)
1119 AM_CONDITIONAL(USE_BLOWFISH, test x$blowfish = xtrue)
1120 AM_CONDITIONAL(USE_RC2, test x$rc2 = xtrue)
1121 AM_CONDITIONAL(USE_MD4, test x$md4 = xtrue)
1122 AM_CONDITIONAL(USE_MD5, test x$md5 = xtrue)
1123 AM_CONDITIONAL(USE_SHA1, test x$sha1 = xtrue)
1124 AM_CONDITIONAL(USE_SHA2, test x$sha2 = xtrue)
1125 AM_CONDITIONAL(USE_FIPS_PRF, test x$fips_prf = xtrue)
1126 AM_CONDITIONAL(USE_GMP, test x$gmp = xtrue)
1127 AM_CONDITIONAL(USE_RDRAND, test x$rdrand = xtrue)
1128 AM_CONDITIONAL(USE_RANDOM, test x$random = xtrue)
1129 AM_CONDITIONAL(USE_NONCE, test x$nonce = xtrue)
1130 AM_CONDITIONAL(USE_X509, test x$x509 = xtrue)
1131 AM_CONDITIONAL(USE_REVOCATION, test x$revocation = xtrue)
1132 AM_CONDITIONAL(USE_CONSTRAINTS, test x$constraints = xtrue)
1133 AM_CONDITIONAL(USE_PUBKEY, test x$pubkey = xtrue)
1134 AM_CONDITIONAL(USE_PKCS1, test x$pkcs1 = xtrue)
1135 AM_CONDITIONAL(USE_PKCS7, test x$pkcs7 = xtrue)
1136 AM_CONDITIONAL(USE_PKCS8, test x$pkcs8 = xtrue)
1137 AM_CONDITIONAL(USE_PKCS12, test x$pkcs12 = xtrue)
1138 AM_CONDITIONAL(USE_PGP, test x$pgp = xtrue)
1139 AM_CONDITIONAL(USE_DNSKEY, test x$dnskey = xtrue)
1140 AM_CONDITIONAL(USE_SSHKEY, test x$sshkey = xtrue)
1141 AM_CONDITIONAL(USE_PEM, test x$pem = xtrue)
1142 AM_CONDITIONAL(USE_HMAC, test x$hmac = xtrue)
1143 AM_CONDITIONAL(USE_CMAC, test x$cmac = xtrue)
1144 AM_CONDITIONAL(USE_XCBC, test x$xcbc = xtrue)
1145 AM_CONDITIONAL(USE_MYSQL, test x$mysql = xtrue)
1146 AM_CONDITIONAL(USE_SQLITE, test x$sqlite = xtrue)
1147 AM_CONDITIONAL(USE_PADLOCK, test x$padlock = xtrue)
1148 AM_CONDITIONAL(USE_OPENSSL, test x$openssl = xtrue)
1149 AM_CONDITIONAL(USE_GCRYPT, test x$gcrypt = xtrue)
1150 AM_CONDITIONAL(USE_AGENT, test x$agent = xtrue)
1151 AM_CONDITIONAL(USE_PKCS11, test x$pkcs11 = xtrue)
1152 AM_CONDITIONAL(USE_CTR, test x$ctr = xtrue)
1153 AM_CONDITIONAL(USE_CCM, test x$ccm = xtrue)
1154 AM_CONDITIONAL(USE_GCM, test x$gcm = xtrue)
1155 AM_CONDITIONAL(USE_AF_ALG, test x$af_alg = xtrue)
1156
1157 #  charon plugins
1158 # ----------------
1159 AM_CONDITIONAL(USE_STROKE, test x$stroke = xtrue)
1160 AM_CONDITIONAL(USE_MEDSRV, test x$medsrv = xtrue)
1161 AM_CONDITIONAL(USE_MEDCLI, test x$medcli = xtrue)
1162 AM_CONDITIONAL(USE_UCI, test x$uci = xtrue)
1163 AM_CONDITIONAL(USE_OSX_ATTR, test x$osx_attr = xtrue)
1164 AM_CONDITIONAL(USE_ANDROID_DNS, test x$android_dns = xtrue)
1165 AM_CONDITIONAL(USE_ANDROID_LOG, test x$android_log = xtrue)
1166 AM_CONDITIONAL(USE_MAEMO, test x$maemo = xtrue)
1167 AM_CONDITIONAL(USE_SMP, test x$smp = xtrue)
1168 AM_CONDITIONAL(USE_SQL, test x$sql = xtrue)
1169 AM_CONDITIONAL(USE_IPSECKEY, test x$ipseckey = xtrue)
1170 AM_CONDITIONAL(USE_UPDOWN, test x$updown = xtrue)
1171 AM_CONDITIONAL(USE_DHCP, test x$dhcp = xtrue)
1172 AM_CONDITIONAL(USE_UNIT_TESTS, test x$unit_tester = xtrue)
1173 AM_CONDITIONAL(USE_LOAD_TESTER, test x$load_tester = xtrue)
1174 AM_CONDITIONAL(USE_HA, test x$ha = xtrue)
1175 AM_CONDITIONAL(USE_KERNEL_LIBIPSEC, test x$kernel_libipsec = xtrue)
1176 AM_CONDITIONAL(USE_WHITELIST, test x$whitelist = xtrue)
1177 AM_CONDITIONAL(USE_LOOKIP, test x$lookip = xtrue)
1178 AM_CONDITIONAL(USE_ERROR_NOTIFY, test x$error_notify = xtrue)
1179 AM_CONDITIONAL(USE_CERTEXPIRE, test x$certexpire = xtrue)
1180 AM_CONDITIONAL(USE_SYSTIME_FIX, test x$systime_fix = xtrue)
1181 AM_CONDITIONAL(USE_LED, test x$led = xtrue)
1182 AM_CONDITIONAL(USE_DUPLICHECK, test x$duplicheck = xtrue)
1183 AM_CONDITIONAL(USE_COUPLING, test x$coupling = xtrue)
1184 AM_CONDITIONAL(USE_RADATTR, test x$radattr = xtrue)
1185 AM_CONDITIONAL(USE_EAP_SIM, test x$eap_sim = xtrue)
1186 AM_CONDITIONAL(USE_EAP_SIM_FILE, test x$eap_sim_file = xtrue)
1187 AM_CONDITIONAL(USE_EAP_SIM_PCSC, test x$eap_sim_pcsc = xtrue)
1188 AM_CONDITIONAL(USE_EAP_SIMAKA_SQL, test x$eap_simaka_sql = xtrue)
1189 AM_CONDITIONAL(USE_EAP_SIMAKA_PSEUDONYM, test x$eap_simaka_pseudonym = xtrue)
1190 AM_CONDITIONAL(USE_EAP_SIMAKA_REAUTH, test x$eap_simaka_reauth = xtrue)
1191 AM_CONDITIONAL(USE_EAP_IDENTITY, test x$eap_identity = xtrue)
1192 AM_CONDITIONAL(USE_EAP_MD5, test x$eap_md5 = xtrue)
1193 AM_CONDITIONAL(USE_EAP_GTC, test x$eap_gtc = xtrue)
1194 AM_CONDITIONAL(USE_EAP_AKA, test x$eap_aka = xtrue)
1195 AM_CONDITIONAL(USE_EAP_AKA_3GPP2, test x$eap_aka_3gpp2 = xtrue)
1196 AM_CONDITIONAL(USE_EAP_MSCHAPV2, test x$eap_mschapv2 = xtrue)
1197 AM_CONDITIONAL(USE_EAP_TLS, test x$eap_tls = xtrue)
1198 AM_CONDITIONAL(USE_EAP_TTLS, test x$eap_ttls = xtrue)
1199 AM_CONDITIONAL(USE_EAP_PEAP, test x$eap_peap = xtrue)
1200 AM_CONDITIONAL(USE_EAP_TNC, test x$eap_tnc = xtrue)
1201 AM_CONDITIONAL(USE_EAP_DYNAMIC, test x$eap_dynamic = xtrue)
1202 AM_CONDITIONAL(USE_EAP_RADIUS, test x$eap_radius = xtrue)
1203 AM_CONDITIONAL(USE_XAUTH_GENERIC, test x$xauth_generic = xtrue)
1204 AM_CONDITIONAL(USE_XAUTH_EAP, test x$xauth_eap = xtrue)
1205 AM_CONDITIONAL(USE_XAUTH_PAM, test x$xauth_pam = xtrue)
1206 AM_CONDITIONAL(USE_XAUTH_NOAUTH, test x$xauth_noauth = xtrue)
1207 AM_CONDITIONAL(USE_TNC_IFMAP, test x$tnc_ifmap = xtrue)
1208 AM_CONDITIONAL(USE_TNC_PDP, test x$tnc_pdp = xtrue)
1209 AM_CONDITIONAL(USE_TNC_IMC, test x$tnc_imc = xtrue)
1210 AM_CONDITIONAL(USE_TNC_IMV, test x$tnc_imv = xtrue)
1211 AM_CONDITIONAL(USE_TNC_TNCCS, test x$tnc_tnccs = xtrue)
1212 AM_CONDITIONAL(USE_TNCCS_11, test x$tnccs_11 = xtrue)
1213 AM_CONDITIONAL(USE_TNCCS_20, test x$tnccs_20 = xtrue)
1214 AM_CONDITIONAL(USE_TNCCS_DYNAMIC, test x$tnccs_dynamic = xtrue)
1215 AM_CONDITIONAL(USE_IMC_TEST, test x$imc_test = xtrue)
1216 AM_CONDITIONAL(USE_IMV_TEST, test x$imv_test = xtrue)
1217 AM_CONDITIONAL(USE_IMC_SCANNER, test x$imc_scanner = xtrue)
1218 AM_CONDITIONAL(USE_IMV_SCANNER, test x$imv_scanner = xtrue)
1219 AM_CONDITIONAL(USE_IMC_OS, test x$imc_os = xtrue)
1220 AM_CONDITIONAL(USE_IMV_OS, test x$imv_os = xtrue)
1221 AM_CONDITIONAL(USE_IMC_ATTESTATION, test x$imc_attestation = xtrue)
1222 AM_CONDITIONAL(USE_IMV_ATTESTATION, test x$imv_attestation = xtrue)
1223 AM_CONDITIONAL(USE_SOCKET_DEFAULT, test x$socket_default = xtrue)
1224 AM_CONDITIONAL(USE_SOCKET_DYNAMIC, test x$socket_dynamic = xtrue)
1225 AM_CONDITIONAL(USE_FARP, test x$farp = xtrue)
1226 AM_CONDITIONAL(USE_ADDRBLOCK, test x$addrblock = xtrue)
1227 AM_CONDITIONAL(USE_UNITY, test x$unity = xtrue)
1228
1229 #  hydra plugins
1230 # ---------------
1231 AM_CONDITIONAL(USE_ATTR, test x$attr = xtrue)
1232 AM_CONDITIONAL(USE_ATTR_SQL, test x$attr_sql = xtrue)
1233 AM_CONDITIONAL(USE_KERNEL_KLIPS, test x$kernel_klips = xtrue)
1234 AM_CONDITIONAL(USE_KERNEL_NETLINK, test x$kernel_netlink = xtrue)
1235 AM_CONDITIONAL(USE_KERNEL_PFKEY, test x$kernel_pfkey = xtrue)
1236 AM_CONDITIONAL(USE_KERNEL_PFROUTE, test x$kernel_pfroute = xtrue)
1237 AM_CONDITIONAL(USE_RESOLVE, test x$resolve = xtrue)
1238
1239 #  other options
1240 # ---------------
1241 AM_CONDITIONAL(USE_LEAK_DETECTIVE, test x$leak_detective = xtrue)
1242 AM_CONDITIONAL(USE_LOCK_PROFILER, test x$lock_profiler = xtrue)
1243 AM_CONDITIONAL(USE_DUMM, test x$dumm = xtrue)
1244 AM_CONDITIONAL(USE_FAST, test x$fast = xtrue)
1245 AM_CONDITIONAL(USE_MANAGER, test x$manager = xtrue)
1246 AM_CONDITIONAL(USE_ME, test x$mediation = xtrue)
1247 AM_CONDITIONAL(USE_INTEGRITY_TEST, test x$integrity_test = xtrue)
1248 AM_CONDITIONAL(USE_LOAD_WARNING, test x$load_warning = xtrue)
1249 AM_CONDITIONAL(USE_IKEV1, test x$ikev1 = xtrue)
1250 AM_CONDITIONAL(USE_IKEV2, test x$ikev2 = xtrue)
1251 AM_CONDITIONAL(USE_THREADS, test x$threads = xtrue)
1252 AM_CONDITIONAL(USE_ADNS, test x$adns = xtrue)
1253 AM_CONDITIONAL(USE_CHARON, test x$charon = xtrue)
1254 AM_CONDITIONAL(USE_NM, test x$nm = xtrue)
1255 AM_CONDITIONAL(USE_TOOLS, test x$tools = xtrue)
1256 AM_CONDITIONAL(USE_SCRIPTS, test x$scripts = xtrue)
1257 AM_CONDITIONAL(USE_CONFTEST, test x$conftest = xtrue)
1258 AM_CONDITIONAL(USE_LIBSTRONGSWAN, test x$charon = xtrue -o x$tools = xtrue -o x$conftest = xtrue -o x$fast = xtrue -o x$imcv = xtrue -o x$nm = xtrue -o x$tkm = xtrue -o x$cmd = xtrue)
1259 AM_CONDITIONAL(USE_LIBHYDRA, test x$charon = xtrue -o x$nm = xtrue -o x$tkm = xtrue -o x$cmd = xtrue)
1260 AM_CONDITIONAL(USE_LIBCHARON, test x$charon = xtrue -o x$conftest = xtrue -o x$nm = xtrue -o x$tkm = xtrue -o x$cmd = xtrue)
1261 AM_CONDITIONAL(USE_LIBIPSEC, test x$libipsec = xtrue)
1262 AM_CONDITIONAL(USE_LIBTNCIF, test x$tnc_tnccs = xtrue -o x$imcv = xtrue)
1263 AM_CONDITIONAL(USE_LIBTNCCS, test x$tnc_tnccs = xtrue)
1264 AM_CONDITIONAL(USE_LIBPTTLS, test x$tnc_tnccs = xtrue)
1265 AM_CONDITIONAL(USE_FILE_CONFIG, test x$stroke = xtrue)
1266 AM_CONDITIONAL(USE_IPSEC_SCRIPT, test x$stroke = xtrue -o x$tools = xtrue -o x$conftest = xtrue)
1267 AM_CONDITIONAL(USE_LIBCAP, test x$capabilities = xlibcap)
1268 AM_CONDITIONAL(USE_VSTR, test x$vstr = xtrue)
1269 AM_CONDITIONAL(USE_SIMAKA, test x$simaka = xtrue)
1270 AM_CONDITIONAL(USE_TLS, test x$tls = xtrue)
1271 AM_CONDITIONAL(USE_RADIUS, test x$radius = xtrue)
1272 AM_CONDITIONAL(USE_IMCV, test x$imcv = xtrue)
1273 AM_CONDITIONAL(USE_PTS, test x$pts = xtrue)
1274 AM_CONDITIONAL(USE_TROUSERS, test x$tss = xtrousers)
1275 AM_CONDITIONAL(MONOLITHIC, test x$monolithic = xtrue)
1276 AM_CONDITIONAL(USE_SILENT_RULES, test x$enable_silent_rules = xyes)
1277 AM_CONDITIONAL(UNITTESTS, test x$unit_tests = xtrue)
1278 AM_CONDITIONAL(COVERAGE, test x$coverage = xtrue)
1279 AM_CONDITIONAL(USE_TKM, test x$tkm = xtrue)
1280 AM_CONDITIONAL(USE_CMD, test x$cmd = xtrue)
1281
1282 # ========================
1283 #  set global definitions
1284 # ========================
1285
1286 if test x$mediation = xtrue; then
1287         AC_DEFINE([ME], [], [mediation extension support])
1288 fi
1289 if test x$capabilities = xlibcap -o x$capabilities = xnative; then
1290         AC_DEFINE([CAPABILITIES], [], [capability dropping support])
1291 fi
1292 if test x$monolithic = xtrue; then
1293         AC_DEFINE([MONOLITHIC], [], [monolithic build embedding plugins])
1294 fi
1295 if test x$ikev1 = xtrue; then
1296         AC_DEFINE([USE_IKEV1], [], [support for IKEv1 protocol])
1297 fi
1298 if test x$ikev2 = xtrue; then
1299         AC_DEFINE([USE_IKEV2], [], [support for IKEv2 protocol])
1300 fi
1301
1302 # =================
1303 #  build Makefiles
1304 # =================
1305
1306 AC_CONFIG_FILES([
1307         Makefile
1308         man/Makefile
1309         init/Makefile
1310         init/systemd/Makefile
1311         src/Makefile
1312         src/include/Makefile
1313         src/libstrongswan/Makefile
1314         src/libstrongswan/plugins/aes/Makefile
1315         src/libstrongswan/plugins/cmac/Makefile
1316         src/libstrongswan/plugins/des/Makefile
1317         src/libstrongswan/plugins/blowfish/Makefile
1318         src/libstrongswan/plugins/rc2/Makefile
1319         src/libstrongswan/plugins/md4/Makefile
1320         src/libstrongswan/plugins/md5/Makefile
1321         src/libstrongswan/plugins/sha1/Makefile
1322         src/libstrongswan/plugins/sha2/Makefile
1323         src/libstrongswan/plugins/fips_prf/Makefile
1324         src/libstrongswan/plugins/gmp/Makefile
1325         src/libstrongswan/plugins/rdrand/Makefile
1326         src/libstrongswan/plugins/random/Makefile
1327         src/libstrongswan/plugins/nonce/Makefile
1328         src/libstrongswan/plugins/hmac/Makefile
1329         src/libstrongswan/plugins/xcbc/Makefile
1330         src/libstrongswan/plugins/x509/Makefile
1331         src/libstrongswan/plugins/revocation/Makefile
1332         src/libstrongswan/plugins/constraints/Makefile
1333         src/libstrongswan/plugins/pubkey/Makefile
1334         src/libstrongswan/plugins/pkcs1/Makefile
1335         src/libstrongswan/plugins/pkcs7/Makefile
1336         src/libstrongswan/plugins/pkcs8/Makefile
1337         src/libstrongswan/plugins/pkcs12/Makefile
1338         src/libstrongswan/plugins/pgp/Makefile
1339         src/libstrongswan/plugins/dnskey/Makefile
1340         src/libstrongswan/plugins/sshkey/Makefile
1341         src/libstrongswan/plugins/pem/Makefile
1342         src/libstrongswan/plugins/curl/Makefile
1343         src/libstrongswan/plugins/unbound/Makefile
1344         src/libstrongswan/plugins/soup/Makefile
1345         src/libstrongswan/plugins/ldap/Makefile
1346         src/libstrongswan/plugins/mysql/Makefile
1347         src/libstrongswan/plugins/sqlite/Makefile
1348         src/libstrongswan/plugins/padlock/Makefile
1349         src/libstrongswan/plugins/openssl/Makefile
1350         src/libstrongswan/plugins/gcrypt/Makefile
1351         src/libstrongswan/plugins/agent/Makefile
1352         src/libstrongswan/plugins/pkcs11/Makefile
1353         src/libstrongswan/plugins/ctr/Makefile
1354         src/libstrongswan/plugins/ccm/Makefile
1355         src/libstrongswan/plugins/gcm/Makefile
1356         src/libstrongswan/plugins/af_alg/Makefile
1357         src/libstrongswan/plugins/test_vectors/Makefile
1358         src/libstrongswan/tests/Makefile
1359         src/libhydra/Makefile
1360         src/libhydra/plugins/attr/Makefile
1361         src/libhydra/plugins/attr_sql/Makefile
1362         src/libhydra/plugins/kernel_klips/Makefile
1363         src/libhydra/plugins/kernel_netlink/Makefile
1364         src/libhydra/plugins/kernel_pfkey/Makefile
1365         src/libhydra/plugins/kernel_pfroute/Makefile
1366         src/libhydra/plugins/resolve/Makefile
1367         src/libipsec/Makefile
1368         src/libsimaka/Makefile
1369         src/libtls/Makefile
1370         src/libradius/Makefile
1371         src/libtncif/Makefile
1372         src/libtnccs/Makefile
1373         src/libpttls/Makefile
1374         src/libpts/Makefile
1375         src/libpts/plugins/imc_attestation/Makefile
1376         src/libpts/plugins/imv_attestation/Makefile
1377         src/libimcv/Makefile
1378         src/libimcv/plugins/imc_test/Makefile
1379         src/libimcv/plugins/imv_test/Makefile
1380         src/libimcv/plugins/imc_scanner/Makefile
1381         src/libimcv/plugins/imv_scanner/Makefile
1382         src/libimcv/plugins/imc_os/Makefile
1383         src/libimcv/plugins/imv_os/Makefile
1384         src/charon/Makefile
1385         src/charon-nm/Makefile
1386         src/charon-tkm/Makefile
1387         src/charon-cmd/Makefile
1388         src/libcharon/Makefile
1389         src/libcharon/plugins/eap_aka/Makefile
1390         src/libcharon/plugins/eap_aka_3gpp2/Makefile
1391         src/libcharon/plugins/eap_dynamic/Makefile
1392         src/libcharon/plugins/eap_identity/Makefile
1393         src/libcharon/plugins/eap_md5/Makefile
1394         src/libcharon/plugins/eap_gtc/Makefile
1395         src/libcharon/plugins/eap_sim/Makefile
1396         src/libcharon/plugins/eap_sim_file/Makefile
1397         src/libcharon/plugins/eap_sim_pcsc/Makefile
1398         src/libcharon/plugins/eap_simaka_sql/Makefile
1399         src/libcharon/plugins/eap_simaka_pseudonym/Makefile
1400         src/libcharon/plugins/eap_simaka_reauth/Makefile
1401         src/libcharon/plugins/eap_mschapv2/Makefile
1402         src/libcharon/plugins/eap_tls/Makefile
1403         src/libcharon/plugins/eap_ttls/Makefile
1404         src/libcharon/plugins/eap_peap/Makefile
1405         src/libcharon/plugins/eap_tnc/Makefile
1406         src/libcharon/plugins/eap_radius/Makefile
1407         src/libcharon/plugins/xauth_generic/Makefile
1408         src/libcharon/plugins/xauth_eap/Makefile
1409         src/libcharon/plugins/xauth_pam/Makefile
1410         src/libcharon/plugins/xauth_noauth/Makefile
1411         src/libcharon/plugins/tnc_ifmap/Makefile
1412         src/libcharon/plugins/tnc_pdp/Makefile
1413         src/libcharon/plugins/tnc_imc/Makefile
1414         src/libcharon/plugins/tnc_imv/Makefile
1415         src/libcharon/plugins/tnc_tnccs/Makefile
1416         src/libcharon/plugins/tnccs_11/Makefile
1417         src/libcharon/plugins/tnccs_20/Makefile
1418         src/libcharon/plugins/tnccs_dynamic/Makefile
1419         src/libcharon/plugins/socket_default/Makefile
1420         src/libcharon/plugins/socket_dynamic/Makefile
1421         src/libcharon/plugins/farp/Makefile
1422         src/libcharon/plugins/smp/Makefile
1423         src/libcharon/plugins/sql/Makefile
1424         src/libcharon/plugins/ipseckey/Makefile
1425         src/libcharon/plugins/medsrv/Makefile
1426         src/libcharon/plugins/medcli/Makefile
1427         src/libcharon/plugins/addrblock/Makefile
1428         src/libcharon/plugins/unity/Makefile
1429         src/libcharon/plugins/uci/Makefile
1430         src/libcharon/plugins/ha/Makefile
1431         src/libcharon/plugins/kernel_libipsec/Makefile
1432         src/libcharon/plugins/whitelist/Makefile
1433         src/libcharon/plugins/lookip/Makefile
1434         src/libcharon/plugins/error_notify/Makefile
1435         src/libcharon/plugins/certexpire/Makefile
1436         src/libcharon/plugins/systime_fix/Makefile
1437         src/libcharon/plugins/led/Makefile
1438         src/libcharon/plugins/duplicheck/Makefile
1439         src/libcharon/plugins/coupling/Makefile
1440         src/libcharon/plugins/radattr/Makefile
1441         src/libcharon/plugins/osx_attr/Makefile
1442         src/libcharon/plugins/android_dns/Makefile
1443         src/libcharon/plugins/android_log/Makefile
1444         src/libcharon/plugins/maemo/Makefile
1445         src/libcharon/plugins/stroke/Makefile
1446         src/libcharon/plugins/updown/Makefile
1447         src/libcharon/plugins/dhcp/Makefile
1448         src/libcharon/plugins/unit_tester/Makefile
1449         src/libcharon/plugins/load_tester/Makefile
1450         src/stroke/Makefile
1451         src/ipsec/Makefile
1452         src/starter/Makefile
1453         src/_updown/Makefile
1454         src/_updown_espmark/Makefile
1455         src/_copyright/Makefile
1456         src/openac/Makefile
1457         src/scepclient/Makefile
1458         src/pki/Makefile
1459         src/dumm/Makefile
1460         src/dumm/ext/extconf.rb
1461         src/libfast/Makefile
1462         src/manager/Makefile
1463         src/medsrv/Makefile
1464         src/checksum/Makefile
1465         src/conftest/Makefile
1466         scripts/Makefile
1467         testing/Makefile
1468 ])
1469 AC_OUTPUT
1470
1471 # ========================
1472 #  report enabled plugins
1473 # ========================
1474
1475 AC_MSG_RESULT([])
1476 AC_MSG_RESULT([ strongSwan will be built with the following plugins])
1477 AC_MSG_RESULT([-----------------------------------------------------])
1478
1479 AC_MSG_RESULT([libstrongswan:$s_plugins])
1480 AC_MSG_RESULT([libcharon:    $c_plugins])
1481 AC_MSG_RESULT([libhydra:     $h_plugins])
1482 AC_MSG_RESULT([])