Merged libpts into libimcv
[strongswan.git] / configure.ac
1 #
2 # Copyright (C) 2007-2014 Tobias Brunner
3 # Copyright (C) 2006-2013 Andreas Steffen
4 # Copyright (C) 2006-2013 Martin Willi
5 # Hochschule fuer Technik Rapperswil
6 #
7 # This program is free software; you can redistribute it and/or modify it
8 # under the terms of the GNU General Public License as published by the
9 # Free Software Foundation; either version 2 of the License, or (at your
10 # option) any later version.  See <http://www.fsf.org/copyleft/gpl.txt>.
11 #
12 # This program is distributed in the hope that it will be useful, but
13 # WITHOUT ANY WARRANTY; without even the implied warranty of MERCHANTABILITY
14 # or FITNESS FOR A PARTICULAR PURPOSE.  See the GNU General Public License
15 # for more details.
16 #
17
18 # ============================
19 #  initialize & set some vars
20 # ============================
21
22 AC_INIT([strongSwan],[5.2.1dr1])
23 AM_INIT_AUTOMAKE(m4_esyscmd([
24         echo tar-ustar
25         echo subdir-objects
26         case `automake --version | head -n 1` in
27                 *" 1.9"*);;
28                 *" 1.10"*);;
29                 *" 1.11"*);;
30                 # don't use parallel test harness in 1.12 and up
31                 *) echo serial-tests;;
32         esac
33 ]))
34 m4_ifdef([AM_SILENT_RULES], [AM_SILENT_RULES])
35 AC_CONFIG_MACRO_DIR([m4/config])
36 AC_CONFIG_HEADERS([config.h])
37 AC_DEFINE([CONFIG_H_INCLUDED], [], [defined if config.h included])
38 PKG_PROG_PKG_CONFIG
39
40 m4_include(m4/macros/split-package-version.m4)
41 SPLIT_PACKAGE_VERSION
42
43 # =================================
44 #  check --enable-xxx & --with-xxx
45 # =================================
46
47 m4_include(m4/macros/with.m4)
48
49 ARG_WITH_SUBST([random-device],      [/dev/random], [set the device to read real random data from])
50 ARG_WITH_SUBST([urandom-device],     [/dev/urandom], [set the device to read pseudo random data from])
51 ARG_WITH_SUBST([strongswan-conf],    [${sysconfdir}/strongswan.conf], [set the strongswan.conf file location])
52 ARG_WITH_SUBST([resolv-conf],        [${sysconfdir}/resolv.conf], [set the file to use in DNS handler plugin])
53 ARG_WITH_SUBST([piddir],             [/var/run], [set path for PID and UNIX socket files])
54 ARG_WITH_SUBST([ipsecdir],           [${libexecdir%/}/ipsec], [set installation path for ipsec tools])
55 ARG_WITH_SUBST([ipseclibdir],        [${libdir%/}/ipsec], [set installation path for ipsec libraries])
56 ARG_WITH_SUBST([plugindir],          [${ipseclibdir%/}/plugins], [set the installation path of plugins])
57 ARG_WITH_SUBST([imcvdir],            [${ipseclibdir%/}/imcvs], [set the installation path of IMC and IMV dynamic librariers])
58 ARG_WITH_SUBST([nm-ca-dir],          [/usr/share/ca-certificates], [directory the NM backend uses to look up trusted root certificates])
59 ARG_WITH_SUBST([swanctldir],         [${sysconfdir}/swanctl], [base directory for swanctl configuration files and credentials])
60 ARG_WITH_SUBST([linux-headers],      [\${top_srcdir}/src/include], [set directory of linux header files to use])
61 ARG_WITH_SUBST([routing-table],      [220], [set routing table to use for IPsec routes])
62 ARG_WITH_SUBST([routing-table-prio], [220], [set priority for IPsec routing table])
63 ARG_WITH_SUBST([ipsec-script],       [ipsec], [change the name of the ipsec script])
64 ARG_WITH_SUBST([fips-mode],          [0], [set openssl FIPS mode: disabled(0), enabled(1), Suite B enabled(2)])
65
66 ARG_WITH_SET([tss],                  [no], [set implementation of the Trusted Computing Group's Software Stack (TSS). Currently the only supported value is "trousers"])
67 ARG_WITH_SET([capabilities],         [no], [set capability dropping library. Currently supported values are "libcap" and "native"])
68 ARG_WITH_SET([mpz_powm_sec],         [yes], [use the more side-channel resistant mpz_powm_sec in libgmp, if available])
69 ARG_WITH_SET([dev-headers],          [no], [install strongSwan development headers to directory.])
70 ARG_WITH_SET([printf-hooks],         [auto], [force the use of a specific printf hook implementation (auto, builtin, glibc, vstr).])
71
72 if test -n "$PKG_CONFIG"; then
73         systemdsystemunitdir_default=$($PKG_CONFIG --variable=systemdsystemunitdir systemd)
74 fi
75 ARG_WITH_SET([systemdsystemunitdir], [$systemdsystemunitdir_default], [directory for systemd service files])
76 AC_SUBST(systemdsystemunitdir)
77
78 AC_ARG_WITH(
79         [user],
80         AS_HELP_STRING([--with-user=user],[change user of the daemons to "user" after startup (default is "root").]),
81         [AC_DEFINE_UNQUOTED([IPSEC_USER], "$withval", [username to run daemon with])
82          AC_SUBST(ipsecuser, "$withval")],
83         [AC_SUBST(ipsecuser, "root")]
84 )
85
86 AC_ARG_WITH(
87         [group],
88         AS_HELP_STRING([--with-group=group],[change group of the daemons to "group" after startup (default is "root").]),
89         [AC_DEFINE_UNQUOTED(IPSEC_GROUP, "$withval", [groupname to run daemon with])
90          AC_SUBST(ipsecgroup, "$withval")],
91         [AC_SUBST(ipsecgroup, "root")]
92 )
93
94 AC_ARG_WITH(
95         [charon-udp-port],
96         AS_HELP_STRING([--with-charon-udp-port=port],[UDP port used by charon locally (default 500). Set to 0 to allocate randomly.]),
97         [AC_DEFINE_UNQUOTED(CHARON_UDP_PORT, [$withval], [UDP port used by charon locally])
98          AC_SUBST(charon_udp_port, [$withval])],
99         [AC_SUBST(charon_udp_port, 500)]
100 )
101
102 AC_ARG_WITH(
103         [charon-natt-port],
104         AS_HELP_STRING([--with-charon-natt-port=port],[UDP port used by charon locally in case a NAT is detected (must be different from charon-udp-port, default 4500). Set to 0 to allocate randomly.]),
105         [AC_DEFINE_UNQUOTED(CHARON_NATT_PORT, [$withval], [UDP post used by charon locally in case a NAT is detected])
106          AC_SUBST(charon_natt_port, [$withval])],
107         [AC_SUBST(charon_natt_port, 4500)]
108 )
109
110 AC_MSG_CHECKING([configured UDP ports ($charon_udp_port, $charon_natt_port)])
111 if test x$charon_udp_port != x0 -a x$charon_udp_port = x$charon_natt_port; then
112         AC_MSG_ERROR(the ports have to be different)
113 else
114         AC_MSG_RESULT(ok)
115 fi
116
117 # convert script name to uppercase
118 AC_SUBST(ipsec_script_upper, [`echo -n "$ipsec_script" | tr a-z A-Z`])
119
120 m4_include(m4/macros/enable-disable.m4)
121
122 # crypto plugins
123 ARG_DISBL_SET([aes],            [disable AES software implementation plugin.])
124 ARG_ENABL_SET([af-alg],         [enable AF_ALG crypto interface to Linux Crypto API.])
125 ARG_ENABL_SET([blowfish],       [enable Blowfish software implementation plugin.])
126 ARG_ENABL_SET([ccm],            [enables the CCM AEAD wrapper crypto plugin.])
127 ARG_DISBL_SET([cmac],           [disable CMAC crypto implementation plugin.])
128 ARG_ENABL_SET([ctr],            [enables the Counter Mode wrapper crypto plugin.])
129 ARG_DISBL_SET([des],            [disable DES/3DES software implementation plugin.])
130 ARG_DISBL_SET([fips-prf],       [disable FIPS PRF software implementation plugin.])
131 ARG_ENABL_SET([gcm],            [enables the GCM AEAD wrapper crypto plugin.])
132 ARG_ENABL_SET([gcrypt],         [enables the libgcrypt plugin.])
133 ARG_DISBL_SET([gmp],            [disable GNU MP (libgmp) based crypto implementation plugin.])
134 ARG_DISBL_SET([hmac],           [disable HMAC crypto implementation plugin.])
135 ARG_ENABL_SET([md4],            [enable MD4 software implementation plugin.])
136 ARG_DISBL_SET([md5],            [disable MD5 software implementation plugin.])
137 ARG_DISBL_SET([nonce],          [disable nonce generation plugin.])
138 ARG_ENABL_SET([ntru],           [enables the NTRU crypto plugin.])
139 ARG_ENABL_SET([openssl],        [enables the OpenSSL crypto plugin.])
140 ARG_ENABL_SET([padlock],        [enables VIA Padlock crypto plugin.])
141 ARG_DISBL_SET([random],         [disable RNG implementation on top of /dev/(u)random.])
142 ARG_DISBL_SET([rc2],            [disable RC2 software implementation plugin.])
143 ARG_ENABL_SET([rdrand],         [enable Intel RDRAND random generator plugin.])
144 ARG_DISBL_SET([sha1],           [disable SHA1 software implementation plugin.])
145 ARG_DISBL_SET([sha2],           [disable SHA256/SHA384/SHA512 software implementation plugin.])
146 ARG_DISBL_SET([xcbc],           [disable xcbc crypto implementation plugin.])
147 # encoding/decoding plugins
148 ARG_DISBL_SET([dnskey],         [disable DNS RR key decoding plugin.])
149 ARG_DISBL_SET([pem],            [disable PEM decoding plugin.])
150 ARG_DISBL_SET([pgp],            [disable PGP key decoding plugin.])
151 ARG_DISBL_SET([pkcs1],          [disable PKCS1 key decoding plugin.])
152 ARG_DISBL_SET([pkcs7],          [disable PKCS7 container support plugin.])
153 ARG_DISBL_SET([pkcs8],          [disable PKCS8 private key decoding plugin.])
154 ARG_DISBL_SET([pkcs12],         [disable PKCS12 container support plugin.])
155 ARG_DISBL_SET([pubkey],         [disable RAW public key support plugin.])
156 ARG_DISBL_SET([sshkey],         [disable SSH key decoding plugin.])
157 ARG_DISBL_SET([x509],           [disable X509 certificate implementation plugin.])
158 # fetcher/resolver plugins
159 ARG_ENABL_SET([curl],           [enable CURL fetcher plugin to fetch files via libcurl. Requires libcurl.])
160 ARG_ENABL_SET([ldap],           [enable LDAP fetching plugin to fetch files via libldap. Requires openLDAP.])
161 ARG_ENABL_SET([soup],           [enable soup fetcher plugin to fetch from HTTP via libsoup. Requires libsoup.])
162 ARG_ENABL_SET([unbound],        [enable UNBOUND resolver plugin to perform DNS queries via libunbound. Requires libldns and libunbound.])
163 ARG_ENABL_SET([winhttp],        [enable WinHTTP based HTTP/HTTPS fetching plugin.])
164 # database plugins
165 ARG_ENABL_SET([mysql],          [enable MySQL database support. Requires libmysqlclient_r.])
166 ARG_ENABL_SET([sqlite],         [enable SQLite database support. Requires libsqlite3.])
167 # authentication/credential plugins
168 ARG_ENABL_SET([addrblock],      [enables RFC 3779 address block constraint support.])
169 ARG_ENABL_SET([acert],          [enable X509 attribute certificate checking plugin.])
170 ARG_ENABL_SET([agent],          [enables the ssh-agent signing plugin.])
171 ARG_DISBL_SET([constraints],    [disable advanced X509 constraint checking plugin.])
172 ARG_ENABL_SET([coupling],       [enable IKEv2 plugin to couple peer certificates permanently to authentication.])
173 ARG_ENABL_SET([dnscert],        [enable DNSCERT authentication plugin.])
174 ARG_ENABL_SET([eap-sim],        [enable SIM authentication module for EAP.])
175 ARG_ENABL_SET([eap-sim-file],   [enable EAP-SIM backend based on a triplet file.])
176 ARG_ENABL_SET([eap-sim-pcsc],   [enable EAP-SIM backend based on a smartcard reader. Requires libpcsclite.])
177 ARG_ENABL_SET([eap-aka],        [enable EAP AKA authentication module.])
178 ARG_ENABL_SET([eap-aka-3gpp2],  [enable EAP AKA backend implementing 3GPP2 algorithms in software. Requires libgmp.])
179 ARG_ENABL_SET([eap-simaka-sql], [enable EAP-SIM/AKA backend based on a triplet/quintuplet SQL database.])
180 ARG_ENABL_SET([eap-simaka-pseudonym], [enable EAP-SIM/AKA pseudonym storage plugin.])
181 ARG_ENABL_SET([eap-simaka-reauth],    [enable EAP-SIM/AKA reauthentication data storage plugin.])
182 ARG_ENABL_SET([eap-identity],   [enable EAP module providing EAP-Identity helper.])
183 ARG_ENABL_SET([eap-md5],        [enable EAP MD5 (CHAP) authentication module.])
184 ARG_ENABL_SET([eap-gtc],        [enable EAP GTC authentication module.])
185 ARG_ENABL_SET([eap-mschapv2],   [enable EAP MS-CHAPv2 authentication module.])
186 ARG_ENABL_SET([eap-tls],        [enable EAP TLS authentication module.])
187 ARG_ENABL_SET([eap-ttls],       [enable EAP TTLS authentication module.])
188 ARG_ENABL_SET([eap-peap],       [enable EAP PEAP authentication module.])
189 ARG_ENABL_SET([eap-tnc],        [enable EAP TNC trusted network connect module.])
190 ARG_ENABL_SET([eap-dynamic],    [enable dynamic EAP proxy module.])
191 ARG_ENABL_SET([eap-radius],     [enable RADIUS proxy authentication module.])
192 ARG_ENABL_SET([ipseckey],       [enable IPSECKEY authentication plugin.])
193 ARG_ENABL_SET([keychain],       [enables OS X Keychain Services credential set.])
194 ARG_ENABL_SET([pkcs11],         [enables the PKCS11 token support plugin.])
195 ARG_DISBL_SET([revocation],     [disable X509 CRL/OCSP revocation check plugin.])
196 ARG_ENABL_SET([whitelist],      [enable peer identity whitelisting plugin.])
197 ARG_DISBL_SET([xauth-generic],  [disable generic XAuth backend.])
198 ARG_ENABL_SET([xauth-eap],      [enable XAuth backend using EAP methods to verify passwords.])
199 ARG_ENABL_SET([xauth-pam],      [enable XAuth backend using PAM to verify passwords.])
200 ARG_ENABL_SET([xauth-noauth],   [enable XAuth pseudo-backend that does not actually verify or even request any credentials.])
201 # kernel interfaces / sockets
202 ARG_DISBL_SET([kernel-netlink], [disable the netlink kernel interface.])
203 ARG_ENABL_SET([kernel-pfkey],   [enable the PF_KEY kernel interface.])
204 ARG_ENABL_SET([kernel-pfroute], [enable the PF_ROUTE kernel interface.])
205 ARG_ENABL_SET([kernel-iph],     [enable the Windows IP Helper based networking backend.])
206 ARG_ENABL_SET([kernel-libipsec],[enable the libipsec kernel interface.])
207 ARG_ENABL_SET([kernel-wfp],     [enable the Windows Filtering Platform IPsec backend.])
208 ARG_DISBL_SET([socket-default], [disable default socket implementation for charon.])
209 ARG_ENABL_SET([socket-dynamic], [enable dynamic socket implementation for charon])
210 ARG_ENABL_SET([socket-win],     [enable Winsock2 based socket implementation for charon])
211 # configuration/control plugins
212 ARG_DISBL_SET([stroke],         [disable charons stroke configuration backend.])
213 ARG_ENABL_SET([smp],            [enable SMP configuration and control interface. Requires libxml.])
214 ARG_ENABL_SET([sql],            [enable SQL database configuration backend.])
215 ARG_ENABL_SET([uci],            [enable OpenWRT UCI configuration plugin.])
216 ARG_ENABL_SET([vici],           [enable strongSwan IKE generic IPC interface plugin.])
217 # attribute provider/consumer plugins
218 ARG_ENABL_SET([android-dns],    [enable Android specific DNS handler.])
219 ARG_DISBL_SET([attr],           [disable strongswan.conf based configuration attribute plugin.])
220 ARG_ENABL_SET([attr-sql],       [enable SQL based configuration attribute plugin.])
221 ARG_ENABL_SET([dhcp],           [enable DHCP based attribute provider plugin.])
222 ARG_ENABL_SET([osx-attr],       [enable OS X SystemConfiguration attribute handler.])
223 ARG_DISBL_SET([resolve],        [disable resolve DNS handler plugin.])
224 ARG_ENABL_SET([unity],          [enables Cisco Unity extension plugin.])
225 # TNC modules/plugins
226 ARG_ENABL_SET([imc-test],       [enable IMC test module.])
227 ARG_ENABL_SET([imv-test],       [enable IMV test module.])
228 ARG_ENABL_SET([imc-scanner],    [enable IMC port scanner module.])
229 ARG_ENABL_SET([imv-scanner],    [enable IMV port scanner module.])
230 ARG_ENABL_SET([imc-os],         [enable IMC operating system module.])
231 ARG_ENABL_SET([imv-os],         [enable IMV operating system module.])
232 ARG_ENABL_SET([imc-attestation],[enable IMC attestation module.])
233 ARG_ENABL_SET([imv-attestation],[enable IMV attestation module.])
234 ARG_ENABL_SET([imc-swid],       [enable IMC swid module.])
235 ARG_ENABL_SET([imv-swid],       [enable IMV swid module.])
236 ARG_ENABL_SET([tnc-ifmap],      [enable TNC IF-MAP module. Requires libxml])
237 ARG_ENABL_SET([tnc-imc],        [enable TNC IMC module.])
238 ARG_ENABL_SET([tnc-imv],        [enable TNC IMV module.])
239 ARG_ENABL_SET([tnc-pdp],        [enable TNC policy decision point module.])
240 ARG_ENABL_SET([tnccs-11],       [enable TNCCS 1.1 protocol module. Requires libxml])
241 ARG_ENABL_SET([tnccs-20],       [enable TNCCS 2.0 protocol module.])
242 ARG_ENABL_SET([tnccs-dynamic],  [enable dynamic TNCCS protocol discovery module.])
243 # misc plugins
244 ARG_ENABL_SET([android-log],    [enable Android specific logger plugin.])
245 ARG_ENABL_SET([certexpire],     [enable CSV export of expiration dates of used certificates.])
246 ARG_ENABL_SET([duplicheck],     [advanced duplicate checking plugin using liveness checks.])
247 ARG_ENABL_SET([error-notify],   [enable error notification plugin.])
248 ARG_ENABL_SET([farp],           [enable ARP faking plugin that responds to ARP requests to peers virtual IP])
249 ARG_ENABL_SET([ha],             [enable high availability cluster plugin.])
250 ARG_ENABL_SET([led],            [enable plugin to control LEDs on IKEv2 activity using the Linux kernel LED subsystem.])
251 ARG_ENABL_SET([load-tester],    [enable load testing plugin for IKEv2 daemon.])
252 ARG_ENABL_SET([lookip],         [enable fast virtual IP lookup and notification plugin.])
253 ARG_ENABL_SET([maemo],          [enable Maemo specific plugin.])
254 ARG_ENABL_SET([radattr],        [enable plugin to inject and process custom RADIUS attributes as IKEv2 client.])
255 ARG_ENABL_SET([systime-fix],    [enable plugin to handle cert lifetimes with invalid system time gracefully.])
256 ARG_ENABL_SET([test-vectors],   [enable plugin providing crypto test vectors.])
257 ARG_ENABL_SET([unit-tester],    [enable unit tests on IKEv2 daemon startup.])
258 ARG_DISBL_SET([updown],         [disable updown firewall script plugin.])
259 # programs/components
260 ARG_ENABL_SET([aikgen],         [enable AIK generator.])
261 ARG_DISBL_SET([charon],         [disable the IKEv1/IKEv2 keying daemon charon.])
262 ARG_ENABL_SET([cmd],            [enable the command line IKE client charon-cmd.])
263 ARG_ENABL_SET([conftest],       [enforce Suite B conformance test framework.])
264 ARG_ENABL_SET([dumm],           [enable the DUMM UML test framework.])
265 ARG_ENABL_SET([fast],           [enable libfast (FastCGI Application Server w/ templates.])
266 ARG_ENABL_SET([libipsec],       [enable user space IPsec implementation.])
267 ARG_ENABL_SET([manager],        [enable web management console (proof of concept).])
268 ARG_ENABL_SET([medcli],         [enable mediation client configuration database plugin.])
269 ARG_ENABL_SET([medsrv],         [enable mediation server web frontend and daemon plugin.])
270 ARG_ENABL_SET([nm],             [enable NetworkManager backend.])
271 ARG_DISBL_SET([pki],            [disable pki certificate utility.])
272 ARG_DISBL_SET([scepclient],     [disable SCEP client tool.])
273 ARG_DISBL_SET([scripts],        [disable additional utilities (found in directory scripts).])
274 ARG_ENABL_SET([svc],            [enable charon Windows service.])
275 ARG_ENABL_SET([systemd],        [enable systemd specific IKE daemon charon-systemd.])
276 ARG_ENABL_SET([swanctl],        [enable swanctl configuration and control tool.])
277 ARG_ENABL_SET([tkm],            [enable Trusted Key Manager support.])
278 # optional features
279 ARG_ENABL_SET([bfd-backtraces], [use binutils libbfd to resolve backtraces for memory leaks and segfaults.])
280 ARG_ENABL_SET([dbghelp-backtraces],[use dbghlp.dll on Windows to create and print backtraces for memory leaks and segfaults.])
281 ARG_DISBL_SET([ikev1],          [disable IKEv1 protocol support in charon.])
282 ARG_DISBL_SET([ikev2],          [disable IKEv2 protocol support in charon.])
283 ARG_ENABL_SET([integrity-test], [enable integrity testing of libstrongswan and plugins.])
284 ARG_DISBL_SET([load-warning],   [disable the charon plugin load option warning in starter.])
285 ARG_ENABL_SET([mediation],      [enable IKEv2 Mediation Extension.])
286 ARG_ENABL_SET([unwind-backtraces],[use libunwind to create backtraces for memory leaks and segfaults.])
287 # compile options
288 ARG_ENABL_SET([coverage],       [enable lcov coverage report generation.])
289 ARG_ENABL_SET([leak-detective], [enable malloc hooks to find memory leaks.])
290 ARG_ENABL_SET([lock-profiler],  [enable lock/mutex profiling code.])
291 ARG_ENABL_SET([monolithic],     [build monolithic version of libstrongswan that includes all enabled plugins. Similarly, the plugins of charon are assembled in libcharon.])
292
293 # ===================================
294 #  option to disable default options
295 # ===================================
296
297 ARG_DISBL_SET([defaults],       [disable all default plugins (they can be enabled with their respective --enable options)])
298
299 if test x$defaults = xfalse; then
300         for option in $enabled_by_default; do
301                 eval test x\${${option}_given} = xtrue && continue
302                 eval $option=false
303         done
304 fi
305
306 # ==============================
307 #  option to enable all options
308 # ==============================
309
310 ARG_ENABL_SET([all],            [enable all plugins and features (they can be disabled with their respective --disable options). Mainly for testing.])
311
312 if test x$all_given = xtrue; then
313         for option in $disabled_by_default; do
314                 eval test x\${${option}_given} = xtrue && continue
315                 eval $option=true
316         done
317 fi
318
319 # ===========================
320 #  set up compiler and flags
321 # ===========================
322
323 if test -z "$CFLAGS"; then
324         CFLAGS="-g -O2 -Wall -Wno-format -Wno-format-security -Wno-pointer-sign"
325 fi
326 AC_PROG_CC
327 AM_PROG_CC_C_O
328
329 AC_LIB_PREFIX
330 AC_C_BIGENDIAN
331
332 # =========================
333 #  check required programs
334 # =========================
335
336 LT_INIT
337 AC_PROG_INSTALL
338 AC_PROG_EGREP
339 AC_PROG_AWK
340 AC_PROG_LEX
341 AC_PROG_YACC
342 AM_PATH_PYTHON(,,[:])
343 AC_PATH_PROG([PERL], [perl], [], [$PATH:/bin:/usr/bin:/usr/local/bin])
344 AC_PATH_PROG([GPERF], [gperf], [], [$PATH:/bin:/usr/bin:/usr/local/bin])
345
346 # because gperf is not needed by end-users we just report it but do not abort on failure
347 AC_MSG_CHECKING([gperf version >= 3.0.0])
348 if test -x "$GPERF"; then
349         if test "`$GPERF --version | $AWK -F' ' '/^GNU gperf/ { print $3 }' | $AWK -F. '{ print $1 }'`" -ge "3"; then
350                 AC_MSG_RESULT([yes])
351         else
352                 AC_MSG_RESULT([no])
353         fi
354 else
355         AC_MSG_RESULT([not found])
356 fi
357
358 # ========================
359 #  dependency calculation
360 # ========================
361
362 if test x$xauth_generic_given = xfalse -a x$ikev1 = xfalse; then
363         xauth_generic=false;
364 fi
365
366 if test x$kernel_libipsec = xtrue; then
367         libipsec=true;
368 fi
369
370 if test x$eap_aka_3gpp2 = xtrue; then
371         gmp=true;
372 fi
373
374 if test x$eap_aka = xtrue; then
375         fips_prf=true;
376         simaka=true;
377 fi
378
379 if test x$eap_sim = xtrue; then
380         fips_prf=true;
381         simaka=true;
382 fi
383
384 if test x$eap_radius = xtrue -o x$radattr = xtrue -o x$tnc_pdp = xtrue; then
385         radius=true;
386 fi
387
388 if test x$tnc_imc = xtrue -o x$tnc_imv = xtrue -o x$tnccs_11 = xtrue -o x$tnccs_11 = xtrue -o x$tnccs_dynamic = xtrue -o x$eap_tnc = xtrue; then
389         tnc_tnccs=true;
390 fi
391
392 if test x$eap_tls = xtrue -o x$eap_ttls = xtrue -o x$eap_peap = xtrue -o x$tnc_tnccs = xtrue; then
393         tls=true;
394 fi
395
396 if test x$imc_test = xtrue -o x$imv_test = xtrue -o x$imc_scanner = xtrue -o x$imv_scanner = xtrue -o x$imc_os = xtrue -o x$imv_os = xtrue -o x$imc_attestation = xtrue -o x$imv_attestation = xtrue -o x$imc_swid = xtrue -o x$imv_swid = xtrue; then
397         imcv=true;
398 fi
399
400 if test x$fips_prf = xtrue; then
401         if test x$openssl = xfalse; then
402                 sha1=true;
403         fi
404 fi
405
406 if test x$swanctl = xtrue; then
407         vici=true
408 fi
409
410 if test x$smp = xtrue -o x$tnccs_11 = xtrue -o x$tnc_ifmap = xtrue; then
411         xml=true
412 fi
413
414 if test x$manager = xtrue; then
415         fast=true
416 fi
417
418 if test x$medsrv = xtrue; then
419         mediation=true
420         fast=true
421 fi
422
423 if test x$medcli = xtrue; then
424         mediation=true
425 fi
426
427 # ===========================================
428 #  check required libraries and header files
429 # ===========================================
430
431 AC_HEADER_STDBOOL
432 AC_FUNC_ALLOCA
433 AC_FUNC_STRERROR_R
434
435 #  libraries needed on some platforms but not on others
436 # ------------------------------------------------------
437 saved_LIBS=$LIBS
438
439 # FreeBSD and Mac OS X have dlopen integrated in libc, Linux needs libdl
440 LIBS=""
441 AC_SEARCH_LIBS(dlopen, dl, [DLLIB=$LIBS])
442 AC_SUBST(DLLIB)
443
444 # glibc's backtrace() can be replicated on FreeBSD with libexecinfo
445 LIBS=""
446 AC_SEARCH_LIBS(backtrace, execinfo, [BTLIB=$LIBS])
447 AC_CHECK_FUNCS(backtrace)
448 AC_SUBST(BTLIB)
449
450 # OpenSolaris needs libsocket and libnsl for socket()
451 LIBS=""
452 AC_SEARCH_LIBS(socket, socket, [SOCKLIB=$LIBS],
453         [AC_CHECK_LIB(nsl, socket, [SOCKLIB="-lsocket -lnsl"], [], [-lsocket])]
454 )
455 AC_SUBST(SOCKLIB)
456
457 # Android has pthread_* functions in bionic (libc), others need libpthread
458 LIBS=""
459 AC_SEARCH_LIBS(pthread_create, pthread, [PTHREADLIB=$LIBS])
460 AC_SUBST(PTHREADLIB)
461
462 LIBS=$saved_LIBS
463 # ------------------------------------------------------
464
465 AC_MSG_CHECKING(for dladdr)
466 AC_COMPILE_IFELSE(
467         [AC_LANG_PROGRAM(
468                 [[#define _GNU_SOURCE
469                   #include <dlfcn.h>]],
470                 [[Dl_info* info = 0;
471                   dladdr(0, info);]])],
472         [AC_MSG_RESULT([yes]); AC_DEFINE([HAVE_DLADDR], [], [have dladdr()])],
473         [AC_MSG_RESULT([no])]
474 )
475
476 # check if pthread_condattr_setclock(CLOCK_MONOTONE) is supported
477 saved_LIBS=$LIBS
478 LIBS=$PTHREADLIB
479 AC_MSG_CHECKING([for pthread_condattr_setclock(CLOCK_MONOTONE)])
480 AC_RUN_IFELSE(
481         [AC_LANG_SOURCE(
482                 [[#include <pthread.h>
483                   int main() { pthread_condattr_t attr;
484                         pthread_condattr_init(&attr);
485                         return pthread_condattr_setclock(&attr, CLOCK_MONOTONIC);}]])],
486         [AC_MSG_RESULT([yes]);
487          AC_DEFINE([HAVE_CONDATTR_CLOCK_MONOTONIC], [],
488                            [pthread_condattr_setclock supports CLOCK_MONOTONIC])],
489         [AC_MSG_RESULT([no])],
490         # Check existence of pthread_condattr_setclock if cross-compiling
491         [AC_MSG_RESULT([unknown]);
492          AC_CHECK_FUNCS(pthread_condattr_setclock,
493                 [AC_DEFINE([HAVE_CONDATTR_CLOCK_MONOTONIC], [],
494                                    [have pthread_condattr_setclock()])]
495         )]
496 )
497 # check if we actually are able to configure attributes on cond vars
498 AC_CHECK_FUNCS(pthread_condattr_init)
499 # instead of pthread_condattr_setclock Android has this function
500 AC_CHECK_FUNCS(pthread_cond_timedwait_monotonic)
501 # check if we can cancel threads
502 AC_CHECK_FUNCS(pthread_cancel)
503 # check if native rwlocks are available
504 AC_CHECK_FUNCS(pthread_rwlock_init)
505 # check if pthread spinlocks are available
506 AC_CHECK_FUNCS(pthread_spin_init)
507 # check if we have POSIX semaphore functions, including timed-wait
508 AC_CHECK_FUNCS(sem_timedwait)
509 LIBS=$saved_LIBS
510
511 AC_CHECK_FUNC(
512         [gettid],
513         [AC_DEFINE([HAVE_GETTID], [], [have gettid()])],
514         [AC_MSG_CHECKING([for SYS_gettid])
515          AC_COMPILE_IFELSE(
516                 [AC_LANG_PROGRAM(
517                         [[#define _GNU_SOURCE
518                           #include <unistd.h>
519                           #include <sys/syscall.h>]],
520                         [[int main() {
521                           return syscall(SYS_gettid);}]])],
522                 [AC_MSG_RESULT([yes]);
523                  AC_DEFINE([HAVE_GETTID], [], [have gettid()])
524                  AC_DEFINE([HAVE_SYS_GETTID], [], [have syscall(SYS_gettid)])],
525                 [AC_MSG_RESULT([no])]
526         )]
527 )
528
529 AC_CHECK_FUNC(
530         [qsort_r],
531         [
532                 AC_DEFINE([HAVE_QSORT_R], [], [have qsort_r()])
533                 # set -Werror so that we get an error for "argument ... has
534                 # incompatible pointer type" warnings
535                 save_CFLAGS="$CFLAGS"
536                 CFLAGS="$CFLAGS -Werror"
537                 AC_MSG_CHECKING([for GNU-style qsort_r])
538                 AC_COMPILE_IFELSE(
539                         [AC_LANG_PROGRAM(
540                                 [[#define _GNU_SOURCE
541                                   #include <stdlib.h>
542                                   int cmp (const void *a, const void *b, void *x) { return 0; }]],
543                                 [[int arr[] = { 0, 1 };
544                                   qsort_r(arr, 2, sizeof(int), cmp, arr);]])],
545                 [AC_MSG_RESULT([yes]);
546                  AC_DEFINE([HAVE_QSORT_R_GNU], [], [have GNU-style qsort_r()])],
547                 [
548                         AC_MSG_RESULT([no]);
549                         AC_MSG_CHECKING([for BSD-style qsort_r])
550                         AC_COMPILE_IFELSE(
551                                 [AC_LANG_PROGRAM(
552                                         [[#include <stdlib.h>
553                                           int cmp (void *x, const void *a, const void *b) { return 0; }]],
554                                         [[int arr[] = { 0, 1 };
555                                           qsort_r(arr, 2, sizeof(int), arr, cmp);]])],
556                         [AC_MSG_RESULT([yes]);
557                          AC_DEFINE([HAVE_QSORT_R_BSD], [], [have BSD-style qsort_r()])],
558                         [AC_MSG_RESULT([no]);
559                          AC_MSG_FAILURE([qsort_r has unknown semantics])])
560                 ])
561                 CFLAGS="$save_CFLAGS"
562         ]
563 )
564
565 AC_CHECK_FUNCS(prctl mallinfo getpass closefrom getpwnam_r getgrnam_r getpwuid_r)
566 AC_CHECK_FUNCS(fmemopen funopen mmap memrchr setlinebuf strptime)
567
568 AC_CHECK_FUNC([syslog], [
569         AC_DEFINE([HAVE_SYSLOG], [], [have syslog(3) and friends])
570         syslog=true
571 ])
572 AM_CONDITIONAL(USE_SYSLOG, [test "x$syslog" = xtrue])
573
574 AC_CHECK_HEADERS(sys/sockio.h glob.h net/if_tun.h)
575 AC_CHECK_HEADERS(net/pfkeyv2.h netipsec/ipsec.h netinet6/ipsec.h linux/udp.h)
576 AC_CHECK_HEADERS([netinet/ip6.h linux/fib_rules.h], [], [],
577 [
578         #include <sys/types.h>
579         #include <netinet/in.h>
580 ])
581
582 AC_CHECK_MEMBERS([struct sockaddr.sa_len], [], [],
583 [
584         #include <sys/types.h>
585         #include <sys/socket.h>
586 ])
587
588 AC_CHECK_MEMBERS([struct sadb_x_policy.sadb_x_policy_priority], [], [],
589 [
590         #include <sys/types.h>
591         #ifdef HAVE_NET_PFKEYV2_H
592         #include <net/pfkeyv2.h>
593         #else
594         #include <stdint.h>
595         #include <linux/pfkeyv2.h>
596         #endif
597 ])
598
599 AC_MSG_CHECKING([for in6addr_any])
600 AC_COMPILE_IFELSE(
601         [AC_LANG_PROGRAM(
602                 [[#include <sys/types.h>
603                   #include <sys/socket.h>
604                   #include <netinet/in.h>]],
605                 [[struct in6_addr in6 __attribute__((unused));
606                   in6 = in6addr_any;]])],
607         [AC_MSG_RESULT([yes]);
608          AC_DEFINE([HAVE_IN6ADDR_ANY], [], [have struct in6_addr in6addr_any])],
609         [AC_MSG_RESULT([no])]
610 )
611
612 AC_MSG_CHECKING([for in6_pktinfo])
613 AC_COMPILE_IFELSE(
614         [AC_LANG_PROGRAM(
615                 [[#define _GNU_SOURCE
616                   #include <sys/types.h>
617                   #include <sys/socket.h>
618                   #include <netinet/in.h>]],
619                 [[struct in6_pktinfo pi;
620                   if (pi.ipi6_ifindex)
621                   {
622                     return 0;
623                   }]])],
624         [AC_MSG_RESULT([yes]);
625          AC_DEFINE([HAVE_IN6_PKTINFO], [], [have struct in6_pktinfo.ipi6_ifindex])],
626         [AC_MSG_RESULT([no])]
627 )
628
629 AC_MSG_CHECKING([for IPSEC_MODE_BEET])
630 AC_COMPILE_IFELSE(
631         [AC_LANG_PROGRAM(
632                 [[#include <sys/types.h>
633                   #ifdef HAVE_NETIPSEC_IPSEC_H
634                   #include <netipsec/ipsec.h>
635                   #elif defined(HAVE_NETINET6_IPSEC_H)
636                   #include <netinet6/ipsec.h>
637                   #else
638                   #include <stdint.h>
639                   #include <linux/ipsec.h>
640                   #endif]],
641                 [[int mode = IPSEC_MODE_BEET;
642                   return mode;]])],
643         [AC_MSG_RESULT([yes]);
644          AC_DEFINE([HAVE_IPSEC_MODE_BEET], [], [have IPSEC_MODE_BEET defined])],
645         [AC_MSG_RESULT([no])]
646 )
647
648 AC_MSG_CHECKING([for IPSEC_DIR_FWD])
649 AC_COMPILE_IFELSE(
650         [AC_LANG_PROGRAM(
651                 [[#include <sys/types.h>
652                   #ifdef HAVE_NETIPSEC_IPSEC_H
653                   #include <netipsec/ipsec.h>
654                   #elif defined(HAVE_NETINET6_IPSEC_H)
655                   #include <netinet6/ipsec.h>
656                   #else
657                   #include <stdint.h>
658                   #include <linux/ipsec.h>
659                   #endif]],
660                 [[int dir = IPSEC_DIR_FWD;
661                   return dir;]])],
662         [AC_MSG_RESULT([yes]);
663          AC_DEFINE([HAVE_IPSEC_DIR_FWD], [], [have IPSEC_DIR_FWD defined])],
664         [AC_MSG_RESULT([no])]
665 )
666
667 AC_MSG_CHECKING([for RTA_TABLE])
668 AC_COMPILE_IFELSE(
669         [AC_LANG_PROGRAM(
670                 [[#include <sys/socket.h>
671                   #include <linux/netlink.h>
672                   #include <linux/rtnetlink.h>]],
673                 [[int rta_type = RTA_TABLE;
674                   return rta_type;]])],
675         [AC_MSG_RESULT([yes]);
676          AC_DEFINE([HAVE_RTA_TABLE], [], [have netlink RTA_TABLE defined])],
677         [AC_MSG_RESULT([no])]
678 )
679
680 AC_MSG_CHECKING([for GCC __sync operations])
681 AC_RUN_IFELSE([AC_LANG_SOURCE(
682         [[
683                         int main() {
684                         int ref = 1;
685                         __sync_fetch_and_add (&ref, 1);
686                         __sync_sub_and_fetch (&ref, 1);
687                         __sync_val_compare_and_swap(&ref, 1, 0);
688                         return ref;
689                 }
690         ]])],
691         [AC_MSG_RESULT([yes]);
692          AC_DEFINE([HAVE_GCC_SYNC_OPERATIONS], [],
693                    [have GCC __sync_* operations])],
694         [AC_MSG_RESULT([no])],
695         [AC_MSG_RESULT([no])]
696 )
697
698 case "$printf_hooks" in
699 auto|builtin|glibc|vstr)
700         ;;
701 *)
702         AC_MSG_NOTICE([invalid printf hook implementation, defaulting to 'auto'])
703         printf_hooks=auto
704         ;;
705 esac
706
707 if test x$printf_hooks = xauto -o x$printf_hooks = xglibc; then
708         # check for the new register_printf_specifier function with len argument,
709         # or the deprecated register_printf_function without
710         AC_CHECK_FUNC(
711                 [register_printf_specifier],
712                 [AC_DEFINE([HAVE_PRINTF_SPECIFIER], [], [have register_printf_specifier()])],
713                 [AC_CHECK_FUNC(
714                         [register_printf_function],
715                         [AC_DEFINE([HAVE_PRINTF_FUNCTION], [], [have register_printf_function()])],
716                         [
717                                 AC_MSG_NOTICE([printf(3) does not support custom format specifiers!])
718                                 if test x$printf_hooks = xglibc; then
719                                         AC_MSG_ERROR([please select a different printf hook implementation])
720                                 else
721                                         # fallback to builtin printf hook implementation
722                                         printf_hooks=builtin
723                                 fi
724                         ]
725                 )]
726         )
727 fi
728
729 AC_MSG_CHECKING([for Windows target])
730 AC_COMPILE_IFELSE(
731         [AC_LANG_PROGRAM(
732                 [[#include <windows.h>]],
733                 [[#ifndef WIN32
734                   # error WIN32 undefined
735                   #endif
736                 ]])],
737         [
738                 AC_MSG_RESULT([yes])
739                 windows=true
740                 openssl_lib=eay32
741                 AC_SUBST(PTHREADLIB, "")
742                 # explicitly disable ms-bitfields, as it breaks __attribute__((packed))
743                 case "$CFLAGS" in
744                         *ms-bitfields*) ;;
745                         *) CFLAGS="$CFLAGS -mno-ms-bitfields" ;;
746                 esac
747         ],
748         [
749                 AC_MSG_RESULT([no])
750                 openssl_lib=crypto
751
752                 # check for clock_gettime() on non-Windows only. Otherwise this
753                 # check might find clock_gettime() in libwinpthread, but we don't want
754                 # to link against it.
755                 saved_LIBS=$LIBS
756                 # FreeBSD has clock_gettime in libc, Linux needs librt
757                 LIBS=""
758                 AC_SEARCH_LIBS(clock_gettime, rt, [RTLIB=$LIBS])
759                 AC_CHECK_FUNCS(clock_gettime)
760                 AC_SUBST(RTLIB)
761                 LIBS=$saved_LIBS
762         ]
763 )
764 AC_SUBST(OPENSSL_LIB, [-l$openssl_lib])
765 AM_CONDITIONAL(USE_WINDOWS, [test "x$windows" = xtrue])
766
767 AC_MSG_CHECKING([for working __attribute__((packed))])
768 AC_COMPILE_IFELSE(
769         [AC_LANG_PROGRAM([], [[
770                 struct test { char a; short b; } __attribute__((packed));
771                 char x[sizeof(struct test) == sizeof(char) + sizeof(short) ? 1 : -1]
772                         __attribute__((unused));
773                 return 0;
774         ]])],
775         [AC_MSG_RESULT([yes])],
776         [AC_MSG_RESULT([no]); AC_MSG_ERROR([__attribute__((packed)) does not work])]
777 )
778
779 AC_MSG_CHECKING([clang])
780 AC_COMPILE_IFELSE(
781         [AC_LANG_PROGRAM(
782                 [], [[
783                  #ifndef __clang__
784                  # error not using LLVM clang
785                  #endif
786                 ]])],
787         [
788                 AC_MSG_RESULT([yes])
789         ],
790         [
791                 AC_MSG_RESULT([no])
792                 # GCC, but not MinGW requires -rdynamic for plugins
793                 if test x$windows != xtrue; then
794                         AC_SUBST(PLUGIN_CFLAGS, [-rdynamic])
795                 fi
796         ]
797 )
798
799 if test x$printf_hooks = xvstr; then
800         AC_CHECK_LIB([vstr],[main],[LIBS="$LIBS"],[AC_MSG_ERROR([Vstr string library not found])],[])
801         AC_DEFINE([USE_VSTR], [], [use Vstr string library for printf hooks])
802 fi
803
804 if test x$printf_hooks = xbuiltin; then
805         AC_DEFINE([USE_BUILTIN_PRINTF], [], [using builtin printf for printf hooks])
806 fi
807
808 if test x$gmp = xtrue; then
809         saved_LIBS=$LIBS
810         AC_CHECK_LIB([gmp],[main],[],[AC_MSG_ERROR([GNU Multi Precision library gmp not found])],[])
811         AC_MSG_CHECKING([mpz_powm_sec])
812         if test x$mpz_powm_sec = xyes; then
813                 AC_COMPILE_IFELSE(
814                         [AC_LANG_PROGRAM(
815                                 [[#include "gmp.h"]],
816                                 [[void *x = mpz_powm_sec;]])],
817                         [AC_MSG_RESULT([yes]);
818                          AC_DEFINE([HAVE_MPZ_POWM_SEC], [], [have mpz_mown_sec()])],
819                         [AC_MSG_RESULT([no])]
820                 )
821         else
822                 AC_MSG_RESULT([disabled])
823         fi
824         LIBS=$saved_LIBS
825         AC_MSG_CHECKING([gmp.h version >= 4.1.4])
826         AC_COMPILE_IFELSE(
827                 [AC_LANG_PROGRAM(
828                         [[#include "gmp.h"]],
829                         [[
830                                 #if (__GNU_MP_VERSION*100 +  __GNU_MP_VERSION_MINOR*10 + __GNU_MP_VERSION_PATCHLEVEL) < 414
831                                         #error bad gmp
832                                 #endif]])],
833                 [AC_MSG_RESULT([yes])],
834                 [AC_MSG_RESULT([no]); AC_MSG_ERROR([No usable gmp.h found!])]
835         )
836 fi
837
838 if test x$ldap = xtrue; then
839         AC_CHECK_LIB([ldap],[main],[LIBS="$LIBS"],[AC_MSG_ERROR([LDAP library ldap not found])],[])
840         AC_CHECK_LIB([lber],[main],[LIBS="$LIBS"],[AC_MSG_ERROR([LDAP library lber not found])],[])
841         AC_CHECK_HEADER([ldap.h],,[AC_MSG_ERROR([LDAP header ldap.h not found!])])
842 fi
843
844 if test x$curl = xtrue; then
845         AC_CHECK_LIB([curl],[main],[LIBS="$LIBS"],[AC_MSG_ERROR([CURL library curl not found])],[])
846         AC_CHECK_HEADER([curl/curl.h],,[AC_MSG_ERROR([CURL header curl/curl.h not found!])])
847 fi
848
849 if test x$unbound = xtrue; then
850         AC_HAVE_LIBRARY([ldns],[LIBS="$LIBS"],[AC_MSG_ERROR([UNBOUND library ldns not found])])
851         AC_CHECK_HEADER([ldns/ldns.h],,[AC_MSG_ERROR([UNBOUND header ldns/ldns.h not found!])])
852         AC_HAVE_LIBRARY([unbound],[LIBS="$LIBS"],[AC_MSG_ERROR([UNBOUND library libunbound not found])])
853         AC_CHECK_HEADER([unbound.h],,[AC_MSG_ERROR([UNBOUND header unbound.h not found!])])
854 fi
855
856 if test x$soup = xtrue; then
857         PKG_CHECK_MODULES(soup, [libsoup-2.4])
858         AC_SUBST(soup_CFLAGS)
859         AC_SUBST(soup_LIBS)
860 fi
861
862 if test x$xml = xtrue; then
863         PKG_CHECK_MODULES(xml, [libxml-2.0])
864         AC_SUBST(xml_CFLAGS)
865         AC_SUBST(xml_LIBS)
866 fi
867
868 if test x$systemd = xtrue; then
869         AC_MSG_CHECKING([for systemd system unit directory])
870         if test -n "$systemdsystemunitdir" -a "x$systemdsystemunitdir" != xno; then
871                 AC_MSG_RESULT([$systemdsystemunitdir])
872         else
873                 AC_MSG_ERROR([not found (try --with-systemdsystemunitdir)])
874         fi
875
876         PKG_CHECK_MODULES(systemd_daemon, [libsystemd-daemon])
877         AC_SUBST(systemd_daemon_CFLAGS)
878         AC_SUBST(systemd_daemon_LIBS)
879
880         PKG_CHECK_MODULES(systemd_journal, [libsystemd-journal])
881         AC_SUBST(systemd_journal_CFLAGS)
882         AC_SUBST(systemd_journal_LIBS)
883 fi
884
885 if test x$tss = xtrousers; then
886         AC_CHECK_LIB([tspi],[main],[LIBS="$LIBS"],[AC_MSG_ERROR([TrouSerS library libtspi not found])],[])
887         AC_CHECK_HEADER([trousers/tss.h],,[AC_MSG_ERROR([TrouSerS header trousers/tss.h not found!])])
888         AC_DEFINE([TSS_TROUSERS], [], [use TrouSerS library libtspi as TSS implementation])
889 fi
890
891 if test x$imv_swid = xtrue; then
892         PKG_CHECK_MODULES(json, [json-c], [],
893                 [PKG_CHECK_MODULES(json, [json])])
894         AC_SUBST(json_CFLAGS)
895         AC_SUBST(json_LIBS)
896 fi
897
898 if test x$dumm = xtrue; then
899         PKG_CHECK_MODULES(gtk, [gtk+-2.0 vte])
900         AC_SUBST(gtk_CFLAGS)
901         AC_SUBST(gtk_LIBS)
902         AC_CHECK_PROGS(RUBY, ruby)
903         AC_MSG_CHECKING([for Ruby header files])
904         if test -n "$RUBY"; then
905                 RUBYINCLUDE=
906                 RUBYDIR=`($RUBY -r rbconfig -e 'print RbConfig::CONFIG[["rubyhdrdir"]] || ""') 2>/dev/null`
907                 if test -n "$RUBYDIR" -a -r "$RUBYDIR/ruby.h"; then
908                         RUBYARCH=`($RUBY -r rbconfig -e 'print RbConfig::CONFIG[["arch"]] || ""') 2>/dev/null`
909                         if test -n "$RUBYARCH"; then
910                                 AC_MSG_RESULT([$RUBYDIR])
911                                 RUBYINCLUDE="-I$RUBYDIR -I$RUBYDIR/$RUBYARCH"
912                         fi
913                 else
914                         RUBYDIR=`($RUBY -r rbconfig -e 'print RbConfig::CONFIG[["archdir"]] || ""') 2>/dev/null`
915                         if test -n "$RUBYDIR" -a -r "$RUBYDIR/ruby.h"; then
916                                 AC_MSG_RESULT([$RUBYDIR])
917                                 RUBYINCLUDE="-I$RUBYDIR"
918                         fi
919                 fi
920                 if test -z "$RUBYINCLUDE"; then
921                         AC_MSG_ERROR([ruby.h not found])
922                 fi
923                 AC_SUBST(RUBYINCLUDE)
924         else
925                 AC_MSG_ERROR([don't know how to run ruby])
926         fi
927         AC_MSG_CHECKING([for libruby])
928         saved_LIBS=$LIBS
929         LIBS=`($RUBY -r rbconfig -e 'print RbConfig::CONFIG[["LIBRUBYARG_SHARED"]] || ""') 2>/dev/null`
930         AC_TRY_LINK_FUNC(ruby_init,
931                 [AC_MSG_RESULT([$LIBS]); RUBYLIB=$LIBS],
932                 [AC_MSG_ERROR([not found])])
933         AC_SUBST(RUBYLIB)
934         AC_CHECK_FUNCS(rb_errinfo)
935         LIBS=$saved_LIBS
936 fi
937
938 if test x$fast = xtrue; then
939         AC_CHECK_LIB([neo_cgi],[main],[LIBS="$LIBS"],[AC_MSG_ERROR([ClearSilver library neo_cgi not found!])],[])
940         AC_CHECK_LIB([neo_utl],[main],[LIBS="$LIBS"],[AC_MSG_ERROR([ClearSilver library neo_utl not found!])],[])
941         AC_MSG_CHECKING([ClearSilver requires zlib])
942         saved_CFLAGS=$CFLAGS
943         saved_LIBS=$LIBS
944         LIBS="-lneo_cgi -lneo_cs -lneo_utl"
945         CFLAGS="-I/usr/include/ClearSilver"
946         AC_LINK_IFELSE(
947                 [AC_LANG_PROGRAM(
948                         [[#include <ClearSilver.h>]],
949                         [[NEOERR *err = cgi_display(NULL, NULL);]])],
950                 [AC_MSG_RESULT([no]); clearsilver_LIBS="$LIBS"],
951                 [AC_MSG_RESULT([yes]); clearsilver_LIBS="$LIBS -lz"]
952         )
953         AC_SUBST(clearsilver_LIBS)
954         LIBS=$saved_LIBS
955         CFLAGS=$saved_CFLAGS
956 # autoconf does not like CamelCase!? How to fix this?
957 #       AC_CHECK_HEADER([ClearSilver/ClearSilver.h],,[AC_MSG_ERROR([ClearSilver header file ClearSilver/ClearSilver.h not found!])])
958
959         AC_CHECK_LIB([fcgi],[main],[LIBS="$LIBS"],[AC_MSG_ERROR([FastCGI library fcgi not found!])],[])
960         AC_CHECK_HEADER([fcgiapp.h],,[AC_MSG_ERROR([FastCGI header file fcgiapp.h not found!])])
961 fi
962
963 if test x$mysql = xtrue; then
964         if test "x$windows" = xtrue; then
965                 AC_CHECK_HEADER([mysql.h],,[AC_MSG_ERROR([MySQL header file mysql.h not found!])])
966                 AC_CHECK_LIB([mysql],[main],[LIBS="$LIBS"],[AC_MSG_ERROR([MySQL library not found!])],[])
967                 AC_SUBST(MYSQLLIB, -lmysql)
968         else
969                 AC_PATH_PROG([MYSQLCONFIG], [mysql_config], [], [$PATH:/bin:/usr/bin:/usr/local/bin])
970                 if test x$MYSQLCONFIG = x; then
971                         AC_MSG_ERROR([mysql_config not found!])
972                 fi
973                 AC_SUBST(MYSQLLIB, `$MYSQLCONFIG --libs_r`)
974                 AC_SUBST(MYSQLCFLAG, `$MYSQLCONFIG --cflags`)
975         fi
976 fi
977
978 if test x$sqlite = xtrue; then
979         AC_CHECK_LIB([sqlite3],[main],[LIBS="$LIBS"],[AC_MSG_ERROR([SQLite library sqlite3 not found])],[])
980         AC_CHECK_HEADER([sqlite3.h],,[AC_MSG_ERROR([SQLite header sqlite3.h not found!])])
981         AC_MSG_CHECKING([sqlite3_prepare_v2])
982         AC_COMPILE_IFELSE(
983                 [AC_LANG_PROGRAM(
984                         [[#include <sqlite3.h>]],
985                         [[void *test = sqlite3_prepare_v2;]])],
986                 [AC_MSG_RESULT([yes]);
987                  AC_DEFINE([HAVE_SQLITE3_PREPARE_V2], [], [have sqlite3_prepare_v2()])],
988                 [AC_MSG_RESULT([no])]
989         )
990         AC_MSG_CHECKING([sqlite3.h version >= 3.3.1])
991         AC_COMPILE_IFELSE(
992                 [AC_LANG_PROGRAM(
993                         [[#include <sqlite3.h>]],
994                         [[
995                                 #if SQLITE_VERSION_NUMBER < 3003001
996                                         #error bad sqlite
997                                 #endif]])],
998                 [AC_MSG_RESULT([yes])],
999                 [AC_MSG_RESULT([no]); AC_MSG_ERROR([SQLite version >= 3.3.1 required!])]
1000         )
1001 fi
1002
1003 if test x$openssl = xtrue; then
1004         AC_CHECK_LIB([$openssl_lib],[main],[LIBS="$LIBS"],[AC_MSG_ERROR([OpenSSL lib$openssl_lib not found])],[])
1005         AC_CHECK_HEADER([openssl/evp.h],,[AC_MSG_ERROR([OpenSSL header openssl/evp.h not found!])])
1006 fi
1007
1008 if test x$gcrypt = xtrue; then
1009         AC_CHECK_LIB([gcrypt],[main],[LIBS="$LIBS"],[AC_MSG_ERROR([gcrypt library not found])],[-lgpg-error])
1010         AC_CHECK_HEADER([gcrypt.h],,[AC_MSG_ERROR([gcrypt header gcrypt.h not found!])])
1011         AC_MSG_CHECKING([gcrypt CAMELLIA cipher])
1012         AC_COMPILE_IFELSE(
1013                 [AC_LANG_PROGRAM(
1014                         [[#include <gcrypt.h>]],
1015                         [[enum gcry_cipher_algos alg = GCRY_CIPHER_CAMELLIA128;]])],
1016                 [AC_MSG_RESULT([yes]);
1017                  AC_DEFINE([HAVE_GCRY_CIPHER_CAMELLIA], [], [have GCRY_CIPHER_CAMELLIA128])],
1018                 [AC_MSG_RESULT([no])]
1019         )
1020 fi
1021
1022 if test x$uci = xtrue; then
1023         AC_CHECK_LIB([uci],[main],[LIBS="$LIBS"],[AC_MSG_ERROR([UCI library libuci not found])],[])
1024         AC_CHECK_HEADER([uci.h],,[AC_MSG_ERROR([UCI header uci.h not found!])])
1025 fi
1026
1027 if test x$android_dns = xtrue; then
1028         AC_CHECK_LIB([cutils],[main],[LIBS="$LIBS"],[AC_MSG_ERROR([Android library libcutils not found])],[])
1029         AC_CHECK_HEADER([cutils/properties.h],,[AC_MSG_ERROR([Android header cutils/properties.h not found!])])
1030         # we have to force the use of libdl here because the autodetection
1031         # above does not work correctly when cross-compiling for android.
1032         DLLIB="-ldl"
1033         AC_SUBST(DLLIB)
1034 fi
1035
1036 if test x$maemo = xtrue; then
1037         PKG_CHECK_MODULES(maemo, [glib-2.0 gthread-2.0 libosso osso-af-settings])
1038         AC_SUBST(maemo_CFLAGS)
1039         AC_SUBST(maemo_LIBS)
1040         dbusservicedir="/usr/share/dbus-1/system-services"
1041         AC_SUBST(dbusservicedir)
1042 fi
1043
1044 if test x$eap_sim_pcsc = xtrue; then
1045         PKG_CHECK_MODULES(pcsclite, [libpcsclite])
1046         AC_SUBST(pcsclite_CFLAGS)
1047         AC_SUBST(pcsclite_LIBS)
1048 fi
1049
1050 if test x$nm = xtrue; then
1051         PKG_CHECK_EXISTS([libnm-glib],
1052                 [PKG_CHECK_MODULES(nm, [NetworkManager gthread-2.0 libnm-util libnm-glib libnm-glib-vpn])],
1053                 [PKG_CHECK_MODULES(nm, [NetworkManager gthread-2.0 libnm_util libnm_glib libnm_glib_vpn])]
1054         )
1055         AC_SUBST(nm_CFLAGS)
1056         AC_SUBST(nm_LIBS)
1057 fi
1058
1059 if test x$xauth_pam = xtrue; then
1060         AC_CHECK_LIB([pam],[main],[LIBS="$LIBS"],[AC_MSG_ERROR([PAM library not found])],[])
1061         AC_CHECK_HEADER([security/pam_appl.h],,[AC_MSG_ERROR([PAM header security/pam_appl.h not found!])])
1062 fi
1063
1064 if test x$capabilities = xnative; then
1065         AC_MSG_NOTICE([Usage of the native Linux capabilities interface is deprecated, use libcap instead])
1066         # Linux requires the following for capset(), Android does not have it,
1067         # but defines capset() in unistd.h instead.
1068         AC_CHECK_HEADERS([sys/capability.h])
1069         AC_CHECK_FUNC(capset,,[AC_MSG_ERROR([capset() not found!])])
1070         AC_DEFINE([CAPABILITIES_NATIVE], [], [have native linux capset()])
1071 fi
1072
1073 if test x$capabilities = xlibcap; then
1074         AC_CHECK_LIB([cap],[main],[LIBS="$LIBS"],[AC_MSG_ERROR([libcap library not found])],[])
1075         AC_CHECK_HEADER([sys/capability.h],
1076                 [AC_DEFINE([HAVE_SYS_CAPABILITY_H], [], [have sys/capability.h])],
1077                 [AC_MSG_ERROR([libcap header sys/capability.h not found!])])
1078         AC_DEFINE([CAPABILITIES_LIBCAP], [], [have libpcap library])
1079 fi
1080
1081 if test x$integrity_test = xtrue; then
1082         AC_MSG_CHECKING([for dladdr()])
1083         AC_COMPILE_IFELSE(
1084                 [AC_LANG_PROGRAM(
1085                         [[#define _GNU_SOURCE
1086                           #include <dlfcn.h>]],
1087                         [[Dl_info info; dladdr(main, &info);]])],
1088                 [AC_MSG_RESULT([yes])],
1089                 [AC_MSG_RESULT([no]);
1090                  AC_MSG_ERROR([dladdr() not supported, required by integrity-test!])]
1091         )
1092         AC_MSG_CHECKING([for dl_iterate_phdr()])
1093         AC_COMPILE_IFELSE(
1094                 [AC_LANG_PROGRAM(
1095                         [[#define _GNU_SOURCE
1096                           #include <link.h>]],
1097                         [[dl_iterate_phdr((void*)0, (void*)0);]])],
1098                 [AC_MSG_RESULT([yes])],
1099                 [AC_MSG_RESULT([no]);
1100                  AC_MSG_ERROR([dl_iterate_phdr() not supported, required by integrity-test!])]
1101         )
1102 fi
1103
1104 if test x$bfd_backtraces = xtrue; then
1105         AC_CHECK_LIB([bfd],[main],[LIBS="$LIBS"],[AC_MSG_ERROR([binutils libbfd not found!])],[])
1106         AC_CHECK_HEADER([bfd.h],[AC_DEFINE([HAVE_BFD_H],,[have binutils bfd.h])],
1107                 [AC_MSG_ERROR([binutils bfd.h header not found!])])
1108         BFDLIB="-lbfd"
1109         AC_SUBST(BFDLIB)
1110 fi
1111
1112 if test x$unwind_backtraces = xtrue; then
1113         AC_CHECK_LIB([unwind],[main],[LIBS="$LIBS"],[AC_MSG_ERROR([libunwind not found!])],[])
1114         AC_CHECK_HEADER([libunwind.h],[AC_DEFINE([HAVE_LIBUNWIND_H],,[have libunwind.h])],
1115                 [AC_MSG_ERROR([libunwind.h header not found!])])
1116         UNWINDLIB="-lunwind"
1117         AC_SUBST(UNWINDLIB)
1118 fi
1119
1120 AM_CONDITIONAL(USE_DEV_HEADERS, [test "x$dev_headers" != xno])
1121 if test x$dev_headers = xyes; then
1122         dev_headers="$includedir/strongswan"
1123 fi
1124 AC_SUBST(dev_headers)
1125
1126 CFLAGS="$CFLAGS -include `pwd`/config.h"
1127
1128 if test x$tkm = xtrue; then
1129         AC_PATH_PROG([GPRBUILD], [gprbuild], [], [$PATH:/bin:/usr/bin:/usr/local/bin])
1130         if test x$GPRBUILD = x; then
1131                 AC_MSG_ERROR([gprbuild not found])
1132         fi
1133 fi
1134
1135 if test x$coverage = xtrue; then
1136         AC_PATH_PROG([LCOV], [lcov], [], [$PATH:/bin:/usr/bin:/usr/local/bin])
1137         if test x$LCOV = x; then
1138                 AC_MSG_ERROR([lcov not found])
1139         fi
1140         AC_PATH_PROG([GENHTML], [genhtml], [], [$PATH:/bin:/usr/bin:/usr/local/bin])
1141         if test x$GENHTML = x; then
1142                 AC_MSG_ERROR([genhtml not found])
1143         fi
1144
1145         COVERAGE_CFLAGS="-fprofile-arcs -ftest-coverage"
1146         COVERAGE_LDFLAGS="-fprofile-arcs"
1147         AC_SUBST(COVERAGE_CFLAGS)
1148         AC_SUBST(COVERAGE_LDFLAGS)
1149
1150         AC_MSG_NOTICE([coverage enabled, adding "-g -O0" to CFLAGS])
1151         CFLAGS="${CFLAGS} -g -O0"
1152 fi
1153
1154 # ===============================================
1155 #  collect plugin list for strongSwan components
1156 # ===============================================
1157
1158 m4_include(m4/macros/add-plugin.m4)
1159
1160 # plugin lists for all components
1161 charon_plugins=
1162 starter_plugins=
1163 pool_plugins=
1164 attest_plugins=
1165 scepclient_plugins=
1166 pki_plugins=
1167 scripts_plugins=
1168 manager_plugins=
1169 medsrv_plugins=
1170 nm_plugins=
1171 cmd_plugins=
1172 aikgen_plugins=
1173
1174 # location specific lists for checksumming,
1175 # for src/libcharon, src/libhydra, src/libstrongswan and src/libtnccs
1176 c_plugins=
1177 h_plugins=
1178 s_plugins=
1179 t_plugins=
1180
1181 ADD_PLUGIN([test-vectors],         [s charon scepclient pki])
1182 ADD_PLUGIN([unbound],              [s charon scripts])
1183 ADD_PLUGIN([ldap],                 [s charon scepclient scripts nm cmd])
1184 ADD_PLUGIN([mysql],                [s charon pool manager medsrv attest])
1185 ADD_PLUGIN([sqlite],               [s charon pool manager medsrv attest])
1186 ADD_PLUGIN([pkcs11],               [s charon pki nm cmd])
1187 ADD_PLUGIN([aes],                  [s charon scepclient pki scripts nm cmd])
1188 ADD_PLUGIN([des],                  [s charon scepclient pki scripts nm cmd])
1189 ADD_PLUGIN([blowfish],             [s charon scepclient pki scripts nm cmd])
1190 ADD_PLUGIN([rc2],                  [s charon scepclient pki scripts nm cmd])
1191 ADD_PLUGIN([sha1],                 [s charon scepclient pki scripts medsrv attest nm cmd aikgen])
1192 ADD_PLUGIN([sha2],                 [s charon scepclient pki scripts medsrv attest nm cmd aikgen])
1193 ADD_PLUGIN([md4],                  [s charon manager scepclient pki nm cmd])
1194 ADD_PLUGIN([md5],                  [s charon scepclient pki scripts attest nm cmd aikgen])
1195 ADD_PLUGIN([rdrand],               [s charon scepclient pki scripts medsrv attest nm cmd aikgen])
1196 ADD_PLUGIN([random],               [s charon scepclient pki scripts medsrv attest nm cmd aikgen])
1197 ADD_PLUGIN([nonce],                [s charon nm cmd aikgen])
1198 ADD_PLUGIN([x509],                 [s charon scepclient pki scripts attest nm cmd aikgen])
1199 ADD_PLUGIN([revocation],           [s charon pki nm cmd])
1200 ADD_PLUGIN([constraints],          [s charon nm cmd])
1201 ADD_PLUGIN([acert],                [s charon])
1202 ADD_PLUGIN([pubkey],               [s charon cmd aikgen])
1203 ADD_PLUGIN([pkcs1],                [s charon scepclient pki scripts manager medsrv attest nm cmd aikgen])
1204 ADD_PLUGIN([pkcs7],                [s charon scepclient pki scripts nm cmd])
1205 ADD_PLUGIN([pkcs8],                [s charon scepclient pki scripts manager medsrv attest nm cmd])
1206 ADD_PLUGIN([pkcs12],               [s charon scepclient pki scripts cmd])
1207 ADD_PLUGIN([pgp],                  [s charon])
1208 ADD_PLUGIN([dnskey],               [s charon pki])
1209 ADD_PLUGIN([sshkey],               [s charon pki nm cmd])
1210 ADD_PLUGIN([dnscert],              [c charon])
1211 ADD_PLUGIN([ipseckey],             [c charon])
1212 ADD_PLUGIN([pem],                  [s charon scepclient pki scripts manager medsrv attest nm cmd aikgen])
1213 ADD_PLUGIN([padlock],              [s charon])
1214 ADD_PLUGIN([openssl],              [s charon scepclient pki scripts manager medsrv attest nm cmd aikgen])
1215 ADD_PLUGIN([gcrypt],               [s charon scepclient pki scripts manager medsrv attest nm cmd aikgen])
1216 ADD_PLUGIN([af-alg],               [s charon scepclient pki scripts medsrv attest nm cmd aikgen])
1217 ADD_PLUGIN([fips-prf],             [s charon nm cmd])
1218 ADD_PLUGIN([gmp],                  [s charon scepclient pki scripts manager medsrv attest nm cmd aikgen])
1219 ADD_PLUGIN([agent],                [s charon nm cmd])
1220 ADD_PLUGIN([keychain],             [s charon cmd])
1221 ADD_PLUGIN([xcbc],                 [s charon nm cmd])
1222 ADD_PLUGIN([cmac],                 [s charon nm cmd])
1223 ADD_PLUGIN([hmac],                 [s charon scripts nm cmd])
1224 ADD_PLUGIN([ctr],                  [s charon scripts nm cmd])
1225 ADD_PLUGIN([ccm],                  [s charon scripts nm cmd])
1226 ADD_PLUGIN([gcm],                  [s charon scripts nm cmd])
1227 ADD_PLUGIN([ntru],                 [s charon scripts nm cmd])
1228 ADD_PLUGIN([curl],                 [s charon scepclient pki scripts nm cmd])
1229 ADD_PLUGIN([winhttp],              [s charon pki scripts])
1230 ADD_PLUGIN([soup],                 [s charon pki scripts nm cmd])
1231 ADD_PLUGIN([attr],                 [h charon])
1232 ADD_PLUGIN([attr-sql],             [h charon])
1233 ADD_PLUGIN([load-tester],          [c charon])
1234 ADD_PLUGIN([kernel-libipsec],      [c charon cmd])
1235 ADD_PLUGIN([kernel-wfp],           [c charon])
1236 ADD_PLUGIN([kernel-iph],           [c charon])
1237 ADD_PLUGIN([kernel-pfkey],         [h charon starter nm cmd])
1238 ADD_PLUGIN([kernel-pfroute],       [h charon starter nm cmd])
1239 ADD_PLUGIN([kernel-netlink],       [h charon starter nm cmd])
1240 ADD_PLUGIN([resolve],              [h charon cmd])
1241 ADD_PLUGIN([socket-default],       [c charon nm cmd])
1242 ADD_PLUGIN([socket-dynamic],       [c charon cmd])
1243 ADD_PLUGIN([socket-win],           [c charon])
1244 ADD_PLUGIN([farp],                 [c charon])
1245 ADD_PLUGIN([stroke],               [c charon])
1246 ADD_PLUGIN([vici],                 [c charon])
1247 ADD_PLUGIN([smp],                  [c charon])
1248 ADD_PLUGIN([sql],                  [c charon])
1249 ADD_PLUGIN([updown],               [c charon])
1250 ADD_PLUGIN([eap-identity],         [c charon nm cmd])
1251 ADD_PLUGIN([eap-sim],              [c charon])
1252 ADD_PLUGIN([eap-sim-file],         [c charon])
1253 ADD_PLUGIN([eap-sim-pcsc],         [c charon])
1254 ADD_PLUGIN([eap-aka],              [c charon])
1255 ADD_PLUGIN([eap-aka-3gpp2],        [c charon])
1256 ADD_PLUGIN([eap-simaka-sql],       [c charon])
1257 ADD_PLUGIN([eap-simaka-pseudonym], [c charon])
1258 ADD_PLUGIN([eap-simaka-reauth],    [c charon])
1259 ADD_PLUGIN([eap-md5],              [c charon nm cmd])
1260 ADD_PLUGIN([eap-gtc],              [c charon nm cmd])
1261 ADD_PLUGIN([eap-mschapv2],         [c charon nm cmd])
1262 ADD_PLUGIN([eap-dynamic],          [c charon])
1263 ADD_PLUGIN([eap-radius],           [c charon])
1264 ADD_PLUGIN([eap-tls],              [c charon nm cmd])
1265 ADD_PLUGIN([eap-ttls],             [c charon nm cmd])
1266 ADD_PLUGIN([eap-peap],             [c charon nm cmd])
1267 ADD_PLUGIN([eap-tnc],              [c charon])
1268 ADD_PLUGIN([xauth-generic],        [c charon cmd])
1269 ADD_PLUGIN([xauth-eap],            [c charon])
1270 ADD_PLUGIN([xauth-pam],            [c charon])
1271 ADD_PLUGIN([xauth-noauth],         [c charon])
1272 ADD_PLUGIN([tnc-ifmap],            [c charon])
1273 ADD_PLUGIN([tnc-pdp],              [c charon])
1274 ADD_PLUGIN([tnc-imc],              [t charon])
1275 ADD_PLUGIN([tnc-imv],              [t charon])
1276 ADD_PLUGIN([tnc-tnccs],            [t charon])
1277 ADD_PLUGIN([tnccs-20],             [t charon])
1278 ADD_PLUGIN([tnccs-11],             [t charon])
1279 ADD_PLUGIN([tnccs-dynamic],        [t charon])
1280 ADD_PLUGIN([medsrv],               [c charon])
1281 ADD_PLUGIN([medcli],               [c charon])
1282 ADD_PLUGIN([dhcp],                 [c charon])
1283 ADD_PLUGIN([osx-attr],             [c charon cmd])
1284 ADD_PLUGIN([android-dns],          [c charon])
1285 ADD_PLUGIN([android-log],          [c charon])
1286 ADD_PLUGIN([ha],                   [c charon])
1287 ADD_PLUGIN([whitelist],            [c charon])
1288 ADD_PLUGIN([lookip],               [c charon])
1289 ADD_PLUGIN([error-notify],         [c charon])
1290 ADD_PLUGIN([certexpire],           [c charon])
1291 ADD_PLUGIN([systime-fix],          [c charon])
1292 ADD_PLUGIN([led],                  [c charon])
1293 ADD_PLUGIN([duplicheck],           [c charon])
1294 ADD_PLUGIN([coupling],             [c charon])
1295 ADD_PLUGIN([radattr],              [c charon])
1296 ADD_PLUGIN([maemo],                [c charon])
1297 ADD_PLUGIN([uci],                  [c charon])
1298 ADD_PLUGIN([addrblock],            [c charon])
1299 ADD_PLUGIN([unity],                [c charon])
1300 ADD_PLUGIN([unit-tester],          [c charon])
1301
1302 AC_SUBST(charon_plugins)
1303 AC_SUBST(starter_plugins)
1304 AC_SUBST(pool_plugins)
1305 AC_SUBST(attest_plugins)
1306 AC_SUBST(scepclient_plugins)
1307 AC_SUBST(pki_plugins)
1308 AC_SUBST(scripts_plugins)
1309 AC_SUBST(manager_plugins)
1310 AC_SUBST(medsrv_plugins)
1311 AC_SUBST(nm_plugins)
1312 AC_SUBST(cmd_plugins)
1313 AC_SUBST(aikgen_plugins)
1314
1315 AC_SUBST(c_plugins)
1316 AC_SUBST(h_plugins)
1317 AC_SUBST(s_plugins)
1318 AC_SUBST(t_plugins)
1319
1320 # ======================
1321 #  set Makefile.am vars
1322 # ======================
1323
1324 #  libstrongswan plugins
1325 # -----------------------
1326 AM_CONDITIONAL(USE_TEST_VECTORS, test x$test_vectors = xtrue)
1327 AM_CONDITIONAL(USE_CURL, test x$curl = xtrue)
1328 AM_CONDITIONAL(USE_WINHTTP, test x$winhttp = xtrue)
1329 AM_CONDITIONAL(USE_UNBOUND, test x$unbound = xtrue)
1330 AM_CONDITIONAL(USE_SOUP, test x$soup = xtrue)
1331 AM_CONDITIONAL(USE_LDAP, test x$ldap = xtrue)
1332 AM_CONDITIONAL(USE_AES, test x$aes = xtrue)
1333 AM_CONDITIONAL(USE_DES, test x$des = xtrue)
1334 AM_CONDITIONAL(USE_BLOWFISH, test x$blowfish = xtrue)
1335 AM_CONDITIONAL(USE_RC2, test x$rc2 = xtrue)
1336 AM_CONDITIONAL(USE_MD4, test x$md4 = xtrue)
1337 AM_CONDITIONAL(USE_MD5, test x$md5 = xtrue)
1338 AM_CONDITIONAL(USE_SHA1, test x$sha1 = xtrue)
1339 AM_CONDITIONAL(USE_SHA2, test x$sha2 = xtrue)
1340 AM_CONDITIONAL(USE_FIPS_PRF, test x$fips_prf = xtrue)
1341 AM_CONDITIONAL(USE_GMP, test x$gmp = xtrue)
1342 AM_CONDITIONAL(USE_RDRAND, test x$rdrand = xtrue)
1343 AM_CONDITIONAL(USE_RANDOM, test x$random = xtrue)
1344 AM_CONDITIONAL(USE_NONCE, test x$nonce = xtrue)
1345 AM_CONDITIONAL(USE_X509, test x$x509 = xtrue)
1346 AM_CONDITIONAL(USE_REVOCATION, test x$revocation = xtrue)
1347 AM_CONDITIONAL(USE_CONSTRAINTS, test x$constraints = xtrue)
1348 AM_CONDITIONAL(USE_ACERT, test x$acert = xtrue)
1349 AM_CONDITIONAL(USE_PUBKEY, test x$pubkey = xtrue)
1350 AM_CONDITIONAL(USE_PKCS1, test x$pkcs1 = xtrue)
1351 AM_CONDITIONAL(USE_PKCS7, test x$pkcs7 = xtrue)
1352 AM_CONDITIONAL(USE_PKCS8, test x$pkcs8 = xtrue)
1353 AM_CONDITIONAL(USE_PKCS12, test x$pkcs12 = xtrue)
1354 AM_CONDITIONAL(USE_PGP, test x$pgp = xtrue)
1355 AM_CONDITIONAL(USE_DNSKEY, test x$dnskey = xtrue)
1356 AM_CONDITIONAL(USE_SSHKEY, test x$sshkey = xtrue)
1357 AM_CONDITIONAL(USE_PEM, test x$pem = xtrue)
1358 AM_CONDITIONAL(USE_HMAC, test x$hmac = xtrue)
1359 AM_CONDITIONAL(USE_CMAC, test x$cmac = xtrue)
1360 AM_CONDITIONAL(USE_XCBC, test x$xcbc = xtrue)
1361 AM_CONDITIONAL(USE_MYSQL, test x$mysql = xtrue)
1362 AM_CONDITIONAL(USE_SQLITE, test x$sqlite = xtrue)
1363 AM_CONDITIONAL(USE_PADLOCK, test x$padlock = xtrue)
1364 AM_CONDITIONAL(USE_OPENSSL, test x$openssl = xtrue)
1365 AM_CONDITIONAL(USE_GCRYPT, test x$gcrypt = xtrue)
1366 AM_CONDITIONAL(USE_AGENT, test x$agent = xtrue)
1367 AM_CONDITIONAL(USE_KEYCHAIN, test x$keychain = xtrue)
1368 AM_CONDITIONAL(USE_PKCS11, test x$pkcs11 = xtrue)
1369 AM_CONDITIONAL(USE_CTR, test x$ctr = xtrue)
1370 AM_CONDITIONAL(USE_CCM, test x$ccm = xtrue)
1371 AM_CONDITIONAL(USE_GCM, test x$gcm = xtrue)
1372 AM_CONDITIONAL(USE_AF_ALG, test x$af_alg = xtrue)
1373 AM_CONDITIONAL(USE_NTRU, test x$ntru = xtrue)
1374
1375 #  charon plugins
1376 # ----------------
1377 AM_CONDITIONAL(USE_STROKE, test x$stroke = xtrue)
1378 AM_CONDITIONAL(USE_VICI, test x$vici = xtrue)
1379 AM_CONDITIONAL(USE_MEDSRV, test x$medsrv = xtrue)
1380 AM_CONDITIONAL(USE_MEDCLI, test x$medcli = xtrue)
1381 AM_CONDITIONAL(USE_UCI, test x$uci = xtrue)
1382 AM_CONDITIONAL(USE_OSX_ATTR, test x$osx_attr = xtrue)
1383 AM_CONDITIONAL(USE_ANDROID_DNS, test x$android_dns = xtrue)
1384 AM_CONDITIONAL(USE_ANDROID_LOG, test x$android_log = xtrue)
1385 AM_CONDITIONAL(USE_MAEMO, test x$maemo = xtrue)
1386 AM_CONDITIONAL(USE_SMP, test x$smp = xtrue)
1387 AM_CONDITIONAL(USE_SQL, test x$sql = xtrue)
1388 AM_CONDITIONAL(USE_DNSCERT, test x$dnscert = xtrue)
1389 AM_CONDITIONAL(USE_IPSECKEY, test x$ipseckey = xtrue)
1390 AM_CONDITIONAL(USE_UPDOWN, test x$updown = xtrue)
1391 AM_CONDITIONAL(USE_DHCP, test x$dhcp = xtrue)
1392 AM_CONDITIONAL(USE_UNIT_TESTS, test x$unit_tester = xtrue)
1393 AM_CONDITIONAL(USE_LOAD_TESTER, test x$load_tester = xtrue)
1394 AM_CONDITIONAL(USE_HA, test x$ha = xtrue)
1395 AM_CONDITIONAL(USE_KERNEL_LIBIPSEC, test x$kernel_libipsec = xtrue)
1396 AM_CONDITIONAL(USE_KERNEL_WFP, test x$kernel_wfp = xtrue)
1397 AM_CONDITIONAL(USE_KERNEL_IPH, test x$kernel_iph = xtrue)
1398 AM_CONDITIONAL(USE_WHITELIST, test x$whitelist = xtrue)
1399 AM_CONDITIONAL(USE_LOOKIP, test x$lookip = xtrue)
1400 AM_CONDITIONAL(USE_ERROR_NOTIFY, test x$error_notify = xtrue)
1401 AM_CONDITIONAL(USE_CERTEXPIRE, test x$certexpire = xtrue)
1402 AM_CONDITIONAL(USE_SYSTIME_FIX, test x$systime_fix = xtrue)
1403 AM_CONDITIONAL(USE_LED, test x$led = xtrue)
1404 AM_CONDITIONAL(USE_DUPLICHECK, test x$duplicheck = xtrue)
1405 AM_CONDITIONAL(USE_COUPLING, test x$coupling = xtrue)
1406 AM_CONDITIONAL(USE_RADATTR, test x$radattr = xtrue)
1407 AM_CONDITIONAL(USE_EAP_SIM, test x$eap_sim = xtrue)
1408 AM_CONDITIONAL(USE_EAP_SIM_FILE, test x$eap_sim_file = xtrue)
1409 AM_CONDITIONAL(USE_EAP_SIM_PCSC, test x$eap_sim_pcsc = xtrue)
1410 AM_CONDITIONAL(USE_EAP_SIMAKA_SQL, test x$eap_simaka_sql = xtrue)
1411 AM_CONDITIONAL(USE_EAP_SIMAKA_PSEUDONYM, test x$eap_simaka_pseudonym = xtrue)
1412 AM_CONDITIONAL(USE_EAP_SIMAKA_REAUTH, test x$eap_simaka_reauth = xtrue)
1413 AM_CONDITIONAL(USE_EAP_IDENTITY, test x$eap_identity = xtrue)
1414 AM_CONDITIONAL(USE_EAP_MD5, test x$eap_md5 = xtrue)
1415 AM_CONDITIONAL(USE_EAP_GTC, test x$eap_gtc = xtrue)
1416 AM_CONDITIONAL(USE_EAP_AKA, test x$eap_aka = xtrue)
1417 AM_CONDITIONAL(USE_EAP_AKA_3GPP2, test x$eap_aka_3gpp2 = xtrue)
1418 AM_CONDITIONAL(USE_EAP_MSCHAPV2, test x$eap_mschapv2 = xtrue)
1419 AM_CONDITIONAL(USE_EAP_TLS, test x$eap_tls = xtrue)
1420 AM_CONDITIONAL(USE_EAP_TTLS, test x$eap_ttls = xtrue)
1421 AM_CONDITIONAL(USE_EAP_PEAP, test x$eap_peap = xtrue)
1422 AM_CONDITIONAL(USE_EAP_TNC, test x$eap_tnc = xtrue)
1423 AM_CONDITIONAL(USE_EAP_DYNAMIC, test x$eap_dynamic = xtrue)
1424 AM_CONDITIONAL(USE_EAP_RADIUS, test x$eap_radius = xtrue)
1425 AM_CONDITIONAL(USE_XAUTH_GENERIC, test x$xauth_generic = xtrue)
1426 AM_CONDITIONAL(USE_XAUTH_EAP, test x$xauth_eap = xtrue)
1427 AM_CONDITIONAL(USE_XAUTH_PAM, test x$xauth_pam = xtrue)
1428 AM_CONDITIONAL(USE_XAUTH_NOAUTH, test x$xauth_noauth = xtrue)
1429 AM_CONDITIONAL(USE_TNC_IFMAP, test x$tnc_ifmap = xtrue)
1430 AM_CONDITIONAL(USE_TNC_PDP, test x$tnc_pdp = xtrue)
1431 AM_CONDITIONAL(USE_TNC_IMC, test x$tnc_imc = xtrue)
1432 AM_CONDITIONAL(USE_TNC_IMV, test x$tnc_imv = xtrue)
1433 AM_CONDITIONAL(USE_TNC_TNCCS, test x$tnc_tnccs = xtrue)
1434 AM_CONDITIONAL(USE_TNCCS_11, test x$tnccs_11 = xtrue)
1435 AM_CONDITIONAL(USE_TNCCS_20, test x$tnccs_20 = xtrue)
1436 AM_CONDITIONAL(USE_TNCCS_DYNAMIC, test x$tnccs_dynamic = xtrue)
1437 AM_CONDITIONAL(USE_IMC_TEST, test x$imc_test = xtrue)
1438 AM_CONDITIONAL(USE_IMV_TEST, test x$imv_test = xtrue)
1439 AM_CONDITIONAL(USE_IMC_SCANNER, test x$imc_scanner = xtrue)
1440 AM_CONDITIONAL(USE_IMV_SCANNER, test x$imv_scanner = xtrue)
1441 AM_CONDITIONAL(USE_IMC_OS, test x$imc_os = xtrue)
1442 AM_CONDITIONAL(USE_IMV_OS, test x$imv_os = xtrue)
1443 AM_CONDITIONAL(USE_IMC_ATTESTATION, test x$imc_attestation = xtrue)
1444 AM_CONDITIONAL(USE_IMV_ATTESTATION, test x$imv_attestation = xtrue)
1445 AM_CONDITIONAL(USE_IMC_SWID, test x$imc_swid = xtrue)
1446 AM_CONDITIONAL(USE_IMV_SWID, test x$imv_swid = xtrue)
1447 AM_CONDITIONAL(USE_SOCKET_DEFAULT, test x$socket_default = xtrue)
1448 AM_CONDITIONAL(USE_SOCKET_DYNAMIC, test x$socket_dynamic = xtrue)
1449 AM_CONDITIONAL(USE_SOCKET_WIN, test x$socket_win = xtrue)
1450 AM_CONDITIONAL(USE_FARP, test x$farp = xtrue)
1451 AM_CONDITIONAL(USE_ADDRBLOCK, test x$addrblock = xtrue)
1452 AM_CONDITIONAL(USE_UNITY, test x$unity = xtrue)
1453
1454 #  hydra plugins
1455 # ---------------
1456 AM_CONDITIONAL(USE_ATTR, test x$attr = xtrue)
1457 AM_CONDITIONAL(USE_ATTR_SQL, test x$attr_sql = xtrue)
1458 AM_CONDITIONAL(USE_KERNEL_NETLINK, test x$kernel_netlink = xtrue)
1459 AM_CONDITIONAL(USE_KERNEL_PFKEY, test x$kernel_pfkey = xtrue)
1460 AM_CONDITIONAL(USE_KERNEL_PFROUTE, test x$kernel_pfroute = xtrue)
1461 AM_CONDITIONAL(USE_RESOLVE, test x$resolve = xtrue)
1462
1463 #  other options
1464 # ---------------
1465 AM_CONDITIONAL(USE_LEAK_DETECTIVE, test x$leak_detective = xtrue)
1466 AM_CONDITIONAL(USE_LOCK_PROFILER, test x$lock_profiler = xtrue)
1467 AM_CONDITIONAL(USE_DUMM, test x$dumm = xtrue)
1468 AM_CONDITIONAL(USE_FAST, test x$fast = xtrue)
1469 AM_CONDITIONAL(USE_MANAGER, test x$manager = xtrue)
1470 AM_CONDITIONAL(USE_ME, test x$mediation = xtrue)
1471 AM_CONDITIONAL(USE_INTEGRITY_TEST, test x$integrity_test = xtrue)
1472 AM_CONDITIONAL(USE_LOAD_WARNING, test x$load_warning = xtrue)
1473 AM_CONDITIONAL(USE_IKEV1, test x$ikev1 = xtrue)
1474 AM_CONDITIONAL(USE_IKEV2, test x$ikev2 = xtrue)
1475 AM_CONDITIONAL(USE_THREADS, test x$threads = xtrue)
1476 AM_CONDITIONAL(USE_ADNS, test x$adns = xtrue)
1477 AM_CONDITIONAL(USE_CHARON, test x$charon = xtrue)
1478 AM_CONDITIONAL(USE_NM, test x$nm = xtrue)
1479 AM_CONDITIONAL(USE_PKI, test x$pki = xtrue)
1480 AM_CONDITIONAL(USE_SCEPCLIENT, test x$scepclient = xtrue)
1481 AM_CONDITIONAL(USE_SCRIPTS, test x$scripts = xtrue)
1482 AM_CONDITIONAL(USE_CONFTEST, test x$conftest = xtrue)
1483 AM_CONDITIONAL(USE_LIBSTRONGSWAN, test x$charon = xtrue -o x$pki = xtrue -o x$scepclient = xtrue -o x$conftest = xtrue -o x$fast = xtrue -o x$imcv = xtrue -o x$nm = xtrue -o x$tkm = xtrue -o x$cmd = xtrue -o x$tls = xtrue -o x$tnc_tnccs = xtrue -o x$aikgen = xtrue -o x$svc = xtrue -o x$systemd = xtrue)
1484 AM_CONDITIONAL(USE_LIBHYDRA, test x$charon = xtrue -o x$nm = xtrue -o x$tkm = xtrue -o x$cmd = xtrue -o x$svc = xtrue -o x$systemd = xtrue)
1485 AM_CONDITIONAL(USE_LIBCHARON, test x$charon = xtrue -o x$conftest = xtrue -o x$nm = xtrue -o x$tkm = xtrue -o x$cmd = xtrue -o x$svc = xtrue -o x$systemd = xtrue)
1486 AM_CONDITIONAL(USE_LIBIPSEC, test x$libipsec = xtrue)
1487 AM_CONDITIONAL(USE_LIBTNCIF, test x$tnc_tnccs = xtrue -o x$imcv = xtrue)
1488 AM_CONDITIONAL(USE_LIBTNCCS, test x$tnc_tnccs = xtrue)
1489 AM_CONDITIONAL(USE_LIBPTTLS, test x$tnc_tnccs = xtrue)
1490 AM_CONDITIONAL(USE_FILE_CONFIG, test x$stroke = xtrue)
1491 AM_CONDITIONAL(USE_IPSEC_SCRIPT, test x$stroke = xtrue -o x$scepclient = xtrue -o x$conftest = xtrue)
1492 AM_CONDITIONAL(USE_LIBCAP, test x$capabilities = xlibcap)
1493 AM_CONDITIONAL(USE_VSTR, test x$printf_hooks = xvstr)
1494 AM_CONDITIONAL(USE_BUILTIN_PRINTF, test x$printf_hooks = xbuiltin)
1495 AM_CONDITIONAL(USE_SIMAKA, test x$simaka = xtrue)
1496 AM_CONDITIONAL(USE_TLS, test x$tls = xtrue)
1497 AM_CONDITIONAL(USE_RADIUS, test x$radius = xtrue)
1498 AM_CONDITIONAL(USE_IMCV, test x$imcv = xtrue)
1499 AM_CONDITIONAL(USE_TROUSERS, test x$tss = xtrousers -o x$aikgen = xtrue)
1500 AM_CONDITIONAL(MONOLITHIC, test x$monolithic = xtrue)
1501 AM_CONDITIONAL(USE_SILENT_RULES, test x$enable_silent_rules = xyes)
1502 AM_CONDITIONAL(COVERAGE, test x$coverage = xtrue)
1503 AM_CONDITIONAL(USE_DBGHELP, test x$dbghelp_backtraces = xtrue)
1504 AM_CONDITIONAL(USE_TKM, test x$tkm = xtrue)
1505 AM_CONDITIONAL(USE_CMD, test x$cmd = xtrue)
1506 AM_CONDITIONAL(USE_AIKGEN, test x$aikgen = xtrue)
1507 AM_CONDITIONAL(USE_SWANCTL, test x$swanctl = xtrue)
1508 AM_CONDITIONAL(USE_SVC, test x$svc = xtrue)
1509 AM_CONDITIONAL(USE_SYSTEMD, test x$systemd = xtrue)
1510 AM_CONDITIONAL(USE_LEGACY_SYSTEMD, test -n "$systemdsystemunitdir" -a "x$systemdsystemunitdir" != xno)
1511
1512 # ========================
1513 #  set global definitions
1514 # ========================
1515
1516 if test x$mediation = xtrue; then
1517         AC_DEFINE([ME], [], [mediation extension support])
1518 fi
1519 if test x$capabilities = xlibcap -o x$capabilities = xnative; then
1520         AC_DEFINE([CAPABILITIES], [], [capability dropping support])
1521 fi
1522 if test x$monolithic = xtrue; then
1523         AC_DEFINE([MONOLITHIC], [], [monolithic build embedding plugins])
1524 fi
1525 if test x$ikev1 = xtrue; then
1526         AC_DEFINE([USE_IKEV1], [], [support for IKEv1 protocol])
1527 fi
1528 if test x$ikev2 = xtrue; then
1529         AC_DEFINE([USE_IKEV2], [], [support for IKEv2 protocol])
1530 fi
1531
1532 # ====================================================
1533 #  options for enabled modules (see conf/Makefile.am)
1534 # ====================================================
1535
1536 strongswan_options=
1537
1538 AM_COND_IF([USE_AIKGEN], [strongswan_options=${strongswan_options}" aikgen"])
1539 AM_COND_IF([USE_ATTR_SQL], [strongswan_options=${strongswan_options}" pool"])
1540 AM_COND_IF([USE_CHARON], [strongswan_options=${strongswan_options}" charon charon-logging"])
1541 AM_COND_IF([USE_FILE_CONFIG], [strongswan_options=${strongswan_options}" starter"])
1542 AM_COND_IF([USE_IMV_ATTESTATION], [strongswan_options=${strongswan_options}" attest"])
1543 AM_COND_IF([USE_IMCV], [strongswan_options=${strongswan_options}" imcv"])
1544 AM_COND_IF([USE_IMV_OS], [strongswan_options=${strongswan_options}" pacman"])
1545 AM_COND_IF([USE_LIBTNCCS], [strongswan_options=${strongswan_options}" tnc"])
1546 AM_COND_IF([USE_MANAGER], [strongswan_options=${strongswan_options}" manager"])
1547 AM_COND_IF([USE_MEDSRV], [strongswan_options=${strongswan_options}" medsrv"])
1548 AM_COND_IF([USE_SCEPCLIENT], [strongswan_options=${strongswan_options}" scepclient"])
1549 AM_COND_IF([USE_PKI], [strongswan_options=${strongswan_options}" pki"])
1550 AM_COND_IF([USE_SWANCTL], [strongswan_options=${strongswan_options}" swanctl"])
1551
1552 AC_SUBST(strongswan_options)
1553
1554 # =================
1555 #  build Makefiles
1556 # =================
1557
1558 AC_CONFIG_FILES([
1559         Makefile
1560         conf/Makefile
1561         man/Makefile
1562         init/Makefile
1563         init/systemd/Makefile
1564         init/systemd-swanctl/Makefile
1565         src/Makefile
1566         src/include/Makefile
1567         src/libstrongswan/Makefile
1568         src/libstrongswan/plugins/aes/Makefile
1569         src/libstrongswan/plugins/cmac/Makefile
1570         src/libstrongswan/plugins/des/Makefile
1571         src/libstrongswan/plugins/blowfish/Makefile
1572         src/libstrongswan/plugins/rc2/Makefile
1573         src/libstrongswan/plugins/md4/Makefile
1574         src/libstrongswan/plugins/md5/Makefile
1575         src/libstrongswan/plugins/sha1/Makefile
1576         src/libstrongswan/plugins/sha2/Makefile
1577         src/libstrongswan/plugins/fips_prf/Makefile
1578         src/libstrongswan/plugins/gmp/Makefile
1579         src/libstrongswan/plugins/rdrand/Makefile
1580         src/libstrongswan/plugins/random/Makefile
1581         src/libstrongswan/plugins/nonce/Makefile
1582         src/libstrongswan/plugins/hmac/Makefile
1583         src/libstrongswan/plugins/xcbc/Makefile
1584         src/libstrongswan/plugins/x509/Makefile
1585         src/libstrongswan/plugins/revocation/Makefile
1586         src/libstrongswan/plugins/constraints/Makefile
1587         src/libstrongswan/plugins/acert/Makefile
1588         src/libstrongswan/plugins/pubkey/Makefile
1589         src/libstrongswan/plugins/pkcs1/Makefile
1590         src/libstrongswan/plugins/pkcs7/Makefile
1591         src/libstrongswan/plugins/pkcs8/Makefile
1592         src/libstrongswan/plugins/pkcs12/Makefile
1593         src/libstrongswan/plugins/pgp/Makefile
1594         src/libstrongswan/plugins/dnskey/Makefile
1595         src/libstrongswan/plugins/sshkey/Makefile
1596         src/libstrongswan/plugins/pem/Makefile
1597         src/libstrongswan/plugins/curl/Makefile
1598         src/libstrongswan/plugins/winhttp/Makefile
1599         src/libstrongswan/plugins/unbound/Makefile
1600         src/libstrongswan/plugins/soup/Makefile
1601         src/libstrongswan/plugins/ldap/Makefile
1602         src/libstrongswan/plugins/mysql/Makefile
1603         src/libstrongswan/plugins/sqlite/Makefile
1604         src/libstrongswan/plugins/padlock/Makefile
1605         src/libstrongswan/plugins/openssl/Makefile
1606         src/libstrongswan/plugins/gcrypt/Makefile
1607         src/libstrongswan/plugins/agent/Makefile
1608         src/libstrongswan/plugins/keychain/Makefile
1609         src/libstrongswan/plugins/pkcs11/Makefile
1610         src/libstrongswan/plugins/ctr/Makefile
1611         src/libstrongswan/plugins/ccm/Makefile
1612         src/libstrongswan/plugins/gcm/Makefile
1613         src/libstrongswan/plugins/af_alg/Makefile
1614         src/libstrongswan/plugins/ntru/Makefile
1615         src/libstrongswan/plugins/test_vectors/Makefile
1616         src/libstrongswan/tests/Makefile
1617         src/libhydra/Makefile
1618         src/libhydra/plugins/attr/Makefile
1619         src/libhydra/plugins/attr_sql/Makefile
1620         src/libhydra/plugins/kernel_netlink/Makefile
1621         src/libhydra/plugins/kernel_pfkey/Makefile
1622         src/libhydra/plugins/kernel_pfroute/Makefile
1623         src/libhydra/plugins/resolve/Makefile
1624         src/libipsec/Makefile
1625         src/libsimaka/Makefile
1626         src/libtls/Makefile
1627         src/libtls/tests/Makefile
1628         src/libradius/Makefile
1629         src/libtncif/Makefile
1630         src/libtnccs/Makefile
1631         src/libtnccs/plugins/tnc_tnccs/Makefile
1632         src/libtnccs/plugins/tnc_imc/Makefile
1633         src/libtnccs/plugins/tnc_imv/Makefile
1634         src/libtnccs/plugins/tnccs_11/Makefile
1635         src/libtnccs/plugins/tnccs_20/Makefile
1636         src/libtnccs/plugins/tnccs_dynamic/Makefile
1637         src/libpttls/Makefile
1638         src/libimcv/Makefile
1639         src/libimcv/plugins/imc_test/Makefile
1640         src/libimcv/plugins/imv_test/Makefile
1641         src/libimcv/plugins/imc_scanner/Makefile
1642         src/libimcv/plugins/imv_scanner/Makefile
1643         src/libimcv/plugins/imc_os/Makefile
1644         src/libimcv/plugins/imv_os/Makefile
1645         src/libimcv/plugins/imc_attestation/Makefile
1646         src/libimcv/plugins/imv_attestation/Makefile
1647         src/libimcv/plugins/imc_swid/Makefile
1648         src/libimcv/plugins/imv_swid/Makefile
1649         src/charon/Makefile
1650         src/charon-nm/Makefile
1651         src/charon-tkm/Makefile
1652         src/charon-cmd/Makefile
1653         src/charon-svc/Makefile
1654         src/charon-systemd/Makefile
1655         src/libcharon/Makefile
1656         src/libcharon/plugins/eap_aka/Makefile
1657         src/libcharon/plugins/eap_aka_3gpp2/Makefile
1658         src/libcharon/plugins/eap_dynamic/Makefile
1659         src/libcharon/plugins/eap_identity/Makefile
1660         src/libcharon/plugins/eap_md5/Makefile
1661         src/libcharon/plugins/eap_gtc/Makefile
1662         src/libcharon/plugins/eap_sim/Makefile
1663         src/libcharon/plugins/eap_sim_file/Makefile
1664         src/libcharon/plugins/eap_sim_pcsc/Makefile
1665         src/libcharon/plugins/eap_simaka_sql/Makefile
1666         src/libcharon/plugins/eap_simaka_pseudonym/Makefile
1667         src/libcharon/plugins/eap_simaka_reauth/Makefile
1668         src/libcharon/plugins/eap_mschapv2/Makefile
1669         src/libcharon/plugins/eap_tls/Makefile
1670         src/libcharon/plugins/eap_ttls/Makefile
1671         src/libcharon/plugins/eap_peap/Makefile
1672         src/libcharon/plugins/eap_tnc/Makefile
1673         src/libcharon/plugins/eap_radius/Makefile
1674         src/libcharon/plugins/xauth_generic/Makefile
1675         src/libcharon/plugins/xauth_eap/Makefile
1676         src/libcharon/plugins/xauth_pam/Makefile
1677         src/libcharon/plugins/xauth_noauth/Makefile
1678         src/libcharon/plugins/tnc_ifmap/Makefile
1679         src/libcharon/plugins/tnc_pdp/Makefile
1680         src/libcharon/plugins/socket_default/Makefile
1681         src/libcharon/plugins/socket_dynamic/Makefile
1682         src/libcharon/plugins/socket_win/Makefile
1683         src/libcharon/plugins/farp/Makefile
1684         src/libcharon/plugins/smp/Makefile
1685         src/libcharon/plugins/sql/Makefile
1686         src/libcharon/plugins/dnscert/Makefile
1687         src/libcharon/plugins/ipseckey/Makefile
1688         src/libcharon/plugins/medsrv/Makefile
1689         src/libcharon/plugins/medcli/Makefile
1690         src/libcharon/plugins/addrblock/Makefile
1691         src/libcharon/plugins/unity/Makefile
1692         src/libcharon/plugins/uci/Makefile
1693         src/libcharon/plugins/ha/Makefile
1694         src/libcharon/plugins/kernel_libipsec/Makefile
1695         src/libcharon/plugins/kernel_wfp/Makefile
1696         src/libcharon/plugins/kernel_iph/Makefile
1697         src/libcharon/plugins/whitelist/Makefile
1698         src/libcharon/plugins/lookip/Makefile
1699         src/libcharon/plugins/error_notify/Makefile
1700         src/libcharon/plugins/certexpire/Makefile
1701         src/libcharon/plugins/systime_fix/Makefile
1702         src/libcharon/plugins/led/Makefile
1703         src/libcharon/plugins/duplicheck/Makefile
1704         src/libcharon/plugins/coupling/Makefile
1705         src/libcharon/plugins/radattr/Makefile
1706         src/libcharon/plugins/osx_attr/Makefile
1707         src/libcharon/plugins/android_dns/Makefile
1708         src/libcharon/plugins/android_log/Makefile
1709         src/libcharon/plugins/maemo/Makefile
1710         src/libcharon/plugins/stroke/Makefile
1711         src/libcharon/plugins/vici/Makefile
1712         src/libcharon/plugins/updown/Makefile
1713         src/libcharon/plugins/dhcp/Makefile
1714         src/libcharon/plugins/unit_tester/Makefile
1715         src/libcharon/plugins/load_tester/Makefile
1716         src/stroke/Makefile
1717         src/ipsec/Makefile
1718         src/starter/Makefile
1719         src/starter/tests/Makefile
1720         src/_updown/Makefile
1721         src/_updown_espmark/Makefile
1722         src/_copyright/Makefile
1723         src/scepclient/Makefile
1724         src/aikgen/Makefile
1725         src/pki/Makefile
1726         src/pki/man/Makefile
1727         src/pool/Makefile
1728         src/dumm/Makefile
1729         src/dumm/ext/extconf.rb
1730         src/libfast/Makefile
1731         src/manager/Makefile
1732         src/medsrv/Makefile
1733         src/checksum/Makefile
1734         src/conftest/Makefile
1735         src/pt-tls-client/Makefile
1736         src/swanctl/Makefile
1737         scripts/Makefile
1738         testing/Makefile
1739 ])
1740
1741 # =================
1742 #  build man pages
1743 # =================
1744
1745 AC_CONFIG_FILES([
1746         conf/strongswan.conf.5.head
1747         conf/strongswan.conf.5.tail
1748         man/ipsec.conf.5
1749         man/ipsec.secrets.5
1750         src/charon-cmd/charon-cmd.8
1751         src/pki/man/pki.1
1752         src/pki/man/pki---gen.1
1753         src/pki/man/pki---issue.1
1754         src/pki/man/pki---keyid.1
1755         src/pki/man/pki---pkcs7.1
1756         src/pki/man/pki---print.1
1757         src/pki/man/pki---pub.1
1758         src/pki/man/pki---req.1
1759         src/pki/man/pki---self.1
1760         src/pki/man/pki---signcrl.1
1761         src/pki/man/pki---acert.1
1762         src/pki/man/pki---verify.1
1763         src/swanctl/swanctl.8
1764         src/swanctl/swanctl.conf.5.head
1765         src/swanctl/swanctl.conf.5.tail
1766 ])
1767
1768 AC_OUTPUT
1769
1770 # ========================
1771 #  report enabled plugins
1772 # ========================
1773
1774 AC_MSG_RESULT([])
1775 AC_MSG_RESULT([ strongSwan will be built with the following plugins])
1776 AC_MSG_RESULT([-----------------------------------------------------])
1777
1778 AC_MSG_RESULT([libstrongswan:$s_plugins])
1779 AC_MSG_RESULT([libcharon:    $c_plugins])
1780 AC_MSG_RESULT([libhydra:     $h_plugins])
1781 AC_MSG_RESULT([libtnccs:     $t_plugins])
1782 AC_MSG_RESULT([])