configure: Cache result of pthread_condattr_setclock() check
[strongswan.git] / configure.ac
1 #
2 # Copyright (C) 2007-2015 Tobias Brunner
3 # Copyright (C) 2006-2015 Andreas Steffen
4 # Copyright (C) 2006-2014 Martin Willi
5 # Hochschule fuer Technik Rapperswil
6 #
7 # This program is free software; you can redistribute it and/or modify it
8 # under the terms of the GNU General Public License as published by the
9 # Free Software Foundation; either version 2 of the License, or (at your
10 # option) any later version.  See <http://www.fsf.org/copyleft/gpl.txt>.
11 #
12 # This program is distributed in the hope that it will be useful, but
13 # WITHOUT ANY WARRANTY; without even the implied warranty of MERCHANTABILITY
14 # or FITNESS FOR A PARTICULAR PURPOSE.  See the GNU General Public License
15 # for more details.
16 #
17
18 # ============================
19 #  initialize & set some vars
20 # ============================
21
22 AC_INIT([strongSwan],[5.4.1dr4])
23 AM_INIT_AUTOMAKE(m4_esyscmd([
24         echo tar-ustar
25         echo subdir-objects
26         case `automake --version | head -n 1` in
27                 *" 1.9"*);;
28                 *" 1.10"*);;
29                 *" 1.11"*);;
30                 # don't use parallel test harness in 1.12 and up
31                 *) echo serial-tests;;
32         esac
33 ]))
34 m4_ifdef([AM_SILENT_RULES], [AM_SILENT_RULES])
35 AC_CONFIG_MACRO_DIR([m4/config])
36 AC_CONFIG_HEADERS([config.h])
37 AC_DEFINE([CONFIG_H_INCLUDED], [], [defined if config.h included])
38 PKG_PROG_PKG_CONFIG
39
40 m4_include(m4/macros/split-package-version.m4)
41 SPLIT_PACKAGE_VERSION
42
43 # =================================
44 #  check --enable-xxx & --with-xxx
45 # =================================
46
47 m4_include(m4/macros/with.m4)
48
49 ARG_WITH_SUBST([random-device],      [/dev/random], [set the device to read real random data from])
50 ARG_WITH_SUBST([urandom-device],     [/dev/urandom], [set the device to read pseudo random data from])
51 ARG_WITH_SUBST([strongswan-conf],    [${sysconfdir}/strongswan.conf], [set the strongswan.conf file location])
52 ARG_WITH_SUBST([resolv-conf],        [${sysconfdir}/resolv.conf], [set the file to use in DNS handler plugin])
53 ARG_WITH_SUBST([piddir],             [/var/run], [set path for PID and UNIX socket files])
54 ARG_WITH_SUBST([ipsecdir],           [${libexecdir%/}/ipsec], [set installation path for ipsec tools])
55 ARG_WITH_SUBST([ipseclibdir],        [${libdir%/}/ipsec], [set installation path for ipsec libraries])
56 ARG_WITH_SUBST([plugindir],          [${ipseclibdir%/}/plugins], [set the installation path of plugins])
57 ARG_WITH_SUBST([imcvdir],            [${ipseclibdir%/}/imcvs], [set the installation path of IMC and IMV dynamic librariers])
58 ARG_WITH_SUBST([nm-ca-dir],          [/usr/share/ca-certificates], [directory the NM backend uses to look up trusted root certificates])
59 ARG_WITH_SUBST([swanctldir],         [${sysconfdir}/swanctl], [base directory for swanctl configuration files and credentials])
60 ARG_WITH_SUBST([linux-headers],      [\${top_srcdir}/src/include], [set directory of linux header files to use])
61 ARG_WITH_SUBST([routing-table],      [220], [set routing table to use for IPsec routes])
62 ARG_WITH_SUBST([routing-table-prio], [220], [set priority for IPsec routing table])
63 ARG_WITH_SUBST([ipsec-script],       [ipsec], [change the name of the ipsec script])
64 ARG_WITH_SUBST([fips-mode],          [0], [set openssl FIPS mode: disabled(0), enabled(1), Suite B enabled(2)])
65
66 ARG_WITH_SET([tss],                  [no], [set implementation of the Trusted Computing Group's Software Stack (TSS). Currently the only supported value is "trousers"])
67 ARG_WITH_SET([capabilities],         [no], [set capability dropping library. Currently supported values are "libcap" and "native"])
68 ARG_WITH_SET([mpz_powm_sec],         [yes], [use the more side-channel resistant mpz_powm_sec in libgmp, if available])
69 ARG_WITH_SET([dev-headers],          [no], [install strongSwan development headers to directory.])
70 ARG_WITH_SET([printf-hooks],         [auto], [force the use of a specific printf hook implementation (auto, builtin, glibc, vstr).])
71 ARG_WITH_SET([rubygemdir],           ["gem environment gemdir"], [path to install ruby gems to])
72 ARG_WITH_SET([pythoneggdir],         ["main site-packages directory"], [path to install python eggs to to])
73
74 if test -n "$PKG_CONFIG"; then
75         systemdsystemunitdir_default=$($PKG_CONFIG --variable=systemdsystemunitdir systemd)
76 fi
77 ARG_WITH_SET([systemdsystemunitdir], [$systemdsystemunitdir_default], [directory for systemd service files])
78 AC_SUBST(systemdsystemunitdir)
79
80 AC_ARG_WITH(
81         [user],
82         AS_HELP_STRING([--with-user=user],[change user of the daemons to "user" after startup (default is "root").]),
83         [AC_DEFINE_UNQUOTED([IPSEC_USER], "$withval", [username to run daemon with])
84          AC_SUBST(ipsecuser, "$withval")],
85         [AC_SUBST(ipsecuser, "root")]
86 )
87
88 AC_ARG_WITH(
89         [group],
90         AS_HELP_STRING([--with-group=group],[change group of the daemons to "group" after startup (default is "root").]),
91         [AC_DEFINE_UNQUOTED(IPSEC_GROUP, "$withval", [groupname to run daemon with])
92          AC_SUBST(ipsecgroup, "$withval")],
93         [AC_SUBST(ipsecgroup, "root")]
94 )
95
96 AC_ARG_WITH(
97         [charon-udp-port],
98         AS_HELP_STRING([--with-charon-udp-port=port],[UDP port used by charon locally (default 500). Set to 0 to allocate randomly.]),
99         [AC_DEFINE_UNQUOTED(CHARON_UDP_PORT, [$withval], [UDP port used by charon locally])
100          AC_SUBST(charon_udp_port, [$withval])],
101         [AC_SUBST(charon_udp_port, 500)]
102 )
103
104 AC_ARG_WITH(
105         [charon-natt-port],
106         AS_HELP_STRING([--with-charon-natt-port=port],[UDP port used by charon locally in case a NAT is detected (must be different from charon-udp-port, default 4500). Set to 0 to allocate randomly.]),
107         [AC_DEFINE_UNQUOTED(CHARON_NATT_PORT, [$withval], [UDP post used by charon locally in case a NAT is detected])
108          AC_SUBST(charon_natt_port, [$withval])],
109         [AC_SUBST(charon_natt_port, 4500)]
110 )
111
112 AC_MSG_CHECKING([configured UDP ports ($charon_udp_port, $charon_natt_port)])
113 if test x$charon_udp_port != x0 -a x$charon_udp_port = x$charon_natt_port; then
114         AC_MSG_ERROR(the ports have to be different)
115 else
116         AC_MSG_RESULT(ok)
117 fi
118
119 # convert script name to uppercase
120 AC_SUBST(ipsec_script_upper, [`echo -n "$ipsec_script" | tr a-z A-Z`])
121
122 m4_include(m4/macros/enable-disable.m4)
123
124 # crypto plugins
125 ARG_DISBL_SET([aes],            [disable AES software implementation plugin.])
126 ARG_ENABL_SET([af-alg],         [enable AF_ALG crypto interface to Linux Crypto API.])
127 ARG_ENABL_SET([bliss],          [enable BLISS software implementation plugin.])
128 ARG_ENABL_SET([blowfish],       [enable Blowfish software implementation plugin.])
129 ARG_ENABL_SET([ccm],            [enables the CCM AEAD wrapper crypto plugin.])
130 ARG_ENABL_SET([chapoly],        [enables the ChaCha20/Poly1305 AEAD plugin.])
131 ARG_DISBL_SET([cmac],           [disable CMAC crypto implementation plugin.])
132 ARG_ENABL_SET([ctr],            [enables the Counter Mode wrapper crypto plugin.])
133 ARG_DISBL_SET([des],            [disable DES/3DES software implementation plugin.])
134 ARG_DISBL_SET([fips-prf],       [disable FIPS PRF software implementation plugin.])
135 ARG_ENABL_SET([gcm],            [enables the GCM AEAD wrapper crypto plugin.])
136 ARG_ENABL_SET([gcrypt],         [enables the libgcrypt plugin.])
137 ARG_DISBL_SET([gmp],            [disable GNU MP (libgmp) based crypto implementation plugin.])
138 ARG_DISBL_SET([hmac],           [disable HMAC crypto implementation plugin.])
139 ARG_ENABL_SET([md4],            [enable MD4 software implementation plugin.])
140 ARG_DISBL_SET([md5],            [disable MD5 software implementation plugin.])
141 ARG_DISBL_SET([nonce],          [disable nonce generation plugin.])
142 ARG_ENABL_SET([ntru],           [enables the NTRU crypto plugin.])
143 ARG_ENABL_SET([openssl],        [enables the OpenSSL crypto plugin.])
144 ARG_ENABL_SET([padlock],        [enables VIA Padlock crypto plugin.])
145 ARG_DISBL_SET([random],         [disable RNG implementation on top of /dev/(u)random.])
146 ARG_DISBL_SET([rc2],            [disable RC2 software implementation plugin.])
147 ARG_ENABL_SET([rdrand],         [enable Intel RDRAND random generator plugin.])
148 ARG_ENABL_SET([aesni],          [enable Intel AES-NI crypto plugin.])
149 ARG_DISBL_SET([sha1],           [disable SHA1 software implementation plugin.])
150 ARG_DISBL_SET([sha2],           [disable SHA256/SHA384/SHA512 software implementation plugin.])
151 ARG_ENABL_SET([sha3],           [enable SHA3_224/SHA3_256/SHA3_384/SHA3_512 software implementation plugin.])
152 ARG_DISBL_SET([xcbc],           [disable xcbc crypto implementation plugin.])
153 # encoding/decoding plugins
154 ARG_DISBL_SET([dnskey],         [disable DNS RR key decoding plugin.])
155 ARG_DISBL_SET([pem],            [disable PEM decoding plugin.])
156 ARG_DISBL_SET([pgp],            [disable PGP key decoding plugin.])
157 ARG_DISBL_SET([pkcs1],          [disable PKCS1 key decoding plugin.])
158 ARG_DISBL_SET([pkcs7],          [disable PKCS7 container support plugin.])
159 ARG_DISBL_SET([pkcs8],          [disable PKCS8 private key decoding plugin.])
160 ARG_DISBL_SET([pkcs12],         [disable PKCS12 container support plugin.])
161 ARG_DISBL_SET([pubkey],         [disable RAW public key support plugin.])
162 ARG_DISBL_SET([sshkey],         [disable SSH key decoding plugin.])
163 ARG_DISBL_SET([x509],           [disable X509 certificate implementation plugin.])
164 # fetcher/resolver plugins
165 ARG_ENABL_SET([curl],           [enable CURL fetcher plugin to fetch files via libcurl. Requires libcurl.])
166 ARG_ENABL_SET([files],          [enable simple file:// URI fetcher.])
167 ARG_ENABL_SET([ldap],           [enable LDAP fetching plugin to fetch files via libldap. Requires openLDAP.])
168 ARG_ENABL_SET([soup],           [enable soup fetcher plugin to fetch from HTTP via libsoup. Requires libsoup.])
169 ARG_ENABL_SET([unbound],        [enable UNBOUND resolver plugin to perform DNS queries via libunbound. Requires libldns and libunbound.])
170 ARG_ENABL_SET([winhttp],        [enable WinHTTP based HTTP/HTTPS fetching plugin.])
171 # database plugins
172 ARG_ENABL_SET([mysql],          [enable MySQL database support. Requires libmysqlclient_r.])
173 ARG_ENABL_SET([sqlite],         [enable SQLite database support. Requires libsqlite3.])
174 # authentication/credential plugins
175 ARG_ENABL_SET([addrblock],      [enables RFC 3779 address block constraint support.])
176 ARG_ENABL_SET([acert],          [enable X509 attribute certificate checking plugin.])
177 ARG_ENABL_SET([agent],          [enables the ssh-agent signing plugin.])
178 ARG_DISBL_SET([constraints],    [disable advanced X509 constraint checking plugin.])
179 ARG_ENABL_SET([coupling],       [enable IKEv2 plugin to couple peer certificates permanently to authentication.])
180 ARG_ENABL_SET([dnscert],        [enable DNSCERT authentication plugin.])
181 ARG_ENABL_SET([eap-sim],        [enable SIM authentication module for EAP.])
182 ARG_ENABL_SET([eap-sim-file],   [enable EAP-SIM backend based on a triplet file.])
183 ARG_ENABL_SET([eap-sim-pcsc],   [enable EAP-SIM backend based on a smartcard reader. Requires libpcsclite.])
184 ARG_ENABL_SET([eap-aka],        [enable EAP AKA authentication module.])
185 ARG_ENABL_SET([eap-aka-3gpp2],  [enable EAP AKA backend implementing 3GPP2 algorithms in software. Requires libgmp.])
186 ARG_ENABL_SET([eap-simaka-sql], [enable EAP-SIM/AKA backend based on a triplet/quintuplet SQL database.])
187 ARG_ENABL_SET([eap-simaka-pseudonym], [enable EAP-SIM/AKA pseudonym storage plugin.])
188 ARG_ENABL_SET([eap-simaka-reauth],    [enable EAP-SIM/AKA reauthentication data storage plugin.])
189 ARG_ENABL_SET([eap-identity],   [enable EAP module providing EAP-Identity helper.])
190 ARG_ENABL_SET([eap-md5],        [enable EAP MD5 (CHAP) authentication module.])
191 ARG_ENABL_SET([eap-gtc],        [enable EAP GTC authentication module.])
192 ARG_ENABL_SET([eap-mschapv2],   [enable EAP MS-CHAPv2 authentication module.])
193 ARG_ENABL_SET([eap-tls],        [enable EAP TLS authentication module.])
194 ARG_ENABL_SET([eap-ttls],       [enable EAP TTLS authentication module.])
195 ARG_ENABL_SET([eap-peap],       [enable EAP PEAP authentication module.])
196 ARG_ENABL_SET([eap-tnc],        [enable EAP TNC trusted network connect module.])
197 ARG_ENABL_SET([eap-dynamic],    [enable dynamic EAP proxy module.])
198 ARG_ENABL_SET([eap-radius],     [enable RADIUS proxy authentication module.])
199 ARG_ENABL_SET([ext-auth],       [enable plugin calling an external authorization script.])
200 ARG_ENABL_SET([ipseckey],       [enable IPSECKEY authentication plugin.])
201 ARG_ENABL_SET([keychain],       [enables OS X Keychain Services credential set.])
202 ARG_ENABL_SET([pkcs11],         [enables the PKCS11 token support plugin.])
203 ARG_DISBL_SET([revocation],     [disable X509 CRL/OCSP revocation check plugin.])
204 ARG_ENABL_SET([whitelist],      [enable peer identity whitelisting plugin.])
205 ARG_DISBL_SET([xauth-generic],  [disable generic XAuth backend.])
206 ARG_ENABL_SET([xauth-eap],      [enable XAuth backend using EAP methods to verify passwords.])
207 ARG_ENABL_SET([xauth-pam],      [enable XAuth backend using PAM to verify passwords.])
208 ARG_ENABL_SET([xauth-noauth],   [enable XAuth pseudo-backend that does not actually verify or even request any credentials.])
209 # kernel interfaces / sockets
210 ARG_DISBL_SET([kernel-netlink], [disable the netlink kernel interface.])
211 ARG_ENABL_SET([kernel-pfkey],   [enable the PF_KEY kernel interface.])
212 ARG_ENABL_SET([kernel-pfroute], [enable the PF_ROUTE kernel interface.])
213 ARG_ENABL_SET([kernel-iph],     [enable the Windows IP Helper based networking backend.])
214 ARG_ENABL_SET([kernel-libipsec],[enable the libipsec kernel interface.])
215 ARG_ENABL_SET([kernel-wfp],     [enable the Windows Filtering Platform IPsec backend.])
216 ARG_DISBL_SET([socket-default], [disable default socket implementation for charon.])
217 ARG_ENABL_SET([socket-dynamic], [enable dynamic socket implementation for charon])
218 ARG_ENABL_SET([socket-win],     [enable Winsock2 based socket implementation for charon])
219 # configuration/control plugins
220 ARG_DISBL_SET([stroke],         [disable charons stroke configuration backend.])
221 ARG_ENABL_SET([smp],            [enable SMP configuration and control interface. Requires libxml.])
222 ARG_ENABL_SET([sql],            [enable SQL database configuration backend.])
223 ARG_ENABL_SET([uci],            [enable OpenWRT UCI configuration plugin.])
224 ARG_DISBL_SET([vici],           [disable strongSwan IKE generic IPC interface plugin.])
225 # attribute provider/consumer plugins
226 ARG_ENABL_SET([android-dns],    [enable Android specific DNS handler.])
227 ARG_DISBL_SET([attr],           [disable strongswan.conf based configuration attribute plugin.])
228 ARG_ENABL_SET([attr-sql],       [enable SQL based configuration attribute plugin.])
229 ARG_ENABL_SET([dhcp],           [enable DHCP based attribute provider plugin.])
230 ARG_ENABL_SET([osx-attr],       [enable OS X SystemConfiguration attribute handler.])
231 ARG_ENABL_SET([p-cscf],         [enable plugin to request P-CSCF server addresses from an ePDG.])
232 ARG_DISBL_SET([resolve],        [disable resolve DNS handler plugin.])
233 ARG_ENABL_SET([unity],          [enables Cisco Unity extension plugin.])
234 # TNC modules/plugins
235 ARG_ENABL_SET([imc-test],       [enable IMC test module.])
236 ARG_ENABL_SET([imv-test],       [enable IMV test module.])
237 ARG_ENABL_SET([imc-scanner],    [enable IMC port scanner module.])
238 ARG_ENABL_SET([imv-scanner],    [enable IMV port scanner module.])
239 ARG_ENABL_SET([imc-os],         [enable IMC operating system module.])
240 ARG_ENABL_SET([imv-os],         [enable IMV operating system module.])
241 ARG_ENABL_SET([imc-attestation],[enable IMC attestation module.])
242 ARG_ENABL_SET([imv-attestation],[enable IMV attestation module.])
243 ARG_ENABL_SET([imc-swid],       [enable IMC swid module.])
244 ARG_ENABL_SET([imv-swid],       [enable IMV swid module.])
245 ARG_ENABL_SET([imc-hcd],        [enable IMC hcd module.])
246 ARG_ENABL_SET([imv-hcd],        [enable IMV hcd module.])
247 ARG_ENABL_SET([tnc-ifmap],      [enable TNC IF-MAP module. Requires libxml])
248 ARG_ENABL_SET([tnc-imc],        [enable TNC IMC module.])
249 ARG_ENABL_SET([tnc-imv],        [enable TNC IMV module.])
250 ARG_ENABL_SET([tnc-pdp],        [enable TNC policy decision point module.])
251 ARG_ENABL_SET([tnccs-11],       [enable TNCCS 1.1 protocol module. Requires libxml])
252 ARG_ENABL_SET([tnccs-20],       [enable TNCCS 2.0 protocol module.])
253 ARG_ENABL_SET([tnccs-dynamic],  [enable dynamic TNCCS protocol discovery module.])
254 # misc plugins
255 ARG_ENABL_SET([android-log],    [enable Android specific logger plugin.])
256 ARG_ENABL_SET([certexpire],     [enable CSV export of expiration dates of used certificates.])
257 ARG_ENABL_SET([connmark],       [enable connmark plugin using conntrack based marks to select return path SA.])
258 ARG_ENABL_SET([forecast],       [enable forecast plugin forwarding broadcast/multicast messages.])
259 ARG_ENABL_SET([duplicheck],     [advanced duplicate checking plugin using liveness checks.])
260 ARG_ENABL_SET([error-notify],   [enable error notification plugin.])
261 ARG_ENABL_SET([farp],           [enable ARP faking plugin that responds to ARP requests to peers virtual IP])
262 ARG_ENABL_SET([ha],             [enable high availability cluster plugin.])
263 ARG_ENABL_SET([led],            [enable plugin to control LEDs on IKEv2 activity using the Linux kernel LED subsystem.])
264 ARG_ENABL_SET([load-tester],    [enable load testing plugin for IKEv2 daemon.])
265 ARG_ENABL_SET([lookip],         [enable fast virtual IP lookup and notification plugin.])
266 ARG_ENABL_SET([maemo],          [enable Maemo specific plugin.])
267 ARG_ENABL_SET([radattr],        [enable plugin to inject and process custom RADIUS attributes as IKEv2 client.])
268 ARG_ENABL_SET([systime-fix],    [enable plugin to handle cert lifetimes with invalid system time gracefully.])
269 ARG_ENABL_SET([test-vectors],   [enable plugin providing crypto test vectors.])
270 ARG_DISBL_SET([updown],         [disable updown firewall script plugin.])
271 # programs/components
272 ARG_ENABL_SET([aikgen],         [enable AIK generator.])
273 ARG_DISBL_SET([charon],         [disable the IKEv1/IKEv2 keying daemon charon.])
274 ARG_ENABL_SET([cmd],            [enable the command line IKE client charon-cmd.])
275 ARG_ENABL_SET([conftest],       [enforce Suite B conformance test framework.])
276 ARG_ENABL_SET([dumm],           [enable the DUMM UML test framework.])
277 ARG_ENABL_SET([fast],           [enable libfast (FastCGI Application Server w/ templates.])
278 ARG_ENABL_SET([libipsec],       [enable user space IPsec implementation.])
279 ARG_ENABL_SET([manager],        [enable web management console (proof of concept).])
280 ARG_ENABL_SET([medcli],         [enable mediation client configuration database plugin.])
281 ARG_ENABL_SET([medsrv],         [enable mediation server web frontend and daemon plugin.])
282 ARG_ENABL_SET([nm],             [enable NetworkManager backend.])
283 ARG_DISBL_SET([pki],            [disable pki certificate utility.])
284 ARG_DISBL_SET([scepclient],     [disable SCEP client tool.])
285 ARG_DISBL_SET([scripts],        [disable additional utilities (found in directory scripts).])
286 ARG_ENABL_SET([svc],            [enable charon Windows service.])
287 ARG_ENABL_SET([systemd],        [enable systemd specific IKE daemon charon-systemd.])
288 ARG_DISBL_SET([swanctl],        [disable swanctl configuration and control tool.])
289 ARG_ENABL_SET([tkm],            [enable Trusted Key Manager support.])
290 # optional features
291 ARG_ENABL_SET([bfd-backtraces], [use binutils libbfd to resolve backtraces for memory leaks and segfaults.])
292 ARG_ENABL_SET([dbghelp-backtraces],[use dbghlp.dll on Windows to create and print backtraces for memory leaks and segfaults.])
293 ARG_DISBL_SET([ikev1],          [disable IKEv1 protocol support in charon.])
294 ARG_DISBL_SET([ikev2],          [disable IKEv2 protocol support in charon.])
295 ARG_ENABL_SET([integrity-test], [enable integrity testing of libstrongswan and plugins.])
296 ARG_DISBL_SET([load-warning],   [disable the charon plugin load option warning in starter.])
297 ARG_ENABL_SET([mediation],      [enable IKEv2 Mediation Extension.])
298 ARG_ENABL_SET([unwind-backtraces],[use libunwind to create backtraces for memory leaks and segfaults.])
299 ARG_ENABL_SET([ruby-gems],      [enable build of provided ruby gems.])
300 ARG_ENABL_SET([ruby-gems-install],[enable installation of provided ruby gems.])
301 ARG_ENABL_SET([python-eggs],    [enable build of provided python eggs.])
302 ARG_ENABL_SET([python-eggs-install],[enable installation of provided python eggs.])
303 ARG_ENABL_SET([perl-cpan],      [enable build of provided perl CPAN module.])
304 ARG_ENABL_SET([perl-cpan-install],[enable installation of provided CPAN module.])
305 # compile options
306 ARG_ENABL_SET([coverage],       [enable lcov coverage report generation.])
307 ARG_ENABL_SET([leak-detective], [enable malloc hooks to find memory leaks.])
308 ARG_ENABL_SET([lock-profiler],  [enable lock/mutex profiling code.])
309 ARG_ENABL_SET([log-thread-ids], [use thread ID, if available, instead of an incremented value starting from 1, to identify threads.])
310 ARG_ENABL_SET([monolithic],     [build monolithic version of libstrongswan that includes all enabled plugins. Similarly, the plugins of charon are assembled in libcharon.])
311
312 # ===================================
313 #  option to disable default options
314 # ===================================
315
316 ARG_DISBL_SET([defaults],       [disable all default plugins (they can be enabled with their respective --enable options)])
317
318 if test x$defaults = xfalse; then
319         for option in $enabled_by_default; do
320                 eval test x\${${option}_given} = xtrue && continue
321                 eval $option=false
322         done
323 fi
324
325 # ==============================
326 #  option to enable all options
327 # ==============================
328
329 ARG_ENABL_SET([all],            [enable all plugins and features (they can be disabled with their respective --disable options). Mainly for testing.])
330
331 if test x$all_given = xtrue; then
332         for option in $disabled_by_default; do
333                 eval test x\${${option}_given} = xtrue && continue
334                 eval $option=true
335         done
336 fi
337
338 # ===========================
339 #  set up compiler and flags
340 # ===========================
341
342 if test -z "$CFLAGS"; then
343         CFLAGS="-g -O2 -Wall -Wno-format -Wno-format-security -Wno-pointer-sign"
344 fi
345 AC_PROG_CC
346 AM_PROG_CC_C_O
347
348 AC_LIB_PREFIX
349 AC_C_BIGENDIAN
350
351 # =========================
352 #  check required programs
353 # =========================
354
355 LT_INIT
356 AC_PROG_INSTALL
357 AC_PROG_EGREP
358 AC_PROG_AWK
359 AC_PROG_LEX
360 AC_PROG_YACC
361 AM_PATH_PYTHON(,,[:])
362 AC_PATH_PROG([PERL], [perl], [], [$PATH:/bin:/usr/bin:/usr/local/bin])
363 AC_PATH_PROG([GPERF], [gperf], [], [$PATH:/bin:/usr/bin:/usr/local/bin])
364
365 # because gperf is not needed by end-users we just report it but do not abort on failure
366 AC_MSG_CHECKING([gperf version >= 3.0.0])
367 if test -x "$GPERF"; then
368         if test "`$GPERF --version | $AWK -F' ' '/^GNU gperf/ { print $3 }' | $AWK -F. '{ print $1 }'`" -ge "3"; then
369                 AC_MSG_RESULT([yes])
370         else
371                 AC_MSG_RESULT([no])
372         fi
373 else
374         AC_MSG_RESULT([not found])
375 fi
376
377 # ========================
378 #  dependency calculation
379 # ========================
380
381 if test x$xauth_generic_given = xfalse -a x$ikev1 = xfalse; then
382         xauth_generic=false;
383 fi
384
385 if test x$kernel_libipsec = xtrue; then
386         libipsec=true;
387 fi
388
389 if test x$eap_aka_3gpp2 = xtrue; then
390         gmp=true;
391 fi
392
393 if test x$eap_aka = xtrue; then
394         fips_prf=true;
395         simaka=true;
396 fi
397
398 if test x$eap_sim = xtrue; then
399         fips_prf=true;
400         simaka=true;
401 fi
402
403 if test x$eap_radius = xtrue -o x$radattr = xtrue -o x$tnc_pdp = xtrue; then
404         radius=true;
405 fi
406
407 if test x$tnc_imc = xtrue -o x$tnc_imv = xtrue -o x$tnccs_11 = xtrue -o x$tnccs_11 = xtrue -o x$tnccs_dynamic = xtrue -o x$eap_tnc = xtrue; then
408         tnc_tnccs=true;
409 fi
410
411 if test x$eap_tls = xtrue -o x$eap_ttls = xtrue -o x$eap_peap = xtrue -o x$tnc_tnccs = xtrue; then
412         tls=true;
413 fi
414
415 if test x$imc_test = xtrue -o x$imv_test = xtrue -o x$imc_scanner = xtrue -o x$imv_scanner = xtrue -o x$imc_os = xtrue -o x$imv_os = xtrue -o x$imc_attestation = xtrue -o x$imv_attestation = xtrue -o x$imc_swid = xtrue -o x$imv_swid = xtrue -o x$imc_hcd = xtrue -o x$imv_hcd = xtrue; then
416         imcv=true;
417 fi
418
419 if test x$fips_prf = xtrue; then
420         if test x$openssl = xfalse; then
421                 sha1=true;
422         fi
423 fi
424
425 if test x$swanctl = xtrue; then
426         vici=true
427 fi
428
429 if test x$smp = xtrue -o x$tnccs_11 = xtrue -o x$tnc_ifmap = xtrue; then
430         xml=true
431 fi
432
433 if test x$manager = xtrue; then
434         fast=true
435 fi
436
437 if test x$medsrv = xtrue; then
438         mediation=true
439         fast=true
440 fi
441
442 if test x$medcli = xtrue; then
443         mediation=true
444 fi
445
446 if test x$ruby_gems_install = xtrue; then
447         ruby_gems=true
448 fi
449
450 if test x$python_eggs_install = xtrue; then
451         python_eggs=true
452 fi
453
454 if test x$perl_cpan_install = xtrue; then
455         perl_cpan=true
456 fi
457
458 # ===========================================
459 #  check required libraries and header files
460 # ===========================================
461
462 AC_HEADER_STDBOOL
463 AC_FUNC_ALLOCA
464 AC_FUNC_STRERROR_R
465
466 #  libraries needed on some platforms but not on others
467 # ------------------------------------------------------
468 saved_LIBS=$LIBS
469
470 # FreeBSD and Mac OS X have dlopen integrated in libc, Linux needs libdl
471 LIBS=""
472 AC_SEARCH_LIBS(dlopen, dl, [DLLIB=$LIBS])
473 AC_SUBST(DLLIB)
474
475 # glibc's backtrace() can be replicated on FreeBSD with libexecinfo
476 LIBS=""
477 AC_SEARCH_LIBS(backtrace, execinfo, [BTLIB=$LIBS])
478 AC_CHECK_FUNCS(backtrace)
479 AC_SUBST(BTLIB)
480
481 # OpenSolaris needs libsocket and libnsl for socket()
482 LIBS=""
483 AC_SEARCH_LIBS(socket, socket, [SOCKLIB=$LIBS],
484         [AC_CHECK_LIB(nsl, socket, [SOCKLIB="-lsocket -lnsl"], [], [-lsocket])]
485 )
486 AC_SUBST(SOCKLIB)
487
488 # Android has pthread_* functions in bionic (libc), others need libpthread
489 LIBS=$DLLIB
490 AC_SEARCH_LIBS(pthread_create, pthread, [PTHREADLIB=$LIBS])
491 AC_SUBST(PTHREADLIB)
492
493 # uClibc requires explicit -latomic for __atomic_* operations
494 LIBS=""
495 AC_SEARCH_LIBS(__atomic_load, atomic, [ATOMICLIB=$LIBS])
496 AC_SUBST(ATOMICLIB)
497
498 LIBS=$saved_LIBS
499 # ------------------------------------------------------
500
501 AC_MSG_CHECKING(for dladdr)
502 AC_COMPILE_IFELSE(
503         [AC_LANG_PROGRAM(
504                 [[#define _GNU_SOURCE
505                   #include <dlfcn.h>]],
506                 [[Dl_info* info = 0;
507                   dladdr(0, info);]])],
508         [AC_MSG_RESULT([yes]); AC_DEFINE([HAVE_DLADDR], [], [have dladdr()])],
509         [AC_MSG_RESULT([no])]
510 )
511
512 # check if pthread_condattr_setclock(CLOCK_MONOTONIC) is supported
513 saved_LIBS=$LIBS
514 LIBS=$PTHREADLIB
515 AC_CACHE_CHECK([for pthread_condattr_setclock(CLOCK_MONOTONIC)],
516         [ss_cv_func_pthread_condattr_setclock_monotonic],
517         [AC_RUN_IFELSE(
518                 [AC_LANG_SOURCE(
519                         [[#include <pthread.h>
520                           int main() { pthread_condattr_t attr;
521                                 pthread_condattr_init(&attr);
522                                 return pthread_condattr_setclock(&attr, CLOCK_MONOTONIC);}]])],
523                 [ss_cv_func_pthread_condattr_setclock_monotonic=yes],
524                 [ss_cv_func_pthread_condattr_setclock_monotonic=no],
525                 # Check existence of pthread_condattr_setclock if cross-compiling
526                 [AC_CHECK_FUNCS(pthread_condattr_setclock,
527                         ss_cv_func_pthread_condattr_setclock_monotonic=unknown)]
528         )])
529 if test x$ss_cv_func_pthread_condattr_setclock_monotonic = xyes; then
530         AC_DEFINE([HAVE_CONDATTR_CLOCK_MONOTONIC], [],
531                           [pthread_condattr_setclock supports CLOCK_MONOTONIC])
532 elif test x$ss_cv_func_pthread_condattr_setclock_monotonic = xunknown; then
533         AC_DEFINE([HAVE_CONDATTR_CLOCK_MONOTONIC], [],
534                           [have pthread_condattr_setclock()])
535 fi
536
537 # check if we actually are able to configure attributes on cond vars
538 AC_CHECK_FUNCS(pthread_condattr_init)
539 # instead of pthread_condattr_setclock Android has this function
540 AC_CHECK_FUNCS(pthread_cond_timedwait_monotonic)
541 # check if we can cancel threads
542 AC_CHECK_FUNCS(pthread_cancel)
543 # check if native rwlocks are available
544 AC_CHECK_FUNCS(pthread_rwlock_init)
545 # check if pthread spinlocks are available
546 AC_CHECK_FUNCS(pthread_spin_init)
547 # check if we have POSIX semaphore functions, including timed-wait
548 AC_CHECK_FUNCS(sem_timedwait)
549 LIBS=$saved_LIBS
550
551 AC_CHECK_FUNC(
552         [gettid],
553         [AC_DEFINE([HAVE_GETTID], [], [have gettid()])],
554         [AC_MSG_CHECKING([for SYS_gettid])
555          AC_COMPILE_IFELSE(
556                 [AC_LANG_PROGRAM(
557                         [[#define _GNU_SOURCE
558                           #include <unistd.h>
559                           #include <sys/syscall.h>]],
560                         [[int main() {
561                           return syscall(SYS_gettid);}]])],
562                 [AC_MSG_RESULT([yes]);
563                  AC_DEFINE([HAVE_GETTID], [], [have gettid()])
564                  AC_DEFINE([HAVE_SYS_GETTID], [], [have syscall(SYS_gettid)])],
565                 [AC_MSG_RESULT([no])]
566         )]
567 )
568
569 AC_CHECK_FUNC(
570         [qsort_r],
571         [
572                 AC_DEFINE([HAVE_QSORT_R], [], [have qsort_r()])
573                 # set -Werror so that we get an error for "argument ... has
574                 # incompatible pointer type" warnings
575                 save_CFLAGS="$CFLAGS"
576                 CFLAGS="$CFLAGS -Werror -Wno-unused-parameter"
577                 AC_MSG_CHECKING([for GNU-style qsort_r])
578                 AC_COMPILE_IFELSE(
579                         [AC_LANG_PROGRAM(
580                                 [[#define _GNU_SOURCE
581                                   #include <stdlib.h>
582                                   int cmp (const void *a, const void *b, void *x) { return 0; }]],
583                                 [[int arr[] = { 0, 1 };
584                                   qsort_r(arr, 2, sizeof(int), cmp, arr);]])],
585                 [AC_MSG_RESULT([yes]);
586                  AC_DEFINE([HAVE_QSORT_R_GNU], [], [have GNU-style qsort_r()])],
587                 [
588                         AC_MSG_RESULT([no]);
589                         AC_MSG_CHECKING([for BSD-style qsort_r])
590                         AC_COMPILE_IFELSE(
591                                 [AC_LANG_PROGRAM(
592                                         [[#include <stdlib.h>
593                                           int cmp (void *x, const void *a, const void *b) { return 0; }]],
594                                         [[int arr[] = { 0, 1 };
595                                           qsort_r(arr, 2, sizeof(int), arr, cmp);]])],
596                         [AC_MSG_RESULT([yes]);
597                          AC_DEFINE([HAVE_QSORT_R_BSD], [], [have BSD-style qsort_r()])],
598                         [AC_MSG_RESULT([no]);
599                          AC_MSG_FAILURE([qsort_r has unknown semantics])])
600                 ])
601                 CFLAGS="$save_CFLAGS"
602         ]
603 )
604
605 AC_CHECK_FUNCS(prctl mallinfo getpass closefrom getpwnam_r getgrnam_r getpwuid_r)
606 AC_CHECK_FUNCS(fmemopen funopen mmap memrchr setlinebuf strptime dirfd sigwaitinfo)
607
608 AC_CHECK_FUNC([syslog], [
609         AC_DEFINE([HAVE_SYSLOG], [], [have syslog(3) and friends])
610         syslog=true
611 ])
612 AM_CONDITIONAL(USE_SYSLOG, [test "x$syslog" = xtrue])
613
614 AC_CHECK_HEADERS(sys/sockio.h sys/syscall.h glob.h net/if_tun.h)
615 AC_CHECK_HEADERS(net/pfkeyv2.h netipsec/ipsec.h netinet6/ipsec.h linux/udp.h)
616 AC_CHECK_HEADERS([netinet/ip6.h linux/fib_rules.h], [], [],
617 [
618         #include <sys/types.h>
619         #include <netinet/in.h>
620 ])
621
622 AC_CHECK_MEMBERS([struct sockaddr.sa_len], [], [],
623 [
624         #include <sys/types.h>
625         #include <sys/socket.h>
626 ])
627
628 AC_CHECK_MEMBERS([struct sadb_x_policy.sadb_x_policy_priority], [], [],
629 [
630         #include <sys/types.h>
631         #ifdef HAVE_NET_PFKEYV2_H
632         #include <net/pfkeyv2.h>
633         #else
634         #include <stdint.h>
635         #include <linux/pfkeyv2.h>
636         #endif
637 ])
638
639 AC_MSG_CHECKING([for in6addr_any])
640 AC_COMPILE_IFELSE(
641         [AC_LANG_PROGRAM(
642                 [[#include <sys/types.h>
643                   #include <sys/socket.h>
644                   #include <netinet/in.h>]],
645                 [[struct in6_addr in6 __attribute__((unused));
646                   in6 = in6addr_any;]])],
647         [AC_MSG_RESULT([yes]);
648          AC_DEFINE([HAVE_IN6ADDR_ANY], [], [have struct in6_addr in6addr_any])],
649         [AC_MSG_RESULT([no])]
650 )
651
652 AC_MSG_CHECKING([for in6_pktinfo])
653 AC_COMPILE_IFELSE(
654         [AC_LANG_PROGRAM(
655                 [[#define _GNU_SOURCE
656                   #include <sys/types.h>
657                   #include <sys/socket.h>
658                   #include <netinet/in.h>]],
659                 [[struct in6_pktinfo pi;
660                   if (pi.ipi6_ifindex)
661                   {
662                     return 0;
663                   }]])],
664         [AC_MSG_RESULT([yes]);
665          AC_DEFINE([HAVE_IN6_PKTINFO], [], [have struct in6_pktinfo.ipi6_ifindex])],
666         [AC_MSG_RESULT([no])]
667 )
668
669 AC_MSG_CHECKING([for RTM_IFANNOUNCE])
670 AC_COMPILE_IFELSE(
671         [AC_LANG_PROGRAM(
672                 [[#include <sys/socket.h>
673                   #include <net/if.h>
674                   #include <net/route.h>]],
675                 [[return RTM_IFANNOUNCE;]])],
676         [AC_MSG_RESULT([yes]);
677          AC_DEFINE([HAVE_RTM_IFANNOUNCE], [], [have PF_ROUTE RTM_IFANNOUNCE defined])],
678         [AC_MSG_RESULT([no])]
679 )
680
681 AC_MSG_CHECKING([for IPSEC_MODE_BEET])
682 AC_COMPILE_IFELSE(
683         [AC_LANG_PROGRAM(
684                 [[#include <sys/types.h>
685                   #ifdef HAVE_NETIPSEC_IPSEC_H
686                   #include <netipsec/ipsec.h>
687                   #elif defined(HAVE_NETINET6_IPSEC_H)
688                   #include <netinet6/ipsec.h>
689                   #else
690                   #include <stdint.h>
691                   #include <linux/ipsec.h>
692                   #endif]],
693                 [[int mode = IPSEC_MODE_BEET;
694                   return mode;]])],
695         [AC_MSG_RESULT([yes]);
696          AC_DEFINE([HAVE_IPSEC_MODE_BEET], [], [have IPSEC_MODE_BEET defined])],
697         [AC_MSG_RESULT([no])]
698 )
699
700 AC_MSG_CHECKING([for IPSEC_DIR_FWD])
701 AC_COMPILE_IFELSE(
702         [AC_LANG_PROGRAM(
703                 [[#include <sys/types.h>
704                   #ifdef HAVE_NETIPSEC_IPSEC_H
705                   #include <netipsec/ipsec.h>
706                   #elif defined(HAVE_NETINET6_IPSEC_H)
707                   #include <netinet6/ipsec.h>
708                   #else
709                   #include <stdint.h>
710                   #include <linux/ipsec.h>
711                   #endif]],
712                 [[int dir = IPSEC_DIR_FWD;
713                   return dir;]])],
714         [AC_MSG_RESULT([yes]);
715          AC_DEFINE([HAVE_IPSEC_DIR_FWD], [], [have IPSEC_DIR_FWD defined])],
716         [AC_MSG_RESULT([no])]
717 )
718
719 AC_MSG_CHECKING([for RTA_TABLE])
720 AC_COMPILE_IFELSE(
721         [AC_LANG_PROGRAM(
722                 [[#include <sys/socket.h>
723                   #include <linux/netlink.h>
724                   #include <linux/rtnetlink.h>]],
725                 [[int rta_type = RTA_TABLE;
726                   return rta_type;]])],
727         [AC_MSG_RESULT([yes]);
728          AC_DEFINE([HAVE_RTA_TABLE], [], [have netlink RTA_TABLE defined])],
729         [AC_MSG_RESULT([no])]
730 )
731
732 AC_MSG_CHECKING([for __int128])
733 AC_COMPILE_IFELSE(
734         [AC_LANG_PROGRAM(
735                 [[#include <sys/types.h>]],
736                 [[__int128 x = 0;
737                   return x;]])],
738         [AC_MSG_RESULT([yes]);
739          AC_DEFINE([HAVE_INT128], [], [have __int128 type support])],
740         [AC_MSG_RESULT([no])]
741 )
742
743 AC_MSG_CHECKING([for GCC __sync operations])
744 AC_RUN_IFELSE([AC_LANG_SOURCE(
745         [[
746                         int main() {
747                         int ref = 1;
748                         __sync_fetch_and_add (&ref, 1);
749                         __sync_sub_and_fetch (&ref, 1);
750                         __sync_val_compare_and_swap(&ref, 1, 0);
751                         return ref;
752                 }
753         ]])],
754         [AC_MSG_RESULT([yes]);
755          AC_DEFINE([HAVE_GCC_SYNC_OPERATIONS], [],
756                    [have GCC __sync_* operations])],
757         [AC_MSG_RESULT([no])],
758         [AC_MSG_RESULT([no])]
759 )
760
761 case "$printf_hooks" in
762 auto|builtin|glibc|vstr)
763         ;;
764 *)
765         AC_MSG_NOTICE([invalid printf hook implementation, defaulting to 'auto'])
766         printf_hooks=auto
767         ;;
768 esac
769
770 if test x$printf_hooks = xauto -o x$printf_hooks = xglibc; then
771         # check for the new register_printf_specifier function with len argument,
772         # or the deprecated register_printf_function without
773         AC_CHECK_FUNC(
774                 [register_printf_specifier],
775                 [AC_DEFINE([HAVE_PRINTF_SPECIFIER], [], [have register_printf_specifier()])],
776                 [AC_CHECK_FUNC(
777                         [register_printf_function],
778                         [AC_DEFINE([HAVE_PRINTF_FUNCTION], [], [have register_printf_function()])],
779                         [
780                                 AC_MSG_NOTICE([printf(3) does not support custom format specifiers!])
781                                 if test x$printf_hooks = xglibc; then
782                                         AC_MSG_ERROR([please select a different printf hook implementation])
783                                 else
784                                         # fallback to builtin printf hook implementation
785                                         printf_hooks=builtin
786                                 fi
787                         ]
788                 )]
789         )
790 fi
791
792 AC_MSG_CHECKING([for Windows target])
793 AC_COMPILE_IFELSE(
794         [AC_LANG_PROGRAM(
795                 [[#include <windows.h>]],
796                 [[#ifndef WIN32
797                   # error WIN32 undefined
798                   #endif
799                 ]])],
800         [
801                 AC_MSG_RESULT([yes])
802                 windows=true
803                 openssl_lib=eay32
804                 AC_SUBST(PTHREADLIB, "")
805                 # explicitly disable ms-bitfields, as it breaks __attribute__((packed))
806                 case "$CFLAGS" in
807                         *ms-bitfields*) ;;
808                         *) CFLAGS="$CFLAGS -mno-ms-bitfields" ;;
809                 esac
810         ],
811         [
812                 AC_MSG_RESULT([no])
813                 openssl_lib=crypto
814
815                 # check for clock_gettime() on non-Windows only. Otherwise this
816                 # check might find clock_gettime() in libwinpthread, but we don't want
817                 # to link against it.
818                 saved_LIBS=$LIBS
819                 # FreeBSD has clock_gettime in libc, Linux needs librt
820                 LIBS=""
821                 AC_SEARCH_LIBS(clock_gettime, rt, [RTLIB=$LIBS])
822                 AC_CHECK_FUNCS(clock_gettime)
823                 AC_SUBST(RTLIB)
824                 LIBS=$saved_LIBS
825         ]
826 )
827 AC_SUBST(OPENSSL_LIB, [-l$openssl_lib])
828 AM_CONDITIONAL(USE_WINDOWS, [test "x$windows" = xtrue])
829
830 AC_MSG_CHECKING([for working __attribute__((packed))])
831 AC_COMPILE_IFELSE(
832         [AC_LANG_PROGRAM([], [[
833                 struct test { char a; short b; } __attribute__((packed));
834                 char x[sizeof(struct test) == sizeof(char) + sizeof(short) ? 1 : -1]
835                         __attribute__((unused));
836                 return 0;
837         ]])],
838         [AC_MSG_RESULT([yes])],
839         [AC_MSG_RESULT([no]); AC_MSG_ERROR([__attribute__((packed)) does not work])]
840 )
841
842 AC_MSG_CHECKING([clang])
843 AC_COMPILE_IFELSE(
844         [AC_LANG_PROGRAM(
845                 [], [[
846                  #ifndef __clang__
847                  # error not using LLVM clang
848                  #endif
849                 ]])],
850         [
851                 AC_MSG_RESULT([yes])
852         ],
853         [
854                 AC_MSG_RESULT([no])
855                 # GCC, but not MinGW requires -rdynamic for plugins
856                 if test x$windows != xtrue; then
857                         AC_SUBST(PLUGIN_CFLAGS, [-rdynamic])
858                 fi
859         ]
860 )
861
862 AC_MSG_CHECKING([x86/x64 target])
863 AC_COMPILE_IFELSE(
864         [AC_LANG_PROGRAM(
865                 [], [[
866                  #if !defined(__i386__) && !defined(__x86_64__)
867                  # error not on x86/x64
868                  #endif
869                 ]])],
870         [
871                 x86x64=true
872                 AC_MSG_RESULT([yes])
873         ],
874         [AC_MSG_RESULT([no])]
875 )
876 AM_CONDITIONAL(USE_X86X64, [test "x$x86x64" = xtrue])
877
878 if test x$printf_hooks = xvstr; then
879         AC_CHECK_LIB([vstr],[main],[LIBS="$LIBS"],[AC_MSG_ERROR([Vstr string library not found])],[])
880         AC_DEFINE([USE_VSTR], [], [use Vstr string library for printf hooks])
881 fi
882
883 if test x$printf_hooks = xbuiltin; then
884         AC_DEFINE([USE_BUILTIN_PRINTF], [], [using builtin printf for printf hooks])
885 fi
886
887 if test x$gmp = xtrue; then
888         saved_LIBS=$LIBS
889         AC_CHECK_LIB([gmp],[main],[],[AC_MSG_ERROR([GNU Multi Precision library gmp not found])],[])
890         AC_MSG_CHECKING([mpz_powm_sec])
891         if test x$mpz_powm_sec = xyes; then
892                 AC_COMPILE_IFELSE(
893                         [AC_LANG_PROGRAM(
894                                 [[#include "gmp.h"]],
895                                 [[void *x = mpz_powm_sec;]])],
896                         [AC_MSG_RESULT([yes]);
897                          AC_DEFINE([HAVE_MPZ_POWM_SEC], [], [have mpz_mown_sec()])],
898                         [AC_MSG_RESULT([no])]
899                 )
900         else
901                 AC_MSG_RESULT([disabled])
902         fi
903         LIBS=$saved_LIBS
904         AC_MSG_CHECKING([gmp.h version >= 4.1.4])
905         AC_COMPILE_IFELSE(
906                 [AC_LANG_PROGRAM(
907                         [[#include "gmp.h"]],
908                         [[
909                                 #if (__GNU_MP_VERSION*100 +  __GNU_MP_VERSION_MINOR*10 + __GNU_MP_VERSION_PATCHLEVEL) < 414
910                                         #error bad gmp
911                                 #endif]])],
912                 [AC_MSG_RESULT([yes])],
913                 [AC_MSG_RESULT([no]); AC_MSG_ERROR([No usable gmp.h found!])]
914         )
915 fi
916
917 if test x$ldap = xtrue; then
918         AC_CHECK_LIB([ldap],[main],[LIBS="$LIBS"],[AC_MSG_ERROR([LDAP library ldap not found])],[])
919         AC_CHECK_LIB([lber],[main],[LIBS="$LIBS"],[AC_MSG_ERROR([LDAP library lber not found])],[])
920         AC_CHECK_HEADER([ldap.h],,[AC_MSG_ERROR([LDAP header ldap.h not found!])])
921 fi
922
923 if test x$curl = xtrue; then
924         AC_CHECK_LIB([curl],[main],[LIBS="$LIBS"],[AC_MSG_ERROR([CURL library curl not found])],[])
925         AC_CHECK_HEADER([curl/curl.h],,[AC_MSG_ERROR([CURL header curl/curl.h not found!])])
926 fi
927
928 if test x$unbound = xtrue; then
929         AC_CHECK_LIB([ldns],[main],[LIBS="$LIBS"],[AC_MSG_ERROR([UNBOUND library ldns not found])],[])
930         AC_CHECK_HEADER([ldns/ldns.h],,[AC_MSG_ERROR([UNBOUND header ldns/ldns.h not found!])])
931         AC_CHECK_LIB([unbound],[main],[LIBS="$LIBS"],[AC_MSG_ERROR([UNBOUND library libunbound not found])],[])
932         AC_CHECK_HEADER([unbound.h],,[AC_MSG_ERROR([UNBOUND header unbound.h not found!])])
933 fi
934
935 if test x$soup = xtrue; then
936         PKG_CHECK_MODULES(soup, [libsoup-2.4])
937         AC_SUBST(soup_CFLAGS)
938         AC_SUBST(soup_LIBS)
939 fi
940
941 if test x$xml = xtrue; then
942         PKG_CHECK_MODULES(xml, [libxml-2.0])
943         AC_SUBST(xml_CFLAGS)
944         AC_SUBST(xml_LIBS)
945 fi
946
947 if test x$systemd = xtrue; then
948         AC_MSG_CHECKING([for systemd system unit directory])
949         if test -n "$systemdsystemunitdir" -a "x$systemdsystemunitdir" != xno; then
950                 AC_MSG_RESULT([$systemdsystemunitdir])
951         else
952                 AC_MSG_ERROR([not found (try --with-systemdsystemunitdir)])
953         fi
954
955         PKG_CHECK_MODULES(systemd, [libsystemd >= 209],
956                 [AC_SUBST(systemd_CFLAGS)
957                  AC_SUBST(systemd_LIBS)],
958                 [PKG_CHECK_MODULES(systemd_daemon, [libsystemd-daemon])
959                  AC_SUBST(systemd_daemon_CFLAGS)
960                  AC_SUBST(systemd_daemon_LIBS)
961                  PKG_CHECK_MODULES(systemd_journal, [libsystemd-journal])
962                  AC_SUBST(systemd_journal_CFLAGS)
963                  AC_SUBST(systemd_journal_LIBS)]
964         )
965 fi
966
967 if test x$tss = xtrousers; then
968         AC_CHECK_LIB([tspi],[main],[LIBS="$LIBS"],[AC_MSG_ERROR([TrouSerS library libtspi not found])],[])
969         AC_CHECK_HEADER([trousers/tss.h],,[AC_MSG_ERROR([TrouSerS header trousers/tss.h not found!])])
970         AC_DEFINE([TSS_TROUSERS], [], [use TrouSerS library libtspi as TSS implementation])
971 fi
972
973 if test x$imv_swid = xtrue; then
974         PKG_CHECK_MODULES(json, [json-c], [],
975                 [PKG_CHECK_MODULES(json, [json])])
976         AC_SUBST(json_CFLAGS)
977         AC_SUBST(json_LIBS)
978 fi
979
980 if test x$dumm = xtrue; then
981         PKG_CHECK_MODULES(gtk, [gtk+-2.0 vte])
982         AC_SUBST(gtk_CFLAGS)
983         AC_SUBST(gtk_LIBS)
984         AC_CHECK_PROGS(RUBY, ruby)
985         AC_MSG_CHECKING([for Ruby header files])
986         if test -n "$RUBY"; then
987                 RUBYINCLUDE=
988                 RUBYDIR=`($RUBY -r rbconfig -e 'print RbConfig::CONFIG[["rubyhdrdir"]] || ""') 2>/dev/null`
989                 if test -n "$RUBYDIR" -a -r "$RUBYDIR/ruby.h"; then
990                         RUBYARCH=`($RUBY -r rbconfig -e 'print RbConfig::CONFIG[["arch"]] || ""') 2>/dev/null`
991                         if test -n "$RUBYARCH"; then
992                                 AC_MSG_RESULT([$RUBYDIR])
993                                 RUBYINCLUDE="-I$RUBYDIR -I$RUBYDIR/$RUBYARCH"
994                         fi
995                 else
996                         RUBYDIR=`($RUBY -r rbconfig -e 'print RbConfig::CONFIG[["archdir"]] || ""') 2>/dev/null`
997                         if test -n "$RUBYDIR" -a -r "$RUBYDIR/ruby.h"; then
998                                 AC_MSG_RESULT([$RUBYDIR])
999                                 RUBYINCLUDE="-I$RUBYDIR"
1000                         fi
1001                 fi
1002                 if test -z "$RUBYINCLUDE"; then
1003                         AC_MSG_ERROR([ruby.h not found])
1004                 fi
1005                 AC_SUBST(RUBYINCLUDE)
1006         else
1007                 AC_MSG_ERROR([don't know how to run ruby])
1008         fi
1009         AC_MSG_CHECKING([for libruby])
1010         saved_LIBS=$LIBS
1011         LIBS=`($RUBY -r rbconfig -e 'print RbConfig::CONFIG[["LIBRUBYARG_SHARED"]] || ""') 2>/dev/null`
1012         AC_TRY_LINK_FUNC(ruby_init,
1013                 [AC_MSG_RESULT([$LIBS]); RUBYLIB=$LIBS],
1014                 [AC_MSG_ERROR([not found])])
1015         AC_SUBST(RUBYLIB)
1016         AC_CHECK_FUNCS(rb_errinfo)
1017         LIBS=$saved_LIBS
1018 fi
1019
1020 if test x$fast = xtrue; then
1021         AC_CHECK_LIB([neo_cgi],[main],[LIBS="$LIBS"],[AC_MSG_ERROR([ClearSilver library neo_cgi not found!])],[])
1022         AC_CHECK_LIB([neo_utl],[main],[LIBS="$LIBS"],[AC_MSG_ERROR([ClearSilver library neo_utl not found!])],[])
1023         AC_MSG_CHECKING([ClearSilver requires zlib])
1024         saved_CFLAGS=$CFLAGS
1025         saved_LIBS=$LIBS
1026         LIBS="-lneo_cgi -lneo_cs -lneo_utl"
1027         CFLAGS="-I/usr/include/ClearSilver"
1028         AC_LINK_IFELSE(
1029                 [AC_LANG_PROGRAM(
1030                         [[#include <ClearSilver.h>]],
1031                         [[NEOERR *err = cgi_display(NULL, NULL);]])],
1032                 [AC_MSG_RESULT([no]); clearsilver_LIBS="$LIBS"],
1033                 [AC_MSG_RESULT([yes]); clearsilver_LIBS="$LIBS -lz"]
1034         )
1035         AC_SUBST(clearsilver_LIBS)
1036         LIBS=$saved_LIBS
1037         CFLAGS=$saved_CFLAGS
1038 # autoconf does not like CamelCase!? How to fix this?
1039 #       AC_CHECK_HEADER([ClearSilver/ClearSilver.h],,[AC_MSG_ERROR([ClearSilver header file ClearSilver/ClearSilver.h not found!])])
1040
1041         AC_CHECK_LIB([fcgi],[main],[LIBS="$LIBS"],[AC_MSG_ERROR([FastCGI library fcgi not found!])],[])
1042         AC_CHECK_HEADER([fcgiapp.h],,[AC_MSG_ERROR([FastCGI header file fcgiapp.h not found!])])
1043 fi
1044
1045 if test x$mysql = xtrue; then
1046         if test "x$windows" = xtrue; then
1047                 AC_CHECK_HEADER([mysql.h],,[AC_MSG_ERROR([MySQL header file mysql.h not found!])])
1048                 AC_CHECK_LIB([mysql],[main],[LIBS="$LIBS"],[AC_MSG_ERROR([MySQL library not found!])],[])
1049                 AC_SUBST(MYSQLLIB, -lmysql)
1050         else
1051                 AC_PATH_PROG([MYSQLCONFIG], [mysql_config], [], [$PATH:/bin:/usr/bin:/usr/local/bin])
1052                 if test x$MYSQLCONFIG = x; then
1053                         AC_MSG_ERROR([mysql_config not found!])
1054                 fi
1055                 AC_SUBST(MYSQLLIB, `$MYSQLCONFIG --libs_r`)
1056                 AC_SUBST(MYSQLCFLAG, `$MYSQLCONFIG --cflags`)
1057         fi
1058 fi
1059
1060 if test x$sqlite = xtrue; then
1061         AC_CHECK_LIB([sqlite3],[main],[LIBS="$LIBS"],[AC_MSG_ERROR([SQLite library sqlite3 not found])],[])
1062         AC_CHECK_HEADER([sqlite3.h],,[AC_MSG_ERROR([SQLite header sqlite3.h not found!])])
1063         AC_MSG_CHECKING([sqlite3_prepare_v2])
1064         AC_COMPILE_IFELSE(
1065                 [AC_LANG_PROGRAM(
1066                         [[#include <sqlite3.h>]],
1067                         [[void *test = sqlite3_prepare_v2;]])],
1068                 [AC_MSG_RESULT([yes]);
1069                  AC_DEFINE([HAVE_SQLITE3_PREPARE_V2], [], [have sqlite3_prepare_v2()])],
1070                 [AC_MSG_RESULT([no])]
1071         )
1072         AC_MSG_CHECKING([sqlite3.h version >= 3.3.1])
1073         AC_COMPILE_IFELSE(
1074                 [AC_LANG_PROGRAM(
1075                         [[#include <sqlite3.h>]],
1076                         [[
1077                                 #if SQLITE_VERSION_NUMBER < 3003001
1078                                         #error bad sqlite
1079                                 #endif]])],
1080                 [AC_MSG_RESULT([yes])],
1081                 [AC_MSG_RESULT([no]); AC_MSG_ERROR([SQLite version >= 3.3.1 required!])]
1082         )
1083 fi
1084
1085 if test x$openssl = xtrue; then
1086         AC_CHECK_LIB([$openssl_lib],[main],[LIBS="$LIBS"],
1087                                  [AC_MSG_ERROR([OpenSSL lib$openssl_lib not found])],[$DLLIB])
1088         AC_CHECK_HEADER([openssl/evp.h],,[AC_MSG_ERROR([OpenSSL header openssl/evp.h not found!])])
1089 fi
1090
1091 if test x$gcrypt = xtrue; then
1092         AC_CHECK_LIB([gcrypt],[main],[LIBS="$LIBS"],[AC_MSG_ERROR([gcrypt library not found])],[-lgpg-error])
1093         AC_CHECK_HEADER([gcrypt.h],,[AC_MSG_ERROR([gcrypt header gcrypt.h not found!])])
1094         AC_MSG_CHECKING([gcrypt CAMELLIA cipher])
1095         AC_COMPILE_IFELSE(
1096                 [AC_LANG_PROGRAM(
1097                         [[#include <gcrypt.h>]],
1098                         [[enum gcry_cipher_algos alg = GCRY_CIPHER_CAMELLIA128;]])],
1099                 [AC_MSG_RESULT([yes]);
1100                  AC_DEFINE([HAVE_GCRY_CIPHER_CAMELLIA], [], [have GCRY_CIPHER_CAMELLIA128])],
1101                 [AC_MSG_RESULT([no])]
1102         )
1103 fi
1104
1105 if test x$uci = xtrue; then
1106         AC_CHECK_LIB([uci],[main],[LIBS="$LIBS"],[AC_MSG_ERROR([UCI library libuci not found])],[])
1107         AC_CHECK_HEADER([uci.h],,[AC_MSG_ERROR([UCI header uci.h not found!])])
1108 fi
1109
1110 if test x$android_dns = xtrue; then
1111         AC_CHECK_LIB([cutils],[main],[LIBS="$LIBS"],[AC_MSG_ERROR([Android library libcutils not found])],[])
1112         AC_CHECK_HEADER([cutils/properties.h],,[AC_MSG_ERROR([Android header cutils/properties.h not found!])])
1113         # we have to force the use of libdl here because the autodetection
1114         # above does not work correctly when cross-compiling for android.
1115         DLLIB="-ldl"
1116         AC_SUBST(DLLIB)
1117 fi
1118
1119 if test x$maemo = xtrue; then
1120         PKG_CHECK_MODULES(maemo, [glib-2.0 gthread-2.0 libosso osso-af-settings])
1121         AC_SUBST(maemo_CFLAGS)
1122         AC_SUBST(maemo_LIBS)
1123         dbusservicedir="/usr/share/dbus-1/system-services"
1124         AC_SUBST(dbusservicedir)
1125 fi
1126
1127 if test x$eap_sim_pcsc = xtrue; then
1128         PKG_CHECK_MODULES(pcsclite, [libpcsclite])
1129         AC_SUBST(pcsclite_CFLAGS)
1130         AC_SUBST(pcsclite_LIBS)
1131 fi
1132
1133 if test x$nm = xtrue; then
1134         PKG_CHECK_EXISTS([libnm-glib],
1135                 [PKG_CHECK_MODULES(nm, [NetworkManager gthread-2.0 libnm-util libnm-glib libnm-glib-vpn])],
1136                 [PKG_CHECK_MODULES(nm, [NetworkManager gthread-2.0 libnm_util libnm_glib libnm_glib_vpn])]
1137         )
1138         AC_SUBST(nm_CFLAGS)
1139         AC_SUBST(nm_LIBS)
1140 fi
1141
1142 if test x$xauth_pam = xtrue; then
1143         AC_CHECK_LIB([pam],[main],[LIBS="$LIBS"],[AC_MSG_ERROR([PAM library not found])],[])
1144         AC_CHECK_HEADER([security/pam_appl.h],,[AC_MSG_ERROR([PAM header security/pam_appl.h not found!])])
1145 fi
1146
1147 if test x$connmark = xtrue -o x$forecast = xtrue; then
1148         PKG_CHECK_MODULES(libiptc, [libiptc])
1149         AC_SUBST(libiptc_CFLAGS)
1150         AC_SUBST(libiptc_LIBS)
1151 fi
1152
1153 if test x$capabilities = xnative; then
1154         AC_MSG_NOTICE([Usage of the native Linux capabilities interface is deprecated, use libcap instead])
1155         # Linux requires the following for capset(), Android does not have it,
1156         # but defines capset() in unistd.h instead.
1157         AC_CHECK_HEADERS([sys/capability.h])
1158         AC_CHECK_FUNC(capset,,[AC_MSG_ERROR([capset() not found!])])
1159         AC_DEFINE([CAPABILITIES_NATIVE], [], [have native linux capset()])
1160 fi
1161
1162 if test x$capabilities = xlibcap; then
1163         AC_CHECK_LIB([cap],[main],[LIBS="$LIBS"],[AC_MSG_ERROR([libcap library not found])],[])
1164         AC_CHECK_HEADER([sys/capability.h],
1165                 [AC_DEFINE([HAVE_SYS_CAPABILITY_H], [], [have sys/capability.h])],
1166                 [AC_MSG_ERROR([libcap header sys/capability.h not found!])])
1167         AC_DEFINE([CAPABILITIES_LIBCAP], [], [have libpcap library])
1168 fi
1169
1170 if test x$integrity_test = xtrue; then
1171         AC_MSG_CHECKING([for dladdr()])
1172         AC_COMPILE_IFELSE(
1173                 [AC_LANG_PROGRAM(
1174                         [[#define _GNU_SOURCE
1175                           #include <dlfcn.h>]],
1176                         [[Dl_info info; dladdr(main, &info);]])],
1177                 [AC_MSG_RESULT([yes])],
1178                 [AC_MSG_RESULT([no]);
1179                  AC_MSG_ERROR([dladdr() not supported, required by integrity-test!])]
1180         )
1181         AC_MSG_CHECKING([for dl_iterate_phdr()])
1182         AC_COMPILE_IFELSE(
1183                 [AC_LANG_PROGRAM(
1184                         [[#define _GNU_SOURCE
1185                           #include <link.h>]],
1186                         [[dl_iterate_phdr((void*)0, (void*)0);]])],
1187                 [AC_MSG_RESULT([yes])],
1188                 [AC_MSG_RESULT([no]);
1189                  AC_MSG_ERROR([dl_iterate_phdr() not supported, required by integrity-test!])]
1190         )
1191 fi
1192
1193 if test x$bfd_backtraces = xtrue; then
1194         AC_CHECK_LIB([bfd],[main],[LIBS="$LIBS"],[AC_MSG_ERROR([binutils libbfd not found!])],[])
1195         AC_CHECK_HEADER([bfd.h],[AC_DEFINE([HAVE_BFD_H],,[have binutils bfd.h])],
1196                 [AC_MSG_ERROR([binutils bfd.h header not found!])])
1197         BFDLIB="-lbfd"
1198         AC_SUBST(BFDLIB)
1199 fi
1200
1201 if test x$unwind_backtraces = xtrue; then
1202         AC_CHECK_LIB([unwind],[main],[LIBS="$LIBS"],[AC_MSG_ERROR([libunwind not found!])],[])
1203         AC_CHECK_HEADER([libunwind.h],[AC_DEFINE([HAVE_LIBUNWIND_H],,[have libunwind.h])],
1204                 [AC_MSG_ERROR([libunwind.h header not found!])])
1205         UNWINDLIB="-lunwind"
1206         AC_SUBST(UNWINDLIB)
1207 fi
1208
1209 AM_CONDITIONAL(USE_DEV_HEADERS, [test "x$dev_headers" != xno])
1210 if test x$dev_headers = xyes; then
1211         dev_headers="$includedir/strongswan"
1212 fi
1213 AC_SUBST(dev_headers)
1214
1215 CFLAGS="$CFLAGS -include `pwd`/config.h"
1216
1217 if test x$tkm = xtrue; then
1218         AC_PATH_PROG([GPRBUILD], [gprbuild], [], [$PATH:/bin:/usr/bin:/usr/local/bin])
1219         if test x$GPRBUILD = x; then
1220                 AC_MSG_ERROR([gprbuild not found])
1221         fi
1222 fi
1223
1224 if test x$coverage = xtrue; then
1225         AC_PATH_PROG([LCOV], [lcov], [], [$PATH:/bin:/usr/bin:/usr/local/bin])
1226         if test x$LCOV = x; then
1227                 AC_MSG_ERROR([lcov not found])
1228         fi
1229         AC_PATH_PROG([GENHTML], [genhtml], [], [$PATH:/bin:/usr/bin:/usr/local/bin])
1230         if test x$GENHTML = x; then
1231                 AC_MSG_ERROR([genhtml not found])
1232         fi
1233
1234         COVERAGE_CFLAGS="-fprofile-arcs -ftest-coverage"
1235         COVERAGE_LDFLAGS="-fprofile-arcs"
1236         AC_SUBST(COVERAGE_CFLAGS)
1237         AC_SUBST(COVERAGE_LDFLAGS)
1238
1239         AC_MSG_NOTICE([coverage enabled, adding "-g -O0" to CFLAGS])
1240         CFLAGS="${CFLAGS} -g -O0"
1241 fi
1242
1243 if test x$ruby_gems = xtrue; then
1244         AC_PATH_PROG([GEM], [gem], [], [$PATH:/bin:/usr/bin:/usr/local/bin])
1245         if test x$GEM = x; then
1246                 AC_MSG_ERROR(RubyGems package manager not found)
1247         fi
1248         if test "x$rubygemdir" = "xgem environment gemdir"; then
1249                 rubygemdir=$($GEM environment gemdir)
1250         fi
1251         AC_SUBST(RUBYGEMDIR, "$rubygemdir")
1252 fi
1253 AM_CONDITIONAL(RUBY_GEMS_INSTALL, [test "x$ruby_gems_install" = xtrue])
1254
1255 if test x$python_eggs = xtrue; then
1256         PYTHON_PACKAGE_VERSION=`echo "$PACKAGE_VERSION" | $SED 's/dr/dev/'`
1257         AC_SUBST([PYTHON_PACKAGE_VERSION])
1258         if test x$python_eggs_install = xtrue; then
1259                 AC_PATH_PROG([EASY_INSTALL], [easy_install], [], [$PATH:/bin:/usr/bin:/usr/local/bin])
1260                 if test x$EASY_INSTALL = x; then
1261                         AC_MSG_ERROR(Python easy_install not found)
1262                 fi
1263         fi
1264         if test "x$pythoneggdir" = "xmain site-packages directory"; then
1265                 AC_SUBST(PYTHONEGGINSTALLDIR, "")
1266         else
1267                 AC_SUBST(PYTHONEGGINSTALLDIR, "--install-dir $pythoneggdir")
1268         fi
1269         AC_PATH_PROG([PY_TEST], [py.test], [], [$PATH:/bin:/usr/bin:/usr/local/bin])
1270 fi
1271 AM_CONDITIONAL(PYTHON_EGGS_INSTALL, [test "x$python_eggs_install" = xtrue])
1272
1273 AM_CONDITIONAL(PERL_CPAN_INSTALL, [test "x$perl_cpan_install" = xtrue])
1274
1275 # ===============================================
1276 #  collect plugin list for strongSwan components
1277 # ===============================================
1278
1279 m4_include(m4/macros/add-plugin.m4)
1280
1281 # plugin lists for all components
1282 charon_plugins=
1283 starter_plugins=
1284 pool_plugins=
1285 attest_plugins=
1286 scepclient_plugins=
1287 pki_plugins=
1288 scripts_plugins=
1289 manager_plugins=
1290 medsrv_plugins=
1291 nm_plugins=
1292 cmd_plugins=
1293 aikgen_plugins=
1294
1295 # location specific lists for checksumming,
1296 # for src/libcharon, src/libstrongswan and src/libtnccs
1297 c_plugins=
1298 s_plugins=
1299 t_plugins=
1300
1301 ADD_PLUGIN([test-vectors],         [s charon scepclient pki])
1302 ADD_PLUGIN([unbound],              [s charon scripts])
1303 ADD_PLUGIN([ldap],                 [s charon scepclient scripts nm cmd])
1304 ADD_PLUGIN([pkcs11],               [s charon pki nm cmd])
1305 ADD_PLUGIN([aesni],                [s charon scepclient pki scripts medsrv attest nm cmd aikgen])
1306 ADD_PLUGIN([aes],                  [s charon scepclient pki scripts nm cmd])
1307 ADD_PLUGIN([des],                  [s charon scepclient pki scripts nm cmd])
1308 ADD_PLUGIN([blowfish],             [s charon scepclient pki scripts nm cmd])
1309 ADD_PLUGIN([rc2],                  [s charon scepclient pki scripts nm cmd])
1310 ADD_PLUGIN([sha2],                 [s charon scepclient pki scripts medsrv attest nm cmd aikgen])
1311 ADD_PLUGIN([sha3],                 [s charon scepclient pki scripts medsrv attest nm cmd aikgen])
1312 ADD_PLUGIN([sha1],                 [s charon scepclient pki scripts manager medsrv attest nm cmd aikgen])
1313 ADD_PLUGIN([md4],                  [s charon scepclient pki nm cmd])
1314 ADD_PLUGIN([md5],                  [s charon scepclient pki scripts attest nm cmd aikgen])
1315 ADD_PLUGIN([rdrand],               [s charon scepclient pki scripts medsrv attest nm cmd aikgen])
1316 ADD_PLUGIN([random],               [s charon scepclient pki scripts manager medsrv attest nm cmd aikgen])
1317 ADD_PLUGIN([nonce],                [s charon nm cmd aikgen])
1318 ADD_PLUGIN([x509],                 [s charon scepclient pki scripts attest nm cmd aikgen])
1319 ADD_PLUGIN([revocation],           [s charon pki nm cmd])
1320 ADD_PLUGIN([constraints],          [s charon nm cmd])
1321 ADD_PLUGIN([acert],                [s charon])
1322 ADD_PLUGIN([pubkey],               [s charon cmd aikgen])
1323 ADD_PLUGIN([pkcs1],                [s charon scepclient pki scripts manager medsrv attest nm cmd aikgen])
1324 ADD_PLUGIN([pkcs7],                [s charon scepclient pki scripts nm cmd])
1325 ADD_PLUGIN([pkcs8],                [s charon scepclient pki scripts manager medsrv attest nm cmd])
1326 ADD_PLUGIN([pkcs12],               [s charon scepclient pki scripts cmd])
1327 ADD_PLUGIN([pgp],                  [s charon])
1328 ADD_PLUGIN([dnskey],               [s charon pki])
1329 ADD_PLUGIN([sshkey],               [s charon pki nm cmd])
1330 ADD_PLUGIN([dnscert],              [c charon])
1331 ADD_PLUGIN([ipseckey],             [c charon])
1332 ADD_PLUGIN([pem],                  [s charon scepclient pki scripts manager medsrv attest nm cmd aikgen])
1333 ADD_PLUGIN([padlock],              [s charon])
1334 ADD_PLUGIN([openssl],              [s charon scepclient pki scripts manager medsrv attest nm cmd aikgen])
1335 ADD_PLUGIN([gcrypt],               [s charon scepclient pki scripts manager medsrv attest nm cmd aikgen])
1336 ADD_PLUGIN([af-alg],               [s charon scepclient pki scripts medsrv attest nm cmd aikgen])
1337 ADD_PLUGIN([fips-prf],             [s charon nm cmd])
1338 ADD_PLUGIN([gmp],                  [s charon scepclient pki scripts manager medsrv attest nm cmd aikgen])
1339 ADD_PLUGIN([agent],                [s charon nm cmd])
1340 ADD_PLUGIN([keychain],             [s charon cmd])
1341 ADD_PLUGIN([chapoly],              [s charon scripts nm cmd])
1342 ADD_PLUGIN([xcbc],                 [s charon nm cmd])
1343 ADD_PLUGIN([cmac],                 [s charon nm cmd])
1344 ADD_PLUGIN([hmac],                 [s charon pki scripts nm cmd])
1345 ADD_PLUGIN([ctr],                  [s charon scripts nm cmd])
1346 ADD_PLUGIN([ccm],                  [s charon scripts nm cmd])
1347 ADD_PLUGIN([gcm],                  [s charon scripts nm cmd])
1348 ADD_PLUGIN([ntru],                 [s charon scripts nm cmd])
1349 ADD_PLUGIN([bliss],                [s charon pki scripts nm cmd])
1350 ADD_PLUGIN([curl],                 [s charon scepclient pki scripts nm cmd])
1351 ADD_PLUGIN([files],                [s charon scepclient pki scripts nm cmd])
1352 ADD_PLUGIN([winhttp],              [s charon pki scripts])
1353 ADD_PLUGIN([soup],                 [s charon pki scripts nm cmd])
1354 ADD_PLUGIN([mysql],                [s charon pool manager medsrv attest])
1355 ADD_PLUGIN([sqlite],               [s charon pool manager medsrv attest])
1356 ADD_PLUGIN([attr],                 [c charon])
1357 ADD_PLUGIN([attr-sql],             [c charon])
1358 ADD_PLUGIN([load-tester],          [c charon])
1359 ADD_PLUGIN([kernel-libipsec],      [c charon cmd])
1360 ADD_PLUGIN([kernel-wfp],           [c charon])
1361 ADD_PLUGIN([kernel-iph],           [c charon])
1362 ADD_PLUGIN([kernel-pfkey],         [c charon starter nm cmd])
1363 ADD_PLUGIN([kernel-pfroute],       [c charon starter nm cmd])
1364 ADD_PLUGIN([kernel-netlink],       [c charon starter nm cmd])
1365 ADD_PLUGIN([resolve],              [c charon cmd])
1366 ADD_PLUGIN([socket-default],       [c charon nm cmd])
1367 ADD_PLUGIN([socket-dynamic],       [c charon cmd])
1368 ADD_PLUGIN([socket-win],           [c charon])
1369 ADD_PLUGIN([connmark],             [c charon])
1370 ADD_PLUGIN([forecast],             [c charon])
1371 ADD_PLUGIN([farp],                 [c charon])
1372 ADD_PLUGIN([stroke],               [c charon])
1373 ADD_PLUGIN([vici],                 [c charon])
1374 ADD_PLUGIN([smp],                  [c charon])
1375 ADD_PLUGIN([sql],                  [c charon])
1376 ADD_PLUGIN([updown],               [c charon])
1377 ADD_PLUGIN([eap-identity],         [c charon nm cmd])
1378 ADD_PLUGIN([eap-sim],              [c charon])
1379 ADD_PLUGIN([eap-sim-file],         [c charon])
1380 ADD_PLUGIN([eap-sim-pcsc],         [c charon])
1381 ADD_PLUGIN([eap-aka],              [c charon])
1382 ADD_PLUGIN([eap-aka-3gpp2],        [c charon])
1383 ADD_PLUGIN([eap-simaka-sql],       [c charon])
1384 ADD_PLUGIN([eap-simaka-pseudonym], [c charon])
1385 ADD_PLUGIN([eap-simaka-reauth],    [c charon])
1386 ADD_PLUGIN([eap-md5],              [c charon nm cmd])
1387 ADD_PLUGIN([eap-gtc],              [c charon nm cmd])
1388 ADD_PLUGIN([eap-mschapv2],         [c charon nm cmd])
1389 ADD_PLUGIN([eap-dynamic],          [c charon])
1390 ADD_PLUGIN([eap-radius],           [c charon])
1391 ADD_PLUGIN([eap-tls],              [c charon nm cmd])
1392 ADD_PLUGIN([eap-ttls],             [c charon nm cmd])
1393 ADD_PLUGIN([eap-peap],             [c charon nm cmd])
1394 ADD_PLUGIN([eap-tnc],              [c charon])
1395 ADD_PLUGIN([xauth-generic],        [c charon cmd])
1396 ADD_PLUGIN([xauth-eap],            [c charon])
1397 ADD_PLUGIN([xauth-pam],            [c charon])
1398 ADD_PLUGIN([xauth-noauth],         [c charon])
1399 ADD_PLUGIN([tnc-ifmap],            [c charon])
1400 ADD_PLUGIN([tnc-pdp],              [c charon])
1401 ADD_PLUGIN([tnc-imc],              [t charon])
1402 ADD_PLUGIN([tnc-imv],              [t charon])
1403 ADD_PLUGIN([tnc-tnccs],            [t charon])
1404 ADD_PLUGIN([tnccs-20],             [t charon])
1405 ADD_PLUGIN([tnccs-11],             [t charon])
1406 ADD_PLUGIN([tnccs-dynamic],        [t charon])
1407 ADD_PLUGIN([medsrv],               [c charon])
1408 ADD_PLUGIN([medcli],               [c charon])
1409 ADD_PLUGIN([dhcp],                 [c charon])
1410 ADD_PLUGIN([osx-attr],             [c charon cmd])
1411 ADD_PLUGIN([p-cscf],               [c charon cmd])
1412 ADD_PLUGIN([android-dns],          [c charon])
1413 ADD_PLUGIN([android-log],          [c charon])
1414 ADD_PLUGIN([ha],                   [c charon])
1415 ADD_PLUGIN([whitelist],            [c charon])
1416 ADD_PLUGIN([ext-auth],             [c charon])
1417 ADD_PLUGIN([lookip],               [c charon])
1418 ADD_PLUGIN([error-notify],         [c charon])
1419 ADD_PLUGIN([certexpire],           [c charon])
1420 ADD_PLUGIN([systime-fix],          [c charon])
1421 ADD_PLUGIN([led],                  [c charon])
1422 ADD_PLUGIN([duplicheck],           [c charon])
1423 ADD_PLUGIN([coupling],             [c charon])
1424 ADD_PLUGIN([radattr],              [c charon])
1425 ADD_PLUGIN([maemo],                [c charon])
1426 ADD_PLUGIN([uci],                  [c charon])
1427 ADD_PLUGIN([addrblock],            [c charon])
1428 ADD_PLUGIN([unity],                [c charon])
1429
1430 AC_SUBST(charon_plugins)
1431 AC_SUBST(starter_plugins)
1432 AC_SUBST(pool_plugins)
1433 AC_SUBST(attest_plugins)
1434 AC_SUBST(scepclient_plugins)
1435 AC_SUBST(pki_plugins)
1436 AC_SUBST(scripts_plugins)
1437 AC_SUBST(manager_plugins)
1438 AC_SUBST(medsrv_plugins)
1439 AC_SUBST(nm_plugins)
1440 AC_SUBST(cmd_plugins)
1441 AC_SUBST(aikgen_plugins)
1442
1443 AC_SUBST(c_plugins)
1444 AC_SUBST(h_plugins)
1445 AC_SUBST(s_plugins)
1446 AC_SUBST(t_plugins)
1447
1448 # ======================
1449 #  set Makefile.am vars
1450 # ======================
1451
1452 #  libstrongswan plugins
1453 # -----------------------
1454 AM_CONDITIONAL(USE_TEST_VECTORS, test x$test_vectors = xtrue)
1455 AM_CONDITIONAL(USE_CURL, test x$curl = xtrue)
1456 AM_CONDITIONAL(USE_FILES, test x$files = xtrue)
1457 AM_CONDITIONAL(USE_WINHTTP, test x$winhttp = xtrue)
1458 AM_CONDITIONAL(USE_UNBOUND, test x$unbound = xtrue)
1459 AM_CONDITIONAL(USE_SOUP, test x$soup = xtrue)
1460 AM_CONDITIONAL(USE_LDAP, test x$ldap = xtrue)
1461 AM_CONDITIONAL(USE_AES, test x$aes = xtrue)
1462 AM_CONDITIONAL(USE_DES, test x$des = xtrue)
1463 AM_CONDITIONAL(USE_BLOWFISH, test x$blowfish = xtrue)
1464 AM_CONDITIONAL(USE_RC2, test x$rc2 = xtrue)
1465 AM_CONDITIONAL(USE_MD4, test x$md4 = xtrue)
1466 AM_CONDITIONAL(USE_MD5, test x$md5 = xtrue)
1467 AM_CONDITIONAL(USE_SHA1, test x$sha1 = xtrue)
1468 AM_CONDITIONAL(USE_SHA2, test x$sha2 = xtrue)
1469 AM_CONDITIONAL(USE_SHA3, test x$sha3 = xtrue)
1470 AM_CONDITIONAL(USE_FIPS_PRF, test x$fips_prf = xtrue)
1471 AM_CONDITIONAL(USE_GMP, test x$gmp = xtrue)
1472 AM_CONDITIONAL(USE_RDRAND, test x$rdrand = xtrue)
1473 AM_CONDITIONAL(USE_AESNI, test x$aesni = xtrue)
1474 AM_CONDITIONAL(USE_RANDOM, test x$random = xtrue)
1475 AM_CONDITIONAL(USE_NONCE, test x$nonce = xtrue)
1476 AM_CONDITIONAL(USE_X509, test x$x509 = xtrue)
1477 AM_CONDITIONAL(USE_REVOCATION, test x$revocation = xtrue)
1478 AM_CONDITIONAL(USE_CONSTRAINTS, test x$constraints = xtrue)
1479 AM_CONDITIONAL(USE_ACERT, test x$acert = xtrue)
1480 AM_CONDITIONAL(USE_PUBKEY, test x$pubkey = xtrue)
1481 AM_CONDITIONAL(USE_PKCS1, test x$pkcs1 = xtrue)
1482 AM_CONDITIONAL(USE_PKCS7, test x$pkcs7 = xtrue)
1483 AM_CONDITIONAL(USE_PKCS8, test x$pkcs8 = xtrue)
1484 AM_CONDITIONAL(USE_PKCS12, test x$pkcs12 = xtrue)
1485 AM_CONDITIONAL(USE_PGP, test x$pgp = xtrue)
1486 AM_CONDITIONAL(USE_DNSKEY, test x$dnskey = xtrue)
1487 AM_CONDITIONAL(USE_SSHKEY, test x$sshkey = xtrue)
1488 AM_CONDITIONAL(USE_PEM, test x$pem = xtrue)
1489 AM_CONDITIONAL(USE_HMAC, test x$hmac = xtrue)
1490 AM_CONDITIONAL(USE_CMAC, test x$cmac = xtrue)
1491 AM_CONDITIONAL(USE_XCBC, test x$xcbc = xtrue)
1492 AM_CONDITIONAL(USE_MYSQL, test x$mysql = xtrue)
1493 AM_CONDITIONAL(USE_SQLITE, test x$sqlite = xtrue)
1494 AM_CONDITIONAL(USE_PADLOCK, test x$padlock = xtrue)
1495 AM_CONDITIONAL(USE_OPENSSL, test x$openssl = xtrue)
1496 AM_CONDITIONAL(USE_GCRYPT, test x$gcrypt = xtrue)
1497 AM_CONDITIONAL(USE_AGENT, test x$agent = xtrue)
1498 AM_CONDITIONAL(USE_KEYCHAIN, test x$keychain = xtrue)
1499 AM_CONDITIONAL(USE_PKCS11, test x$pkcs11 = xtrue)
1500 AM_CONDITIONAL(USE_CHAPOLY, test x$chapoly = xtrue)
1501 AM_CONDITIONAL(USE_CTR, test x$ctr = xtrue)
1502 AM_CONDITIONAL(USE_CCM, test x$ccm = xtrue)
1503 AM_CONDITIONAL(USE_GCM, test x$gcm = xtrue)
1504 AM_CONDITIONAL(USE_AF_ALG, test x$af_alg = xtrue)
1505 AM_CONDITIONAL(USE_NTRU, test x$ntru = xtrue)
1506 AM_CONDITIONAL(USE_BLISS, test x$bliss = xtrue)
1507
1508 #  charon plugins
1509 # ----------------
1510 AM_CONDITIONAL(USE_STROKE, test x$stroke = xtrue)
1511 AM_CONDITIONAL(USE_VICI, test x$vici = xtrue)
1512 AM_CONDITIONAL(USE_MEDSRV, test x$medsrv = xtrue)
1513 AM_CONDITIONAL(USE_MEDCLI, test x$medcli = xtrue)
1514 AM_CONDITIONAL(USE_UCI, test x$uci = xtrue)
1515 AM_CONDITIONAL(USE_OSX_ATTR, test x$osx_attr = xtrue)
1516 AM_CONDITIONAL(USE_P_CSCF, test x$p_cscf = xtrue)
1517 AM_CONDITIONAL(USE_ANDROID_DNS, test x$android_dns = xtrue)
1518 AM_CONDITIONAL(USE_ANDROID_LOG, test x$android_log = xtrue)
1519 AM_CONDITIONAL(USE_MAEMO, test x$maemo = xtrue)
1520 AM_CONDITIONAL(USE_SMP, test x$smp = xtrue)
1521 AM_CONDITIONAL(USE_SQL, test x$sql = xtrue)
1522 AM_CONDITIONAL(USE_DNSCERT, test x$dnscert = xtrue)
1523 AM_CONDITIONAL(USE_IPSECKEY, test x$ipseckey = xtrue)
1524 AM_CONDITIONAL(USE_UPDOWN, test x$updown = xtrue)
1525 AM_CONDITIONAL(USE_DHCP, test x$dhcp = xtrue)
1526 AM_CONDITIONAL(USE_LOAD_TESTER, test x$load_tester = xtrue)
1527 AM_CONDITIONAL(USE_HA, test x$ha = xtrue)
1528 AM_CONDITIONAL(USE_KERNEL_NETLINK, test x$kernel_netlink = xtrue)
1529 AM_CONDITIONAL(USE_KERNEL_PFKEY, test x$kernel_pfkey = xtrue)
1530 AM_CONDITIONAL(USE_KERNEL_PFROUTE, test x$kernel_pfroute = xtrue)
1531 AM_CONDITIONAL(USE_KERNEL_LIBIPSEC, test x$kernel_libipsec = xtrue)
1532 AM_CONDITIONAL(USE_KERNEL_WFP, test x$kernel_wfp = xtrue)
1533 AM_CONDITIONAL(USE_KERNEL_IPH, test x$kernel_iph = xtrue)
1534 AM_CONDITIONAL(USE_WHITELIST, test x$whitelist = xtrue)
1535 AM_CONDITIONAL(USE_EXT_AUTH, test x$ext_auth = xtrue)
1536 AM_CONDITIONAL(USE_LOOKIP, test x$lookip = xtrue)
1537 AM_CONDITIONAL(USE_ERROR_NOTIFY, test x$error_notify = xtrue)
1538 AM_CONDITIONAL(USE_CERTEXPIRE, test x$certexpire = xtrue)
1539 AM_CONDITIONAL(USE_SYSTIME_FIX, test x$systime_fix = xtrue)
1540 AM_CONDITIONAL(USE_LED, test x$led = xtrue)
1541 AM_CONDITIONAL(USE_DUPLICHECK, test x$duplicheck = xtrue)
1542 AM_CONDITIONAL(USE_COUPLING, test x$coupling = xtrue)
1543 AM_CONDITIONAL(USE_RADATTR, test x$radattr = xtrue)
1544 AM_CONDITIONAL(USE_EAP_SIM, test x$eap_sim = xtrue)
1545 AM_CONDITIONAL(USE_EAP_SIM_FILE, test x$eap_sim_file = xtrue)
1546 AM_CONDITIONAL(USE_EAP_SIM_PCSC, test x$eap_sim_pcsc = xtrue)
1547 AM_CONDITIONAL(USE_EAP_SIMAKA_SQL, test x$eap_simaka_sql = xtrue)
1548 AM_CONDITIONAL(USE_EAP_SIMAKA_PSEUDONYM, test x$eap_simaka_pseudonym = xtrue)
1549 AM_CONDITIONAL(USE_EAP_SIMAKA_REAUTH, test x$eap_simaka_reauth = xtrue)
1550 AM_CONDITIONAL(USE_EAP_IDENTITY, test x$eap_identity = xtrue)
1551 AM_CONDITIONAL(USE_EAP_MD5, test x$eap_md5 = xtrue)
1552 AM_CONDITIONAL(USE_EAP_GTC, test x$eap_gtc = xtrue)
1553 AM_CONDITIONAL(USE_EAP_AKA, test x$eap_aka = xtrue)
1554 AM_CONDITIONAL(USE_EAP_AKA_3GPP2, test x$eap_aka_3gpp2 = xtrue)
1555 AM_CONDITIONAL(USE_EAP_MSCHAPV2, test x$eap_mschapv2 = xtrue)
1556 AM_CONDITIONAL(USE_EAP_TLS, test x$eap_tls = xtrue)
1557 AM_CONDITIONAL(USE_EAP_TTLS, test x$eap_ttls = xtrue)
1558 AM_CONDITIONAL(USE_EAP_PEAP, test x$eap_peap = xtrue)
1559 AM_CONDITIONAL(USE_EAP_TNC, test x$eap_tnc = xtrue)
1560 AM_CONDITIONAL(USE_EAP_DYNAMIC, test x$eap_dynamic = xtrue)
1561 AM_CONDITIONAL(USE_EAP_RADIUS, test x$eap_radius = xtrue)
1562 AM_CONDITIONAL(USE_XAUTH_GENERIC, test x$xauth_generic = xtrue)
1563 AM_CONDITIONAL(USE_XAUTH_EAP, test x$xauth_eap = xtrue)
1564 AM_CONDITIONAL(USE_XAUTH_PAM, test x$xauth_pam = xtrue)
1565 AM_CONDITIONAL(USE_XAUTH_NOAUTH, test x$xauth_noauth = xtrue)
1566 AM_CONDITIONAL(USE_TNC_IFMAP, test x$tnc_ifmap = xtrue)
1567 AM_CONDITIONAL(USE_TNC_PDP, test x$tnc_pdp = xtrue)
1568 AM_CONDITIONAL(USE_TNC_IMC, test x$tnc_imc = xtrue)
1569 AM_CONDITIONAL(USE_TNC_IMV, test x$tnc_imv = xtrue)
1570 AM_CONDITIONAL(USE_TNC_TNCCS, test x$tnc_tnccs = xtrue)
1571 AM_CONDITIONAL(USE_TNCCS_11, test x$tnccs_11 = xtrue)
1572 AM_CONDITIONAL(USE_TNCCS_20, test x$tnccs_20 = xtrue)
1573 AM_CONDITIONAL(USE_TNCCS_DYNAMIC, test x$tnccs_dynamic = xtrue)
1574 AM_CONDITIONAL(USE_IMC_TEST, test x$imc_test = xtrue)
1575 AM_CONDITIONAL(USE_IMV_TEST, test x$imv_test = xtrue)
1576 AM_CONDITIONAL(USE_IMC_SCANNER, test x$imc_scanner = xtrue)
1577 AM_CONDITIONAL(USE_IMV_SCANNER, test x$imv_scanner = xtrue)
1578 AM_CONDITIONAL(USE_IMC_OS, test x$imc_os = xtrue)
1579 AM_CONDITIONAL(USE_IMV_OS, test x$imv_os = xtrue)
1580 AM_CONDITIONAL(USE_IMC_ATTESTATION, test x$imc_attestation = xtrue)
1581 AM_CONDITIONAL(USE_IMV_ATTESTATION, test x$imv_attestation = xtrue)
1582 AM_CONDITIONAL(USE_IMC_SWID, test x$imc_swid = xtrue)
1583 AM_CONDITIONAL(USE_IMV_SWID, test x$imv_swid = xtrue)
1584 AM_CONDITIONAL(USE_IMC_HCD, test x$imc_hcd = xtrue)
1585 AM_CONDITIONAL(USE_IMV_HCD, test x$imv_hcd = xtrue)
1586 AM_CONDITIONAL(USE_SOCKET_DEFAULT, test x$socket_default = xtrue)
1587 AM_CONDITIONAL(USE_SOCKET_DYNAMIC, test x$socket_dynamic = xtrue)
1588 AM_CONDITIONAL(USE_SOCKET_WIN, test x$socket_win = xtrue)
1589 AM_CONDITIONAL(USE_CONNMARK, test x$connmark = xtrue)
1590 AM_CONDITIONAL(USE_FORECAST, test x$forecast = xtrue)
1591 AM_CONDITIONAL(USE_FARP, test x$farp = xtrue)
1592 AM_CONDITIONAL(USE_ADDRBLOCK, test x$addrblock = xtrue)
1593 AM_CONDITIONAL(USE_UNITY, test x$unity = xtrue)
1594 AM_CONDITIONAL(USE_RESOLVE, test x$resolve = xtrue)
1595 AM_CONDITIONAL(USE_ATTR, test x$attr = xtrue)
1596 AM_CONDITIONAL(USE_ATTR_SQL, test x$attr_sql = xtrue)
1597
1598 #  other options
1599 # ---------------
1600 AM_CONDITIONAL(USE_LEAK_DETECTIVE, test x$leak_detective = xtrue)
1601 AM_CONDITIONAL(USE_LOCK_PROFILER, test x$lock_profiler = xtrue)
1602 AM_CONDITIONAL(USE_DUMM, test x$dumm = xtrue)
1603 AM_CONDITIONAL(USE_FAST, test x$fast = xtrue)
1604 AM_CONDITIONAL(USE_MANAGER, test x$manager = xtrue)
1605 AM_CONDITIONAL(USE_ME, test x$mediation = xtrue)
1606 AM_CONDITIONAL(USE_INTEGRITY_TEST, test x$integrity_test = xtrue)
1607 AM_CONDITIONAL(USE_LOAD_WARNING, test x$load_warning = xtrue)
1608 AM_CONDITIONAL(USE_IKEV1, test x$ikev1 = xtrue)
1609 AM_CONDITIONAL(USE_IKEV2, test x$ikev2 = xtrue)
1610 AM_CONDITIONAL(USE_THREADS, test x$threads = xtrue)
1611 AM_CONDITIONAL(USE_ADNS, test x$adns = xtrue)
1612 AM_CONDITIONAL(USE_CHARON, test x$charon = xtrue)
1613 AM_CONDITIONAL(USE_NM, test x$nm = xtrue)
1614 AM_CONDITIONAL(USE_PKI, test x$pki = xtrue)
1615 AM_CONDITIONAL(USE_SCEPCLIENT, test x$scepclient = xtrue)
1616 AM_CONDITIONAL(USE_SCRIPTS, test x$scripts = xtrue)
1617 AM_CONDITIONAL(USE_CONFTEST, test x$conftest = xtrue)
1618 AM_CONDITIONAL(USE_LIBSTRONGSWAN, test x$charon = xtrue -o x$pki = xtrue -o x$scepclient = xtrue -o x$conftest = xtrue -o x$fast = xtrue -o x$imcv = xtrue -o x$nm = xtrue -o x$tkm = xtrue -o x$cmd = xtrue -o x$tls = xtrue -o x$tnc_tnccs = xtrue -o x$aikgen = xtrue -o x$svc = xtrue -o x$systemd = xtrue)
1619 AM_CONDITIONAL(USE_LIBCHARON, test x$charon = xtrue -o x$conftest = xtrue -o x$nm = xtrue -o x$tkm = xtrue -o x$cmd = xtrue -o x$svc = xtrue -o x$systemd = xtrue)
1620 AM_CONDITIONAL(USE_LIBIPSEC, test x$libipsec = xtrue)
1621 AM_CONDITIONAL(USE_LIBTNCIF, test x$tnc_tnccs = xtrue -o x$imcv = xtrue)
1622 AM_CONDITIONAL(USE_LIBTNCCS, test x$tnc_tnccs = xtrue)
1623 AM_CONDITIONAL(USE_LIBPTTLS, test x$tnc_tnccs = xtrue)
1624 AM_CONDITIONAL(USE_FILE_CONFIG, test x$stroke = xtrue)
1625 AM_CONDITIONAL(USE_IPSEC_SCRIPT, test x$stroke = xtrue -o x$scepclient = xtrue -o x$conftest = xtrue)
1626 AM_CONDITIONAL(USE_LIBCAP, test x$capabilities = xlibcap)
1627 AM_CONDITIONAL(USE_VSTR, test x$printf_hooks = xvstr)
1628 AM_CONDITIONAL(USE_BUILTIN_PRINTF, test x$printf_hooks = xbuiltin)
1629 AM_CONDITIONAL(USE_SIMAKA, test x$simaka = xtrue)
1630 AM_CONDITIONAL(USE_TLS, test x$tls = xtrue)
1631 AM_CONDITIONAL(USE_RADIUS, test x$radius = xtrue)
1632 AM_CONDITIONAL(USE_IMCV, test x$imcv = xtrue)
1633 AM_CONDITIONAL(USE_TROUSERS, test x$tss = xtrousers -o x$aikgen = xtrue)
1634 AM_CONDITIONAL(MONOLITHIC, test x$monolithic = xtrue)
1635 AM_CONDITIONAL(USE_SILENT_RULES, test x$enable_silent_rules = xyes)
1636 AM_CONDITIONAL(COVERAGE, test x$coverage = xtrue)
1637 AM_CONDITIONAL(USE_DBGHELP, test x$dbghelp_backtraces = xtrue)
1638 AM_CONDITIONAL(USE_TKM, test x$tkm = xtrue)
1639 AM_CONDITIONAL(USE_CMD, test x$cmd = xtrue)
1640 AM_CONDITIONAL(USE_AIKGEN, test x$aikgen = xtrue)
1641 AM_CONDITIONAL(USE_SWANCTL, test x$swanctl = xtrue)
1642 AM_CONDITIONAL(USE_SVC, test x$svc = xtrue)
1643 AM_CONDITIONAL(USE_SYSTEMD, test x$systemd = xtrue)
1644 AM_CONDITIONAL(USE_LEGACY_SYSTEMD, test -n "$systemdsystemunitdir" -a "x$systemdsystemunitdir" != xno)
1645 AM_CONDITIONAL(USE_RUBY_GEMS, test x$ruby_gems = xtrue)
1646 AM_CONDITIONAL(USE_PYTHON_EGGS, test x$python_eggs = xtrue)
1647 AM_CONDITIONAL(USE_PERL_CPAN, test x$perl_cpan = xtrue)
1648 AM_CONDITIONAL(USE_PY_TEST, test "x$PY_TEST" != x)
1649
1650 # ========================
1651 #  set global definitions
1652 # ========================
1653
1654 if test x$mediation = xtrue; then
1655         AC_DEFINE([ME], [], [mediation extension support])
1656 fi
1657 if test x$capabilities = xlibcap -o x$capabilities = xnative; then
1658         AC_DEFINE([CAPABILITIES], [], [capability dropping support])
1659 fi
1660 if test x$log_thread_ids = xtrue; then
1661         AC_DEFINE([USE_THREAD_IDS], [], [use thread ID for thread identification, if available])
1662 fi
1663 if test x$monolithic = xtrue; then
1664         AC_DEFINE([MONOLITHIC], [], [monolithic build embedding plugins])
1665 fi
1666 if test x$ikev1 = xtrue; then
1667         AC_DEFINE([USE_IKEV1], [], [support for IKEv1 protocol])
1668 fi
1669 if test x$ikev2 = xtrue; then
1670         AC_DEFINE([USE_IKEV2], [], [support for IKEv2 protocol])
1671 fi
1672
1673 # ====================================================
1674 #  options for enabled modules (see conf/Makefile.am)
1675 # ====================================================
1676
1677 strongswan_options=
1678
1679 AM_COND_IF([USE_AIKGEN], [strongswan_options=${strongswan_options}" aikgen"])
1680 AM_COND_IF([USE_ATTR_SQL], [strongswan_options=${strongswan_options}" pool"])
1681 AM_COND_IF([USE_CHARON], [strongswan_options=${strongswan_options}" charon charon-logging"])
1682 AM_COND_IF([USE_FILE_CONFIG], [strongswan_options=${strongswan_options}" starter"])
1683 AM_COND_IF([USE_IMV_ATTESTATION], [strongswan_options=${strongswan_options}" attest"])
1684 AM_COND_IF([USE_IMCV], [strongswan_options=${strongswan_options}" imcv"])
1685 AM_COND_IF([USE_IMV_OS], [strongswan_options=${strongswan_options}" pacman"])
1686 AM_COND_IF([USE_LIBTNCCS], [strongswan_options=${strongswan_options}" tnc"])
1687 AM_COND_IF([USE_MANAGER], [strongswan_options=${strongswan_options}" manager"])
1688 AM_COND_IF([USE_MEDSRV], [strongswan_options=${strongswan_options}" medsrv"])
1689 AM_COND_IF([USE_SCEPCLIENT], [strongswan_options=${strongswan_options}" scepclient"])
1690 AM_COND_IF([USE_PKI], [strongswan_options=${strongswan_options}" pki"])
1691 AM_COND_IF([USE_SWANCTL], [strongswan_options=${strongswan_options}" swanctl"])
1692
1693 AC_SUBST(strongswan_options)
1694
1695 # =================
1696 #  build Makefiles
1697 # =================
1698
1699 AC_CONFIG_FILES([
1700         Makefile
1701         conf/Makefile
1702         man/Makefile
1703         init/Makefile
1704         init/systemd/Makefile
1705         init/systemd-swanctl/Makefile
1706         src/Makefile
1707         src/include/Makefile
1708         src/libstrongswan/Makefile
1709         src/libstrongswan/plugins/aes/Makefile
1710         src/libstrongswan/plugins/cmac/Makefile
1711         src/libstrongswan/plugins/des/Makefile
1712         src/libstrongswan/plugins/blowfish/Makefile
1713         src/libstrongswan/plugins/rc2/Makefile
1714         src/libstrongswan/plugins/md4/Makefile
1715         src/libstrongswan/plugins/md5/Makefile
1716         src/libstrongswan/plugins/sha1/Makefile
1717         src/libstrongswan/plugins/sha2/Makefile
1718         src/libstrongswan/plugins/sha3/Makefile
1719         src/libstrongswan/plugins/fips_prf/Makefile
1720         src/libstrongswan/plugins/gmp/Makefile
1721         src/libstrongswan/plugins/rdrand/Makefile
1722         src/libstrongswan/plugins/aesni/Makefile
1723         src/libstrongswan/plugins/random/Makefile
1724         src/libstrongswan/plugins/nonce/Makefile
1725         src/libstrongswan/plugins/hmac/Makefile
1726         src/libstrongswan/plugins/xcbc/Makefile
1727         src/libstrongswan/plugins/x509/Makefile
1728         src/libstrongswan/plugins/revocation/Makefile
1729         src/libstrongswan/plugins/constraints/Makefile
1730         src/libstrongswan/plugins/acert/Makefile
1731         src/libstrongswan/plugins/pubkey/Makefile
1732         src/libstrongswan/plugins/pkcs1/Makefile
1733         src/libstrongswan/plugins/pkcs7/Makefile
1734         src/libstrongswan/plugins/pkcs8/Makefile
1735         src/libstrongswan/plugins/pkcs12/Makefile
1736         src/libstrongswan/plugins/pgp/Makefile
1737         src/libstrongswan/plugins/dnskey/Makefile
1738         src/libstrongswan/plugins/sshkey/Makefile
1739         src/libstrongswan/plugins/pem/Makefile
1740         src/libstrongswan/plugins/curl/Makefile
1741         src/libstrongswan/plugins/files/Makefile
1742         src/libstrongswan/plugins/winhttp/Makefile
1743         src/libstrongswan/plugins/unbound/Makefile
1744         src/libstrongswan/plugins/soup/Makefile
1745         src/libstrongswan/plugins/ldap/Makefile
1746         src/libstrongswan/plugins/mysql/Makefile
1747         src/libstrongswan/plugins/sqlite/Makefile
1748         src/libstrongswan/plugins/padlock/Makefile
1749         src/libstrongswan/plugins/openssl/Makefile
1750         src/libstrongswan/plugins/gcrypt/Makefile
1751         src/libstrongswan/plugins/agent/Makefile
1752         src/libstrongswan/plugins/keychain/Makefile
1753         src/libstrongswan/plugins/pkcs11/Makefile
1754         src/libstrongswan/plugins/chapoly/Makefile
1755         src/libstrongswan/plugins/ctr/Makefile
1756         src/libstrongswan/plugins/ccm/Makefile
1757         src/libstrongswan/plugins/gcm/Makefile
1758         src/libstrongswan/plugins/af_alg/Makefile
1759         src/libstrongswan/plugins/ntru/Makefile
1760         src/libstrongswan/plugins/bliss/Makefile
1761         src/libstrongswan/plugins/bliss/tests/Makefile
1762         src/libstrongswan/plugins/test_vectors/Makefile
1763         src/libstrongswan/tests/Makefile
1764         src/libipsec/Makefile
1765         src/libipsec/tests/Makefile
1766         src/libsimaka/Makefile
1767         src/libtls/Makefile
1768         src/libtls/tests/Makefile
1769         src/libradius/Makefile
1770         src/libtncif/Makefile
1771         src/libtnccs/Makefile
1772         src/libtnccs/plugins/tnc_tnccs/Makefile
1773         src/libtnccs/plugins/tnc_imc/Makefile
1774         src/libtnccs/plugins/tnc_imv/Makefile
1775         src/libtnccs/plugins/tnccs_11/Makefile
1776         src/libtnccs/plugins/tnccs_20/Makefile
1777         src/libtnccs/plugins/tnccs_dynamic/Makefile
1778         src/libpttls/Makefile
1779         src/libimcv/Makefile
1780         src/libimcv/plugins/imc_test/Makefile
1781         src/libimcv/plugins/imv_test/Makefile
1782         src/libimcv/plugins/imc_scanner/Makefile
1783         src/libimcv/plugins/imv_scanner/Makefile
1784         src/libimcv/plugins/imc_os/Makefile
1785         src/libimcv/plugins/imv_os/Makefile
1786         src/libimcv/plugins/imc_attestation/Makefile
1787         src/libimcv/plugins/imv_attestation/Makefile
1788         src/libimcv/plugins/imc_swid/Makefile
1789         src/libimcv/plugins/imv_swid/Makefile
1790         src/libimcv/plugins/imc_hcd/Makefile
1791         src/libimcv/plugins/imv_hcd/Makefile
1792         src/charon/Makefile
1793         src/charon-nm/Makefile
1794         src/charon-tkm/Makefile
1795         src/charon-cmd/Makefile
1796         src/charon-svc/Makefile
1797         src/charon-systemd/Makefile
1798         src/libcharon/Makefile
1799         src/libcharon/plugins/eap_aka/Makefile
1800         src/libcharon/plugins/eap_aka_3gpp2/Makefile
1801         src/libcharon/plugins/eap_dynamic/Makefile
1802         src/libcharon/plugins/eap_identity/Makefile
1803         src/libcharon/plugins/eap_md5/Makefile
1804         src/libcharon/plugins/eap_gtc/Makefile
1805         src/libcharon/plugins/eap_sim/Makefile
1806         src/libcharon/plugins/eap_sim_file/Makefile
1807         src/libcharon/plugins/eap_sim_pcsc/Makefile
1808         src/libcharon/plugins/eap_simaka_sql/Makefile
1809         src/libcharon/plugins/eap_simaka_pseudonym/Makefile
1810         src/libcharon/plugins/eap_simaka_reauth/Makefile
1811         src/libcharon/plugins/eap_mschapv2/Makefile
1812         src/libcharon/plugins/eap_tls/Makefile
1813         src/libcharon/plugins/eap_ttls/Makefile
1814         src/libcharon/plugins/eap_peap/Makefile
1815         src/libcharon/plugins/eap_tnc/Makefile
1816         src/libcharon/plugins/eap_radius/Makefile
1817         src/libcharon/plugins/xauth_generic/Makefile
1818         src/libcharon/plugins/xauth_eap/Makefile
1819         src/libcharon/plugins/xauth_pam/Makefile
1820         src/libcharon/plugins/xauth_noauth/Makefile
1821         src/libcharon/plugins/tnc_ifmap/Makefile
1822         src/libcharon/plugins/tnc_pdp/Makefile
1823         src/libcharon/plugins/socket_default/Makefile
1824         src/libcharon/plugins/socket_dynamic/Makefile
1825         src/libcharon/plugins/socket_win/Makefile
1826         src/libcharon/plugins/connmark/Makefile
1827         src/libcharon/plugins/forecast/Makefile
1828         src/libcharon/plugins/farp/Makefile
1829         src/libcharon/plugins/smp/Makefile
1830         src/libcharon/plugins/sql/Makefile
1831         src/libcharon/plugins/dnscert/Makefile
1832         src/libcharon/plugins/ipseckey/Makefile
1833         src/libcharon/plugins/medsrv/Makefile
1834         src/libcharon/plugins/medcli/Makefile
1835         src/libcharon/plugins/addrblock/Makefile
1836         src/libcharon/plugins/unity/Makefile
1837         src/libcharon/plugins/uci/Makefile
1838         src/libcharon/plugins/ha/Makefile
1839         src/libcharon/plugins/kernel_netlink/Makefile
1840         src/libcharon/plugins/kernel_pfkey/Makefile
1841         src/libcharon/plugins/kernel_pfroute/Makefile
1842         src/libcharon/plugins/kernel_libipsec/Makefile
1843         src/libcharon/plugins/kernel_wfp/Makefile
1844         src/libcharon/plugins/kernel_iph/Makefile
1845         src/libcharon/plugins/whitelist/Makefile
1846         src/libcharon/plugins/ext_auth/Makefile
1847         src/libcharon/plugins/lookip/Makefile
1848         src/libcharon/plugins/error_notify/Makefile
1849         src/libcharon/plugins/certexpire/Makefile
1850         src/libcharon/plugins/systime_fix/Makefile
1851         src/libcharon/plugins/led/Makefile
1852         src/libcharon/plugins/duplicheck/Makefile
1853         src/libcharon/plugins/coupling/Makefile
1854         src/libcharon/plugins/radattr/Makefile
1855         src/libcharon/plugins/osx_attr/Makefile
1856         src/libcharon/plugins/p_cscf/Makefile
1857         src/libcharon/plugins/android_dns/Makefile
1858         src/libcharon/plugins/android_log/Makefile
1859         src/libcharon/plugins/maemo/Makefile
1860         src/libcharon/plugins/stroke/Makefile
1861         src/libcharon/plugins/vici/Makefile
1862         src/libcharon/plugins/vici/ruby/Makefile
1863         src/libcharon/plugins/vici/perl/Makefile
1864         src/libcharon/plugins/vici/python/Makefile
1865         src/libcharon/plugins/updown/Makefile
1866         src/libcharon/plugins/dhcp/Makefile
1867         src/libcharon/plugins/load_tester/Makefile
1868         src/libcharon/plugins/resolve/Makefile
1869         src/libcharon/plugins/attr/Makefile
1870         src/libcharon/plugins/attr_sql/Makefile
1871         src/libcharon/tests/Makefile
1872         src/stroke/Makefile
1873         src/ipsec/Makefile
1874         src/starter/Makefile
1875         src/starter/tests/Makefile
1876         src/_updown/Makefile
1877         src/_copyright/Makefile
1878         src/scepclient/Makefile
1879         src/aikgen/Makefile
1880         src/pki/Makefile
1881         src/pki/man/Makefile
1882         src/pool/Makefile
1883         src/dumm/Makefile
1884         src/dumm/ext/extconf.rb
1885         src/libfast/Makefile
1886         src/manager/Makefile
1887         src/medsrv/Makefile
1888         src/checksum/Makefile
1889         src/conftest/Makefile
1890         src/pt-tls-client/Makefile
1891         src/swanctl/Makefile
1892         scripts/Makefile
1893         testing/Makefile
1894 ])
1895
1896 # =================
1897 #  build man pages
1898 # =================
1899
1900 AC_CONFIG_FILES([
1901         conf/strongswan.conf.5.head
1902         conf/strongswan.conf.5.tail
1903         man/ipsec.conf.5
1904         man/ipsec.secrets.5
1905         src/charon-cmd/charon-cmd.8
1906         src/pki/man/pki.1
1907         src/pki/man/pki---acert.1
1908         src/pki/man/pki---dn.1
1909         src/pki/man/pki---gen.1
1910         src/pki/man/pki---issue.1
1911         src/pki/man/pki---keyid.1
1912         src/pki/man/pki---pkcs12.1
1913         src/pki/man/pki---pkcs7.1
1914         src/pki/man/pki---print.1
1915         src/pki/man/pki---pub.1
1916         src/pki/man/pki---req.1
1917         src/pki/man/pki---self.1
1918         src/pki/man/pki---signcrl.1
1919         src/pki/man/pki---verify.1
1920         src/swanctl/swanctl.8
1921         src/swanctl/swanctl.conf.5.head
1922         src/swanctl/swanctl.conf.5.tail
1923 ])
1924
1925 AC_OUTPUT
1926
1927 # ========================
1928 #  report enabled plugins
1929 # ========================
1930
1931 AC_MSG_RESULT([])
1932 AC_MSG_RESULT([ strongSwan will be built with the following plugins])
1933 AC_MSG_RESULT([-----------------------------------------------------])
1934
1935 AC_MSG_RESULT([libstrongswan:$s_plugins])
1936 AC_MSG_RESULT([libcharon:    $c_plugins])
1937 AC_MSG_RESULT([libtnccs:     $t_plugins])
1938 AC_MSG_RESULT([])