bypass-lan: Add plugin that installs bypass policies for locally attached subnets
[strongswan.git] / configure.ac
1 #
2 # Copyright (C) 2007-2015 Tobias Brunner
3 # Copyright (C) 2006-2016 Andreas Steffen
4 # Copyright (C) 2006-2014 Martin Willi
5 # HSR Hochschule fuer Technik Rapperswil
6 #
7 # This program is free software; you can redistribute it and/or modify it
8 # under the terms of the GNU General Public License as published by the
9 # Free Software Foundation; either version 2 of the License, or (at your
10 # option) any later version.  See <http://www.fsf.org/copyleft/gpl.txt>.
11 #
12 # This program is distributed in the hope that it will be useful, but
13 # WITHOUT ANY WARRANTY; without even the implied warranty of MERCHANTABILITY
14 # or FITNESS FOR A PARTICULAR PURPOSE.  See the GNU General Public License
15 # for more details.
16 #
17
18 # ============================
19 #  initialize & set some vars
20 # ============================
21
22 AC_INIT([strongSwan],[5.5.2dr4])
23 AM_INIT_AUTOMAKE(m4_esyscmd([
24         echo tar-ustar
25         echo subdir-objects
26         case `automake --version | head -n 1` in
27                 *" 1.9"*);;
28                 *" 1.10"*);;
29                 *" 1.11"*);;
30                 # don't use parallel test harness in 1.12 and up
31                 *) echo serial-tests;;
32         esac
33 ]))
34 m4_ifdef([AM_SILENT_RULES], [AM_SILENT_RULES])
35 AC_CONFIG_MACRO_DIR([m4/config])
36 AC_CONFIG_HEADERS([config.h])
37 AC_DEFINE([CONFIG_H_INCLUDED], [], [defined if config.h included])
38 PKG_PROG_PKG_CONFIG
39
40 m4_include(m4/macros/split-package-version.m4)
41 SPLIT_PACKAGE_VERSION
42
43 # =================================
44 #  check --enable-xxx & --with-xxx
45 # =================================
46
47 m4_include(m4/macros/with.m4)
48
49 ARG_WITH_SUBST([random-device],      [/dev/random], [set the device to read real random data from])
50 ARG_WITH_SUBST([urandom-device],     [/dev/urandom], [set the device to read pseudo random data from])
51 ARG_WITH_SUBST([strongswan-conf],    [${sysconfdir}/strongswan.conf], [set the strongswan.conf file location])
52 ARG_WITH_SUBST([resolv-conf],        [${sysconfdir}/resolv.conf], [set the file to use in DNS handler plugin])
53 ARG_WITH_SUBST([piddir],             [/var/run], [set path for PID and UNIX socket files])
54 ARG_WITH_SUBST([ipsecdir],           [${libexecdir%/}/ipsec], [set installation path for ipsec tools])
55 ARG_WITH_SUBST([ipseclibdir],        [${libdir%/}/ipsec], [set installation path for ipsec libraries])
56 ARG_WITH_SUBST([plugindir],          [${ipseclibdir%/}/plugins], [set the installation path of plugins])
57 ARG_WITH_SUBST([imcvdir],            [${ipseclibdir%/}/imcvs], [set the installation path of IMC and IMV dynamic librariers])
58 ARG_WITH_SUBST([nm-ca-dir],          [/usr/share/ca-certificates], [directory the NM backend uses to look up trusted root certificates])
59 ARG_WITH_SUBST([swanctldir],         [${sysconfdir}/swanctl], [base directory for swanctl configuration files and credentials])
60 ARG_WITH_SUBST([linux-headers],      [\${top_srcdir}/src/include], [set directory of linux header files to use])
61 ARG_WITH_SUBST([routing-table],      [220], [set routing table to use for IPsec routes])
62 ARG_WITH_SUBST([routing-table-prio], [220], [set priority for IPsec routing table])
63 ARG_WITH_SUBST([ipsec-script],       [ipsec], [change the name of the ipsec script])
64 ARG_WITH_SUBST([fips-mode],          [0], [set openssl FIPS mode: disabled(0), enabled(1), Suite B enabled(2)])
65 ARG_WITH_SET([capabilities],         [no], [set capability dropping library. Currently supported values are "libcap" and "native"])
66 ARG_WITH_SET([mpz_powm_sec],         [yes], [use the more side-channel resistant mpz_powm_sec in libgmp, if available])
67 ARG_WITH_SET([dev-headers],          [no], [install strongSwan development headers to directory.])
68 ARG_WITH_SET([printf-hooks],         [auto], [force the use of a specific printf hook implementation (auto, builtin, glibc, vstr).])
69 ARG_WITH_SET([rubygemdir],           ["gem environment gemdir"], [path to install ruby gems to])
70 ARG_WITH_SET([pythoneggdir],         ["main site-packages directory"], [path to install python eggs to to])
71
72 if test -n "$PKG_CONFIG"; then
73         systemdsystemunitdir_default=$($PKG_CONFIG --variable=systemdsystemunitdir systemd)
74 fi
75 ARG_WITH_SET([systemdsystemunitdir], [$systemdsystemunitdir_default], [directory for systemd service files])
76 AC_SUBST(systemdsystemunitdir)
77
78 AC_ARG_WITH(
79         [user],
80         AS_HELP_STRING([--with-user=user],[change user of the daemons to "user" after startup (default is "root").]),
81         [AC_DEFINE_UNQUOTED([IPSEC_USER], "$withval", [username to run daemon with])
82          AC_SUBST(ipsecuser, "$withval")],
83         [AC_SUBST(ipsecuser, "root")]
84 )
85
86 AC_ARG_WITH(
87         [group],
88         AS_HELP_STRING([--with-group=group],[change group of the daemons to "group" after startup (default is "root").]),
89         [AC_DEFINE_UNQUOTED(IPSEC_GROUP, "$withval", [groupname to run daemon with])
90          AC_SUBST(ipsecgroup, "$withval")],
91         [AC_SUBST(ipsecgroup, "root")]
92 )
93
94 AC_ARG_WITH(
95         [charon-udp-port],
96         AS_HELP_STRING([--with-charon-udp-port=port],[UDP port used by charon locally (default 500). Set to 0 to allocate randomly.]),
97         [AC_DEFINE_UNQUOTED(CHARON_UDP_PORT, [$withval], [UDP port used by charon locally])
98          AC_SUBST(charon_udp_port, [$withval])],
99         [AC_SUBST(charon_udp_port, 500)]
100 )
101
102 AC_ARG_WITH(
103         [charon-natt-port],
104         AS_HELP_STRING([--with-charon-natt-port=port],[UDP port used by charon locally in case a NAT is detected (must be different from charon-udp-port, default 4500). Set to 0 to allocate randomly.]),
105         [AC_DEFINE_UNQUOTED(CHARON_NATT_PORT, [$withval], [UDP post used by charon locally in case a NAT is detected])
106          AC_SUBST(charon_natt_port, [$withval])],
107         [AC_SUBST(charon_natt_port, 4500)]
108 )
109
110 AC_MSG_CHECKING([configured UDP ports ($charon_udp_port, $charon_natt_port)])
111 if test x$charon_udp_port != x0 -a x$charon_udp_port = x$charon_natt_port; then
112         AC_MSG_ERROR(the ports have to be different)
113 else
114         AC_MSG_RESULT(ok)
115 fi
116
117 # convert script name to uppercase
118 AC_SUBST(ipsec_script_upper, [`echo -n "$ipsec_script" | tr a-z A-Z`])
119
120 m4_include(m4/macros/enable-disable.m4)
121
122 # crypto plugins
123 ARG_DISBL_SET([aes],            [disable AES software implementation plugin.])
124 ARG_ENABL_SET([af-alg],         [enable AF_ALG crypto interface to Linux Crypto API.])
125 ARG_ENABL_SET([bliss],          [enable BLISS software implementation plugin.])
126 ARG_ENABL_SET([blowfish],       [enable Blowfish software implementation plugin.])
127 ARG_ENABL_SET([ccm],            [enables the CCM AEAD wrapper crypto plugin.])
128 ARG_ENABL_SET([chapoly],        [enables the ChaCha20/Poly1305 AEAD plugin.])
129 ARG_DISBL_SET([cmac],           [disable CMAC crypto implementation plugin.])
130 ARG_ENABL_SET([ctr],            [enables the Counter Mode wrapper crypto plugin.])
131 ARG_DISBL_SET([des],            [disable DES/3DES software implementation plugin.])
132 ARG_DISBL_SET([fips-prf],       [disable FIPS PRF software implementation plugin.])
133 ARG_ENABL_SET([gcm],            [enables the GCM AEAD wrapper crypto plugin.])
134 ARG_ENABL_SET([gcrypt],         [enables the libgcrypt plugin.])
135 ARG_DISBL_SET([gmp],            [disable GNU MP (libgmp) based crypto implementation plugin.])
136 ARG_DISBL_SET([curve25519],     [disable Curve25519 Diffie-Hellman plugin.])
137 ARG_DISBL_SET([hmac],           [disable HMAC crypto implementation plugin.])
138 ARG_ENABL_SET([md4],            [enable MD4 software implementation plugin.])
139 ARG_DISBL_SET([md5],            [disable MD5 software implementation plugin.])
140 ARG_ENABL_SET([mgf1],           [enable the MGF1 software implementation plugin.])
141 ARG_ENABL_SET([newhope],        [enable New Hope crypto plugin.])
142 ARG_DISBL_SET([nonce],          [disable nonce generation plugin.])
143 ARG_ENABL_SET([ntru],           [enables the NTRU crypto plugin.])
144 ARG_ENABL_SET([openssl],        [enables the OpenSSL crypto plugin.])
145 ARG_ENABL_SET([padlock],        [enables VIA Padlock crypto plugin.])
146 ARG_DISBL_SET([random],         [disable RNG implementation on top of /dev/(u)random.])
147 ARG_DISBL_SET([rc2],            [disable RC2 software implementation plugin.])
148 ARG_ENABL_SET([rdrand],         [enable Intel RDRAND random generator plugin.])
149 ARG_ENABL_SET([aesni],          [enable Intel AES-NI crypto plugin.])
150 ARG_DISBL_SET([sha1],           [disable SHA1 software implementation plugin.])
151 ARG_DISBL_SET([sha2],           [disable SHA256/SHA384/SHA512 software implementation plugin.])
152 ARG_ENABL_SET([sha3],           [enable SHA3_224/SHA3_256/SHA3_384/SHA3_512 software implementation plugin.])
153 ARG_DISBL_SET([xcbc],           [disable xcbc crypto implementation plugin.])
154 # encoding/decoding plugins
155 ARG_DISBL_SET([dnskey],         [disable DNS RR key decoding plugin.])
156 ARG_DISBL_SET([pem],            [disable PEM decoding plugin.])
157 ARG_DISBL_SET([pgp],            [disable PGP key decoding plugin.])
158 ARG_DISBL_SET([pkcs1],          [disable PKCS1 key decoding plugin.])
159 ARG_DISBL_SET([pkcs7],          [disable PKCS7 container support plugin.])
160 ARG_DISBL_SET([pkcs8],          [disable PKCS8 private key decoding plugin.])
161 ARG_DISBL_SET([pkcs12],         [disable PKCS12 container support plugin.])
162 ARG_DISBL_SET([pubkey],         [disable RAW public key support plugin.])
163 ARG_DISBL_SET([sshkey],         [disable SSH key decoding plugin.])
164 ARG_DISBL_SET([x509],           [disable X509 certificate implementation plugin.])
165 # fetcher/resolver plugins
166 ARG_ENABL_SET([curl],           [enable CURL fetcher plugin to fetch files via libcurl. Requires libcurl.])
167 ARG_ENABL_SET([files],          [enable simple file:// URI fetcher.])
168 ARG_ENABL_SET([ldap],           [enable LDAP fetching plugin to fetch files via libldap. Requires openLDAP.])
169 ARG_ENABL_SET([soup],           [enable soup fetcher plugin to fetch from HTTP via libsoup. Requires libsoup.])
170 ARG_ENABL_SET([unbound],        [enable UNBOUND resolver plugin to perform DNS queries via libunbound. Requires libldns and libunbound.])
171 ARG_ENABL_SET([winhttp],        [enable WinHTTP based HTTP/HTTPS fetching plugin.])
172 # database plugins
173 ARG_ENABL_SET([mysql],          [enable MySQL database support. Requires libmysqlclient_r.])
174 ARG_ENABL_SET([sqlite],         [enable SQLite database support. Requires libsqlite3.])
175 # authentication/credential plugins
176 ARG_ENABL_SET([addrblock],      [enables RFC 3779 address block constraint support.])
177 ARG_ENABL_SET([acert],          [enable X509 attribute certificate checking plugin.])
178 ARG_ENABL_SET([agent],          [enables the ssh-agent signing plugin.])
179 ARG_DISBL_SET([constraints],    [disable advanced X509 constraint checking plugin.])
180 ARG_ENABL_SET([coupling],       [enable IKEv2 plugin to couple peer certificates permanently to authentication.])
181 ARG_ENABL_SET([dnscert],        [enable DNSCERT authentication plugin.])
182 ARG_ENABL_SET([eap-sim],        [enable SIM authentication module for EAP.])
183 ARG_ENABL_SET([eap-sim-file],   [enable EAP-SIM backend based on a triplet file.])
184 ARG_ENABL_SET([eap-sim-pcsc],   [enable EAP-SIM backend based on a smartcard reader. Requires libpcsclite.])
185 ARG_ENABL_SET([eap-aka],        [enable EAP AKA authentication module.])
186 ARG_ENABL_SET([eap-aka-3gpp2],  [enable EAP AKA backend implementing 3GPP2 algorithms in software. Requires libgmp.])
187 ARG_ENABL_SET([eap-simaka-sql], [enable EAP-SIM/AKA backend based on a triplet/quintuplet SQL database.])
188 ARG_ENABL_SET([eap-simaka-pseudonym], [enable EAP-SIM/AKA pseudonym storage plugin.])
189 ARG_ENABL_SET([eap-simaka-reauth],    [enable EAP-SIM/AKA reauthentication data storage plugin.])
190 ARG_ENABL_SET([eap-identity],   [enable EAP module providing EAP-Identity helper.])
191 ARG_ENABL_SET([eap-md5],        [enable EAP MD5 (CHAP) authentication module.])
192 ARG_ENABL_SET([eap-gtc],        [enable EAP GTC authentication module.])
193 ARG_ENABL_SET([eap-mschapv2],   [enable EAP MS-CHAPv2 authentication module.])
194 ARG_ENABL_SET([eap-tls],        [enable EAP TLS authentication module.])
195 ARG_ENABL_SET([eap-ttls],       [enable EAP TTLS authentication module.])
196 ARG_ENABL_SET([eap-peap],       [enable EAP PEAP authentication module.])
197 ARG_ENABL_SET([eap-tnc],        [enable EAP TNC trusted network connect module.])
198 ARG_ENABL_SET([eap-dynamic],    [enable dynamic EAP proxy module.])
199 ARG_ENABL_SET([eap-radius],     [enable RADIUS proxy authentication module.])
200 ARG_ENABL_SET([ext-auth],       [enable plugin calling an external authorization script.])
201 ARG_ENABL_SET([ipseckey],       [enable IPSECKEY authentication plugin.])
202 ARG_ENABL_SET([keychain],       [enables OS X Keychain Services credential set.])
203 ARG_ENABL_SET([pkcs11],         [enables the PKCS11 token support plugin.])
204 ARG_DISBL_SET([revocation],     [disable X509 CRL/OCSP revocation check plugin.])
205 ARG_ENABL_SET([whitelist],      [enable peer identity whitelisting plugin.])
206 ARG_DISBL_SET([xauth-generic],  [disable generic XAuth backend.])
207 ARG_ENABL_SET([xauth-eap],      [enable XAuth backend using EAP methods to verify passwords.])
208 ARG_ENABL_SET([xauth-pam],      [enable XAuth backend using PAM to verify passwords.])
209 ARG_ENABL_SET([xauth-noauth],   [enable XAuth pseudo-backend that does not actually verify or even request any credentials.])
210 # kernel interfaces / sockets
211 ARG_DISBL_SET([kernel-netlink], [disable the netlink kernel interface.])
212 ARG_ENABL_SET([kernel-pfkey],   [enable the PF_KEY kernel interface.])
213 ARG_ENABL_SET([kernel-pfroute], [enable the PF_ROUTE kernel interface.])
214 ARG_ENABL_SET([kernel-iph],     [enable the Windows IP Helper based networking backend.])
215 ARG_ENABL_SET([kernel-libipsec],[enable the libipsec kernel interface.])
216 ARG_ENABL_SET([kernel-wfp],     [enable the Windows Filtering Platform IPsec backend.])
217 ARG_DISBL_SET([socket-default], [disable default socket implementation for charon.])
218 ARG_ENABL_SET([socket-dynamic], [enable dynamic socket implementation for charon])
219 ARG_ENABL_SET([socket-win],     [enable Winsock2 based socket implementation for charon])
220 # configuration/control plugins
221 ARG_DISBL_SET([stroke],         [disable charons stroke configuration backend.])
222 ARG_ENABL_SET([smp],            [enable SMP configuration and control interface. Requires libxml.])
223 ARG_ENABL_SET([sql],            [enable SQL database configuration backend.])
224 ARG_ENABL_SET([uci],            [enable OpenWRT UCI configuration plugin.])
225 ARG_DISBL_SET([vici],           [disable strongSwan IKE generic IPC interface plugin.])
226 # attribute provider/consumer plugins
227 ARG_ENABL_SET([android-dns],    [enable Android specific DNS handler.])
228 ARG_DISBL_SET([attr],           [disable strongswan.conf based configuration attribute plugin.])
229 ARG_ENABL_SET([attr-sql],       [enable SQL based configuration attribute plugin.])
230 ARG_ENABL_SET([dhcp],           [enable DHCP based attribute provider plugin.])
231 ARG_ENABL_SET([osx-attr],       [enable OS X SystemConfiguration attribute handler.])
232 ARG_ENABL_SET([p-cscf],         [enable plugin to request P-CSCF server addresses from an ePDG.])
233 ARG_DISBL_SET([resolve],        [disable resolve DNS handler plugin.])
234 ARG_ENABL_SET([unity],          [enables Cisco Unity extension plugin.])
235 # TNC modules/plugins
236 ARG_ENABL_SET([imc-test],       [enable IMC test module.])
237 ARG_ENABL_SET([imv-test],       [enable IMV test module.])
238 ARG_ENABL_SET([imc-scanner],    [enable IMC port scanner module.])
239 ARG_ENABL_SET([imv-scanner],    [enable IMV port scanner module.])
240 ARG_ENABL_SET([imc-os],         [enable IMC operating system module.])
241 ARG_ENABL_SET([imv-os],         [enable IMV operating system module.])
242 ARG_ENABL_SET([imc-attestation],[enable IMC attestation module.])
243 ARG_ENABL_SET([imv-attestation],[enable IMV attestation module.])
244 ARG_ENABL_SET([imc-swid],       [enable IMC swid module.])
245 ARG_ENABL_SET([imv-swid],       [enable IMV swid module.])
246 ARG_ENABL_SET([imc-hcd],        [enable IMC hcd module.])
247 ARG_ENABL_SET([imv-hcd],        [enable IMV hcd module.])
248 ARG_ENABL_SET([tnc-ifmap],      [enable TNC IF-MAP module. Requires libxml])
249 ARG_ENABL_SET([tnc-imc],        [enable TNC IMC module.])
250 ARG_ENABL_SET([tnc-imv],        [enable TNC IMV module.])
251 ARG_ENABL_SET([tnc-pdp],        [enable TNC policy decision point module.])
252 ARG_ENABL_SET([tnccs-11],       [enable TNCCS 1.1 protocol module. Requires libxml])
253 ARG_ENABL_SET([tnccs-20],       [enable TNCCS 2.0 protocol module.])
254 ARG_ENABL_SET([tnccs-dynamic],  [enable dynamic TNCCS protocol discovery module.])
255 # misc plugins
256 ARG_ENABL_SET([android-log],    [enable Android specific logger plugin.])
257 ARG_ENABL_SET([bypass-lan],     [enable plugin to install bypass policies for local subnets.])
258 ARG_ENABL_SET([certexpire],     [enable CSV export of expiration dates of used certificates.])
259 ARG_ENABL_SET([connmark],       [enable connmark plugin using conntrack based marks to select return path SA.])
260 ARG_ENABL_SET([forecast],       [enable forecast plugin forwarding broadcast/multicast messages.])
261 ARG_ENABL_SET([duplicheck],     [advanced duplicate checking plugin using liveness checks.])
262 ARG_ENABL_SET([error-notify],   [enable error notification plugin.])
263 ARG_ENABL_SET([farp],           [enable ARP faking plugin that responds to ARP requests to peers virtual IP])
264 ARG_ENABL_SET([ha],             [enable high availability cluster plugin.])
265 ARG_ENABL_SET([led],            [enable plugin to control LEDs on IKEv2 activity using the Linux kernel LED subsystem.])
266 ARG_ENABL_SET([load-tester],    [enable load testing plugin for IKEv2 daemon.])
267 ARG_ENABL_SET([lookip],         [enable fast virtual IP lookup and notification plugin.])
268 ARG_ENABL_SET([radattr],        [enable plugin to inject and process custom RADIUS attributes as IKEv2 client.])
269 ARG_ENABL_SET([systime-fix],    [enable plugin to handle cert lifetimes with invalid system time gracefully.])
270 ARG_ENABL_SET([test-vectors],   [enable plugin providing crypto test vectors.])
271 ARG_DISBL_SET([updown],         [disable updown firewall script plugin.])
272 # programs/components
273 ARG_ENABL_SET([aikgen],         [enable AIK generator for TPM 1.2.])
274 ARG_ENABL_SET([aikpub2],        [enable AIK extractor for TPM 2.0.])
275 ARG_DISBL_SET([charon],         [disable the IKEv1/IKEv2 keying daemon charon.])
276 ARG_ENABL_SET([cmd],            [enable the command line IKE client charon-cmd.])
277 ARG_ENABL_SET([conftest],       [enforce Suite B conformance test framework.])
278 ARG_ENABL_SET([dumm],           [enable the DUMM UML test framework.])
279 ARG_ENABL_SET([fast],           [enable libfast (FastCGI Application Server w/ templates.])
280 ARG_ENABL_SET([libipsec],       [enable user space IPsec implementation.])
281 ARG_ENABL_SET([manager],        [enable web management console (proof of concept).])
282 ARG_ENABL_SET([medcli],         [enable mediation client configuration database plugin.])
283 ARG_ENABL_SET([medsrv],         [enable mediation server web frontend and daemon plugin.])
284 ARG_ENABL_SET([nm],             [enable NetworkManager backend.])
285 ARG_DISBL_SET([pki],            [disable pki certificate utility.])
286 ARG_DISBL_SET([scepclient],     [disable SCEP client tool.])
287 ARG_DISBL_SET([scripts],        [disable additional utilities (found in directory scripts).])
288 ARG_ENABL_SET([svc],            [enable charon Windows service.])
289 ARG_ENABL_SET([systemd],        [enable systemd specific IKE daemon charon-systemd.])
290 ARG_DISBL_SET([swanctl],        [disable swanctl configuration and control tool.])
291 ARG_ENABL_SET([tkm],            [enable Trusted Key Manager support.])
292 # optional features
293 ARG_ENABL_SET([bfd-backtraces], [use binutils libbfd to resolve backtraces for memory leaks and segfaults.])
294 ARG_ENABL_SET([dbghelp-backtraces],[use dbghlp.dll on Windows to create and print backtraces for memory leaks and segfaults.])
295 ARG_DISBL_SET([ikev1],          [disable IKEv1 protocol support in charon.])
296 ARG_DISBL_SET([ikev2],          [disable IKEv2 protocol support in charon.])
297 ARG_ENABL_SET([integrity-test], [enable integrity testing of libstrongswan and plugins.])
298 ARG_DISBL_SET([load-warning],   [disable the charon plugin load option warning in starter.])
299 ARG_ENABL_SET([mediation],      [enable IKEv2 Mediation Extension.])
300 ARG_ENABL_SET([unwind-backtraces],[use libunwind to create backtraces for memory leaks and segfaults.])
301 ARG_ENABL_SET([ruby-gems],      [enable build of provided ruby gems.])
302 ARG_ENABL_SET([ruby-gems-install],[enable installation of provided ruby gems.])
303 ARG_ENABL_SET([python-eggs],    [enable build of provided python eggs.])
304 ARG_ENABL_SET([python-eggs-install],[enable installation of provided python eggs.])
305 ARG_ENABL_SET([perl-cpan],      [enable build of provided perl CPAN module.])
306 ARG_ENABL_SET([perl-cpan-install],[enable installation of provided CPAN module.])
307 ARG_ENABL_SET([tss-trousers],   [enable the use of the TrouSerS Trusted Software Stack])
308 ARG_ENABL_SET([tss-tss2],       [enable the use of the TSS 2.0 Trusted Software Stack])
309
310 # compile options
311 ARG_ENABL_SET([coverage],       [enable lcov coverage report generation.])
312 ARG_ENABL_SET([leak-detective], [enable malloc hooks to find memory leaks.])
313 ARG_ENABL_SET([lock-profiler],  [enable lock/mutex profiling code.])
314 ARG_ENABL_SET([log-thread-ids], [use thread ID, if available, instead of an incremented value starting from 1, to identify threads.])
315 ARG_ENABL_SET([monolithic],     [build monolithic version of libstrongswan that includes all enabled plugins. Similarly, the plugins of charon are assembled in libcharon.])
316
317 # ===================================
318 #  option to disable default options
319 # ===================================
320
321 ARG_DISBL_SET([defaults],       [disable all default plugins (they can be enabled with their respective --enable options)])
322
323 if test x$defaults = xfalse; then
324         for option in $enabled_by_default; do
325                 eval test x\${${option}_given} = xtrue && continue
326                 eval $option=false
327         done
328 fi
329
330 # ==============================
331 #  option to enable all options
332 # ==============================
333
334 ARG_ENABL_SET([all],            [enable all plugins and features (they can be disabled with their respective --disable options). Mainly for testing.])
335
336 if test x$all_given = xtrue; then
337         for option in $disabled_by_default; do
338                 eval test x\${${option}_given} = xtrue && continue
339                 eval $option=true
340         done
341 fi
342
343 # ===========================
344 #  set up compiler and flags
345 # ===========================
346
347 if test -z "$CFLAGS"; then
348         CFLAGS="-g -O2 -Wall -Wno-format -Wno-format-security -Wno-pointer-sign"
349 fi
350 AC_PROG_CC
351 AM_PROG_CC_C_O
352
353 AC_LIB_PREFIX
354 AC_C_BIGENDIAN
355
356 # =========================
357 #  check required programs
358 # =========================
359
360 LT_INIT
361 AC_PROG_INSTALL
362 AC_PROG_EGREP
363 AC_PROG_AWK
364 AC_PROG_LEX
365 AC_PROG_YACC
366 AM_PATH_PYTHON(,,[:])
367 AC_PATH_PROG([PERL], [perl], [], [$PATH:/bin:/usr/bin:/usr/local/bin])
368 AC_PATH_PROG([GPERF], [gperf], [], [$PATH:/bin:/usr/bin:/usr/local/bin])
369
370 # because gperf is not needed by end-users we just report it but do not abort on failure
371 AC_MSG_CHECKING([gperf version >= 3.0.0])
372 if test -x "$GPERF"; then
373         if test "`$GPERF --version | $AWK -F' ' '/^GNU gperf/ { print $3 }' | $AWK -F. '{ print $1 }'`" -ge "3"; then
374                 AC_MSG_RESULT([yes])
375         else
376                 AC_MSG_RESULT([no])
377         fi
378 else
379         AC_MSG_RESULT([not found])
380 fi
381
382 # ========================
383 #  dependency calculation
384 # ========================
385
386 if test x$xauth_generic_given = xfalse -a x$ikev1 = xfalse; then
387         xauth_generic=false;
388 fi
389
390 if test x$kernel_libipsec = xtrue; then
391         libipsec=true;
392 fi
393
394 if test x$eap_aka_3gpp2 = xtrue; then
395         gmp=true;
396 fi
397
398 if test x$eap_aka = xtrue; then
399         fips_prf=true;
400         simaka=true;
401 fi
402
403 if test x$eap_sim = xtrue; then
404         fips_prf=true;
405         simaka=true;
406 fi
407
408 if test x$eap_radius = xtrue -o x$radattr = xtrue -o x$tnc_pdp = xtrue; then
409         radius=true;
410 fi
411
412 if test x$tnc_imc = xtrue -o x$tnc_imv = xtrue -o x$tnccs_11 = xtrue -o x$tnccs_11 = xtrue -o x$tnccs_dynamic = xtrue -o x$eap_tnc = xtrue; then
413         tnc_tnccs=true;
414 fi
415
416 if test x$eap_tls = xtrue -o x$eap_ttls = xtrue -o x$eap_peap = xtrue -o x$tnc_tnccs = xtrue; then
417         tls=true;
418 fi
419
420 if test x$imc_test = xtrue -o x$imv_test = xtrue -o x$imc_scanner = xtrue -o x$imv_scanner = xtrue -o x$imc_os = xtrue -o x$imv_os = xtrue -o x$imc_attestation = xtrue -o x$imv_attestation = xtrue -o x$imc_swid = xtrue -o x$imv_swid = xtrue -o x$imc_hcd = xtrue -o x$imv_hcd = xtrue; then
421         imcv=true;
422 fi
423
424 if test x$fips_prf = xtrue; then
425         if test x$openssl = xfalse; then
426                 sha1=true;
427         fi
428 fi
429
430 if test x$swanctl = xtrue; then
431         vici=true
432 fi
433
434 if test x$smp = xtrue -o x$tnccs_11 = xtrue -o x$tnc_ifmap = xtrue; then
435         xml=true
436 fi
437
438 if test x$manager = xtrue; then
439         fast=true
440 fi
441
442 if test x$medsrv = xtrue; then
443         mediation=true
444         fast=true
445 fi
446
447 if test x$medcli = xtrue; then
448         mediation=true
449 fi
450
451 if test x$ruby_gems_install = xtrue; then
452         ruby_gems=true
453 fi
454
455 if test x$python_eggs_install = xtrue; then
456         python_eggs=true
457 fi
458
459 if test x$perl_cpan_install = xtrue; then
460         perl_cpan=true
461 fi
462
463 if test x$aikgen = xtrue; then
464         tss_trousers=true
465 fi
466
467 if test x$aikpub2 = xtrue; then
468         tss_tss2=true
469 fi
470
471 if test x$ntru = xtrue -o x$bliss = xtrue; then
472         mgf1=true
473 fi
474
475 # ===========================================
476 #  check required libraries and header files
477 # ===========================================
478
479 AC_HEADER_STDBOOL
480 AC_FUNC_ALLOCA
481 AC_FUNC_STRERROR_R
482
483 #  libraries needed on some platforms but not on others
484 # ------------------------------------------------------
485 saved_LIBS=$LIBS
486
487 # FreeBSD and Mac OS X have dlopen integrated in libc, Linux needs libdl
488 LIBS=""
489 AC_SEARCH_LIBS(dlopen, dl, [DLLIB=$LIBS])
490 AC_SUBST(DLLIB)
491
492 # glibc's backtrace() can be replicated on FreeBSD with libexecinfo
493 LIBS=""
494 AC_SEARCH_LIBS(backtrace, execinfo, [BTLIB=$LIBS])
495 AC_CHECK_FUNCS(backtrace)
496 AC_SUBST(BTLIB)
497
498 # OpenSolaris needs libsocket and libnsl for socket()
499 LIBS=""
500 AC_SEARCH_LIBS(socket, socket, [SOCKLIB=$LIBS],
501         [AC_CHECK_LIB(nsl, socket, [SOCKLIB="-lsocket -lnsl"], [], [-lsocket])]
502 )
503 AC_SUBST(SOCKLIB)
504
505 # Android has pthread_* functions in bionic (libc), others need libpthread
506 LIBS=$DLLIB
507 AC_SEARCH_LIBS(pthread_create, pthread, [PTHREADLIB=$LIBS])
508 AC_SUBST(PTHREADLIB)
509
510 # Some architectures require explicit -latomic for __atomic_* operations
511 # AC_SEARCH_LIBS() does not work when checking built-ins due to conflicting types
512 LIBS=""
513 AC_MSG_CHECKING(for library containing __atomic_and_fetch)
514 AC_LINK_IFELSE(
515         [AC_LANG_PROGRAM([[]], [[int x; __atomic_and_fetch(&x, 1, __ATOMIC_RELAXED);]])],
516         [AC_MSG_RESULT([none required])],
517         [LIBS="-latomic";
518          AC_LINK_IFELSE(
519                 [AC_LANG_PROGRAM([[]], [[int x; __atomic_and_fetch(&x, 1, __ATOMIC_RELAXED);]])],
520                 [AC_MSG_RESULT([-latomic]); ATOMICLIB=$LIBS],
521                 [AC_MSG_RESULT([no])])
522         ]
523 )
524 AC_SUBST(ATOMICLIB)
525
526 LIBS=$saved_LIBS
527 # ------------------------------------------------------
528
529 AC_MSG_CHECKING(for dladdr)
530 AC_COMPILE_IFELSE(
531         [AC_LANG_PROGRAM(
532                 [[#define _GNU_SOURCE
533                   #include <dlfcn.h>]],
534                 [[Dl_info* info = 0;
535                   dladdr(0, info);]])],
536         [AC_MSG_RESULT([yes]); AC_DEFINE([HAVE_DLADDR], [], [have dladdr()])],
537         [AC_MSG_RESULT([no])]
538 )
539
540 # check if pthread_condattr_setclock(CLOCK_MONOTONIC) is supported
541 saved_LIBS=$LIBS
542 LIBS=$PTHREADLIB
543 AC_MSG_CHECKING([for pthread_condattr_setclock(CLOCK_MONOTONIC)])
544 AC_RUN_IFELSE(
545         [AC_LANG_SOURCE(
546                 [[#include <pthread.h>
547                   int main() { pthread_condattr_t attr;
548                         pthread_condattr_init(&attr);
549                         return pthread_condattr_setclock(&attr, CLOCK_MONOTONIC);}]])],
550         [AC_MSG_RESULT([yes]);
551          AC_DEFINE([HAVE_CONDATTR_CLOCK_MONOTONIC], [],
552                            [pthread_condattr_setclock supports CLOCK_MONOTONIC])],
553         [AC_MSG_RESULT([no])],
554         # Check existence of pthread_condattr_setclock if cross-compiling
555         [AC_MSG_RESULT([unknown]);
556          AC_CHECK_FUNCS(pthread_condattr_setclock,
557                 [AC_DEFINE([HAVE_CONDATTR_CLOCK_MONOTONIC], [],
558                                    [have pthread_condattr_setclock()])]
559         )]
560 )
561 # check if we actually are able to configure attributes on cond vars
562 AC_CHECK_FUNCS(pthread_condattr_init)
563 # instead of pthread_condattr_setclock Android has this function
564 AC_CHECK_FUNCS(pthread_cond_timedwait_monotonic)
565 # check if we can cancel threads
566 AC_CHECK_FUNCS(pthread_cancel)
567 # check if native rwlocks are available
568 AC_CHECK_FUNCS(pthread_rwlock_init)
569 # check if pthread spinlocks are available
570 AC_CHECK_FUNCS(pthread_spin_init)
571 # check if we have POSIX semaphore functions, including timed-wait
572 AC_CHECK_FUNCS(sem_timedwait)
573 LIBS=$saved_LIBS
574
575 AC_CHECK_FUNC(
576         [gettid],
577         [AC_DEFINE([HAVE_GETTID], [], [have gettid()])],
578         [AC_MSG_CHECKING([for SYS_gettid])
579          AC_COMPILE_IFELSE(
580                 [AC_LANG_PROGRAM(
581                         [[#define _GNU_SOURCE
582                           #include <unistd.h>
583                           #include <sys/syscall.h>]],
584                         [[int main() {
585                           return syscall(SYS_gettid);}]])],
586                 [AC_MSG_RESULT([yes]);
587                  AC_DEFINE([HAVE_GETTID], [], [have gettid()])
588                  AC_DEFINE([HAVE_SYS_GETTID], [], [have syscall(SYS_gettid)])],
589                 [AC_MSG_RESULT([no])]
590         )]
591 )
592
593 AC_CHECK_FUNC(
594         [qsort_r],
595         [
596                 AC_DEFINE([HAVE_QSORT_R], [], [have qsort_r()])
597                 # set -Werror so that we get an error for "argument ... has
598                 # incompatible pointer type" warnings
599                 save_CFLAGS="$CFLAGS"
600                 CFLAGS="$CFLAGS -Werror -Wno-unused-parameter"
601                 AC_MSG_CHECKING([for GNU-style qsort_r])
602                 AC_COMPILE_IFELSE(
603                         [AC_LANG_PROGRAM(
604                                 [[#define _GNU_SOURCE
605                                   #include <stdlib.h>
606                                   int cmp (const void *a, const void *b, void *x) { return 0; }]],
607                                 [[int arr[] = { 0, 1 };
608                                   qsort_r(arr, 2, sizeof(int), cmp, arr);]])],
609                 [AC_MSG_RESULT([yes]);
610                  AC_DEFINE([HAVE_QSORT_R_GNU], [], [have GNU-style qsort_r()])],
611                 [
612                         AC_MSG_RESULT([no]);
613                         AC_MSG_CHECKING([for BSD-style qsort_r])
614                         AC_COMPILE_IFELSE(
615                                 [AC_LANG_PROGRAM(
616                                         [[#include <stdlib.h>
617                                           int cmp (void *x, const void *a, const void *b) { return 0; }]],
618                                         [[int arr[] = { 0, 1 };
619                                           qsort_r(arr, 2, sizeof(int), arr, cmp);]])],
620                         [AC_MSG_RESULT([yes]);
621                          AC_DEFINE([HAVE_QSORT_R_BSD], [], [have BSD-style qsort_r()])],
622                         [AC_MSG_RESULT([no]);
623                          AC_MSG_FAILURE([qsort_r has unknown semantics])])
624                 ])
625                 CFLAGS="$save_CFLAGS"
626         ]
627 )
628
629 AC_CHECK_FUNCS(prctl mallinfo getpass closefrom getpwnam_r getgrnam_r getpwuid_r)
630 AC_CHECK_FUNCS(fmemopen funopen mmap memrchr setlinebuf strptime dirfd sigwaitinfo)
631
632 AC_CHECK_FUNC([syslog], [
633         AC_DEFINE([HAVE_SYSLOG], [], [have syslog(3) and friends])
634         syslog=true
635 ])
636 AM_CONDITIONAL(USE_SYSLOG, [test "x$syslog" = xtrue])
637
638 AC_CHECK_HEADERS(sys/sockio.h sys/syscall.h sys/param.h glob.h net/if_tun.h)
639 AC_CHECK_HEADERS(net/pfkeyv2.h netipsec/ipsec.h netinet6/ipsec.h linux/udp.h)
640 AC_CHECK_HEADERS([netinet/ip6.h linux/fib_rules.h], [], [],
641 [
642         #include <sys/types.h>
643         #include <netinet/in.h>
644 ])
645
646 AC_CHECK_MEMBERS([struct sockaddr.sa_len], [], [],
647 [
648         #include <sys/types.h>
649         #include <sys/socket.h>
650 ])
651
652 AC_CHECK_MEMBERS([struct sadb_x_policy.sadb_x_policy_priority], [], [],
653 [
654         #include <sys/types.h>
655         #ifdef HAVE_NET_PFKEYV2_H
656         #include <net/pfkeyv2.h>
657         #else
658         #include <stdint.h>
659         #include <linux/pfkeyv2.h>
660         #endif
661 ])
662
663 AC_MSG_CHECKING([for in6addr_any])
664 AC_COMPILE_IFELSE(
665         [AC_LANG_PROGRAM(
666                 [[#include <sys/types.h>
667                   #include <sys/socket.h>
668                   #include <netinet/in.h>]],
669                 [[struct in6_addr in6 __attribute__((unused));
670                   in6 = in6addr_any;]])],
671         [AC_MSG_RESULT([yes]);
672          AC_DEFINE([HAVE_IN6ADDR_ANY], [], [have struct in6_addr in6addr_any])],
673         [AC_MSG_RESULT([no])]
674 )
675
676 AC_MSG_CHECKING([for in6_pktinfo])
677 AC_COMPILE_IFELSE(
678         [AC_LANG_PROGRAM(
679                 [[#define _GNU_SOURCE
680                   #include <sys/types.h>
681                   #include <sys/socket.h>
682                   #include <netinet/in.h>]],
683                 [[struct in6_pktinfo pi;
684                   if (pi.ipi6_ifindex)
685                   {
686                     return 0;
687                   }]])],
688         [AC_MSG_RESULT([yes]);
689          AC_DEFINE([HAVE_IN6_PKTINFO], [], [have struct in6_pktinfo.ipi6_ifindex])],
690         [AC_MSG_RESULT([no])]
691 )
692
693 AC_MSG_CHECKING([for RTM_IFANNOUNCE])
694 AC_COMPILE_IFELSE(
695         [AC_LANG_PROGRAM(
696                 [[#include <sys/socket.h>
697                   #include <net/if.h>
698                   #include <net/route.h>]],
699                 [[return RTM_IFANNOUNCE;]])],
700         [AC_MSG_RESULT([yes]);
701          AC_DEFINE([HAVE_RTM_IFANNOUNCE], [], [have PF_ROUTE RTM_IFANNOUNCE defined])],
702         [AC_MSG_RESULT([no])]
703 )
704
705 AC_MSG_CHECKING([for IPSEC_MODE_BEET])
706 AC_COMPILE_IFELSE(
707         [AC_LANG_PROGRAM(
708                 [[#include <sys/types.h>
709                   #ifdef HAVE_NETIPSEC_IPSEC_H
710                   #include <netipsec/ipsec.h>
711                   #elif defined(HAVE_NETINET6_IPSEC_H)
712                   #include <netinet6/ipsec.h>
713                   #else
714                   #include <stdint.h>
715                   #include <linux/ipsec.h>
716                   #endif]],
717                 [[int mode = IPSEC_MODE_BEET;
718                   return mode;]])],
719         [AC_MSG_RESULT([yes]);
720          AC_DEFINE([HAVE_IPSEC_MODE_BEET], [], [have IPSEC_MODE_BEET defined])],
721         [AC_MSG_RESULT([no])]
722 )
723
724 AC_MSG_CHECKING([for IPSEC_DIR_FWD])
725 AC_COMPILE_IFELSE(
726         [AC_LANG_PROGRAM(
727                 [[#include <sys/types.h>
728                   #ifdef HAVE_NETIPSEC_IPSEC_H
729                   #include <netipsec/ipsec.h>
730                   #elif defined(HAVE_NETINET6_IPSEC_H)
731                   #include <netinet6/ipsec.h>
732                   #else
733                   #include <stdint.h>
734                   #include <linux/ipsec.h>
735                   #endif]],
736                 [[int dir = IPSEC_DIR_FWD;
737                   return dir;]])],
738         [AC_MSG_RESULT([yes]);
739          AC_DEFINE([HAVE_IPSEC_DIR_FWD], [], [have IPSEC_DIR_FWD defined])],
740         [AC_MSG_RESULT([no])]
741 )
742
743 AC_MSG_CHECKING([for RTA_TABLE])
744 AC_COMPILE_IFELSE(
745         [AC_LANG_PROGRAM(
746                 [[#include <sys/socket.h>
747                   #include <linux/netlink.h>
748                   #include <linux/rtnetlink.h>]],
749                 [[int rta_type = RTA_TABLE;
750                   return rta_type;]])],
751         [AC_MSG_RESULT([yes]);
752          AC_DEFINE([HAVE_RTA_TABLE], [], [have netlink RTA_TABLE defined])],
753         [AC_MSG_RESULT([no])]
754 )
755
756 AC_MSG_CHECKING([for __int128])
757 AC_COMPILE_IFELSE(
758         [AC_LANG_PROGRAM(
759                 [[#include <sys/types.h>]],
760                 [[__int128 x = 0;
761                   return x;]])],
762         [AC_MSG_RESULT([yes]);
763          AC_DEFINE([HAVE_INT128], [], [have __int128 type support])],
764         [AC_MSG_RESULT([no])]
765 )
766
767 AC_MSG_CHECKING([for GCC __sync operations])
768 AC_RUN_IFELSE([AC_LANG_SOURCE(
769         [[
770                         int main() {
771                         int ref = 1;
772                         __sync_fetch_and_add (&ref, 1);
773                         __sync_sub_and_fetch (&ref, 1);
774                         __sync_val_compare_and_swap(&ref, 1, 0);
775                         return ref;
776                 }
777         ]])],
778         [AC_MSG_RESULT([yes]);
779          AC_DEFINE([HAVE_GCC_SYNC_OPERATIONS], [],
780                    [have GCC __sync_* operations])],
781         [AC_MSG_RESULT([no])],
782         [AC_MSG_RESULT([no])]
783 )
784
785 case "$printf_hooks" in
786 auto|builtin|glibc|vstr)
787         ;;
788 *)
789         AC_MSG_NOTICE([invalid printf hook implementation, defaulting to 'auto'])
790         printf_hooks=auto
791         ;;
792 esac
793
794 if test x$printf_hooks = xauto -o x$printf_hooks = xglibc; then
795         # check for the new register_printf_specifier function with len argument,
796         # or the deprecated register_printf_function without
797         AC_CHECK_FUNC(
798                 [register_printf_specifier],
799                 [AC_DEFINE([HAVE_PRINTF_SPECIFIER], [], [have register_printf_specifier()])],
800                 [AC_CHECK_FUNC(
801                         [register_printf_function],
802                         [AC_DEFINE([HAVE_PRINTF_FUNCTION], [], [have register_printf_function()])],
803                         [
804                                 AC_MSG_NOTICE([printf(3) does not support custom format specifiers!])
805                                 if test x$printf_hooks = xglibc; then
806                                         AC_MSG_ERROR([please select a different printf hook implementation])
807                                 else
808                                         # fallback to builtin printf hook implementation
809                                         printf_hooks=builtin
810                                 fi
811                         ]
812                 )]
813         )
814 fi
815
816 AC_MSG_CHECKING([for Windows target])
817 AC_COMPILE_IFELSE(
818         [AC_LANG_PROGRAM(
819                 [[#include <windows.h>]],
820                 [[#ifndef WIN32
821                   # error WIN32 undefined
822                   #endif
823                 ]])],
824         [
825                 AC_MSG_RESULT([yes])
826                 windows=true
827                 openssl_lib=eay32
828                 AC_SUBST(PTHREADLIB, "")
829                 # explicitly disable ms-bitfields, as it breaks __attribute__((packed))
830                 case "$CFLAGS" in
831                         *ms-bitfields*) ;;
832                         *) CFLAGS="$CFLAGS -mno-ms-bitfields" ;;
833                 esac
834         ],
835         [
836                 AC_MSG_RESULT([no])
837                 openssl_lib=crypto
838
839                 # check for clock_gettime() on non-Windows only. Otherwise this
840                 # check might find clock_gettime() in libwinpthread, but we don't want
841                 # to link against it.
842                 saved_LIBS=$LIBS
843                 # FreeBSD has clock_gettime in libc, Linux needs librt
844                 LIBS=""
845                 AC_SEARCH_LIBS(clock_gettime, rt, [RTLIB=$LIBS])
846                 AC_CHECK_FUNCS(clock_gettime)
847                 AC_SUBST(RTLIB)
848                 LIBS=$saved_LIBS
849         ]
850 )
851 AC_SUBST(OPENSSL_LIB, [-l$openssl_lib])
852 AM_CONDITIONAL(USE_WINDOWS, [test "x$windows" = xtrue])
853
854 AC_MSG_CHECKING([for working __attribute__((packed))])
855 AC_COMPILE_IFELSE(
856         [AC_LANG_PROGRAM([], [[
857                 struct test { char a; short b; } __attribute__((packed));
858                 char x[sizeof(struct test) == sizeof(char) + sizeof(short) ? 1 : -1]
859                         __attribute__((unused));
860                 return 0;
861         ]])],
862         [AC_MSG_RESULT([yes])],
863         [AC_MSG_RESULT([no]); AC_MSG_ERROR([__attribute__((packed)) does not work])]
864 )
865
866 AC_MSG_CHECKING([clang])
867 AC_COMPILE_IFELSE(
868         [AC_LANG_PROGRAM(
869                 [], [[
870                  #ifndef __clang__
871                  # error not using LLVM clang
872                  #endif
873                 ]])],
874         [
875                 AC_MSG_RESULT([yes])
876         ],
877         [
878                 AC_MSG_RESULT([no])
879                 # GCC, but not MinGW requires -rdynamic for plugins
880                 if test x$windows != xtrue; then
881                         AC_SUBST(PLUGIN_CFLAGS, [-rdynamic])
882                 fi
883         ]
884 )
885
886 AC_MSG_CHECKING([x86/x64 target])
887 AC_COMPILE_IFELSE(
888         [AC_LANG_PROGRAM(
889                 [], [[
890                  #if !defined(__i386__) && !defined(__x86_64__)
891                  # error not on x86/x64
892                  #endif
893                 ]])],
894         [
895                 x86x64=true
896                 AC_MSG_RESULT([yes])
897         ],
898         [AC_MSG_RESULT([no])]
899 )
900 AM_CONDITIONAL(USE_X86X64, [test "x$x86x64" = xtrue])
901
902 if test x$printf_hooks = xvstr; then
903         AC_CHECK_LIB([vstr],[vstr_init],[LIBS="$LIBS"],[AC_MSG_ERROR([Vstr string library not found])],[])
904         AC_DEFINE([USE_VSTR], [], [use Vstr string library for printf hooks])
905 fi
906
907 if test x$printf_hooks = xbuiltin; then
908         AC_DEFINE([USE_BUILTIN_PRINTF], [], [using builtin printf for printf hooks])
909 fi
910
911 if test x$gmp = xtrue; then
912         saved_LIBS=$LIBS
913         AC_CHECK_LIB([gmp],[__gmpz_init],[],[AC_MSG_ERROR([GNU Multi Precision library gmp not found])],[])
914         AC_MSG_CHECKING([mpz_powm_sec])
915         if test x$mpz_powm_sec = xyes; then
916                 AC_COMPILE_IFELSE(
917                         [AC_LANG_PROGRAM(
918                                 [[#include "gmp.h"]],
919                                 [[void *x = mpz_powm_sec;]])],
920                         [AC_MSG_RESULT([yes]);
921                          AC_DEFINE([HAVE_MPZ_POWM_SEC], [], [have mpz_mown_sec()])],
922                         [AC_MSG_RESULT([no])]
923                 )
924         else
925                 AC_MSG_RESULT([disabled])
926         fi
927         LIBS=$saved_LIBS
928         AC_MSG_CHECKING([gmp.h version >= 4.1.4])
929         AC_COMPILE_IFELSE(
930                 [AC_LANG_PROGRAM(
931                         [[#include "gmp.h"]],
932                         [[
933                                 #if (__GNU_MP_VERSION*100 +  __GNU_MP_VERSION_MINOR*10 + __GNU_MP_VERSION_PATCHLEVEL) < 414
934                                         #error bad gmp
935                                 #endif]])],
936                 [AC_MSG_RESULT([yes])],
937                 [AC_MSG_RESULT([no]); AC_MSG_ERROR([No usable gmp.h found!])]
938         )
939 fi
940
941 if test x$ldap = xtrue; then
942         AC_CHECK_LIB([ldap],[ldap_init],[LIBS="$LIBS"],[AC_MSG_ERROR([LDAP library ldap not found])],[])
943         AC_CHECK_LIB([lber],[ber_free],[LIBS="$LIBS"],[AC_MSG_ERROR([LDAP library lber not found])],[])
944         AC_CHECK_HEADER([ldap.h],,[AC_MSG_ERROR([LDAP header ldap.h not found!])])
945 fi
946
947 if test x$curl = xtrue; then
948         AC_CHECK_LIB([curl],[curl_global_init],[LIBS="$LIBS"],[AC_MSG_ERROR([CURL library curl not found])],[])
949         AC_CHECK_HEADER([curl/curl.h],,[AC_MSG_ERROR([CURL header curl/curl.h not found!])])
950 fi
951
952 if test x$unbound = xtrue; then
953         AC_CHECK_LIB([ldns],[ldns_rr_get_type],[LIBS="$LIBS"],[AC_MSG_ERROR([UNBOUND library ldns not found])],[])
954         AC_CHECK_HEADER([ldns/ldns.h],,[AC_MSG_ERROR([UNBOUND header ldns/ldns.h not found!])])
955         AC_CHECK_LIB([unbound],[ub_ctx_create],[LIBS="$LIBS"],[AC_MSG_ERROR([UNBOUND library libunbound not found])],[])
956         AC_CHECK_HEADER([unbound.h],,[AC_MSG_ERROR([UNBOUND header unbound.h not found!])])
957 fi
958
959 if test x$soup = xtrue; then
960         PKG_CHECK_MODULES(soup, [libsoup-2.4])
961         AC_SUBST(soup_CFLAGS)
962         AC_SUBST(soup_LIBS)
963 fi
964
965 if test x$xml = xtrue; then
966         PKG_CHECK_MODULES(xml, [libxml-2.0])
967         AC_SUBST(xml_CFLAGS)
968         AC_SUBST(xml_LIBS)
969 fi
970
971 if test x$systemd = xtrue; then
972         AC_MSG_CHECKING([for systemd system unit directory])
973         if test -n "$systemdsystemunitdir" -a "x$systemdsystemunitdir" != xno; then
974                 AC_MSG_RESULT([$systemdsystemunitdir])
975         else
976                 AC_MSG_ERROR([not found (try --with-systemdsystemunitdir)])
977         fi
978
979         PKG_CHECK_MODULES(systemd, [libsystemd >= 209],
980                 [AC_SUBST(systemd_CFLAGS)
981                  AC_SUBST(systemd_LIBS)],
982                 [PKG_CHECK_MODULES(systemd_daemon, [libsystemd-daemon])
983                  AC_SUBST(systemd_daemon_CFLAGS)
984                  AC_SUBST(systemd_daemon_LIBS)
985                  PKG_CHECK_MODULES(systemd_journal, [libsystemd-journal])
986                  AC_SUBST(systemd_journal_CFLAGS)
987                  AC_SUBST(systemd_journal_LIBS)]
988         )
989 fi
990
991 if test x$tss_trousers = xtrue; then
992         AC_CHECK_LIB([tspi],[Tspi_Context_Create],[LIBS="$LIBS"],[AC_MSG_ERROR([TrouSerS library libtspi not found])],[])
993         AC_CHECK_HEADER([trousers/tss.h],,[AC_MSG_ERROR([TrouSerS header trousers/tss.h not found!])])
994         AC_DEFINE([TSS_TROUSERS], [], [use TrouSerS library libtspi])
995 fi
996
997 if test x$tss_tss2 = xtrue; then
998         PKG_CHECK_MODULES(tss2, [tcti-socket], [AC_DEFINE([TSS_TSS2], [], [use TSS 2.0 libraries])])
999         AC_SUBST(tss2_CFLAGS)
1000         AC_SUBST(tss2_LIBS)
1001 fi
1002
1003 if test x$imv_swid = xtrue; then
1004         PKG_CHECK_MODULES(json, [json-c], [],
1005                 [PKG_CHECK_MODULES(json, [json])])
1006         AC_SUBST(json_CFLAGS)
1007         AC_SUBST(json_LIBS)
1008 fi
1009
1010 if test x$dumm = xtrue; then
1011         PKG_CHECK_MODULES(gtk, [gtk+-2.0 vte])
1012         AC_SUBST(gtk_CFLAGS)
1013         AC_SUBST(gtk_LIBS)
1014         AC_CHECK_PROGS(RUBY, ruby)
1015         AC_MSG_CHECKING([for Ruby header files])
1016         if test -n "$RUBY"; then
1017                 RUBYINCLUDE=
1018                 RUBYDIR=`($RUBY -r rbconfig -e 'print RbConfig::CONFIG[["rubyhdrdir"]] || ""') 2>/dev/null`
1019                 if test -n "$RUBYDIR" -a -r "$RUBYDIR/ruby.h"; then
1020                         RUBYARCH=`($RUBY -r rbconfig -e 'print RbConfig::CONFIG[["arch"]] || ""') 2>/dev/null`
1021                         if test -n "$RUBYARCH"; then
1022                                 AC_MSG_RESULT([$RUBYDIR])
1023                                 RUBYINCLUDE="-I$RUBYDIR -I$RUBYDIR/$RUBYARCH"
1024                         fi
1025                 else
1026                         RUBYDIR=`($RUBY -r rbconfig -e 'print RbConfig::CONFIG[["archdir"]] || ""') 2>/dev/null`
1027                         if test -n "$RUBYDIR" -a -r "$RUBYDIR/ruby.h"; then
1028                                 AC_MSG_RESULT([$RUBYDIR])
1029                                 RUBYINCLUDE="-I$RUBYDIR"
1030                         fi
1031                 fi
1032                 if test -z "$RUBYINCLUDE"; then
1033                         AC_MSG_ERROR([ruby.h not found])
1034                 fi
1035                 AC_SUBST(RUBYINCLUDE)
1036         else
1037                 AC_MSG_ERROR([don't know how to run ruby])
1038         fi
1039         AC_MSG_CHECKING([for libruby])
1040         saved_LIBS=$LIBS
1041         LIBS=`($RUBY -r rbconfig -e 'print RbConfig::CONFIG[["LIBRUBYARG_SHARED"]] || ""') 2>/dev/null`
1042         AC_TRY_LINK_FUNC(ruby_init,
1043                 [AC_MSG_RESULT([$LIBS]); RUBYLIB=$LIBS],
1044                 [AC_MSG_ERROR([not found])])
1045         AC_SUBST(RUBYLIB)
1046         AC_CHECK_FUNCS(rb_errinfo)
1047         LIBS=$saved_LIBS
1048 fi
1049
1050 if test x$fast = xtrue; then
1051         AC_CHECK_LIB([neo_utl],[hdf_init],[LIBS="$LIBS"],[AC_MSG_ERROR([ClearSilver library neo_utl not found!])],[])
1052         AC_MSG_CHECKING([for -lneo_cgi and dependencies])
1053         saved_CFLAGS=$CFLAGS
1054         saved_LIBS=$LIBS
1055         LIBS="-lneo_cgi -lneo_cs -lneo_utl"
1056         CFLAGS="-I/usr/include/ClearSilver"
1057         AC_LINK_IFELSE(
1058                 [AC_LANG_PROGRAM(
1059                         [[#include <cgi/cgi.h>]],
1060                         [[NEOERR *err = cgi_display(NULL, NULL);]])],
1061                 [AC_MSG_RESULT([yes])],
1062                 [LIBS="$LIBS -lz";
1063                  AC_LINK_IFELSE(
1064                         [AC_LANG_PROGRAM(
1065                                 [[#include <cgi/cgi.h>]],
1066                                 [[NEOERR *err = cgi_display(NULL, NULL);]])],
1067                         [AC_MSG_RESULT([yes, zlib required])],
1068                         [AC_MSG_ERROR([not found])]
1069                  )]
1070         )
1071         clearsilver_LIBS="$LIBS"
1072         AC_SUBST(clearsilver_LIBS)
1073         LIBS=$saved_LIBS
1074         CFLAGS=$saved_CFLAGS
1075
1076         AC_CHECK_LIB([fcgi],[FCGX_Init],[LIBS="$LIBS"],[AC_MSG_ERROR([FastCGI library fcgi not found!])],[])
1077         AC_CHECK_HEADER([fcgiapp.h],,[AC_MSG_ERROR([FastCGI header file fcgiapp.h not found!])])
1078 fi
1079
1080 if test x$mysql = xtrue; then
1081         if test "x$windows" = xtrue; then
1082                 AC_CHECK_HEADER([mysql.h],,[AC_MSG_ERROR([MySQL header file mysql.h not found!])])
1083                 AC_CHECK_LIB([mysql],[mysql_database_init],[LIBS="$LIBS"],[AC_MSG_ERROR([MySQL library not found!])],[])
1084                 AC_SUBST(MYSQLLIB, -lmysql)
1085         else
1086                 AC_PATH_PROG([MYSQLCONFIG], [mysql_config], [], [$PATH:/bin:/usr/bin:/usr/local/bin])
1087                 if test x$MYSQLCONFIG = x; then
1088                         AC_MSG_ERROR([mysql_config not found!])
1089                 fi
1090                 AC_SUBST(MYSQLLIB, `$MYSQLCONFIG --libs_r`)
1091                 AC_SUBST(MYSQLCFLAG, `$MYSQLCONFIG --cflags`)
1092         fi
1093 fi
1094
1095 if test x$sqlite = xtrue; then
1096         AC_CHECK_LIB([sqlite3],[sqlite3_open],[LIBS="$LIBS"],[AC_MSG_ERROR([SQLite library sqlite3 not found])],[])
1097         AC_CHECK_HEADER([sqlite3.h],,[AC_MSG_ERROR([SQLite header sqlite3.h not found!])])
1098         AC_MSG_CHECKING([sqlite3_prepare_v2])
1099         AC_COMPILE_IFELSE(
1100                 [AC_LANG_PROGRAM(
1101                         [[#include <sqlite3.h>]],
1102                         [[void *test = sqlite3_prepare_v2;]])],
1103                 [AC_MSG_RESULT([yes]);
1104                  AC_DEFINE([HAVE_SQLITE3_PREPARE_V2], [], [have sqlite3_prepare_v2()])],
1105                 [AC_MSG_RESULT([no])]
1106         )
1107         AC_MSG_CHECKING([sqlite3.h version >= 3.3.1])
1108         AC_COMPILE_IFELSE(
1109                 [AC_LANG_PROGRAM(
1110                         [[#include <sqlite3.h>]],
1111                         [[
1112                                 #if SQLITE_VERSION_NUMBER < 3003001
1113                                         #error bad sqlite
1114                                 #endif]])],
1115                 [AC_MSG_RESULT([yes])],
1116                 [AC_MSG_RESULT([no]); AC_MSG_ERROR([SQLite version >= 3.3.1 required!])]
1117         )
1118 fi
1119
1120 if test x$openssl = xtrue; then
1121         AC_CHECK_LIB([$openssl_lib],[EVP_CIPHER_CTX_new],[LIBS="$LIBS"],
1122                                  [AC_MSG_ERROR([OpenSSL lib$openssl_lib not found])],[$DLLIB])
1123         AC_CHECK_HEADER([openssl/evp.h],,[AC_MSG_ERROR([OpenSSL header openssl/evp.h not found!])])
1124 fi
1125
1126 if test x$gcrypt = xtrue; then
1127         AC_CHECK_LIB([gcrypt],[gcry_control],[LIBS="$LIBS"],[AC_MSG_ERROR([gcrypt library not found])],[-lgpg-error])
1128         AC_CHECK_HEADER([gcrypt.h],,[AC_MSG_ERROR([gcrypt header gcrypt.h not found!])])
1129         AC_MSG_CHECKING([gcrypt CAMELLIA cipher])
1130         AC_COMPILE_IFELSE(
1131                 [AC_LANG_PROGRAM(
1132                         [[#include <gcrypt.h>]],
1133                         [[enum gcry_cipher_algos alg = GCRY_CIPHER_CAMELLIA128;]])],
1134                 [AC_MSG_RESULT([yes]);
1135                  AC_DEFINE([HAVE_GCRY_CIPHER_CAMELLIA], [], [have GCRY_CIPHER_CAMELLIA128])],
1136                 [AC_MSG_RESULT([no])]
1137         )
1138 fi
1139
1140 if test x$uci = xtrue; then
1141         AC_CHECK_LIB([uci],[uci_alloc_context],[LIBS="$LIBS"],[AC_MSG_ERROR([UCI library libuci not found])],[])
1142         AC_CHECK_HEADER([uci.h],,[AC_MSG_ERROR([UCI header uci.h not found!])])
1143 fi
1144
1145 if test x$android_dns = xtrue; then
1146         AC_CHECK_LIB([cutils],[property_get],[LIBS="$LIBS"],[AC_MSG_ERROR([Android library libcutils not found])],[])
1147         AC_CHECK_HEADER([cutils/properties.h],,[AC_MSG_ERROR([Android header cutils/properties.h not found!])])
1148         # we have to force the use of libdl here because the autodetection
1149         # above does not work correctly when cross-compiling for android.
1150         DLLIB="-ldl"
1151         AC_SUBST(DLLIB)
1152 fi
1153
1154 if test x$eap_sim_pcsc = xtrue; then
1155         PKG_CHECK_MODULES(pcsclite, [libpcsclite])
1156         AC_SUBST(pcsclite_CFLAGS)
1157         AC_SUBST(pcsclite_LIBS)
1158 fi
1159
1160 if test x$nm = xtrue; then
1161         PKG_CHECK_EXISTS([libnm-glib],
1162                 [PKG_CHECK_MODULES(nm, [NetworkManager gthread-2.0 libnm-util libnm-glib libnm-glib-vpn])],
1163                 [PKG_CHECK_MODULES(nm, [NetworkManager gthread-2.0 libnm_util libnm_glib libnm_glib_vpn])]
1164         )
1165         AC_SUBST(nm_CFLAGS)
1166         AC_SUBST(nm_LIBS)
1167 fi
1168
1169 if test x$xauth_pam = xtrue; then
1170         AC_CHECK_LIB([pam],[pam_start],[LIBS="$LIBS"],[AC_MSG_ERROR([PAM library not found])],[])
1171         AC_CHECK_HEADER([security/pam_appl.h],,[AC_MSG_ERROR([PAM header security/pam_appl.h not found!])])
1172 fi
1173
1174 if test x$connmark = xtrue -o x$forecast = xtrue; then
1175         PKG_CHECK_MODULES(libiptc, [libiptc])
1176         AC_SUBST(libiptc_CFLAGS)
1177         AC_SUBST(libiptc_LIBS)
1178 fi
1179
1180 if test x$capabilities = xnative; then
1181         AC_MSG_NOTICE([Usage of the native Linux capabilities interface is deprecated, use libcap instead])
1182         # Linux requires the following for capset(), Android does not have it,
1183         # but defines capset() in unistd.h instead.
1184         AC_CHECK_HEADERS([sys/capability.h])
1185         AC_CHECK_FUNC(capset,,[AC_MSG_ERROR([capset() not found!])])
1186         AC_DEFINE([CAPABILITIES_NATIVE], [], [have native linux capset()])
1187 fi
1188
1189 if test x$capabilities = xlibcap; then
1190         AC_CHECK_LIB([cap],[cap_init],[LIBS="$LIBS"],[AC_MSG_ERROR([libcap library not found])],[])
1191         AC_CHECK_HEADER([sys/capability.h],
1192                 [AC_DEFINE([HAVE_SYS_CAPABILITY_H], [], [have sys/capability.h])],
1193                 [AC_MSG_ERROR([libcap header sys/capability.h not found!])])
1194         AC_DEFINE([CAPABILITIES_LIBCAP], [], [have libpcap library])
1195 fi
1196
1197 if test x$integrity_test = xtrue; then
1198         AC_MSG_CHECKING([for dladdr()])
1199         AC_COMPILE_IFELSE(
1200                 [AC_LANG_PROGRAM(
1201                         [[#define _GNU_SOURCE
1202                           #include <dlfcn.h>]],
1203                         [[Dl_info info; dladdr(main, &info);]])],
1204                 [AC_MSG_RESULT([yes])],
1205                 [AC_MSG_RESULT([no]);
1206                  AC_MSG_ERROR([dladdr() not supported, required by integrity-test!])]
1207         )
1208         AC_MSG_CHECKING([for dl_iterate_phdr()])
1209         AC_COMPILE_IFELSE(
1210                 [AC_LANG_PROGRAM(
1211                         [[#define _GNU_SOURCE
1212                           #include <link.h>]],
1213                         [[dl_iterate_phdr((void*)0, (void*)0);]])],
1214                 [AC_MSG_RESULT([yes])],
1215                 [AC_MSG_RESULT([no]);
1216                  AC_MSG_ERROR([dl_iterate_phdr() not supported, required by integrity-test!])]
1217         )
1218 fi
1219
1220 if test x$bfd_backtraces = xtrue; then
1221         AC_CHECK_LIB([bfd],[bfd_init],[LIBS="$LIBS"],[AC_MSG_ERROR([binutils libbfd not found!])],[])
1222         AC_CHECK_HEADER([bfd.h],[AC_DEFINE([HAVE_BFD_H],,[have binutils bfd.h])],
1223                 [AC_MSG_ERROR([binutils bfd.h header not found!])])
1224         BFDLIB="-lbfd"
1225         AC_SUBST(BFDLIB)
1226 fi
1227
1228 if test x$unwind_backtraces = xtrue; then
1229         AC_CHECK_LIB([unwind],[unw_getcontext],[LIBS="$LIBS"],[AC_MSG_ERROR([libunwind not found!])],[])
1230         AC_CHECK_HEADER([libunwind.h],[AC_DEFINE([HAVE_LIBUNWIND_H],,[have libunwind.h])],
1231                 [AC_MSG_ERROR([libunwind.h header not found!])])
1232         UNWINDLIB="-lunwind"
1233         AC_SUBST(UNWINDLIB)
1234 fi
1235
1236 AM_CONDITIONAL(USE_DEV_HEADERS, [test "x$dev_headers" != xno])
1237 if test x$dev_headers = xyes; then
1238         dev_headers="$includedir/strongswan"
1239 fi
1240 AC_SUBST(dev_headers)
1241
1242 CFLAGS="$CFLAGS -include `pwd`/config.h"
1243
1244 if test x$tkm = xtrue; then
1245         AC_PATH_PROG([GPRBUILD], [gprbuild], [], [$PATH:/bin:/usr/bin:/usr/local/bin])
1246         if test x$GPRBUILD = x; then
1247                 AC_MSG_ERROR([gprbuild not found])
1248         fi
1249 fi
1250
1251 if test x$coverage = xtrue; then
1252         AC_PATH_PROG([LCOV], [lcov], [], [$PATH:/bin:/usr/bin:/usr/local/bin])
1253         if test x$LCOV = x; then
1254                 AC_MSG_ERROR([lcov not found])
1255         fi
1256         AC_PATH_PROG([GENHTML], [genhtml], [], [$PATH:/bin:/usr/bin:/usr/local/bin])
1257         if test x$GENHTML = x; then
1258                 AC_MSG_ERROR([genhtml not found])
1259         fi
1260
1261         COVERAGE_CFLAGS="-fprofile-arcs -ftest-coverage"
1262         COVERAGE_LDFLAGS="-fprofile-arcs"
1263         AC_SUBST(COVERAGE_CFLAGS)
1264         AC_SUBST(COVERAGE_LDFLAGS)
1265
1266         AC_MSG_NOTICE([coverage enabled, adding "-g -O0" to CFLAGS])
1267         CFLAGS="${CFLAGS} -g -O0"
1268 fi
1269
1270 if test x$ruby_gems = xtrue; then
1271         AC_PATH_PROG([GEM], [gem], [], [$PATH:/bin:/usr/bin:/usr/local/bin])
1272         if test x$GEM = x; then
1273                 AC_MSG_ERROR(RubyGems package manager not found)
1274         fi
1275         if test "x$rubygemdir" = "xgem environment gemdir"; then
1276                 rubygemdir=$($GEM environment gemdir)
1277         fi
1278         AC_SUBST(RUBYGEMDIR, "$rubygemdir")
1279 fi
1280 AM_CONDITIONAL(RUBY_GEMS_INSTALL, [test "x$ruby_gems_install" = xtrue])
1281
1282 if test x$python_eggs = xtrue; then
1283         PYTHON_PACKAGE_VERSION=`echo "$PACKAGE_VERSION" | $SED 's/dr/dev/'`
1284         AC_SUBST([PYTHON_PACKAGE_VERSION])
1285         if test x$python_eggs_install = xtrue; then
1286                 AC_PATH_PROG([EASY_INSTALL], [easy_install], [], [$PATH:/bin:/usr/bin:/usr/local/bin])
1287                 if test x$EASY_INSTALL = x; then
1288                         AC_MSG_ERROR(Python easy_install not found)
1289                 fi
1290         fi
1291         if test "x$pythoneggdir" = "xmain site-packages directory"; then
1292                 AC_SUBST(PYTHONEGGINSTALLDIR, "")
1293         else
1294                 AC_SUBST(PYTHONEGGINSTALLDIR, "--install-dir $pythoneggdir")
1295         fi
1296         AC_PATH_PROG([PY_TEST], [py.test], [], [$PATH:/bin:/usr/bin:/usr/local/bin])
1297 fi
1298 AM_CONDITIONAL(PYTHON_EGGS_INSTALL, [test "x$python_eggs_install" = xtrue])
1299
1300 AM_CONDITIONAL(PERL_CPAN_INSTALL, [test "x$perl_cpan_install" = xtrue])
1301
1302 # ===============================================
1303 #  collect plugin list for strongSwan components
1304 # ===============================================
1305
1306 m4_include(m4/macros/add-plugin.m4)
1307
1308 # plugin lists for all components
1309 charon_plugins=
1310 starter_plugins=
1311 pool_plugins=
1312 attest_plugins=
1313 scepclient_plugins=
1314 pki_plugins=
1315 scripts_plugins=
1316 manager_plugins=
1317 medsrv_plugins=
1318 nm_plugins=
1319 cmd_plugins=
1320 aikgen_plugins=
1321
1322 # location specific lists for checksumming,
1323 # for src/libcharon, src/libstrongswan and src/libtnccs
1324 c_plugins=
1325 s_plugins=
1326 t_plugins=
1327
1328 ADD_PLUGIN([test-vectors],         [s charon scepclient pki])
1329 ADD_PLUGIN([unbound],              [s charon scripts])
1330 ADD_PLUGIN([ldap],                 [s charon scepclient scripts nm cmd])
1331 ADD_PLUGIN([pkcs11],               [s charon pki nm cmd])
1332 ADD_PLUGIN([aesni],                [s charon scepclient pki scripts medsrv attest nm cmd aikgen])
1333 ADD_PLUGIN([aes],                  [s charon scepclient pki scripts nm cmd])
1334 ADD_PLUGIN([des],                  [s charon scepclient pki scripts nm cmd])
1335 ADD_PLUGIN([blowfish],             [s charon scepclient pki scripts nm cmd])
1336 ADD_PLUGIN([rc2],                  [s charon scepclient pki scripts nm cmd])
1337 ADD_PLUGIN([sha2],                 [s charon scepclient pki scripts medsrv attest nm cmd aikgen])
1338 ADD_PLUGIN([sha3],                 [s charon scepclient pki scripts medsrv attest nm cmd aikgen])
1339 ADD_PLUGIN([sha1],                 [s charon scepclient pki scripts manager medsrv attest nm cmd aikgen])
1340 ADD_PLUGIN([md4],                  [s charon scepclient pki nm cmd])
1341 ADD_PLUGIN([md5],                  [s charon scepclient pki scripts attest nm cmd aikgen])
1342 ADD_PLUGIN([mgf1],                 [s charon scepclient pki scripts medsrv attest nm cmd aikgen])
1343 ADD_PLUGIN([rdrand],               [s charon scepclient pki scripts medsrv attest nm cmd aikgen])
1344 ADD_PLUGIN([random],               [s charon scepclient pki scripts manager medsrv attest nm cmd aikgen])
1345 ADD_PLUGIN([nonce],                [s charon nm cmd aikgen])
1346 ADD_PLUGIN([x509],                 [s charon scepclient pki scripts attest nm cmd aikgen])
1347 ADD_PLUGIN([revocation],           [s charon pki nm cmd])
1348 ADD_PLUGIN([constraints],          [s charon nm cmd])
1349 ADD_PLUGIN([acert],                [s charon])
1350 ADD_PLUGIN([pubkey],               [s charon cmd aikgen])
1351 ADD_PLUGIN([pkcs1],                [s charon scepclient pki scripts manager medsrv attest nm cmd aikgen])
1352 ADD_PLUGIN([pkcs7],                [s charon scepclient pki scripts nm cmd])
1353 ADD_PLUGIN([pkcs8],                [s charon scepclient pki scripts manager medsrv attest nm cmd])
1354 ADD_PLUGIN([pkcs12],               [s charon scepclient pki scripts cmd])
1355 ADD_PLUGIN([pgp],                  [s charon])
1356 ADD_PLUGIN([dnskey],               [s charon pki])
1357 ADD_PLUGIN([sshkey],               [s charon pki nm cmd])
1358 ADD_PLUGIN([dnscert],              [c charon])
1359 ADD_PLUGIN([ipseckey],             [c charon])
1360 ADD_PLUGIN([pem],                  [s charon scepclient pki scripts manager medsrv attest nm cmd aikgen])
1361 ADD_PLUGIN([padlock],              [s charon])
1362 ADD_PLUGIN([openssl],              [s charon scepclient pki scripts manager medsrv attest nm cmd aikgen])
1363 ADD_PLUGIN([gcrypt],               [s charon scepclient pki scripts manager medsrv attest nm cmd aikgen])
1364 ADD_PLUGIN([af-alg],               [s charon scepclient pki scripts medsrv attest nm cmd aikgen])
1365 ADD_PLUGIN([fips-prf],             [s charon nm cmd])
1366 ADD_PLUGIN([gmp],                  [s charon scepclient pki scripts manager medsrv attest nm cmd aikgen])
1367 ADD_PLUGIN([curve25519],           [s charon scripts nm cmd])
1368 ADD_PLUGIN([agent],                [s charon nm cmd])
1369 ADD_PLUGIN([keychain],             [s charon cmd])
1370 ADD_PLUGIN([chapoly],              [s charon scripts nm cmd])
1371 ADD_PLUGIN([xcbc],                 [s charon nm cmd])
1372 ADD_PLUGIN([cmac],                 [s charon nm cmd])
1373 ADD_PLUGIN([hmac],                 [s charon pki scripts nm cmd])
1374 ADD_PLUGIN([ctr],                  [s charon scripts nm cmd])
1375 ADD_PLUGIN([ccm],                  [s charon scripts nm cmd])
1376 ADD_PLUGIN([gcm],                  [s charon scripts nm cmd])
1377 ADD_PLUGIN([ntru],                 [s charon scripts nm cmd])
1378 ADD_PLUGIN([newhope],              [s charon scripts nm cmd])
1379 ADD_PLUGIN([bliss],                [s charon pki scripts nm cmd])
1380 ADD_PLUGIN([curl],                 [s charon scepclient pki scripts nm cmd])
1381 ADD_PLUGIN([files],                [s charon scepclient pki scripts nm cmd])
1382 ADD_PLUGIN([winhttp],              [s charon pki scripts])
1383 ADD_PLUGIN([soup],                 [s charon pki scripts nm cmd])
1384 ADD_PLUGIN([mysql],                [s charon pool manager medsrv attest])
1385 ADD_PLUGIN([sqlite],               [s charon pool manager medsrv attest])
1386 ADD_PLUGIN([attr],                 [c charon])
1387 ADD_PLUGIN([attr-sql],             [c charon])
1388 ADD_PLUGIN([load-tester],          [c charon])
1389 ADD_PLUGIN([kernel-libipsec],      [c charon cmd])
1390 ADD_PLUGIN([kernel-wfp],           [c charon])
1391 ADD_PLUGIN([kernel-iph],           [c charon])
1392 ADD_PLUGIN([kernel-pfkey],         [c charon starter nm cmd])
1393 ADD_PLUGIN([kernel-pfroute],       [c charon starter nm cmd])
1394 ADD_PLUGIN([kernel-netlink],       [c charon starter nm cmd])
1395 ADD_PLUGIN([resolve],              [c charon cmd])
1396 ADD_PLUGIN([socket-default],       [c charon nm cmd])
1397 ADD_PLUGIN([socket-dynamic],       [c charon cmd])
1398 ADD_PLUGIN([socket-win],           [c charon])
1399 ADD_PLUGIN([bypass-lan],           [c charon nm cmd])
1400 ADD_PLUGIN([connmark],             [c charon])
1401 ADD_PLUGIN([forecast],             [c charon])
1402 ADD_PLUGIN([farp],                 [c charon])
1403 ADD_PLUGIN([stroke],               [c charon])
1404 ADD_PLUGIN([vici],                 [c charon])
1405 ADD_PLUGIN([smp],                  [c charon])
1406 ADD_PLUGIN([sql],                  [c charon])
1407 ADD_PLUGIN([updown],               [c charon])
1408 ADD_PLUGIN([eap-identity],         [c charon nm cmd])
1409 ADD_PLUGIN([eap-sim],              [c charon])
1410 ADD_PLUGIN([eap-sim-file],         [c charon])
1411 ADD_PLUGIN([eap-sim-pcsc],         [c charon])
1412 ADD_PLUGIN([eap-aka],              [c charon])
1413 ADD_PLUGIN([eap-aka-3gpp2],        [c charon])
1414 ADD_PLUGIN([eap-simaka-sql],       [c charon])
1415 ADD_PLUGIN([eap-simaka-pseudonym], [c charon])
1416 ADD_PLUGIN([eap-simaka-reauth],    [c charon])
1417 ADD_PLUGIN([eap-md5],              [c charon nm cmd])
1418 ADD_PLUGIN([eap-gtc],              [c charon nm cmd])
1419 ADD_PLUGIN([eap-mschapv2],         [c charon nm cmd])
1420 ADD_PLUGIN([eap-dynamic],          [c charon])
1421 ADD_PLUGIN([eap-radius],           [c charon])
1422 ADD_PLUGIN([eap-tls],              [c charon nm cmd])
1423 ADD_PLUGIN([eap-ttls],             [c charon nm cmd])
1424 ADD_PLUGIN([eap-peap],             [c charon nm cmd])
1425 ADD_PLUGIN([eap-tnc],              [c charon])
1426 ADD_PLUGIN([xauth-generic],        [c charon cmd])
1427 ADD_PLUGIN([xauth-eap],            [c charon])
1428 ADD_PLUGIN([xauth-pam],            [c charon])
1429 ADD_PLUGIN([xauth-noauth],         [c charon])
1430 ADD_PLUGIN([tnc-ifmap],            [c charon])
1431 ADD_PLUGIN([tnc-pdp],              [c charon])
1432 ADD_PLUGIN([tnc-imc],              [t charon])
1433 ADD_PLUGIN([tnc-imv],              [t charon])
1434 ADD_PLUGIN([tnc-tnccs],            [t charon])
1435 ADD_PLUGIN([tnccs-20],             [t charon])
1436 ADD_PLUGIN([tnccs-11],             [t charon])
1437 ADD_PLUGIN([tnccs-dynamic],        [t charon])
1438 ADD_PLUGIN([medsrv],               [c charon])
1439 ADD_PLUGIN([medcli],               [c charon])
1440 ADD_PLUGIN([dhcp],                 [c charon])
1441 ADD_PLUGIN([osx-attr],             [c charon cmd])
1442 ADD_PLUGIN([p-cscf],               [c charon cmd])
1443 ADD_PLUGIN([android-dns],          [c charon])
1444 ADD_PLUGIN([android-log],          [c charon])
1445 ADD_PLUGIN([ha],                   [c charon])
1446 ADD_PLUGIN([whitelist],            [c charon])
1447 ADD_PLUGIN([ext-auth],             [c charon])
1448 ADD_PLUGIN([lookip],               [c charon])
1449 ADD_PLUGIN([error-notify],         [c charon])
1450 ADD_PLUGIN([certexpire],           [c charon])
1451 ADD_PLUGIN([systime-fix],          [c charon])
1452 ADD_PLUGIN([led],                  [c charon])
1453 ADD_PLUGIN([duplicheck],           [c charon])
1454 ADD_PLUGIN([coupling],             [c charon])
1455 ADD_PLUGIN([radattr],              [c charon])
1456 ADD_PLUGIN([uci],                  [c charon])
1457 ADD_PLUGIN([addrblock],            [c charon])
1458 ADD_PLUGIN([unity],                [c charon])
1459
1460 AC_SUBST(charon_plugins)
1461 AC_SUBST(starter_plugins)
1462 AC_SUBST(pool_plugins)
1463 AC_SUBST(attest_plugins)
1464 AC_SUBST(scepclient_plugins)
1465 AC_SUBST(pki_plugins)
1466 AC_SUBST(scripts_plugins)
1467 AC_SUBST(manager_plugins)
1468 AC_SUBST(medsrv_plugins)
1469 AC_SUBST(nm_plugins)
1470 AC_SUBST(cmd_plugins)
1471 AC_SUBST(aikgen_plugins)
1472
1473 AC_SUBST(c_plugins)
1474 AC_SUBST(h_plugins)
1475 AC_SUBST(s_plugins)
1476 AC_SUBST(t_plugins)
1477
1478 # ======================
1479 #  set Makefile.am vars
1480 # ======================
1481
1482 #  libstrongswan plugins
1483 # -----------------------
1484 AM_CONDITIONAL(USE_TEST_VECTORS, test x$test_vectors = xtrue)
1485 AM_CONDITIONAL(USE_CURL, test x$curl = xtrue)
1486 AM_CONDITIONAL(USE_FILES, test x$files = xtrue)
1487 AM_CONDITIONAL(USE_WINHTTP, test x$winhttp = xtrue)
1488 AM_CONDITIONAL(USE_UNBOUND, test x$unbound = xtrue)
1489 AM_CONDITIONAL(USE_SOUP, test x$soup = xtrue)
1490 AM_CONDITIONAL(USE_LDAP, test x$ldap = xtrue)
1491 AM_CONDITIONAL(USE_AES, test x$aes = xtrue)
1492 AM_CONDITIONAL(USE_DES, test x$des = xtrue)
1493 AM_CONDITIONAL(USE_BLOWFISH, test x$blowfish = xtrue)
1494 AM_CONDITIONAL(USE_RC2, test x$rc2 = xtrue)
1495 AM_CONDITIONAL(USE_MD4, test x$md4 = xtrue)
1496 AM_CONDITIONAL(USE_MD5, test x$md5 = xtrue)
1497 AM_CONDITIONAL(USE_SHA1, test x$sha1 = xtrue)
1498 AM_CONDITIONAL(USE_SHA2, test x$sha2 = xtrue)
1499 AM_CONDITIONAL(USE_SHA3, test x$sha3 = xtrue)
1500 AM_CONDITIONAL(USE_MGF1, test x$mgf1 = xtrue)
1501 AM_CONDITIONAL(USE_FIPS_PRF, test x$fips_prf = xtrue)
1502 AM_CONDITIONAL(USE_GMP, test x$gmp = xtrue)
1503 AM_CONDITIONAL(USE_CURVE25519, test x$curve25519 = xtrue)
1504 AM_CONDITIONAL(USE_RDRAND, test x$rdrand = xtrue)
1505 AM_CONDITIONAL(USE_AESNI, test x$aesni = xtrue)
1506 AM_CONDITIONAL(USE_RANDOM, test x$random = xtrue)
1507 AM_CONDITIONAL(USE_NONCE, test x$nonce = xtrue)
1508 AM_CONDITIONAL(USE_X509, test x$x509 = xtrue)
1509 AM_CONDITIONAL(USE_REVOCATION, test x$revocation = xtrue)
1510 AM_CONDITIONAL(USE_CONSTRAINTS, test x$constraints = xtrue)
1511 AM_CONDITIONAL(USE_ACERT, test x$acert = xtrue)
1512 AM_CONDITIONAL(USE_PUBKEY, test x$pubkey = xtrue)
1513 AM_CONDITIONAL(USE_PKCS1, test x$pkcs1 = xtrue)
1514 AM_CONDITIONAL(USE_PKCS7, test x$pkcs7 = xtrue)
1515 AM_CONDITIONAL(USE_PKCS8, test x$pkcs8 = xtrue)
1516 AM_CONDITIONAL(USE_PKCS12, test x$pkcs12 = xtrue)
1517 AM_CONDITIONAL(USE_PGP, test x$pgp = xtrue)
1518 AM_CONDITIONAL(USE_DNSKEY, test x$dnskey = xtrue)
1519 AM_CONDITIONAL(USE_SSHKEY, test x$sshkey = xtrue)
1520 AM_CONDITIONAL(USE_PEM, test x$pem = xtrue)
1521 AM_CONDITIONAL(USE_HMAC, test x$hmac = xtrue)
1522 AM_CONDITIONAL(USE_CMAC, test x$cmac = xtrue)
1523 AM_CONDITIONAL(USE_XCBC, test x$xcbc = xtrue)
1524 AM_CONDITIONAL(USE_MYSQL, test x$mysql = xtrue)
1525 AM_CONDITIONAL(USE_SQLITE, test x$sqlite = xtrue)
1526 AM_CONDITIONAL(USE_PADLOCK, test x$padlock = xtrue)
1527 AM_CONDITIONAL(USE_OPENSSL, test x$openssl = xtrue)
1528 AM_CONDITIONAL(USE_GCRYPT, test x$gcrypt = xtrue)
1529 AM_CONDITIONAL(USE_AGENT, test x$agent = xtrue)
1530 AM_CONDITIONAL(USE_KEYCHAIN, test x$keychain = xtrue)
1531 AM_CONDITIONAL(USE_PKCS11, test x$pkcs11 = xtrue)
1532 AM_CONDITIONAL(USE_CHAPOLY, test x$chapoly = xtrue)
1533 AM_CONDITIONAL(USE_CTR, test x$ctr = xtrue)
1534 AM_CONDITIONAL(USE_CCM, test x$ccm = xtrue)
1535 AM_CONDITIONAL(USE_GCM, test x$gcm = xtrue)
1536 AM_CONDITIONAL(USE_AF_ALG, test x$af_alg = xtrue)
1537 AM_CONDITIONAL(USE_NTRU, test x$ntru = xtrue)
1538 AM_CONDITIONAL(USE_NEWHOPE, test x$newhope = xtrue)
1539 AM_CONDITIONAL(USE_BLISS, test x$bliss = xtrue)
1540
1541 #  charon plugins
1542 # ----------------
1543 AM_CONDITIONAL(USE_STROKE, test x$stroke = xtrue)
1544 AM_CONDITIONAL(USE_VICI, test x$vici = xtrue)
1545 AM_CONDITIONAL(USE_MEDSRV, test x$medsrv = xtrue)
1546 AM_CONDITIONAL(USE_MEDCLI, test x$medcli = xtrue)
1547 AM_CONDITIONAL(USE_UCI, test x$uci = xtrue)
1548 AM_CONDITIONAL(USE_OSX_ATTR, test x$osx_attr = xtrue)
1549 AM_CONDITIONAL(USE_P_CSCF, test x$p_cscf = xtrue)
1550 AM_CONDITIONAL(USE_ANDROID_DNS, test x$android_dns = xtrue)
1551 AM_CONDITIONAL(USE_ANDROID_LOG, test x$android_log = xtrue)
1552 AM_CONDITIONAL(USE_SMP, test x$smp = xtrue)
1553 AM_CONDITIONAL(USE_SQL, test x$sql = xtrue)
1554 AM_CONDITIONAL(USE_DNSCERT, test x$dnscert = xtrue)
1555 AM_CONDITIONAL(USE_IPSECKEY, test x$ipseckey = xtrue)
1556 AM_CONDITIONAL(USE_UPDOWN, test x$updown = xtrue)
1557 AM_CONDITIONAL(USE_DHCP, test x$dhcp = xtrue)
1558 AM_CONDITIONAL(USE_LOAD_TESTER, test x$load_tester = xtrue)
1559 AM_CONDITIONAL(USE_HA, test x$ha = xtrue)
1560 AM_CONDITIONAL(USE_KERNEL_NETLINK, test x$kernel_netlink = xtrue)
1561 AM_CONDITIONAL(USE_KERNEL_PFKEY, test x$kernel_pfkey = xtrue)
1562 AM_CONDITIONAL(USE_KERNEL_PFROUTE, test x$kernel_pfroute = xtrue)
1563 AM_CONDITIONAL(USE_KERNEL_LIBIPSEC, test x$kernel_libipsec = xtrue)
1564 AM_CONDITIONAL(USE_KERNEL_WFP, test x$kernel_wfp = xtrue)
1565 AM_CONDITIONAL(USE_KERNEL_IPH, test x$kernel_iph = xtrue)
1566 AM_CONDITIONAL(USE_WHITELIST, test x$whitelist = xtrue)
1567 AM_CONDITIONAL(USE_EXT_AUTH, test x$ext_auth = xtrue)
1568 AM_CONDITIONAL(USE_LOOKIP, test x$lookip = xtrue)
1569 AM_CONDITIONAL(USE_ERROR_NOTIFY, test x$error_notify = xtrue)
1570 AM_CONDITIONAL(USE_CERTEXPIRE, test x$certexpire = xtrue)
1571 AM_CONDITIONAL(USE_SYSTIME_FIX, test x$systime_fix = xtrue)
1572 AM_CONDITIONAL(USE_LED, test x$led = xtrue)
1573 AM_CONDITIONAL(USE_DUPLICHECK, test x$duplicheck = xtrue)
1574 AM_CONDITIONAL(USE_COUPLING, test x$coupling = xtrue)
1575 AM_CONDITIONAL(USE_RADATTR, test x$radattr = xtrue)
1576 AM_CONDITIONAL(USE_EAP_SIM, test x$eap_sim = xtrue)
1577 AM_CONDITIONAL(USE_EAP_SIM_FILE, test x$eap_sim_file = xtrue)
1578 AM_CONDITIONAL(USE_EAP_SIM_PCSC, test x$eap_sim_pcsc = xtrue)
1579 AM_CONDITIONAL(USE_EAP_SIMAKA_SQL, test x$eap_simaka_sql = xtrue)
1580 AM_CONDITIONAL(USE_EAP_SIMAKA_PSEUDONYM, test x$eap_simaka_pseudonym = xtrue)
1581 AM_CONDITIONAL(USE_EAP_SIMAKA_REAUTH, test x$eap_simaka_reauth = xtrue)
1582 AM_CONDITIONAL(USE_EAP_IDENTITY, test x$eap_identity = xtrue)
1583 AM_CONDITIONAL(USE_EAP_MD5, test x$eap_md5 = xtrue)
1584 AM_CONDITIONAL(USE_EAP_GTC, test x$eap_gtc = xtrue)
1585 AM_CONDITIONAL(USE_EAP_AKA, test x$eap_aka = xtrue)
1586 AM_CONDITIONAL(USE_EAP_AKA_3GPP2, test x$eap_aka_3gpp2 = xtrue)
1587 AM_CONDITIONAL(USE_EAP_MSCHAPV2, test x$eap_mschapv2 = xtrue)
1588 AM_CONDITIONAL(USE_EAP_TLS, test x$eap_tls = xtrue)
1589 AM_CONDITIONAL(USE_EAP_TTLS, test x$eap_ttls = xtrue)
1590 AM_CONDITIONAL(USE_EAP_PEAP, test x$eap_peap = xtrue)
1591 AM_CONDITIONAL(USE_EAP_TNC, test x$eap_tnc = xtrue)
1592 AM_CONDITIONAL(USE_EAP_DYNAMIC, test x$eap_dynamic = xtrue)
1593 AM_CONDITIONAL(USE_EAP_RADIUS, test x$eap_radius = xtrue)
1594 AM_CONDITIONAL(USE_XAUTH_GENERIC, test x$xauth_generic = xtrue)
1595 AM_CONDITIONAL(USE_XAUTH_EAP, test x$xauth_eap = xtrue)
1596 AM_CONDITIONAL(USE_XAUTH_PAM, test x$xauth_pam = xtrue)
1597 AM_CONDITIONAL(USE_XAUTH_NOAUTH, test x$xauth_noauth = xtrue)
1598 AM_CONDITIONAL(USE_TNC_IFMAP, test x$tnc_ifmap = xtrue)
1599 AM_CONDITIONAL(USE_TNC_PDP, test x$tnc_pdp = xtrue)
1600 AM_CONDITIONAL(USE_TNC_IMC, test x$tnc_imc = xtrue)
1601 AM_CONDITIONAL(USE_TNC_IMV, test x$tnc_imv = xtrue)
1602 AM_CONDITIONAL(USE_TNC_TNCCS, test x$tnc_tnccs = xtrue)
1603 AM_CONDITIONAL(USE_TNCCS_11, test x$tnccs_11 = xtrue)
1604 AM_CONDITIONAL(USE_TNCCS_20, test x$tnccs_20 = xtrue)
1605 AM_CONDITIONAL(USE_TNCCS_DYNAMIC, test x$tnccs_dynamic = xtrue)
1606 AM_CONDITIONAL(USE_IMC_TEST, test x$imc_test = xtrue)
1607 AM_CONDITIONAL(USE_IMV_TEST, test x$imv_test = xtrue)
1608 AM_CONDITIONAL(USE_IMC_SCANNER, test x$imc_scanner = xtrue)
1609 AM_CONDITIONAL(USE_IMV_SCANNER, test x$imv_scanner = xtrue)
1610 AM_CONDITIONAL(USE_IMC_OS, test x$imc_os = xtrue)
1611 AM_CONDITIONAL(USE_IMV_OS, test x$imv_os = xtrue)
1612 AM_CONDITIONAL(USE_IMC_ATTESTATION, test x$imc_attestation = xtrue)
1613 AM_CONDITIONAL(USE_IMV_ATTESTATION, test x$imv_attestation = xtrue)
1614 AM_CONDITIONAL(USE_IMC_SWID, test x$imc_swid = xtrue)
1615 AM_CONDITIONAL(USE_IMV_SWID, test x$imv_swid = xtrue)
1616 AM_CONDITIONAL(USE_IMC_HCD, test x$imc_hcd = xtrue)
1617 AM_CONDITIONAL(USE_IMV_HCD, test x$imv_hcd = xtrue)
1618 AM_CONDITIONAL(USE_SOCKET_DEFAULT, test x$socket_default = xtrue)
1619 AM_CONDITIONAL(USE_SOCKET_DYNAMIC, test x$socket_dynamic = xtrue)
1620 AM_CONDITIONAL(USE_SOCKET_WIN, test x$socket_win = xtrue)
1621 AM_CONDITIONAL(USE_BYPASS_LAN, test x$bypass_lan = xtrue)
1622 AM_CONDITIONAL(USE_CONNMARK, test x$connmark = xtrue)
1623 AM_CONDITIONAL(USE_FORECAST, test x$forecast = xtrue)
1624 AM_CONDITIONAL(USE_FARP, test x$farp = xtrue)
1625 AM_CONDITIONAL(USE_ADDRBLOCK, test x$addrblock = xtrue)
1626 AM_CONDITIONAL(USE_UNITY, test x$unity = xtrue)
1627 AM_CONDITIONAL(USE_RESOLVE, test x$resolve = xtrue)
1628 AM_CONDITIONAL(USE_ATTR, test x$attr = xtrue)
1629 AM_CONDITIONAL(USE_ATTR_SQL, test x$attr_sql = xtrue)
1630
1631 #  other options
1632 # ---------------
1633 AM_CONDITIONAL(USE_LEAK_DETECTIVE, test x$leak_detective = xtrue)
1634 AM_CONDITIONAL(USE_LOCK_PROFILER, test x$lock_profiler = xtrue)
1635 AM_CONDITIONAL(USE_DUMM, test x$dumm = xtrue)
1636 AM_CONDITIONAL(USE_FAST, test x$fast = xtrue)
1637 AM_CONDITIONAL(USE_MANAGER, test x$manager = xtrue)
1638 AM_CONDITIONAL(USE_ME, test x$mediation = xtrue)
1639 AM_CONDITIONAL(USE_INTEGRITY_TEST, test x$integrity_test = xtrue)
1640 AM_CONDITIONAL(USE_LOAD_WARNING, test x$load_warning = xtrue)
1641 AM_CONDITIONAL(USE_IKEV1, test x$ikev1 = xtrue)
1642 AM_CONDITIONAL(USE_IKEV2, test x$ikev2 = xtrue)
1643 AM_CONDITIONAL(USE_THREADS, test x$threads = xtrue)
1644 AM_CONDITIONAL(USE_ADNS, test x$adns = xtrue)
1645 AM_CONDITIONAL(USE_CHARON, test x$charon = xtrue)
1646 AM_CONDITIONAL(USE_NM, test x$nm = xtrue)
1647 AM_CONDITIONAL(USE_PKI, test x$pki = xtrue)
1648 AM_CONDITIONAL(USE_SCEPCLIENT, test x$scepclient = xtrue)
1649 AM_CONDITIONAL(USE_SCRIPTS, test x$scripts = xtrue)
1650 AM_CONDITIONAL(USE_CONFTEST, test x$conftest = xtrue)
1651 AM_CONDITIONAL(USE_LIBSTRONGSWAN, test x$charon = xtrue -o x$pki = xtrue -o x$scepclient = xtrue -o x$conftest = xtrue -o x$fast = xtrue -o x$imcv = xtrue -o x$nm = xtrue -o x$tkm = xtrue -o x$cmd = xtrue -o x$tls = xtrue -o x$tnc_tnccs = xtrue -o x$aikgen = xtrue -o x$aikpub2 = xtrue -o x$svc = xtrue -o x$systemd = xtrue)
1652 AM_CONDITIONAL(USE_LIBCHARON, test x$charon = xtrue -o x$conftest = xtrue -o x$nm = xtrue -o x$tkm = xtrue -o x$cmd = xtrue -o x$svc = xtrue -o x$systemd = xtrue)
1653 AM_CONDITIONAL(USE_LIBIPSEC, test x$libipsec = xtrue)
1654 AM_CONDITIONAL(USE_LIBNTTFFT, test x$bliss = xtrue -o x$newhope = xtrue)
1655 AM_CONDITIONAL(USE_LIBTNCIF, test x$tnc_tnccs = xtrue -o x$imcv = xtrue)
1656 AM_CONDITIONAL(USE_LIBTNCCS, test x$tnc_tnccs = xtrue)
1657 AM_CONDITIONAL(USE_LIBPTTLS, test x$tnc_tnccs = xtrue)
1658 AM_CONDITIONAL(USE_LIBTPMTSS, test x$tss_trousers = xtrue -o x$tss_tss2 = xtrue -o x$aikgen = xtrue -o x$aikpub2 = xtrue -o x$imcv = xtrue)
1659 AM_CONDITIONAL(USE_FILE_CONFIG, test x$stroke = xtrue)
1660 AM_CONDITIONAL(USE_IPSEC_SCRIPT, test x$stroke = xtrue -o x$scepclient = xtrue -o x$conftest = xtrue)
1661 AM_CONDITIONAL(USE_LIBCAP, test x$capabilities = xlibcap)
1662 AM_CONDITIONAL(USE_VSTR, test x$printf_hooks = xvstr)
1663 AM_CONDITIONAL(USE_BUILTIN_PRINTF, test x$printf_hooks = xbuiltin)
1664 AM_CONDITIONAL(USE_SIMAKA, test x$simaka = xtrue)
1665 AM_CONDITIONAL(USE_TLS, test x$tls = xtrue)
1666 AM_CONDITIONAL(USE_RADIUS, test x$radius = xtrue)
1667 AM_CONDITIONAL(USE_IMCV, test x$imcv = xtrue)
1668 AM_CONDITIONAL(USE_TROUSERS, test x$tss_trousers = xtrue)
1669 AM_CONDITIONAL(USE_TSS2, test x$tss_tss2 = xtrue)
1670 AM_CONDITIONAL(MONOLITHIC, test x$monolithic = xtrue)
1671 AM_CONDITIONAL(USE_SILENT_RULES, test x$enable_silent_rules = xyes)
1672 AM_CONDITIONAL(COVERAGE, test x$coverage = xtrue)
1673 AM_CONDITIONAL(USE_DBGHELP, test x$dbghelp_backtraces = xtrue)
1674 AM_CONDITIONAL(USE_TKM, test x$tkm = xtrue)
1675 AM_CONDITIONAL(USE_CMD, test x$cmd = xtrue)
1676 AM_CONDITIONAL(USE_AIKGEN, test x$aikgen = xtrue)
1677 AM_CONDITIONAL(USE_AIKPUB2, test x$aikpub2 = xtrue)
1678 AM_CONDITIONAL(USE_SWANCTL, test x$swanctl = xtrue)
1679 AM_CONDITIONAL(USE_SVC, test x$svc = xtrue)
1680 AM_CONDITIONAL(USE_SYSTEMD, test x$systemd = xtrue)
1681 AM_CONDITIONAL(USE_LEGACY_SYSTEMD, test -n "$systemdsystemunitdir" -a "x$systemdsystemunitdir" != xno)
1682 AM_CONDITIONAL(USE_RUBY_GEMS, test x$ruby_gems = xtrue)
1683 AM_CONDITIONAL(USE_PYTHON_EGGS, test x$python_eggs = xtrue)
1684 AM_CONDITIONAL(USE_PERL_CPAN, test x$perl_cpan = xtrue)
1685 AM_CONDITIONAL(USE_PY_TEST, test "x$PY_TEST" != x)
1686
1687 # ========================
1688 #  set global definitions
1689 # ========================
1690
1691 if test x$mediation = xtrue; then
1692         AC_DEFINE([ME], [], [mediation extension support])
1693 fi
1694 if test x$capabilities = xlibcap -o x$capabilities = xnative; then
1695         AC_DEFINE([CAPABILITIES], [], [capability dropping support])
1696 fi
1697 if test x$log_thread_ids = xtrue; then
1698         AC_DEFINE([USE_THREAD_IDS], [], [use thread ID for thread identification, if available])
1699 fi
1700 if test x$monolithic = xtrue; then
1701         AC_DEFINE([MONOLITHIC], [], [monolithic build embedding plugins])
1702 fi
1703 if test x$ikev1 = xtrue; then
1704         AC_DEFINE([USE_IKEV1], [], [support for IKEv1 protocol])
1705 fi
1706 if test x$ikev2 = xtrue; then
1707         AC_DEFINE([USE_IKEV2], [], [support for IKEv2 protocol])
1708 fi
1709
1710 # ====================================================
1711 #  options for enabled modules (see conf/Makefile.am)
1712 # ====================================================
1713
1714 strongswan_options=
1715
1716 AM_COND_IF([USE_AIKGEN], [strongswan_options=${strongswan_options}" aikgen"])
1717 AM_COND_IF([USE_AIKPUB2], [strongswan_options=${strongswan_options}" aikpub2"])
1718 AM_COND_IF([USE_ATTR_SQL], [strongswan_options=${strongswan_options}" pool"])
1719 AM_COND_IF([USE_CHARON], [strongswan_options=${strongswan_options}" charon charon-logging"])
1720 AM_COND_IF([USE_FILE_CONFIG], [strongswan_options=${strongswan_options}" starter"])
1721 AM_COND_IF([USE_IMV_ATTESTATION], [strongswan_options=${strongswan_options}" attest"])
1722 AM_COND_IF([USE_IMCV], [strongswan_options=${strongswan_options}" imcv"])
1723 AM_COND_IF([USE_IMV_OS], [strongswan_options=${strongswan_options}" pacman"])
1724 AM_COND_IF([USE_LIBTNCCS], [strongswan_options=${strongswan_options}" tnc"])
1725 AM_COND_IF([USE_MANAGER], [strongswan_options=${strongswan_options}" manager"])
1726 AM_COND_IF([USE_MEDSRV], [strongswan_options=${strongswan_options}" medsrv"])
1727 AM_COND_IF([USE_SCEPCLIENT], [strongswan_options=${strongswan_options}" scepclient"])
1728 AM_COND_IF([USE_PKI], [strongswan_options=${strongswan_options}" pki"])
1729 AM_COND_IF([USE_SWANCTL], [strongswan_options=${strongswan_options}" swanctl"])
1730
1731 AC_SUBST(strongswan_options)
1732
1733 # =================
1734 #  build Makefiles
1735 # =================
1736
1737 AC_CONFIG_FILES([
1738         Makefile
1739         conf/Makefile
1740         man/Makefile
1741         init/Makefile
1742         init/systemd/Makefile
1743         init/systemd-swanctl/Makefile
1744         src/Makefile
1745         src/include/Makefile
1746         src/libstrongswan/Makefile
1747         src/libstrongswan/math/libnttfft/Makefile
1748         src/libstrongswan/math/libnttfft/tests/Makefile
1749         src/libstrongswan/plugins/aes/Makefile
1750         src/libstrongswan/plugins/cmac/Makefile
1751         src/libstrongswan/plugins/des/Makefile
1752         src/libstrongswan/plugins/blowfish/Makefile
1753         src/libstrongswan/plugins/rc2/Makefile
1754         src/libstrongswan/plugins/md4/Makefile
1755         src/libstrongswan/plugins/md5/Makefile
1756         src/libstrongswan/plugins/sha1/Makefile
1757         src/libstrongswan/plugins/sha2/Makefile
1758         src/libstrongswan/plugins/sha3/Makefile
1759         src/libstrongswan/plugins/mgf1/Makefile
1760         src/libstrongswan/plugins/fips_prf/Makefile
1761         src/libstrongswan/plugins/gmp/Makefile
1762         src/libstrongswan/plugins/curve25519/Makefile
1763         src/libstrongswan/plugins/rdrand/Makefile
1764         src/libstrongswan/plugins/aesni/Makefile
1765         src/libstrongswan/plugins/random/Makefile
1766         src/libstrongswan/plugins/nonce/Makefile
1767         src/libstrongswan/plugins/hmac/Makefile
1768         src/libstrongswan/plugins/xcbc/Makefile
1769         src/libstrongswan/plugins/x509/Makefile
1770         src/libstrongswan/plugins/revocation/Makefile
1771         src/libstrongswan/plugins/constraints/Makefile
1772         src/libstrongswan/plugins/acert/Makefile
1773         src/libstrongswan/plugins/pubkey/Makefile
1774         src/libstrongswan/plugins/pkcs1/Makefile
1775         src/libstrongswan/plugins/pkcs7/Makefile
1776         src/libstrongswan/plugins/pkcs8/Makefile
1777         src/libstrongswan/plugins/pkcs12/Makefile
1778         src/libstrongswan/plugins/pgp/Makefile
1779         src/libstrongswan/plugins/dnskey/Makefile
1780         src/libstrongswan/plugins/sshkey/Makefile
1781         src/libstrongswan/plugins/pem/Makefile
1782         src/libstrongswan/plugins/curl/Makefile
1783         src/libstrongswan/plugins/files/Makefile
1784         src/libstrongswan/plugins/winhttp/Makefile
1785         src/libstrongswan/plugins/unbound/Makefile
1786         src/libstrongswan/plugins/soup/Makefile
1787         src/libstrongswan/plugins/ldap/Makefile
1788         src/libstrongswan/plugins/mysql/Makefile
1789         src/libstrongswan/plugins/sqlite/Makefile
1790         src/libstrongswan/plugins/padlock/Makefile
1791         src/libstrongswan/plugins/openssl/Makefile
1792         src/libstrongswan/plugins/gcrypt/Makefile
1793         src/libstrongswan/plugins/agent/Makefile
1794         src/libstrongswan/plugins/keychain/Makefile
1795         src/libstrongswan/plugins/pkcs11/Makefile
1796         src/libstrongswan/plugins/chapoly/Makefile
1797         src/libstrongswan/plugins/ctr/Makefile
1798         src/libstrongswan/plugins/ccm/Makefile
1799         src/libstrongswan/plugins/gcm/Makefile
1800         src/libstrongswan/plugins/af_alg/Makefile
1801         src/libstrongswan/plugins/ntru/Makefile
1802         src/libstrongswan/plugins/bliss/Makefile
1803         src/libstrongswan/plugins/bliss/tests/Makefile
1804         src/libstrongswan/plugins/newhope/Makefile
1805         src/libstrongswan/plugins/newhope/tests/Makefile
1806         src/libstrongswan/plugins/test_vectors/Makefile
1807         src/libstrongswan/tests/Makefile
1808         src/libipsec/Makefile
1809         src/libipsec/tests/Makefile
1810         src/libsimaka/Makefile
1811         src/libtls/Makefile
1812         src/libtls/tests/Makefile
1813         src/libradius/Makefile
1814         src/libtncif/Makefile
1815         src/libtnccs/Makefile
1816         src/libtnccs/plugins/tnc_tnccs/Makefile
1817         src/libtnccs/plugins/tnc_imc/Makefile
1818         src/libtnccs/plugins/tnc_imv/Makefile
1819         src/libtnccs/plugins/tnccs_11/Makefile
1820         src/libtnccs/plugins/tnccs_20/Makefile
1821         src/libtnccs/plugins/tnccs_dynamic/Makefile
1822         src/libpttls/Makefile
1823         src/libimcv/Makefile
1824         src/libimcv/plugins/imc_test/Makefile
1825         src/libimcv/plugins/imv_test/Makefile
1826         src/libimcv/plugins/imc_scanner/Makefile
1827         src/libimcv/plugins/imv_scanner/Makefile
1828         src/libimcv/plugins/imc_os/Makefile
1829         src/libimcv/plugins/imv_os/Makefile
1830         src/libimcv/plugins/imc_attestation/Makefile
1831         src/libimcv/plugins/imv_attestation/Makefile
1832         src/libimcv/plugins/imc_swid/Makefile
1833         src/libimcv/plugins/imv_swid/Makefile
1834         src/libimcv/plugins/imc_hcd/Makefile
1835         src/libimcv/plugins/imv_hcd/Makefile
1836         src/charon/Makefile
1837         src/charon-nm/Makefile
1838         src/charon-tkm/Makefile
1839         src/charon-cmd/Makefile
1840         src/charon-svc/Makefile
1841         src/charon-systemd/Makefile
1842         src/libcharon/Makefile
1843         src/libcharon/plugins/eap_aka/Makefile
1844         src/libcharon/plugins/eap_aka_3gpp2/Makefile
1845         src/libcharon/plugins/eap_dynamic/Makefile
1846         src/libcharon/plugins/eap_identity/Makefile
1847         src/libcharon/plugins/eap_md5/Makefile
1848         src/libcharon/plugins/eap_gtc/Makefile
1849         src/libcharon/plugins/eap_sim/Makefile
1850         src/libcharon/plugins/eap_sim_file/Makefile
1851         src/libcharon/plugins/eap_sim_pcsc/Makefile
1852         src/libcharon/plugins/eap_simaka_sql/Makefile
1853         src/libcharon/plugins/eap_simaka_pseudonym/Makefile
1854         src/libcharon/plugins/eap_simaka_reauth/Makefile
1855         src/libcharon/plugins/eap_mschapv2/Makefile
1856         src/libcharon/plugins/eap_tls/Makefile
1857         src/libcharon/plugins/eap_ttls/Makefile
1858         src/libcharon/plugins/eap_peap/Makefile
1859         src/libcharon/plugins/eap_tnc/Makefile
1860         src/libcharon/plugins/eap_radius/Makefile
1861         src/libcharon/plugins/xauth_generic/Makefile
1862         src/libcharon/plugins/xauth_eap/Makefile
1863         src/libcharon/plugins/xauth_pam/Makefile
1864         src/libcharon/plugins/xauth_noauth/Makefile
1865         src/libcharon/plugins/tnc_ifmap/Makefile
1866         src/libcharon/plugins/tnc_pdp/Makefile
1867         src/libcharon/plugins/socket_default/Makefile
1868         src/libcharon/plugins/socket_dynamic/Makefile
1869         src/libcharon/plugins/socket_win/Makefile
1870         src/libcharon/plugins/bypass_lan/Makefile
1871         src/libcharon/plugins/connmark/Makefile
1872         src/libcharon/plugins/forecast/Makefile
1873         src/libcharon/plugins/farp/Makefile
1874         src/libcharon/plugins/smp/Makefile
1875         src/libcharon/plugins/sql/Makefile
1876         src/libcharon/plugins/dnscert/Makefile
1877         src/libcharon/plugins/ipseckey/Makefile
1878         src/libcharon/plugins/medsrv/Makefile
1879         src/libcharon/plugins/medcli/Makefile
1880         src/libcharon/plugins/addrblock/Makefile
1881         src/libcharon/plugins/unity/Makefile
1882         src/libcharon/plugins/uci/Makefile
1883         src/libcharon/plugins/ha/Makefile
1884         src/libcharon/plugins/kernel_netlink/Makefile
1885         src/libcharon/plugins/kernel_pfkey/Makefile
1886         src/libcharon/plugins/kernel_pfroute/Makefile
1887         src/libcharon/plugins/kernel_libipsec/Makefile
1888         src/libcharon/plugins/kernel_wfp/Makefile
1889         src/libcharon/plugins/kernel_iph/Makefile
1890         src/libcharon/plugins/whitelist/Makefile
1891         src/libcharon/plugins/ext_auth/Makefile
1892         src/libcharon/plugins/lookip/Makefile
1893         src/libcharon/plugins/error_notify/Makefile
1894         src/libcharon/plugins/certexpire/Makefile
1895         src/libcharon/plugins/systime_fix/Makefile
1896         src/libcharon/plugins/led/Makefile
1897         src/libcharon/plugins/duplicheck/Makefile
1898         src/libcharon/plugins/coupling/Makefile
1899         src/libcharon/plugins/radattr/Makefile
1900         src/libcharon/plugins/osx_attr/Makefile
1901         src/libcharon/plugins/p_cscf/Makefile
1902         src/libcharon/plugins/android_dns/Makefile
1903         src/libcharon/plugins/android_log/Makefile
1904         src/libcharon/plugins/stroke/Makefile
1905         src/libcharon/plugins/vici/Makefile
1906         src/libcharon/plugins/vici/ruby/Makefile
1907         src/libcharon/plugins/vici/perl/Makefile
1908         src/libcharon/plugins/vici/python/Makefile
1909         src/libcharon/plugins/updown/Makefile
1910         src/libcharon/plugins/dhcp/Makefile
1911         src/libcharon/plugins/load_tester/Makefile
1912         src/libcharon/plugins/resolve/Makefile
1913         src/libcharon/plugins/attr/Makefile
1914         src/libcharon/plugins/attr_sql/Makefile
1915         src/libcharon/tests/Makefile
1916         src/libtpmtss/Makefile
1917         src/stroke/Makefile
1918         src/ipsec/Makefile
1919         src/starter/Makefile
1920         src/starter/tests/Makefile
1921         src/_updown/Makefile
1922         src/_copyright/Makefile
1923         src/scepclient/Makefile
1924         src/aikgen/Makefile
1925         src/aikpub2/Makefile
1926         src/pki/Makefile
1927         src/pki/man/Makefile
1928         src/pool/Makefile
1929         src/dumm/Makefile
1930         src/dumm/ext/extconf.rb
1931         src/libfast/Makefile
1932         src/manager/Makefile
1933         src/medsrv/Makefile
1934         src/checksum/Makefile
1935         src/conftest/Makefile
1936         src/pt-tls-client/Makefile
1937         src/swanctl/Makefile
1938         scripts/Makefile
1939         testing/Makefile
1940 ])
1941
1942 # =================
1943 #  build man pages
1944 # =================
1945
1946 AC_CONFIG_FILES([
1947         conf/strongswan.conf.5.head
1948         conf/strongswan.conf.5.tail
1949         man/ipsec.conf.5
1950         man/ipsec.secrets.5
1951         src/charon-cmd/charon-cmd.8
1952         src/pki/man/pki.1
1953         src/pki/man/pki---acert.1
1954         src/pki/man/pki---dn.1
1955         src/pki/man/pki---gen.1
1956         src/pki/man/pki---issue.1
1957         src/pki/man/pki---keyid.1
1958         src/pki/man/pki---pkcs12.1
1959         src/pki/man/pki---pkcs7.1
1960         src/pki/man/pki---print.1
1961         src/pki/man/pki---pub.1
1962         src/pki/man/pki---req.1
1963         src/pki/man/pki---self.1
1964         src/pki/man/pki---signcrl.1
1965         src/pki/man/pki---verify.1
1966         src/swanctl/swanctl.8
1967         src/swanctl/swanctl.conf.5.head
1968         src/swanctl/swanctl.conf.5.tail
1969 ])
1970
1971 AC_OUTPUT
1972
1973 # ========================
1974 #  report enabled plugins
1975 # ========================
1976
1977 AC_MSG_RESULT([])
1978 AC_MSG_RESULT([ strongSwan will be built with the following plugins])
1979 AC_MSG_RESULT([-----------------------------------------------------])
1980
1981 AC_MSG_RESULT([libstrongswan:$s_plugins])
1982 AC_MSG_RESULT([libcharon:    $c_plugins])
1983 AC_MSG_RESULT([libtnccs:     $t_plugins])
1984 AC_MSG_RESULT([])