Merge branch 'ext-auth'
[strongswan.git] / configure.ac
1 #
2 # Copyright (C) 2007-2014 Tobias Brunner
3 # Copyright (C) 2006-2013 Andreas Steffen
4 # Copyright (C) 2006-2013 Martin Willi
5 # Hochschule fuer Technik Rapperswil
6 #
7 # This program is free software; you can redistribute it and/or modify it
8 # under the terms of the GNU General Public License as published by the
9 # Free Software Foundation; either version 2 of the License, or (at your
10 # option) any later version.  See <http://www.fsf.org/copyleft/gpl.txt>.
11 #
12 # This program is distributed in the hope that it will be useful, but
13 # WITHOUT ANY WARRANTY; without even the implied warranty of MERCHANTABILITY
14 # or FITNESS FOR A PARTICULAR PURPOSE.  See the GNU General Public License
15 # for more details.
16 #
17
18 # ============================
19 #  initialize & set some vars
20 # ============================
21
22 AC_INIT([strongSwan],[5.2.1dr1])
23 AM_INIT_AUTOMAKE(m4_esyscmd([
24         echo tar-ustar
25         echo subdir-objects
26         case `automake --version | head -n 1` in
27                 *" 1.9"*);;
28                 *" 1.10"*);;
29                 *" 1.11"*);;
30                 # don't use parallel test harness in 1.12 and up
31                 *) echo serial-tests;;
32         esac
33 ]))
34 m4_ifdef([AM_SILENT_RULES], [AM_SILENT_RULES])
35 AC_CONFIG_MACRO_DIR([m4/config])
36 AC_CONFIG_HEADERS([config.h])
37 AC_DEFINE([CONFIG_H_INCLUDED], [], [defined if config.h included])
38 PKG_PROG_PKG_CONFIG
39
40 m4_include(m4/macros/split-package-version.m4)
41 SPLIT_PACKAGE_VERSION
42
43 # =================================
44 #  check --enable-xxx & --with-xxx
45 # =================================
46
47 m4_include(m4/macros/with.m4)
48
49 ARG_WITH_SUBST([random-device],      [/dev/random], [set the device to read real random data from])
50 ARG_WITH_SUBST([urandom-device],     [/dev/urandom], [set the device to read pseudo random data from])
51 ARG_WITH_SUBST([strongswan-conf],    [${sysconfdir}/strongswan.conf], [set the strongswan.conf file location])
52 ARG_WITH_SUBST([resolv-conf],        [${sysconfdir}/resolv.conf], [set the file to use in DNS handler plugin])
53 ARG_WITH_SUBST([piddir],             [/var/run], [set path for PID and UNIX socket files])
54 ARG_WITH_SUBST([ipsecdir],           [${libexecdir%/}/ipsec], [set installation path for ipsec tools])
55 ARG_WITH_SUBST([ipseclibdir],        [${libdir%/}/ipsec], [set installation path for ipsec libraries])
56 ARG_WITH_SUBST([plugindir],          [${ipseclibdir%/}/plugins], [set the installation path of plugins])
57 ARG_WITH_SUBST([imcvdir],            [${ipseclibdir%/}/imcvs], [set the installation path of IMC and IMV dynamic librariers])
58 ARG_WITH_SUBST([nm-ca-dir],          [/usr/share/ca-certificates], [directory the NM backend uses to look up trusted root certificates])
59 ARG_WITH_SUBST([swanctldir],         [${sysconfdir}/swanctl], [base directory for swanctl configuration files and credentials])
60 ARG_WITH_SUBST([linux-headers],      [\${top_srcdir}/src/include], [set directory of linux header files to use])
61 ARG_WITH_SUBST([routing-table],      [220], [set routing table to use for IPsec routes])
62 ARG_WITH_SUBST([routing-table-prio], [220], [set priority for IPsec routing table])
63 ARG_WITH_SUBST([ipsec-script],       [ipsec], [change the name of the ipsec script])
64 ARG_WITH_SUBST([fips-mode],          [0], [set openssl FIPS mode: disabled(0), enabled(1), Suite B enabled(2)])
65
66 ARG_WITH_SET([tss],                  [no], [set implementation of the Trusted Computing Group's Software Stack (TSS). Currently the only supported value is "trousers"])
67 ARG_WITH_SET([capabilities],         [no], [set capability dropping library. Currently supported values are "libcap" and "native"])
68 ARG_WITH_SET([mpz_powm_sec],         [yes], [use the more side-channel resistant mpz_powm_sec in libgmp, if available])
69 ARG_WITH_SET([dev-headers],          [no], [install strongSwan development headers to directory.])
70 ARG_WITH_SET([printf-hooks],         [auto], [force the use of a specific printf hook implementation (auto, builtin, glibc, vstr).])
71
72 if test -n "$PKG_CONFIG"; then
73         systemdsystemunitdir_default=$($PKG_CONFIG --variable=systemdsystemunitdir systemd)
74 fi
75 ARG_WITH_SET([systemdsystemunitdir], [$systemdsystemunitdir_default], [directory for systemd service files])
76 AC_SUBST(systemdsystemunitdir)
77
78 AC_ARG_WITH(
79         [user],
80         AS_HELP_STRING([--with-user=user],[change user of the daemons to "user" after startup (default is "root").]),
81         [AC_DEFINE_UNQUOTED([IPSEC_USER], "$withval", [username to run daemon with])
82          AC_SUBST(ipsecuser, "$withval")],
83         [AC_SUBST(ipsecuser, "root")]
84 )
85
86 AC_ARG_WITH(
87         [group],
88         AS_HELP_STRING([--with-group=group],[change group of the daemons to "group" after startup (default is "root").]),
89         [AC_DEFINE_UNQUOTED(IPSEC_GROUP, "$withval", [groupname to run daemon with])
90          AC_SUBST(ipsecgroup, "$withval")],
91         [AC_SUBST(ipsecgroup, "root")]
92 )
93
94 AC_ARG_WITH(
95         [charon-udp-port],
96         AS_HELP_STRING([--with-charon-udp-port=port],[UDP port used by charon locally (default 500). Set to 0 to allocate randomly.]),
97         [AC_DEFINE_UNQUOTED(CHARON_UDP_PORT, [$withval], [UDP port used by charon locally])
98          AC_SUBST(charon_udp_port, [$withval])],
99         [AC_SUBST(charon_udp_port, 500)]
100 )
101
102 AC_ARG_WITH(
103         [charon-natt-port],
104         AS_HELP_STRING([--with-charon-natt-port=port],[UDP port used by charon locally in case a NAT is detected (must be different from charon-udp-port, default 4500). Set to 0 to allocate randomly.]),
105         [AC_DEFINE_UNQUOTED(CHARON_NATT_PORT, [$withval], [UDP post used by charon locally in case a NAT is detected])
106          AC_SUBST(charon_natt_port, [$withval])],
107         [AC_SUBST(charon_natt_port, 4500)]
108 )
109
110 AC_MSG_CHECKING([configured UDP ports ($charon_udp_port, $charon_natt_port)])
111 if test x$charon_udp_port != x0 -a x$charon_udp_port = x$charon_natt_port; then
112         AC_MSG_ERROR(the ports have to be different)
113 else
114         AC_MSG_RESULT(ok)
115 fi
116
117 # convert script name to uppercase
118 AC_SUBST(ipsec_script_upper, [`echo -n "$ipsec_script" | tr a-z A-Z`])
119
120 m4_include(m4/macros/enable-disable.m4)
121
122 # crypto plugins
123 ARG_DISBL_SET([aes],            [disable AES software implementation plugin.])
124 ARG_ENABL_SET([af-alg],         [enable AF_ALG crypto interface to Linux Crypto API.])
125 ARG_ENABL_SET([blowfish],       [enable Blowfish software implementation plugin.])
126 ARG_ENABL_SET([ccm],            [enables the CCM AEAD wrapper crypto plugin.])
127 ARG_DISBL_SET([cmac],           [disable CMAC crypto implementation plugin.])
128 ARG_ENABL_SET([ctr],            [enables the Counter Mode wrapper crypto plugin.])
129 ARG_DISBL_SET([des],            [disable DES/3DES software implementation plugin.])
130 ARG_DISBL_SET([fips-prf],       [disable FIPS PRF software implementation plugin.])
131 ARG_ENABL_SET([gcm],            [enables the GCM AEAD wrapper crypto plugin.])
132 ARG_ENABL_SET([gcrypt],         [enables the libgcrypt plugin.])
133 ARG_DISBL_SET([gmp],            [disable GNU MP (libgmp) based crypto implementation plugin.])
134 ARG_DISBL_SET([hmac],           [disable HMAC crypto implementation plugin.])
135 ARG_ENABL_SET([md4],            [enable MD4 software implementation plugin.])
136 ARG_DISBL_SET([md5],            [disable MD5 software implementation plugin.])
137 ARG_DISBL_SET([nonce],          [disable nonce generation plugin.])
138 ARG_ENABL_SET([ntru],           [enables the NTRU crypto plugin.])
139 ARG_ENABL_SET([openssl],        [enables the OpenSSL crypto plugin.])
140 ARG_ENABL_SET([padlock],        [enables VIA Padlock crypto plugin.])
141 ARG_DISBL_SET([random],         [disable RNG implementation on top of /dev/(u)random.])
142 ARG_DISBL_SET([rc2],            [disable RC2 software implementation plugin.])
143 ARG_ENABL_SET([rdrand],         [enable Intel RDRAND random generator plugin.])
144 ARG_DISBL_SET([sha1],           [disable SHA1 software implementation plugin.])
145 ARG_DISBL_SET([sha2],           [disable SHA256/SHA384/SHA512 software implementation plugin.])
146 ARG_DISBL_SET([xcbc],           [disable xcbc crypto implementation plugin.])
147 # encoding/decoding plugins
148 ARG_DISBL_SET([dnskey],         [disable DNS RR key decoding plugin.])
149 ARG_DISBL_SET([pem],            [disable PEM decoding plugin.])
150 ARG_DISBL_SET([pgp],            [disable PGP key decoding plugin.])
151 ARG_DISBL_SET([pkcs1],          [disable PKCS1 key decoding plugin.])
152 ARG_DISBL_SET([pkcs7],          [disable PKCS7 container support plugin.])
153 ARG_DISBL_SET([pkcs8],          [disable PKCS8 private key decoding plugin.])
154 ARG_DISBL_SET([pkcs12],         [disable PKCS12 container support plugin.])
155 ARG_DISBL_SET([pubkey],         [disable RAW public key support plugin.])
156 ARG_DISBL_SET([sshkey],         [disable SSH key decoding plugin.])
157 ARG_DISBL_SET([x509],           [disable X509 certificate implementation plugin.])
158 # fetcher/resolver plugins
159 ARG_ENABL_SET([curl],           [enable CURL fetcher plugin to fetch files via libcurl. Requires libcurl.])
160 ARG_ENABL_SET([ldap],           [enable LDAP fetching plugin to fetch files via libldap. Requires openLDAP.])
161 ARG_ENABL_SET([soup],           [enable soup fetcher plugin to fetch from HTTP via libsoup. Requires libsoup.])
162 ARG_ENABL_SET([unbound],        [enable UNBOUND resolver plugin to perform DNS queries via libunbound. Requires libldns and libunbound.])
163 ARG_ENABL_SET([winhttp],        [enable WinHTTP based HTTP/HTTPS fetching plugin.])
164 # database plugins
165 ARG_ENABL_SET([mysql],          [enable MySQL database support. Requires libmysqlclient_r.])
166 ARG_ENABL_SET([sqlite],         [enable SQLite database support. Requires libsqlite3.])
167 # authentication/credential plugins
168 ARG_ENABL_SET([addrblock],      [enables RFC 3779 address block constraint support.])
169 ARG_ENABL_SET([acert],          [enable X509 attribute certificate checking plugin.])
170 ARG_ENABL_SET([agent],          [enables the ssh-agent signing plugin.])
171 ARG_DISBL_SET([constraints],    [disable advanced X509 constraint checking plugin.])
172 ARG_ENABL_SET([coupling],       [enable IKEv2 plugin to couple peer certificates permanently to authentication.])
173 ARG_ENABL_SET([dnscert],        [enable DNSCERT authentication plugin.])
174 ARG_ENABL_SET([eap-sim],        [enable SIM authentication module for EAP.])
175 ARG_ENABL_SET([eap-sim-file],   [enable EAP-SIM backend based on a triplet file.])
176 ARG_ENABL_SET([eap-sim-pcsc],   [enable EAP-SIM backend based on a smartcard reader. Requires libpcsclite.])
177 ARG_ENABL_SET([eap-aka],        [enable EAP AKA authentication module.])
178 ARG_ENABL_SET([eap-aka-3gpp2],  [enable EAP AKA backend implementing 3GPP2 algorithms in software. Requires libgmp.])
179 ARG_ENABL_SET([eap-simaka-sql], [enable EAP-SIM/AKA backend based on a triplet/quintuplet SQL database.])
180 ARG_ENABL_SET([eap-simaka-pseudonym], [enable EAP-SIM/AKA pseudonym storage plugin.])
181 ARG_ENABL_SET([eap-simaka-reauth],    [enable EAP-SIM/AKA reauthentication data storage plugin.])
182 ARG_ENABL_SET([eap-identity],   [enable EAP module providing EAP-Identity helper.])
183 ARG_ENABL_SET([eap-md5],        [enable EAP MD5 (CHAP) authentication module.])
184 ARG_ENABL_SET([eap-gtc],        [enable EAP GTC authentication module.])
185 ARG_ENABL_SET([eap-mschapv2],   [enable EAP MS-CHAPv2 authentication module.])
186 ARG_ENABL_SET([eap-tls],        [enable EAP TLS authentication module.])
187 ARG_ENABL_SET([eap-ttls],       [enable EAP TTLS authentication module.])
188 ARG_ENABL_SET([eap-peap],       [enable EAP PEAP authentication module.])
189 ARG_ENABL_SET([eap-tnc],        [enable EAP TNC trusted network connect module.])
190 ARG_ENABL_SET([eap-dynamic],    [enable dynamic EAP proxy module.])
191 ARG_ENABL_SET([eap-radius],     [enable RADIUS proxy authentication module.])
192 ARG_ENABL_SET([ext-auth],       [enable plugin calling an external authorization script.])
193 ARG_ENABL_SET([ipseckey],       [enable IPSECKEY authentication plugin.])
194 ARG_ENABL_SET([keychain],       [enables OS X Keychain Services credential set.])
195 ARG_ENABL_SET([pkcs11],         [enables the PKCS11 token support plugin.])
196 ARG_DISBL_SET([revocation],     [disable X509 CRL/OCSP revocation check plugin.])
197 ARG_ENABL_SET([whitelist],      [enable peer identity whitelisting plugin.])
198 ARG_DISBL_SET([xauth-generic],  [disable generic XAuth backend.])
199 ARG_ENABL_SET([xauth-eap],      [enable XAuth backend using EAP methods to verify passwords.])
200 ARG_ENABL_SET([xauth-pam],      [enable XAuth backend using PAM to verify passwords.])
201 ARG_ENABL_SET([xauth-noauth],   [enable XAuth pseudo-backend that does not actually verify or even request any credentials.])
202 # kernel interfaces / sockets
203 ARG_DISBL_SET([kernel-netlink], [disable the netlink kernel interface.])
204 ARG_ENABL_SET([kernel-pfkey],   [enable the PF_KEY kernel interface.])
205 ARG_ENABL_SET([kernel-pfroute], [enable the PF_ROUTE kernel interface.])
206 ARG_ENABL_SET([kernel-iph],     [enable the Windows IP Helper based networking backend.])
207 ARG_ENABL_SET([kernel-libipsec],[enable the libipsec kernel interface.])
208 ARG_ENABL_SET([kernel-wfp],     [enable the Windows Filtering Platform IPsec backend.])
209 ARG_DISBL_SET([socket-default], [disable default socket implementation for charon.])
210 ARG_ENABL_SET([socket-dynamic], [enable dynamic socket implementation for charon])
211 ARG_ENABL_SET([socket-win],     [enable Winsock2 based socket implementation for charon])
212 # configuration/control plugins
213 ARG_DISBL_SET([stroke],         [disable charons stroke configuration backend.])
214 ARG_ENABL_SET([smp],            [enable SMP configuration and control interface. Requires libxml.])
215 ARG_ENABL_SET([sql],            [enable SQL database configuration backend.])
216 ARG_ENABL_SET([uci],            [enable OpenWRT UCI configuration plugin.])
217 ARG_ENABL_SET([vici],           [enable strongSwan IKE generic IPC interface plugin.])
218 # attribute provider/consumer plugins
219 ARG_ENABL_SET([android-dns],    [enable Android specific DNS handler.])
220 ARG_DISBL_SET([attr],           [disable strongswan.conf based configuration attribute plugin.])
221 ARG_ENABL_SET([attr-sql],       [enable SQL based configuration attribute plugin.])
222 ARG_ENABL_SET([dhcp],           [enable DHCP based attribute provider plugin.])
223 ARG_ENABL_SET([osx-attr],       [enable OS X SystemConfiguration attribute handler.])
224 ARG_DISBL_SET([resolve],        [disable resolve DNS handler plugin.])
225 ARG_ENABL_SET([unity],          [enables Cisco Unity extension plugin.])
226 # TNC modules/plugins
227 ARG_ENABL_SET([imc-test],       [enable IMC test module.])
228 ARG_ENABL_SET([imv-test],       [enable IMV test module.])
229 ARG_ENABL_SET([imc-scanner],    [enable IMC port scanner module.])
230 ARG_ENABL_SET([imv-scanner],    [enable IMV port scanner module.])
231 ARG_ENABL_SET([imc-os],         [enable IMC operating system module.])
232 ARG_ENABL_SET([imv-os],         [enable IMV operating system module.])
233 ARG_ENABL_SET([imc-attestation],[enable IMC attestation module.])
234 ARG_ENABL_SET([imv-attestation],[enable IMV attestation module.])
235 ARG_ENABL_SET([imc-swid],       [enable IMC swid module.])
236 ARG_ENABL_SET([imv-swid],       [enable IMV swid module.])
237 ARG_ENABL_SET([tnc-ifmap],      [enable TNC IF-MAP module. Requires libxml])
238 ARG_ENABL_SET([tnc-imc],        [enable TNC IMC module.])
239 ARG_ENABL_SET([tnc-imv],        [enable TNC IMV module.])
240 ARG_ENABL_SET([tnc-pdp],        [enable TNC policy decision point module.])
241 ARG_ENABL_SET([tnccs-11],       [enable TNCCS 1.1 protocol module. Requires libxml])
242 ARG_ENABL_SET([tnccs-20],       [enable TNCCS 2.0 protocol module.])
243 ARG_ENABL_SET([tnccs-dynamic],  [enable dynamic TNCCS protocol discovery module.])
244 # misc plugins
245 ARG_ENABL_SET([android-log],    [enable Android specific logger plugin.])
246 ARG_ENABL_SET([certexpire],     [enable CSV export of expiration dates of used certificates.])
247 ARG_ENABL_SET([duplicheck],     [advanced duplicate checking plugin using liveness checks.])
248 ARG_ENABL_SET([error-notify],   [enable error notification plugin.])
249 ARG_ENABL_SET([farp],           [enable ARP faking plugin that responds to ARP requests to peers virtual IP])
250 ARG_ENABL_SET([ha],             [enable high availability cluster plugin.])
251 ARG_ENABL_SET([led],            [enable plugin to control LEDs on IKEv2 activity using the Linux kernel LED subsystem.])
252 ARG_ENABL_SET([load-tester],    [enable load testing plugin for IKEv2 daemon.])
253 ARG_ENABL_SET([lookip],         [enable fast virtual IP lookup and notification plugin.])
254 ARG_ENABL_SET([maemo],          [enable Maemo specific plugin.])
255 ARG_ENABL_SET([radattr],        [enable plugin to inject and process custom RADIUS attributes as IKEv2 client.])
256 ARG_ENABL_SET([systime-fix],    [enable plugin to handle cert lifetimes with invalid system time gracefully.])
257 ARG_ENABL_SET([test-vectors],   [enable plugin providing crypto test vectors.])
258 ARG_ENABL_SET([unit-tester],    [enable unit tests on IKEv2 daemon startup.])
259 ARG_DISBL_SET([updown],         [disable updown firewall script plugin.])
260 # programs/components
261 ARG_ENABL_SET([aikgen],         [enable AIK generator.])
262 ARG_DISBL_SET([charon],         [disable the IKEv1/IKEv2 keying daemon charon.])
263 ARG_ENABL_SET([cmd],            [enable the command line IKE client charon-cmd.])
264 ARG_ENABL_SET([conftest],       [enforce Suite B conformance test framework.])
265 ARG_ENABL_SET([dumm],           [enable the DUMM UML test framework.])
266 ARG_ENABL_SET([fast],           [enable libfast (FastCGI Application Server w/ templates.])
267 ARG_ENABL_SET([libipsec],       [enable user space IPsec implementation.])
268 ARG_ENABL_SET([manager],        [enable web management console (proof of concept).])
269 ARG_ENABL_SET([medcli],         [enable mediation client configuration database plugin.])
270 ARG_ENABL_SET([medsrv],         [enable mediation server web frontend and daemon plugin.])
271 ARG_ENABL_SET([nm],             [enable NetworkManager backend.])
272 ARG_DISBL_SET([pki],            [disable pki certificate utility.])
273 ARG_DISBL_SET([scepclient],     [disable SCEP client tool.])
274 ARG_DISBL_SET([scripts],        [disable additional utilities (found in directory scripts).])
275 ARG_ENABL_SET([svc],            [enable charon Windows service.])
276 ARG_ENABL_SET([systemd],        [enable systemd specific IKE daemon charon-systemd.])
277 ARG_ENABL_SET([swanctl],        [enable swanctl configuration and control tool.])
278 ARG_ENABL_SET([tkm],            [enable Trusted Key Manager support.])
279 # optional features
280 ARG_ENABL_SET([bfd-backtraces], [use binutils libbfd to resolve backtraces for memory leaks and segfaults.])
281 ARG_ENABL_SET([dbghelp-backtraces],[use dbghlp.dll on Windows to create and print backtraces for memory leaks and segfaults.])
282 ARG_DISBL_SET([ikev1],          [disable IKEv1 protocol support in charon.])
283 ARG_DISBL_SET([ikev2],          [disable IKEv2 protocol support in charon.])
284 ARG_ENABL_SET([integrity-test], [enable integrity testing of libstrongswan and plugins.])
285 ARG_DISBL_SET([load-warning],   [disable the charon plugin load option warning in starter.])
286 ARG_ENABL_SET([mediation],      [enable IKEv2 Mediation Extension.])
287 ARG_ENABL_SET([unwind-backtraces],[use libunwind to create backtraces for memory leaks and segfaults.])
288 # compile options
289 ARG_ENABL_SET([coverage],       [enable lcov coverage report generation.])
290 ARG_ENABL_SET([leak-detective], [enable malloc hooks to find memory leaks.])
291 ARG_ENABL_SET([lock-profiler],  [enable lock/mutex profiling code.])
292 ARG_ENABL_SET([monolithic],     [build monolithic version of libstrongswan that includes all enabled plugins. Similarly, the plugins of charon are assembled in libcharon.])
293
294 # ===================================
295 #  option to disable default options
296 # ===================================
297
298 ARG_DISBL_SET([defaults],       [disable all default plugins (they can be enabled with their respective --enable options)])
299
300 if test x$defaults = xfalse; then
301         for option in $enabled_by_default; do
302                 eval test x\${${option}_given} = xtrue && continue
303                 eval $option=false
304         done
305 fi
306
307 # ==============================
308 #  option to enable all options
309 # ==============================
310
311 ARG_ENABL_SET([all],            [enable all plugins and features (they can be disabled with their respective --disable options). Mainly for testing.])
312
313 if test x$all_given = xtrue; then
314         for option in $disabled_by_default; do
315                 eval test x\${${option}_given} = xtrue && continue
316                 eval $option=true
317         done
318 fi
319
320 # ===========================
321 #  set up compiler and flags
322 # ===========================
323
324 if test -z "$CFLAGS"; then
325         CFLAGS="-g -O2 -Wall -Wno-format -Wno-format-security -Wno-pointer-sign"
326 fi
327 AC_PROG_CC
328 AM_PROG_CC_C_O
329
330 AC_LIB_PREFIX
331 AC_C_BIGENDIAN
332
333 # =========================
334 #  check required programs
335 # =========================
336
337 LT_INIT
338 AC_PROG_INSTALL
339 AC_PROG_EGREP
340 AC_PROG_AWK
341 AC_PROG_LEX
342 AC_PROG_YACC
343 AM_PATH_PYTHON(,,[:])
344 AC_PATH_PROG([PERL], [perl], [], [$PATH:/bin:/usr/bin:/usr/local/bin])
345 AC_PATH_PROG([GPERF], [gperf], [], [$PATH:/bin:/usr/bin:/usr/local/bin])
346
347 # because gperf is not needed by end-users we just report it but do not abort on failure
348 AC_MSG_CHECKING([gperf version >= 3.0.0])
349 if test -x "$GPERF"; then
350         if test "`$GPERF --version | $AWK -F' ' '/^GNU gperf/ { print $3 }' | $AWK -F. '{ print $1 }'`" -ge "3"; then
351                 AC_MSG_RESULT([yes])
352         else
353                 AC_MSG_RESULT([no])
354         fi
355 else
356         AC_MSG_RESULT([not found])
357 fi
358
359 # ========================
360 #  dependency calculation
361 # ========================
362
363 if test x$xauth_generic_given = xfalse -a x$ikev1 = xfalse; then
364         xauth_generic=false;
365 fi
366
367 if test x$kernel_libipsec = xtrue; then
368         libipsec=true;
369 fi
370
371 if test x$eap_aka_3gpp2 = xtrue; then
372         gmp=true;
373 fi
374
375 if test x$eap_aka = xtrue; then
376         fips_prf=true;
377         simaka=true;
378 fi
379
380 if test x$eap_sim = xtrue; then
381         fips_prf=true;
382         simaka=true;
383 fi
384
385 if test x$eap_radius = xtrue -o x$radattr = xtrue -o x$tnc_pdp = xtrue; then
386         radius=true;
387 fi
388
389 if test x$tnc_imc = xtrue -o x$tnc_imv = xtrue -o x$tnccs_11 = xtrue -o x$tnccs_11 = xtrue -o x$tnccs_dynamic = xtrue -o x$eap_tnc = xtrue; then
390         tnc_tnccs=true;
391 fi
392
393 if test x$eap_tls = xtrue -o x$eap_ttls = xtrue -o x$eap_peap = xtrue -o x$tnc_tnccs = xtrue; then
394         tls=true;
395 fi
396
397 if test x$imc_test = xtrue -o x$imv_test = xtrue -o x$imc_scanner = xtrue -o x$imv_scanner = xtrue -o x$imc_os = xtrue -o x$imv_os = xtrue -o x$imc_attestation = xtrue -o x$imv_attestation = xtrue -o x$imc_swid = xtrue -o x$imv_swid = xtrue; then
398         imcv=true;
399 fi
400
401 if test x$fips_prf = xtrue; then
402         if test x$openssl = xfalse; then
403                 sha1=true;
404         fi
405 fi
406
407 if test x$swanctl = xtrue; then
408         vici=true
409 fi
410
411 if test x$smp = xtrue -o x$tnccs_11 = xtrue -o x$tnc_ifmap = xtrue; then
412         xml=true
413 fi
414
415 if test x$manager = xtrue; then
416         fast=true
417 fi
418
419 if test x$medsrv = xtrue; then
420         mediation=true
421         fast=true
422 fi
423
424 if test x$medcli = xtrue; then
425         mediation=true
426 fi
427
428 # ===========================================
429 #  check required libraries and header files
430 # ===========================================
431
432 AC_HEADER_STDBOOL
433 AC_FUNC_ALLOCA
434 AC_FUNC_STRERROR_R
435
436 #  libraries needed on some platforms but not on others
437 # ------------------------------------------------------
438 saved_LIBS=$LIBS
439
440 # FreeBSD and Mac OS X have dlopen integrated in libc, Linux needs libdl
441 LIBS=""
442 AC_SEARCH_LIBS(dlopen, dl, [DLLIB=$LIBS])
443 AC_SUBST(DLLIB)
444
445 # glibc's backtrace() can be replicated on FreeBSD with libexecinfo
446 LIBS=""
447 AC_SEARCH_LIBS(backtrace, execinfo, [BTLIB=$LIBS])
448 AC_CHECK_FUNCS(backtrace)
449 AC_SUBST(BTLIB)
450
451 # OpenSolaris needs libsocket and libnsl for socket()
452 LIBS=""
453 AC_SEARCH_LIBS(socket, socket, [SOCKLIB=$LIBS],
454         [AC_CHECK_LIB(nsl, socket, [SOCKLIB="-lsocket -lnsl"], [], [-lsocket])]
455 )
456 AC_SUBST(SOCKLIB)
457
458 # Android has pthread_* functions in bionic (libc), others need libpthread
459 LIBS=""
460 AC_SEARCH_LIBS(pthread_create, pthread, [PTHREADLIB=$LIBS])
461 AC_SUBST(PTHREADLIB)
462
463 LIBS=$saved_LIBS
464 # ------------------------------------------------------
465
466 AC_MSG_CHECKING(for dladdr)
467 AC_COMPILE_IFELSE(
468         [AC_LANG_PROGRAM(
469                 [[#define _GNU_SOURCE
470                   #include <dlfcn.h>]],
471                 [[Dl_info* info = 0;
472                   dladdr(0, info);]])],
473         [AC_MSG_RESULT([yes]); AC_DEFINE([HAVE_DLADDR], [], [have dladdr()])],
474         [AC_MSG_RESULT([no])]
475 )
476
477 # check if pthread_condattr_setclock(CLOCK_MONOTONE) is supported
478 saved_LIBS=$LIBS
479 LIBS=$PTHREADLIB
480 AC_MSG_CHECKING([for pthread_condattr_setclock(CLOCK_MONOTONE)])
481 AC_RUN_IFELSE(
482         [AC_LANG_SOURCE(
483                 [[#include <pthread.h>
484                   int main() { pthread_condattr_t attr;
485                         pthread_condattr_init(&attr);
486                         return pthread_condattr_setclock(&attr, CLOCK_MONOTONIC);}]])],
487         [AC_MSG_RESULT([yes]);
488          AC_DEFINE([HAVE_CONDATTR_CLOCK_MONOTONIC], [],
489                            [pthread_condattr_setclock supports CLOCK_MONOTONIC])],
490         [AC_MSG_RESULT([no])],
491         # Check existence of pthread_condattr_setclock if cross-compiling
492         [AC_MSG_RESULT([unknown]);
493          AC_CHECK_FUNCS(pthread_condattr_setclock,
494                 [AC_DEFINE([HAVE_CONDATTR_CLOCK_MONOTONIC], [],
495                                    [have pthread_condattr_setclock()])]
496         )]
497 )
498 # check if we actually are able to configure attributes on cond vars
499 AC_CHECK_FUNCS(pthread_condattr_init)
500 # instead of pthread_condattr_setclock Android has this function
501 AC_CHECK_FUNCS(pthread_cond_timedwait_monotonic)
502 # check if we can cancel threads
503 AC_CHECK_FUNCS(pthread_cancel)
504 # check if native rwlocks are available
505 AC_CHECK_FUNCS(pthread_rwlock_init)
506 # check if pthread spinlocks are available
507 AC_CHECK_FUNCS(pthread_spin_init)
508 # check if we have POSIX semaphore functions, including timed-wait
509 AC_CHECK_FUNCS(sem_timedwait)
510 LIBS=$saved_LIBS
511
512 AC_CHECK_FUNC(
513         [gettid],
514         [AC_DEFINE([HAVE_GETTID], [], [have gettid()])],
515         [AC_MSG_CHECKING([for SYS_gettid])
516          AC_COMPILE_IFELSE(
517                 [AC_LANG_PROGRAM(
518                         [[#define _GNU_SOURCE
519                           #include <unistd.h>
520                           #include <sys/syscall.h>]],
521                         [[int main() {
522                           return syscall(SYS_gettid);}]])],
523                 [AC_MSG_RESULT([yes]);
524                  AC_DEFINE([HAVE_GETTID], [], [have gettid()])
525                  AC_DEFINE([HAVE_SYS_GETTID], [], [have syscall(SYS_gettid)])],
526                 [AC_MSG_RESULT([no])]
527         )]
528 )
529
530 AC_CHECK_FUNC(
531         [qsort_r],
532         [
533                 AC_DEFINE([HAVE_QSORT_R], [], [have qsort_r()])
534                 # set -Werror so that we get an error for "argument ... has
535                 # incompatible pointer type" warnings
536                 save_CFLAGS="$CFLAGS"
537                 CFLAGS="$CFLAGS -Werror"
538                 AC_MSG_CHECKING([for GNU-style qsort_r])
539                 AC_COMPILE_IFELSE(
540                         [AC_LANG_PROGRAM(
541                                 [[#define _GNU_SOURCE
542                                   #include <stdlib.h>
543                                   int cmp (const void *a, const void *b, void *x) { return 0; }]],
544                                 [[int arr[] = { 0, 1 };
545                                   qsort_r(arr, 2, sizeof(int), cmp, arr);]])],
546                 [AC_MSG_RESULT([yes]);
547                  AC_DEFINE([HAVE_QSORT_R_GNU], [], [have GNU-style qsort_r()])],
548                 [
549                         AC_MSG_RESULT([no]);
550                         AC_MSG_CHECKING([for BSD-style qsort_r])
551                         AC_COMPILE_IFELSE(
552                                 [AC_LANG_PROGRAM(
553                                         [[#include <stdlib.h>
554                                           int cmp (void *x, const void *a, const void *b) { return 0; }]],
555                                         [[int arr[] = { 0, 1 };
556                                           qsort_r(arr, 2, sizeof(int), arr, cmp);]])],
557                         [AC_MSG_RESULT([yes]);
558                          AC_DEFINE([HAVE_QSORT_R_BSD], [], [have BSD-style qsort_r()])],
559                         [AC_MSG_RESULT([no]);
560                          AC_MSG_FAILURE([qsort_r has unknown semantics])])
561                 ])
562                 CFLAGS="$save_CFLAGS"
563         ]
564 )
565
566 AC_CHECK_FUNCS(prctl mallinfo getpass closefrom getpwnam_r getgrnam_r getpwuid_r)
567 AC_CHECK_FUNCS(fmemopen funopen mmap memrchr setlinebuf strptime)
568
569 AC_CHECK_FUNC([syslog], [
570         AC_DEFINE([HAVE_SYSLOG], [], [have syslog(3) and friends])
571         syslog=true
572 ])
573 AM_CONDITIONAL(USE_SYSLOG, [test "x$syslog" = xtrue])
574
575 AC_CHECK_HEADERS(sys/sockio.h glob.h net/if_tun.h)
576 AC_CHECK_HEADERS(net/pfkeyv2.h netipsec/ipsec.h netinet6/ipsec.h linux/udp.h)
577 AC_CHECK_HEADERS([netinet/ip6.h linux/fib_rules.h], [], [],
578 [
579         #include <sys/types.h>
580         #include <netinet/in.h>
581 ])
582
583 AC_CHECK_MEMBERS([struct sockaddr.sa_len], [], [],
584 [
585         #include <sys/types.h>
586         #include <sys/socket.h>
587 ])
588
589 AC_CHECK_MEMBERS([struct sadb_x_policy.sadb_x_policy_priority], [], [],
590 [
591         #include <sys/types.h>
592         #ifdef HAVE_NET_PFKEYV2_H
593         #include <net/pfkeyv2.h>
594         #else
595         #include <stdint.h>
596         #include <linux/pfkeyv2.h>
597         #endif
598 ])
599
600 AC_MSG_CHECKING([for in6addr_any])
601 AC_COMPILE_IFELSE(
602         [AC_LANG_PROGRAM(
603                 [[#include <sys/types.h>
604                   #include <sys/socket.h>
605                   #include <netinet/in.h>]],
606                 [[struct in6_addr in6 __attribute__((unused));
607                   in6 = in6addr_any;]])],
608         [AC_MSG_RESULT([yes]);
609          AC_DEFINE([HAVE_IN6ADDR_ANY], [], [have struct in6_addr in6addr_any])],
610         [AC_MSG_RESULT([no])]
611 )
612
613 AC_MSG_CHECKING([for in6_pktinfo])
614 AC_COMPILE_IFELSE(
615         [AC_LANG_PROGRAM(
616                 [[#define _GNU_SOURCE
617                   #include <sys/types.h>
618                   #include <sys/socket.h>
619                   #include <netinet/in.h>]],
620                 [[struct in6_pktinfo pi;
621                   if (pi.ipi6_ifindex)
622                   {
623                     return 0;
624                   }]])],
625         [AC_MSG_RESULT([yes]);
626          AC_DEFINE([HAVE_IN6_PKTINFO], [], [have struct in6_pktinfo.ipi6_ifindex])],
627         [AC_MSG_RESULT([no])]
628 )
629
630 AC_MSG_CHECKING([for IPSEC_MODE_BEET])
631 AC_COMPILE_IFELSE(
632         [AC_LANG_PROGRAM(
633                 [[#include <sys/types.h>
634                   #ifdef HAVE_NETIPSEC_IPSEC_H
635                   #include <netipsec/ipsec.h>
636                   #elif defined(HAVE_NETINET6_IPSEC_H)
637                   #include <netinet6/ipsec.h>
638                   #else
639                   #include <stdint.h>
640                   #include <linux/ipsec.h>
641                   #endif]],
642                 [[int mode = IPSEC_MODE_BEET;
643                   return mode;]])],
644         [AC_MSG_RESULT([yes]);
645          AC_DEFINE([HAVE_IPSEC_MODE_BEET], [], [have IPSEC_MODE_BEET defined])],
646         [AC_MSG_RESULT([no])]
647 )
648
649 AC_MSG_CHECKING([for IPSEC_DIR_FWD])
650 AC_COMPILE_IFELSE(
651         [AC_LANG_PROGRAM(
652                 [[#include <sys/types.h>
653                   #ifdef HAVE_NETIPSEC_IPSEC_H
654                   #include <netipsec/ipsec.h>
655                   #elif defined(HAVE_NETINET6_IPSEC_H)
656                   #include <netinet6/ipsec.h>
657                   #else
658                   #include <stdint.h>
659                   #include <linux/ipsec.h>
660                   #endif]],
661                 [[int dir = IPSEC_DIR_FWD;
662                   return dir;]])],
663         [AC_MSG_RESULT([yes]);
664          AC_DEFINE([HAVE_IPSEC_DIR_FWD], [], [have IPSEC_DIR_FWD defined])],
665         [AC_MSG_RESULT([no])]
666 )
667
668 AC_MSG_CHECKING([for RTA_TABLE])
669 AC_COMPILE_IFELSE(
670         [AC_LANG_PROGRAM(
671                 [[#include <sys/socket.h>
672                   #include <linux/netlink.h>
673                   #include <linux/rtnetlink.h>]],
674                 [[int rta_type = RTA_TABLE;
675                   return rta_type;]])],
676         [AC_MSG_RESULT([yes]);
677          AC_DEFINE([HAVE_RTA_TABLE], [], [have netlink RTA_TABLE defined])],
678         [AC_MSG_RESULT([no])]
679 )
680
681 AC_MSG_CHECKING([for GCC __sync operations])
682 AC_RUN_IFELSE([AC_LANG_SOURCE(
683         [[
684                         int main() {
685                         int ref = 1;
686                         __sync_fetch_and_add (&ref, 1);
687                         __sync_sub_and_fetch (&ref, 1);
688                         __sync_val_compare_and_swap(&ref, 1, 0);
689                         return ref;
690                 }
691         ]])],
692         [AC_MSG_RESULT([yes]);
693          AC_DEFINE([HAVE_GCC_SYNC_OPERATIONS], [],
694                    [have GCC __sync_* operations])],
695         [AC_MSG_RESULT([no])],
696         [AC_MSG_RESULT([no])]
697 )
698
699 case "$printf_hooks" in
700 auto|builtin|glibc|vstr)
701         ;;
702 *)
703         AC_MSG_NOTICE([invalid printf hook implementation, defaulting to 'auto'])
704         printf_hooks=auto
705         ;;
706 esac
707
708 if test x$printf_hooks = xauto -o x$printf_hooks = xglibc; then
709         # check for the new register_printf_specifier function with len argument,
710         # or the deprecated register_printf_function without
711         AC_CHECK_FUNC(
712                 [register_printf_specifier],
713                 [AC_DEFINE([HAVE_PRINTF_SPECIFIER], [], [have register_printf_specifier()])],
714                 [AC_CHECK_FUNC(
715                         [register_printf_function],
716                         [AC_DEFINE([HAVE_PRINTF_FUNCTION], [], [have register_printf_function()])],
717                         [
718                                 AC_MSG_NOTICE([printf(3) does not support custom format specifiers!])
719                                 if test x$printf_hooks = xglibc; then
720                                         AC_MSG_ERROR([please select a different printf hook implementation])
721                                 else
722                                         # fallback to builtin printf hook implementation
723                                         printf_hooks=builtin
724                                 fi
725                         ]
726                 )]
727         )
728 fi
729
730 AC_MSG_CHECKING([for Windows target])
731 AC_COMPILE_IFELSE(
732         [AC_LANG_PROGRAM(
733                 [[#include <windows.h>]],
734                 [[#ifndef WIN32
735                   # error WIN32 undefined
736                   #endif
737                 ]])],
738         [
739                 AC_MSG_RESULT([yes])
740                 windows=true
741                 openssl_lib=eay32
742                 AC_SUBST(PTHREADLIB, "")
743                 # explicitly disable ms-bitfields, as it breaks __attribute__((packed))
744                 case "$CFLAGS" in
745                         *ms-bitfields*) ;;
746                         *) CFLAGS="$CFLAGS -mno-ms-bitfields" ;;
747                 esac
748         ],
749         [
750                 AC_MSG_RESULT([no])
751                 openssl_lib=crypto
752
753                 # check for clock_gettime() on non-Windows only. Otherwise this
754                 # check might find clock_gettime() in libwinpthread, but we don't want
755                 # to link against it.
756                 saved_LIBS=$LIBS
757                 # FreeBSD has clock_gettime in libc, Linux needs librt
758                 LIBS=""
759                 AC_SEARCH_LIBS(clock_gettime, rt, [RTLIB=$LIBS])
760                 AC_CHECK_FUNCS(clock_gettime)
761                 AC_SUBST(RTLIB)
762                 LIBS=$saved_LIBS
763         ]
764 )
765 AC_SUBST(OPENSSL_LIB, [-l$openssl_lib])
766 AM_CONDITIONAL(USE_WINDOWS, [test "x$windows" = xtrue])
767
768 AC_MSG_CHECKING([for working __attribute__((packed))])
769 AC_COMPILE_IFELSE(
770         [AC_LANG_PROGRAM([], [[
771                 struct test { char a; short b; } __attribute__((packed));
772                 char x[sizeof(struct test) == sizeof(char) + sizeof(short) ? 1 : -1]
773                         __attribute__((unused));
774                 return 0;
775         ]])],
776         [AC_MSG_RESULT([yes])],
777         [AC_MSG_RESULT([no]); AC_MSG_ERROR([__attribute__((packed)) does not work])]
778 )
779
780 AC_MSG_CHECKING([clang])
781 AC_COMPILE_IFELSE(
782         [AC_LANG_PROGRAM(
783                 [], [[
784                  #ifndef __clang__
785                  # error not using LLVM clang
786                  #endif
787                 ]])],
788         [
789                 AC_MSG_RESULT([yes])
790         ],
791         [
792                 AC_MSG_RESULT([no])
793                 # GCC, but not MinGW requires -rdynamic for plugins
794                 if test x$windows != xtrue; then
795                         AC_SUBST(PLUGIN_CFLAGS, [-rdynamic])
796                 fi
797         ]
798 )
799
800 if test x$printf_hooks = xvstr; then
801         AC_CHECK_LIB([vstr],[main],[LIBS="$LIBS"],[AC_MSG_ERROR([Vstr string library not found])],[])
802         AC_DEFINE([USE_VSTR], [], [use Vstr string library for printf hooks])
803 fi
804
805 if test x$printf_hooks = xbuiltin; then
806         AC_DEFINE([USE_BUILTIN_PRINTF], [], [using builtin printf for printf hooks])
807 fi
808
809 if test x$gmp = xtrue; then
810         saved_LIBS=$LIBS
811         AC_CHECK_LIB([gmp],[main],[],[AC_MSG_ERROR([GNU Multi Precision library gmp not found])],[])
812         AC_MSG_CHECKING([mpz_powm_sec])
813         if test x$mpz_powm_sec = xyes; then
814                 AC_COMPILE_IFELSE(
815                         [AC_LANG_PROGRAM(
816                                 [[#include "gmp.h"]],
817                                 [[void *x = mpz_powm_sec;]])],
818                         [AC_MSG_RESULT([yes]);
819                          AC_DEFINE([HAVE_MPZ_POWM_SEC], [], [have mpz_mown_sec()])],
820                         [AC_MSG_RESULT([no])]
821                 )
822         else
823                 AC_MSG_RESULT([disabled])
824         fi
825         LIBS=$saved_LIBS
826         AC_MSG_CHECKING([gmp.h version >= 4.1.4])
827         AC_COMPILE_IFELSE(
828                 [AC_LANG_PROGRAM(
829                         [[#include "gmp.h"]],
830                         [[
831                                 #if (__GNU_MP_VERSION*100 +  __GNU_MP_VERSION_MINOR*10 + __GNU_MP_VERSION_PATCHLEVEL) < 414
832                                         #error bad gmp
833                                 #endif]])],
834                 [AC_MSG_RESULT([yes])],
835                 [AC_MSG_RESULT([no]); AC_MSG_ERROR([No usable gmp.h found!])]
836         )
837 fi
838
839 if test x$ldap = xtrue; then
840         AC_CHECK_LIB([ldap],[main],[LIBS="$LIBS"],[AC_MSG_ERROR([LDAP library ldap not found])],[])
841         AC_CHECK_LIB([lber],[main],[LIBS="$LIBS"],[AC_MSG_ERROR([LDAP library lber not found])],[])
842         AC_CHECK_HEADER([ldap.h],,[AC_MSG_ERROR([LDAP header ldap.h not found!])])
843 fi
844
845 if test x$curl = xtrue; then
846         AC_CHECK_LIB([curl],[main],[LIBS="$LIBS"],[AC_MSG_ERROR([CURL library curl not found])],[])
847         AC_CHECK_HEADER([curl/curl.h],,[AC_MSG_ERROR([CURL header curl/curl.h not found!])])
848 fi
849
850 if test x$unbound = xtrue; then
851         AC_HAVE_LIBRARY([ldns],[LIBS="$LIBS"],[AC_MSG_ERROR([UNBOUND library ldns not found])])
852         AC_CHECK_HEADER([ldns/ldns.h],,[AC_MSG_ERROR([UNBOUND header ldns/ldns.h not found!])])
853         AC_HAVE_LIBRARY([unbound],[LIBS="$LIBS"],[AC_MSG_ERROR([UNBOUND library libunbound not found])])
854         AC_CHECK_HEADER([unbound.h],,[AC_MSG_ERROR([UNBOUND header unbound.h not found!])])
855 fi
856
857 if test x$soup = xtrue; then
858         PKG_CHECK_MODULES(soup, [libsoup-2.4])
859         AC_SUBST(soup_CFLAGS)
860         AC_SUBST(soup_LIBS)
861 fi
862
863 if test x$xml = xtrue; then
864         PKG_CHECK_MODULES(xml, [libxml-2.0])
865         AC_SUBST(xml_CFLAGS)
866         AC_SUBST(xml_LIBS)
867 fi
868
869 if test x$systemd = xtrue; then
870         AC_MSG_CHECKING([for systemd system unit directory])
871         if test -n "$systemdsystemunitdir" -a "x$systemdsystemunitdir" != xno; then
872                 AC_MSG_RESULT([$systemdsystemunitdir])
873         else
874                 AC_MSG_ERROR([not found (try --with-systemdsystemunitdir)])
875         fi
876
877         PKG_CHECK_MODULES(systemd_daemon, [libsystemd-daemon])
878         AC_SUBST(systemd_daemon_CFLAGS)
879         AC_SUBST(systemd_daemon_LIBS)
880
881         PKG_CHECK_MODULES(systemd_journal, [libsystemd-journal])
882         AC_SUBST(systemd_journal_CFLAGS)
883         AC_SUBST(systemd_journal_LIBS)
884 fi
885
886 if test x$tss = xtrousers; then
887         AC_CHECK_LIB([tspi],[main],[LIBS="$LIBS"],[AC_MSG_ERROR([TrouSerS library libtspi not found])],[])
888         AC_CHECK_HEADER([trousers/tss.h],,[AC_MSG_ERROR([TrouSerS header trousers/tss.h not found!])])
889         AC_DEFINE([TSS_TROUSERS], [], [use TrouSerS library libtspi as TSS implementation])
890 fi
891
892 if test x$imv_swid = xtrue; then
893         PKG_CHECK_MODULES(json, [json-c], [],
894                 [PKG_CHECK_MODULES(json, [json])])
895         AC_SUBST(json_CFLAGS)
896         AC_SUBST(json_LIBS)
897 fi
898
899 if test x$dumm = xtrue; then
900         PKG_CHECK_MODULES(gtk, [gtk+-2.0 vte])
901         AC_SUBST(gtk_CFLAGS)
902         AC_SUBST(gtk_LIBS)
903         AC_CHECK_PROGS(RUBY, ruby)
904         AC_MSG_CHECKING([for Ruby header files])
905         if test -n "$RUBY"; then
906                 RUBYINCLUDE=
907                 RUBYDIR=`($RUBY -r rbconfig -e 'print RbConfig::CONFIG[["rubyhdrdir"]] || ""') 2>/dev/null`
908                 if test -n "$RUBYDIR" -a -r "$RUBYDIR/ruby.h"; then
909                         RUBYARCH=`($RUBY -r rbconfig -e 'print RbConfig::CONFIG[["arch"]] || ""') 2>/dev/null`
910                         if test -n "$RUBYARCH"; then
911                                 AC_MSG_RESULT([$RUBYDIR])
912                                 RUBYINCLUDE="-I$RUBYDIR -I$RUBYDIR/$RUBYARCH"
913                         fi
914                 else
915                         RUBYDIR=`($RUBY -r rbconfig -e 'print RbConfig::CONFIG[["archdir"]] || ""') 2>/dev/null`
916                         if test -n "$RUBYDIR" -a -r "$RUBYDIR/ruby.h"; then
917                                 AC_MSG_RESULT([$RUBYDIR])
918                                 RUBYINCLUDE="-I$RUBYDIR"
919                         fi
920                 fi
921                 if test -z "$RUBYINCLUDE"; then
922                         AC_MSG_ERROR([ruby.h not found])
923                 fi
924                 AC_SUBST(RUBYINCLUDE)
925         else
926                 AC_MSG_ERROR([don't know how to run ruby])
927         fi
928         AC_MSG_CHECKING([for libruby])
929         saved_LIBS=$LIBS
930         LIBS=`($RUBY -r rbconfig -e 'print RbConfig::CONFIG[["LIBRUBYARG_SHARED"]] || ""') 2>/dev/null`
931         AC_TRY_LINK_FUNC(ruby_init,
932                 [AC_MSG_RESULT([$LIBS]); RUBYLIB=$LIBS],
933                 [AC_MSG_ERROR([not found])])
934         AC_SUBST(RUBYLIB)
935         AC_CHECK_FUNCS(rb_errinfo)
936         LIBS=$saved_LIBS
937 fi
938
939 if test x$fast = xtrue; then
940         AC_CHECK_LIB([neo_cgi],[main],[LIBS="$LIBS"],[AC_MSG_ERROR([ClearSilver library neo_cgi not found!])],[])
941         AC_CHECK_LIB([neo_utl],[main],[LIBS="$LIBS"],[AC_MSG_ERROR([ClearSilver library neo_utl not found!])],[])
942         AC_MSG_CHECKING([ClearSilver requires zlib])
943         saved_CFLAGS=$CFLAGS
944         saved_LIBS=$LIBS
945         LIBS="-lneo_cgi -lneo_cs -lneo_utl"
946         CFLAGS="-I/usr/include/ClearSilver"
947         AC_LINK_IFELSE(
948                 [AC_LANG_PROGRAM(
949                         [[#include <ClearSilver.h>]],
950                         [[NEOERR *err = cgi_display(NULL, NULL);]])],
951                 [AC_MSG_RESULT([no]); clearsilver_LIBS="$LIBS"],
952                 [AC_MSG_RESULT([yes]); clearsilver_LIBS="$LIBS -lz"]
953         )
954         AC_SUBST(clearsilver_LIBS)
955         LIBS=$saved_LIBS
956         CFLAGS=$saved_CFLAGS
957 # autoconf does not like CamelCase!? How to fix this?
958 #       AC_CHECK_HEADER([ClearSilver/ClearSilver.h],,[AC_MSG_ERROR([ClearSilver header file ClearSilver/ClearSilver.h not found!])])
959
960         AC_CHECK_LIB([fcgi],[main],[LIBS="$LIBS"],[AC_MSG_ERROR([FastCGI library fcgi not found!])],[])
961         AC_CHECK_HEADER([fcgiapp.h],,[AC_MSG_ERROR([FastCGI header file fcgiapp.h not found!])])
962 fi
963
964 if test x$mysql = xtrue; then
965         if test "x$windows" = xtrue; then
966                 AC_CHECK_HEADER([mysql.h],,[AC_MSG_ERROR([MySQL header file mysql.h not found!])])
967                 AC_CHECK_LIB([mysql],[main],[LIBS="$LIBS"],[AC_MSG_ERROR([MySQL library not found!])],[])
968                 AC_SUBST(MYSQLLIB, -lmysql)
969         else
970                 AC_PATH_PROG([MYSQLCONFIG], [mysql_config], [], [$PATH:/bin:/usr/bin:/usr/local/bin])
971                 if test x$MYSQLCONFIG = x; then
972                         AC_MSG_ERROR([mysql_config not found!])
973                 fi
974                 AC_SUBST(MYSQLLIB, `$MYSQLCONFIG --libs_r`)
975                 AC_SUBST(MYSQLCFLAG, `$MYSQLCONFIG --cflags`)
976         fi
977 fi
978
979 if test x$sqlite = xtrue; then
980         AC_CHECK_LIB([sqlite3],[main],[LIBS="$LIBS"],[AC_MSG_ERROR([SQLite library sqlite3 not found])],[])
981         AC_CHECK_HEADER([sqlite3.h],,[AC_MSG_ERROR([SQLite header sqlite3.h not found!])])
982         AC_MSG_CHECKING([sqlite3_prepare_v2])
983         AC_COMPILE_IFELSE(
984                 [AC_LANG_PROGRAM(
985                         [[#include <sqlite3.h>]],
986                         [[void *test = sqlite3_prepare_v2;]])],
987                 [AC_MSG_RESULT([yes]);
988                  AC_DEFINE([HAVE_SQLITE3_PREPARE_V2], [], [have sqlite3_prepare_v2()])],
989                 [AC_MSG_RESULT([no])]
990         )
991         AC_MSG_CHECKING([sqlite3.h version >= 3.3.1])
992         AC_COMPILE_IFELSE(
993                 [AC_LANG_PROGRAM(
994                         [[#include <sqlite3.h>]],
995                         [[
996                                 #if SQLITE_VERSION_NUMBER < 3003001
997                                         #error bad sqlite
998                                 #endif]])],
999                 [AC_MSG_RESULT([yes])],
1000                 [AC_MSG_RESULT([no]); AC_MSG_ERROR([SQLite version >= 3.3.1 required!])]
1001         )
1002 fi
1003
1004 if test x$openssl = xtrue; then
1005         AC_CHECK_LIB([$openssl_lib],[main],[LIBS="$LIBS"],[AC_MSG_ERROR([OpenSSL lib$openssl_lib not found])],[])
1006         AC_CHECK_HEADER([openssl/evp.h],,[AC_MSG_ERROR([OpenSSL header openssl/evp.h not found!])])
1007 fi
1008
1009 if test x$gcrypt = xtrue; then
1010         AC_CHECK_LIB([gcrypt],[main],[LIBS="$LIBS"],[AC_MSG_ERROR([gcrypt library not found])],[-lgpg-error])
1011         AC_CHECK_HEADER([gcrypt.h],,[AC_MSG_ERROR([gcrypt header gcrypt.h not found!])])
1012         AC_MSG_CHECKING([gcrypt CAMELLIA cipher])
1013         AC_COMPILE_IFELSE(
1014                 [AC_LANG_PROGRAM(
1015                         [[#include <gcrypt.h>]],
1016                         [[enum gcry_cipher_algos alg = GCRY_CIPHER_CAMELLIA128;]])],
1017                 [AC_MSG_RESULT([yes]);
1018                  AC_DEFINE([HAVE_GCRY_CIPHER_CAMELLIA], [], [have GCRY_CIPHER_CAMELLIA128])],
1019                 [AC_MSG_RESULT([no])]
1020         )
1021 fi
1022
1023 if test x$uci = xtrue; then
1024         AC_CHECK_LIB([uci],[main],[LIBS="$LIBS"],[AC_MSG_ERROR([UCI library libuci not found])],[])
1025         AC_CHECK_HEADER([uci.h],,[AC_MSG_ERROR([UCI header uci.h not found!])])
1026 fi
1027
1028 if test x$android_dns = xtrue; then
1029         AC_CHECK_LIB([cutils],[main],[LIBS="$LIBS"],[AC_MSG_ERROR([Android library libcutils not found])],[])
1030         AC_CHECK_HEADER([cutils/properties.h],,[AC_MSG_ERROR([Android header cutils/properties.h not found!])])
1031         # we have to force the use of libdl here because the autodetection
1032         # above does not work correctly when cross-compiling for android.
1033         DLLIB="-ldl"
1034         AC_SUBST(DLLIB)
1035 fi
1036
1037 if test x$maemo = xtrue; then
1038         PKG_CHECK_MODULES(maemo, [glib-2.0 gthread-2.0 libosso osso-af-settings])
1039         AC_SUBST(maemo_CFLAGS)
1040         AC_SUBST(maemo_LIBS)
1041         dbusservicedir="/usr/share/dbus-1/system-services"
1042         AC_SUBST(dbusservicedir)
1043 fi
1044
1045 if test x$eap_sim_pcsc = xtrue; then
1046         PKG_CHECK_MODULES(pcsclite, [libpcsclite])
1047         AC_SUBST(pcsclite_CFLAGS)
1048         AC_SUBST(pcsclite_LIBS)
1049 fi
1050
1051 if test x$nm = xtrue; then
1052         PKG_CHECK_EXISTS([libnm-glib],
1053                 [PKG_CHECK_MODULES(nm, [NetworkManager gthread-2.0 libnm-util libnm-glib libnm-glib-vpn])],
1054                 [PKG_CHECK_MODULES(nm, [NetworkManager gthread-2.0 libnm_util libnm_glib libnm_glib_vpn])]
1055         )
1056         AC_SUBST(nm_CFLAGS)
1057         AC_SUBST(nm_LIBS)
1058 fi
1059
1060 if test x$xauth_pam = xtrue; then
1061         AC_CHECK_LIB([pam],[main],[LIBS="$LIBS"],[AC_MSG_ERROR([PAM library not found])],[])
1062         AC_CHECK_HEADER([security/pam_appl.h],,[AC_MSG_ERROR([PAM header security/pam_appl.h not found!])])
1063 fi
1064
1065 if test x$capabilities = xnative; then
1066         AC_MSG_NOTICE([Usage of the native Linux capabilities interface is deprecated, use libcap instead])
1067         # Linux requires the following for capset(), Android does not have it,
1068         # but defines capset() in unistd.h instead.
1069         AC_CHECK_HEADERS([sys/capability.h])
1070         AC_CHECK_FUNC(capset,,[AC_MSG_ERROR([capset() not found!])])
1071         AC_DEFINE([CAPABILITIES_NATIVE], [], [have native linux capset()])
1072 fi
1073
1074 if test x$capabilities = xlibcap; then
1075         AC_CHECK_LIB([cap],[main],[LIBS="$LIBS"],[AC_MSG_ERROR([libcap library not found])],[])
1076         AC_CHECK_HEADER([sys/capability.h],
1077                 [AC_DEFINE([HAVE_SYS_CAPABILITY_H], [], [have sys/capability.h])],
1078                 [AC_MSG_ERROR([libcap header sys/capability.h not found!])])
1079         AC_DEFINE([CAPABILITIES_LIBCAP], [], [have libpcap library])
1080 fi
1081
1082 if test x$integrity_test = xtrue; then
1083         AC_MSG_CHECKING([for dladdr()])
1084         AC_COMPILE_IFELSE(
1085                 [AC_LANG_PROGRAM(
1086                         [[#define _GNU_SOURCE
1087                           #include <dlfcn.h>]],
1088                         [[Dl_info info; dladdr(main, &info);]])],
1089                 [AC_MSG_RESULT([yes])],
1090                 [AC_MSG_RESULT([no]);
1091                  AC_MSG_ERROR([dladdr() not supported, required by integrity-test!])]
1092         )
1093         AC_MSG_CHECKING([for dl_iterate_phdr()])
1094         AC_COMPILE_IFELSE(
1095                 [AC_LANG_PROGRAM(
1096                         [[#define _GNU_SOURCE
1097                           #include <link.h>]],
1098                         [[dl_iterate_phdr((void*)0, (void*)0);]])],
1099                 [AC_MSG_RESULT([yes])],
1100                 [AC_MSG_RESULT([no]);
1101                  AC_MSG_ERROR([dl_iterate_phdr() not supported, required by integrity-test!])]
1102         )
1103 fi
1104
1105 if test x$bfd_backtraces = xtrue; then
1106         AC_CHECK_LIB([bfd],[main],[LIBS="$LIBS"],[AC_MSG_ERROR([binutils libbfd not found!])],[])
1107         AC_CHECK_HEADER([bfd.h],[AC_DEFINE([HAVE_BFD_H],,[have binutils bfd.h])],
1108                 [AC_MSG_ERROR([binutils bfd.h header not found!])])
1109         BFDLIB="-lbfd"
1110         AC_SUBST(BFDLIB)
1111 fi
1112
1113 if test x$unwind_backtraces = xtrue; then
1114         AC_CHECK_LIB([unwind],[main],[LIBS="$LIBS"],[AC_MSG_ERROR([libunwind not found!])],[])
1115         AC_CHECK_HEADER([libunwind.h],[AC_DEFINE([HAVE_LIBUNWIND_H],,[have libunwind.h])],
1116                 [AC_MSG_ERROR([libunwind.h header not found!])])
1117         UNWINDLIB="-lunwind"
1118         AC_SUBST(UNWINDLIB)
1119 fi
1120
1121 AM_CONDITIONAL(USE_DEV_HEADERS, [test "x$dev_headers" != xno])
1122 if test x$dev_headers = xyes; then
1123         dev_headers="$includedir/strongswan"
1124 fi
1125 AC_SUBST(dev_headers)
1126
1127 CFLAGS="$CFLAGS -include `pwd`/config.h"
1128
1129 if test x$tkm = xtrue; then
1130         AC_PATH_PROG([GPRBUILD], [gprbuild], [], [$PATH:/bin:/usr/bin:/usr/local/bin])
1131         if test x$GPRBUILD = x; then
1132                 AC_MSG_ERROR([gprbuild not found])
1133         fi
1134 fi
1135
1136 if test x$coverage = xtrue; then
1137         AC_PATH_PROG([LCOV], [lcov], [], [$PATH:/bin:/usr/bin:/usr/local/bin])
1138         if test x$LCOV = x; then
1139                 AC_MSG_ERROR([lcov not found])
1140         fi
1141         AC_PATH_PROG([GENHTML], [genhtml], [], [$PATH:/bin:/usr/bin:/usr/local/bin])
1142         if test x$GENHTML = x; then
1143                 AC_MSG_ERROR([genhtml not found])
1144         fi
1145
1146         COVERAGE_CFLAGS="-fprofile-arcs -ftest-coverage"
1147         COVERAGE_LDFLAGS="-fprofile-arcs"
1148         AC_SUBST(COVERAGE_CFLAGS)
1149         AC_SUBST(COVERAGE_LDFLAGS)
1150
1151         AC_MSG_NOTICE([coverage enabled, adding "-g -O0" to CFLAGS])
1152         CFLAGS="${CFLAGS} -g -O0"
1153 fi
1154
1155 # ===============================================
1156 #  collect plugin list for strongSwan components
1157 # ===============================================
1158
1159 m4_include(m4/macros/add-plugin.m4)
1160
1161 # plugin lists for all components
1162 charon_plugins=
1163 starter_plugins=
1164 pool_plugins=
1165 attest_plugins=
1166 scepclient_plugins=
1167 pki_plugins=
1168 scripts_plugins=
1169 manager_plugins=
1170 medsrv_plugins=
1171 nm_plugins=
1172 cmd_plugins=
1173 aikgen_plugins=
1174
1175 # location specific lists for checksumming,
1176 # for src/libcharon, src/libhydra, src/libstrongswan and src/libtnccs
1177 c_plugins=
1178 h_plugins=
1179 s_plugins=
1180 t_plugins=
1181
1182 ADD_PLUGIN([test-vectors],         [s charon scepclient pki])
1183 ADD_PLUGIN([unbound],              [s charon scripts])
1184 ADD_PLUGIN([ldap],                 [s charon scepclient scripts nm cmd])
1185 ADD_PLUGIN([mysql],                [s charon pool manager medsrv attest])
1186 ADD_PLUGIN([sqlite],               [s charon pool manager medsrv attest])
1187 ADD_PLUGIN([pkcs11],               [s charon pki nm cmd])
1188 ADD_PLUGIN([aes],                  [s charon scepclient pki scripts nm cmd])
1189 ADD_PLUGIN([des],                  [s charon scepclient pki scripts nm cmd])
1190 ADD_PLUGIN([blowfish],             [s charon scepclient pki scripts nm cmd])
1191 ADD_PLUGIN([rc2],                  [s charon scepclient pki scripts nm cmd])
1192 ADD_PLUGIN([sha1],                 [s charon scepclient pki scripts medsrv attest nm cmd aikgen])
1193 ADD_PLUGIN([sha2],                 [s charon scepclient pki scripts medsrv attest nm cmd aikgen])
1194 ADD_PLUGIN([md4],                  [s charon manager scepclient pki nm cmd])
1195 ADD_PLUGIN([md5],                  [s charon scepclient pki scripts attest nm cmd aikgen])
1196 ADD_PLUGIN([rdrand],               [s charon scepclient pki scripts medsrv attest nm cmd aikgen])
1197 ADD_PLUGIN([random],               [s charon scepclient pki scripts medsrv attest nm cmd aikgen])
1198 ADD_PLUGIN([nonce],                [s charon nm cmd aikgen])
1199 ADD_PLUGIN([x509],                 [s charon scepclient pki scripts attest nm cmd aikgen])
1200 ADD_PLUGIN([revocation],           [s charon pki nm cmd])
1201 ADD_PLUGIN([constraints],          [s charon nm cmd])
1202 ADD_PLUGIN([acert],                [s charon])
1203 ADD_PLUGIN([pubkey],               [s charon cmd aikgen])
1204 ADD_PLUGIN([pkcs1],                [s charon scepclient pki scripts manager medsrv attest nm cmd aikgen])
1205 ADD_PLUGIN([pkcs7],                [s charon scepclient pki scripts nm cmd])
1206 ADD_PLUGIN([pkcs8],                [s charon scepclient pki scripts manager medsrv attest nm cmd])
1207 ADD_PLUGIN([pkcs12],               [s charon scepclient pki scripts cmd])
1208 ADD_PLUGIN([pgp],                  [s charon])
1209 ADD_PLUGIN([dnskey],               [s charon pki])
1210 ADD_PLUGIN([sshkey],               [s charon pki nm cmd])
1211 ADD_PLUGIN([dnscert],              [c charon])
1212 ADD_PLUGIN([ipseckey],             [c charon])
1213 ADD_PLUGIN([pem],                  [s charon scepclient pki scripts manager medsrv attest nm cmd aikgen])
1214 ADD_PLUGIN([padlock],              [s charon])
1215 ADD_PLUGIN([openssl],              [s charon scepclient pki scripts manager medsrv attest nm cmd aikgen])
1216 ADD_PLUGIN([gcrypt],               [s charon scepclient pki scripts manager medsrv attest nm cmd aikgen])
1217 ADD_PLUGIN([af-alg],               [s charon scepclient pki scripts medsrv attest nm cmd aikgen])
1218 ADD_PLUGIN([fips-prf],             [s charon nm cmd])
1219 ADD_PLUGIN([gmp],                  [s charon scepclient pki scripts manager medsrv attest nm cmd aikgen])
1220 ADD_PLUGIN([agent],                [s charon nm cmd])
1221 ADD_PLUGIN([keychain],             [s charon cmd])
1222 ADD_PLUGIN([xcbc],                 [s charon nm cmd])
1223 ADD_PLUGIN([cmac],                 [s charon nm cmd])
1224 ADD_PLUGIN([hmac],                 [s charon scripts nm cmd])
1225 ADD_PLUGIN([ctr],                  [s charon scripts nm cmd])
1226 ADD_PLUGIN([ccm],                  [s charon scripts nm cmd])
1227 ADD_PLUGIN([gcm],                  [s charon scripts nm cmd])
1228 ADD_PLUGIN([ntru],                 [s charon scripts nm cmd])
1229 ADD_PLUGIN([curl],                 [s charon scepclient pki scripts nm cmd])
1230 ADD_PLUGIN([winhttp],              [s charon pki scripts])
1231 ADD_PLUGIN([soup],                 [s charon pki scripts nm cmd])
1232 ADD_PLUGIN([attr],                 [h charon])
1233 ADD_PLUGIN([attr-sql],             [h charon])
1234 ADD_PLUGIN([load-tester],          [c charon])
1235 ADD_PLUGIN([kernel-libipsec],      [c charon cmd])
1236 ADD_PLUGIN([kernel-wfp],           [c charon])
1237 ADD_PLUGIN([kernel-iph],           [c charon])
1238 ADD_PLUGIN([kernel-pfkey],         [h charon starter nm cmd])
1239 ADD_PLUGIN([kernel-pfroute],       [h charon starter nm cmd])
1240 ADD_PLUGIN([kernel-netlink],       [h charon starter nm cmd])
1241 ADD_PLUGIN([resolve],              [h charon cmd])
1242 ADD_PLUGIN([socket-default],       [c charon nm cmd])
1243 ADD_PLUGIN([socket-dynamic],       [c charon cmd])
1244 ADD_PLUGIN([socket-win],           [c charon])
1245 ADD_PLUGIN([farp],                 [c charon])
1246 ADD_PLUGIN([stroke],               [c charon])
1247 ADD_PLUGIN([vici],                 [c charon])
1248 ADD_PLUGIN([smp],                  [c charon])
1249 ADD_PLUGIN([sql],                  [c charon])
1250 ADD_PLUGIN([updown],               [c charon])
1251 ADD_PLUGIN([eap-identity],         [c charon nm cmd])
1252 ADD_PLUGIN([eap-sim],              [c charon])
1253 ADD_PLUGIN([eap-sim-file],         [c charon])
1254 ADD_PLUGIN([eap-sim-pcsc],         [c charon])
1255 ADD_PLUGIN([eap-aka],              [c charon])
1256 ADD_PLUGIN([eap-aka-3gpp2],        [c charon])
1257 ADD_PLUGIN([eap-simaka-sql],       [c charon])
1258 ADD_PLUGIN([eap-simaka-pseudonym], [c charon])
1259 ADD_PLUGIN([eap-simaka-reauth],    [c charon])
1260 ADD_PLUGIN([eap-md5],              [c charon nm cmd])
1261 ADD_PLUGIN([eap-gtc],              [c charon nm cmd])
1262 ADD_PLUGIN([eap-mschapv2],         [c charon nm cmd])
1263 ADD_PLUGIN([eap-dynamic],          [c charon])
1264 ADD_PLUGIN([eap-radius],           [c charon])
1265 ADD_PLUGIN([eap-tls],              [c charon nm cmd])
1266 ADD_PLUGIN([eap-ttls],             [c charon nm cmd])
1267 ADD_PLUGIN([eap-peap],             [c charon nm cmd])
1268 ADD_PLUGIN([eap-tnc],              [c charon])
1269 ADD_PLUGIN([xauth-generic],        [c charon cmd])
1270 ADD_PLUGIN([xauth-eap],            [c charon])
1271 ADD_PLUGIN([xauth-pam],            [c charon])
1272 ADD_PLUGIN([xauth-noauth],         [c charon])
1273 ADD_PLUGIN([tnc-ifmap],            [c charon])
1274 ADD_PLUGIN([tnc-pdp],              [c charon])
1275 ADD_PLUGIN([tnc-imc],              [t charon])
1276 ADD_PLUGIN([tnc-imv],              [t charon])
1277 ADD_PLUGIN([tnc-tnccs],            [t charon])
1278 ADD_PLUGIN([tnccs-20],             [t charon])
1279 ADD_PLUGIN([tnccs-11],             [t charon])
1280 ADD_PLUGIN([tnccs-dynamic],        [t charon])
1281 ADD_PLUGIN([medsrv],               [c charon])
1282 ADD_PLUGIN([medcli],               [c charon])
1283 ADD_PLUGIN([dhcp],                 [c charon])
1284 ADD_PLUGIN([osx-attr],             [c charon cmd])
1285 ADD_PLUGIN([android-dns],          [c charon])
1286 ADD_PLUGIN([android-log],          [c charon])
1287 ADD_PLUGIN([ha],                   [c charon])
1288 ADD_PLUGIN([whitelist],            [c charon])
1289 ADD_PLUGIN([ext-auth],             [c charon])
1290 ADD_PLUGIN([lookip],               [c charon])
1291 ADD_PLUGIN([error-notify],         [c charon])
1292 ADD_PLUGIN([certexpire],           [c charon])
1293 ADD_PLUGIN([systime-fix],          [c charon])
1294 ADD_PLUGIN([led],                  [c charon])
1295 ADD_PLUGIN([duplicheck],           [c charon])
1296 ADD_PLUGIN([coupling],             [c charon])
1297 ADD_PLUGIN([radattr],              [c charon])
1298 ADD_PLUGIN([maemo],                [c charon])
1299 ADD_PLUGIN([uci],                  [c charon])
1300 ADD_PLUGIN([addrblock],            [c charon])
1301 ADD_PLUGIN([unity],                [c charon])
1302 ADD_PLUGIN([unit-tester],          [c charon])
1303
1304 AC_SUBST(charon_plugins)
1305 AC_SUBST(starter_plugins)
1306 AC_SUBST(pool_plugins)
1307 AC_SUBST(attest_plugins)
1308 AC_SUBST(scepclient_plugins)
1309 AC_SUBST(pki_plugins)
1310 AC_SUBST(scripts_plugins)
1311 AC_SUBST(manager_plugins)
1312 AC_SUBST(medsrv_plugins)
1313 AC_SUBST(nm_plugins)
1314 AC_SUBST(cmd_plugins)
1315 AC_SUBST(aikgen_plugins)
1316
1317 AC_SUBST(c_plugins)
1318 AC_SUBST(h_plugins)
1319 AC_SUBST(s_plugins)
1320 AC_SUBST(t_plugins)
1321
1322 # ======================
1323 #  set Makefile.am vars
1324 # ======================
1325
1326 #  libstrongswan plugins
1327 # -----------------------
1328 AM_CONDITIONAL(USE_TEST_VECTORS, test x$test_vectors = xtrue)
1329 AM_CONDITIONAL(USE_CURL, test x$curl = xtrue)
1330 AM_CONDITIONAL(USE_WINHTTP, test x$winhttp = xtrue)
1331 AM_CONDITIONAL(USE_UNBOUND, test x$unbound = xtrue)
1332 AM_CONDITIONAL(USE_SOUP, test x$soup = xtrue)
1333 AM_CONDITIONAL(USE_LDAP, test x$ldap = xtrue)
1334 AM_CONDITIONAL(USE_AES, test x$aes = xtrue)
1335 AM_CONDITIONAL(USE_DES, test x$des = xtrue)
1336 AM_CONDITIONAL(USE_BLOWFISH, test x$blowfish = xtrue)
1337 AM_CONDITIONAL(USE_RC2, test x$rc2 = xtrue)
1338 AM_CONDITIONAL(USE_MD4, test x$md4 = xtrue)
1339 AM_CONDITIONAL(USE_MD5, test x$md5 = xtrue)
1340 AM_CONDITIONAL(USE_SHA1, test x$sha1 = xtrue)
1341 AM_CONDITIONAL(USE_SHA2, test x$sha2 = xtrue)
1342 AM_CONDITIONAL(USE_FIPS_PRF, test x$fips_prf = xtrue)
1343 AM_CONDITIONAL(USE_GMP, test x$gmp = xtrue)
1344 AM_CONDITIONAL(USE_RDRAND, test x$rdrand = xtrue)
1345 AM_CONDITIONAL(USE_RANDOM, test x$random = xtrue)
1346 AM_CONDITIONAL(USE_NONCE, test x$nonce = xtrue)
1347 AM_CONDITIONAL(USE_X509, test x$x509 = xtrue)
1348 AM_CONDITIONAL(USE_REVOCATION, test x$revocation = xtrue)
1349 AM_CONDITIONAL(USE_CONSTRAINTS, test x$constraints = xtrue)
1350 AM_CONDITIONAL(USE_ACERT, test x$acert = xtrue)
1351 AM_CONDITIONAL(USE_PUBKEY, test x$pubkey = xtrue)
1352 AM_CONDITIONAL(USE_PKCS1, test x$pkcs1 = xtrue)
1353 AM_CONDITIONAL(USE_PKCS7, test x$pkcs7 = xtrue)
1354 AM_CONDITIONAL(USE_PKCS8, test x$pkcs8 = xtrue)
1355 AM_CONDITIONAL(USE_PKCS12, test x$pkcs12 = xtrue)
1356 AM_CONDITIONAL(USE_PGP, test x$pgp = xtrue)
1357 AM_CONDITIONAL(USE_DNSKEY, test x$dnskey = xtrue)
1358 AM_CONDITIONAL(USE_SSHKEY, test x$sshkey = xtrue)
1359 AM_CONDITIONAL(USE_PEM, test x$pem = xtrue)
1360 AM_CONDITIONAL(USE_HMAC, test x$hmac = xtrue)
1361 AM_CONDITIONAL(USE_CMAC, test x$cmac = xtrue)
1362 AM_CONDITIONAL(USE_XCBC, test x$xcbc = xtrue)
1363 AM_CONDITIONAL(USE_MYSQL, test x$mysql = xtrue)
1364 AM_CONDITIONAL(USE_SQLITE, test x$sqlite = xtrue)
1365 AM_CONDITIONAL(USE_PADLOCK, test x$padlock = xtrue)
1366 AM_CONDITIONAL(USE_OPENSSL, test x$openssl = xtrue)
1367 AM_CONDITIONAL(USE_GCRYPT, test x$gcrypt = xtrue)
1368 AM_CONDITIONAL(USE_AGENT, test x$agent = xtrue)
1369 AM_CONDITIONAL(USE_KEYCHAIN, test x$keychain = xtrue)
1370 AM_CONDITIONAL(USE_PKCS11, test x$pkcs11 = xtrue)
1371 AM_CONDITIONAL(USE_CTR, test x$ctr = xtrue)
1372 AM_CONDITIONAL(USE_CCM, test x$ccm = xtrue)
1373 AM_CONDITIONAL(USE_GCM, test x$gcm = xtrue)
1374 AM_CONDITIONAL(USE_AF_ALG, test x$af_alg = xtrue)
1375 AM_CONDITIONAL(USE_NTRU, test x$ntru = xtrue)
1376
1377 #  charon plugins
1378 # ----------------
1379 AM_CONDITIONAL(USE_STROKE, test x$stroke = xtrue)
1380 AM_CONDITIONAL(USE_VICI, test x$vici = xtrue)
1381 AM_CONDITIONAL(USE_MEDSRV, test x$medsrv = xtrue)
1382 AM_CONDITIONAL(USE_MEDCLI, test x$medcli = xtrue)
1383 AM_CONDITIONAL(USE_UCI, test x$uci = xtrue)
1384 AM_CONDITIONAL(USE_OSX_ATTR, test x$osx_attr = xtrue)
1385 AM_CONDITIONAL(USE_ANDROID_DNS, test x$android_dns = xtrue)
1386 AM_CONDITIONAL(USE_ANDROID_LOG, test x$android_log = xtrue)
1387 AM_CONDITIONAL(USE_MAEMO, test x$maemo = xtrue)
1388 AM_CONDITIONAL(USE_SMP, test x$smp = xtrue)
1389 AM_CONDITIONAL(USE_SQL, test x$sql = xtrue)
1390 AM_CONDITIONAL(USE_DNSCERT, test x$dnscert = xtrue)
1391 AM_CONDITIONAL(USE_IPSECKEY, test x$ipseckey = xtrue)
1392 AM_CONDITIONAL(USE_UPDOWN, test x$updown = xtrue)
1393 AM_CONDITIONAL(USE_DHCP, test x$dhcp = xtrue)
1394 AM_CONDITIONAL(USE_UNIT_TESTS, test x$unit_tester = xtrue)
1395 AM_CONDITIONAL(USE_LOAD_TESTER, test x$load_tester = xtrue)
1396 AM_CONDITIONAL(USE_HA, test x$ha = xtrue)
1397 AM_CONDITIONAL(USE_KERNEL_LIBIPSEC, test x$kernel_libipsec = xtrue)
1398 AM_CONDITIONAL(USE_KERNEL_WFP, test x$kernel_wfp = xtrue)
1399 AM_CONDITIONAL(USE_KERNEL_IPH, test x$kernel_iph = xtrue)
1400 AM_CONDITIONAL(USE_WHITELIST, test x$whitelist = xtrue)
1401 AM_CONDITIONAL(USE_EXT_AUTH, test x$ext_auth = xtrue)
1402 AM_CONDITIONAL(USE_LOOKIP, test x$lookip = xtrue)
1403 AM_CONDITIONAL(USE_ERROR_NOTIFY, test x$error_notify = xtrue)
1404 AM_CONDITIONAL(USE_CERTEXPIRE, test x$certexpire = xtrue)
1405 AM_CONDITIONAL(USE_SYSTIME_FIX, test x$systime_fix = xtrue)
1406 AM_CONDITIONAL(USE_LED, test x$led = xtrue)
1407 AM_CONDITIONAL(USE_DUPLICHECK, test x$duplicheck = xtrue)
1408 AM_CONDITIONAL(USE_COUPLING, test x$coupling = xtrue)
1409 AM_CONDITIONAL(USE_RADATTR, test x$radattr = xtrue)
1410 AM_CONDITIONAL(USE_EAP_SIM, test x$eap_sim = xtrue)
1411 AM_CONDITIONAL(USE_EAP_SIM_FILE, test x$eap_sim_file = xtrue)
1412 AM_CONDITIONAL(USE_EAP_SIM_PCSC, test x$eap_sim_pcsc = xtrue)
1413 AM_CONDITIONAL(USE_EAP_SIMAKA_SQL, test x$eap_simaka_sql = xtrue)
1414 AM_CONDITIONAL(USE_EAP_SIMAKA_PSEUDONYM, test x$eap_simaka_pseudonym = xtrue)
1415 AM_CONDITIONAL(USE_EAP_SIMAKA_REAUTH, test x$eap_simaka_reauth = xtrue)
1416 AM_CONDITIONAL(USE_EAP_IDENTITY, test x$eap_identity = xtrue)
1417 AM_CONDITIONAL(USE_EAP_MD5, test x$eap_md5 = xtrue)
1418 AM_CONDITIONAL(USE_EAP_GTC, test x$eap_gtc = xtrue)
1419 AM_CONDITIONAL(USE_EAP_AKA, test x$eap_aka = xtrue)
1420 AM_CONDITIONAL(USE_EAP_AKA_3GPP2, test x$eap_aka_3gpp2 = xtrue)
1421 AM_CONDITIONAL(USE_EAP_MSCHAPV2, test x$eap_mschapv2 = xtrue)
1422 AM_CONDITIONAL(USE_EAP_TLS, test x$eap_tls = xtrue)
1423 AM_CONDITIONAL(USE_EAP_TTLS, test x$eap_ttls = xtrue)
1424 AM_CONDITIONAL(USE_EAP_PEAP, test x$eap_peap = xtrue)
1425 AM_CONDITIONAL(USE_EAP_TNC, test x$eap_tnc = xtrue)
1426 AM_CONDITIONAL(USE_EAP_DYNAMIC, test x$eap_dynamic = xtrue)
1427 AM_CONDITIONAL(USE_EAP_RADIUS, test x$eap_radius = xtrue)
1428 AM_CONDITIONAL(USE_XAUTH_GENERIC, test x$xauth_generic = xtrue)
1429 AM_CONDITIONAL(USE_XAUTH_EAP, test x$xauth_eap = xtrue)
1430 AM_CONDITIONAL(USE_XAUTH_PAM, test x$xauth_pam = xtrue)
1431 AM_CONDITIONAL(USE_XAUTH_NOAUTH, test x$xauth_noauth = xtrue)
1432 AM_CONDITIONAL(USE_TNC_IFMAP, test x$tnc_ifmap = xtrue)
1433 AM_CONDITIONAL(USE_TNC_PDP, test x$tnc_pdp = xtrue)
1434 AM_CONDITIONAL(USE_TNC_IMC, test x$tnc_imc = xtrue)
1435 AM_CONDITIONAL(USE_TNC_IMV, test x$tnc_imv = xtrue)
1436 AM_CONDITIONAL(USE_TNC_TNCCS, test x$tnc_tnccs = xtrue)
1437 AM_CONDITIONAL(USE_TNCCS_11, test x$tnccs_11 = xtrue)
1438 AM_CONDITIONAL(USE_TNCCS_20, test x$tnccs_20 = xtrue)
1439 AM_CONDITIONAL(USE_TNCCS_DYNAMIC, test x$tnccs_dynamic = xtrue)
1440 AM_CONDITIONAL(USE_IMC_TEST, test x$imc_test = xtrue)
1441 AM_CONDITIONAL(USE_IMV_TEST, test x$imv_test = xtrue)
1442 AM_CONDITIONAL(USE_IMC_SCANNER, test x$imc_scanner = xtrue)
1443 AM_CONDITIONAL(USE_IMV_SCANNER, test x$imv_scanner = xtrue)
1444 AM_CONDITIONAL(USE_IMC_OS, test x$imc_os = xtrue)
1445 AM_CONDITIONAL(USE_IMV_OS, test x$imv_os = xtrue)
1446 AM_CONDITIONAL(USE_IMC_ATTESTATION, test x$imc_attestation = xtrue)
1447 AM_CONDITIONAL(USE_IMV_ATTESTATION, test x$imv_attestation = xtrue)
1448 AM_CONDITIONAL(USE_IMC_SWID, test x$imc_swid = xtrue)
1449 AM_CONDITIONAL(USE_IMV_SWID, test x$imv_swid = xtrue)
1450 AM_CONDITIONAL(USE_SOCKET_DEFAULT, test x$socket_default = xtrue)
1451 AM_CONDITIONAL(USE_SOCKET_DYNAMIC, test x$socket_dynamic = xtrue)
1452 AM_CONDITIONAL(USE_SOCKET_WIN, test x$socket_win = xtrue)
1453 AM_CONDITIONAL(USE_FARP, test x$farp = xtrue)
1454 AM_CONDITIONAL(USE_ADDRBLOCK, test x$addrblock = xtrue)
1455 AM_CONDITIONAL(USE_UNITY, test x$unity = xtrue)
1456
1457 #  hydra plugins
1458 # ---------------
1459 AM_CONDITIONAL(USE_ATTR, test x$attr = xtrue)
1460 AM_CONDITIONAL(USE_ATTR_SQL, test x$attr_sql = xtrue)
1461 AM_CONDITIONAL(USE_KERNEL_NETLINK, test x$kernel_netlink = xtrue)
1462 AM_CONDITIONAL(USE_KERNEL_PFKEY, test x$kernel_pfkey = xtrue)
1463 AM_CONDITIONAL(USE_KERNEL_PFROUTE, test x$kernel_pfroute = xtrue)
1464 AM_CONDITIONAL(USE_RESOLVE, test x$resolve = xtrue)
1465
1466 #  other options
1467 # ---------------
1468 AM_CONDITIONAL(USE_LEAK_DETECTIVE, test x$leak_detective = xtrue)
1469 AM_CONDITIONAL(USE_LOCK_PROFILER, test x$lock_profiler = xtrue)
1470 AM_CONDITIONAL(USE_DUMM, test x$dumm = xtrue)
1471 AM_CONDITIONAL(USE_FAST, test x$fast = xtrue)
1472 AM_CONDITIONAL(USE_MANAGER, test x$manager = xtrue)
1473 AM_CONDITIONAL(USE_ME, test x$mediation = xtrue)
1474 AM_CONDITIONAL(USE_INTEGRITY_TEST, test x$integrity_test = xtrue)
1475 AM_CONDITIONAL(USE_LOAD_WARNING, test x$load_warning = xtrue)
1476 AM_CONDITIONAL(USE_IKEV1, test x$ikev1 = xtrue)
1477 AM_CONDITIONAL(USE_IKEV2, test x$ikev2 = xtrue)
1478 AM_CONDITIONAL(USE_THREADS, test x$threads = xtrue)
1479 AM_CONDITIONAL(USE_ADNS, test x$adns = xtrue)
1480 AM_CONDITIONAL(USE_CHARON, test x$charon = xtrue)
1481 AM_CONDITIONAL(USE_NM, test x$nm = xtrue)
1482 AM_CONDITIONAL(USE_PKI, test x$pki = xtrue)
1483 AM_CONDITIONAL(USE_SCEPCLIENT, test x$scepclient = xtrue)
1484 AM_CONDITIONAL(USE_SCRIPTS, test x$scripts = xtrue)
1485 AM_CONDITIONAL(USE_CONFTEST, test x$conftest = xtrue)
1486 AM_CONDITIONAL(USE_LIBSTRONGSWAN, test x$charon = xtrue -o x$pki = xtrue -o x$scepclient = xtrue -o x$conftest = xtrue -o x$fast = xtrue -o x$imcv = xtrue -o x$nm = xtrue -o x$tkm = xtrue -o x$cmd = xtrue -o x$tls = xtrue -o x$tnc_tnccs = xtrue -o x$aikgen = xtrue -o x$svc = xtrue -o x$systemd = xtrue)
1487 AM_CONDITIONAL(USE_LIBHYDRA, test x$charon = xtrue -o x$nm = xtrue -o x$tkm = xtrue -o x$cmd = xtrue -o x$svc = xtrue -o x$systemd = xtrue)
1488 AM_CONDITIONAL(USE_LIBCHARON, test x$charon = xtrue -o x$conftest = xtrue -o x$nm = xtrue -o x$tkm = xtrue -o x$cmd = xtrue -o x$svc = xtrue -o x$systemd = xtrue)
1489 AM_CONDITIONAL(USE_LIBIPSEC, test x$libipsec = xtrue)
1490 AM_CONDITIONAL(USE_LIBTNCIF, test x$tnc_tnccs = xtrue -o x$imcv = xtrue)
1491 AM_CONDITIONAL(USE_LIBTNCCS, test x$tnc_tnccs = xtrue)
1492 AM_CONDITIONAL(USE_LIBPTTLS, test x$tnc_tnccs = xtrue)
1493 AM_CONDITIONAL(USE_FILE_CONFIG, test x$stroke = xtrue)
1494 AM_CONDITIONAL(USE_IPSEC_SCRIPT, test x$stroke = xtrue -o x$scepclient = xtrue -o x$conftest = xtrue)
1495 AM_CONDITIONAL(USE_LIBCAP, test x$capabilities = xlibcap)
1496 AM_CONDITIONAL(USE_VSTR, test x$printf_hooks = xvstr)
1497 AM_CONDITIONAL(USE_BUILTIN_PRINTF, test x$printf_hooks = xbuiltin)
1498 AM_CONDITIONAL(USE_SIMAKA, test x$simaka = xtrue)
1499 AM_CONDITIONAL(USE_TLS, test x$tls = xtrue)
1500 AM_CONDITIONAL(USE_RADIUS, test x$radius = xtrue)
1501 AM_CONDITIONAL(USE_IMCV, test x$imcv = xtrue)
1502 AM_CONDITIONAL(USE_TROUSERS, test x$tss = xtrousers -o x$aikgen = xtrue)
1503 AM_CONDITIONAL(MONOLITHIC, test x$monolithic = xtrue)
1504 AM_CONDITIONAL(USE_SILENT_RULES, test x$enable_silent_rules = xyes)
1505 AM_CONDITIONAL(COVERAGE, test x$coverage = xtrue)
1506 AM_CONDITIONAL(USE_DBGHELP, test x$dbghelp_backtraces = xtrue)
1507 AM_CONDITIONAL(USE_TKM, test x$tkm = xtrue)
1508 AM_CONDITIONAL(USE_CMD, test x$cmd = xtrue)
1509 AM_CONDITIONAL(USE_AIKGEN, test x$aikgen = xtrue)
1510 AM_CONDITIONAL(USE_SWANCTL, test x$swanctl = xtrue)
1511 AM_CONDITIONAL(USE_SVC, test x$svc = xtrue)
1512 AM_CONDITIONAL(USE_SYSTEMD, test x$systemd = xtrue)
1513 AM_CONDITIONAL(USE_LEGACY_SYSTEMD, test -n "$systemdsystemunitdir" -a "x$systemdsystemunitdir" != xno)
1514
1515 # ========================
1516 #  set global definitions
1517 # ========================
1518
1519 if test x$mediation = xtrue; then
1520         AC_DEFINE([ME], [], [mediation extension support])
1521 fi
1522 if test x$capabilities = xlibcap -o x$capabilities = xnative; then
1523         AC_DEFINE([CAPABILITIES], [], [capability dropping support])
1524 fi
1525 if test x$monolithic = xtrue; then
1526         AC_DEFINE([MONOLITHIC], [], [monolithic build embedding plugins])
1527 fi
1528 if test x$ikev1 = xtrue; then
1529         AC_DEFINE([USE_IKEV1], [], [support for IKEv1 protocol])
1530 fi
1531 if test x$ikev2 = xtrue; then
1532         AC_DEFINE([USE_IKEV2], [], [support for IKEv2 protocol])
1533 fi
1534
1535 # ====================================================
1536 #  options for enabled modules (see conf/Makefile.am)
1537 # ====================================================
1538
1539 strongswan_options=
1540
1541 AM_COND_IF([USE_AIKGEN], [strongswan_options=${strongswan_options}" aikgen"])
1542 AM_COND_IF([USE_ATTR_SQL], [strongswan_options=${strongswan_options}" pool"])
1543 AM_COND_IF([USE_CHARON], [strongswan_options=${strongswan_options}" charon charon-logging"])
1544 AM_COND_IF([USE_FILE_CONFIG], [strongswan_options=${strongswan_options}" starter"])
1545 AM_COND_IF([USE_IMV_ATTESTATION], [strongswan_options=${strongswan_options}" attest"])
1546 AM_COND_IF([USE_IMCV], [strongswan_options=${strongswan_options}" imcv"])
1547 AM_COND_IF([USE_IMV_OS], [strongswan_options=${strongswan_options}" pacman"])
1548 AM_COND_IF([USE_LIBTNCCS], [strongswan_options=${strongswan_options}" tnc"])
1549 AM_COND_IF([USE_MANAGER], [strongswan_options=${strongswan_options}" manager"])
1550 AM_COND_IF([USE_MEDSRV], [strongswan_options=${strongswan_options}" medsrv"])
1551 AM_COND_IF([USE_SCEPCLIENT], [strongswan_options=${strongswan_options}" scepclient"])
1552 AM_COND_IF([USE_PKI], [strongswan_options=${strongswan_options}" pki"])
1553 AM_COND_IF([USE_SWANCTL], [strongswan_options=${strongswan_options}" swanctl"])
1554
1555 AC_SUBST(strongswan_options)
1556
1557 # =================
1558 #  build Makefiles
1559 # =================
1560
1561 AC_CONFIG_FILES([
1562         Makefile
1563         conf/Makefile
1564         man/Makefile
1565         init/Makefile
1566         init/systemd/Makefile
1567         init/systemd-swanctl/Makefile
1568         src/Makefile
1569         src/include/Makefile
1570         src/libstrongswan/Makefile
1571         src/libstrongswan/plugins/aes/Makefile
1572         src/libstrongswan/plugins/cmac/Makefile
1573         src/libstrongswan/plugins/des/Makefile
1574         src/libstrongswan/plugins/blowfish/Makefile
1575         src/libstrongswan/plugins/rc2/Makefile
1576         src/libstrongswan/plugins/md4/Makefile
1577         src/libstrongswan/plugins/md5/Makefile
1578         src/libstrongswan/plugins/sha1/Makefile
1579         src/libstrongswan/plugins/sha2/Makefile
1580         src/libstrongswan/plugins/fips_prf/Makefile
1581         src/libstrongswan/plugins/gmp/Makefile
1582         src/libstrongswan/plugins/rdrand/Makefile
1583         src/libstrongswan/plugins/random/Makefile
1584         src/libstrongswan/plugins/nonce/Makefile
1585         src/libstrongswan/plugins/hmac/Makefile
1586         src/libstrongswan/plugins/xcbc/Makefile
1587         src/libstrongswan/plugins/x509/Makefile
1588         src/libstrongswan/plugins/revocation/Makefile
1589         src/libstrongswan/plugins/constraints/Makefile
1590         src/libstrongswan/plugins/acert/Makefile
1591         src/libstrongswan/plugins/pubkey/Makefile
1592         src/libstrongswan/plugins/pkcs1/Makefile
1593         src/libstrongswan/plugins/pkcs7/Makefile
1594         src/libstrongswan/plugins/pkcs8/Makefile
1595         src/libstrongswan/plugins/pkcs12/Makefile
1596         src/libstrongswan/plugins/pgp/Makefile
1597         src/libstrongswan/plugins/dnskey/Makefile
1598         src/libstrongswan/plugins/sshkey/Makefile
1599         src/libstrongswan/plugins/pem/Makefile
1600         src/libstrongswan/plugins/curl/Makefile
1601         src/libstrongswan/plugins/winhttp/Makefile
1602         src/libstrongswan/plugins/unbound/Makefile
1603         src/libstrongswan/plugins/soup/Makefile
1604         src/libstrongswan/plugins/ldap/Makefile
1605         src/libstrongswan/plugins/mysql/Makefile
1606         src/libstrongswan/plugins/sqlite/Makefile
1607         src/libstrongswan/plugins/padlock/Makefile
1608         src/libstrongswan/plugins/openssl/Makefile
1609         src/libstrongswan/plugins/gcrypt/Makefile
1610         src/libstrongswan/plugins/agent/Makefile
1611         src/libstrongswan/plugins/keychain/Makefile
1612         src/libstrongswan/plugins/pkcs11/Makefile
1613         src/libstrongswan/plugins/ctr/Makefile
1614         src/libstrongswan/plugins/ccm/Makefile
1615         src/libstrongswan/plugins/gcm/Makefile
1616         src/libstrongswan/plugins/af_alg/Makefile
1617         src/libstrongswan/plugins/ntru/Makefile
1618         src/libstrongswan/plugins/test_vectors/Makefile
1619         src/libstrongswan/tests/Makefile
1620         src/libhydra/Makefile
1621         src/libhydra/plugins/attr/Makefile
1622         src/libhydra/plugins/attr_sql/Makefile
1623         src/libhydra/plugins/kernel_netlink/Makefile
1624         src/libhydra/plugins/kernel_pfkey/Makefile
1625         src/libhydra/plugins/kernel_pfroute/Makefile
1626         src/libhydra/plugins/resolve/Makefile
1627         src/libipsec/Makefile
1628         src/libsimaka/Makefile
1629         src/libtls/Makefile
1630         src/libtls/tests/Makefile
1631         src/libradius/Makefile
1632         src/libtncif/Makefile
1633         src/libtnccs/Makefile
1634         src/libtnccs/plugins/tnc_tnccs/Makefile
1635         src/libtnccs/plugins/tnc_imc/Makefile
1636         src/libtnccs/plugins/tnc_imv/Makefile
1637         src/libtnccs/plugins/tnccs_11/Makefile
1638         src/libtnccs/plugins/tnccs_20/Makefile
1639         src/libtnccs/plugins/tnccs_dynamic/Makefile
1640         src/libpttls/Makefile
1641         src/libimcv/Makefile
1642         src/libimcv/plugins/imc_test/Makefile
1643         src/libimcv/plugins/imv_test/Makefile
1644         src/libimcv/plugins/imc_scanner/Makefile
1645         src/libimcv/plugins/imv_scanner/Makefile
1646         src/libimcv/plugins/imc_os/Makefile
1647         src/libimcv/plugins/imv_os/Makefile
1648         src/libimcv/plugins/imc_attestation/Makefile
1649         src/libimcv/plugins/imv_attestation/Makefile
1650         src/libimcv/plugins/imc_swid/Makefile
1651         src/libimcv/plugins/imv_swid/Makefile
1652         src/charon/Makefile
1653         src/charon-nm/Makefile
1654         src/charon-tkm/Makefile
1655         src/charon-cmd/Makefile
1656         src/charon-svc/Makefile
1657         src/charon-systemd/Makefile
1658         src/libcharon/Makefile
1659         src/libcharon/plugins/eap_aka/Makefile
1660         src/libcharon/plugins/eap_aka_3gpp2/Makefile
1661         src/libcharon/plugins/eap_dynamic/Makefile
1662         src/libcharon/plugins/eap_identity/Makefile
1663         src/libcharon/plugins/eap_md5/Makefile
1664         src/libcharon/plugins/eap_gtc/Makefile
1665         src/libcharon/plugins/eap_sim/Makefile
1666         src/libcharon/plugins/eap_sim_file/Makefile
1667         src/libcharon/plugins/eap_sim_pcsc/Makefile
1668         src/libcharon/plugins/eap_simaka_sql/Makefile
1669         src/libcharon/plugins/eap_simaka_pseudonym/Makefile
1670         src/libcharon/plugins/eap_simaka_reauth/Makefile
1671         src/libcharon/plugins/eap_mschapv2/Makefile
1672         src/libcharon/plugins/eap_tls/Makefile
1673         src/libcharon/plugins/eap_ttls/Makefile
1674         src/libcharon/plugins/eap_peap/Makefile
1675         src/libcharon/plugins/eap_tnc/Makefile
1676         src/libcharon/plugins/eap_radius/Makefile
1677         src/libcharon/plugins/xauth_generic/Makefile
1678         src/libcharon/plugins/xauth_eap/Makefile
1679         src/libcharon/plugins/xauth_pam/Makefile
1680         src/libcharon/plugins/xauth_noauth/Makefile
1681         src/libcharon/plugins/tnc_ifmap/Makefile
1682         src/libcharon/plugins/tnc_pdp/Makefile
1683         src/libcharon/plugins/socket_default/Makefile
1684         src/libcharon/plugins/socket_dynamic/Makefile
1685         src/libcharon/plugins/socket_win/Makefile
1686         src/libcharon/plugins/farp/Makefile
1687         src/libcharon/plugins/smp/Makefile
1688         src/libcharon/plugins/sql/Makefile
1689         src/libcharon/plugins/dnscert/Makefile
1690         src/libcharon/plugins/ipseckey/Makefile
1691         src/libcharon/plugins/medsrv/Makefile
1692         src/libcharon/plugins/medcli/Makefile
1693         src/libcharon/plugins/addrblock/Makefile
1694         src/libcharon/plugins/unity/Makefile
1695         src/libcharon/plugins/uci/Makefile
1696         src/libcharon/plugins/ha/Makefile
1697         src/libcharon/plugins/kernel_libipsec/Makefile
1698         src/libcharon/plugins/kernel_wfp/Makefile
1699         src/libcharon/plugins/kernel_iph/Makefile
1700         src/libcharon/plugins/whitelist/Makefile
1701         src/libcharon/plugins/ext_auth/Makefile
1702         src/libcharon/plugins/lookip/Makefile
1703         src/libcharon/plugins/error_notify/Makefile
1704         src/libcharon/plugins/certexpire/Makefile
1705         src/libcharon/plugins/systime_fix/Makefile
1706         src/libcharon/plugins/led/Makefile
1707         src/libcharon/plugins/duplicheck/Makefile
1708         src/libcharon/plugins/coupling/Makefile
1709         src/libcharon/plugins/radattr/Makefile
1710         src/libcharon/plugins/osx_attr/Makefile
1711         src/libcharon/plugins/android_dns/Makefile
1712         src/libcharon/plugins/android_log/Makefile
1713         src/libcharon/plugins/maemo/Makefile
1714         src/libcharon/plugins/stroke/Makefile
1715         src/libcharon/plugins/vici/Makefile
1716         src/libcharon/plugins/updown/Makefile
1717         src/libcharon/plugins/dhcp/Makefile
1718         src/libcharon/plugins/unit_tester/Makefile
1719         src/libcharon/plugins/load_tester/Makefile
1720         src/stroke/Makefile
1721         src/ipsec/Makefile
1722         src/starter/Makefile
1723         src/starter/tests/Makefile
1724         src/_updown/Makefile
1725         src/_updown_espmark/Makefile
1726         src/_copyright/Makefile
1727         src/scepclient/Makefile
1728         src/aikgen/Makefile
1729         src/pki/Makefile
1730         src/pki/man/Makefile
1731         src/pool/Makefile
1732         src/dumm/Makefile
1733         src/dumm/ext/extconf.rb
1734         src/libfast/Makefile
1735         src/manager/Makefile
1736         src/medsrv/Makefile
1737         src/checksum/Makefile
1738         src/conftest/Makefile
1739         src/pt-tls-client/Makefile
1740         src/swanctl/Makefile
1741         scripts/Makefile
1742         testing/Makefile
1743 ])
1744
1745 # =================
1746 #  build man pages
1747 # =================
1748
1749 AC_CONFIG_FILES([
1750         conf/strongswan.conf.5.head
1751         conf/strongswan.conf.5.tail
1752         man/ipsec.conf.5
1753         man/ipsec.secrets.5
1754         src/charon-cmd/charon-cmd.8
1755         src/pki/man/pki.1
1756         src/pki/man/pki---gen.1
1757         src/pki/man/pki---issue.1
1758         src/pki/man/pki---keyid.1
1759         src/pki/man/pki---pkcs7.1
1760         src/pki/man/pki---print.1
1761         src/pki/man/pki---pub.1
1762         src/pki/man/pki---req.1
1763         src/pki/man/pki---self.1
1764         src/pki/man/pki---signcrl.1
1765         src/pki/man/pki---acert.1
1766         src/pki/man/pki---verify.1
1767         src/swanctl/swanctl.8
1768         src/swanctl/swanctl.conf.5.head
1769         src/swanctl/swanctl.conf.5.tail
1770 ])
1771
1772 AC_OUTPUT
1773
1774 # ========================
1775 #  report enabled plugins
1776 # ========================
1777
1778 AC_MSG_RESULT([])
1779 AC_MSG_RESULT([ strongSwan will be built with the following plugins])
1780 AC_MSG_RESULT([-----------------------------------------------------])
1781
1782 AC_MSG_RESULT([libstrongswan:$s_plugins])
1783 AC_MSG_RESULT([libcharon:    $c_plugins])
1784 AC_MSG_RESULT([libhydra:     $h_plugins])
1785 AC_MSG_RESULT([libtnccs:     $t_plugins])
1786 AC_MSG_RESULT([])