utils: Fix definition of BYTE_ORDER with MinGW
[strongswan.git] / configure.ac
1 #
2 # Copyright (C) 2007-2015 Tobias Brunner
3 # Copyright (C) 2006-2016 Andreas Steffen
4 # Copyright (C) 2006-2014 Martin Willi
5 # HSR Hochschule fuer Technik Rapperswil
6 #
7 # This program is free software; you can redistribute it and/or modify it
8 # under the terms of the GNU General Public License as published by the
9 # Free Software Foundation; either version 2 of the License, or (at your
10 # option) any later version.  See <http://www.fsf.org/copyleft/gpl.txt>.
11 #
12 # This program is distributed in the hope that it will be useful, but
13 # WITHOUT ANY WARRANTY; without even the implied warranty of MERCHANTABILITY
14 # or FITNESS FOR A PARTICULAR PURPOSE.  See the GNU General Public License
15 # for more details.
16 #
17
18 # ============================
19 #  initialize & set some vars
20 # ============================
21
22 AC_INIT([strongSwan],[5.5.1dr1])
23 AM_INIT_AUTOMAKE(m4_esyscmd([
24         echo tar-ustar
25         echo subdir-objects
26         case `automake --version | head -n 1` in
27                 *" 1.9"*);;
28                 *" 1.10"*);;
29                 *" 1.11"*);;
30                 # don't use parallel test harness in 1.12 and up
31                 *) echo serial-tests;;
32         esac
33 ]))
34 m4_ifdef([AM_SILENT_RULES], [AM_SILENT_RULES])
35 AC_CONFIG_MACRO_DIR([m4/config])
36 AC_CONFIG_HEADERS([config.h])
37 AC_DEFINE([CONFIG_H_INCLUDED], [], [defined if config.h included])
38 PKG_PROG_PKG_CONFIG
39
40 m4_include(m4/macros/split-package-version.m4)
41 SPLIT_PACKAGE_VERSION
42
43 # =================================
44 #  check --enable-xxx & --with-xxx
45 # =================================
46
47 m4_include(m4/macros/with.m4)
48
49 ARG_WITH_SUBST([random-device],      [/dev/random], [set the device to read real random data from])
50 ARG_WITH_SUBST([urandom-device],     [/dev/urandom], [set the device to read pseudo random data from])
51 ARG_WITH_SUBST([strongswan-conf],    [${sysconfdir}/strongswan.conf], [set the strongswan.conf file location])
52 ARG_WITH_SUBST([resolv-conf],        [${sysconfdir}/resolv.conf], [set the file to use in DNS handler plugin])
53 ARG_WITH_SUBST([piddir],             [/var/run], [set path for PID and UNIX socket files])
54 ARG_WITH_SUBST([ipsecdir],           [${libexecdir%/}/ipsec], [set installation path for ipsec tools])
55 ARG_WITH_SUBST([ipseclibdir],        [${libdir%/}/ipsec], [set installation path for ipsec libraries])
56 ARG_WITH_SUBST([plugindir],          [${ipseclibdir%/}/plugins], [set the installation path of plugins])
57 ARG_WITH_SUBST([imcvdir],            [${ipseclibdir%/}/imcvs], [set the installation path of IMC and IMV dynamic librariers])
58 ARG_WITH_SUBST([nm-ca-dir],          [/usr/share/ca-certificates], [directory the NM backend uses to look up trusted root certificates])
59 ARG_WITH_SUBST([swanctldir],         [${sysconfdir}/swanctl], [base directory for swanctl configuration files and credentials])
60 ARG_WITH_SUBST([linux-headers],      [\${top_srcdir}/src/include], [set directory of linux header files to use])
61 ARG_WITH_SUBST([routing-table],      [220], [set routing table to use for IPsec routes])
62 ARG_WITH_SUBST([routing-table-prio], [220], [set priority for IPsec routing table])
63 ARG_WITH_SUBST([ipsec-script],       [ipsec], [change the name of the ipsec script])
64 ARG_WITH_SUBST([fips-mode],          [0], [set openssl FIPS mode: disabled(0), enabled(1), Suite B enabled(2)])
65 ARG_WITH_SET([capabilities],         [no], [set capability dropping library. Currently supported values are "libcap" and "native"])
66 ARG_WITH_SET([mpz_powm_sec],         [yes], [use the more side-channel resistant mpz_powm_sec in libgmp, if available])
67 ARG_WITH_SET([dev-headers],          [no], [install strongSwan development headers to directory.])
68 ARG_WITH_SET([printf-hooks],         [auto], [force the use of a specific printf hook implementation (auto, builtin, glibc, vstr).])
69 ARG_WITH_SET([rubygemdir],           ["gem environment gemdir"], [path to install ruby gems to])
70 ARG_WITH_SET([pythoneggdir],         ["main site-packages directory"], [path to install python eggs to to])
71
72 if test -n "$PKG_CONFIG"; then
73         systemdsystemunitdir_default=$($PKG_CONFIG --variable=systemdsystemunitdir systemd)
74 fi
75 ARG_WITH_SET([systemdsystemunitdir], [$systemdsystemunitdir_default], [directory for systemd service files])
76 AC_SUBST(systemdsystemunitdir)
77
78 AC_ARG_WITH(
79         [user],
80         AS_HELP_STRING([--with-user=user],[change user of the daemons to "user" after startup (default is "root").]),
81         [AC_DEFINE_UNQUOTED([IPSEC_USER], "$withval", [username to run daemon with])
82          AC_SUBST(ipsecuser, "$withval")],
83         [AC_SUBST(ipsecuser, "root")]
84 )
85
86 AC_ARG_WITH(
87         [group],
88         AS_HELP_STRING([--with-group=group],[change group of the daemons to "group" after startup (default is "root").]),
89         [AC_DEFINE_UNQUOTED(IPSEC_GROUP, "$withval", [groupname to run daemon with])
90          AC_SUBST(ipsecgroup, "$withval")],
91         [AC_SUBST(ipsecgroup, "root")]
92 )
93
94 AC_ARG_WITH(
95         [charon-udp-port],
96         AS_HELP_STRING([--with-charon-udp-port=port],[UDP port used by charon locally (default 500). Set to 0 to allocate randomly.]),
97         [AC_DEFINE_UNQUOTED(CHARON_UDP_PORT, [$withval], [UDP port used by charon locally])
98          AC_SUBST(charon_udp_port, [$withval])],
99         [AC_SUBST(charon_udp_port, 500)]
100 )
101
102 AC_ARG_WITH(
103         [charon-natt-port],
104         AS_HELP_STRING([--with-charon-natt-port=port],[UDP port used by charon locally in case a NAT is detected (must be different from charon-udp-port, default 4500). Set to 0 to allocate randomly.]),
105         [AC_DEFINE_UNQUOTED(CHARON_NATT_PORT, [$withval], [UDP post used by charon locally in case a NAT is detected])
106          AC_SUBST(charon_natt_port, [$withval])],
107         [AC_SUBST(charon_natt_port, 4500)]
108 )
109
110 AC_MSG_CHECKING([configured UDP ports ($charon_udp_port, $charon_natt_port)])
111 if test x$charon_udp_port != x0 -a x$charon_udp_port = x$charon_natt_port; then
112         AC_MSG_ERROR(the ports have to be different)
113 else
114         AC_MSG_RESULT(ok)
115 fi
116
117 # convert script name to uppercase
118 AC_SUBST(ipsec_script_upper, [`echo -n "$ipsec_script" | tr a-z A-Z`])
119
120 m4_include(m4/macros/enable-disable.m4)
121
122 # crypto plugins
123 ARG_DISBL_SET([aes],            [disable AES software implementation plugin.])
124 ARG_ENABL_SET([af-alg],         [enable AF_ALG crypto interface to Linux Crypto API.])
125 ARG_ENABL_SET([bliss],          [enable BLISS software implementation plugin.])
126 ARG_ENABL_SET([blowfish],       [enable Blowfish software implementation plugin.])
127 ARG_ENABL_SET([ccm],            [enables the CCM AEAD wrapper crypto plugin.])
128 ARG_ENABL_SET([chapoly],        [enables the ChaCha20/Poly1305 AEAD plugin.])
129 ARG_DISBL_SET([cmac],           [disable CMAC crypto implementation plugin.])
130 ARG_ENABL_SET([ctr],            [enables the Counter Mode wrapper crypto plugin.])
131 ARG_DISBL_SET([des],            [disable DES/3DES software implementation plugin.])
132 ARG_DISBL_SET([fips-prf],       [disable FIPS PRF software implementation plugin.])
133 ARG_ENABL_SET([gcm],            [enables the GCM AEAD wrapper crypto plugin.])
134 ARG_ENABL_SET([gcrypt],         [enables the libgcrypt plugin.])
135 ARG_DISBL_SET([gmp],            [disable GNU MP (libgmp) based crypto implementation plugin.])
136 ARG_DISBL_SET([hmac],           [disable HMAC crypto implementation plugin.])
137 ARG_ENABL_SET([md4],            [enable MD4 software implementation plugin.])
138 ARG_DISBL_SET([md5],            [disable MD5 software implementation plugin.])
139 ARG_ENABL_SET([newhope],        [enable New Hope crypto plugin.])
140 ARG_DISBL_SET([nonce],          [disable nonce generation plugin.])
141 ARG_ENABL_SET([ntru],           [enables the NTRU crypto plugin.])
142 ARG_ENABL_SET([openssl],        [enables the OpenSSL crypto plugin.])
143 ARG_ENABL_SET([padlock],        [enables VIA Padlock crypto plugin.])
144 ARG_DISBL_SET([random],         [disable RNG implementation on top of /dev/(u)random.])
145 ARG_DISBL_SET([rc2],            [disable RC2 software implementation plugin.])
146 ARG_ENABL_SET([rdrand],         [enable Intel RDRAND random generator plugin.])
147 ARG_ENABL_SET([aesni],          [enable Intel AES-NI crypto plugin.])
148 ARG_DISBL_SET([sha1],           [disable SHA1 software implementation plugin.])
149 ARG_DISBL_SET([sha2],           [disable SHA256/SHA384/SHA512 software implementation plugin.])
150 ARG_ENABL_SET([sha3],           [enable SHA3_224/SHA3_256/SHA3_384/SHA3_512 software implementation plugin.])
151 ARG_DISBL_SET([xcbc],           [disable xcbc crypto implementation plugin.])
152 # encoding/decoding plugins
153 ARG_DISBL_SET([dnskey],         [disable DNS RR key decoding plugin.])
154 ARG_DISBL_SET([pem],            [disable PEM decoding plugin.])
155 ARG_DISBL_SET([pgp],            [disable PGP key decoding plugin.])
156 ARG_DISBL_SET([pkcs1],          [disable PKCS1 key decoding plugin.])
157 ARG_DISBL_SET([pkcs7],          [disable PKCS7 container support plugin.])
158 ARG_DISBL_SET([pkcs8],          [disable PKCS8 private key decoding plugin.])
159 ARG_DISBL_SET([pkcs12],         [disable PKCS12 container support plugin.])
160 ARG_DISBL_SET([pubkey],         [disable RAW public key support plugin.])
161 ARG_DISBL_SET([sshkey],         [disable SSH key decoding plugin.])
162 ARG_DISBL_SET([x509],           [disable X509 certificate implementation plugin.])
163 # fetcher/resolver plugins
164 ARG_ENABL_SET([curl],           [enable CURL fetcher plugin to fetch files via libcurl. Requires libcurl.])
165 ARG_ENABL_SET([files],          [enable simple file:// URI fetcher.])
166 ARG_ENABL_SET([ldap],           [enable LDAP fetching plugin to fetch files via libldap. Requires openLDAP.])
167 ARG_ENABL_SET([soup],           [enable soup fetcher plugin to fetch from HTTP via libsoup. Requires libsoup.])
168 ARG_ENABL_SET([unbound],        [enable UNBOUND resolver plugin to perform DNS queries via libunbound. Requires libldns and libunbound.])
169 ARG_ENABL_SET([winhttp],        [enable WinHTTP based HTTP/HTTPS fetching plugin.])
170 # database plugins
171 ARG_ENABL_SET([mysql],          [enable MySQL database support. Requires libmysqlclient_r.])
172 ARG_ENABL_SET([sqlite],         [enable SQLite database support. Requires libsqlite3.])
173 # authentication/credential plugins
174 ARG_ENABL_SET([addrblock],      [enables RFC 3779 address block constraint support.])
175 ARG_ENABL_SET([acert],          [enable X509 attribute certificate checking plugin.])
176 ARG_ENABL_SET([agent],          [enables the ssh-agent signing plugin.])
177 ARG_DISBL_SET([constraints],    [disable advanced X509 constraint checking plugin.])
178 ARG_ENABL_SET([coupling],       [enable IKEv2 plugin to couple peer certificates permanently to authentication.])
179 ARG_ENABL_SET([dnscert],        [enable DNSCERT authentication plugin.])
180 ARG_ENABL_SET([eap-sim],        [enable SIM authentication module for EAP.])
181 ARG_ENABL_SET([eap-sim-file],   [enable EAP-SIM backend based on a triplet file.])
182 ARG_ENABL_SET([eap-sim-pcsc],   [enable EAP-SIM backend based on a smartcard reader. Requires libpcsclite.])
183 ARG_ENABL_SET([eap-aka],        [enable EAP AKA authentication module.])
184 ARG_ENABL_SET([eap-aka-3gpp2],  [enable EAP AKA backend implementing 3GPP2 algorithms in software. Requires libgmp.])
185 ARG_ENABL_SET([eap-simaka-sql], [enable EAP-SIM/AKA backend based on a triplet/quintuplet SQL database.])
186 ARG_ENABL_SET([eap-simaka-pseudonym], [enable EAP-SIM/AKA pseudonym storage plugin.])
187 ARG_ENABL_SET([eap-simaka-reauth],    [enable EAP-SIM/AKA reauthentication data storage plugin.])
188 ARG_ENABL_SET([eap-identity],   [enable EAP module providing EAP-Identity helper.])
189 ARG_ENABL_SET([eap-md5],        [enable EAP MD5 (CHAP) authentication module.])
190 ARG_ENABL_SET([eap-gtc],        [enable EAP GTC authentication module.])
191 ARG_ENABL_SET([eap-mschapv2],   [enable EAP MS-CHAPv2 authentication module.])
192 ARG_ENABL_SET([eap-tls],        [enable EAP TLS authentication module.])
193 ARG_ENABL_SET([eap-ttls],       [enable EAP TTLS authentication module.])
194 ARG_ENABL_SET([eap-peap],       [enable EAP PEAP authentication module.])
195 ARG_ENABL_SET([eap-tnc],        [enable EAP TNC trusted network connect module.])
196 ARG_ENABL_SET([eap-dynamic],    [enable dynamic EAP proxy module.])
197 ARG_ENABL_SET([eap-radius],     [enable RADIUS proxy authentication module.])
198 ARG_ENABL_SET([ext-auth],       [enable plugin calling an external authorization script.])
199 ARG_ENABL_SET([ipseckey],       [enable IPSECKEY authentication plugin.])
200 ARG_ENABL_SET([keychain],       [enables OS X Keychain Services credential set.])
201 ARG_ENABL_SET([pkcs11],         [enables the PKCS11 token support plugin.])
202 ARG_DISBL_SET([revocation],     [disable X509 CRL/OCSP revocation check plugin.])
203 ARG_ENABL_SET([whitelist],      [enable peer identity whitelisting plugin.])
204 ARG_DISBL_SET([xauth-generic],  [disable generic XAuth backend.])
205 ARG_ENABL_SET([xauth-eap],      [enable XAuth backend using EAP methods to verify passwords.])
206 ARG_ENABL_SET([xauth-pam],      [enable XAuth backend using PAM to verify passwords.])
207 ARG_ENABL_SET([xauth-noauth],   [enable XAuth pseudo-backend that does not actually verify or even request any credentials.])
208 # kernel interfaces / sockets
209 ARG_DISBL_SET([kernel-netlink], [disable the netlink kernel interface.])
210 ARG_ENABL_SET([kernel-pfkey],   [enable the PF_KEY kernel interface.])
211 ARG_ENABL_SET([kernel-pfroute], [enable the PF_ROUTE kernel interface.])
212 ARG_ENABL_SET([kernel-iph],     [enable the Windows IP Helper based networking backend.])
213 ARG_ENABL_SET([kernel-libipsec],[enable the libipsec kernel interface.])
214 ARG_ENABL_SET([kernel-wfp],     [enable the Windows Filtering Platform IPsec backend.])
215 ARG_DISBL_SET([socket-default], [disable default socket implementation for charon.])
216 ARG_ENABL_SET([socket-dynamic], [enable dynamic socket implementation for charon])
217 ARG_ENABL_SET([socket-win],     [enable Winsock2 based socket implementation for charon])
218 # configuration/control plugins
219 ARG_DISBL_SET([stroke],         [disable charons stroke configuration backend.])
220 ARG_ENABL_SET([smp],            [enable SMP configuration and control interface. Requires libxml.])
221 ARG_ENABL_SET([sql],            [enable SQL database configuration backend.])
222 ARG_ENABL_SET([uci],            [enable OpenWRT UCI configuration plugin.])
223 ARG_DISBL_SET([vici],           [disable strongSwan IKE generic IPC interface plugin.])
224 # attribute provider/consumer plugins
225 ARG_ENABL_SET([android-dns],    [enable Android specific DNS handler.])
226 ARG_DISBL_SET([attr],           [disable strongswan.conf based configuration attribute plugin.])
227 ARG_ENABL_SET([attr-sql],       [enable SQL based configuration attribute plugin.])
228 ARG_ENABL_SET([dhcp],           [enable DHCP based attribute provider plugin.])
229 ARG_ENABL_SET([osx-attr],       [enable OS X SystemConfiguration attribute handler.])
230 ARG_ENABL_SET([p-cscf],         [enable plugin to request P-CSCF server addresses from an ePDG.])
231 ARG_DISBL_SET([resolve],        [disable resolve DNS handler plugin.])
232 ARG_ENABL_SET([unity],          [enables Cisco Unity extension plugin.])
233 # TNC modules/plugins
234 ARG_ENABL_SET([imc-test],       [enable IMC test module.])
235 ARG_ENABL_SET([imv-test],       [enable IMV test module.])
236 ARG_ENABL_SET([imc-scanner],    [enable IMC port scanner module.])
237 ARG_ENABL_SET([imv-scanner],    [enable IMV port scanner module.])
238 ARG_ENABL_SET([imc-os],         [enable IMC operating system module.])
239 ARG_ENABL_SET([imv-os],         [enable IMV operating system module.])
240 ARG_ENABL_SET([imc-attestation],[enable IMC attestation module.])
241 ARG_ENABL_SET([imv-attestation],[enable IMV attestation module.])
242 ARG_ENABL_SET([imc-swid],       [enable IMC swid module.])
243 ARG_ENABL_SET([imv-swid],       [enable IMV swid module.])
244 ARG_ENABL_SET([imc-hcd],        [enable IMC hcd module.])
245 ARG_ENABL_SET([imv-hcd],        [enable IMV hcd module.])
246 ARG_ENABL_SET([tnc-ifmap],      [enable TNC IF-MAP module. Requires libxml])
247 ARG_ENABL_SET([tnc-imc],        [enable TNC IMC module.])
248 ARG_ENABL_SET([tnc-imv],        [enable TNC IMV module.])
249 ARG_ENABL_SET([tnc-pdp],        [enable TNC policy decision point module.])
250 ARG_ENABL_SET([tnccs-11],       [enable TNCCS 1.1 protocol module. Requires libxml])
251 ARG_ENABL_SET([tnccs-20],       [enable TNCCS 2.0 protocol module.])
252 ARG_ENABL_SET([tnccs-dynamic],  [enable dynamic TNCCS protocol discovery module.])
253 # misc plugins
254 ARG_ENABL_SET([android-log],    [enable Android specific logger plugin.])
255 ARG_ENABL_SET([certexpire],     [enable CSV export of expiration dates of used certificates.])
256 ARG_ENABL_SET([connmark],       [enable connmark plugin using conntrack based marks to select return path SA.])
257 ARG_ENABL_SET([forecast],       [enable forecast plugin forwarding broadcast/multicast messages.])
258 ARG_ENABL_SET([duplicheck],     [advanced duplicate checking plugin using liveness checks.])
259 ARG_ENABL_SET([error-notify],   [enable error notification plugin.])
260 ARG_ENABL_SET([farp],           [enable ARP faking plugin that responds to ARP requests to peers virtual IP])
261 ARG_ENABL_SET([ha],             [enable high availability cluster plugin.])
262 ARG_ENABL_SET([led],            [enable plugin to control LEDs on IKEv2 activity using the Linux kernel LED subsystem.])
263 ARG_ENABL_SET([load-tester],    [enable load testing plugin for IKEv2 daemon.])
264 ARG_ENABL_SET([lookip],         [enable fast virtual IP lookup and notification plugin.])
265 ARG_ENABL_SET([maemo],          [enable Maemo specific plugin.])
266 ARG_ENABL_SET([radattr],        [enable plugin to inject and process custom RADIUS attributes as IKEv2 client.])
267 ARG_ENABL_SET([systime-fix],    [enable plugin to handle cert lifetimes with invalid system time gracefully.])
268 ARG_ENABL_SET([test-vectors],   [enable plugin providing crypto test vectors.])
269 ARG_DISBL_SET([updown],         [disable updown firewall script plugin.])
270 # programs/components
271 ARG_ENABL_SET([aikgen],         [enable AIK generator for TPM 1.2.])
272 ARG_ENABL_SET([aikpub2],        [enable AIK extractor for TPM 2.0.])
273 ARG_DISBL_SET([charon],         [disable the IKEv1/IKEv2 keying daemon charon.])
274 ARG_ENABL_SET([cmd],            [enable the command line IKE client charon-cmd.])
275 ARG_ENABL_SET([conftest],       [enforce Suite B conformance test framework.])
276 ARG_ENABL_SET([dumm],           [enable the DUMM UML test framework.])
277 ARG_ENABL_SET([fast],           [enable libfast (FastCGI Application Server w/ templates.])
278 ARG_ENABL_SET([libipsec],       [enable user space IPsec implementation.])
279 ARG_ENABL_SET([manager],        [enable web management console (proof of concept).])
280 ARG_ENABL_SET([medcli],         [enable mediation client configuration database plugin.])
281 ARG_ENABL_SET([medsrv],         [enable mediation server web frontend and daemon plugin.])
282 ARG_ENABL_SET([nm],             [enable NetworkManager backend.])
283 ARG_DISBL_SET([pki],            [disable pki certificate utility.])
284 ARG_DISBL_SET([scepclient],     [disable SCEP client tool.])
285 ARG_DISBL_SET([scripts],        [disable additional utilities (found in directory scripts).])
286 ARG_ENABL_SET([svc],            [enable charon Windows service.])
287 ARG_ENABL_SET([systemd],        [enable systemd specific IKE daemon charon-systemd.])
288 ARG_DISBL_SET([swanctl],        [disable swanctl configuration and control tool.])
289 ARG_ENABL_SET([tkm],            [enable Trusted Key Manager support.])
290 # optional features
291 ARG_ENABL_SET([bfd-backtraces], [use binutils libbfd to resolve backtraces for memory leaks and segfaults.])
292 ARG_ENABL_SET([dbghelp-backtraces],[use dbghlp.dll on Windows to create and print backtraces for memory leaks and segfaults.])
293 ARG_DISBL_SET([ikev1],          [disable IKEv1 protocol support in charon.])
294 ARG_DISBL_SET([ikev2],          [disable IKEv2 protocol support in charon.])
295 ARG_ENABL_SET([integrity-test], [enable integrity testing of libstrongswan and plugins.])
296 ARG_DISBL_SET([load-warning],   [disable the charon plugin load option warning in starter.])
297 ARG_ENABL_SET([mediation],      [enable IKEv2 Mediation Extension.])
298 ARG_ENABL_SET([unwind-backtraces],[use libunwind to create backtraces for memory leaks and segfaults.])
299 ARG_ENABL_SET([ruby-gems],      [enable build of provided ruby gems.])
300 ARG_ENABL_SET([ruby-gems-install],[enable installation of provided ruby gems.])
301 ARG_ENABL_SET([python-eggs],    [enable build of provided python eggs.])
302 ARG_ENABL_SET([python-eggs-install],[enable installation of provided python eggs.])
303 ARG_ENABL_SET([perl-cpan],      [enable build of provided perl CPAN module.])
304 ARG_ENABL_SET([perl-cpan-install],[enable installation of provided CPAN module.])
305 ARG_ENABL_SET([tss-trousers],   [enable the use of the TrouSerS Trusted Software Stack])
306 ARG_ENABL_SET([tss-tss2],       [enable the use of the TSS 2.0 Trusted Software Stack])
307
308 # compile options
309 ARG_ENABL_SET([coverage],       [enable lcov coverage report generation.])
310 ARG_ENABL_SET([leak-detective], [enable malloc hooks to find memory leaks.])
311 ARG_ENABL_SET([lock-profiler],  [enable lock/mutex profiling code.])
312 ARG_ENABL_SET([log-thread-ids], [use thread ID, if available, instead of an incremented value starting from 1, to identify threads.])
313 ARG_ENABL_SET([monolithic],     [build monolithic version of libstrongswan that includes all enabled plugins. Similarly, the plugins of charon are assembled in libcharon.])
314
315 # ===================================
316 #  option to disable default options
317 # ===================================
318
319 ARG_DISBL_SET([defaults],       [disable all default plugins (they can be enabled with their respective --enable options)])
320
321 if test x$defaults = xfalse; then
322         for option in $enabled_by_default; do
323                 eval test x\${${option}_given} = xtrue && continue
324                 eval $option=false
325         done
326 fi
327
328 # ==============================
329 #  option to enable all options
330 # ==============================
331
332 ARG_ENABL_SET([all],            [enable all plugins and features (they can be disabled with their respective --disable options). Mainly for testing.])
333
334 if test x$all_given = xtrue; then
335         for option in $disabled_by_default; do
336                 eval test x\${${option}_given} = xtrue && continue
337                 eval $option=true
338         done
339 fi
340
341 # ===========================
342 #  set up compiler and flags
343 # ===========================
344
345 if test -z "$CFLAGS"; then
346         CFLAGS="-g -O2 -Wall -Wno-format -Wno-format-security -Wno-pointer-sign"
347 fi
348 AC_PROG_CC
349 AM_PROG_CC_C_O
350
351 AC_LIB_PREFIX
352 AC_C_BIGENDIAN
353
354 # =========================
355 #  check required programs
356 # =========================
357
358 LT_INIT
359 AC_PROG_INSTALL
360 AC_PROG_EGREP
361 AC_PROG_AWK
362 AC_PROG_LEX
363 AC_PROG_YACC
364 AM_PATH_PYTHON(,,[:])
365 AC_PATH_PROG([PERL], [perl], [], [$PATH:/bin:/usr/bin:/usr/local/bin])
366 AC_PATH_PROG([GPERF], [gperf], [], [$PATH:/bin:/usr/bin:/usr/local/bin])
367
368 # because gperf is not needed by end-users we just report it but do not abort on failure
369 AC_MSG_CHECKING([gperf version >= 3.0.0])
370 if test -x "$GPERF"; then
371         if test "`$GPERF --version | $AWK -F' ' '/^GNU gperf/ { print $3 }' | $AWK -F. '{ print $1 }'`" -ge "3"; then
372                 AC_MSG_RESULT([yes])
373         else
374                 AC_MSG_RESULT([no])
375         fi
376 else
377         AC_MSG_RESULT([not found])
378 fi
379
380 # ========================
381 #  dependency calculation
382 # ========================
383
384 if test x$xauth_generic_given = xfalse -a x$ikev1 = xfalse; then
385         xauth_generic=false;
386 fi
387
388 if test x$kernel_libipsec = xtrue; then
389         libipsec=true;
390 fi
391
392 if test x$eap_aka_3gpp2 = xtrue; then
393         gmp=true;
394 fi
395
396 if test x$eap_aka = xtrue; then
397         fips_prf=true;
398         simaka=true;
399 fi
400
401 if test x$eap_sim = xtrue; then
402         fips_prf=true;
403         simaka=true;
404 fi
405
406 if test x$eap_radius = xtrue -o x$radattr = xtrue -o x$tnc_pdp = xtrue; then
407         radius=true;
408 fi
409
410 if test x$tnc_imc = xtrue -o x$tnc_imv = xtrue -o x$tnccs_11 = xtrue -o x$tnccs_11 = xtrue -o x$tnccs_dynamic = xtrue -o x$eap_tnc = xtrue; then
411         tnc_tnccs=true;
412 fi
413
414 if test x$eap_tls = xtrue -o x$eap_ttls = xtrue -o x$eap_peap = xtrue -o x$tnc_tnccs = xtrue; then
415         tls=true;
416 fi
417
418 if test x$imc_test = xtrue -o x$imv_test = xtrue -o x$imc_scanner = xtrue -o x$imv_scanner = xtrue -o x$imc_os = xtrue -o x$imv_os = xtrue -o x$imc_attestation = xtrue -o x$imv_attestation = xtrue -o x$imc_swid = xtrue -o x$imv_swid = xtrue -o x$imc_hcd = xtrue -o x$imv_hcd = xtrue; then
419         imcv=true;
420 fi
421
422 if test x$fips_prf = xtrue; then
423         if test x$openssl = xfalse; then
424                 sha1=true;
425         fi
426 fi
427
428 if test x$swanctl = xtrue; then
429         vici=true
430 fi
431
432 if test x$smp = xtrue -o x$tnccs_11 = xtrue -o x$tnc_ifmap = xtrue; then
433         xml=true
434 fi
435
436 if test x$manager = xtrue; then
437         fast=true
438 fi
439
440 if test x$medsrv = xtrue; then
441         mediation=true
442         fast=true
443 fi
444
445 if test x$medcli = xtrue; then
446         mediation=true
447 fi
448
449 if test x$ruby_gems_install = xtrue; then
450         ruby_gems=true
451 fi
452
453 if test x$python_eggs_install = xtrue; then
454         python_eggs=true
455 fi
456
457 if test x$perl_cpan_install = xtrue; then
458         perl_cpan=true
459 fi
460
461 if test x$aikgen = xtrue; then
462         tss_trousers=true
463 fi
464
465 if test x$aikpub2 = xtrue; then
466         tss_tss2=true
467 fi
468
469 # ===========================================
470 #  check required libraries and header files
471 # ===========================================
472
473 AC_HEADER_STDBOOL
474 AC_FUNC_ALLOCA
475 AC_FUNC_STRERROR_R
476
477 #  libraries needed on some platforms but not on others
478 # ------------------------------------------------------
479 saved_LIBS=$LIBS
480
481 # FreeBSD and Mac OS X have dlopen integrated in libc, Linux needs libdl
482 LIBS=""
483 AC_SEARCH_LIBS(dlopen, dl, [DLLIB=$LIBS])
484 AC_SUBST(DLLIB)
485
486 # glibc's backtrace() can be replicated on FreeBSD with libexecinfo
487 LIBS=""
488 AC_SEARCH_LIBS(backtrace, execinfo, [BTLIB=$LIBS])
489 AC_CHECK_FUNCS(backtrace)
490 AC_SUBST(BTLIB)
491
492 # OpenSolaris needs libsocket and libnsl for socket()
493 LIBS=""
494 AC_SEARCH_LIBS(socket, socket, [SOCKLIB=$LIBS],
495         [AC_CHECK_LIB(nsl, socket, [SOCKLIB="-lsocket -lnsl"], [], [-lsocket])]
496 )
497 AC_SUBST(SOCKLIB)
498
499 # Android has pthread_* functions in bionic (libc), others need libpthread
500 LIBS=$DLLIB
501 AC_SEARCH_LIBS(pthread_create, pthread, [PTHREADLIB=$LIBS])
502 AC_SUBST(PTHREADLIB)
503
504 # uClibc requires explicit -latomic for __atomic_* operations
505 LIBS=""
506 AC_SEARCH_LIBS(__atomic_load, atomic, [ATOMICLIB=$LIBS])
507 AC_SUBST(ATOMICLIB)
508
509 LIBS=$saved_LIBS
510 # ------------------------------------------------------
511
512 AC_MSG_CHECKING(for dladdr)
513 AC_COMPILE_IFELSE(
514         [AC_LANG_PROGRAM(
515                 [[#define _GNU_SOURCE
516                   #include <dlfcn.h>]],
517                 [[Dl_info* info = 0;
518                   dladdr(0, info);]])],
519         [AC_MSG_RESULT([yes]); AC_DEFINE([HAVE_DLADDR], [], [have dladdr()])],
520         [AC_MSG_RESULT([no])]
521 )
522
523 # check if pthread_condattr_setclock(CLOCK_MONOTONIC) is supported
524 saved_LIBS=$LIBS
525 LIBS=$PTHREADLIB
526 AC_MSG_CHECKING([for pthread_condattr_setclock(CLOCK_MONOTONIC)])
527 AC_RUN_IFELSE(
528         [AC_LANG_SOURCE(
529                 [[#include <pthread.h>
530                   int main() { pthread_condattr_t attr;
531                         pthread_condattr_init(&attr);
532                         return pthread_condattr_setclock(&attr, CLOCK_MONOTONIC);}]])],
533         [AC_MSG_RESULT([yes]);
534          AC_DEFINE([HAVE_CONDATTR_CLOCK_MONOTONIC], [],
535                            [pthread_condattr_setclock supports CLOCK_MONOTONIC])],
536         [AC_MSG_RESULT([no])],
537         # Check existence of pthread_condattr_setclock if cross-compiling
538         [AC_MSG_RESULT([unknown]);
539          AC_CHECK_FUNCS(pthread_condattr_setclock,
540                 [AC_DEFINE([HAVE_CONDATTR_CLOCK_MONOTONIC], [],
541                                    [have pthread_condattr_setclock()])]
542         )]
543 )
544 # check if we actually are able to configure attributes on cond vars
545 AC_CHECK_FUNCS(pthread_condattr_init)
546 # instead of pthread_condattr_setclock Android has this function
547 AC_CHECK_FUNCS(pthread_cond_timedwait_monotonic)
548 # check if we can cancel threads
549 AC_CHECK_FUNCS(pthread_cancel)
550 # check if native rwlocks are available
551 AC_CHECK_FUNCS(pthread_rwlock_init)
552 # check if pthread spinlocks are available
553 AC_CHECK_FUNCS(pthread_spin_init)
554 # check if we have POSIX semaphore functions, including timed-wait
555 AC_CHECK_FUNCS(sem_timedwait)
556 LIBS=$saved_LIBS
557
558 AC_CHECK_FUNC(
559         [gettid],
560         [AC_DEFINE([HAVE_GETTID], [], [have gettid()])],
561         [AC_MSG_CHECKING([for SYS_gettid])
562          AC_COMPILE_IFELSE(
563                 [AC_LANG_PROGRAM(
564                         [[#define _GNU_SOURCE
565                           #include <unistd.h>
566                           #include <sys/syscall.h>]],
567                         [[int main() {
568                           return syscall(SYS_gettid);}]])],
569                 [AC_MSG_RESULT([yes]);
570                  AC_DEFINE([HAVE_GETTID], [], [have gettid()])
571                  AC_DEFINE([HAVE_SYS_GETTID], [], [have syscall(SYS_gettid)])],
572                 [AC_MSG_RESULT([no])]
573         )]
574 )
575
576 AC_CHECK_FUNC(
577         [qsort_r],
578         [
579                 AC_DEFINE([HAVE_QSORT_R], [], [have qsort_r()])
580                 # set -Werror so that we get an error for "argument ... has
581                 # incompatible pointer type" warnings
582                 save_CFLAGS="$CFLAGS"
583                 CFLAGS="$CFLAGS -Werror -Wno-unused-parameter"
584                 AC_MSG_CHECKING([for GNU-style qsort_r])
585                 AC_COMPILE_IFELSE(
586                         [AC_LANG_PROGRAM(
587                                 [[#define _GNU_SOURCE
588                                   #include <stdlib.h>
589                                   int cmp (const void *a, const void *b, void *x) { return 0; }]],
590                                 [[int arr[] = { 0, 1 };
591                                   qsort_r(arr, 2, sizeof(int), cmp, arr);]])],
592                 [AC_MSG_RESULT([yes]);
593                  AC_DEFINE([HAVE_QSORT_R_GNU], [], [have GNU-style qsort_r()])],
594                 [
595                         AC_MSG_RESULT([no]);
596                         AC_MSG_CHECKING([for BSD-style qsort_r])
597                         AC_COMPILE_IFELSE(
598                                 [AC_LANG_PROGRAM(
599                                         [[#include <stdlib.h>
600                                           int cmp (void *x, const void *a, const void *b) { return 0; }]],
601                                         [[int arr[] = { 0, 1 };
602                                           qsort_r(arr, 2, sizeof(int), arr, cmp);]])],
603                         [AC_MSG_RESULT([yes]);
604                          AC_DEFINE([HAVE_QSORT_R_BSD], [], [have BSD-style qsort_r()])],
605                         [AC_MSG_RESULT([no]);
606                          AC_MSG_FAILURE([qsort_r has unknown semantics])])
607                 ])
608                 CFLAGS="$save_CFLAGS"
609         ]
610 )
611
612 AC_CHECK_FUNCS(prctl mallinfo getpass closefrom getpwnam_r getgrnam_r getpwuid_r)
613 AC_CHECK_FUNCS(fmemopen funopen mmap memrchr setlinebuf strptime dirfd sigwaitinfo)
614
615 AC_CHECK_FUNC([syslog], [
616         AC_DEFINE([HAVE_SYSLOG], [], [have syslog(3) and friends])
617         syslog=true
618 ])
619 AM_CONDITIONAL(USE_SYSLOG, [test "x$syslog" = xtrue])
620
621 AC_CHECK_HEADERS(sys/sockio.h sys/syscall.h sys/param.h glob.h net/if_tun.h)
622 AC_CHECK_HEADERS(net/pfkeyv2.h netipsec/ipsec.h netinet6/ipsec.h linux/udp.h)
623 AC_CHECK_HEADERS([netinet/ip6.h linux/fib_rules.h], [], [],
624 [
625         #include <sys/types.h>
626         #include <netinet/in.h>
627 ])
628
629 AC_CHECK_MEMBERS([struct sockaddr.sa_len], [], [],
630 [
631         #include <sys/types.h>
632         #include <sys/socket.h>
633 ])
634
635 AC_CHECK_MEMBERS([struct sadb_x_policy.sadb_x_policy_priority], [], [],
636 [
637         #include <sys/types.h>
638         #ifdef HAVE_NET_PFKEYV2_H
639         #include <net/pfkeyv2.h>
640         #else
641         #include <stdint.h>
642         #include <linux/pfkeyv2.h>
643         #endif
644 ])
645
646 AC_MSG_CHECKING([for in6addr_any])
647 AC_COMPILE_IFELSE(
648         [AC_LANG_PROGRAM(
649                 [[#include <sys/types.h>
650                   #include <sys/socket.h>
651                   #include <netinet/in.h>]],
652                 [[struct in6_addr in6 __attribute__((unused));
653                   in6 = in6addr_any;]])],
654         [AC_MSG_RESULT([yes]);
655          AC_DEFINE([HAVE_IN6ADDR_ANY], [], [have struct in6_addr in6addr_any])],
656         [AC_MSG_RESULT([no])]
657 )
658
659 AC_MSG_CHECKING([for in6_pktinfo])
660 AC_COMPILE_IFELSE(
661         [AC_LANG_PROGRAM(
662                 [[#define _GNU_SOURCE
663                   #include <sys/types.h>
664                   #include <sys/socket.h>
665                   #include <netinet/in.h>]],
666                 [[struct in6_pktinfo pi;
667                   if (pi.ipi6_ifindex)
668                   {
669                     return 0;
670                   }]])],
671         [AC_MSG_RESULT([yes]);
672          AC_DEFINE([HAVE_IN6_PKTINFO], [], [have struct in6_pktinfo.ipi6_ifindex])],
673         [AC_MSG_RESULT([no])]
674 )
675
676 AC_MSG_CHECKING([for RTM_IFANNOUNCE])
677 AC_COMPILE_IFELSE(
678         [AC_LANG_PROGRAM(
679                 [[#include <sys/socket.h>
680                   #include <net/if.h>
681                   #include <net/route.h>]],
682                 [[return RTM_IFANNOUNCE;]])],
683         [AC_MSG_RESULT([yes]);
684          AC_DEFINE([HAVE_RTM_IFANNOUNCE], [], [have PF_ROUTE RTM_IFANNOUNCE defined])],
685         [AC_MSG_RESULT([no])]
686 )
687
688 AC_MSG_CHECKING([for IPSEC_MODE_BEET])
689 AC_COMPILE_IFELSE(
690         [AC_LANG_PROGRAM(
691                 [[#include <sys/types.h>
692                   #ifdef HAVE_NETIPSEC_IPSEC_H
693                   #include <netipsec/ipsec.h>
694                   #elif defined(HAVE_NETINET6_IPSEC_H)
695                   #include <netinet6/ipsec.h>
696                   #else
697                   #include <stdint.h>
698                   #include <linux/ipsec.h>
699                   #endif]],
700                 [[int mode = IPSEC_MODE_BEET;
701                   return mode;]])],
702         [AC_MSG_RESULT([yes]);
703          AC_DEFINE([HAVE_IPSEC_MODE_BEET], [], [have IPSEC_MODE_BEET defined])],
704         [AC_MSG_RESULT([no])]
705 )
706
707 AC_MSG_CHECKING([for IPSEC_DIR_FWD])
708 AC_COMPILE_IFELSE(
709         [AC_LANG_PROGRAM(
710                 [[#include <sys/types.h>
711                   #ifdef HAVE_NETIPSEC_IPSEC_H
712                   #include <netipsec/ipsec.h>
713                   #elif defined(HAVE_NETINET6_IPSEC_H)
714                   #include <netinet6/ipsec.h>
715                   #else
716                   #include <stdint.h>
717                   #include <linux/ipsec.h>
718                   #endif]],
719                 [[int dir = IPSEC_DIR_FWD;
720                   return dir;]])],
721         [AC_MSG_RESULT([yes]);
722          AC_DEFINE([HAVE_IPSEC_DIR_FWD], [], [have IPSEC_DIR_FWD defined])],
723         [AC_MSG_RESULT([no])]
724 )
725
726 AC_MSG_CHECKING([for RTA_TABLE])
727 AC_COMPILE_IFELSE(
728         [AC_LANG_PROGRAM(
729                 [[#include <sys/socket.h>
730                   #include <linux/netlink.h>
731                   #include <linux/rtnetlink.h>]],
732                 [[int rta_type = RTA_TABLE;
733                   return rta_type;]])],
734         [AC_MSG_RESULT([yes]);
735          AC_DEFINE([HAVE_RTA_TABLE], [], [have netlink RTA_TABLE defined])],
736         [AC_MSG_RESULT([no])]
737 )
738
739 AC_MSG_CHECKING([for __int128])
740 AC_COMPILE_IFELSE(
741         [AC_LANG_PROGRAM(
742                 [[#include <sys/types.h>]],
743                 [[__int128 x = 0;
744                   return x;]])],
745         [AC_MSG_RESULT([yes]);
746          AC_DEFINE([HAVE_INT128], [], [have __int128 type support])],
747         [AC_MSG_RESULT([no])]
748 )
749
750 AC_MSG_CHECKING([for GCC __sync operations])
751 AC_RUN_IFELSE([AC_LANG_SOURCE(
752         [[
753                         int main() {
754                         int ref = 1;
755                         __sync_fetch_and_add (&ref, 1);
756                         __sync_sub_and_fetch (&ref, 1);
757                         __sync_val_compare_and_swap(&ref, 1, 0);
758                         return ref;
759                 }
760         ]])],
761         [AC_MSG_RESULT([yes]);
762          AC_DEFINE([HAVE_GCC_SYNC_OPERATIONS], [],
763                    [have GCC __sync_* operations])],
764         [AC_MSG_RESULT([no])],
765         [AC_MSG_RESULT([no])]
766 )
767
768 case "$printf_hooks" in
769 auto|builtin|glibc|vstr)
770         ;;
771 *)
772         AC_MSG_NOTICE([invalid printf hook implementation, defaulting to 'auto'])
773         printf_hooks=auto
774         ;;
775 esac
776
777 if test x$printf_hooks = xauto -o x$printf_hooks = xglibc; then
778         # check for the new register_printf_specifier function with len argument,
779         # or the deprecated register_printf_function without
780         AC_CHECK_FUNC(
781                 [register_printf_specifier],
782                 [AC_DEFINE([HAVE_PRINTF_SPECIFIER], [], [have register_printf_specifier()])],
783                 [AC_CHECK_FUNC(
784                         [register_printf_function],
785                         [AC_DEFINE([HAVE_PRINTF_FUNCTION], [], [have register_printf_function()])],
786                         [
787                                 AC_MSG_NOTICE([printf(3) does not support custom format specifiers!])
788                                 if test x$printf_hooks = xglibc; then
789                                         AC_MSG_ERROR([please select a different printf hook implementation])
790                                 else
791                                         # fallback to builtin printf hook implementation
792                                         printf_hooks=builtin
793                                 fi
794                         ]
795                 )]
796         )
797 fi
798
799 AC_MSG_CHECKING([for Windows target])
800 AC_COMPILE_IFELSE(
801         [AC_LANG_PROGRAM(
802                 [[#include <windows.h>]],
803                 [[#ifndef WIN32
804                   # error WIN32 undefined
805                   #endif
806                 ]])],
807         [
808                 AC_MSG_RESULT([yes])
809                 windows=true
810                 openssl_lib=eay32
811                 AC_SUBST(PTHREADLIB, "")
812                 # explicitly disable ms-bitfields, as it breaks __attribute__((packed))
813                 case "$CFLAGS" in
814                         *ms-bitfields*) ;;
815                         *) CFLAGS="$CFLAGS -mno-ms-bitfields" ;;
816                 esac
817         ],
818         [
819                 AC_MSG_RESULT([no])
820                 openssl_lib=crypto
821
822                 # check for clock_gettime() on non-Windows only. Otherwise this
823                 # check might find clock_gettime() in libwinpthread, but we don't want
824                 # to link against it.
825                 saved_LIBS=$LIBS
826                 # FreeBSD has clock_gettime in libc, Linux needs librt
827                 LIBS=""
828                 AC_SEARCH_LIBS(clock_gettime, rt, [RTLIB=$LIBS])
829                 AC_CHECK_FUNCS(clock_gettime)
830                 AC_SUBST(RTLIB)
831                 LIBS=$saved_LIBS
832         ]
833 )
834 AC_SUBST(OPENSSL_LIB, [-l$openssl_lib])
835 AM_CONDITIONAL(USE_WINDOWS, [test "x$windows" = xtrue])
836
837 AC_MSG_CHECKING([for working __attribute__((packed))])
838 AC_COMPILE_IFELSE(
839         [AC_LANG_PROGRAM([], [[
840                 struct test { char a; short b; } __attribute__((packed));
841                 char x[sizeof(struct test) == sizeof(char) + sizeof(short) ? 1 : -1]
842                         __attribute__((unused));
843                 return 0;
844         ]])],
845         [AC_MSG_RESULT([yes])],
846         [AC_MSG_RESULT([no]); AC_MSG_ERROR([__attribute__((packed)) does not work])]
847 )
848
849 AC_MSG_CHECKING([clang])
850 AC_COMPILE_IFELSE(
851         [AC_LANG_PROGRAM(
852                 [], [[
853                  #ifndef __clang__
854                  # error not using LLVM clang
855                  #endif
856                 ]])],
857         [
858                 AC_MSG_RESULT([yes])
859         ],
860         [
861                 AC_MSG_RESULT([no])
862                 # GCC, but not MinGW requires -rdynamic for plugins
863                 if test x$windows != xtrue; then
864                         AC_SUBST(PLUGIN_CFLAGS, [-rdynamic])
865                 fi
866         ]
867 )
868
869 AC_MSG_CHECKING([x86/x64 target])
870 AC_COMPILE_IFELSE(
871         [AC_LANG_PROGRAM(
872                 [], [[
873                  #if !defined(__i386__) && !defined(__x86_64__)
874                  # error not on x86/x64
875                  #endif
876                 ]])],
877         [
878                 x86x64=true
879                 AC_MSG_RESULT([yes])
880         ],
881         [AC_MSG_RESULT([no])]
882 )
883 AM_CONDITIONAL(USE_X86X64, [test "x$x86x64" = xtrue])
884
885 if test x$printf_hooks = xvstr; then
886         AC_CHECK_LIB([vstr],[main],[LIBS="$LIBS"],[AC_MSG_ERROR([Vstr string library not found])],[])
887         AC_DEFINE([USE_VSTR], [], [use Vstr string library for printf hooks])
888 fi
889
890 if test x$printf_hooks = xbuiltin; then
891         AC_DEFINE([USE_BUILTIN_PRINTF], [], [using builtin printf for printf hooks])
892 fi
893
894 if test x$gmp = xtrue; then
895         saved_LIBS=$LIBS
896         AC_CHECK_LIB([gmp],[main],[],[AC_MSG_ERROR([GNU Multi Precision library gmp not found])],[])
897         AC_MSG_CHECKING([mpz_powm_sec])
898         if test x$mpz_powm_sec = xyes; then
899                 AC_COMPILE_IFELSE(
900                         [AC_LANG_PROGRAM(
901                                 [[#include "gmp.h"]],
902                                 [[void *x = mpz_powm_sec;]])],
903                         [AC_MSG_RESULT([yes]);
904                          AC_DEFINE([HAVE_MPZ_POWM_SEC], [], [have mpz_mown_sec()])],
905                         [AC_MSG_RESULT([no])]
906                 )
907         else
908                 AC_MSG_RESULT([disabled])
909         fi
910         LIBS=$saved_LIBS
911         AC_MSG_CHECKING([gmp.h version >= 4.1.4])
912         AC_COMPILE_IFELSE(
913                 [AC_LANG_PROGRAM(
914                         [[#include "gmp.h"]],
915                         [[
916                                 #if (__GNU_MP_VERSION*100 +  __GNU_MP_VERSION_MINOR*10 + __GNU_MP_VERSION_PATCHLEVEL) < 414
917                                         #error bad gmp
918                                 #endif]])],
919                 [AC_MSG_RESULT([yes])],
920                 [AC_MSG_RESULT([no]); AC_MSG_ERROR([No usable gmp.h found!])]
921         )
922 fi
923
924 if test x$ldap = xtrue; then
925         AC_CHECK_LIB([ldap],[main],[LIBS="$LIBS"],[AC_MSG_ERROR([LDAP library ldap not found])],[])
926         AC_CHECK_LIB([lber],[main],[LIBS="$LIBS"],[AC_MSG_ERROR([LDAP library lber not found])],[])
927         AC_CHECK_HEADER([ldap.h],,[AC_MSG_ERROR([LDAP header ldap.h not found!])])
928 fi
929
930 if test x$curl = xtrue; then
931         AC_CHECK_LIB([curl],[main],[LIBS="$LIBS"],[AC_MSG_ERROR([CURL library curl not found])],[])
932         AC_CHECK_HEADER([curl/curl.h],,[AC_MSG_ERROR([CURL header curl/curl.h not found!])])
933 fi
934
935 if test x$unbound = xtrue; then
936         AC_CHECK_LIB([ldns],[main],[LIBS="$LIBS"],[AC_MSG_ERROR([UNBOUND library ldns not found])],[])
937         AC_CHECK_HEADER([ldns/ldns.h],,[AC_MSG_ERROR([UNBOUND header ldns/ldns.h not found!])])
938         AC_CHECK_LIB([unbound],[main],[LIBS="$LIBS"],[AC_MSG_ERROR([UNBOUND library libunbound not found])],[])
939         AC_CHECK_HEADER([unbound.h],,[AC_MSG_ERROR([UNBOUND header unbound.h not found!])])
940 fi
941
942 if test x$soup = xtrue; then
943         PKG_CHECK_MODULES(soup, [libsoup-2.4])
944         AC_SUBST(soup_CFLAGS)
945         AC_SUBST(soup_LIBS)
946 fi
947
948 if test x$xml = xtrue; then
949         PKG_CHECK_MODULES(xml, [libxml-2.0])
950         AC_SUBST(xml_CFLAGS)
951         AC_SUBST(xml_LIBS)
952 fi
953
954 if test x$systemd = xtrue; then
955         AC_MSG_CHECKING([for systemd system unit directory])
956         if test -n "$systemdsystemunitdir" -a "x$systemdsystemunitdir" != xno; then
957                 AC_MSG_RESULT([$systemdsystemunitdir])
958         else
959                 AC_MSG_ERROR([not found (try --with-systemdsystemunitdir)])
960         fi
961
962         PKG_CHECK_MODULES(systemd, [libsystemd >= 209],
963                 [AC_SUBST(systemd_CFLAGS)
964                  AC_SUBST(systemd_LIBS)],
965                 [PKG_CHECK_MODULES(systemd_daemon, [libsystemd-daemon])
966                  AC_SUBST(systemd_daemon_CFLAGS)
967                  AC_SUBST(systemd_daemon_LIBS)
968                  PKG_CHECK_MODULES(systemd_journal, [libsystemd-journal])
969                  AC_SUBST(systemd_journal_CFLAGS)
970                  AC_SUBST(systemd_journal_LIBS)]
971         )
972 fi
973
974 if test x$tss_trousers = xtrue; then
975         AC_CHECK_LIB([tspi],[main],[LIBS="$LIBS"],[AC_MSG_ERROR([TrouSerS library libtspi not found])],[])
976         AC_CHECK_HEADER([trousers/tss.h],,[AC_MSG_ERROR([TrouSerS header trousers/tss.h not found!])])
977         AC_DEFINE([TSS_TROUSERS], [], [use TrouSerS library libtspi])
978 fi
979
980 if test x$tss_tss2 = xtrue; then
981         PKG_CHECK_MODULES(tss2, [tcti-socket], [AC_DEFINE([TSS_TSS2], [], [use TSS 2.0 libraries])])
982         AC_SUBST(tss2_CFLAGS)
983         AC_SUBST(tss2_LIBS)
984 fi
985
986 if test x$imv_swid = xtrue; then
987         PKG_CHECK_MODULES(json, [json-c], [],
988                 [PKG_CHECK_MODULES(json, [json])])
989         AC_SUBST(json_CFLAGS)
990         AC_SUBST(json_LIBS)
991 fi
992
993 if test x$dumm = xtrue; then
994         PKG_CHECK_MODULES(gtk, [gtk+-2.0 vte])
995         AC_SUBST(gtk_CFLAGS)
996         AC_SUBST(gtk_LIBS)
997         AC_CHECK_PROGS(RUBY, ruby)
998         AC_MSG_CHECKING([for Ruby header files])
999         if test -n "$RUBY"; then
1000                 RUBYINCLUDE=
1001                 RUBYDIR=`($RUBY -r rbconfig -e 'print RbConfig::CONFIG[["rubyhdrdir"]] || ""') 2>/dev/null`
1002                 if test -n "$RUBYDIR" -a -r "$RUBYDIR/ruby.h"; then
1003                         RUBYARCH=`($RUBY -r rbconfig -e 'print RbConfig::CONFIG[["arch"]] || ""') 2>/dev/null`
1004                         if test -n "$RUBYARCH"; then
1005                                 AC_MSG_RESULT([$RUBYDIR])
1006                                 RUBYINCLUDE="-I$RUBYDIR -I$RUBYDIR/$RUBYARCH"
1007                         fi
1008                 else
1009                         RUBYDIR=`($RUBY -r rbconfig -e 'print RbConfig::CONFIG[["archdir"]] || ""') 2>/dev/null`
1010                         if test -n "$RUBYDIR" -a -r "$RUBYDIR/ruby.h"; then
1011                                 AC_MSG_RESULT([$RUBYDIR])
1012                                 RUBYINCLUDE="-I$RUBYDIR"
1013                         fi
1014                 fi
1015                 if test -z "$RUBYINCLUDE"; then
1016                         AC_MSG_ERROR([ruby.h not found])
1017                 fi
1018                 AC_SUBST(RUBYINCLUDE)
1019         else
1020                 AC_MSG_ERROR([don't know how to run ruby])
1021         fi
1022         AC_MSG_CHECKING([for libruby])
1023         saved_LIBS=$LIBS
1024         LIBS=`($RUBY -r rbconfig -e 'print RbConfig::CONFIG[["LIBRUBYARG_SHARED"]] || ""') 2>/dev/null`
1025         AC_TRY_LINK_FUNC(ruby_init,
1026                 [AC_MSG_RESULT([$LIBS]); RUBYLIB=$LIBS],
1027                 [AC_MSG_ERROR([not found])])
1028         AC_SUBST(RUBYLIB)
1029         AC_CHECK_FUNCS(rb_errinfo)
1030         LIBS=$saved_LIBS
1031 fi
1032
1033 if test x$fast = xtrue; then
1034         AC_CHECK_LIB([neo_cgi],[main],[LIBS="$LIBS"],[AC_MSG_ERROR([ClearSilver library neo_cgi not found!])],[])
1035         AC_CHECK_LIB([neo_utl],[main],[LIBS="$LIBS"],[AC_MSG_ERROR([ClearSilver library neo_utl not found!])],[])
1036         AC_MSG_CHECKING([ClearSilver requires zlib])
1037         saved_CFLAGS=$CFLAGS
1038         saved_LIBS=$LIBS
1039         LIBS="-lneo_cgi -lneo_cs -lneo_utl"
1040         CFLAGS="-I/usr/include/ClearSilver"
1041         AC_LINK_IFELSE(
1042                 [AC_LANG_PROGRAM(
1043                         [[#include <ClearSilver.h>]],
1044                         [[NEOERR *err = cgi_display(NULL, NULL);]])],
1045                 [AC_MSG_RESULT([no]); clearsilver_LIBS="$LIBS"],
1046                 [AC_MSG_RESULT([yes]); clearsilver_LIBS="$LIBS -lz"]
1047         )
1048         AC_SUBST(clearsilver_LIBS)
1049         LIBS=$saved_LIBS
1050         CFLAGS=$saved_CFLAGS
1051 # autoconf does not like CamelCase!? How to fix this?
1052 #       AC_CHECK_HEADER([ClearSilver/ClearSilver.h],,[AC_MSG_ERROR([ClearSilver header file ClearSilver/ClearSilver.h not found!])])
1053
1054         AC_CHECK_LIB([fcgi],[main],[LIBS="$LIBS"],[AC_MSG_ERROR([FastCGI library fcgi not found!])],[])
1055         AC_CHECK_HEADER([fcgiapp.h],,[AC_MSG_ERROR([FastCGI header file fcgiapp.h not found!])])
1056 fi
1057
1058 if test x$mysql = xtrue; then
1059         if test "x$windows" = xtrue; then
1060                 AC_CHECK_HEADER([mysql.h],,[AC_MSG_ERROR([MySQL header file mysql.h not found!])])
1061                 AC_CHECK_LIB([mysql],[main],[LIBS="$LIBS"],[AC_MSG_ERROR([MySQL library not found!])],[])
1062                 AC_SUBST(MYSQLLIB, -lmysql)
1063         else
1064                 AC_PATH_PROG([MYSQLCONFIG], [mysql_config], [], [$PATH:/bin:/usr/bin:/usr/local/bin])
1065                 if test x$MYSQLCONFIG = x; then
1066                         AC_MSG_ERROR([mysql_config not found!])
1067                 fi
1068                 AC_SUBST(MYSQLLIB, `$MYSQLCONFIG --libs_r`)
1069                 AC_SUBST(MYSQLCFLAG, `$MYSQLCONFIG --cflags`)
1070         fi
1071 fi
1072
1073 if test x$sqlite = xtrue; then
1074         AC_CHECK_LIB([sqlite3],[main],[LIBS="$LIBS"],[AC_MSG_ERROR([SQLite library sqlite3 not found])],[])
1075         AC_CHECK_HEADER([sqlite3.h],,[AC_MSG_ERROR([SQLite header sqlite3.h not found!])])
1076         AC_MSG_CHECKING([sqlite3_prepare_v2])
1077         AC_COMPILE_IFELSE(
1078                 [AC_LANG_PROGRAM(
1079                         [[#include <sqlite3.h>]],
1080                         [[void *test = sqlite3_prepare_v2;]])],
1081                 [AC_MSG_RESULT([yes]);
1082                  AC_DEFINE([HAVE_SQLITE3_PREPARE_V2], [], [have sqlite3_prepare_v2()])],
1083                 [AC_MSG_RESULT([no])]
1084         )
1085         AC_MSG_CHECKING([sqlite3.h version >= 3.3.1])
1086         AC_COMPILE_IFELSE(
1087                 [AC_LANG_PROGRAM(
1088                         [[#include <sqlite3.h>]],
1089                         [[
1090                                 #if SQLITE_VERSION_NUMBER < 3003001
1091                                         #error bad sqlite
1092                                 #endif]])],
1093                 [AC_MSG_RESULT([yes])],
1094                 [AC_MSG_RESULT([no]); AC_MSG_ERROR([SQLite version >= 3.3.1 required!])]
1095         )
1096 fi
1097
1098 if test x$openssl = xtrue; then
1099         AC_CHECK_LIB([$openssl_lib],[main],[LIBS="$LIBS"],
1100                                  [AC_MSG_ERROR([OpenSSL lib$openssl_lib not found])],[$DLLIB])
1101         AC_CHECK_HEADER([openssl/evp.h],,[AC_MSG_ERROR([OpenSSL header openssl/evp.h not found!])])
1102 fi
1103
1104 if test x$gcrypt = xtrue; then
1105         AC_CHECK_LIB([gcrypt],[main],[LIBS="$LIBS"],[AC_MSG_ERROR([gcrypt library not found])],[-lgpg-error])
1106         AC_CHECK_HEADER([gcrypt.h],,[AC_MSG_ERROR([gcrypt header gcrypt.h not found!])])
1107         AC_MSG_CHECKING([gcrypt CAMELLIA cipher])
1108         AC_COMPILE_IFELSE(
1109                 [AC_LANG_PROGRAM(
1110                         [[#include <gcrypt.h>]],
1111                         [[enum gcry_cipher_algos alg = GCRY_CIPHER_CAMELLIA128;]])],
1112                 [AC_MSG_RESULT([yes]);
1113                  AC_DEFINE([HAVE_GCRY_CIPHER_CAMELLIA], [], [have GCRY_CIPHER_CAMELLIA128])],
1114                 [AC_MSG_RESULT([no])]
1115         )
1116 fi
1117
1118 if test x$uci = xtrue; then
1119         AC_CHECK_LIB([uci],[main],[LIBS="$LIBS"],[AC_MSG_ERROR([UCI library libuci not found])],[])
1120         AC_CHECK_HEADER([uci.h],,[AC_MSG_ERROR([UCI header uci.h not found!])])
1121 fi
1122
1123 if test x$android_dns = xtrue; then
1124         AC_CHECK_LIB([cutils],[main],[LIBS="$LIBS"],[AC_MSG_ERROR([Android library libcutils not found])],[])
1125         AC_CHECK_HEADER([cutils/properties.h],,[AC_MSG_ERROR([Android header cutils/properties.h not found!])])
1126         # we have to force the use of libdl here because the autodetection
1127         # above does not work correctly when cross-compiling for android.
1128         DLLIB="-ldl"
1129         AC_SUBST(DLLIB)
1130 fi
1131
1132 if test x$maemo = xtrue; then
1133         PKG_CHECK_MODULES(maemo, [glib-2.0 gthread-2.0 libosso osso-af-settings])
1134         AC_SUBST(maemo_CFLAGS)
1135         AC_SUBST(maemo_LIBS)
1136         dbusservicedir="/usr/share/dbus-1/system-services"
1137         AC_SUBST(dbusservicedir)
1138 fi
1139
1140 if test x$eap_sim_pcsc = xtrue; then
1141         PKG_CHECK_MODULES(pcsclite, [libpcsclite])
1142         AC_SUBST(pcsclite_CFLAGS)
1143         AC_SUBST(pcsclite_LIBS)
1144 fi
1145
1146 if test x$nm = xtrue; then
1147         PKG_CHECK_EXISTS([libnm-glib],
1148                 [PKG_CHECK_MODULES(nm, [NetworkManager gthread-2.0 libnm-util libnm-glib libnm-glib-vpn])],
1149                 [PKG_CHECK_MODULES(nm, [NetworkManager gthread-2.0 libnm_util libnm_glib libnm_glib_vpn])]
1150         )
1151         AC_SUBST(nm_CFLAGS)
1152         AC_SUBST(nm_LIBS)
1153 fi
1154
1155 if test x$xauth_pam = xtrue; then
1156         AC_CHECK_LIB([pam],[main],[LIBS="$LIBS"],[AC_MSG_ERROR([PAM library not found])],[])
1157         AC_CHECK_HEADER([security/pam_appl.h],,[AC_MSG_ERROR([PAM header security/pam_appl.h not found!])])
1158 fi
1159
1160 if test x$connmark = xtrue -o x$forecast = xtrue; then
1161         PKG_CHECK_MODULES(libiptc, [libiptc])
1162         AC_SUBST(libiptc_CFLAGS)
1163         AC_SUBST(libiptc_LIBS)
1164 fi
1165
1166 if test x$capabilities = xnative; then
1167         AC_MSG_NOTICE([Usage of the native Linux capabilities interface is deprecated, use libcap instead])
1168         # Linux requires the following for capset(), Android does not have it,
1169         # but defines capset() in unistd.h instead.
1170         AC_CHECK_HEADERS([sys/capability.h])
1171         AC_CHECK_FUNC(capset,,[AC_MSG_ERROR([capset() not found!])])
1172         AC_DEFINE([CAPABILITIES_NATIVE], [], [have native linux capset()])
1173 fi
1174
1175 if test x$capabilities = xlibcap; then
1176         AC_CHECK_LIB([cap],[main],[LIBS="$LIBS"],[AC_MSG_ERROR([libcap library not found])],[])
1177         AC_CHECK_HEADER([sys/capability.h],
1178                 [AC_DEFINE([HAVE_SYS_CAPABILITY_H], [], [have sys/capability.h])],
1179                 [AC_MSG_ERROR([libcap header sys/capability.h not found!])])
1180         AC_DEFINE([CAPABILITIES_LIBCAP], [], [have libpcap library])
1181 fi
1182
1183 if test x$integrity_test = xtrue; then
1184         AC_MSG_CHECKING([for dladdr()])
1185         AC_COMPILE_IFELSE(
1186                 [AC_LANG_PROGRAM(
1187                         [[#define _GNU_SOURCE
1188                           #include <dlfcn.h>]],
1189                         [[Dl_info info; dladdr(main, &info);]])],
1190                 [AC_MSG_RESULT([yes])],
1191                 [AC_MSG_RESULT([no]);
1192                  AC_MSG_ERROR([dladdr() not supported, required by integrity-test!])]
1193         )
1194         AC_MSG_CHECKING([for dl_iterate_phdr()])
1195         AC_COMPILE_IFELSE(
1196                 [AC_LANG_PROGRAM(
1197                         [[#define _GNU_SOURCE
1198                           #include <link.h>]],
1199                         [[dl_iterate_phdr((void*)0, (void*)0);]])],
1200                 [AC_MSG_RESULT([yes])],
1201                 [AC_MSG_RESULT([no]);
1202                  AC_MSG_ERROR([dl_iterate_phdr() not supported, required by integrity-test!])]
1203         )
1204 fi
1205
1206 if test x$bfd_backtraces = xtrue; then
1207         AC_CHECK_LIB([bfd],[main],[LIBS="$LIBS"],[AC_MSG_ERROR([binutils libbfd not found!])],[])
1208         AC_CHECK_HEADER([bfd.h],[AC_DEFINE([HAVE_BFD_H],,[have binutils bfd.h])],
1209                 [AC_MSG_ERROR([binutils bfd.h header not found!])])
1210         BFDLIB="-lbfd"
1211         AC_SUBST(BFDLIB)
1212 fi
1213
1214 if test x$unwind_backtraces = xtrue; then
1215         AC_CHECK_LIB([unwind],[main],[LIBS="$LIBS"],[AC_MSG_ERROR([libunwind not found!])],[])
1216         AC_CHECK_HEADER([libunwind.h],[AC_DEFINE([HAVE_LIBUNWIND_H],,[have libunwind.h])],
1217                 [AC_MSG_ERROR([libunwind.h header not found!])])
1218         UNWINDLIB="-lunwind"
1219         AC_SUBST(UNWINDLIB)
1220 fi
1221
1222 AM_CONDITIONAL(USE_DEV_HEADERS, [test "x$dev_headers" != xno])
1223 if test x$dev_headers = xyes; then
1224         dev_headers="$includedir/strongswan"
1225 fi
1226 AC_SUBST(dev_headers)
1227
1228 CFLAGS="$CFLAGS -include `pwd`/config.h"
1229
1230 if test x$tkm = xtrue; then
1231         AC_PATH_PROG([GPRBUILD], [gprbuild], [], [$PATH:/bin:/usr/bin:/usr/local/bin])
1232         if test x$GPRBUILD = x; then
1233                 AC_MSG_ERROR([gprbuild not found])
1234         fi
1235 fi
1236
1237 if test x$coverage = xtrue; then
1238         AC_PATH_PROG([LCOV], [lcov], [], [$PATH:/bin:/usr/bin:/usr/local/bin])
1239         if test x$LCOV = x; then
1240                 AC_MSG_ERROR([lcov not found])
1241         fi
1242         AC_PATH_PROG([GENHTML], [genhtml], [], [$PATH:/bin:/usr/bin:/usr/local/bin])
1243         if test x$GENHTML = x; then
1244                 AC_MSG_ERROR([genhtml not found])
1245         fi
1246
1247         COVERAGE_CFLAGS="-fprofile-arcs -ftest-coverage"
1248         COVERAGE_LDFLAGS="-fprofile-arcs"
1249         AC_SUBST(COVERAGE_CFLAGS)
1250         AC_SUBST(COVERAGE_LDFLAGS)
1251
1252         AC_MSG_NOTICE([coverage enabled, adding "-g -O0" to CFLAGS])
1253         CFLAGS="${CFLAGS} -g -O0"
1254 fi
1255
1256 if test x$ruby_gems = xtrue; then
1257         AC_PATH_PROG([GEM], [gem], [], [$PATH:/bin:/usr/bin:/usr/local/bin])
1258         if test x$GEM = x; then
1259                 AC_MSG_ERROR(RubyGems package manager not found)
1260         fi
1261         if test "x$rubygemdir" = "xgem environment gemdir"; then
1262                 rubygemdir=$($GEM environment gemdir)
1263         fi
1264         AC_SUBST(RUBYGEMDIR, "$rubygemdir")
1265 fi
1266 AM_CONDITIONAL(RUBY_GEMS_INSTALL, [test "x$ruby_gems_install" = xtrue])
1267
1268 if test x$python_eggs = xtrue; then
1269         PYTHON_PACKAGE_VERSION=`echo "$PACKAGE_VERSION" | $SED 's/dr/dev/'`
1270         AC_SUBST([PYTHON_PACKAGE_VERSION])
1271         if test x$python_eggs_install = xtrue; then
1272                 AC_PATH_PROG([EASY_INSTALL], [easy_install], [], [$PATH:/bin:/usr/bin:/usr/local/bin])
1273                 if test x$EASY_INSTALL = x; then
1274                         AC_MSG_ERROR(Python easy_install not found)
1275                 fi
1276         fi
1277         if test "x$pythoneggdir" = "xmain site-packages directory"; then
1278                 AC_SUBST(PYTHONEGGINSTALLDIR, "")
1279         else
1280                 AC_SUBST(PYTHONEGGINSTALLDIR, "--install-dir $pythoneggdir")
1281         fi
1282         AC_PATH_PROG([PY_TEST], [py.test], [], [$PATH:/bin:/usr/bin:/usr/local/bin])
1283 fi
1284 AM_CONDITIONAL(PYTHON_EGGS_INSTALL, [test "x$python_eggs_install" = xtrue])
1285
1286 AM_CONDITIONAL(PERL_CPAN_INSTALL, [test "x$perl_cpan_install" = xtrue])
1287
1288 # ===============================================
1289 #  collect plugin list for strongSwan components
1290 # ===============================================
1291
1292 m4_include(m4/macros/add-plugin.m4)
1293
1294 # plugin lists for all components
1295 charon_plugins=
1296 starter_plugins=
1297 pool_plugins=
1298 attest_plugins=
1299 scepclient_plugins=
1300 pki_plugins=
1301 scripts_plugins=
1302 manager_plugins=
1303 medsrv_plugins=
1304 nm_plugins=
1305 cmd_plugins=
1306 aikgen_plugins=
1307
1308 # location specific lists for checksumming,
1309 # for src/libcharon, src/libstrongswan and src/libtnccs
1310 c_plugins=
1311 s_plugins=
1312 t_plugins=
1313
1314 ADD_PLUGIN([test-vectors],         [s charon scepclient pki])
1315 ADD_PLUGIN([unbound],              [s charon scripts])
1316 ADD_PLUGIN([ldap],                 [s charon scepclient scripts nm cmd])
1317 ADD_PLUGIN([pkcs11],               [s charon pki nm cmd])
1318 ADD_PLUGIN([aesni],                [s charon scepclient pki scripts medsrv attest nm cmd aikgen])
1319 ADD_PLUGIN([aes],                  [s charon scepclient pki scripts nm cmd])
1320 ADD_PLUGIN([des],                  [s charon scepclient pki scripts nm cmd])
1321 ADD_PLUGIN([blowfish],             [s charon scepclient pki scripts nm cmd])
1322 ADD_PLUGIN([rc2],                  [s charon scepclient pki scripts nm cmd])
1323 ADD_PLUGIN([sha2],                 [s charon scepclient pki scripts medsrv attest nm cmd aikgen])
1324 ADD_PLUGIN([sha3],                 [s charon scepclient pki scripts medsrv attest nm cmd aikgen])
1325 ADD_PLUGIN([sha1],                 [s charon scepclient pki scripts manager medsrv attest nm cmd aikgen])
1326 ADD_PLUGIN([md4],                  [s charon scepclient pki nm cmd])
1327 ADD_PLUGIN([md5],                  [s charon scepclient pki scripts attest nm cmd aikgen])
1328 ADD_PLUGIN([rdrand],               [s charon scepclient pki scripts medsrv attest nm cmd aikgen])
1329 ADD_PLUGIN([random],               [s charon scepclient pki scripts manager medsrv attest nm cmd aikgen])
1330 ADD_PLUGIN([nonce],                [s charon nm cmd aikgen])
1331 ADD_PLUGIN([x509],                 [s charon scepclient pki scripts attest nm cmd aikgen])
1332 ADD_PLUGIN([revocation],           [s charon pki nm cmd])
1333 ADD_PLUGIN([constraints],          [s charon nm cmd])
1334 ADD_PLUGIN([acert],                [s charon])
1335 ADD_PLUGIN([pubkey],               [s charon cmd aikgen])
1336 ADD_PLUGIN([pkcs1],                [s charon scepclient pki scripts manager medsrv attest nm cmd aikgen])
1337 ADD_PLUGIN([pkcs7],                [s charon scepclient pki scripts nm cmd])
1338 ADD_PLUGIN([pkcs8],                [s charon scepclient pki scripts manager medsrv attest nm cmd])
1339 ADD_PLUGIN([pkcs12],               [s charon scepclient pki scripts cmd])
1340 ADD_PLUGIN([pgp],                  [s charon])
1341 ADD_PLUGIN([dnskey],               [s charon pki])
1342 ADD_PLUGIN([sshkey],               [s charon pki nm cmd])
1343 ADD_PLUGIN([dnscert],              [c charon])
1344 ADD_PLUGIN([ipseckey],             [c charon])
1345 ADD_PLUGIN([pem],                  [s charon scepclient pki scripts manager medsrv attest nm cmd aikgen])
1346 ADD_PLUGIN([padlock],              [s charon])
1347 ADD_PLUGIN([openssl],              [s charon scepclient pki scripts manager medsrv attest nm cmd aikgen])
1348 ADD_PLUGIN([gcrypt],               [s charon scepclient pki scripts manager medsrv attest nm cmd aikgen])
1349 ADD_PLUGIN([af-alg],               [s charon scepclient pki scripts medsrv attest nm cmd aikgen])
1350 ADD_PLUGIN([fips-prf],             [s charon nm cmd])
1351 ADD_PLUGIN([gmp],                  [s charon scepclient pki scripts manager medsrv attest nm cmd aikgen])
1352 ADD_PLUGIN([agent],                [s charon nm cmd])
1353 ADD_PLUGIN([keychain],             [s charon cmd])
1354 ADD_PLUGIN([chapoly],              [s charon scripts nm cmd])
1355 ADD_PLUGIN([xcbc],                 [s charon nm cmd])
1356 ADD_PLUGIN([cmac],                 [s charon nm cmd])
1357 ADD_PLUGIN([hmac],                 [s charon pki scripts nm cmd])
1358 ADD_PLUGIN([ctr],                  [s charon scripts nm cmd])
1359 ADD_PLUGIN([ccm],                  [s charon scripts nm cmd])
1360 ADD_PLUGIN([gcm],                  [s charon scripts nm cmd])
1361 ADD_PLUGIN([ntru],                 [s charon scripts nm cmd])
1362 ADD_PLUGIN([newhope],              [s charon scripts nm cmd])
1363 ADD_PLUGIN([bliss],                [s charon pki scripts nm cmd])
1364 ADD_PLUGIN([curl],                 [s charon scepclient pki scripts nm cmd])
1365 ADD_PLUGIN([files],                [s charon scepclient pki scripts nm cmd])
1366 ADD_PLUGIN([winhttp],              [s charon pki scripts])
1367 ADD_PLUGIN([soup],                 [s charon pki scripts nm cmd])
1368 ADD_PLUGIN([mysql],                [s charon pool manager medsrv attest])
1369 ADD_PLUGIN([sqlite],               [s charon pool manager medsrv attest])
1370 ADD_PLUGIN([attr],                 [c charon])
1371 ADD_PLUGIN([attr-sql],             [c charon])
1372 ADD_PLUGIN([load-tester],          [c charon])
1373 ADD_PLUGIN([kernel-libipsec],      [c charon cmd])
1374 ADD_PLUGIN([kernel-wfp],           [c charon])
1375 ADD_PLUGIN([kernel-iph],           [c charon])
1376 ADD_PLUGIN([kernel-pfkey],         [c charon starter nm cmd])
1377 ADD_PLUGIN([kernel-pfroute],       [c charon starter nm cmd])
1378 ADD_PLUGIN([kernel-netlink],       [c charon starter nm cmd])
1379 ADD_PLUGIN([resolve],              [c charon cmd])
1380 ADD_PLUGIN([socket-default],       [c charon nm cmd])
1381 ADD_PLUGIN([socket-dynamic],       [c charon cmd])
1382 ADD_PLUGIN([socket-win],           [c charon])
1383 ADD_PLUGIN([connmark],             [c charon])
1384 ADD_PLUGIN([forecast],             [c charon])
1385 ADD_PLUGIN([farp],                 [c charon])
1386 ADD_PLUGIN([stroke],               [c charon])
1387 ADD_PLUGIN([vici],                 [c charon])
1388 ADD_PLUGIN([smp],                  [c charon])
1389 ADD_PLUGIN([sql],                  [c charon])
1390 ADD_PLUGIN([updown],               [c charon])
1391 ADD_PLUGIN([eap-identity],         [c charon nm cmd])
1392 ADD_PLUGIN([eap-sim],              [c charon])
1393 ADD_PLUGIN([eap-sim-file],         [c charon])
1394 ADD_PLUGIN([eap-sim-pcsc],         [c charon])
1395 ADD_PLUGIN([eap-aka],              [c charon])
1396 ADD_PLUGIN([eap-aka-3gpp2],        [c charon])
1397 ADD_PLUGIN([eap-simaka-sql],       [c charon])
1398 ADD_PLUGIN([eap-simaka-pseudonym], [c charon])
1399 ADD_PLUGIN([eap-simaka-reauth],    [c charon])
1400 ADD_PLUGIN([eap-md5],              [c charon nm cmd])
1401 ADD_PLUGIN([eap-gtc],              [c charon nm cmd])
1402 ADD_PLUGIN([eap-mschapv2],         [c charon nm cmd])
1403 ADD_PLUGIN([eap-dynamic],          [c charon])
1404 ADD_PLUGIN([eap-radius],           [c charon])
1405 ADD_PLUGIN([eap-tls],              [c charon nm cmd])
1406 ADD_PLUGIN([eap-ttls],             [c charon nm cmd])
1407 ADD_PLUGIN([eap-peap],             [c charon nm cmd])
1408 ADD_PLUGIN([eap-tnc],              [c charon])
1409 ADD_PLUGIN([xauth-generic],        [c charon cmd])
1410 ADD_PLUGIN([xauth-eap],            [c charon])
1411 ADD_PLUGIN([xauth-pam],            [c charon])
1412 ADD_PLUGIN([xauth-noauth],         [c charon])
1413 ADD_PLUGIN([tnc-ifmap],            [c charon])
1414 ADD_PLUGIN([tnc-pdp],              [c charon])
1415 ADD_PLUGIN([tnc-imc],              [t charon])
1416 ADD_PLUGIN([tnc-imv],              [t charon])
1417 ADD_PLUGIN([tnc-tnccs],            [t charon])
1418 ADD_PLUGIN([tnccs-20],             [t charon])
1419 ADD_PLUGIN([tnccs-11],             [t charon])
1420 ADD_PLUGIN([tnccs-dynamic],        [t charon])
1421 ADD_PLUGIN([medsrv],               [c charon])
1422 ADD_PLUGIN([medcli],               [c charon])
1423 ADD_PLUGIN([dhcp],                 [c charon])
1424 ADD_PLUGIN([osx-attr],             [c charon cmd])
1425 ADD_PLUGIN([p-cscf],               [c charon cmd])
1426 ADD_PLUGIN([android-dns],          [c charon])
1427 ADD_PLUGIN([android-log],          [c charon])
1428 ADD_PLUGIN([ha],                   [c charon])
1429 ADD_PLUGIN([whitelist],            [c charon])
1430 ADD_PLUGIN([ext-auth],             [c charon])
1431 ADD_PLUGIN([lookip],               [c charon])
1432 ADD_PLUGIN([error-notify],         [c charon])
1433 ADD_PLUGIN([certexpire],           [c charon])
1434 ADD_PLUGIN([systime-fix],          [c charon])
1435 ADD_PLUGIN([led],                  [c charon])
1436 ADD_PLUGIN([duplicheck],           [c charon])
1437 ADD_PLUGIN([coupling],             [c charon])
1438 ADD_PLUGIN([radattr],              [c charon])
1439 ADD_PLUGIN([maemo],                [c charon])
1440 ADD_PLUGIN([uci],                  [c charon])
1441 ADD_PLUGIN([addrblock],            [c charon])
1442 ADD_PLUGIN([unity],                [c charon])
1443
1444 AC_SUBST(charon_plugins)
1445 AC_SUBST(starter_plugins)
1446 AC_SUBST(pool_plugins)
1447 AC_SUBST(attest_plugins)
1448 AC_SUBST(scepclient_plugins)
1449 AC_SUBST(pki_plugins)
1450 AC_SUBST(scripts_plugins)
1451 AC_SUBST(manager_plugins)
1452 AC_SUBST(medsrv_plugins)
1453 AC_SUBST(nm_plugins)
1454 AC_SUBST(cmd_plugins)
1455 AC_SUBST(aikgen_plugins)
1456
1457 AC_SUBST(c_plugins)
1458 AC_SUBST(h_plugins)
1459 AC_SUBST(s_plugins)
1460 AC_SUBST(t_plugins)
1461
1462 # ======================
1463 #  set Makefile.am vars
1464 # ======================
1465
1466 #  libstrongswan plugins
1467 # -----------------------
1468 AM_CONDITIONAL(USE_TEST_VECTORS, test x$test_vectors = xtrue)
1469 AM_CONDITIONAL(USE_CURL, test x$curl = xtrue)
1470 AM_CONDITIONAL(USE_FILES, test x$files = xtrue)
1471 AM_CONDITIONAL(USE_WINHTTP, test x$winhttp = xtrue)
1472 AM_CONDITIONAL(USE_UNBOUND, test x$unbound = xtrue)
1473 AM_CONDITIONAL(USE_SOUP, test x$soup = xtrue)
1474 AM_CONDITIONAL(USE_LDAP, test x$ldap = xtrue)
1475 AM_CONDITIONAL(USE_AES, test x$aes = xtrue)
1476 AM_CONDITIONAL(USE_DES, test x$des = xtrue)
1477 AM_CONDITIONAL(USE_BLOWFISH, test x$blowfish = xtrue)
1478 AM_CONDITIONAL(USE_RC2, test x$rc2 = xtrue)
1479 AM_CONDITIONAL(USE_MD4, test x$md4 = xtrue)
1480 AM_CONDITIONAL(USE_MD5, test x$md5 = xtrue)
1481 AM_CONDITIONAL(USE_SHA1, test x$sha1 = xtrue)
1482 AM_CONDITIONAL(USE_SHA2, test x$sha2 = xtrue)
1483 AM_CONDITIONAL(USE_SHA3, test x$sha3 = xtrue)
1484 AM_CONDITIONAL(USE_FIPS_PRF, test x$fips_prf = xtrue)
1485 AM_CONDITIONAL(USE_GMP, test x$gmp = xtrue)
1486 AM_CONDITIONAL(USE_RDRAND, test x$rdrand = xtrue)
1487 AM_CONDITIONAL(USE_AESNI, test x$aesni = xtrue)
1488 AM_CONDITIONAL(USE_RANDOM, test x$random = xtrue)
1489 AM_CONDITIONAL(USE_NONCE, test x$nonce = xtrue)
1490 AM_CONDITIONAL(USE_X509, test x$x509 = xtrue)
1491 AM_CONDITIONAL(USE_REVOCATION, test x$revocation = xtrue)
1492 AM_CONDITIONAL(USE_CONSTRAINTS, test x$constraints = xtrue)
1493 AM_CONDITIONAL(USE_ACERT, test x$acert = xtrue)
1494 AM_CONDITIONAL(USE_PUBKEY, test x$pubkey = xtrue)
1495 AM_CONDITIONAL(USE_PKCS1, test x$pkcs1 = xtrue)
1496 AM_CONDITIONAL(USE_PKCS7, test x$pkcs7 = xtrue)
1497 AM_CONDITIONAL(USE_PKCS8, test x$pkcs8 = xtrue)
1498 AM_CONDITIONAL(USE_PKCS12, test x$pkcs12 = xtrue)
1499 AM_CONDITIONAL(USE_PGP, test x$pgp = xtrue)
1500 AM_CONDITIONAL(USE_DNSKEY, test x$dnskey = xtrue)
1501 AM_CONDITIONAL(USE_SSHKEY, test x$sshkey = xtrue)
1502 AM_CONDITIONAL(USE_PEM, test x$pem = xtrue)
1503 AM_CONDITIONAL(USE_HMAC, test x$hmac = xtrue)
1504 AM_CONDITIONAL(USE_CMAC, test x$cmac = xtrue)
1505 AM_CONDITIONAL(USE_XCBC, test x$xcbc = xtrue)
1506 AM_CONDITIONAL(USE_MYSQL, test x$mysql = xtrue)
1507 AM_CONDITIONAL(USE_SQLITE, test x$sqlite = xtrue)
1508 AM_CONDITIONAL(USE_PADLOCK, test x$padlock = xtrue)
1509 AM_CONDITIONAL(USE_OPENSSL, test x$openssl = xtrue)
1510 AM_CONDITIONAL(USE_GCRYPT, test x$gcrypt = xtrue)
1511 AM_CONDITIONAL(USE_AGENT, test x$agent = xtrue)
1512 AM_CONDITIONAL(USE_KEYCHAIN, test x$keychain = xtrue)
1513 AM_CONDITIONAL(USE_PKCS11, test x$pkcs11 = xtrue)
1514 AM_CONDITIONAL(USE_CHAPOLY, test x$chapoly = xtrue)
1515 AM_CONDITIONAL(USE_CTR, test x$ctr = xtrue)
1516 AM_CONDITIONAL(USE_CCM, test x$ccm = xtrue)
1517 AM_CONDITIONAL(USE_GCM, test x$gcm = xtrue)
1518 AM_CONDITIONAL(USE_AF_ALG, test x$af_alg = xtrue)
1519 AM_CONDITIONAL(USE_NTRU, test x$ntru = xtrue)
1520 AM_CONDITIONAL(USE_NEWHOPE, test x$newhope = xtrue)
1521 AM_CONDITIONAL(USE_BLISS, test x$bliss = xtrue)
1522
1523 #  charon plugins
1524 # ----------------
1525 AM_CONDITIONAL(USE_STROKE, test x$stroke = xtrue)
1526 AM_CONDITIONAL(USE_VICI, test x$vici = xtrue)
1527 AM_CONDITIONAL(USE_MEDSRV, test x$medsrv = xtrue)
1528 AM_CONDITIONAL(USE_MEDCLI, test x$medcli = xtrue)
1529 AM_CONDITIONAL(USE_UCI, test x$uci = xtrue)
1530 AM_CONDITIONAL(USE_OSX_ATTR, test x$osx_attr = xtrue)
1531 AM_CONDITIONAL(USE_P_CSCF, test x$p_cscf = xtrue)
1532 AM_CONDITIONAL(USE_ANDROID_DNS, test x$android_dns = xtrue)
1533 AM_CONDITIONAL(USE_ANDROID_LOG, test x$android_log = xtrue)
1534 AM_CONDITIONAL(USE_MAEMO, test x$maemo = xtrue)
1535 AM_CONDITIONAL(USE_SMP, test x$smp = xtrue)
1536 AM_CONDITIONAL(USE_SQL, test x$sql = xtrue)
1537 AM_CONDITIONAL(USE_DNSCERT, test x$dnscert = xtrue)
1538 AM_CONDITIONAL(USE_IPSECKEY, test x$ipseckey = xtrue)
1539 AM_CONDITIONAL(USE_UPDOWN, test x$updown = xtrue)
1540 AM_CONDITIONAL(USE_DHCP, test x$dhcp = xtrue)
1541 AM_CONDITIONAL(USE_LOAD_TESTER, test x$load_tester = xtrue)
1542 AM_CONDITIONAL(USE_HA, test x$ha = xtrue)
1543 AM_CONDITIONAL(USE_KERNEL_NETLINK, test x$kernel_netlink = xtrue)
1544 AM_CONDITIONAL(USE_KERNEL_PFKEY, test x$kernel_pfkey = xtrue)
1545 AM_CONDITIONAL(USE_KERNEL_PFROUTE, test x$kernel_pfroute = xtrue)
1546 AM_CONDITIONAL(USE_KERNEL_LIBIPSEC, test x$kernel_libipsec = xtrue)
1547 AM_CONDITIONAL(USE_KERNEL_WFP, test x$kernel_wfp = xtrue)
1548 AM_CONDITIONAL(USE_KERNEL_IPH, test x$kernel_iph = xtrue)
1549 AM_CONDITIONAL(USE_WHITELIST, test x$whitelist = xtrue)
1550 AM_CONDITIONAL(USE_EXT_AUTH, test x$ext_auth = xtrue)
1551 AM_CONDITIONAL(USE_LOOKIP, test x$lookip = xtrue)
1552 AM_CONDITIONAL(USE_ERROR_NOTIFY, test x$error_notify = xtrue)
1553 AM_CONDITIONAL(USE_CERTEXPIRE, test x$certexpire = xtrue)
1554 AM_CONDITIONAL(USE_SYSTIME_FIX, test x$systime_fix = xtrue)
1555 AM_CONDITIONAL(USE_LED, test x$led = xtrue)
1556 AM_CONDITIONAL(USE_DUPLICHECK, test x$duplicheck = xtrue)
1557 AM_CONDITIONAL(USE_COUPLING, test x$coupling = xtrue)
1558 AM_CONDITIONAL(USE_RADATTR, test x$radattr = xtrue)
1559 AM_CONDITIONAL(USE_EAP_SIM, test x$eap_sim = xtrue)
1560 AM_CONDITIONAL(USE_EAP_SIM_FILE, test x$eap_sim_file = xtrue)
1561 AM_CONDITIONAL(USE_EAP_SIM_PCSC, test x$eap_sim_pcsc = xtrue)
1562 AM_CONDITIONAL(USE_EAP_SIMAKA_SQL, test x$eap_simaka_sql = xtrue)
1563 AM_CONDITIONAL(USE_EAP_SIMAKA_PSEUDONYM, test x$eap_simaka_pseudonym = xtrue)
1564 AM_CONDITIONAL(USE_EAP_SIMAKA_REAUTH, test x$eap_simaka_reauth = xtrue)
1565 AM_CONDITIONAL(USE_EAP_IDENTITY, test x$eap_identity = xtrue)
1566 AM_CONDITIONAL(USE_EAP_MD5, test x$eap_md5 = xtrue)
1567 AM_CONDITIONAL(USE_EAP_GTC, test x$eap_gtc = xtrue)
1568 AM_CONDITIONAL(USE_EAP_AKA, test x$eap_aka = xtrue)
1569 AM_CONDITIONAL(USE_EAP_AKA_3GPP2, test x$eap_aka_3gpp2 = xtrue)
1570 AM_CONDITIONAL(USE_EAP_MSCHAPV2, test x$eap_mschapv2 = xtrue)
1571 AM_CONDITIONAL(USE_EAP_TLS, test x$eap_tls = xtrue)
1572 AM_CONDITIONAL(USE_EAP_TTLS, test x$eap_ttls = xtrue)
1573 AM_CONDITIONAL(USE_EAP_PEAP, test x$eap_peap = xtrue)
1574 AM_CONDITIONAL(USE_EAP_TNC, test x$eap_tnc = xtrue)
1575 AM_CONDITIONAL(USE_EAP_DYNAMIC, test x$eap_dynamic = xtrue)
1576 AM_CONDITIONAL(USE_EAP_RADIUS, test x$eap_radius = xtrue)
1577 AM_CONDITIONAL(USE_XAUTH_GENERIC, test x$xauth_generic = xtrue)
1578 AM_CONDITIONAL(USE_XAUTH_EAP, test x$xauth_eap = xtrue)
1579 AM_CONDITIONAL(USE_XAUTH_PAM, test x$xauth_pam = xtrue)
1580 AM_CONDITIONAL(USE_XAUTH_NOAUTH, test x$xauth_noauth = xtrue)
1581 AM_CONDITIONAL(USE_TNC_IFMAP, test x$tnc_ifmap = xtrue)
1582 AM_CONDITIONAL(USE_TNC_PDP, test x$tnc_pdp = xtrue)
1583 AM_CONDITIONAL(USE_TNC_IMC, test x$tnc_imc = xtrue)
1584 AM_CONDITIONAL(USE_TNC_IMV, test x$tnc_imv = xtrue)
1585 AM_CONDITIONAL(USE_TNC_TNCCS, test x$tnc_tnccs = xtrue)
1586 AM_CONDITIONAL(USE_TNCCS_11, test x$tnccs_11 = xtrue)
1587 AM_CONDITIONAL(USE_TNCCS_20, test x$tnccs_20 = xtrue)
1588 AM_CONDITIONAL(USE_TNCCS_DYNAMIC, test x$tnccs_dynamic = xtrue)
1589 AM_CONDITIONAL(USE_IMC_TEST, test x$imc_test = xtrue)
1590 AM_CONDITIONAL(USE_IMV_TEST, test x$imv_test = xtrue)
1591 AM_CONDITIONAL(USE_IMC_SCANNER, test x$imc_scanner = xtrue)
1592 AM_CONDITIONAL(USE_IMV_SCANNER, test x$imv_scanner = xtrue)
1593 AM_CONDITIONAL(USE_IMC_OS, test x$imc_os = xtrue)
1594 AM_CONDITIONAL(USE_IMV_OS, test x$imv_os = xtrue)
1595 AM_CONDITIONAL(USE_IMC_ATTESTATION, test x$imc_attestation = xtrue)
1596 AM_CONDITIONAL(USE_IMV_ATTESTATION, test x$imv_attestation = xtrue)
1597 AM_CONDITIONAL(USE_IMC_SWID, test x$imc_swid = xtrue)
1598 AM_CONDITIONAL(USE_IMV_SWID, test x$imv_swid = xtrue)
1599 AM_CONDITIONAL(USE_IMC_HCD, test x$imc_hcd = xtrue)
1600 AM_CONDITIONAL(USE_IMV_HCD, test x$imv_hcd = xtrue)
1601 AM_CONDITIONAL(USE_SOCKET_DEFAULT, test x$socket_default = xtrue)
1602 AM_CONDITIONAL(USE_SOCKET_DYNAMIC, test x$socket_dynamic = xtrue)
1603 AM_CONDITIONAL(USE_SOCKET_WIN, test x$socket_win = xtrue)
1604 AM_CONDITIONAL(USE_CONNMARK, test x$connmark = xtrue)
1605 AM_CONDITIONAL(USE_FORECAST, test x$forecast = xtrue)
1606 AM_CONDITIONAL(USE_FARP, test x$farp = xtrue)
1607 AM_CONDITIONAL(USE_ADDRBLOCK, test x$addrblock = xtrue)
1608 AM_CONDITIONAL(USE_UNITY, test x$unity = xtrue)
1609 AM_CONDITIONAL(USE_RESOLVE, test x$resolve = xtrue)
1610 AM_CONDITIONAL(USE_ATTR, test x$attr = xtrue)
1611 AM_CONDITIONAL(USE_ATTR_SQL, test x$attr_sql = xtrue)
1612
1613 #  other options
1614 # ---------------
1615 AM_CONDITIONAL(USE_LEAK_DETECTIVE, test x$leak_detective = xtrue)
1616 AM_CONDITIONAL(USE_LOCK_PROFILER, test x$lock_profiler = xtrue)
1617 AM_CONDITIONAL(USE_DUMM, test x$dumm = xtrue)
1618 AM_CONDITIONAL(USE_FAST, test x$fast = xtrue)
1619 AM_CONDITIONAL(USE_MANAGER, test x$manager = xtrue)
1620 AM_CONDITIONAL(USE_ME, test x$mediation = xtrue)
1621 AM_CONDITIONAL(USE_INTEGRITY_TEST, test x$integrity_test = xtrue)
1622 AM_CONDITIONAL(USE_LOAD_WARNING, test x$load_warning = xtrue)
1623 AM_CONDITIONAL(USE_IKEV1, test x$ikev1 = xtrue)
1624 AM_CONDITIONAL(USE_IKEV2, test x$ikev2 = xtrue)
1625 AM_CONDITIONAL(USE_THREADS, test x$threads = xtrue)
1626 AM_CONDITIONAL(USE_ADNS, test x$adns = xtrue)
1627 AM_CONDITIONAL(USE_CHARON, test x$charon = xtrue)
1628 AM_CONDITIONAL(USE_NM, test x$nm = xtrue)
1629 AM_CONDITIONAL(USE_PKI, test x$pki = xtrue)
1630 AM_CONDITIONAL(USE_SCEPCLIENT, test x$scepclient = xtrue)
1631 AM_CONDITIONAL(USE_SCRIPTS, test x$scripts = xtrue)
1632 AM_CONDITIONAL(USE_CONFTEST, test x$conftest = xtrue)
1633 AM_CONDITIONAL(USE_LIBSTRONGSWAN, test x$charon = xtrue -o x$pki = xtrue -o x$scepclient = xtrue -o x$conftest = xtrue -o x$fast = xtrue -o x$imcv = xtrue -o x$nm = xtrue -o x$tkm = xtrue -o x$cmd = xtrue -o x$tls = xtrue -o x$tnc_tnccs = xtrue -o x$aikgen = xtrue -o x$aikpub2 = xtrue -o x$svc = xtrue -o x$systemd = xtrue)
1634 AM_CONDITIONAL(USE_LIBCHARON, test x$charon = xtrue -o x$conftest = xtrue -o x$nm = xtrue -o x$tkm = xtrue -o x$cmd = xtrue -o x$svc = xtrue -o x$systemd = xtrue)
1635 AM_CONDITIONAL(USE_LIBIPSEC, test x$libipsec = xtrue)
1636 AM_CONDITIONAL(USE_LIBNTTFFT, test x$bliss = xtrue -o x$newhope = xtrue)
1637 AM_CONDITIONAL(USE_LIBTNCIF, test x$tnc_tnccs = xtrue -o x$imcv = xtrue)
1638 AM_CONDITIONAL(USE_LIBTNCCS, test x$tnc_tnccs = xtrue)
1639 AM_CONDITIONAL(USE_LIBPTTLS, test x$tnc_tnccs = xtrue)
1640 AM_CONDITIONAL(USE_LIBTPMTSS, test x$tss_trousers = xtrue -o x$tss_tss2 = xtrue -o x$aikgen = xtrue -o x$aikpub2 = xtrue -o x$imcv = xtrue)
1641 AM_CONDITIONAL(USE_FILE_CONFIG, test x$stroke = xtrue)
1642 AM_CONDITIONAL(USE_IPSEC_SCRIPT, test x$stroke = xtrue -o x$scepclient = xtrue -o x$conftest = xtrue)
1643 AM_CONDITIONAL(USE_LIBCAP, test x$capabilities = xlibcap)
1644 AM_CONDITIONAL(USE_VSTR, test x$printf_hooks = xvstr)
1645 AM_CONDITIONAL(USE_BUILTIN_PRINTF, test x$printf_hooks = xbuiltin)
1646 AM_CONDITIONAL(USE_SIMAKA, test x$simaka = xtrue)
1647 AM_CONDITIONAL(USE_TLS, test x$tls = xtrue)
1648 AM_CONDITIONAL(USE_RADIUS, test x$radius = xtrue)
1649 AM_CONDITIONAL(USE_IMCV, test x$imcv = xtrue)
1650 AM_CONDITIONAL(USE_TROUSERS, test x$tss_trousers = xtrue)
1651 AM_CONDITIONAL(USE_TSS2, test x$tss_tss2 = xtrue)
1652 AM_CONDITIONAL(MONOLITHIC, test x$monolithic = xtrue)
1653 AM_CONDITIONAL(USE_SILENT_RULES, test x$enable_silent_rules = xyes)
1654 AM_CONDITIONAL(COVERAGE, test x$coverage = xtrue)
1655 AM_CONDITIONAL(USE_DBGHELP, test x$dbghelp_backtraces = xtrue)
1656 AM_CONDITIONAL(USE_TKM, test x$tkm = xtrue)
1657 AM_CONDITIONAL(USE_CMD, test x$cmd = xtrue)
1658 AM_CONDITIONAL(USE_AIKGEN, test x$aikgen = xtrue)
1659 AM_CONDITIONAL(USE_AIKPUB2, test x$aikpub2 = xtrue)
1660 AM_CONDITIONAL(USE_SWANCTL, test x$swanctl = xtrue)
1661 AM_CONDITIONAL(USE_SVC, test x$svc = xtrue)
1662 AM_CONDITIONAL(USE_SYSTEMD, test x$systemd = xtrue)
1663 AM_CONDITIONAL(USE_LEGACY_SYSTEMD, test -n "$systemdsystemunitdir" -a "x$systemdsystemunitdir" != xno)
1664 AM_CONDITIONAL(USE_RUBY_GEMS, test x$ruby_gems = xtrue)
1665 AM_CONDITIONAL(USE_PYTHON_EGGS, test x$python_eggs = xtrue)
1666 AM_CONDITIONAL(USE_PERL_CPAN, test x$perl_cpan = xtrue)
1667 AM_CONDITIONAL(USE_PY_TEST, test "x$PY_TEST" != x)
1668
1669 # ========================
1670 #  set global definitions
1671 # ========================
1672
1673 if test x$mediation = xtrue; then
1674         AC_DEFINE([ME], [], [mediation extension support])
1675 fi
1676 if test x$capabilities = xlibcap -o x$capabilities = xnative; then
1677         AC_DEFINE([CAPABILITIES], [], [capability dropping support])
1678 fi
1679 if test x$log_thread_ids = xtrue; then
1680         AC_DEFINE([USE_THREAD_IDS], [], [use thread ID for thread identification, if available])
1681 fi
1682 if test x$monolithic = xtrue; then
1683         AC_DEFINE([MONOLITHIC], [], [monolithic build embedding plugins])
1684 fi
1685 if test x$ikev1 = xtrue; then
1686         AC_DEFINE([USE_IKEV1], [], [support for IKEv1 protocol])
1687 fi
1688 if test x$ikev2 = xtrue; then
1689         AC_DEFINE([USE_IKEV2], [], [support for IKEv2 protocol])
1690 fi
1691
1692 # ====================================================
1693 #  options for enabled modules (see conf/Makefile.am)
1694 # ====================================================
1695
1696 strongswan_options=
1697
1698 AM_COND_IF([USE_AIKGEN], [strongswan_options=${strongswan_options}" aikgen"])
1699 AM_COND_IF([USE_AIKPUB2], [strongswan_options=${strongswan_options}" aikpub2"])
1700 AM_COND_IF([USE_ATTR_SQL], [strongswan_options=${strongswan_options}" pool"])
1701 AM_COND_IF([USE_CHARON], [strongswan_options=${strongswan_options}" charon charon-logging"])
1702 AM_COND_IF([USE_FILE_CONFIG], [strongswan_options=${strongswan_options}" starter"])
1703 AM_COND_IF([USE_IMV_ATTESTATION], [strongswan_options=${strongswan_options}" attest"])
1704 AM_COND_IF([USE_IMCV], [strongswan_options=${strongswan_options}" imcv"])
1705 AM_COND_IF([USE_IMV_OS], [strongswan_options=${strongswan_options}" pacman"])
1706 AM_COND_IF([USE_LIBTNCCS], [strongswan_options=${strongswan_options}" tnc"])
1707 AM_COND_IF([USE_MANAGER], [strongswan_options=${strongswan_options}" manager"])
1708 AM_COND_IF([USE_MEDSRV], [strongswan_options=${strongswan_options}" medsrv"])
1709 AM_COND_IF([USE_SCEPCLIENT], [strongswan_options=${strongswan_options}" scepclient"])
1710 AM_COND_IF([USE_PKI], [strongswan_options=${strongswan_options}" pki"])
1711 AM_COND_IF([USE_SWANCTL], [strongswan_options=${strongswan_options}" swanctl"])
1712
1713 AC_SUBST(strongswan_options)
1714
1715 # =================
1716 #  build Makefiles
1717 # =================
1718
1719 AC_CONFIG_FILES([
1720         Makefile
1721         conf/Makefile
1722         man/Makefile
1723         init/Makefile
1724         init/systemd/Makefile
1725         init/systemd-swanctl/Makefile
1726         src/Makefile
1727         src/include/Makefile
1728         src/libstrongswan/Makefile
1729         src/libstrongswan/math/libnttfft/Makefile
1730         src/libstrongswan/math/libnttfft/tests/Makefile
1731         src/libstrongswan/plugins/aes/Makefile
1732         src/libstrongswan/plugins/cmac/Makefile
1733         src/libstrongswan/plugins/des/Makefile
1734         src/libstrongswan/plugins/blowfish/Makefile
1735         src/libstrongswan/plugins/rc2/Makefile
1736         src/libstrongswan/plugins/md4/Makefile
1737         src/libstrongswan/plugins/md5/Makefile
1738         src/libstrongswan/plugins/sha1/Makefile
1739         src/libstrongswan/plugins/sha2/Makefile
1740         src/libstrongswan/plugins/sha3/Makefile
1741         src/libstrongswan/plugins/fips_prf/Makefile
1742         src/libstrongswan/plugins/gmp/Makefile
1743         src/libstrongswan/plugins/rdrand/Makefile
1744         src/libstrongswan/plugins/aesni/Makefile
1745         src/libstrongswan/plugins/random/Makefile
1746         src/libstrongswan/plugins/nonce/Makefile
1747         src/libstrongswan/plugins/hmac/Makefile
1748         src/libstrongswan/plugins/xcbc/Makefile
1749         src/libstrongswan/plugins/x509/Makefile
1750         src/libstrongswan/plugins/revocation/Makefile
1751         src/libstrongswan/plugins/constraints/Makefile
1752         src/libstrongswan/plugins/acert/Makefile
1753         src/libstrongswan/plugins/pubkey/Makefile
1754         src/libstrongswan/plugins/pkcs1/Makefile
1755         src/libstrongswan/plugins/pkcs7/Makefile
1756         src/libstrongswan/plugins/pkcs8/Makefile
1757         src/libstrongswan/plugins/pkcs12/Makefile
1758         src/libstrongswan/plugins/pgp/Makefile
1759         src/libstrongswan/plugins/dnskey/Makefile
1760         src/libstrongswan/plugins/sshkey/Makefile
1761         src/libstrongswan/plugins/pem/Makefile
1762         src/libstrongswan/plugins/curl/Makefile
1763         src/libstrongswan/plugins/files/Makefile
1764         src/libstrongswan/plugins/winhttp/Makefile
1765         src/libstrongswan/plugins/unbound/Makefile
1766         src/libstrongswan/plugins/soup/Makefile
1767         src/libstrongswan/plugins/ldap/Makefile
1768         src/libstrongswan/plugins/mysql/Makefile
1769         src/libstrongswan/plugins/sqlite/Makefile
1770         src/libstrongswan/plugins/padlock/Makefile
1771         src/libstrongswan/plugins/openssl/Makefile
1772         src/libstrongswan/plugins/gcrypt/Makefile
1773         src/libstrongswan/plugins/agent/Makefile
1774         src/libstrongswan/plugins/keychain/Makefile
1775         src/libstrongswan/plugins/pkcs11/Makefile
1776         src/libstrongswan/plugins/chapoly/Makefile
1777         src/libstrongswan/plugins/ctr/Makefile
1778         src/libstrongswan/plugins/ccm/Makefile
1779         src/libstrongswan/plugins/gcm/Makefile
1780         src/libstrongswan/plugins/af_alg/Makefile
1781         src/libstrongswan/plugins/ntru/Makefile
1782         src/libstrongswan/plugins/bliss/Makefile
1783         src/libstrongswan/plugins/bliss/tests/Makefile
1784         src/libstrongswan/plugins/newhope/Makefile
1785         src/libstrongswan/plugins/newhope/tests/Makefile
1786         src/libstrongswan/plugins/test_vectors/Makefile
1787         src/libstrongswan/tests/Makefile
1788         src/libipsec/Makefile
1789         src/libipsec/tests/Makefile
1790         src/libsimaka/Makefile
1791         src/libtls/Makefile
1792         src/libtls/tests/Makefile
1793         src/libradius/Makefile
1794         src/libtncif/Makefile
1795         src/libtnccs/Makefile
1796         src/libtnccs/plugins/tnc_tnccs/Makefile
1797         src/libtnccs/plugins/tnc_imc/Makefile
1798         src/libtnccs/plugins/tnc_imv/Makefile
1799         src/libtnccs/plugins/tnccs_11/Makefile
1800         src/libtnccs/plugins/tnccs_20/Makefile
1801         src/libtnccs/plugins/tnccs_dynamic/Makefile
1802         src/libpttls/Makefile
1803         src/libimcv/Makefile
1804         src/libimcv/plugins/imc_test/Makefile
1805         src/libimcv/plugins/imv_test/Makefile
1806         src/libimcv/plugins/imc_scanner/Makefile
1807         src/libimcv/plugins/imv_scanner/Makefile
1808         src/libimcv/plugins/imc_os/Makefile
1809         src/libimcv/plugins/imv_os/Makefile
1810         src/libimcv/plugins/imc_attestation/Makefile
1811         src/libimcv/plugins/imv_attestation/Makefile
1812         src/libimcv/plugins/imc_swid/Makefile
1813         src/libimcv/plugins/imv_swid/Makefile
1814         src/libimcv/plugins/imc_hcd/Makefile
1815         src/libimcv/plugins/imv_hcd/Makefile
1816         src/charon/Makefile
1817         src/charon-nm/Makefile
1818         src/charon-tkm/Makefile
1819         src/charon-cmd/Makefile
1820         src/charon-svc/Makefile
1821         src/charon-systemd/Makefile
1822         src/libcharon/Makefile
1823         src/libcharon/plugins/eap_aka/Makefile
1824         src/libcharon/plugins/eap_aka_3gpp2/Makefile
1825         src/libcharon/plugins/eap_dynamic/Makefile
1826         src/libcharon/plugins/eap_identity/Makefile
1827         src/libcharon/plugins/eap_md5/Makefile
1828         src/libcharon/plugins/eap_gtc/Makefile
1829         src/libcharon/plugins/eap_sim/Makefile
1830         src/libcharon/plugins/eap_sim_file/Makefile
1831         src/libcharon/plugins/eap_sim_pcsc/Makefile
1832         src/libcharon/plugins/eap_simaka_sql/Makefile
1833         src/libcharon/plugins/eap_simaka_pseudonym/Makefile
1834         src/libcharon/plugins/eap_simaka_reauth/Makefile
1835         src/libcharon/plugins/eap_mschapv2/Makefile
1836         src/libcharon/plugins/eap_tls/Makefile
1837         src/libcharon/plugins/eap_ttls/Makefile
1838         src/libcharon/plugins/eap_peap/Makefile
1839         src/libcharon/plugins/eap_tnc/Makefile
1840         src/libcharon/plugins/eap_radius/Makefile
1841         src/libcharon/plugins/xauth_generic/Makefile
1842         src/libcharon/plugins/xauth_eap/Makefile
1843         src/libcharon/plugins/xauth_pam/Makefile
1844         src/libcharon/plugins/xauth_noauth/Makefile
1845         src/libcharon/plugins/tnc_ifmap/Makefile
1846         src/libcharon/plugins/tnc_pdp/Makefile
1847         src/libcharon/plugins/socket_default/Makefile
1848         src/libcharon/plugins/socket_dynamic/Makefile
1849         src/libcharon/plugins/socket_win/Makefile
1850         src/libcharon/plugins/connmark/Makefile
1851         src/libcharon/plugins/forecast/Makefile
1852         src/libcharon/plugins/farp/Makefile
1853         src/libcharon/plugins/smp/Makefile
1854         src/libcharon/plugins/sql/Makefile
1855         src/libcharon/plugins/dnscert/Makefile
1856         src/libcharon/plugins/ipseckey/Makefile
1857         src/libcharon/plugins/medsrv/Makefile
1858         src/libcharon/plugins/medcli/Makefile
1859         src/libcharon/plugins/addrblock/Makefile
1860         src/libcharon/plugins/unity/Makefile
1861         src/libcharon/plugins/uci/Makefile
1862         src/libcharon/plugins/ha/Makefile
1863         src/libcharon/plugins/kernel_netlink/Makefile
1864         src/libcharon/plugins/kernel_pfkey/Makefile
1865         src/libcharon/plugins/kernel_pfroute/Makefile
1866         src/libcharon/plugins/kernel_libipsec/Makefile
1867         src/libcharon/plugins/kernel_wfp/Makefile
1868         src/libcharon/plugins/kernel_iph/Makefile
1869         src/libcharon/plugins/whitelist/Makefile
1870         src/libcharon/plugins/ext_auth/Makefile
1871         src/libcharon/plugins/lookip/Makefile
1872         src/libcharon/plugins/error_notify/Makefile
1873         src/libcharon/plugins/certexpire/Makefile
1874         src/libcharon/plugins/systime_fix/Makefile
1875         src/libcharon/plugins/led/Makefile
1876         src/libcharon/plugins/duplicheck/Makefile
1877         src/libcharon/plugins/coupling/Makefile
1878         src/libcharon/plugins/radattr/Makefile
1879         src/libcharon/plugins/osx_attr/Makefile
1880         src/libcharon/plugins/p_cscf/Makefile
1881         src/libcharon/plugins/android_dns/Makefile
1882         src/libcharon/plugins/android_log/Makefile
1883         src/libcharon/plugins/maemo/Makefile
1884         src/libcharon/plugins/stroke/Makefile
1885         src/libcharon/plugins/vici/Makefile
1886         src/libcharon/plugins/vici/ruby/Makefile
1887         src/libcharon/plugins/vici/perl/Makefile
1888         src/libcharon/plugins/vici/python/Makefile
1889         src/libcharon/plugins/updown/Makefile
1890         src/libcharon/plugins/dhcp/Makefile
1891         src/libcharon/plugins/load_tester/Makefile
1892         src/libcharon/plugins/resolve/Makefile
1893         src/libcharon/plugins/attr/Makefile
1894         src/libcharon/plugins/attr_sql/Makefile
1895         src/libcharon/tests/Makefile
1896         src/libtpmtss/Makefile
1897         src/stroke/Makefile
1898         src/ipsec/Makefile
1899         src/starter/Makefile
1900         src/starter/tests/Makefile
1901         src/_updown/Makefile
1902         src/_copyright/Makefile
1903         src/scepclient/Makefile
1904         src/aikgen/Makefile
1905         src/aikpub2/Makefile
1906         src/pki/Makefile
1907         src/pki/man/Makefile
1908         src/pool/Makefile
1909         src/dumm/Makefile
1910         src/dumm/ext/extconf.rb
1911         src/libfast/Makefile
1912         src/manager/Makefile
1913         src/medsrv/Makefile
1914         src/checksum/Makefile
1915         src/conftest/Makefile
1916         src/pt-tls-client/Makefile
1917         src/swanctl/Makefile
1918         scripts/Makefile
1919         testing/Makefile
1920 ])
1921
1922 # =================
1923 #  build man pages
1924 # =================
1925
1926 AC_CONFIG_FILES([
1927         conf/strongswan.conf.5.head
1928         conf/strongswan.conf.5.tail
1929         man/ipsec.conf.5
1930         man/ipsec.secrets.5
1931         src/charon-cmd/charon-cmd.8
1932         src/pki/man/pki.1
1933         src/pki/man/pki---acert.1
1934         src/pki/man/pki---dn.1
1935         src/pki/man/pki---gen.1
1936         src/pki/man/pki---issue.1
1937         src/pki/man/pki---keyid.1
1938         src/pki/man/pki---pkcs12.1
1939         src/pki/man/pki---pkcs7.1
1940         src/pki/man/pki---print.1
1941         src/pki/man/pki---pub.1
1942         src/pki/man/pki---req.1
1943         src/pki/man/pki---self.1
1944         src/pki/man/pki---signcrl.1
1945         src/pki/man/pki---verify.1
1946         src/swanctl/swanctl.8
1947         src/swanctl/swanctl.conf.5.head
1948         src/swanctl/swanctl.conf.5.tail
1949 ])
1950
1951 AC_OUTPUT
1952
1953 # ========================
1954 #  report enabled plugins
1955 # ========================
1956
1957 AC_MSG_RESULT([])
1958 AC_MSG_RESULT([ strongSwan will be built with the following plugins])
1959 AC_MSG_RESULT([-----------------------------------------------------])
1960
1961 AC_MSG_RESULT([libstrongswan:$s_plugins])
1962 AC_MSG_RESULT([libcharon:    $c_plugins])
1963 AC_MSG_RESULT([libtnccs:     $t_plugins])
1964 AC_MSG_RESULT([])