Merge branch 'win-socket'
[strongswan.git] / configure.ac
1 #
2 # Copyright (C) 2007-2014 Tobias Brunner
3 # Copyright (C) 2006-2013 Andreas Steffen
4 # Copyright (C) 2006-2013 Martin Willi
5 # Hochschule fuer Technik Rapperswil
6 #
7 # This program is free software; you can redistribute it and/or modify it
8 # under the terms of the GNU General Public License as published by the
9 # Free Software Foundation; either version 2 of the License, or (at your
10 # option) any later version.  See <http://www.fsf.org/copyleft/gpl.txt>.
11 #
12 # This program is distributed in the hope that it will be useful, but
13 # WITHOUT ANY WARRANTY; without even the implied warranty of MERCHANTABILITY
14 # or FITNESS FOR A PARTICULAR PURPOSE.  See the GNU General Public License
15 # for more details.
16 #
17
18 # ============================
19 #  initialize & set some vars
20 # ============================
21
22 AC_INIT([strongSwan],[5.2.0dr5])
23 AM_INIT_AUTOMAKE(m4_esyscmd([
24         echo tar-ustar
25         echo subdir-objects
26         case `automake --version | head -n 1` in
27                 *" 1.9"*);;
28                 *" 1.10"*);;
29                 *" 1.11"*);;
30                 # don't use parallel test harness in 1.12 and up
31                 *) echo serial-tests;;
32         esac
33 ]))
34 m4_ifdef([AM_SILENT_RULES], [AM_SILENT_RULES])
35 AC_CONFIG_MACRO_DIR([m4/config])
36 AC_CONFIG_HEADERS([config.h])
37 AC_DEFINE([CONFIG_H_INCLUDED], [], [defined if config.h included])
38 PKG_PROG_PKG_CONFIG
39
40 m4_include(m4/macros/split-package-version.m4)
41 SPLIT_PACKAGE_VERSION
42
43 # =================================
44 #  check --enable-xxx & --with-xxx
45 # =================================
46
47 m4_include(m4/macros/with.m4)
48
49 ARG_WITH_SUBST([random-device],      [/dev/random], [set the device to read real random data from])
50 ARG_WITH_SUBST([urandom-device],     [/dev/urandom], [set the device to read pseudo random data from])
51 ARG_WITH_SUBST([strongswan-conf],    [${sysconfdir}/strongswan.conf], [set the strongswan.conf file location])
52 ARG_WITH_SUBST([resolv-conf],        [${sysconfdir}/resolv.conf], [set the file to use in DNS handler plugin])
53 ARG_WITH_SUBST([piddir],             [/var/run], [set path for PID and UNIX socket files])
54 ARG_WITH_SUBST([ipsecdir],           [${libexecdir%/}/ipsec], [set installation path for ipsec tools])
55 ARG_WITH_SUBST([ipseclibdir],        [${libdir%/}/ipsec], [set installation path for ipsec libraries])
56 ARG_WITH_SUBST([plugindir],          [${ipseclibdir%/}/plugins], [set the installation path of plugins])
57 ARG_WITH_SUBST([imcvdir],            [${ipseclibdir%/}/imcvs], [set the installation path of IMC and IMV dynamic librariers])
58 ARG_WITH_SUBST([nm-ca-dir],          [/usr/share/ca-certificates], [directory the NM backend uses to look up trusted root certificates])
59 ARG_WITH_SUBST([swanctldir],         [${sysconfdir}/swanctl], [base directory for swanctl configuration files and credentials])
60 ARG_WITH_SUBST([linux-headers],      [\${top_srcdir}/src/include], [set directory of linux header files to use])
61 ARG_WITH_SUBST([routing-table],      [220], [set routing table to use for IPsec routes])
62 ARG_WITH_SUBST([routing-table-prio], [220], [set priority for IPsec routing table])
63 ARG_WITH_SUBST([ipsec-script],       [ipsec], [change the name of the ipsec script])
64 ARG_WITH_SUBST([fips-mode],          [0], [set openssl FIPS mode: disabled(0), enabled(1), Suite B enabled(2)])
65
66 ARG_WITH_SET([tss],                  [no], [set implementation of the Trusted Computing Group's Software Stack (TSS). Currently the only supported value is "trousers"])
67 ARG_WITH_SET([capabilities],         [no], [set capability dropping library. Currently supported values are "libcap" and "native"])
68 ARG_WITH_SET([mpz_powm_sec],         [yes], [use the more side-channel resistant mpz_powm_sec in libgmp, if available])
69 ARG_WITH_SET([dev-headers],          [no], [install strongSwan development headers to directory.])
70 ARG_WITH_SET([printf-hooks],         [auto], [force the use of a specific printf hook implementation (auto, builtin, glibc, vstr).])
71
72 if test -n "$PKG_CONFIG"; then
73         systemdsystemunitdir_default=$($PKG_CONFIG --variable=systemdsystemunitdir systemd)
74 fi
75 ARG_WITH_SET([systemdsystemunitdir], [$systemdsystemunitdir_default], [directory for systemd service files])
76 AM_CONDITIONAL(HAVE_SYSTEMD, [test -n "$systemdsystemunitdir" -a "x$systemdsystemunitdir" != xno])
77 AC_SUBST(systemdsystemunitdir)
78
79 AC_ARG_WITH(
80         [user],
81         AS_HELP_STRING([--with-user=user],[change user of the daemons to "user" after startup (default is "root").]),
82         [AC_DEFINE_UNQUOTED([IPSEC_USER], "$withval", [username to run daemon with])
83          AC_SUBST(ipsecuser, "$withval")],
84         [AC_SUBST(ipsecuser, "root")]
85 )
86
87 AC_ARG_WITH(
88         [group],
89         AS_HELP_STRING([--with-group=group],[change group of the daemons to "group" after startup (default is "root").]),
90         [AC_DEFINE_UNQUOTED(IPSEC_GROUP, "$withval", [groupname to run daemon with])
91          AC_SUBST(ipsecgroup, "$withval")],
92         [AC_SUBST(ipsecgroup, "root")]
93 )
94
95 AC_ARG_WITH(
96         [charon-udp-port],
97         AS_HELP_STRING([--with-charon-udp-port=port],[UDP port used by charon locally (default 500). Set to 0 to allocate randomly.]),
98         [AC_DEFINE_UNQUOTED(CHARON_UDP_PORT, [$withval], [UDP port used by charon locally])
99          AC_SUBST(charon_udp_port, [$withval])],
100         [AC_SUBST(charon_udp_port, 500)]
101 )
102
103 AC_ARG_WITH(
104         [charon-natt-port],
105         AS_HELP_STRING([--with-charon-natt-port=port],[UDP port used by charon locally in case a NAT is detected (must be different from charon-udp-port, default 4500). Set to 0 to allocate randomly.]),
106         [AC_DEFINE_UNQUOTED(CHARON_NATT_PORT, [$withval], [UDP post used by charon locally in case a NAT is detected])
107          AC_SUBST(charon_natt_port, [$withval])],
108         [AC_SUBST(charon_natt_port, 4500)]
109 )
110
111 AC_MSG_CHECKING([configured UDP ports ($charon_udp_port, $charon_natt_port)])
112 if test x$charon_udp_port != x0 -a x$charon_udp_port = x$charon_natt_port; then
113         AC_MSG_ERROR(the ports have to be different)
114 else
115         AC_MSG_RESULT(ok)
116 fi
117
118 # convert script name to uppercase
119 AC_SUBST(ipsec_script_upper, [`echo -n "$ipsec_script" | tr a-z A-Z`])
120
121 m4_include(m4/macros/enable-disable.m4)
122
123 # crypto plugins
124 ARG_DISBL_SET([aes],            [disable AES software implementation plugin.])
125 ARG_ENABL_SET([af-alg],         [enable AF_ALG crypto interface to Linux Crypto API.])
126 ARG_ENABL_SET([blowfish],       [enable Blowfish software implementation plugin.])
127 ARG_ENABL_SET([ccm],            [enables the CCM AEAD wrapper crypto plugin.])
128 ARG_DISBL_SET([cmac],           [disable CMAC crypto implementation plugin.])
129 ARG_ENABL_SET([ctr],            [enables the Counter Mode wrapper crypto plugin.])
130 ARG_DISBL_SET([des],            [disable DES/3DES software implementation plugin.])
131 ARG_DISBL_SET([fips-prf],       [disable FIPS PRF software implementation plugin.])
132 ARG_ENABL_SET([gcm],            [enables the GCM AEAD wrapper crypto plugin.])
133 ARG_ENABL_SET([gcrypt],         [enables the libgcrypt plugin.])
134 ARG_DISBL_SET([gmp],            [disable GNU MP (libgmp) based crypto implementation plugin.])
135 ARG_DISBL_SET([hmac],           [disable HMAC crypto implementation plugin.])
136 ARG_ENABL_SET([md4],            [enable MD4 software implementation plugin.])
137 ARG_DISBL_SET([md5],            [disable MD5 software implementation plugin.])
138 ARG_DISBL_SET([nonce],          [disable nonce generation plugin.])
139 ARG_ENABL_SET([ntru],           [enables the NTRU crypto plugin.])
140 ARG_ENABL_SET([openssl],        [enables the OpenSSL crypto plugin.])
141 ARG_ENABL_SET([padlock],        [enables VIA Padlock crypto plugin.])
142 ARG_DISBL_SET([random],         [disable RNG implementation on top of /dev/(u)random.])
143 ARG_DISBL_SET([rc2],            [disable RC2 software implementation plugin.])
144 ARG_ENABL_SET([rdrand],         [enable Intel RDRAND random generator plugin.])
145 ARG_DISBL_SET([sha1],           [disable SHA1 software implementation plugin.])
146 ARG_DISBL_SET([sha2],           [disable SHA256/SHA384/SHA512 software implementation plugin.])
147 ARG_DISBL_SET([xcbc],           [disable xcbc crypto implementation plugin.])
148 # encoding/decoding plugins
149 ARG_DISBL_SET([dnskey],         [disable DNS RR key decoding plugin.])
150 ARG_DISBL_SET([pem],            [disable PEM decoding plugin.])
151 ARG_DISBL_SET([pgp],            [disable PGP key decoding plugin.])
152 ARG_DISBL_SET([pkcs1],          [disable PKCS1 key decoding plugin.])
153 ARG_DISBL_SET([pkcs7],          [disable PKCS7 container support plugin.])
154 ARG_DISBL_SET([pkcs8],          [disable PKCS8 private key decoding plugin.])
155 ARG_DISBL_SET([pkcs12],         [disable PKCS12 container support plugin.])
156 ARG_DISBL_SET([pubkey],         [disable RAW public key support plugin.])
157 ARG_DISBL_SET([sshkey],         [disable SSH key decoding plugin.])
158 ARG_DISBL_SET([x509],           [disable X509 certificate implementation plugin.])
159 # fetcher/resolver plugins
160 ARG_ENABL_SET([curl],           [enable CURL fetcher plugin to fetch files via libcurl. Requires libcurl.])
161 ARG_ENABL_SET([ldap],           [enable LDAP fetching plugin to fetch files via libldap. Requires openLDAP.])
162 ARG_ENABL_SET([soup],           [enable soup fetcher plugin to fetch from HTTP via libsoup. Requires libsoup.])
163 ARG_ENABL_SET([unbound],        [enable UNBOUND resolver plugin to perform DNS queries via libunbound. Requires libldns and libunbound.])
164 # database plugins
165 ARG_ENABL_SET([mysql],          [enable MySQL database support. Requires libmysqlclient_r.])
166 ARG_ENABL_SET([sqlite],         [enable SQLite database support. Requires libsqlite3.])
167 # authentication/credential plugins
168 ARG_ENABL_SET([addrblock],      [enables RFC 3779 address block constraint support.])
169 ARG_ENABL_SET([acert],          [enable X509 attribute certificate checking plugin.])
170 ARG_ENABL_SET([agent],          [enables the ssh-agent signing plugin.])
171 ARG_DISBL_SET([constraints],    [disable advanced X509 constraint checking plugin.])
172 ARG_ENABL_SET([coupling],       [enable IKEv2 plugin to couple peer certificates permanently to authentication.])
173 ARG_ENABL_SET([dnscert],        [enable DNSCERT authentication plugin.])
174 ARG_ENABL_SET([eap-sim],        [enable SIM authentication module for EAP.])
175 ARG_ENABL_SET([eap-sim-file],   [enable EAP-SIM backend based on a triplet file.])
176 ARG_ENABL_SET([eap-sim-pcsc],   [enable EAP-SIM backend based on a smartcard reader. Requires libpcsclite.])
177 ARG_ENABL_SET([eap-aka],        [enable EAP AKA authentication module.])
178 ARG_ENABL_SET([eap-aka-3gpp2],  [enable EAP AKA backend implementing 3GPP2 algorithms in software. Requires libgmp.])
179 ARG_ENABL_SET([eap-simaka-sql], [enable EAP-SIM/AKA backend based on a triplet/quintuplet SQL database.])
180 ARG_ENABL_SET([eap-simaka-pseudonym], [enable EAP-SIM/AKA pseudonym storage plugin.])
181 ARG_ENABL_SET([eap-simaka-reauth],    [enable EAP-SIM/AKA reauthentication data storage plugin.])
182 ARG_ENABL_SET([eap-identity],   [enable EAP module providing EAP-Identity helper.])
183 ARG_ENABL_SET([eap-md5],        [enable EAP MD5 (CHAP) authentication module.])
184 ARG_ENABL_SET([eap-gtc],        [enable EAP GTC authentication module.])
185 ARG_ENABL_SET([eap-mschapv2],   [enable EAP MS-CHAPv2 authentication module.])
186 ARG_ENABL_SET([eap-tls],        [enable EAP TLS authentication module.])
187 ARG_ENABL_SET([eap-ttls],       [enable EAP TTLS authentication module.])
188 ARG_ENABL_SET([eap-peap],       [enable EAP PEAP authentication module.])
189 ARG_ENABL_SET([eap-tnc],        [enable EAP TNC trusted network connect module.])
190 ARG_ENABL_SET([eap-dynamic],    [enable dynamic EAP proxy module.])
191 ARG_ENABL_SET([eap-radius],     [enable RADIUS proxy authentication module.])
192 ARG_ENABL_SET([ipseckey],       [enable IPSECKEY authentication plugin.])
193 ARG_ENABL_SET([keychain],       [enables OS X Keychain Services credential set.])
194 ARG_ENABL_SET([pkcs11],         [enables the PKCS11 token support plugin.])
195 ARG_DISBL_SET([revocation],     [disable X509 CRL/OCSP revocation check plugin.])
196 ARG_ENABL_SET([whitelist],      [enable peer identity whitelisting plugin.])
197 ARG_DISBL_SET([xauth-generic],  [disable generic XAuth backend.])
198 ARG_ENABL_SET([xauth-eap],      [enable XAuth backend using EAP methods to verify passwords.])
199 ARG_ENABL_SET([xauth-pam],      [enable XAuth backend using PAM to verify passwords.])
200 ARG_ENABL_SET([xauth-noauth],   [enable XAuth pseudo-backend that does not actually verify or even request any credentials.])
201 # kernel interfaces / sockets
202 ARG_DISBL_SET([kernel-netlink], [disable the netlink kernel interface.])
203 ARG_ENABL_SET([kernel-pfkey],   [enable the PF_KEY kernel interface.])
204 ARG_ENABL_SET([kernel-pfroute], [enable the PF_ROUTE kernel interface.])
205 ARG_ENABL_SET([kernel-klips],   [enable the KLIPS kernel interface.])
206 ARG_ENABL_SET([kernel-libipsec],[enable the libipsec kernel interface.])
207 ARG_DISBL_SET([socket-default], [disable default socket implementation for charon.])
208 ARG_ENABL_SET([socket-dynamic], [enable dynamic socket implementation for charon])
209 ARG_ENABL_SET([socket-win],     [enable Winsock2 based socket implementation for charon])
210 # configuration/control plugins
211 ARG_DISBL_SET([stroke],         [disable charons stroke configuration backend.])
212 ARG_ENABL_SET([smp],            [enable SMP configuration and control interface. Requires libxml.])
213 ARG_ENABL_SET([sql],            [enable SQL database configuration backend.])
214 ARG_ENABL_SET([uci],            [enable OpenWRT UCI configuration plugin.])
215 ARG_ENABL_SET([vici],           [enable strongSwan IKE generic IPC interface plugin.])
216 # attribute provider/consumer plugins
217 ARG_ENABL_SET([android-dns],    [enable Android specific DNS handler.])
218 ARG_DISBL_SET([attr],           [disable strongswan.conf based configuration attribute plugin.])
219 ARG_ENABL_SET([attr-sql],       [enable SQL based configuration attribute plugin.])
220 ARG_ENABL_SET([dhcp],           [enable DHCP based attribute provider plugin.])
221 ARG_ENABL_SET([osx-attr],       [enable OS X SystemConfiguration attribute handler.])
222 ARG_DISBL_SET([resolve],        [disable resolve DNS handler plugin.])
223 ARG_ENABL_SET([unity],          [enables Cisco Unity extension plugin.])
224 # TNC modules/plugins
225 ARG_ENABL_SET([imc-test],       [enable IMC test module.])
226 ARG_ENABL_SET([imv-test],       [enable IMV test module.])
227 ARG_ENABL_SET([imc-scanner],    [enable IMC port scanner module.])
228 ARG_ENABL_SET([imv-scanner],    [enable IMV port scanner module.])
229 ARG_ENABL_SET([imc-os],         [enable IMC operating system module.])
230 ARG_ENABL_SET([imv-os],         [enable IMV operating system module.])
231 ARG_ENABL_SET([imc-attestation],[enable IMC attestation module.])
232 ARG_ENABL_SET([imv-attestation],[enable IMV attestation module.])
233 ARG_ENABL_SET([imc-swid],       [enable IMC swid module.])
234 ARG_ENABL_SET([imv-swid],       [enable IMV swid module.])
235 ARG_ENABL_SET([tnc-ifmap],      [enable TNC IF-MAP module. Requires libxml])
236 ARG_ENABL_SET([tnc-imc],        [enable TNC IMC module.])
237 ARG_ENABL_SET([tnc-imv],        [enable TNC IMV module.])
238 ARG_ENABL_SET([tnc-pdp],        [enable TNC policy decision point module.])
239 ARG_ENABL_SET([tnccs-11],       [enable TNCCS 1.1 protocol module. Requires libxml])
240 ARG_ENABL_SET([tnccs-20],       [enable TNCCS 2.0 protocol module.])
241 ARG_ENABL_SET([tnccs-dynamic],  [enable dynamic TNCCS protocol discovery module.])
242 # misc plugins
243 ARG_ENABL_SET([android-log],    [enable Android specific logger plugin.])
244 ARG_ENABL_SET([certexpire],     [enable CSV export of expiration dates of used certificates.])
245 ARG_ENABL_SET([duplicheck],     [advanced duplicate checking plugin using liveness checks.])
246 ARG_ENABL_SET([error-notify],   [enable error notification plugin.])
247 ARG_ENABL_SET([farp],           [enable ARP faking plugin that responds to ARP requests to peers virtual IP])
248 ARG_ENABL_SET([ha],             [enable high availability cluster plugin.])
249 ARG_ENABL_SET([led],            [enable plugin to control LEDs on IKEv2 activity using the Linux kernel LED subsystem.])
250 ARG_ENABL_SET([load-tester],    [enable load testing plugin for IKEv2 daemon.])
251 ARG_ENABL_SET([lookip],         [enable fast virtual IP lookup and notification plugin.])
252 ARG_ENABL_SET([maemo],          [enable Maemo specific plugin.])
253 ARG_ENABL_SET([radattr],        [enable plugin to inject and process custom RADIUS attributes as IKEv2 client.])
254 ARG_ENABL_SET([systime-fix],    [enable plugin to handle cert lifetimes with invalid system time gracefully.])
255 ARG_ENABL_SET([test-vectors],   [enable plugin providing crypto test vectors.])
256 ARG_ENABL_SET([unit-tester],    [enable unit tests on IKEv2 daemon startup.])
257 ARG_DISBL_SET([updown],         [disable updown firewall script plugin.])
258 # programs/components
259 ARG_DISBL_SET([charon],         [disable the IKEv1/IKEv2 keying daemon charon.])
260 ARG_ENABL_SET([cmd],            [enable the command line IKE client charon-cmd.])
261 ARG_ENABL_SET([conftest],       [enforce Suite B conformance test framework.])
262 ARG_ENABL_SET([dumm],           [enable the DUMM UML test framework.])
263 ARG_ENABL_SET([fast],           [enable libfast (FastCGI Application Server w/ templates.])
264 ARG_ENABL_SET([libipsec],       [enable user space IPsec implementation.])
265 ARG_ENABL_SET([manager],        [enable web management console (proof of concept).])
266 ARG_ENABL_SET([medcli],         [enable mediation client configuration database plugin.])
267 ARG_ENABL_SET([medsrv],         [enable mediation server web frontend and daemon plugin.])
268 ARG_ENABL_SET([nm],             [enable NetworkManager backend.])
269 ARG_DISBL_SET([pki],            [disable pki certificate utility.])
270 ARG_DISBL_SET([scripts],        [disable additional utilities (found in directory scripts).])
271 ARG_ENABL_SET([svc],            [enable charon Windows service.])
272 ARG_ENABL_SET([swanctl],        [enable swanctl configuration and control tool.])
273 ARG_ENABL_SET([tkm],            [enable Trusted Key Manager support.])
274 ARG_DISBL_SET([tools],          [disable additional utilities (scepclient).])
275 ARG_ENABL_SET([aikgen],         [enable AIK generator.])
276 # optional features
277 ARG_ENABL_SET([bfd-backtraces], [use binutils libbfd to resolve backtraces for memory leaks and segfaults.])
278 ARG_ENABL_SET([dbghelp-backtraces],[use dbghlp.dll on Windows to create and print backtraces for memory leaks and segfaults.])
279 ARG_DISBL_SET([ikev1],          [disable IKEv1 protocol support in charon.])
280 ARG_DISBL_SET([ikev2],          [disable IKEv2 protocol support in charon.])
281 ARG_ENABL_SET([integrity-test], [enable integrity testing of libstrongswan and plugins.])
282 ARG_DISBL_SET([load-warning],   [disable the charon plugin load option warning in starter.])
283 ARG_ENABL_SET([mediation],      [enable IKEv2 Mediation Extension.])
284 ARG_ENABL_SET([unwind-backtraces],[use libunwind to create backtraces for memory leaks and segfaults.])
285 # compile options
286 ARG_ENABL_SET([coverage],       [enable lcov coverage report generation.])
287 ARG_ENABL_SET([leak-detective], [enable malloc hooks to find memory leaks.])
288 ARG_ENABL_SET([lock-profiler],  [enable lock/mutex profiling code.])
289 ARG_ENABL_SET([monolithic],     [build monolithic version of libstrongswan that includes all enabled plugins. Similarly, the plugins of charon are assembled in libcharon.])
290
291 # ===================================
292 #  option to disable default options
293 # ===================================
294
295 ARG_DISBL_SET([defaults],       [disable all default plugins (they can be enabled with their respective --enable options)])
296
297 if test x$defaults = xfalse; then
298         for option in $enabled_by_default; do
299                 eval test x\${${option}_given} = xtrue && continue
300                 eval $option=false
301         done
302 fi
303
304 # ==============================
305 #  option to enable all options
306 # ==============================
307
308 ARG_ENABL_SET([all],            [enable all plugins and features (they can be disabled with their respective --disable options). Mainly for testing.])
309
310 if test x$all_given = xtrue; then
311         for option in $disabled_by_default; do
312                 eval test x\${${option}_given} = xtrue && continue
313                 eval $option=true
314         done
315 fi
316
317 # ===========================
318 #  set up compiler and flags
319 # ===========================
320
321 if test -z "$CFLAGS"; then
322         CFLAGS="-g -O2 -Wall -Wno-format -Wno-format-security -Wno-pointer-sign"
323 fi
324 AC_PROG_CC
325 AM_PROG_CC_C_O
326
327 AC_LIB_PREFIX
328 AC_C_BIGENDIAN
329
330 # =========================
331 #  check required programs
332 # =========================
333
334 LT_INIT
335 AC_PROG_INSTALL
336 AC_PROG_EGREP
337 AC_PROG_AWK
338 AC_PROG_LEX
339 AC_PROG_YACC
340 AM_PATH_PYTHON(,,[:])
341 AC_PATH_PROG([PERL], [perl], [], [$PATH:/bin:/usr/bin:/usr/local/bin])
342 AC_PATH_PROG([GPERF], [gperf], [], [$PATH:/bin:/usr/bin:/usr/local/bin])
343
344 # because gperf is not needed by end-users we just report it but do not abort on failure
345 AC_MSG_CHECKING([gperf version >= 3.0.0])
346 if test -x "$GPERF"; then
347         if test "`$GPERF --version | $AWK -F' ' '/^GNU gperf/ { print $3 }' | $AWK -F. '{ print $1 }'`" -ge "3"; then
348                 AC_MSG_RESULT([yes])
349         else
350                 AC_MSG_RESULT([no])
351         fi
352 else
353         AC_MSG_RESULT([not found])
354 fi
355
356 # ========================
357 #  dependency calculation
358 # ========================
359
360 if test x$xauth_generic_given = xfalse -a x$ikev1 = xfalse; then
361         xauth_generic=false;
362 fi
363
364 if test x$kernel_libipsec = xtrue; then
365         libipsec=true;
366 fi
367
368 if test x$eap_aka_3gpp2 = xtrue; then
369         gmp=true;
370 fi
371
372 if test x$eap_aka = xtrue; then
373         fips_prf=true;
374         simaka=true;
375 fi
376
377 if test x$eap_sim = xtrue; then
378         fips_prf=true;
379         simaka=true;
380 fi
381
382 if test x$eap_radius = xtrue -o x$radattr = xtrue -o x$tnc_pdp = xtrue; then
383         radius=true;
384 fi
385
386 if test x$tnc_imc = xtrue -o x$tnc_imv = xtrue -o x$tnccs_11 = xtrue -o x$tnccs_11 = xtrue -o x$tnccs_dynamic = xtrue -o x$eap_tnc = xtrue; then
387         tnc_tnccs=true;
388 fi
389
390 if test x$eap_tls = xtrue -o x$eap_ttls = xtrue -o x$eap_peap = xtrue -o x$tnc_tnccs = xtrue; then
391         tls=true;
392 fi
393
394 if test x$imc_test = xtrue -o x$imv_test = xtrue -o x$imc_scanner = xtrue -o x$imv_scanner = xtrue -o x$imc_os = xtrue -o x$imv_os = xtrue -o x$imc_attestation = xtrue -o x$imv_attestation = xtrue -o x$imc_swid = xtrue -o x$imv_swid = xtrue; then
395         imcv=true;
396 fi
397
398 if test x$imc_attestation = xtrue -o x$imv_attestation = xtrue -o x$imc_swid = xtrue -o x$imv_swid = xtrue; then
399         pts=true;
400 fi
401
402 if test x$fips_prf = xtrue; then
403         if test x$openssl = xfalse; then
404                 sha1=true;
405         fi
406 fi
407
408 if test x$swanctl = xtrue; then
409         vici=true
410 fi
411
412 if test x$smp = xtrue -o x$tnccs_11 = xtrue -o x$tnc_ifmap = xtrue; then
413         xml=true
414 fi
415
416 if test x$manager = xtrue; then
417         fast=true
418 fi
419
420 if test x$medsrv = xtrue; then
421         mediation=true
422         fast=true
423 fi
424
425 if test x$medcli = xtrue; then
426         mediation=true
427 fi
428
429 # ===========================================
430 #  check required libraries and header files
431 # ===========================================
432
433 AC_HEADER_STDBOOL
434 AC_FUNC_ALLOCA
435 AC_FUNC_STRERROR_R
436
437 #  libraries needed on some platforms but not on others
438 # ------------------------------------------------------
439 saved_LIBS=$LIBS
440
441 # FreeBSD and Mac OS X have dlopen integrated in libc, Linux needs libdl
442 LIBS=""
443 AC_SEARCH_LIBS(dlopen, dl, [DLLIB=$LIBS])
444 AC_SUBST(DLLIB)
445
446 # glibc's backtrace() can be replicated on FreeBSD with libexecinfo
447 LIBS=""
448 AC_SEARCH_LIBS(backtrace, execinfo, [BTLIB=$LIBS])
449 AC_CHECK_FUNCS(backtrace)
450 AC_SUBST(BTLIB)
451
452 # OpenSolaris needs libsocket and libnsl for socket()
453 LIBS=""
454 AC_SEARCH_LIBS(socket, socket, [SOCKLIB=$LIBS],
455         [AC_CHECK_LIB(nsl, socket, [SOCKLIB="-lsocket -lnsl"], [], [-lsocket])]
456 )
457 AC_SUBST(SOCKLIB)
458
459 # FreeBSD has clock_gettime in libc, Linux needs librt
460 LIBS=""
461 AC_SEARCH_LIBS(clock_gettime, rt, [RTLIB=$LIBS])
462 AC_CHECK_FUNCS(clock_gettime)
463 AC_SUBST(RTLIB)
464
465 # Android has pthread_* functions in bionic (libc), others need libpthread
466 LIBS=""
467 AC_SEARCH_LIBS(pthread_create, pthread, [PTHREADLIB=$LIBS])
468 AC_SUBST(PTHREADLIB)
469
470 LIBS=$saved_LIBS
471 # ------------------------------------------------------
472
473 AC_MSG_CHECKING(for dladdr)
474 AC_COMPILE_IFELSE(
475         [AC_LANG_PROGRAM(
476                 [[#define _GNU_SOURCE
477                   #include <dlfcn.h>]],
478                 [[Dl_info* info = 0;
479                   dladdr(0, info);]])],
480         [AC_MSG_RESULT([yes]); AC_DEFINE([HAVE_DLADDR], [], [have dladdr()])],
481         [AC_MSG_RESULT([no])]
482 )
483
484 # check if pthread_condattr_setclock(CLOCK_MONOTONE) is supported
485 saved_LIBS=$LIBS
486 LIBS=$PTHREADLIB
487 AC_MSG_CHECKING([for pthread_condattr_setclock(CLOCK_MONOTONE)])
488 AC_RUN_IFELSE(
489         [AC_LANG_SOURCE(
490                 [[#include <pthread.h>
491                   int main() { pthread_condattr_t attr;
492                         pthread_condattr_init(&attr);
493                         return pthread_condattr_setclock(&attr, CLOCK_MONOTONIC);}]])],
494         [AC_MSG_RESULT([yes]);
495          AC_DEFINE([HAVE_CONDATTR_CLOCK_MONOTONIC], [],
496                            [pthread_condattr_setclock supports CLOCK_MONOTONIC])],
497         [AC_MSG_RESULT([no])],
498         # Check existence of pthread_condattr_setclock if cross-compiling
499         [AC_MSG_RESULT([unknown]);
500          AC_CHECK_FUNCS(pthread_condattr_setclock,
501                 [AC_DEFINE([HAVE_CONDATTR_CLOCK_MONOTONIC], [],
502                                    [have pthread_condattr_setclock()])]
503         )]
504 )
505 # check if we actually are able to configure attributes on cond vars
506 AC_CHECK_FUNCS(pthread_condattr_init)
507 # instead of pthread_condattr_setclock Android has this function
508 AC_CHECK_FUNCS(pthread_cond_timedwait_monotonic)
509 # check if we can cancel threads
510 AC_CHECK_FUNCS(pthread_cancel)
511 # check if native rwlocks are available
512 AC_CHECK_FUNCS(pthread_rwlock_init)
513 # check if pthread spinlocks are available
514 AC_CHECK_FUNCS(pthread_spin_init)
515 # check if we have POSIX semaphore functions, including timed-wait
516 AC_CHECK_FUNCS(sem_timedwait)
517 LIBS=$saved_LIBS
518
519 AC_CHECK_FUNC(
520         [gettid],
521         [AC_DEFINE([HAVE_GETTID], [], [have gettid()])],
522         [AC_MSG_CHECKING([for SYS_gettid])
523          AC_COMPILE_IFELSE(
524                 [AC_LANG_PROGRAM(
525                         [[#define _GNU_SOURCE
526                           #include <unistd.h>
527                           #include <sys/syscall.h>]],
528                         [[int main() {
529                           return syscall(SYS_gettid);}]])],
530                 [AC_MSG_RESULT([yes]);
531                  AC_DEFINE([HAVE_GETTID], [], [have gettid()])
532                  AC_DEFINE([HAVE_SYS_GETTID], [], [have syscall(SYS_gettid)])],
533                 [AC_MSG_RESULT([no])]
534         )]
535 )
536
537 AC_CHECK_FUNC(
538         [qsort_r],
539         [
540                 AC_DEFINE([HAVE_QSORT_R], [], [have qsort_r()])
541                 # set -Werror so that we get an error for "argument ... has
542                 # incompatible pointer type" warnings
543                 save_CFLAGS="$CFLAGS"
544                 CFLAGS="$CFLAGS -Werror"
545                 AC_MSG_CHECKING([for GNU-style qsort_r])
546                 AC_COMPILE_IFELSE(
547                         [AC_LANG_PROGRAM(
548                                 [[#define _GNU_SOURCE
549                                   #include <stdlib.h>
550                                   int cmp (const void *a, const void *b, void *x) { return 0; }]],
551                                 [[int arr[] = { 0, 1 };
552                                   qsort_r(arr, 2, sizeof(int), cmp, arr);]])],
553                 [AC_MSG_RESULT([yes]);
554                  AC_DEFINE([HAVE_QSORT_R_GNU], [], [have GNU-style qsort_r()])],
555                 [
556                         AC_MSG_RESULT([no]);
557                         AC_MSG_CHECKING([for BSD-style qsort_r])
558                         AC_COMPILE_IFELSE(
559                                 [AC_LANG_PROGRAM(
560                                         [[#include <stdlib.h>
561                                           int cmp (void *x, const void *a, const void *b) { return 0; }]],
562                                         [[int arr[] = { 0, 1 };
563                                           qsort_r(arr, 2, sizeof(int), arr, cmp);]])],
564                         [AC_MSG_RESULT([yes]);
565                          AC_DEFINE([HAVE_QSORT_R_BSD], [], [have BSD-style qsort_r()])],
566                         [AC_MSG_RESULT([no]);
567                          AC_MSG_FAILURE([qsort_r has unknown semantics])])
568                 ])
569                 CFLAGS="$save_CFLAGS"
570         ]
571 )
572
573 AC_CHECK_FUNCS(prctl mallinfo getpass closefrom getpwnam_r getgrnam_r getpwuid_r)
574 AC_CHECK_FUNCS(fmemopen funopen mmap memrchr setlinebuf strptime)
575
576 AC_CHECK_FUNC([syslog], [
577         AC_DEFINE([HAVE_SYSLOG], [], [have syslog(3) and friends])
578         syslog=true
579 ])
580 AM_CONDITIONAL(USE_SYSLOG, [test "x$syslog" = xtrue])
581
582 AC_CHECK_HEADERS(sys/sockio.h glob.h net/if_tun.h linux/fib_rules.h)
583 AC_CHECK_HEADERS(net/pfkeyv2.h netipsec/ipsec.h netinet6/ipsec.h linux/udp.h)
584 AC_CHECK_HEADERS(netinet/ip6.h, [], [],
585 [
586         #include <sys/types.h>
587         #include <netinet/in.h>
588 ])
589
590 AC_CHECK_MEMBERS([struct sockaddr.sa_len], [], [],
591 [
592         #include <sys/types.h>
593         #include <sys/socket.h>
594 ])
595
596 AC_CHECK_MEMBERS([struct sadb_x_policy.sadb_x_policy_priority], [], [],
597 [
598         #include <sys/types.h>
599         #ifdef HAVE_NET_PFKEYV2_H
600         #include <net/pfkeyv2.h>
601         #else
602         #include <stdint.h>
603         #include <linux/pfkeyv2.h>
604         #endif
605 ])
606
607 AC_MSG_CHECKING([for in6addr_any])
608 AC_COMPILE_IFELSE(
609         [AC_LANG_PROGRAM(
610                 [[#include <sys/types.h>
611                   #include <sys/socket.h>
612                   #include <netinet/in.h>]],
613                 [[struct in6_addr in6 __attribute__((unused));
614                   in6 = in6addr_any;]])],
615         [AC_MSG_RESULT([yes]);
616          AC_DEFINE([HAVE_IN6ADDR_ANY], [], [have struct in6_addr in6addr_any])],
617         [AC_MSG_RESULT([no])]
618 )
619
620 AC_MSG_CHECKING([for in6_pktinfo])
621 AC_COMPILE_IFELSE(
622         [AC_LANG_PROGRAM(
623                 [[#define _GNU_SOURCE
624                   #include <sys/types.h>
625                   #include <sys/socket.h>
626                   #include <netinet/in.h>]],
627                 [[struct in6_pktinfo pi;
628                   if (pi.ipi6_ifindex)
629                   {
630                     return 0;
631                   }]])],
632         [AC_MSG_RESULT([yes]);
633          AC_DEFINE([HAVE_IN6_PKTINFO], [], [have struct in6_pktinfo.ipi6_ifindex])],
634         [AC_MSG_RESULT([no])]
635 )
636
637 AC_MSG_CHECKING([for IPSEC_MODE_BEET])
638 AC_COMPILE_IFELSE(
639         [AC_LANG_PROGRAM(
640                 [[#include <sys/types.h>
641                   #ifdef HAVE_NETIPSEC_IPSEC_H
642                   #include <netipsec/ipsec.h>
643                   #elif defined(HAVE_NETINET6_IPSEC_H)
644                   #include <netinet6/ipsec.h>
645                   #else
646                   #include <stdint.h>
647                   #include <linux/ipsec.h>
648                   #endif]],
649                 [[int mode = IPSEC_MODE_BEET;
650                   return mode;]])],
651         [AC_MSG_RESULT([yes]);
652          AC_DEFINE([HAVE_IPSEC_MODE_BEET], [], [have IPSEC_MODE_BEET defined])],
653         [AC_MSG_RESULT([no])]
654 )
655
656 AC_MSG_CHECKING([for IPSEC_DIR_FWD])
657 AC_COMPILE_IFELSE(
658         [AC_LANG_PROGRAM(
659                 [[#include <sys/types.h>
660                   #ifdef HAVE_NETIPSEC_IPSEC_H
661                   #include <netipsec/ipsec.h>
662                   #elif defined(HAVE_NETINET6_IPSEC_H)
663                   #include <netinet6/ipsec.h>
664                   #else
665                   #include <stdint.h>
666                   #include <linux/ipsec.h>
667                   #endif]],
668                 [[int dir = IPSEC_DIR_FWD;
669                   return dir;]])],
670         [AC_MSG_RESULT([yes]);
671          AC_DEFINE([HAVE_IPSEC_DIR_FWD], [], [have IPSEC_DIR_FWD defined])],
672         [AC_MSG_RESULT([no])]
673 )
674
675 AC_MSG_CHECKING([for RTA_TABLE])
676 AC_COMPILE_IFELSE(
677         [AC_LANG_PROGRAM(
678                 [[#include <sys/socket.h>
679                   #include <linux/netlink.h>
680                   #include <linux/rtnetlink.h>]],
681                 [[int rta_type = RTA_TABLE;
682                   return rta_type;]])],
683         [AC_MSG_RESULT([yes]);
684          AC_DEFINE([HAVE_RTA_TABLE], [], [have netlink RTA_TABLE defined])],
685         [AC_MSG_RESULT([no])]
686 )
687
688 AC_MSG_CHECKING([for GCC __sync operations])
689 AC_RUN_IFELSE([AC_LANG_SOURCE(
690         [[
691                         int main() {
692                         int ref = 1;
693                         __sync_fetch_and_add (&ref, 1);
694                         __sync_sub_and_fetch (&ref, 1);
695                         __sync_val_compare_and_swap(&ref, 1, 0);
696                         return ref;
697                 }
698         ]])],
699         [AC_MSG_RESULT([yes]);
700          AC_DEFINE([HAVE_GCC_SYNC_OPERATIONS], [],
701                    [have GCC __sync_* operations])],
702         [AC_MSG_RESULT([no])],
703         [AC_MSG_RESULT([no])]
704 )
705
706 case "$printf_hooks" in
707 auto|builtin|glibc|vstr)
708         ;;
709 *)
710         AC_MSG_NOTICE([invalid printf hook implementation, defaulting to 'auto'])
711         printf_hooks=auto
712         ;;
713 esac
714
715 if test x$printf_hooks = xauto -o x$printf_hooks = xglibc; then
716         # check for the new register_printf_specifier function with len argument,
717         # or the deprecated register_printf_function without
718         AC_CHECK_FUNC(
719                 [register_printf_specifier],
720                 [AC_DEFINE([HAVE_PRINTF_SPECIFIER], [], [have register_printf_specifier()])],
721                 [AC_CHECK_FUNC(
722                         [register_printf_function],
723                         [AC_DEFINE([HAVE_PRINTF_FUNCTION], [], [have register_printf_function()])],
724                         [
725                                 AC_MSG_NOTICE([printf(3) does not support custom format specifiers!])
726                                 if test x$printf_hooks = xglibc; then
727                                         AC_MSG_ERROR([please select a different printf hook implementation])
728                                 else
729                                         # fallback to builtin printf hook implementation
730                                         printf_hooks=builtin
731                                 fi
732                         ]
733                 )]
734         )
735 fi
736
737 AC_MSG_CHECKING([for Windows target])
738 AC_COMPILE_IFELSE(
739         [AC_LANG_PROGRAM(
740                 [[#include <windows.h>]],
741                 [[#ifndef WIN32
742                   # error WIN32 undefined
743                   #endif
744                 ]])],
745         [
746                 AC_MSG_RESULT([yes])
747                 windows=true
748                 openssl_lib=eay32
749                 AC_SUBST(PTHREADLIB, "")
750                 # explicitly disable ms-bitfields, as it breaks __attribute__((packed))
751                 case "$CFLAGS" in
752                         *ms-bitfields*) ;;
753                         *) CFLAGS="$CFLAGS -mno-ms-bitfields" ;;
754                 esac
755         ],
756         [
757                 AC_MSG_RESULT([no])
758                 openssl_lib=crypto
759         ]
760 )
761 AC_SUBST(OPENSSL_LIB, [-l$openssl_lib])
762 AM_CONDITIONAL(USE_WINDOWS, [test "x$windows" = xtrue])
763
764 AC_MSG_CHECKING([for working __attribute__((packed))])
765 AC_COMPILE_IFELSE(
766         [AC_LANG_PROGRAM([], [[
767                 struct test { char a; short b; } __attribute__((packed));
768                 char x[sizeof(struct test) == sizeof(char) + sizeof(short) ? 1 : -1]
769                         __attribute__((unused));
770                 return 0;
771         ]])],
772         [AC_MSG_RESULT([yes])],
773         [AC_MSG_RESULT([no]); AC_MSG_ERROR([__attribute__((packed)) does not work])]
774 )
775
776 AC_MSG_CHECKING([clang])
777 AC_COMPILE_IFELSE(
778         [AC_LANG_PROGRAM(
779                 [], [[
780                  #ifndef __clang__
781                  # error not using LLVM clang
782                  #endif
783                 ]])],
784         [
785                 AC_MSG_RESULT([yes])
786         ],
787         [
788                 AC_MSG_RESULT([no])
789                 # GCC, but not MinGW requires -rdynamic for plugins
790                 if test x$windows != xtrue; then
791                         AC_SUBST(PLUGIN_CFLAGS, [-rdynamic])
792                 fi
793         ]
794 )
795
796 if test x$printf_hooks = xvstr; then
797         AC_CHECK_LIB([vstr],[main],[LIBS="$LIBS"],[AC_MSG_ERROR([Vstr string library not found])],[])
798         AC_DEFINE([USE_VSTR], [], [use Vstr string library for printf hooks])
799 fi
800
801 if test x$printf_hooks = xbuiltin; then
802         AC_DEFINE([USE_BUILTIN_PRINTF], [], [using builtin printf for printf hooks])
803 fi
804
805 if test x$gmp = xtrue; then
806         saved_LIBS=$LIBS
807         AC_CHECK_LIB([gmp],[main],[],[AC_MSG_ERROR([GNU Multi Precision library gmp not found])],[])
808         AC_MSG_CHECKING([mpz_powm_sec])
809         if test x$mpz_powm_sec = xyes; then
810                 AC_COMPILE_IFELSE(
811                         [AC_LANG_PROGRAM(
812                                 [[#include "gmp.h"]],
813                                 [[void *x = mpz_powm_sec;]])],
814                         [AC_MSG_RESULT([yes]);
815                          AC_DEFINE([HAVE_MPZ_POWM_SEC], [], [have mpz_mown_sec()])],
816                         [AC_MSG_RESULT([no])]
817                 )
818         else
819                 AC_MSG_RESULT([disabled])
820         fi
821         LIBS=$saved_LIBS
822         AC_MSG_CHECKING([gmp.h version >= 4.1.4])
823         AC_COMPILE_IFELSE(
824                 [AC_LANG_PROGRAM(
825                         [[#include "gmp.h"]],
826                         [[
827                                 #if (__GNU_MP_VERSION*100 +  __GNU_MP_VERSION_MINOR*10 + __GNU_MP_VERSION_PATCHLEVEL) < 414
828                                         #error bad gmp
829                                 #endif]])],
830                 [AC_MSG_RESULT([yes])],
831                 [AC_MSG_RESULT([no]); AC_MSG_ERROR([No usable gmp.h found!])]
832         )
833 fi
834
835 if test x$ldap = xtrue; then
836         AC_CHECK_LIB([ldap],[main],[LIBS="$LIBS"],[AC_MSG_ERROR([LDAP library ldap not found])],[])
837         AC_CHECK_LIB([lber],[main],[LIBS="$LIBS"],[AC_MSG_ERROR([LDAP library lber not found])],[])
838         AC_CHECK_HEADER([ldap.h],,[AC_MSG_ERROR([LDAP header ldap.h not found!])])
839 fi
840
841 if test x$curl = xtrue; then
842         AC_CHECK_LIB([curl],[main],[LIBS="$LIBS"],[AC_MSG_ERROR([CURL library curl not found])],[])
843         AC_CHECK_HEADER([curl/curl.h],,[AC_MSG_ERROR([CURL header curl/curl.h not found!])])
844 fi
845
846 if test x$unbound = xtrue; then
847         AC_HAVE_LIBRARY([ldns],[LIBS="$LIBS"],[AC_MSG_ERROR([UNBOUND library ldns not found])])
848         AC_CHECK_HEADER([ldns/ldns.h],,[AC_MSG_ERROR([UNBOUND header ldns/ldns.h not found!])])
849         AC_HAVE_LIBRARY([unbound],[LIBS="$LIBS"],[AC_MSG_ERROR([UNBOUND library libunbound not found])])
850         AC_CHECK_HEADER([unbound.h],,[AC_MSG_ERROR([UNBOUND header unbound.h not found!])])
851 fi
852
853 if test x$soup = xtrue; then
854         PKG_CHECK_MODULES(soup, [libsoup-2.4])
855         AC_SUBST(soup_CFLAGS)
856         AC_SUBST(soup_LIBS)
857 fi
858
859 if test x$xml = xtrue; then
860         PKG_CHECK_MODULES(xml, [libxml-2.0])
861         AC_SUBST(xml_CFLAGS)
862         AC_SUBST(xml_LIBS)
863 fi
864
865 if test x$tss = xtrousers; then
866         AC_CHECK_LIB([tspi],[main],[LIBS="$LIBS"],[AC_MSG_ERROR([TrouSerS library libtspi not found])],[])
867         AC_CHECK_HEADER([trousers/tss.h],,[AC_MSG_ERROR([TrouSerS header trousers/tss.h not found!])])
868         AC_DEFINE([TSS_TROUSERS], [], [use TrouSerS library libtspi as TSS implementation])
869 fi
870
871 if test x$imv_swid = xtrue; then
872         AC_CHECK_LIB([json],[main],[LIBS="$LIBS"],[AC_MSG_ERROR([JSON library libjson not found])],[])
873         AC_CHECK_HEADER([json/json.h],,[AC_MSG_ERROR([JSON header json/json.h not found!])])
874 fi
875
876 if test x$dumm = xtrue; then
877         PKG_CHECK_MODULES(gtk, [gtk+-2.0 vte])
878         AC_SUBST(gtk_CFLAGS)
879         AC_SUBST(gtk_LIBS)
880         AC_CHECK_PROGS(RUBY, ruby)
881         AC_MSG_CHECKING([for Ruby header files])
882         if test -n "$RUBY"; then
883                 RUBYINCLUDE=
884                 RUBYDIR=`($RUBY -r rbconfig -e 'print RbConfig::CONFIG[["rubyhdrdir"]] || ""') 2>/dev/null`
885                 if test -n "$RUBYDIR" -a -r "$RUBYDIR/ruby.h"; then
886                         RUBYARCH=`($RUBY -r rbconfig -e 'print RbConfig::CONFIG[["arch"]] || ""') 2>/dev/null`
887                         if test -n "$RUBYARCH"; then
888                                 AC_MSG_RESULT([$RUBYDIR])
889                                 RUBYINCLUDE="-I$RUBYDIR -I$RUBYDIR/$RUBYARCH"
890                         fi
891                 else
892                         RUBYDIR=`($RUBY -r rbconfig -e 'print RbConfig::CONFIG[["archdir"]] || ""') 2>/dev/null`
893                         if test -n "$RUBYDIR" -a -r "$RUBYDIR/ruby.h"; then
894                                 AC_MSG_RESULT([$RUBYDIR])
895                                 RUBYINCLUDE="-I$RUBYDIR"
896                         fi
897                 fi
898                 if test -z "$RUBYINCLUDE"; then
899                         AC_MSG_ERROR([ruby.h not found])
900                 fi
901                 AC_SUBST(RUBYINCLUDE)
902         else
903                 AC_MSG_ERROR([don't know how to run ruby])
904         fi
905         AC_MSG_CHECKING([for libruby])
906         saved_LIBS=$LIBS
907         LIBS=`($RUBY -r rbconfig -e 'print RbConfig::CONFIG[["LIBRUBYARG_SHARED"]] || ""') 2>/dev/null`
908         AC_TRY_LINK_FUNC(ruby_init,
909                 [AC_MSG_RESULT([$LIBS]); RUBYLIB=$LIBS],
910                 [AC_MSG_ERROR([not found])])
911         AC_SUBST(RUBYLIB)
912         AC_CHECK_FUNCS(rb_errinfo)
913         LIBS=$saved_LIBS
914 fi
915
916 if test x$fast = xtrue; then
917         AC_CHECK_LIB([neo_cgi],[main],[LIBS="$LIBS"],[AC_MSG_ERROR([ClearSilver library neo_cgi not found!])],[])
918         AC_CHECK_LIB([neo_utl],[main],[LIBS="$LIBS"],[AC_MSG_ERROR([ClearSilver library neo_utl not found!])],[])
919         AC_MSG_CHECKING([ClearSilver requires zlib])
920         saved_CFLAGS=$CFLAGS
921         saved_LIBS=$LIBS
922         LIBS="-lneo_cgi -lneo_cs -lneo_utl"
923         CFLAGS="-I/usr/include/ClearSilver"
924         AC_LINK_IFELSE(
925                 [AC_LANG_PROGRAM(
926                         [[#include <ClearSilver.h>]],
927                         [[NEOERR *err = cgi_display(NULL, NULL);]])],
928                 [AC_MSG_RESULT([no]); clearsilver_LIBS="$LIBS"],
929                 [AC_MSG_RESULT([yes]); clearsilver_LIBS="$LIBS -lz"]
930         )
931         AC_SUBST(clearsilver_LIBS)
932         LIBS=$saved_LIBS
933         CFLAGS=$saved_CFLAGS
934 # autoconf does not like CamelCase!? How to fix this?
935 #       AC_CHECK_HEADER([ClearSilver/ClearSilver.h],,[AC_MSG_ERROR([ClearSilver header file ClearSilver/ClearSilver.h not found!])])
936
937         AC_CHECK_LIB([fcgi],[main],[LIBS="$LIBS"],[AC_MSG_ERROR([FastCGI library fcgi not found!])],[])
938         AC_CHECK_HEADER([fcgiapp.h],,[AC_MSG_ERROR([FastCGI header file fcgiapp.h not found!])])
939 fi
940
941 if test x$mysql = xtrue; then
942         if test "x$windows" = xtrue; then
943                 AC_CHECK_HEADER([mysql.h],,[AC_MSG_ERROR([MySQL header file mysql.h not found!])])
944                 AC_CHECK_LIB([mysql],[main],[LIBS="$LIBS"],[AC_MSG_ERROR([MySQL library not found!])],[])
945                 AC_SUBST(MYSQLLIB, -lmysql)
946         else
947                 AC_PATH_PROG([MYSQLCONFIG], [mysql_config], [], [$PATH:/bin:/usr/bin:/usr/local/bin])
948                 if test x$MYSQLCONFIG = x; then
949                         AC_MSG_ERROR([mysql_config not found!])
950                 fi
951                 AC_SUBST(MYSQLLIB, `$MYSQLCONFIG --libs_r`)
952                 AC_SUBST(MYSQLCFLAG, `$MYSQLCONFIG --cflags`)
953         fi
954 fi
955
956 if test x$sqlite = xtrue; then
957         AC_CHECK_LIB([sqlite3],[main],[LIBS="$LIBS"],[AC_MSG_ERROR([SQLite library sqlite3 not found])],[])
958         AC_CHECK_HEADER([sqlite3.h],,[AC_MSG_ERROR([SQLite header sqlite3.h not found!])])
959         AC_MSG_CHECKING([sqlite3_prepare_v2])
960         AC_COMPILE_IFELSE(
961                 [AC_LANG_PROGRAM(
962                         [[#include <sqlite3.h>]],
963                         [[void *test = sqlite3_prepare_v2;]])],
964                 [AC_MSG_RESULT([yes]);
965                  AC_DEFINE([HAVE_SQLITE3_PREPARE_V2], [], [have sqlite3_prepare_v2()])],
966                 [AC_MSG_RESULT([no])]
967         )
968         AC_MSG_CHECKING([sqlite3.h version >= 3.3.1])
969         AC_COMPILE_IFELSE(
970                 [AC_LANG_PROGRAM(
971                         [[#include <sqlite3.h>]],
972                         [[
973                                 #if SQLITE_VERSION_NUMBER < 3003001
974                                         #error bad sqlite
975                                 #endif]])],
976                 [AC_MSG_RESULT([yes])],
977                 [AC_MSG_RESULT([no]); AC_MSG_ERROR([SQLite version >= 3.3.1 required!])]
978         )
979 fi
980
981 if test x$openssl = xtrue; then
982         AC_CHECK_LIB([$openssl_lib],[main],[LIBS="$LIBS"],[AC_MSG_ERROR([OpenSSL lib$openssl_lib not found])],[])
983         AC_CHECK_HEADER([openssl/evp.h],,[AC_MSG_ERROR([OpenSSL header openssl/evp.h not found!])])
984 fi
985
986 if test x$gcrypt = xtrue; then
987         AC_CHECK_LIB([gcrypt],[main],[LIBS="$LIBS"],[AC_MSG_ERROR([gcrypt library not found])],[-lgpg-error])
988         AC_CHECK_HEADER([gcrypt.h],,[AC_MSG_ERROR([gcrypt header gcrypt.h not found!])])
989         AC_MSG_CHECKING([gcrypt CAMELLIA cipher])
990         AC_COMPILE_IFELSE(
991                 [AC_LANG_PROGRAM(
992                         [[#include <gcrypt.h>]],
993                         [[enum gcry_cipher_algos alg = GCRY_CIPHER_CAMELLIA128;]])],
994                 [AC_MSG_RESULT([yes]);
995                  AC_DEFINE([HAVE_GCRY_CIPHER_CAMELLIA], [], [have GCRY_CIPHER_CAMELLIA128])],
996                 [AC_MSG_RESULT([no])]
997         )
998 fi
999
1000 if test x$uci = xtrue; then
1001         AC_CHECK_LIB([uci],[main],[LIBS="$LIBS"],[AC_MSG_ERROR([UCI library libuci not found])],[])
1002         AC_CHECK_HEADER([uci.h],,[AC_MSG_ERROR([UCI header uci.h not found!])])
1003 fi
1004
1005 if test x$android_dns = xtrue; then
1006         AC_CHECK_LIB([cutils],[main],[LIBS="$LIBS"],[AC_MSG_ERROR([Android library libcutils not found])],[])
1007         AC_CHECK_HEADER([cutils/properties.h],,[AC_MSG_ERROR([Android header cutils/properties.h not found!])])
1008         # we have to force the use of libdl here because the autodetection
1009         # above does not work correctly when cross-compiling for android.
1010         DLLIB="-ldl"
1011         AC_SUBST(DLLIB)
1012 fi
1013
1014 if test x$maemo = xtrue; then
1015         PKG_CHECK_MODULES(maemo, [glib-2.0 gthread-2.0 libosso osso-af-settings])
1016         AC_SUBST(maemo_CFLAGS)
1017         AC_SUBST(maemo_LIBS)
1018         dbusservicedir="/usr/share/dbus-1/system-services"
1019         AC_SUBST(dbusservicedir)
1020 fi
1021
1022 if test x$eap_sim_pcsc = xtrue; then
1023         PKG_CHECK_MODULES(pcsclite, [libpcsclite])
1024         AC_SUBST(pcsclite_CFLAGS)
1025         AC_SUBST(pcsclite_LIBS)
1026 fi
1027
1028 if test x$nm = xtrue; then
1029         PKG_CHECK_EXISTS([libnm-glib],
1030                 [PKG_CHECK_MODULES(nm, [NetworkManager gthread-2.0 libnm-util libnm-glib libnm-glib-vpn])],
1031                 [PKG_CHECK_MODULES(nm, [NetworkManager gthread-2.0 libnm_util libnm_glib libnm_glib_vpn])]
1032         )
1033         AC_SUBST(nm_CFLAGS)
1034         AC_SUBST(nm_LIBS)
1035 fi
1036
1037 if test x$xauth_pam = xtrue; then
1038         AC_CHECK_LIB([pam],[main],[LIBS="$LIBS"],[AC_MSG_ERROR([PAM library not found])],[])
1039         AC_CHECK_HEADER([security/pam_appl.h],,[AC_MSG_ERROR([PAM header security/pam_appl.h not found!])])
1040 fi
1041
1042 if test x$capabilities = xnative; then
1043         AC_MSG_NOTICE([Usage of the native Linux capabilities interface is deprecated, use libcap instead])
1044         # Linux requires the following for capset(), Android does not have it,
1045         # but defines capset() in unistd.h instead.
1046         AC_CHECK_HEADERS([sys/capability.h])
1047         AC_CHECK_FUNC(capset,,[AC_MSG_ERROR([capset() not found!])])
1048         AC_DEFINE([CAPABILITIES_NATIVE], [], [have native linux capset()])
1049 fi
1050
1051 if test x$capabilities = xlibcap; then
1052         AC_CHECK_LIB([cap],[main],[LIBS="$LIBS"],[AC_MSG_ERROR([libcap library not found])],[])
1053         AC_CHECK_HEADER([sys/capability.h],
1054                 [AC_DEFINE([HAVE_SYS_CAPABILITY_H], [], [have sys/capability.h])],
1055                 [AC_MSG_ERROR([libcap header sys/capability.h not found!])])
1056         AC_DEFINE([CAPABILITIES_LIBCAP], [], [have libpcap library])
1057 fi
1058
1059 if test x$integrity_test = xtrue; then
1060         AC_MSG_CHECKING([for dladdr()])
1061         AC_COMPILE_IFELSE(
1062                 [AC_LANG_PROGRAM(
1063                         [[#define _GNU_SOURCE
1064                           #include <dlfcn.h>]],
1065                         [[Dl_info info; dladdr(main, &info);]])],
1066                 [AC_MSG_RESULT([yes])],
1067                 [AC_MSG_RESULT([no]);
1068                  AC_MSG_ERROR([dladdr() not supported, required by integrity-test!])]
1069         )
1070         AC_MSG_CHECKING([for dl_iterate_phdr()])
1071         AC_COMPILE_IFELSE(
1072                 [AC_LANG_PROGRAM(
1073                         [[#define _GNU_SOURCE
1074                           #include <link.h>]],
1075                         [[dl_iterate_phdr((void*)0, (void*)0);]])],
1076                 [AC_MSG_RESULT([yes])],
1077                 [AC_MSG_RESULT([no]);
1078                  AC_MSG_ERROR([dl_iterate_phdr() not supported, required by integrity-test!])]
1079         )
1080 fi
1081
1082 if test x$bfd_backtraces = xtrue; then
1083         AC_CHECK_LIB([bfd],[main],[LIBS="$LIBS"],[AC_MSG_ERROR([binutils libbfd not found!])],[])
1084         AC_CHECK_HEADER([bfd.h],[AC_DEFINE([HAVE_BFD_H],,[have binutils bfd.h])],
1085                 [AC_MSG_ERROR([binutils bfd.h header not found!])])
1086         BFDLIB="-lbfd"
1087         AC_SUBST(BFDLIB)
1088 fi
1089
1090 if test x$unwind_backtraces = xtrue; then
1091         AC_CHECK_LIB([unwind],[main],[LIBS="$LIBS"],[AC_MSG_ERROR([libunwind not found!])],[])
1092         AC_CHECK_HEADER([libunwind.h],[AC_DEFINE([HAVE_LIBUNWIND_H],,[have libunwind.h])],
1093                 [AC_MSG_ERROR([libunwind.h header not found!])])
1094         UNWINDLIB="-lunwind"
1095         AC_SUBST(UNWINDLIB)
1096 fi
1097
1098 AM_CONDITIONAL(USE_DEV_HEADERS, [test "x$dev_headers" != xno])
1099 if test x$dev_headers = xyes; then
1100         dev_headers="$includedir/strongswan"
1101 fi
1102 AC_SUBST(dev_headers)
1103
1104 CFLAGS="$CFLAGS -include `pwd`/config.h"
1105
1106 if test x$tkm = xtrue; then
1107         AC_PATH_PROG([GPRBUILD], [gprbuild], [], [$PATH:/bin:/usr/bin:/usr/local/bin])
1108         if test x$GPRBUILD = x; then
1109                 AC_MSG_ERROR([gprbuild not found])
1110         fi
1111 fi
1112
1113 if test x$coverage = xtrue; then
1114         AC_PATH_PROG([LCOV], [lcov], [], [$PATH:/bin:/usr/bin:/usr/local/bin])
1115         if test x$LCOV = x; then
1116                 AC_MSG_ERROR([lcov not found])
1117         fi
1118         AC_PATH_PROG([GENHTML], [genhtml], [], [$PATH:/bin:/usr/bin:/usr/local/bin])
1119         if test x$GENHTML = x; then
1120                 AC_MSG_ERROR([genhtml not found])
1121         fi
1122
1123         COVERAGE_CFLAGS="-fprofile-arcs -ftest-coverage"
1124         COVERAGE_LDFLAGS="-fprofile-arcs"
1125         AC_SUBST(COVERAGE_CFLAGS)
1126         AC_SUBST(COVERAGE_LDFLAGS)
1127
1128         AC_MSG_NOTICE([coverage enabled, adding "-g -O0" to CFLAGS])
1129         CFLAGS="${CFLAGS} -g -O0"
1130 fi
1131
1132 # ===============================================
1133 #  collect plugin list for strongSwan components
1134 # ===============================================
1135
1136 m4_include(m4/macros/add-plugin.m4)
1137
1138 # plugin lists for all components
1139 charon_plugins=
1140 starter_plugins=
1141 pool_plugins=
1142 attest_plugins=
1143 scepclient_plugins=
1144 pki_plugins=
1145 scripts_plugins=
1146 manager_plugins=
1147 medsrv_plugins=
1148 nm_plugins=
1149 cmd_plugins=
1150 aikgen_plugins=
1151
1152 # location specific lists for checksumming,
1153 # for src/libcharon, src/libhydra, src/libstrongswan and src/libtnccs
1154 c_plugins=
1155 h_plugins=
1156 s_plugins=
1157 t_plugins=
1158
1159 ADD_PLUGIN([test-vectors],         [s charon scepclient pki])
1160 ADD_PLUGIN([curl],                 [s charon scepclient scripts nm cmd])
1161 ADD_PLUGIN([soup],                 [s charon scripts nm cmd])
1162 ADD_PLUGIN([unbound],              [s charon scripts])
1163 ADD_PLUGIN([ldap],                 [s charon scepclient scripts nm cmd])
1164 ADD_PLUGIN([mysql],                [s charon pool manager medsrv attest])
1165 ADD_PLUGIN([sqlite],               [s charon pool manager medsrv attest])
1166 ADD_PLUGIN([pkcs11],               [s charon pki nm cmd])
1167 ADD_PLUGIN([aes],                  [s charon scepclient pki scripts nm cmd])
1168 ADD_PLUGIN([des],                  [s charon scepclient pki scripts nm cmd])
1169 ADD_PLUGIN([blowfish],             [s charon scepclient pki scripts nm cmd])
1170 ADD_PLUGIN([rc2],                  [s charon scepclient pki scripts nm cmd])
1171 ADD_PLUGIN([sha1],                 [s charon scepclient pki scripts medsrv attest nm cmd aikgen])
1172 ADD_PLUGIN([sha2],                 [s charon scepclient pki scripts medsrv attest nm cmd aikgen])
1173 ADD_PLUGIN([md4],                  [s charon manager scepclient pki nm cmd])
1174 ADD_PLUGIN([md5],                  [s charon scepclient pki scripts attest nm cmd aikgen])
1175 ADD_PLUGIN([rdrand],               [s charon scepclient pki scripts medsrv attest nm cmd aikgen])
1176 ADD_PLUGIN([random],               [s charon scepclient pki scripts medsrv attest nm cmd aikgen])
1177 ADD_PLUGIN([nonce],                [s charon nm cmd aikgen])
1178 ADD_PLUGIN([x509],                 [s charon scepclient pki scripts attest nm cmd aikgen])
1179 ADD_PLUGIN([revocation],           [s charon nm cmd])
1180 ADD_PLUGIN([constraints],          [s charon nm cmd])
1181 ADD_PLUGIN([acert],                [s charon])
1182 ADD_PLUGIN([pubkey],               [s charon cmd aikgen])
1183 ADD_PLUGIN([pkcs1],                [s charon scepclient pki scripts manager medsrv attest nm cmd aikgen])
1184 ADD_PLUGIN([pkcs7],                [s charon scepclient pki scripts nm cmd])
1185 ADD_PLUGIN([pkcs8],                [s charon scepclient pki scripts manager medsrv attest nm cmd])
1186 ADD_PLUGIN([pkcs12],               [s charon scepclient pki scripts cmd])
1187 ADD_PLUGIN([pgp],                  [s charon])
1188 ADD_PLUGIN([dnskey],               [s charon pki])
1189 ADD_PLUGIN([sshkey],               [s charon pki nm cmd])
1190 ADD_PLUGIN([dnscert],              [c charon])
1191 ADD_PLUGIN([ipseckey],             [c charon])
1192 ADD_PLUGIN([pem],                  [s charon scepclient pki scripts manager medsrv attest nm cmd aikgen])
1193 ADD_PLUGIN([padlock],              [s charon])
1194 ADD_PLUGIN([openssl],              [s charon scepclient pki scripts manager medsrv attest nm cmd aikgen])
1195 ADD_PLUGIN([gcrypt],               [s charon scepclient pki scripts manager medsrv attest nm cmd aikgen])
1196 ADD_PLUGIN([af-alg],               [s charon scepclient pki scripts medsrv attest nm cmd aikgen])
1197 ADD_PLUGIN([fips-prf],             [s charon nm cmd])
1198 ADD_PLUGIN([gmp],                  [s charon scepclient pki scripts manager medsrv attest nm cmd aikgen])
1199 ADD_PLUGIN([agent],                [s charon nm cmd])
1200 ADD_PLUGIN([keychain],             [s charon cmd])
1201 ADD_PLUGIN([xcbc],                 [s charon nm cmd])
1202 ADD_PLUGIN([cmac],                 [s charon nm cmd])
1203 ADD_PLUGIN([hmac],                 [s charon scripts nm cmd])
1204 ADD_PLUGIN([ctr],                  [s charon scripts nm cmd])
1205 ADD_PLUGIN([ccm],                  [s charon scripts nm cmd])
1206 ADD_PLUGIN([gcm],                  [s charon scripts nm cmd])
1207 ADD_PLUGIN([ntru],                 [s charon scripts nm cmd])
1208 ADD_PLUGIN([attr],                 [h charon])
1209 ADD_PLUGIN([attr-sql],             [h charon])
1210 ADD_PLUGIN([load-tester],          [c charon])
1211 ADD_PLUGIN([kernel-libipsec],      [c charon cmd])
1212 ADD_PLUGIN([kernel-pfkey],         [h charon starter nm cmd])
1213 ADD_PLUGIN([kernel-pfroute],       [h charon starter nm cmd])
1214 ADD_PLUGIN([kernel-klips],         [h charon starter])
1215 ADD_PLUGIN([kernel-netlink],       [h charon starter nm cmd])
1216 ADD_PLUGIN([resolve],              [h charon cmd])
1217 ADD_PLUGIN([socket-default],       [c charon nm cmd])
1218 ADD_PLUGIN([socket-dynamic],       [c charon cmd])
1219 ADD_PLUGIN([socket-win],           [c charon])
1220 ADD_PLUGIN([farp],                 [c charon])
1221 ADD_PLUGIN([stroke],               [c charon])
1222 ADD_PLUGIN([vici],                 [c charon])
1223 ADD_PLUGIN([smp],                  [c charon])
1224 ADD_PLUGIN([sql],                  [c charon])
1225 ADD_PLUGIN([updown],               [c charon])
1226 ADD_PLUGIN([eap-identity],         [c charon nm cmd])
1227 ADD_PLUGIN([eap-sim],              [c charon])
1228 ADD_PLUGIN([eap-sim-file],         [c charon])
1229 ADD_PLUGIN([eap-sim-pcsc],         [c charon])
1230 ADD_PLUGIN([eap-aka],              [c charon])
1231 ADD_PLUGIN([eap-aka-3gpp2],        [c charon])
1232 ADD_PLUGIN([eap-simaka-sql],       [c charon])
1233 ADD_PLUGIN([eap-simaka-pseudonym], [c charon])
1234 ADD_PLUGIN([eap-simaka-reauth],    [c charon])
1235 ADD_PLUGIN([eap-md5],              [c charon nm cmd])
1236 ADD_PLUGIN([eap-gtc],              [c charon nm cmd])
1237 ADD_PLUGIN([eap-mschapv2],         [c charon nm cmd])
1238 ADD_PLUGIN([eap-dynamic],          [c charon])
1239 ADD_PLUGIN([eap-radius],           [c charon])
1240 ADD_PLUGIN([eap-tls],              [c charon nm cmd])
1241 ADD_PLUGIN([eap-ttls],             [c charon nm cmd])
1242 ADD_PLUGIN([eap-peap],             [c charon nm cmd])
1243 ADD_PLUGIN([eap-tnc],              [c charon])
1244 ADD_PLUGIN([xauth-generic],        [c charon cmd])
1245 ADD_PLUGIN([xauth-eap],            [c charon])
1246 ADD_PLUGIN([xauth-pam],            [c charon])
1247 ADD_PLUGIN([xauth-noauth],         [c charon])
1248 ADD_PLUGIN([tnc-ifmap],            [c charon])
1249 ADD_PLUGIN([tnc-pdp],              [c charon])
1250 ADD_PLUGIN([tnc-imc],              [t charon])
1251 ADD_PLUGIN([tnc-imv],              [t charon])
1252 ADD_PLUGIN([tnc-tnccs],            [t charon])
1253 ADD_PLUGIN([tnccs-20],             [t charon])
1254 ADD_PLUGIN([tnccs-11],             [t charon])
1255 ADD_PLUGIN([tnccs-dynamic],        [t charon])
1256 ADD_PLUGIN([medsrv],               [c charon])
1257 ADD_PLUGIN([medcli],               [c charon])
1258 ADD_PLUGIN([dhcp],                 [c charon])
1259 ADD_PLUGIN([osx-attr],             [c charon cmd])
1260 ADD_PLUGIN([android-dns],          [c charon])
1261 ADD_PLUGIN([android-log],          [c charon])
1262 ADD_PLUGIN([ha],                   [c charon])
1263 ADD_PLUGIN([whitelist],            [c charon])
1264 ADD_PLUGIN([lookip],               [c charon])
1265 ADD_PLUGIN([error-notify],         [c charon])
1266 ADD_PLUGIN([certexpire],           [c charon])
1267 ADD_PLUGIN([systime-fix],          [c charon])
1268 ADD_PLUGIN([led],                  [c charon])
1269 ADD_PLUGIN([duplicheck],           [c charon])
1270 ADD_PLUGIN([coupling],             [c charon])
1271 ADD_PLUGIN([radattr],              [c charon])
1272 ADD_PLUGIN([maemo],                [c charon])
1273 ADD_PLUGIN([uci],                  [c charon])
1274 ADD_PLUGIN([addrblock],            [c charon])
1275 ADD_PLUGIN([unity],                [c charon])
1276 ADD_PLUGIN([unit-tester],          [c charon])
1277
1278 AC_SUBST(charon_plugins)
1279 AC_SUBST(starter_plugins)
1280 AC_SUBST(pool_plugins)
1281 AC_SUBST(attest_plugins)
1282 AC_SUBST(scepclient_plugins)
1283 AC_SUBST(pki_plugins)
1284 AC_SUBST(scripts_plugins)
1285 AC_SUBST(manager_plugins)
1286 AC_SUBST(medsrv_plugins)
1287 AC_SUBST(nm_plugins)
1288 AC_SUBST(cmd_plugins)
1289 AC_SUBST(aikgen_plugins)
1290
1291 AC_SUBST(c_plugins)
1292 AC_SUBST(h_plugins)
1293 AC_SUBST(s_plugins)
1294 AC_SUBST(t_plugins)
1295
1296 # ======================
1297 #  set Makefile.am vars
1298 # ======================
1299
1300 #  libstrongswan plugins
1301 # -----------------------
1302 AM_CONDITIONAL(USE_TEST_VECTORS, test x$test_vectors = xtrue)
1303 AM_CONDITIONAL(USE_CURL, test x$curl = xtrue)
1304 AM_CONDITIONAL(USE_UNBOUND, test x$unbound = xtrue)
1305 AM_CONDITIONAL(USE_SOUP, test x$soup = xtrue)
1306 AM_CONDITIONAL(USE_LDAP, test x$ldap = xtrue)
1307 AM_CONDITIONAL(USE_AES, test x$aes = xtrue)
1308 AM_CONDITIONAL(USE_DES, test x$des = xtrue)
1309 AM_CONDITIONAL(USE_BLOWFISH, test x$blowfish = xtrue)
1310 AM_CONDITIONAL(USE_RC2, test x$rc2 = xtrue)
1311 AM_CONDITIONAL(USE_MD4, test x$md4 = xtrue)
1312 AM_CONDITIONAL(USE_MD5, test x$md5 = xtrue)
1313 AM_CONDITIONAL(USE_SHA1, test x$sha1 = xtrue)
1314 AM_CONDITIONAL(USE_SHA2, test x$sha2 = xtrue)
1315 AM_CONDITIONAL(USE_FIPS_PRF, test x$fips_prf = xtrue)
1316 AM_CONDITIONAL(USE_GMP, test x$gmp = xtrue)
1317 AM_CONDITIONAL(USE_RDRAND, test x$rdrand = xtrue)
1318 AM_CONDITIONAL(USE_RANDOM, test x$random = xtrue)
1319 AM_CONDITIONAL(USE_NONCE, test x$nonce = xtrue)
1320 AM_CONDITIONAL(USE_X509, test x$x509 = xtrue)
1321 AM_CONDITIONAL(USE_REVOCATION, test x$revocation = xtrue)
1322 AM_CONDITIONAL(USE_CONSTRAINTS, test x$constraints = xtrue)
1323 AM_CONDITIONAL(USE_ACERT, test x$acert = xtrue)
1324 AM_CONDITIONAL(USE_PUBKEY, test x$pubkey = xtrue)
1325 AM_CONDITIONAL(USE_PKCS1, test x$pkcs1 = xtrue)
1326 AM_CONDITIONAL(USE_PKCS7, test x$pkcs7 = xtrue)
1327 AM_CONDITIONAL(USE_PKCS8, test x$pkcs8 = xtrue)
1328 AM_CONDITIONAL(USE_PKCS12, test x$pkcs12 = xtrue)
1329 AM_CONDITIONAL(USE_PGP, test x$pgp = xtrue)
1330 AM_CONDITIONAL(USE_DNSKEY, test x$dnskey = xtrue)
1331 AM_CONDITIONAL(USE_SSHKEY, test x$sshkey = xtrue)
1332 AM_CONDITIONAL(USE_PEM, test x$pem = xtrue)
1333 AM_CONDITIONAL(USE_HMAC, test x$hmac = xtrue)
1334 AM_CONDITIONAL(USE_CMAC, test x$cmac = xtrue)
1335 AM_CONDITIONAL(USE_XCBC, test x$xcbc = xtrue)
1336 AM_CONDITIONAL(USE_MYSQL, test x$mysql = xtrue)
1337 AM_CONDITIONAL(USE_SQLITE, test x$sqlite = xtrue)
1338 AM_CONDITIONAL(USE_PADLOCK, test x$padlock = xtrue)
1339 AM_CONDITIONAL(USE_OPENSSL, test x$openssl = xtrue)
1340 AM_CONDITIONAL(USE_GCRYPT, test x$gcrypt = xtrue)
1341 AM_CONDITIONAL(USE_AGENT, test x$agent = xtrue)
1342 AM_CONDITIONAL(USE_KEYCHAIN, test x$keychain = xtrue)
1343 AM_CONDITIONAL(USE_PKCS11, test x$pkcs11 = xtrue)
1344 AM_CONDITIONAL(USE_CTR, test x$ctr = xtrue)
1345 AM_CONDITIONAL(USE_CCM, test x$ccm = xtrue)
1346 AM_CONDITIONAL(USE_GCM, test x$gcm = xtrue)
1347 AM_CONDITIONAL(USE_AF_ALG, test x$af_alg = xtrue)
1348 AM_CONDITIONAL(USE_NTRU, test x$ntru = xtrue)
1349
1350 #  charon plugins
1351 # ----------------
1352 AM_CONDITIONAL(USE_STROKE, test x$stroke = xtrue)
1353 AM_CONDITIONAL(USE_VICI, test x$vici = xtrue)
1354 AM_CONDITIONAL(USE_MEDSRV, test x$medsrv = xtrue)
1355 AM_CONDITIONAL(USE_MEDCLI, test x$medcli = xtrue)
1356 AM_CONDITIONAL(USE_UCI, test x$uci = xtrue)
1357 AM_CONDITIONAL(USE_OSX_ATTR, test x$osx_attr = xtrue)
1358 AM_CONDITIONAL(USE_ANDROID_DNS, test x$android_dns = xtrue)
1359 AM_CONDITIONAL(USE_ANDROID_LOG, test x$android_log = xtrue)
1360 AM_CONDITIONAL(USE_MAEMO, test x$maemo = xtrue)
1361 AM_CONDITIONAL(USE_SMP, test x$smp = xtrue)
1362 AM_CONDITIONAL(USE_SQL, test x$sql = xtrue)
1363 AM_CONDITIONAL(USE_DNSCERT, test x$dnscert = xtrue)
1364 AM_CONDITIONAL(USE_IPSECKEY, test x$ipseckey = xtrue)
1365 AM_CONDITIONAL(USE_UPDOWN, test x$updown = xtrue)
1366 AM_CONDITIONAL(USE_DHCP, test x$dhcp = xtrue)
1367 AM_CONDITIONAL(USE_UNIT_TESTS, test x$unit_tester = xtrue)
1368 AM_CONDITIONAL(USE_LOAD_TESTER, test x$load_tester = xtrue)
1369 AM_CONDITIONAL(USE_HA, test x$ha = xtrue)
1370 AM_CONDITIONAL(USE_KERNEL_LIBIPSEC, test x$kernel_libipsec = xtrue)
1371 AM_CONDITIONAL(USE_WHITELIST, test x$whitelist = xtrue)
1372 AM_CONDITIONAL(USE_LOOKIP, test x$lookip = xtrue)
1373 AM_CONDITIONAL(USE_ERROR_NOTIFY, test x$error_notify = xtrue)
1374 AM_CONDITIONAL(USE_CERTEXPIRE, test x$certexpire = xtrue)
1375 AM_CONDITIONAL(USE_SYSTIME_FIX, test x$systime_fix = xtrue)
1376 AM_CONDITIONAL(USE_LED, test x$led = xtrue)
1377 AM_CONDITIONAL(USE_DUPLICHECK, test x$duplicheck = xtrue)
1378 AM_CONDITIONAL(USE_COUPLING, test x$coupling = xtrue)
1379 AM_CONDITIONAL(USE_RADATTR, test x$radattr = xtrue)
1380 AM_CONDITIONAL(USE_EAP_SIM, test x$eap_sim = xtrue)
1381 AM_CONDITIONAL(USE_EAP_SIM_FILE, test x$eap_sim_file = xtrue)
1382 AM_CONDITIONAL(USE_EAP_SIM_PCSC, test x$eap_sim_pcsc = xtrue)
1383 AM_CONDITIONAL(USE_EAP_SIMAKA_SQL, test x$eap_simaka_sql = xtrue)
1384 AM_CONDITIONAL(USE_EAP_SIMAKA_PSEUDONYM, test x$eap_simaka_pseudonym = xtrue)
1385 AM_CONDITIONAL(USE_EAP_SIMAKA_REAUTH, test x$eap_simaka_reauth = xtrue)
1386 AM_CONDITIONAL(USE_EAP_IDENTITY, test x$eap_identity = xtrue)
1387 AM_CONDITIONAL(USE_EAP_MD5, test x$eap_md5 = xtrue)
1388 AM_CONDITIONAL(USE_EAP_GTC, test x$eap_gtc = xtrue)
1389 AM_CONDITIONAL(USE_EAP_AKA, test x$eap_aka = xtrue)
1390 AM_CONDITIONAL(USE_EAP_AKA_3GPP2, test x$eap_aka_3gpp2 = xtrue)
1391 AM_CONDITIONAL(USE_EAP_MSCHAPV2, test x$eap_mschapv2 = xtrue)
1392 AM_CONDITIONAL(USE_EAP_TLS, test x$eap_tls = xtrue)
1393 AM_CONDITIONAL(USE_EAP_TTLS, test x$eap_ttls = xtrue)
1394 AM_CONDITIONAL(USE_EAP_PEAP, test x$eap_peap = xtrue)
1395 AM_CONDITIONAL(USE_EAP_TNC, test x$eap_tnc = xtrue)
1396 AM_CONDITIONAL(USE_EAP_DYNAMIC, test x$eap_dynamic = xtrue)
1397 AM_CONDITIONAL(USE_EAP_RADIUS, test x$eap_radius = xtrue)
1398 AM_CONDITIONAL(USE_XAUTH_GENERIC, test x$xauth_generic = xtrue)
1399 AM_CONDITIONAL(USE_XAUTH_EAP, test x$xauth_eap = xtrue)
1400 AM_CONDITIONAL(USE_XAUTH_PAM, test x$xauth_pam = xtrue)
1401 AM_CONDITIONAL(USE_XAUTH_NOAUTH, test x$xauth_noauth = xtrue)
1402 AM_CONDITIONAL(USE_TNC_IFMAP, test x$tnc_ifmap = xtrue)
1403 AM_CONDITIONAL(USE_TNC_PDP, test x$tnc_pdp = xtrue)
1404 AM_CONDITIONAL(USE_TNC_IMC, test x$tnc_imc = xtrue)
1405 AM_CONDITIONAL(USE_TNC_IMV, test x$tnc_imv = xtrue)
1406 AM_CONDITIONAL(USE_TNC_TNCCS, test x$tnc_tnccs = xtrue)
1407 AM_CONDITIONAL(USE_TNCCS_11, test x$tnccs_11 = xtrue)
1408 AM_CONDITIONAL(USE_TNCCS_20, test x$tnccs_20 = xtrue)
1409 AM_CONDITIONAL(USE_TNCCS_DYNAMIC, test x$tnccs_dynamic = xtrue)
1410 AM_CONDITIONAL(USE_IMC_TEST, test x$imc_test = xtrue)
1411 AM_CONDITIONAL(USE_IMV_TEST, test x$imv_test = xtrue)
1412 AM_CONDITIONAL(USE_IMC_SCANNER, test x$imc_scanner = xtrue)
1413 AM_CONDITIONAL(USE_IMV_SCANNER, test x$imv_scanner = xtrue)
1414 AM_CONDITIONAL(USE_IMC_OS, test x$imc_os = xtrue)
1415 AM_CONDITIONAL(USE_IMV_OS, test x$imv_os = xtrue)
1416 AM_CONDITIONAL(USE_IMC_ATTESTATION, test x$imc_attestation = xtrue)
1417 AM_CONDITIONAL(USE_IMV_ATTESTATION, test x$imv_attestation = xtrue)
1418 AM_CONDITIONAL(USE_IMC_SWID, test x$imc_swid = xtrue)
1419 AM_CONDITIONAL(USE_IMV_SWID, test x$imv_swid = xtrue)
1420 AM_CONDITIONAL(USE_SOCKET_DEFAULT, test x$socket_default = xtrue)
1421 AM_CONDITIONAL(USE_SOCKET_DYNAMIC, test x$socket_dynamic = xtrue)
1422 AM_CONDITIONAL(USE_SOCKET_WIN, test x$socket_win = xtrue)
1423 AM_CONDITIONAL(USE_FARP, test x$farp = xtrue)
1424 AM_CONDITIONAL(USE_ADDRBLOCK, test x$addrblock = xtrue)
1425 AM_CONDITIONAL(USE_UNITY, test x$unity = xtrue)
1426
1427 #  hydra plugins
1428 # ---------------
1429 AM_CONDITIONAL(USE_ATTR, test x$attr = xtrue)
1430 AM_CONDITIONAL(USE_ATTR_SQL, test x$attr_sql = xtrue)
1431 AM_CONDITIONAL(USE_KERNEL_KLIPS, test x$kernel_klips = xtrue)
1432 AM_CONDITIONAL(USE_KERNEL_NETLINK, test x$kernel_netlink = xtrue)
1433 AM_CONDITIONAL(USE_KERNEL_PFKEY, test x$kernel_pfkey = xtrue)
1434 AM_CONDITIONAL(USE_KERNEL_PFROUTE, test x$kernel_pfroute = xtrue)
1435 AM_CONDITIONAL(USE_RESOLVE, test x$resolve = xtrue)
1436
1437 #  other options
1438 # ---------------
1439 AM_CONDITIONAL(USE_LEAK_DETECTIVE, test x$leak_detective = xtrue)
1440 AM_CONDITIONAL(USE_LOCK_PROFILER, test x$lock_profiler = xtrue)
1441 AM_CONDITIONAL(USE_DUMM, test x$dumm = xtrue)
1442 AM_CONDITIONAL(USE_FAST, test x$fast = xtrue)
1443 AM_CONDITIONAL(USE_MANAGER, test x$manager = xtrue)
1444 AM_CONDITIONAL(USE_ME, test x$mediation = xtrue)
1445 AM_CONDITIONAL(USE_INTEGRITY_TEST, test x$integrity_test = xtrue)
1446 AM_CONDITIONAL(USE_LOAD_WARNING, test x$load_warning = xtrue)
1447 AM_CONDITIONAL(USE_IKEV1, test x$ikev1 = xtrue)
1448 AM_CONDITIONAL(USE_IKEV2, test x$ikev2 = xtrue)
1449 AM_CONDITIONAL(USE_THREADS, test x$threads = xtrue)
1450 AM_CONDITIONAL(USE_ADNS, test x$adns = xtrue)
1451 AM_CONDITIONAL(USE_CHARON, test x$charon = xtrue)
1452 AM_CONDITIONAL(USE_NM, test x$nm = xtrue)
1453 AM_CONDITIONAL(USE_PKI, test x$pki = xtrue)
1454 AM_CONDITIONAL(USE_TOOLS, test x$tools = xtrue)
1455 AM_CONDITIONAL(USE_SCRIPTS, test x$scripts = xtrue)
1456 AM_CONDITIONAL(USE_CONFTEST, test x$conftest = xtrue)
1457 AM_CONDITIONAL(USE_LIBSTRONGSWAN, test x$charon = xtrue -o x$pki = xtrue -o x$tools = xtrue -o x$conftest = xtrue -o x$fast = xtrue -o x$imcv = xtrue -o x$nm = xtrue -o x$tkm = xtrue -o x$cmd = xtrue -o x$tls = xtrue -o x$tnc_tnccs = xtrue -o x$aikgen = xtrue -o x$svc = xtrue)
1458 AM_CONDITIONAL(USE_LIBHYDRA, test x$charon = xtrue -o x$nm = xtrue -o x$tkm = xtrue -o x$cmd = xtrue -o x$svc = xtrue)
1459 AM_CONDITIONAL(USE_LIBCHARON, test x$charon = xtrue -o x$conftest = xtrue -o x$nm = xtrue -o x$tkm = xtrue -o x$cmd = xtrue -o x$svc = xtrue)
1460 AM_CONDITIONAL(USE_LIBIPSEC, test x$libipsec = xtrue)
1461 AM_CONDITIONAL(USE_LIBTNCIF, test x$tnc_tnccs = xtrue -o x$imcv = xtrue)
1462 AM_CONDITIONAL(USE_LIBTNCCS, test x$tnc_tnccs = xtrue)
1463 AM_CONDITIONAL(USE_LIBPTTLS, test x$tnc_tnccs = xtrue)
1464 AM_CONDITIONAL(USE_FILE_CONFIG, test x$stroke = xtrue)
1465 AM_CONDITIONAL(USE_IPSEC_SCRIPT, test x$stroke = xtrue -o x$tools = xtrue -o x$conftest = xtrue)
1466 AM_CONDITIONAL(USE_LIBCAP, test x$capabilities = xlibcap)
1467 AM_CONDITIONAL(USE_VSTR, test x$printf_hooks = xvstr)
1468 AM_CONDITIONAL(USE_BUILTIN_PRINTF, test x$printf_hooks = xbuiltin)
1469 AM_CONDITIONAL(USE_SIMAKA, test x$simaka = xtrue)
1470 AM_CONDITIONAL(USE_TLS, test x$tls = xtrue)
1471 AM_CONDITIONAL(USE_RADIUS, test x$radius = xtrue)
1472 AM_CONDITIONAL(USE_IMCV, test x$imcv = xtrue)
1473 AM_CONDITIONAL(USE_PTS, test x$pts = xtrue)
1474 AM_CONDITIONAL(USE_TROUSERS, test x$tss = xtrousers -o x$aikgen = xtrue)
1475 AM_CONDITIONAL(MONOLITHIC, test x$monolithic = xtrue)
1476 AM_CONDITIONAL(USE_SILENT_RULES, test x$enable_silent_rules = xyes)
1477 AM_CONDITIONAL(COVERAGE, test x$coverage = xtrue)
1478 AM_CONDITIONAL(USE_DBGHELP, test x$dbghelp_backtraces = xtrue)
1479 AM_CONDITIONAL(USE_TKM, test x$tkm = xtrue)
1480 AM_CONDITIONAL(USE_CMD, test x$cmd = xtrue)
1481 AM_CONDITIONAL(USE_AIKGEN, test x$aikgen = xtrue)
1482 AM_CONDITIONAL(USE_SWANCTL, test x$swanctl = xtrue)
1483 AM_CONDITIONAL(USE_SVC, test x$svc = xtrue)
1484
1485 # ========================
1486 #  set global definitions
1487 # ========================
1488
1489 if test x$mediation = xtrue; then
1490         AC_DEFINE([ME], [], [mediation extension support])
1491 fi
1492 if test x$capabilities = xlibcap -o x$capabilities = xnative; then
1493         AC_DEFINE([CAPABILITIES], [], [capability dropping support])
1494 fi
1495 if test x$monolithic = xtrue; then
1496         AC_DEFINE([MONOLITHIC], [], [monolithic build embedding plugins])
1497 fi
1498 if test x$ikev1 = xtrue; then
1499         AC_DEFINE([USE_IKEV1], [], [support for IKEv1 protocol])
1500 fi
1501 if test x$ikev2 = xtrue; then
1502         AC_DEFINE([USE_IKEV2], [], [support for IKEv2 protocol])
1503 fi
1504
1505 # ====================================================
1506 #  options for enabled modules (see conf/Makefile.am)
1507 # ====================================================
1508
1509 strongswan_options=
1510
1511 AM_COND_IF([USE_ATTR_SQL], [strongswan_options=${strongswan_options}" pool"])
1512 AM_COND_IF([USE_CHARON], [strongswan_options=${strongswan_options}" charon charon-logging"])
1513 AM_COND_IF([USE_FILE_CONFIG], [strongswan_options=${strongswan_options}" starter"])
1514 AM_COND_IF([USE_IMV_ATTESTATION], [strongswan_options=${strongswan_options}" attest"])
1515 AM_COND_IF([USE_IMCV], [strongswan_options=${strongswan_options}" imcv"])
1516 AM_COND_IF([USE_IMV_OS], [strongswan_options=${strongswan_options}" pacman"])
1517 AM_COND_IF([USE_LIBTNCCS], [strongswan_options=${strongswan_options}" tnc"])
1518 AM_COND_IF([USE_MANAGER], [strongswan_options=${strongswan_options}" manager"])
1519 AM_COND_IF([USE_MEDSRV], [strongswan_options=${strongswan_options}" medsrv"])
1520 AM_COND_IF([USE_TOOLS], [strongswan_options=${strongswan_options}" tools"])
1521 AM_COND_IF([USE_PKI], [strongswan_options=${strongswan_options}" pki"])
1522
1523 AC_SUBST(strongswan_options)
1524
1525 # =================
1526 #  build Makefiles
1527 # =================
1528
1529 AC_CONFIG_FILES([
1530         Makefile
1531         conf/Makefile
1532         man/Makefile
1533         init/Makefile
1534         init/systemd/Makefile
1535         src/Makefile
1536         src/include/Makefile
1537         src/libstrongswan/Makefile
1538         src/libstrongswan/plugins/aes/Makefile
1539         src/libstrongswan/plugins/cmac/Makefile
1540         src/libstrongswan/plugins/des/Makefile
1541         src/libstrongswan/plugins/blowfish/Makefile
1542         src/libstrongswan/plugins/rc2/Makefile
1543         src/libstrongswan/plugins/md4/Makefile
1544         src/libstrongswan/plugins/md5/Makefile
1545         src/libstrongswan/plugins/sha1/Makefile
1546         src/libstrongswan/plugins/sha2/Makefile
1547         src/libstrongswan/plugins/fips_prf/Makefile
1548         src/libstrongswan/plugins/gmp/Makefile
1549         src/libstrongswan/plugins/rdrand/Makefile
1550         src/libstrongswan/plugins/random/Makefile
1551         src/libstrongswan/plugins/nonce/Makefile
1552         src/libstrongswan/plugins/hmac/Makefile
1553         src/libstrongswan/plugins/xcbc/Makefile
1554         src/libstrongswan/plugins/x509/Makefile
1555         src/libstrongswan/plugins/revocation/Makefile
1556         src/libstrongswan/plugins/constraints/Makefile
1557         src/libstrongswan/plugins/acert/Makefile
1558         src/libstrongswan/plugins/pubkey/Makefile
1559         src/libstrongswan/plugins/pkcs1/Makefile
1560         src/libstrongswan/plugins/pkcs7/Makefile
1561         src/libstrongswan/plugins/pkcs8/Makefile
1562         src/libstrongswan/plugins/pkcs12/Makefile
1563         src/libstrongswan/plugins/pgp/Makefile
1564         src/libstrongswan/plugins/dnskey/Makefile
1565         src/libstrongswan/plugins/sshkey/Makefile
1566         src/libstrongswan/plugins/pem/Makefile
1567         src/libstrongswan/plugins/curl/Makefile
1568         src/libstrongswan/plugins/unbound/Makefile
1569         src/libstrongswan/plugins/soup/Makefile
1570         src/libstrongswan/plugins/ldap/Makefile
1571         src/libstrongswan/plugins/mysql/Makefile
1572         src/libstrongswan/plugins/sqlite/Makefile
1573         src/libstrongswan/plugins/padlock/Makefile
1574         src/libstrongswan/plugins/openssl/Makefile
1575         src/libstrongswan/plugins/gcrypt/Makefile
1576         src/libstrongswan/plugins/agent/Makefile
1577         src/libstrongswan/plugins/keychain/Makefile
1578         src/libstrongswan/plugins/pkcs11/Makefile
1579         src/libstrongswan/plugins/ctr/Makefile
1580         src/libstrongswan/plugins/ccm/Makefile
1581         src/libstrongswan/plugins/gcm/Makefile
1582         src/libstrongswan/plugins/af_alg/Makefile
1583         src/libstrongswan/plugins/ntru/Makefile
1584         src/libstrongswan/plugins/test_vectors/Makefile
1585         src/libstrongswan/tests/Makefile
1586         src/libhydra/Makefile
1587         src/libhydra/plugins/attr/Makefile
1588         src/libhydra/plugins/attr_sql/Makefile
1589         src/libhydra/plugins/kernel_klips/Makefile
1590         src/libhydra/plugins/kernel_netlink/Makefile
1591         src/libhydra/plugins/kernel_pfkey/Makefile
1592         src/libhydra/plugins/kernel_pfroute/Makefile
1593         src/libhydra/plugins/resolve/Makefile
1594         src/libipsec/Makefile
1595         src/libsimaka/Makefile
1596         src/libtls/Makefile
1597         src/libtls/tests/Makefile
1598         src/libradius/Makefile
1599         src/libtncif/Makefile
1600         src/libtnccs/Makefile
1601         src/libtnccs/plugins/tnc_tnccs/Makefile
1602         src/libtnccs/plugins/tnc_imc/Makefile
1603         src/libtnccs/plugins/tnc_imv/Makefile
1604         src/libtnccs/plugins/tnccs_11/Makefile
1605         src/libtnccs/plugins/tnccs_20/Makefile
1606         src/libtnccs/plugins/tnccs_dynamic/Makefile
1607         src/libpttls/Makefile
1608         src/libpts/Makefile
1609         src/libpts/plugins/imc_attestation/Makefile
1610         src/libpts/plugins/imv_attestation/Makefile
1611         src/libpts/plugins/imc_swid/Makefile
1612         src/libpts/plugins/imv_swid/Makefile
1613         src/libimcv/Makefile
1614         src/libimcv/plugins/imc_test/Makefile
1615         src/libimcv/plugins/imv_test/Makefile
1616         src/libimcv/plugins/imc_scanner/Makefile
1617         src/libimcv/plugins/imv_scanner/Makefile
1618         src/libimcv/plugins/imc_os/Makefile
1619         src/libimcv/plugins/imv_os/Makefile
1620         src/charon/Makefile
1621         src/charon-nm/Makefile
1622         src/charon-tkm/Makefile
1623         src/charon-cmd/Makefile
1624         src/charon-svc/Makefile
1625         src/libcharon/Makefile
1626         src/libcharon/plugins/eap_aka/Makefile
1627         src/libcharon/plugins/eap_aka_3gpp2/Makefile
1628         src/libcharon/plugins/eap_dynamic/Makefile
1629         src/libcharon/plugins/eap_identity/Makefile
1630         src/libcharon/plugins/eap_md5/Makefile
1631         src/libcharon/plugins/eap_gtc/Makefile
1632         src/libcharon/plugins/eap_sim/Makefile
1633         src/libcharon/plugins/eap_sim_file/Makefile
1634         src/libcharon/plugins/eap_sim_pcsc/Makefile
1635         src/libcharon/plugins/eap_simaka_sql/Makefile
1636         src/libcharon/plugins/eap_simaka_pseudonym/Makefile
1637         src/libcharon/plugins/eap_simaka_reauth/Makefile
1638         src/libcharon/plugins/eap_mschapv2/Makefile
1639         src/libcharon/plugins/eap_tls/Makefile
1640         src/libcharon/plugins/eap_ttls/Makefile
1641         src/libcharon/plugins/eap_peap/Makefile
1642         src/libcharon/plugins/eap_tnc/Makefile
1643         src/libcharon/plugins/eap_radius/Makefile
1644         src/libcharon/plugins/xauth_generic/Makefile
1645         src/libcharon/plugins/xauth_eap/Makefile
1646         src/libcharon/plugins/xauth_pam/Makefile
1647         src/libcharon/plugins/xauth_noauth/Makefile
1648         src/libcharon/plugins/tnc_ifmap/Makefile
1649         src/libcharon/plugins/tnc_pdp/Makefile
1650         src/libcharon/plugins/socket_default/Makefile
1651         src/libcharon/plugins/socket_dynamic/Makefile
1652         src/libcharon/plugins/socket_win/Makefile
1653         src/libcharon/plugins/farp/Makefile
1654         src/libcharon/plugins/smp/Makefile
1655         src/libcharon/plugins/sql/Makefile
1656         src/libcharon/plugins/dnscert/Makefile
1657         src/libcharon/plugins/ipseckey/Makefile
1658         src/libcharon/plugins/medsrv/Makefile
1659         src/libcharon/plugins/medcli/Makefile
1660         src/libcharon/plugins/addrblock/Makefile
1661         src/libcharon/plugins/unity/Makefile
1662         src/libcharon/plugins/uci/Makefile
1663         src/libcharon/plugins/ha/Makefile
1664         src/libcharon/plugins/kernel_libipsec/Makefile
1665         src/libcharon/plugins/whitelist/Makefile
1666         src/libcharon/plugins/lookip/Makefile
1667         src/libcharon/plugins/error_notify/Makefile
1668         src/libcharon/plugins/certexpire/Makefile
1669         src/libcharon/plugins/systime_fix/Makefile
1670         src/libcharon/plugins/led/Makefile
1671         src/libcharon/plugins/duplicheck/Makefile
1672         src/libcharon/plugins/coupling/Makefile
1673         src/libcharon/plugins/radattr/Makefile
1674         src/libcharon/plugins/osx_attr/Makefile
1675         src/libcharon/plugins/android_dns/Makefile
1676         src/libcharon/plugins/android_log/Makefile
1677         src/libcharon/plugins/maemo/Makefile
1678         src/libcharon/plugins/stroke/Makefile
1679         src/libcharon/plugins/vici/Makefile
1680         src/libcharon/plugins/updown/Makefile
1681         src/libcharon/plugins/dhcp/Makefile
1682         src/libcharon/plugins/unit_tester/Makefile
1683         src/libcharon/plugins/load_tester/Makefile
1684         src/stroke/Makefile
1685         src/ipsec/Makefile
1686         src/starter/Makefile
1687         src/_updown/Makefile
1688         src/_updown_espmark/Makefile
1689         src/_copyright/Makefile
1690         src/scepclient/Makefile
1691         src/aikgen/Makefile
1692         src/pki/Makefile
1693         src/pki/man/Makefile
1694         src/pool/Makefile
1695         src/dumm/Makefile
1696         src/dumm/ext/extconf.rb
1697         src/libfast/Makefile
1698         src/manager/Makefile
1699         src/medsrv/Makefile
1700         src/checksum/Makefile
1701         src/conftest/Makefile
1702         src/pt-tls-client/Makefile
1703         src/swanctl/Makefile
1704         scripts/Makefile
1705         testing/Makefile
1706 ])
1707
1708 # =================
1709 #  build man pages
1710 # =================
1711
1712 AC_CONFIG_FILES([
1713         conf/strongswan.conf.5.head
1714         conf/strongswan.conf.5.tail
1715         man/ipsec.conf.5
1716         man/ipsec.secrets.5
1717         src/charon-cmd/charon-cmd.8
1718         src/pki/man/pki.1
1719         src/pki/man/pki---gen.1
1720         src/pki/man/pki---issue.1
1721         src/pki/man/pki---keyid.1
1722         src/pki/man/pki---pkcs7.1
1723         src/pki/man/pki---print.1
1724         src/pki/man/pki---pub.1
1725         src/pki/man/pki---req.1
1726         src/pki/man/pki---self.1
1727         src/pki/man/pki---signcrl.1
1728         src/pki/man/pki---acert.1
1729         src/pki/man/pki---verify.1
1730         src/swanctl/swanctl.8
1731         src/swanctl/swanctl.conf.5.head
1732         src/swanctl/swanctl.conf.5.tail
1733 ])
1734
1735 AC_OUTPUT
1736
1737 # ========================
1738 #  report enabled plugins
1739 # ========================
1740
1741 AC_MSG_RESULT([])
1742 AC_MSG_RESULT([ strongSwan will be built with the following plugins])
1743 AC_MSG_RESULT([-----------------------------------------------------])
1744
1745 AC_MSG_RESULT([libstrongswan:$s_plugins])
1746 AC_MSG_RESULT([libcharon:    $c_plugins])
1747 AC_MSG_RESULT([libhydra:     $h_plugins])
1748 AC_MSG_RESULT([libtnccs:     $t_plugins])
1749 AC_MSG_RESULT([])