configure: Check if __attribute__((packed)) works as expected
[strongswan.git] / configure.ac
1 #
2 # Copyright (C) 2007-2014 Tobias Brunner
3 # Copyright (C) 2006-2013 Andreas Steffen
4 # Copyright (C) 2006-2013 Martin Willi
5 # Hochschule fuer Technik Rapperswil
6 #
7 # This program is free software; you can redistribute it and/or modify it
8 # under the terms of the GNU General Public License as published by the
9 # Free Software Foundation; either version 2 of the License, or (at your
10 # option) any later version.  See <http://www.fsf.org/copyleft/gpl.txt>.
11 #
12 # This program is distributed in the hope that it will be useful, but
13 # WITHOUT ANY WARRANTY; without even the implied warranty of MERCHANTABILITY
14 # or FITNESS FOR A PARTICULAR PURPOSE.  See the GNU General Public License
15 # for more details.
16 #
17
18 # ============================
19 #  initialize & set some vars
20 # ============================
21
22 AC_INIT([strongSwan],[5.2.0dr5])
23 AM_INIT_AUTOMAKE(m4_esyscmd([
24         echo tar-ustar
25         echo subdir-objects
26         case `automake --version | head -n 1` in
27                 *" 1.9"*);;
28                 *" 1.10"*);;
29                 *" 1.11"*);;
30                 # don't use parallel test harness in 1.12 and up
31                 *) echo serial-tests;;
32         esac
33 ]))
34 m4_ifdef([AM_SILENT_RULES], [AM_SILENT_RULES])
35 AC_CONFIG_MACRO_DIR([m4/config])
36 AC_CONFIG_HEADERS([config.h])
37 AC_DEFINE([CONFIG_H_INCLUDED], [], [defined if config.h included])
38 PKG_PROG_PKG_CONFIG
39
40 m4_include(m4/macros/split-package-version.m4)
41 SPLIT_PACKAGE_VERSION
42
43 # =================================
44 #  check --enable-xxx & --with-xxx
45 # =================================
46
47 m4_include(m4/macros/with.m4)
48
49 ARG_WITH_SUBST([random-device],      [/dev/random], [set the device to read real random data from])
50 ARG_WITH_SUBST([urandom-device],     [/dev/urandom], [set the device to read pseudo random data from])
51 ARG_WITH_SUBST([strongswan-conf],    [${sysconfdir}/strongswan.conf], [set the strongswan.conf file location])
52 ARG_WITH_SUBST([resolv-conf],        [${sysconfdir}/resolv.conf], [set the file to use in DNS handler plugin])
53 ARG_WITH_SUBST([piddir],             [/var/run], [set path for PID and UNIX socket files])
54 ARG_WITH_SUBST([ipsecdir],           [${libexecdir%/}/ipsec], [set installation path for ipsec tools])
55 ARG_WITH_SUBST([ipseclibdir],        [${libdir%/}/ipsec], [set installation path for ipsec libraries])
56 ARG_WITH_SUBST([plugindir],          [${ipseclibdir%/}/plugins], [set the installation path of plugins])
57 ARG_WITH_SUBST([imcvdir],            [${ipseclibdir%/}/imcvs], [set the installation path of IMC and IMV dynamic librariers])
58 ARG_WITH_SUBST([nm-ca-dir],          [/usr/share/ca-certificates], [directory the NM backend uses to look up trusted root certificates])
59 ARG_WITH_SUBST([swanctldir],         [${sysconfdir}/swanctl], [base directory for swanctl configuration files and credentials])
60 ARG_WITH_SUBST([linux-headers],      [\${top_srcdir}/src/include], [set directory of linux header files to use])
61 ARG_WITH_SUBST([routing-table],      [220], [set routing table to use for IPsec routes])
62 ARG_WITH_SUBST([routing-table-prio], [220], [set priority for IPsec routing table])
63 ARG_WITH_SUBST([ipsec-script],       [ipsec], [change the name of the ipsec script])
64 ARG_WITH_SUBST([fips-mode],          [0], [set openssl FIPS mode: disabled(0), enabled(1), Suite B enabled(2)])
65
66 ARG_WITH_SET([tss],                  [no], [set implementation of the Trusted Computing Group's Software Stack (TSS). Currently the only supported value is "trousers"])
67 ARG_WITH_SET([capabilities],         [no], [set capability dropping library. Currently supported values are "libcap" and "native"])
68 ARG_WITH_SET([mpz_powm_sec],         [yes], [use the more side-channel resistant mpz_powm_sec in libgmp, if available])
69 ARG_WITH_SET([dev-headers],          [no], [install strongSwan development headers to directory.])
70 ARG_WITH_SET([printf-hooks],         [auto], [force the use of a specific printf hook implementation (auto, builtin, glibc, vstr).])
71
72 if test -n "$PKG_CONFIG"; then
73         systemdsystemunitdir_default=$($PKG_CONFIG --variable=systemdsystemunitdir systemd)
74 fi
75 ARG_WITH_SET([systemdsystemunitdir], [$systemdsystemunitdir_default], [directory for systemd service files])
76 AM_CONDITIONAL(HAVE_SYSTEMD, [test -n "$systemdsystemunitdir" -a "x$systemdsystemunitdir" != xno])
77 AC_SUBST(systemdsystemunitdir)
78
79 AC_ARG_WITH(
80         [user],
81         AS_HELP_STRING([--with-user=user],[change user of the daemons to "user" after startup (default is "root").]),
82         [AC_DEFINE_UNQUOTED([IPSEC_USER], "$withval", [username to run daemon with])
83          AC_SUBST(ipsecuser, "$withval")],
84         [AC_SUBST(ipsecuser, "root")]
85 )
86
87 AC_ARG_WITH(
88         [group],
89         AS_HELP_STRING([--with-group=group],[change group of the daemons to "group" after startup (default is "root").]),
90         [AC_DEFINE_UNQUOTED(IPSEC_GROUP, "$withval", [groupname to run daemon with])
91          AC_SUBST(ipsecgroup, "$withval")],
92         [AC_SUBST(ipsecgroup, "root")]
93 )
94
95 AC_ARG_WITH(
96         [charon-udp-port],
97         AS_HELP_STRING([--with-charon-udp-port=port],[UDP port used by charon locally (default 500). Set to 0 to allocate randomly.]),
98         [AC_DEFINE_UNQUOTED(CHARON_UDP_PORT, [$withval], [UDP port used by charon locally])
99          AC_SUBST(charon_udp_port, [$withval])],
100         [AC_SUBST(charon_udp_port, 500)]
101 )
102
103 AC_ARG_WITH(
104         [charon-natt-port],
105         AS_HELP_STRING([--with-charon-natt-port=port],[UDP port used by charon locally in case a NAT is detected (must be different from charon-udp-port, default 4500). Set to 0 to allocate randomly.]),
106         [AC_DEFINE_UNQUOTED(CHARON_NATT_PORT, [$withval], [UDP post used by charon locally in case a NAT is detected])
107          AC_SUBST(charon_natt_port, [$withval])],
108         [AC_SUBST(charon_natt_port, 4500)]
109 )
110
111 AC_MSG_CHECKING([configured UDP ports ($charon_udp_port, $charon_natt_port)])
112 if test x$charon_udp_port != x0 -a x$charon_udp_port = x$charon_natt_port; then
113         AC_MSG_ERROR(the ports have to be different)
114 else
115         AC_MSG_RESULT(ok)
116 fi
117
118 # convert script name to uppercase
119 AC_SUBST(ipsec_script_upper, [`echo -n "$ipsec_script" | tr a-z A-Z`])
120
121 m4_include(m4/macros/enable-disable.m4)
122
123 # crypto plugins
124 ARG_DISBL_SET([aes],            [disable AES software implementation plugin.])
125 ARG_ENABL_SET([af-alg],         [enable AF_ALG crypto interface to Linux Crypto API.])
126 ARG_ENABL_SET([blowfish],       [enable Blowfish software implementation plugin.])
127 ARG_ENABL_SET([ccm],            [enables the CCM AEAD wrapper crypto plugin.])
128 ARG_DISBL_SET([cmac],           [disable CMAC crypto implementation plugin.])
129 ARG_ENABL_SET([ctr],            [enables the Counter Mode wrapper crypto plugin.])
130 ARG_DISBL_SET([des],            [disable DES/3DES software implementation plugin.])
131 ARG_DISBL_SET([fips-prf],       [disable FIPS PRF software implementation plugin.])
132 ARG_ENABL_SET([gcm],            [enables the GCM AEAD wrapper crypto plugin.])
133 ARG_ENABL_SET([gcrypt],         [enables the libgcrypt plugin.])
134 ARG_DISBL_SET([gmp],            [disable GNU MP (libgmp) based crypto implementation plugin.])
135 ARG_DISBL_SET([hmac],           [disable HMAC crypto implementation plugin.])
136 ARG_ENABL_SET([md4],            [enable MD4 software implementation plugin.])
137 ARG_DISBL_SET([md5],            [disable MD5 software implementation plugin.])
138 ARG_DISBL_SET([nonce],          [disable nonce generation plugin.])
139 ARG_ENABL_SET([ntru],           [enables the NTRU crypto plugin.])
140 ARG_ENABL_SET([openssl],        [enables the OpenSSL crypto plugin.])
141 ARG_ENABL_SET([padlock],        [enables VIA Padlock crypto plugin.])
142 ARG_DISBL_SET([random],         [disable RNG implementation on top of /dev/(u)random.])
143 ARG_DISBL_SET([rc2],            [disable RC2 software implementation plugin.])
144 ARG_ENABL_SET([rdrand],         [enable Intel RDRAND random generator plugin.])
145 ARG_DISBL_SET([sha1],           [disable SHA1 software implementation plugin.])
146 ARG_DISBL_SET([sha2],           [disable SHA256/SHA384/SHA512 software implementation plugin.])
147 ARG_DISBL_SET([xcbc],           [disable xcbc crypto implementation plugin.])
148 # encoding/decoding plugins
149 ARG_DISBL_SET([dnskey],         [disable DNS RR key decoding plugin.])
150 ARG_DISBL_SET([pem],            [disable PEM decoding plugin.])
151 ARG_DISBL_SET([pgp],            [disable PGP key decoding plugin.])
152 ARG_DISBL_SET([pkcs1],          [disable PKCS1 key decoding plugin.])
153 ARG_DISBL_SET([pkcs7],          [disable PKCS7 container support plugin.])
154 ARG_DISBL_SET([pkcs8],          [disable PKCS8 private key decoding plugin.])
155 ARG_DISBL_SET([pkcs12],         [disable PKCS12 container support plugin.])
156 ARG_DISBL_SET([pubkey],         [disable RAW public key support plugin.])
157 ARG_DISBL_SET([sshkey],         [disable SSH key decoding plugin.])
158 ARG_DISBL_SET([x509],           [disable X509 certificate implementation plugin.])
159 # fetcher/resolver plugins
160 ARG_ENABL_SET([curl],           [enable CURL fetcher plugin to fetch files via libcurl. Requires libcurl.])
161 ARG_ENABL_SET([ldap],           [enable LDAP fetching plugin to fetch files via libldap. Requires openLDAP.])
162 ARG_ENABL_SET([soup],           [enable soup fetcher plugin to fetch from HTTP via libsoup. Requires libsoup.])
163 ARG_ENABL_SET([unbound],        [enable UNBOUND resolver plugin to perform DNS queries via libunbound. Requires libldns and libunbound.])
164 # database plugins
165 ARG_ENABL_SET([mysql],          [enable MySQL database support. Requires libmysqlclient_r.])
166 ARG_ENABL_SET([sqlite],         [enable SQLite database support. Requires libsqlite3.])
167 # authentication/credential plugins
168 ARG_ENABL_SET([addrblock],      [enables RFC 3779 address block constraint support.])
169 ARG_ENABL_SET([acert],          [enable X509 attribute certificate checking plugin.])
170 ARG_ENABL_SET([agent],          [enables the ssh-agent signing plugin.])
171 ARG_DISBL_SET([constraints],    [disable advanced X509 constraint checking plugin.])
172 ARG_ENABL_SET([coupling],       [enable IKEv2 plugin to couple peer certificates permanently to authentication.])
173 ARG_ENABL_SET([dnscert],        [enable DNSCERT authentication plugin.])
174 ARG_ENABL_SET([eap-sim],        [enable SIM authentication module for EAP.])
175 ARG_ENABL_SET([eap-sim-file],   [enable EAP-SIM backend based on a triplet file.])
176 ARG_ENABL_SET([eap-sim-pcsc],   [enable EAP-SIM backend based on a smartcard reader. Requires libpcsclite.])
177 ARG_ENABL_SET([eap-aka],        [enable EAP AKA authentication module.])
178 ARG_ENABL_SET([eap-aka-3gpp2],  [enable EAP AKA backend implementing 3GPP2 algorithms in software. Requires libgmp.])
179 ARG_ENABL_SET([eap-simaka-sql], [enable EAP-SIM/AKA backend based on a triplet/quintuplet SQL database.])
180 ARG_ENABL_SET([eap-simaka-pseudonym], [enable EAP-SIM/AKA pseudonym storage plugin.])
181 ARG_ENABL_SET([eap-simaka-reauth],    [enable EAP-SIM/AKA reauthentication data storage plugin.])
182 ARG_ENABL_SET([eap-identity],   [enable EAP module providing EAP-Identity helper.])
183 ARG_ENABL_SET([eap-md5],        [enable EAP MD5 (CHAP) authentication module.])
184 ARG_ENABL_SET([eap-gtc],        [enable EAP GTC authentication module.])
185 ARG_ENABL_SET([eap-mschapv2],   [enable EAP MS-CHAPv2 authentication module.])
186 ARG_ENABL_SET([eap-tls],        [enable EAP TLS authentication module.])
187 ARG_ENABL_SET([eap-ttls],       [enable EAP TTLS authentication module.])
188 ARG_ENABL_SET([eap-peap],       [enable EAP PEAP authentication module.])
189 ARG_ENABL_SET([eap-tnc],        [enable EAP TNC trusted network connect module.])
190 ARG_ENABL_SET([eap-dynamic],    [enable dynamic EAP proxy module.])
191 ARG_ENABL_SET([eap-radius],     [enable RADIUS proxy authentication module.])
192 ARG_ENABL_SET([ipseckey],       [enable IPSECKEY authentication plugin.])
193 ARG_ENABL_SET([keychain],       [enables OS X Keychain Services credential set.])
194 ARG_ENABL_SET([pkcs11],         [enables the PKCS11 token support plugin.])
195 ARG_DISBL_SET([revocation],     [disable X509 CRL/OCSP revocation check plugin.])
196 ARG_ENABL_SET([whitelist],      [enable peer identity whitelisting plugin.])
197 ARG_DISBL_SET([xauth-generic],  [disable generic XAuth backend.])
198 ARG_ENABL_SET([xauth-eap],      [enable XAuth backend using EAP methods to verify passwords.])
199 ARG_ENABL_SET([xauth-pam],      [enable XAuth backend using PAM to verify passwords.])
200 ARG_ENABL_SET([xauth-noauth],   [enable XAuth pseudo-backend that does not actually verify or even request any credentials.])
201 # kernel interfaces / sockets
202 ARG_DISBL_SET([kernel-netlink], [disable the netlink kernel interface.])
203 ARG_ENABL_SET([kernel-pfkey],   [enable the PF_KEY kernel interface.])
204 ARG_ENABL_SET([kernel-pfroute], [enable the PF_ROUTE kernel interface.])
205 ARG_ENABL_SET([kernel-klips],   [enable the KLIPS kernel interface.])
206 ARG_ENABL_SET([kernel-libipsec],[enable the libipsec kernel interface.])
207 ARG_DISBL_SET([socket-default], [disable default socket implementation for charon.])
208 ARG_ENABL_SET([socket-dynamic], [enable dynamic socket implementation for charon])
209 # configuration/control plugins
210 ARG_DISBL_SET([stroke],         [disable charons stroke configuration backend.])
211 ARG_ENABL_SET([smp],            [enable SMP configuration and control interface. Requires libxml.])
212 ARG_ENABL_SET([sql],            [enable SQL database configuration backend.])
213 ARG_ENABL_SET([uci],            [enable OpenWRT UCI configuration plugin.])
214 ARG_ENABL_SET([vici],           [enable strongSwan IKE generic IPC interface plugin.])
215 # attribute provider/consumer plugins
216 ARG_ENABL_SET([android-dns],    [enable Android specific DNS handler.])
217 ARG_DISBL_SET([attr],           [disable strongswan.conf based configuration attribute plugin.])
218 ARG_ENABL_SET([attr-sql],       [enable SQL based configuration attribute plugin.])
219 ARG_ENABL_SET([dhcp],           [enable DHCP based attribute provider plugin.])
220 ARG_ENABL_SET([osx-attr],       [enable OS X SystemConfiguration attribute handler.])
221 ARG_DISBL_SET([resolve],        [disable resolve DNS handler plugin.])
222 ARG_ENABL_SET([unity],          [enables Cisco Unity extension plugin.])
223 # TNC modules/plugins
224 ARG_ENABL_SET([imc-test],       [enable IMC test module.])
225 ARG_ENABL_SET([imv-test],       [enable IMV test module.])
226 ARG_ENABL_SET([imc-scanner],    [enable IMC port scanner module.])
227 ARG_ENABL_SET([imv-scanner],    [enable IMV port scanner module.])
228 ARG_ENABL_SET([imc-os],         [enable IMC operating system module.])
229 ARG_ENABL_SET([imv-os],         [enable IMV operating system module.])
230 ARG_ENABL_SET([imc-attestation],[enable IMC attestation module.])
231 ARG_ENABL_SET([imv-attestation],[enable IMV attestation module.])
232 ARG_ENABL_SET([imc-swid],       [enable IMC swid module.])
233 ARG_ENABL_SET([imv-swid],       [enable IMV swid module.])
234 ARG_ENABL_SET([tnc-ifmap],      [enable TNC IF-MAP module. Requires libxml])
235 ARG_ENABL_SET([tnc-imc],        [enable TNC IMC module.])
236 ARG_ENABL_SET([tnc-imv],        [enable TNC IMV module.])
237 ARG_ENABL_SET([tnc-pdp],        [enable TNC policy decision point module.])
238 ARG_ENABL_SET([tnccs-11],       [enable TNCCS 1.1 protocol module. Requires libxml])
239 ARG_ENABL_SET([tnccs-20],       [enable TNCCS 2.0 protocol module.])
240 ARG_ENABL_SET([tnccs-dynamic],  [enable dynamic TNCCS protocol discovery module.])
241 # misc plugins
242 ARG_ENABL_SET([android-log],    [enable Android specific logger plugin.])
243 ARG_ENABL_SET([certexpire],     [enable CSV export of expiration dates of used certificates.])
244 ARG_ENABL_SET([duplicheck],     [advanced duplicate checking plugin using liveness checks.])
245 ARG_ENABL_SET([error-notify],   [enable error notification plugin.])
246 ARG_ENABL_SET([farp],           [enable ARP faking plugin that responds to ARP requests to peers virtual IP])
247 ARG_ENABL_SET([ha],             [enable high availability cluster plugin.])
248 ARG_ENABL_SET([led],            [enable plugin to control LEDs on IKEv2 activity using the Linux kernel LED subsystem.])
249 ARG_ENABL_SET([load-tester],    [enable load testing plugin for IKEv2 daemon.])
250 ARG_ENABL_SET([lookip],         [enable fast virtual IP lookup and notification plugin.])
251 ARG_ENABL_SET([maemo],          [enable Maemo specific plugin.])
252 ARG_ENABL_SET([radattr],        [enable plugin to inject and process custom RADIUS attributes as IKEv2 client.])
253 ARG_ENABL_SET([systime-fix],    [enable plugin to handle cert lifetimes with invalid system time gracefully.])
254 ARG_ENABL_SET([test-vectors],   [enable plugin providing crypto test vectors.])
255 ARG_ENABL_SET([unit-tester],    [enable unit tests on IKEv2 daemon startup.])
256 ARG_DISBL_SET([updown],         [disable updown firewall script plugin.])
257 # programs/components
258 ARG_DISBL_SET([charon],         [disable the IKEv1/IKEv2 keying daemon charon.])
259 ARG_ENABL_SET([cmd],            [enable the command line IKE client charon-cmd.])
260 ARG_ENABL_SET([conftest],       [enforce Suite B conformance test framework.])
261 ARG_ENABL_SET([dumm],           [enable the DUMM UML test framework.])
262 ARG_ENABL_SET([fast],           [enable libfast (FastCGI Application Server w/ templates.])
263 ARG_ENABL_SET([libipsec],       [enable user space IPsec implementation.])
264 ARG_ENABL_SET([manager],        [enable web management console (proof of concept).])
265 ARG_ENABL_SET([medcli],         [enable mediation client configuration database plugin.])
266 ARG_ENABL_SET([medsrv],         [enable mediation server web frontend and daemon plugin.])
267 ARG_ENABL_SET([nm],             [enable NetworkManager backend.])
268 ARG_DISBL_SET([scripts],        [disable additional utilities (found in directory scripts).])
269 ARG_ENABL_SET([svc],            [enable charon Windows service.])
270 ARG_ENABL_SET([swanctl],        [enable swanctl configuration and control tool.])
271 ARG_ENABL_SET([tkm],            [enable Trusted Key Manager support.])
272 ARG_DISBL_SET([tools],          [disable additional utilities (scepclient and pki).])
273 ARG_ENABL_SET([aikgen],         [enable AIK generator.])
274 # optional features
275 ARG_ENABL_SET([bfd-backtraces], [use binutils libbfd to resolve backtraces for memory leaks and segfaults.])
276 ARG_ENABL_SET([dbghelp-backtraces],[use dbghlp.dll on Windows to create and print backtraces for memory leaks and segfaults.])
277 ARG_DISBL_SET([ikev1],          [disable IKEv1 protocol support in charon.])
278 ARG_DISBL_SET([ikev2],          [disable IKEv2 protocol support in charon.])
279 ARG_ENABL_SET([integrity-test], [enable integrity testing of libstrongswan and plugins.])
280 ARG_DISBL_SET([load-warning],   [disable the charon plugin load option warning in starter.])
281 ARG_ENABL_SET([mediation],      [enable IKEv2 Mediation Extension.])
282 ARG_ENABL_SET([unwind-backtraces],[use libunwind to create backtraces for memory leaks and segfaults.])
283 # compile options
284 ARG_ENABL_SET([coverage],       [enable lcov coverage report generation.])
285 ARG_ENABL_SET([leak-detective], [enable malloc hooks to find memory leaks.])
286 ARG_ENABL_SET([lock-profiler],  [enable lock/mutex profiling code.])
287 ARG_ENABL_SET([monolithic],     [build monolithic version of libstrongswan that includes all enabled plugins. Similarly, the plugins of charon are assembled in libcharon.])
288
289 # ===================================
290 #  option to disable default options
291 # ===================================
292
293 ARG_DISBL_SET([defaults],       [disable all default plugins (they can be enabled with their respective --enable options)])
294
295 if test x$defaults = xfalse; then
296         for option in $enabled_by_default; do
297                 eval test x\${${option}_given} = xtrue && continue
298                 eval $option=false
299         done
300 fi
301
302 # ==============================
303 #  option to enable all options
304 # ==============================
305
306 ARG_ENABL_SET([all],            [enable all plugins and features (they can be disabled with their respective --disable options). Mainly for testing.])
307
308 if test x$all_given = xtrue; then
309         for option in $disabled_by_default; do
310                 eval test x\${${option}_given} = xtrue && continue
311                 eval $option=true
312         done
313 fi
314
315 # ===========================
316 #  set up compiler and flags
317 # ===========================
318
319 if test -z "$CFLAGS"; then
320         CFLAGS="-g -O2 -Wall -Wno-format -Wno-format-security -Wno-pointer-sign"
321 fi
322 AC_PROG_CC
323 AM_PROG_CC_C_O
324
325 AC_LIB_PREFIX
326 AC_C_BIGENDIAN
327
328 # =========================
329 #  check required programs
330 # =========================
331
332 LT_INIT
333 AC_PROG_INSTALL
334 AC_PROG_EGREP
335 AC_PROG_AWK
336 AC_PROG_LEX
337 AC_PROG_YACC
338 AM_PATH_PYTHON(,,[:])
339 AC_PATH_PROG([PERL], [perl], [], [$PATH:/bin:/usr/bin:/usr/local/bin])
340 AC_PATH_PROG([GPERF], [gperf], [], [$PATH:/bin:/usr/bin:/usr/local/bin])
341
342 # because gperf is not needed by end-users we just report it but do not abort on failure
343 AC_MSG_CHECKING([gperf version >= 3.0.0])
344 if test -x "$GPERF"; then
345         if test "`$GPERF --version | $AWK -F' ' '/^GNU gperf/ { print $3 }' | $AWK -F. '{ print $1 }'`" -ge "3"; then
346                 AC_MSG_RESULT([yes])
347         else
348                 AC_MSG_RESULT([no])
349         fi
350 else
351         AC_MSG_RESULT([not found])
352 fi
353
354 # ========================
355 #  dependency calculation
356 # ========================
357
358 if test x$xauth_generic_given = xfalse -a x$ikev1 = xfalse; then
359         xauth_generic=false;
360 fi
361
362 if test x$kernel_libipsec = xtrue; then
363         libipsec=true;
364 fi
365
366 if test x$eap_aka_3gpp2 = xtrue; then
367         gmp=true;
368 fi
369
370 if test x$eap_aka = xtrue; then
371         fips_prf=true;
372         simaka=true;
373 fi
374
375 if test x$eap_sim = xtrue; then
376         fips_prf=true;
377         simaka=true;
378 fi
379
380 if test x$eap_radius = xtrue -o x$radattr = xtrue -o x$tnc_pdp = xtrue; then
381         radius=true;
382 fi
383
384 if test x$tnc_imc = xtrue -o x$tnc_imv = xtrue -o x$tnccs_11 = xtrue -o x$tnccs_11 = xtrue -o x$tnccs_dynamic = xtrue -o x$eap_tnc = xtrue; then
385         tnc_tnccs=true;
386 fi
387
388 if test x$eap_tls = xtrue -o x$eap_ttls = xtrue -o x$eap_peap = xtrue -o x$tnc_tnccs = xtrue; then
389         tls=true;
390 fi
391
392 if test x$imc_test = xtrue -o x$imv_test = xtrue -o x$imc_scanner = xtrue -o x$imv_scanner = xtrue -o x$imc_os = xtrue -o x$imv_os = xtrue -o x$imc_attestation = xtrue -o x$imv_attestation = xtrue -o x$imc_swid = xtrue -o x$imv_swid = xtrue; then
393         imcv=true;
394 fi
395
396 if test x$imc_attestation = xtrue -o x$imv_attestation = xtrue -o x$imc_swid = xtrue -o x$imv_swid = xtrue; then
397         pts=true;
398 fi
399
400 if test x$fips_prf = xtrue; then
401         if test x$openssl = xfalse; then
402                 sha1=true;
403         fi
404 fi
405
406 if test x$swanctl = xtrue; then
407         vici=true
408 fi
409
410 if test x$smp = xtrue -o x$tnccs_11 = xtrue -o x$tnc_ifmap = xtrue; then
411         xml=true
412 fi
413
414 if test x$manager = xtrue; then
415         fast=true
416 fi
417
418 if test x$medsrv = xtrue; then
419         mediation=true
420         fast=true
421 fi
422
423 if test x$medcli = xtrue; then
424         mediation=true
425 fi
426
427 # ===========================================
428 #  check required libraries and header files
429 # ===========================================
430
431 AC_HEADER_STDBOOL
432 AC_FUNC_ALLOCA
433 AC_FUNC_STRERROR_R
434
435 #  libraries needed on some platforms but not on others
436 # ------------------------------------------------------
437 saved_LIBS=$LIBS
438
439 # FreeBSD and Mac OS X have dlopen integrated in libc, Linux needs libdl
440 LIBS=""
441 AC_SEARCH_LIBS(dlopen, dl, [DLLIB=$LIBS])
442 AC_SUBST(DLLIB)
443
444 # glibc's backtrace() can be replicated on FreeBSD with libexecinfo
445 LIBS=""
446 AC_SEARCH_LIBS(backtrace, execinfo, [BTLIB=$LIBS])
447 AC_CHECK_FUNCS(backtrace)
448 AC_SUBST(BTLIB)
449
450 # OpenSolaris needs libsocket and libnsl for socket()
451 LIBS=""
452 AC_SEARCH_LIBS(socket, socket, [SOCKLIB=$LIBS],
453         [AC_CHECK_LIB(nsl, socket, [SOCKLIB="-lsocket -lnsl"], [], [-lsocket])]
454 )
455 AC_SUBST(SOCKLIB)
456
457 # FreeBSD has clock_gettime in libc, Linux needs librt
458 LIBS=""
459 AC_SEARCH_LIBS(clock_gettime, rt, [RTLIB=$LIBS])
460 AC_CHECK_FUNCS(clock_gettime)
461 AC_SUBST(RTLIB)
462
463 # Android has pthread_* functions in bionic (libc), others need libpthread
464 LIBS=""
465 AC_SEARCH_LIBS(pthread_create, pthread, [PTHREADLIB=$LIBS])
466 AC_SUBST(PTHREADLIB)
467
468 LIBS=$saved_LIBS
469 # ------------------------------------------------------
470
471 AC_MSG_CHECKING(for dladdr)
472 AC_COMPILE_IFELSE(
473         [AC_LANG_PROGRAM(
474                 [[#define _GNU_SOURCE
475                   #include <dlfcn.h>]],
476                 [[Dl_info* info = 0;
477                   dladdr(0, info);]])],
478         [AC_MSG_RESULT([yes]); AC_DEFINE([HAVE_DLADDR], [], [have dladdr()])],
479         [AC_MSG_RESULT([no])]
480 )
481
482 # check if pthread_condattr_setclock(CLOCK_MONOTONE) is supported
483 saved_LIBS=$LIBS
484 LIBS=$PTHREADLIB
485 AC_MSG_CHECKING([for pthread_condattr_setclock(CLOCK_MONOTONE)])
486 AC_RUN_IFELSE(
487         [AC_LANG_SOURCE(
488                 [[#include <pthread.h>
489                   int main() { pthread_condattr_t attr;
490                         pthread_condattr_init(&attr);
491                         return pthread_condattr_setclock(&attr, CLOCK_MONOTONIC);}]])],
492         [AC_MSG_RESULT([yes]);
493          AC_DEFINE([HAVE_CONDATTR_CLOCK_MONOTONIC], [],
494                            [pthread_condattr_setclock supports CLOCK_MONOTONIC])],
495         [AC_MSG_RESULT([no])],
496         # Check existence of pthread_condattr_setclock if cross-compiling
497         [AC_MSG_RESULT([unknown]);
498          AC_CHECK_FUNCS(pthread_condattr_setclock,
499                 [AC_DEFINE([HAVE_CONDATTR_CLOCK_MONOTONIC], [],
500                                    [have pthread_condattr_setclock()])]
501         )]
502 )
503 # check if we actually are able to configure attributes on cond vars
504 AC_CHECK_FUNCS(pthread_condattr_init)
505 # instead of pthread_condattr_setclock Android has this function
506 AC_CHECK_FUNCS(pthread_cond_timedwait_monotonic)
507 # check if we can cancel threads
508 AC_CHECK_FUNCS(pthread_cancel)
509 # check if native rwlocks are available
510 AC_CHECK_FUNCS(pthread_rwlock_init)
511 # check if pthread spinlocks are available
512 AC_CHECK_FUNCS(pthread_spin_init)
513 # check if we have POSIX semaphore functions, including timed-wait
514 AC_CHECK_FUNCS(sem_timedwait)
515 LIBS=$saved_LIBS
516
517 AC_CHECK_FUNC(
518         [gettid],
519         [AC_DEFINE([HAVE_GETTID], [], [have gettid()])],
520         [AC_MSG_CHECKING([for SYS_gettid])
521          AC_COMPILE_IFELSE(
522                 [AC_LANG_PROGRAM(
523                         [[#define _GNU_SOURCE
524                           #include <unistd.h>
525                           #include <sys/syscall.h>]],
526                         [[int main() {
527                           return syscall(SYS_gettid);}]])],
528                 [AC_MSG_RESULT([yes]);
529                  AC_DEFINE([HAVE_GETTID], [], [have gettid()])
530                  AC_DEFINE([HAVE_SYS_GETTID], [], [have syscall(SYS_gettid)])],
531                 [AC_MSG_RESULT([no])]
532         )]
533 )
534
535 AC_CHECK_FUNC(
536         [qsort_r],
537         [
538                 AC_DEFINE([HAVE_QSORT_R], [], [have qsort_r()])
539                 # set -Werror so that we get an error for "argument ... has
540                 # incompatible pointer type" warnings
541                 save_CFLAGS="$CFLAGS"
542                 CFLAGS="$CFLAGS -Werror"
543                 AC_MSG_CHECKING([for GNU-style qsort_r])
544                 AC_COMPILE_IFELSE(
545                         [AC_LANG_PROGRAM(
546                                 [[#define _GNU_SOURCE
547                                   #include <stdlib.h>
548                                   int cmp (const void *a, const void *b, void *x) { return 0; }]],
549                                 [[int arr[] = { 0, 1 };
550                                   qsort_r(arr, 2, sizeof(int), cmp, arr);]])],
551                 [AC_MSG_RESULT([yes]);
552                  AC_DEFINE([HAVE_QSORT_R_GNU], [], [have GNU-style qsort_r()])],
553                 [
554                         AC_MSG_RESULT([no]);
555                         AC_MSG_CHECKING([for BSD-style qsort_r])
556                         AC_COMPILE_IFELSE(
557                                 [AC_LANG_PROGRAM(
558                                         [[#include <stdlib.h>
559                                           int cmp (void *x, const void *a, const void *b) { return 0; }]],
560                                         [[int arr[] = { 0, 1 };
561                                           qsort_r(arr, 2, sizeof(int), arr, cmp);]])],
562                         [AC_MSG_RESULT([yes]);
563                          AC_DEFINE([HAVE_QSORT_R_BSD], [], [have BSD-style qsort_r()])],
564                         [AC_MSG_RESULT([no]);
565                          AC_MSG_FAILURE([qsort_r has unknown semantics])])
566                 ])
567                 CFLAGS="$save_CFLAGS"
568         ]
569 )
570
571 AC_CHECK_FUNCS(prctl mallinfo getpass closefrom getpwnam_r getgrnam_r getpwuid_r)
572 AC_CHECK_FUNCS(fmemopen funopen mmap memrchr setlinebuf)
573
574 AC_CHECK_FUNC([syslog], [
575         AC_DEFINE([HAVE_SYSLOG], [], [have syslog(3) and friends])
576         syslog=true
577 ])
578 AM_CONDITIONAL(USE_SYSLOG, [test "x$syslog" = xtrue])
579
580 AC_CHECK_HEADERS(sys/sockio.h glob.h net/if_tun.h linux/fib_rules.h)
581 AC_CHECK_HEADERS(net/pfkeyv2.h netipsec/ipsec.h netinet6/ipsec.h linux/udp.h)
582 AC_CHECK_HEADERS(netinet/ip6.h, [], [],
583 [
584         #include <sys/types.h>
585         #include <netinet/in.h>
586 ])
587
588 AC_CHECK_MEMBERS([struct sockaddr.sa_len], [], [],
589 [
590         #include <sys/types.h>
591         #include <sys/socket.h>
592 ])
593
594 AC_CHECK_MEMBERS([struct sadb_x_policy.sadb_x_policy_priority], [], [],
595 [
596         #include <sys/types.h>
597         #ifdef HAVE_NET_PFKEYV2_H
598         #include <net/pfkeyv2.h>
599         #else
600         #include <stdint.h>
601         #include <linux/pfkeyv2.h>
602         #endif
603 ])
604
605 AC_MSG_CHECKING([for in6addr_any])
606 AC_COMPILE_IFELSE(
607         [AC_LANG_PROGRAM(
608                 [[#include <sys/types.h>
609                   #include <sys/socket.h>
610                   #include <netinet/in.h>]],
611                 [[struct in6_addr in6;
612                   in6 = in6addr_any;]])],
613         [AC_MSG_RESULT([yes]);
614          AC_DEFINE([HAVE_IN6ADDR_ANY], [], [have struct in6_addr in6addr_any])],
615         [AC_MSG_RESULT([no])]
616 )
617
618 AC_MSG_CHECKING([for in6_pktinfo])
619 AC_COMPILE_IFELSE(
620         [AC_LANG_PROGRAM(
621                 [[#define _GNU_SOURCE
622                   #include <sys/types.h>
623                   #include <sys/socket.h>
624                   #include <netinet/in.h>]],
625                 [[struct in6_pktinfo pi;
626                   if (pi.ipi6_ifindex)
627                   {
628                     return 0;
629                   }]])],
630         [AC_MSG_RESULT([yes]);
631          AC_DEFINE([HAVE_IN6_PKTINFO], [], [have struct in6_pktinfo.ipi6_ifindex])],
632         [AC_MSG_RESULT([no])]
633 )
634
635 AC_MSG_CHECKING([for IPSEC_MODE_BEET])
636 AC_COMPILE_IFELSE(
637         [AC_LANG_PROGRAM(
638                 [[#include <sys/types.h>
639                   #ifdef HAVE_NETIPSEC_IPSEC_H
640                   #include <netipsec/ipsec.h>
641                   #elif defined(HAVE_NETINET6_IPSEC_H)
642                   #include <netinet6/ipsec.h>
643                   #else
644                   #include <stdint.h>
645                   #include <linux/ipsec.h>
646                   #endif]],
647                 [[int mode = IPSEC_MODE_BEET;
648                   return mode;]])],
649         [AC_MSG_RESULT([yes]);
650          AC_DEFINE([HAVE_IPSEC_MODE_BEET], [], [have IPSEC_MODE_BEET defined])],
651         [AC_MSG_RESULT([no])]
652 )
653
654 AC_MSG_CHECKING([for IPSEC_DIR_FWD])
655 AC_COMPILE_IFELSE(
656         [AC_LANG_PROGRAM(
657                 [[#include <sys/types.h>
658                   #ifdef HAVE_NETIPSEC_IPSEC_H
659                   #include <netipsec/ipsec.h>
660                   #elif defined(HAVE_NETINET6_IPSEC_H)
661                   #include <netinet6/ipsec.h>
662                   #else
663                   #include <stdint.h>
664                   #include <linux/ipsec.h>
665                   #endif]],
666                 [[int dir = IPSEC_DIR_FWD;
667                   return dir;]])],
668         [AC_MSG_RESULT([yes]);
669          AC_DEFINE([HAVE_IPSEC_DIR_FWD], [], [have IPSEC_DIR_FWD defined])],
670         [AC_MSG_RESULT([no])]
671 )
672
673 AC_MSG_CHECKING([for RTA_TABLE])
674 AC_COMPILE_IFELSE(
675         [AC_LANG_PROGRAM(
676                 [[#include <sys/socket.h>
677                   #include <linux/netlink.h>
678                   #include <linux/rtnetlink.h>]],
679                 [[int rta_type = RTA_TABLE;
680                   return rta_type;]])],
681         [AC_MSG_RESULT([yes]);
682          AC_DEFINE([HAVE_RTA_TABLE], [], [have netlink RTA_TABLE defined])],
683         [AC_MSG_RESULT([no])]
684 )
685
686 AC_MSG_CHECKING([for GCC __sync operations])
687 AC_RUN_IFELSE([AC_LANG_SOURCE(
688         [[
689                         int main() {
690                         int ref = 1;
691                         __sync_fetch_and_add (&ref, 1);
692                         __sync_sub_and_fetch (&ref, 1);
693                         __sync_val_compare_and_swap(&ref, 1, 0);
694                         return ref;
695                 }
696         ]])],
697         [AC_MSG_RESULT([yes]);
698          AC_DEFINE([HAVE_GCC_SYNC_OPERATIONS], [],
699                    [have GCC __sync_* operations])],
700         [AC_MSG_RESULT([no])],
701         [AC_MSG_RESULT([no])]
702 )
703
704 case "$printf_hooks" in
705 auto|builtin|glibc|vstr)
706         ;;
707 *)
708         AC_MSG_NOTICE([invalid printf hook implementation, defaulting to 'auto'])
709         printf_hooks=auto
710         ;;
711 esac
712
713 if test x$printf_hooks = xauto -o x$printf_hooks = xglibc; then
714         # check for the new register_printf_specifier function with len argument,
715         # or the deprecated register_printf_function without
716         AC_CHECK_FUNC(
717                 [register_printf_specifier],
718                 [AC_DEFINE([HAVE_PRINTF_SPECIFIER], [], [have register_printf_specifier()])],
719                 [AC_CHECK_FUNC(
720                         [register_printf_function],
721                         [AC_DEFINE([HAVE_PRINTF_FUNCTION], [], [have register_printf_function()])],
722                         [
723                                 AC_MSG_NOTICE([printf(3) does not support custom format specifiers!])
724                                 if test x$printf_hooks = xglibc; then
725                                         AC_MSG_ERROR([please select a different printf hook implementation])
726                                 else
727                                         # fallback to builtin printf hook implementation
728                                         printf_hooks=builtin
729                                 fi
730                         ]
731                 )]
732         )
733 fi
734
735 AC_MSG_CHECKING([for Windows target])
736 AC_COMPILE_IFELSE(
737         [AC_LANG_PROGRAM(
738                 [[#include <windows.h>]],
739                 [[#ifndef WIN32
740                   # error WIN32 undefined
741                   #endif
742                 ]])],
743         [
744                 AC_MSG_RESULT([yes])
745                 windows=true
746                 openssl_lib=eay32
747                 AC_SUBST(PTHREADLIB, "")
748         ],
749         [
750                 AC_MSG_RESULT([no])
751                 openssl_lib=crypto
752                 AC_SUBST(PLUGIN_CFLAGS, [-rdynamic])
753         ]
754 )
755 AC_SUBST(OPENSSL_LIB, [-l$openssl_lib])
756 AM_CONDITIONAL(USE_WINDOWS, [test "x$windows" = xtrue])
757
758 AC_MSG_CHECKING([for working __attribute__((packed))])
759 AC_COMPILE_IFELSE(
760         [AC_LANG_PROGRAM([], [[
761                 struct test { char a; short b; } __attribute__((packed));
762                 char x[sizeof(struct test) == sizeof(char) + sizeof(short) ? 1 : -1];
763                 return 0;
764         ]])],
765         [AC_MSG_RESULT([yes])],
766         [AC_MSG_RESULT([no]); AC_MSG_ERROR([__attribute__((packed)) does not work])]
767 )
768
769 if test x$printf_hooks = xvstr; then
770         AC_CHECK_LIB([vstr],[main],[LIBS="$LIBS"],[AC_MSG_ERROR([Vstr string library not found])],[])
771         AC_DEFINE([USE_VSTR], [], [use Vstr string library for printf hooks])
772 fi
773
774 if test x$printf_hooks = xbuiltin; then
775         AC_DEFINE([USE_BUILTIN_PRINTF], [], [using builtin printf for printf hooks])
776 fi
777
778 if test x$gmp = xtrue; then
779         saved_LIBS=$LIBS
780         AC_CHECK_LIB([gmp],[main],[],[AC_MSG_ERROR([GNU Multi Precision library gmp not found])],[])
781         AC_MSG_CHECKING([mpz_powm_sec])
782         if test x$mpz_powm_sec = xyes; then
783                 AC_COMPILE_IFELSE(
784                         [AC_LANG_PROGRAM(
785                                 [[#include "gmp.h"]],
786                                 [[void *x = mpz_powm_sec;]])],
787                         [AC_MSG_RESULT([yes]);
788                          AC_DEFINE([HAVE_MPZ_POWM_SEC], [], [have mpz_mown_sec()])],
789                         [AC_MSG_RESULT([no])]
790                 )
791         else
792                 AC_MSG_RESULT([disabled])
793         fi
794         LIBS=$saved_LIBS
795         AC_MSG_CHECKING([gmp.h version >= 4.1.4])
796         AC_COMPILE_IFELSE(
797                 [AC_LANG_PROGRAM(
798                         [[#include "gmp.h"]],
799                         [[
800                                 #if (__GNU_MP_VERSION*100 +  __GNU_MP_VERSION_MINOR*10 + __GNU_MP_VERSION_PATCHLEVEL) < 414
801                                         #error bad gmp
802                                 #endif]])],
803                 [AC_MSG_RESULT([yes])],
804                 [AC_MSG_RESULT([no]); AC_MSG_ERROR([No usable gmp.h found!])]
805         )
806 fi
807
808 if test x$ldap = xtrue; then
809         AC_CHECK_LIB([ldap],[main],[LIBS="$LIBS"],[AC_MSG_ERROR([LDAP library ldap not found])],[])
810         AC_CHECK_LIB([lber],[main],[LIBS="$LIBS"],[AC_MSG_ERROR([LDAP library lber not found])],[])
811         AC_CHECK_HEADER([ldap.h],,[AC_MSG_ERROR([LDAP header ldap.h not found!])])
812 fi
813
814 if test x$curl = xtrue; then
815         AC_CHECK_LIB([curl],[main],[LIBS="$LIBS"],[AC_MSG_ERROR([CURL library curl not found])],[])
816         AC_CHECK_HEADER([curl/curl.h],,[AC_MSG_ERROR([CURL header curl/curl.h not found!])])
817 fi
818
819 if test x$unbound = xtrue; then
820         AC_HAVE_LIBRARY([ldns],[LIBS="$LIBS"],[AC_MSG_ERROR([UNBOUND library ldns not found])])
821         AC_CHECK_HEADER([ldns/ldns.h],,[AC_MSG_ERROR([UNBOUND header ldns/ldns.h not found!])])
822         AC_HAVE_LIBRARY([unbound],[LIBS="$LIBS"],[AC_MSG_ERROR([UNBOUND library libunbound not found])])
823         AC_CHECK_HEADER([unbound.h],,[AC_MSG_ERROR([UNBOUND header unbound.h not found!])])
824 fi
825
826 if test x$soup = xtrue; then
827         PKG_CHECK_MODULES(soup, [libsoup-2.4])
828         AC_SUBST(soup_CFLAGS)
829         AC_SUBST(soup_LIBS)
830 fi
831
832 if test x$xml = xtrue; then
833         PKG_CHECK_MODULES(xml, [libxml-2.0])
834         AC_SUBST(xml_CFLAGS)
835         AC_SUBST(xml_LIBS)
836 fi
837
838 if test x$tss = xtrousers; then
839         AC_CHECK_LIB([tspi],[main],[LIBS="$LIBS"],[AC_MSG_ERROR([TrouSerS library libtspi not found])],[])
840         AC_CHECK_HEADER([trousers/tss.h],,[AC_MSG_ERROR([TrouSerS header trousers/tss.h not found!])])
841         AC_DEFINE([TSS_TROUSERS], [], [use TrouSerS library libtspi as TSS implementation])
842 fi
843
844 if test x$imv_swid = xtrue; then
845         AC_CHECK_LIB([json],[main],[LIBS="$LIBS"],[AC_MSG_ERROR([JSON library libjson not found])],[])
846         AC_CHECK_HEADER([json/json.h],,[AC_MSG_ERROR([JSON header json/json.h not found!])])
847 fi
848
849 if test x$dumm = xtrue; then
850         PKG_CHECK_MODULES(gtk, [gtk+-2.0 vte])
851         AC_SUBST(gtk_CFLAGS)
852         AC_SUBST(gtk_LIBS)
853         AC_CHECK_PROGS(RUBY, ruby)
854         AC_MSG_CHECKING([for Ruby header files])
855         if test -n "$RUBY"; then
856                 RUBYINCLUDE=
857                 RUBYDIR=`($RUBY -r rbconfig -e 'print RbConfig::CONFIG[["rubyhdrdir"]] || ""') 2>/dev/null`
858                 if test -n "$RUBYDIR" -a -r "$RUBYDIR/ruby.h"; then
859                         RUBYARCH=`($RUBY -r rbconfig -e 'print RbConfig::CONFIG[["arch"]] || ""') 2>/dev/null`
860                         if test -n "$RUBYARCH"; then
861                                 AC_MSG_RESULT([$RUBYDIR])
862                                 RUBYINCLUDE="-I$RUBYDIR -I$RUBYDIR/$RUBYARCH"
863                         fi
864                 else
865                         RUBYDIR=`($RUBY -r rbconfig -e 'print RbConfig::CONFIG[["archdir"]] || ""') 2>/dev/null`
866                         if test -n "$RUBYDIR" -a -r "$RUBYDIR/ruby.h"; then
867                                 AC_MSG_RESULT([$RUBYDIR])
868                                 RUBYINCLUDE="-I$RUBYDIR"
869                         fi
870                 fi
871                 if test -z "$RUBYINCLUDE"; then
872                         AC_MSG_ERROR([ruby.h not found])
873                 fi
874                 AC_SUBST(RUBYINCLUDE)
875         else
876                 AC_MSG_ERROR([don't know how to run ruby])
877         fi
878         AC_MSG_CHECKING([for libruby])
879         saved_LIBS=$LIBS
880         LIBS=`($RUBY -r rbconfig -e 'print RbConfig::CONFIG[["LIBRUBYARG_SHARED"]] || ""') 2>/dev/null`
881         AC_TRY_LINK_FUNC(ruby_init,
882                 [AC_MSG_RESULT([$LIBS]); RUBYLIB=$LIBS],
883                 [AC_MSG_ERROR([not found])])
884         AC_SUBST(RUBYLIB)
885         AC_CHECK_FUNCS(rb_errinfo)
886         LIBS=$saved_LIBS
887 fi
888
889 if test x$fast = xtrue; then
890         AC_CHECK_LIB([neo_cgi],[main],[LIBS="$LIBS"],[AC_MSG_ERROR([ClearSilver library neo_cgi not found!])],[])
891         AC_CHECK_LIB([neo_utl],[main],[LIBS="$LIBS"],[AC_MSG_ERROR([ClearSilver library neo_utl not found!])],[])
892         AC_MSG_CHECKING([ClearSilver requires zlib])
893         saved_CFLAGS=$CFLAGS
894         saved_LIBS=$LIBS
895         LIBS="-lneo_cgi -lneo_cs -lneo_utl"
896         CFLAGS="-I/usr/include/ClearSilver"
897         AC_LINK_IFELSE(
898                 [AC_LANG_PROGRAM(
899                         [[#include <ClearSilver.h>]],
900                         [[NEOERR *err = cgi_display(NULL, NULL);]])],
901                 [AC_MSG_RESULT([no]); clearsilver_LIBS="$LIBS"],
902                 [AC_MSG_RESULT([yes]); clearsilver_LIBS="$LIBS -lz"]
903         )
904         AC_SUBST(clearsilver_LIBS)
905         LIBS=$saved_LIBS
906         CFLAGS=$saved_CFLAGS
907 # autoconf does not like CamelCase!? How to fix this?
908 #       AC_CHECK_HEADER([ClearSilver/ClearSilver.h],,[AC_MSG_ERROR([ClearSilver header file ClearSilver/ClearSilver.h not found!])])
909
910         AC_CHECK_LIB([fcgi],[main],[LIBS="$LIBS"],[AC_MSG_ERROR([FastCGI library fcgi not found!])],[])
911         AC_CHECK_HEADER([fcgiapp.h],,[AC_MSG_ERROR([FastCGI header file fcgiapp.h not found!])])
912 fi
913
914 if test x$mysql = xtrue; then
915         if test "x$windows" = xtrue; then
916                 AC_CHECK_HEADER([mysql.h],,[AC_MSG_ERROR([MySQL header file mysql.h not found!])])
917                 AC_CHECK_LIB([mysql],[main],[LIBS="$LIBS"],[AC_MSG_ERROR([MySQL library not found!])],[])
918                 AC_SUBST(MYSQLLIB, -lmysql)
919         else
920                 AC_PATH_PROG([MYSQLCONFIG], [mysql_config], [], [$PATH:/bin:/usr/bin:/usr/local/bin])
921                 if test x$MYSQLCONFIG = x; then
922                         AC_MSG_ERROR([mysql_config not found!])
923                 fi
924                 AC_SUBST(MYSQLLIB, `$MYSQLCONFIG --libs_r`)
925                 AC_SUBST(MYSQLCFLAG, `$MYSQLCONFIG --cflags`)
926         fi
927 fi
928
929 if test x$sqlite = xtrue; then
930         AC_CHECK_LIB([sqlite3],[main],[LIBS="$LIBS"],[AC_MSG_ERROR([SQLite library sqlite3 not found])],[])
931         AC_CHECK_HEADER([sqlite3.h],,[AC_MSG_ERROR([SQLite header sqlite3.h not found!])])
932         AC_MSG_CHECKING([sqlite3_prepare_v2])
933         AC_COMPILE_IFELSE(
934                 [AC_LANG_PROGRAM(
935                         [[#include <sqlite3.h>]],
936                         [[void *test = sqlite3_prepare_v2;]])],
937                 [AC_MSG_RESULT([yes]);
938                  AC_DEFINE([HAVE_SQLITE3_PREPARE_V2], [], [have sqlite3_prepare_v2()])],
939                 [AC_MSG_RESULT([no])]
940         )
941         AC_MSG_CHECKING([sqlite3.h version >= 3.3.1])
942         AC_COMPILE_IFELSE(
943                 [AC_LANG_PROGRAM(
944                         [[#include <sqlite3.h>]],
945                         [[
946                                 #if SQLITE_VERSION_NUMBER < 3003001
947                                         #error bad sqlite
948                                 #endif]])],
949                 [AC_MSG_RESULT([yes])],
950                 [AC_MSG_RESULT([no]); AC_MSG_ERROR([SQLite version >= 3.3.1 required!])]
951         )
952 fi
953
954 if test x$openssl = xtrue; then
955         AC_CHECK_LIB([$openssl_lib],[main],[LIBS="$LIBS"],[AC_MSG_ERROR([OpenSSL lib$openssl_lib not found])],[])
956         AC_CHECK_HEADER([openssl/evp.h],,[AC_MSG_ERROR([OpenSSL header openssl/evp.h not found!])])
957 fi
958
959 if test x$gcrypt = xtrue; then
960         AC_CHECK_LIB([gcrypt],[main],[LIBS="$LIBS"],[AC_MSG_ERROR([gcrypt library not found])],[-lgpg-error])
961         AC_CHECK_HEADER([gcrypt.h],,[AC_MSG_ERROR([gcrypt header gcrypt.h not found!])])
962         AC_MSG_CHECKING([gcrypt CAMELLIA cipher])
963         AC_COMPILE_IFELSE(
964                 [AC_LANG_PROGRAM(
965                         [[#include <gcrypt.h>]],
966                         [[enum gcry_cipher_algos alg = GCRY_CIPHER_CAMELLIA128;]])],
967                 [AC_MSG_RESULT([yes]);
968                  AC_DEFINE([HAVE_GCRY_CIPHER_CAMELLIA], [], [have GCRY_CIPHER_CAMELLIA128])],
969                 [AC_MSG_RESULT([no])]
970         )
971 fi
972
973 if test x$uci = xtrue; then
974         AC_CHECK_LIB([uci],[main],[LIBS="$LIBS"],[AC_MSG_ERROR([UCI library libuci not found])],[])
975         AC_CHECK_HEADER([uci.h],,[AC_MSG_ERROR([UCI header uci.h not found!])])
976 fi
977
978 if test x$android_dns = xtrue; then
979         AC_CHECK_LIB([cutils],[main],[LIBS="$LIBS"],[AC_MSG_ERROR([Android library libcutils not found])],[])
980         AC_CHECK_HEADER([cutils/properties.h],,[AC_MSG_ERROR([Android header cutils/properties.h not found!])])
981         # we have to force the use of libdl here because the autodetection
982         # above does not work correctly when cross-compiling for android.
983         DLLIB="-ldl"
984         AC_SUBST(DLLIB)
985 fi
986
987 if test x$maemo = xtrue; then
988         PKG_CHECK_MODULES(maemo, [glib-2.0 gthread-2.0 libosso osso-af-settings])
989         AC_SUBST(maemo_CFLAGS)
990         AC_SUBST(maemo_LIBS)
991         dbusservicedir="/usr/share/dbus-1/system-services"
992         AC_SUBST(dbusservicedir)
993 fi
994
995 if test x$eap_sim_pcsc = xtrue; then
996         PKG_CHECK_MODULES(pcsclite, [libpcsclite])
997         AC_SUBST(pcsclite_CFLAGS)
998         AC_SUBST(pcsclite_LIBS)
999 fi
1000
1001 if test x$nm = xtrue; then
1002         PKG_CHECK_EXISTS([libnm-glib],
1003                 [PKG_CHECK_MODULES(nm, [NetworkManager gthread-2.0 libnm-util libnm-glib libnm-glib-vpn])],
1004                 [PKG_CHECK_MODULES(nm, [NetworkManager gthread-2.0 libnm_util libnm_glib libnm_glib_vpn])]
1005         )
1006         AC_SUBST(nm_CFLAGS)
1007         AC_SUBST(nm_LIBS)
1008 fi
1009
1010 if test x$xauth_pam = xtrue; then
1011         AC_CHECK_LIB([pam],[main],[LIBS="$LIBS"],[AC_MSG_ERROR([PAM library not found])],[])
1012         AC_CHECK_HEADER([security/pam_appl.h],,[AC_MSG_ERROR([PAM header security/pam_appl.h not found!])])
1013 fi
1014
1015 if test x$capabilities = xnative; then
1016         AC_MSG_NOTICE([Usage of the native Linux capabilities interface is deprecated, use libcap instead])
1017         # Linux requires the following for capset(), Android does not have it,
1018         # but defines capset() in unistd.h instead.
1019         AC_CHECK_HEADERS([sys/capability.h])
1020         AC_CHECK_FUNC(capset,,[AC_MSG_ERROR([capset() not found!])])
1021         AC_DEFINE([CAPABILITIES_NATIVE], [], [have native linux capset()])
1022 fi
1023
1024 if test x$capabilities = xlibcap; then
1025         AC_CHECK_LIB([cap],[main],[LIBS="$LIBS"],[AC_MSG_ERROR([libcap library not found])],[])
1026         AC_CHECK_HEADER([sys/capability.h],
1027                 [AC_DEFINE([HAVE_SYS_CAPABILITY_H], [], [have sys/capability.h])],
1028                 [AC_MSG_ERROR([libcap header sys/capability.h not found!])])
1029         AC_DEFINE([CAPABILITIES_LIBCAP], [], [have libpcap library])
1030 fi
1031
1032 if test x$integrity_test = xtrue; then
1033         AC_MSG_CHECKING([for dladdr()])
1034         AC_COMPILE_IFELSE(
1035                 [AC_LANG_PROGRAM(
1036                         [[#define _GNU_SOURCE
1037                           #include <dlfcn.h>]],
1038                         [[Dl_info info; dladdr(main, &info);]])],
1039                 [AC_MSG_RESULT([yes])],
1040                 [AC_MSG_RESULT([no]);
1041                  AC_MSG_ERROR([dladdr() not supported, required by integrity-test!])]
1042         )
1043         AC_MSG_CHECKING([for dl_iterate_phdr()])
1044         AC_COMPILE_IFELSE(
1045                 [AC_LANG_PROGRAM(
1046                         [[#define _GNU_SOURCE
1047                           #include <link.h>]],
1048                         [[dl_iterate_phdr((void*)0, (void*)0);]])],
1049                 [AC_MSG_RESULT([yes])],
1050                 [AC_MSG_RESULT([no]);
1051                  AC_MSG_ERROR([dl_iterate_phdr() not supported, required by integrity-test!])]
1052         )
1053 fi
1054
1055 if test x$bfd_backtraces = xtrue; then
1056         AC_CHECK_LIB([bfd],[main],[LIBS="$LIBS"],[AC_MSG_ERROR([binutils libbfd not found!])],[])
1057         AC_CHECK_HEADER([bfd.h],[AC_DEFINE([HAVE_BFD_H],,[have binutils bfd.h])],
1058                 [AC_MSG_ERROR([binutils bfd.h header not found!])])
1059         BFDLIB="-lbfd"
1060         AC_SUBST(BFDLIB)
1061 fi
1062
1063 if test x$unwind_backtraces = xtrue; then
1064         AC_CHECK_LIB([unwind],[main],[LIBS="$LIBS"],[AC_MSG_ERROR([libunwind not found!])],[])
1065         AC_CHECK_HEADER([libunwind.h],[AC_DEFINE([HAVE_LIBUNWIND_H],,[have libunwind.h])],
1066                 [AC_MSG_ERROR([libunwind.h header not found!])])
1067         UNWINDLIB="-lunwind"
1068         AC_SUBST(UNWINDLIB)
1069 fi
1070
1071 AM_CONDITIONAL(USE_DEV_HEADERS, [test "x$dev_headers" != xno])
1072 if test x$dev_headers = xyes; then
1073         dev_headers="$includedir/strongswan"
1074 fi
1075 AC_SUBST(dev_headers)
1076
1077 CFLAGS="$CFLAGS -include `pwd`/config.h"
1078
1079 if test x$tkm = xtrue; then
1080         AC_PATH_PROG([GPRBUILD], [gprbuild], [], [$PATH:/bin:/usr/bin:/usr/local/bin])
1081         if test x$GPRBUILD = x; then
1082                 AC_MSG_ERROR([gprbuild not found])
1083         fi
1084 fi
1085
1086 if test x$coverage = xtrue; then
1087         AC_PATH_PROG([LCOV], [lcov], [], [$PATH:/bin:/usr/bin:/usr/local/bin])
1088         if test x$LCOV = x; then
1089                 AC_MSG_ERROR([lcov not found])
1090         fi
1091         AC_PATH_PROG([GENHTML], [genhtml], [], [$PATH:/bin:/usr/bin:/usr/local/bin])
1092         if test x$GENHTML = x; then
1093                 AC_MSG_ERROR([genhtml not found])
1094         fi
1095
1096         COVERAGE_CFLAGS="-fprofile-arcs -ftest-coverage"
1097         COVERAGE_LDFLAGS="-fprofile-arcs"
1098         AC_SUBST(COVERAGE_CFLAGS)
1099         AC_SUBST(COVERAGE_LDFLAGS)
1100
1101         AC_MSG_NOTICE([coverage enabled, adding "-g -O0" to CFLAGS])
1102         CFLAGS="${CFLAGS} -g -O0"
1103 fi
1104
1105 # ===============================================
1106 #  collect plugin list for strongSwan components
1107 # ===============================================
1108
1109 m4_include(m4/macros/add-plugin.m4)
1110
1111 # plugin lists for all components
1112 charon_plugins=
1113 starter_plugins=
1114 pool_plugins=
1115 attest_plugins=
1116 scepclient_plugins=
1117 pki_plugins=
1118 scripts_plugins=
1119 manager_plugins=
1120 medsrv_plugins=
1121 nm_plugins=
1122 cmd_plugins=
1123 aikgen_plugins=
1124
1125 # location specific lists for checksumming,
1126 # for src/libcharon, src/libhydra, src/libstrongswan and src/libtnccs
1127 c_plugins=
1128 h_plugins=
1129 s_plugins=
1130 t_plugins=
1131
1132 ADD_PLUGIN([test-vectors],         [s charon scepclient pki])
1133 ADD_PLUGIN([curl],                 [s charon scepclient scripts nm cmd])
1134 ADD_PLUGIN([soup],                 [s charon scripts nm cmd])
1135 ADD_PLUGIN([unbound],              [s charon scripts])
1136 ADD_PLUGIN([ldap],                 [s charon scepclient scripts nm cmd])
1137 ADD_PLUGIN([mysql],                [s charon pool manager medsrv attest])
1138 ADD_PLUGIN([sqlite],               [s charon pool manager medsrv attest])
1139 ADD_PLUGIN([pkcs11],               [s charon pki nm cmd])
1140 ADD_PLUGIN([aes],                  [s charon scepclient pki scripts nm cmd])
1141 ADD_PLUGIN([des],                  [s charon scepclient pki scripts nm cmd])
1142 ADD_PLUGIN([blowfish],             [s charon scepclient pki scripts nm cmd])
1143 ADD_PLUGIN([rc2],                  [s charon scepclient pki scripts nm cmd])
1144 ADD_PLUGIN([sha1],                 [s charon scepclient pki scripts medsrv attest nm cmd aikgen])
1145 ADD_PLUGIN([sha2],                 [s charon scepclient pki scripts medsrv attest nm cmd aikgen])
1146 ADD_PLUGIN([md4],                  [s charon manager scepclient pki nm cmd])
1147 ADD_PLUGIN([md5],                  [s charon scepclient pki scripts attest nm cmd aikgen])
1148 ADD_PLUGIN([rdrand],               [s charon scepclient pki scripts medsrv attest nm cmd aikgen])
1149 ADD_PLUGIN([random],               [s charon scepclient pki scripts medsrv attest nm cmd aikgen])
1150 ADD_PLUGIN([nonce],                [s charon nm cmd aikgen])
1151 ADD_PLUGIN([x509],                 [s charon scepclient pki scripts attest nm cmd aikgen])
1152 ADD_PLUGIN([revocation],           [s charon nm cmd])
1153 ADD_PLUGIN([constraints],          [s charon nm cmd])
1154 ADD_PLUGIN([acert],                [s charon])
1155 ADD_PLUGIN([pubkey],               [s charon cmd aikgen])
1156 ADD_PLUGIN([pkcs1],                [s charon scepclient pki scripts manager medsrv attest nm cmd aikgen])
1157 ADD_PLUGIN([pkcs7],                [s charon scepclient pki scripts nm cmd])
1158 ADD_PLUGIN([pkcs8],                [s charon scepclient pki scripts manager medsrv attest nm cmd])
1159 ADD_PLUGIN([pkcs12],               [s charon scepclient pki scripts cmd])
1160 ADD_PLUGIN([pgp],                  [s charon])
1161 ADD_PLUGIN([dnskey],               [s charon pki])
1162 ADD_PLUGIN([sshkey],               [s charon pki nm cmd])
1163 ADD_PLUGIN([dnscert],              [c charon])
1164 ADD_PLUGIN([ipseckey],             [c charon])
1165 ADD_PLUGIN([pem],                  [s charon scepclient pki scripts manager medsrv attest nm cmd aikgen])
1166 ADD_PLUGIN([padlock],              [s charon])
1167 ADD_PLUGIN([openssl],              [s charon scepclient pki scripts manager medsrv attest nm cmd aikgen])
1168 ADD_PLUGIN([gcrypt],               [s charon scepclient pki scripts manager medsrv attest nm cmd aikgen])
1169 ADD_PLUGIN([af-alg],               [s charon scepclient pki scripts medsrv attest nm cmd aikgen])
1170 ADD_PLUGIN([fips-prf],             [s charon nm cmd])
1171 ADD_PLUGIN([gmp],                  [s charon scepclient pki scripts manager medsrv attest nm cmd aikgen])
1172 ADD_PLUGIN([agent],                [s charon nm cmd])
1173 ADD_PLUGIN([keychain],             [s charon cmd])
1174 ADD_PLUGIN([xcbc],                 [s charon nm cmd])
1175 ADD_PLUGIN([cmac],                 [s charon nm cmd])
1176 ADD_PLUGIN([hmac],                 [s charon scripts nm cmd])
1177 ADD_PLUGIN([ctr],                  [s charon scripts nm cmd])
1178 ADD_PLUGIN([ccm],                  [s charon scripts nm cmd])
1179 ADD_PLUGIN([gcm],                  [s charon scripts nm cmd])
1180 ADD_PLUGIN([ntru],                 [s charon scripts nm cmd])
1181 ADD_PLUGIN([attr],                 [h charon])
1182 ADD_PLUGIN([attr-sql],             [h charon])
1183 ADD_PLUGIN([load-tester],          [c charon])
1184 ADD_PLUGIN([kernel-libipsec],      [c charon cmd])
1185 ADD_PLUGIN([kernel-pfkey],         [h charon starter nm cmd])
1186 ADD_PLUGIN([kernel-pfroute],       [h charon starter nm cmd])
1187 ADD_PLUGIN([kernel-klips],         [h charon starter])
1188 ADD_PLUGIN([kernel-netlink],       [h charon starter nm cmd])
1189 ADD_PLUGIN([resolve],              [h charon cmd])
1190 ADD_PLUGIN([socket-default],       [c charon nm cmd])
1191 ADD_PLUGIN([socket-dynamic],       [c charon cmd])
1192 ADD_PLUGIN([farp],                 [c charon])
1193 ADD_PLUGIN([stroke],               [c charon])
1194 ADD_PLUGIN([vici],                 [c charon])
1195 ADD_PLUGIN([smp],                  [c charon])
1196 ADD_PLUGIN([sql],                  [c charon])
1197 ADD_PLUGIN([updown],               [c charon])
1198 ADD_PLUGIN([eap-identity],         [c charon nm cmd])
1199 ADD_PLUGIN([eap-sim],              [c charon])
1200 ADD_PLUGIN([eap-sim-file],         [c charon])
1201 ADD_PLUGIN([eap-sim-pcsc],         [c charon])
1202 ADD_PLUGIN([eap-aka],              [c charon])
1203 ADD_PLUGIN([eap-aka-3gpp2],        [c charon])
1204 ADD_PLUGIN([eap-simaka-sql],       [c charon])
1205 ADD_PLUGIN([eap-simaka-pseudonym], [c charon])
1206 ADD_PLUGIN([eap-simaka-reauth],    [c charon])
1207 ADD_PLUGIN([eap-md5],              [c charon nm cmd])
1208 ADD_PLUGIN([eap-gtc],              [c charon nm cmd])
1209 ADD_PLUGIN([eap-mschapv2],         [c charon nm cmd])
1210 ADD_PLUGIN([eap-dynamic],          [c charon])
1211 ADD_PLUGIN([eap-radius],           [c charon])
1212 ADD_PLUGIN([eap-tls],              [c charon nm cmd])
1213 ADD_PLUGIN([eap-ttls],             [c charon nm cmd])
1214 ADD_PLUGIN([eap-peap],             [c charon nm cmd])
1215 ADD_PLUGIN([eap-tnc],              [c charon])
1216 ADD_PLUGIN([xauth-generic],        [c charon cmd])
1217 ADD_PLUGIN([xauth-eap],            [c charon])
1218 ADD_PLUGIN([xauth-pam],            [c charon])
1219 ADD_PLUGIN([xauth-noauth],         [c charon])
1220 ADD_PLUGIN([tnc-ifmap],            [c charon])
1221 ADD_PLUGIN([tnc-pdp],              [c charon])
1222 ADD_PLUGIN([tnc-imc],              [t charon])
1223 ADD_PLUGIN([tnc-imv],              [t charon])
1224 ADD_PLUGIN([tnc-tnccs],            [t charon])
1225 ADD_PLUGIN([tnccs-20],             [t charon])
1226 ADD_PLUGIN([tnccs-11],             [t charon])
1227 ADD_PLUGIN([tnccs-dynamic],        [t charon])
1228 ADD_PLUGIN([medsrv],               [c charon])
1229 ADD_PLUGIN([medcli],               [c charon])
1230 ADD_PLUGIN([dhcp],                 [c charon])
1231 ADD_PLUGIN([osx-attr],             [c charon cmd])
1232 ADD_PLUGIN([android-dns],          [c charon])
1233 ADD_PLUGIN([android-log],          [c charon])
1234 ADD_PLUGIN([ha],                   [c charon])
1235 ADD_PLUGIN([whitelist],            [c charon])
1236 ADD_PLUGIN([lookip],               [c charon])
1237 ADD_PLUGIN([error-notify],         [c charon])
1238 ADD_PLUGIN([certexpire],           [c charon])
1239 ADD_PLUGIN([systime-fix],          [c charon])
1240 ADD_PLUGIN([led],                  [c charon])
1241 ADD_PLUGIN([duplicheck],           [c charon])
1242 ADD_PLUGIN([coupling],             [c charon])
1243 ADD_PLUGIN([radattr],              [c charon])
1244 ADD_PLUGIN([maemo],                [c charon])
1245 ADD_PLUGIN([uci],                  [c charon])
1246 ADD_PLUGIN([addrblock],            [c charon])
1247 ADD_PLUGIN([unity],                [c charon])
1248 ADD_PLUGIN([unit-tester],          [c charon])
1249
1250 AC_SUBST(charon_plugins)
1251 AC_SUBST(starter_plugins)
1252 AC_SUBST(pool_plugins)
1253 AC_SUBST(attest_plugins)
1254 AC_SUBST(scepclient_plugins)
1255 AC_SUBST(pki_plugins)
1256 AC_SUBST(scripts_plugins)
1257 AC_SUBST(manager_plugins)
1258 AC_SUBST(medsrv_plugins)
1259 AC_SUBST(nm_plugins)
1260 AC_SUBST(cmd_plugins)
1261 AC_SUBST(aikgen_plugins)
1262
1263 AC_SUBST(c_plugins)
1264 AC_SUBST(h_plugins)
1265 AC_SUBST(s_plugins)
1266 AC_SUBST(t_plugins)
1267
1268 # ======================
1269 #  set Makefile.am vars
1270 # ======================
1271
1272 #  libstrongswan plugins
1273 # -----------------------
1274 AM_CONDITIONAL(USE_TEST_VECTORS, test x$test_vectors = xtrue)
1275 AM_CONDITIONAL(USE_CURL, test x$curl = xtrue)
1276 AM_CONDITIONAL(USE_UNBOUND, test x$unbound = xtrue)
1277 AM_CONDITIONAL(USE_SOUP, test x$soup = xtrue)
1278 AM_CONDITIONAL(USE_LDAP, test x$ldap = xtrue)
1279 AM_CONDITIONAL(USE_AES, test x$aes = xtrue)
1280 AM_CONDITIONAL(USE_DES, test x$des = xtrue)
1281 AM_CONDITIONAL(USE_BLOWFISH, test x$blowfish = xtrue)
1282 AM_CONDITIONAL(USE_RC2, test x$rc2 = xtrue)
1283 AM_CONDITIONAL(USE_MD4, test x$md4 = xtrue)
1284 AM_CONDITIONAL(USE_MD5, test x$md5 = xtrue)
1285 AM_CONDITIONAL(USE_SHA1, test x$sha1 = xtrue)
1286 AM_CONDITIONAL(USE_SHA2, test x$sha2 = xtrue)
1287 AM_CONDITIONAL(USE_FIPS_PRF, test x$fips_prf = xtrue)
1288 AM_CONDITIONAL(USE_GMP, test x$gmp = xtrue)
1289 AM_CONDITIONAL(USE_RDRAND, test x$rdrand = xtrue)
1290 AM_CONDITIONAL(USE_RANDOM, test x$random = xtrue)
1291 AM_CONDITIONAL(USE_NONCE, test x$nonce = xtrue)
1292 AM_CONDITIONAL(USE_X509, test x$x509 = xtrue)
1293 AM_CONDITIONAL(USE_REVOCATION, test x$revocation = xtrue)
1294 AM_CONDITIONAL(USE_CONSTRAINTS, test x$constraints = xtrue)
1295 AM_CONDITIONAL(USE_ACERT, test x$acert = xtrue)
1296 AM_CONDITIONAL(USE_PUBKEY, test x$pubkey = xtrue)
1297 AM_CONDITIONAL(USE_PKCS1, test x$pkcs1 = xtrue)
1298 AM_CONDITIONAL(USE_PKCS7, test x$pkcs7 = xtrue)
1299 AM_CONDITIONAL(USE_PKCS8, test x$pkcs8 = xtrue)
1300 AM_CONDITIONAL(USE_PKCS12, test x$pkcs12 = xtrue)
1301 AM_CONDITIONAL(USE_PGP, test x$pgp = xtrue)
1302 AM_CONDITIONAL(USE_DNSKEY, test x$dnskey = xtrue)
1303 AM_CONDITIONAL(USE_SSHKEY, test x$sshkey = xtrue)
1304 AM_CONDITIONAL(USE_PEM, test x$pem = xtrue)
1305 AM_CONDITIONAL(USE_HMAC, test x$hmac = xtrue)
1306 AM_CONDITIONAL(USE_CMAC, test x$cmac = xtrue)
1307 AM_CONDITIONAL(USE_XCBC, test x$xcbc = xtrue)
1308 AM_CONDITIONAL(USE_MYSQL, test x$mysql = xtrue)
1309 AM_CONDITIONAL(USE_SQLITE, test x$sqlite = xtrue)
1310 AM_CONDITIONAL(USE_PADLOCK, test x$padlock = xtrue)
1311 AM_CONDITIONAL(USE_OPENSSL, test x$openssl = xtrue)
1312 AM_CONDITIONAL(USE_GCRYPT, test x$gcrypt = xtrue)
1313 AM_CONDITIONAL(USE_AGENT, test x$agent = xtrue)
1314 AM_CONDITIONAL(USE_KEYCHAIN, test x$keychain = xtrue)
1315 AM_CONDITIONAL(USE_PKCS11, test x$pkcs11 = xtrue)
1316 AM_CONDITIONAL(USE_CTR, test x$ctr = xtrue)
1317 AM_CONDITIONAL(USE_CCM, test x$ccm = xtrue)
1318 AM_CONDITIONAL(USE_GCM, test x$gcm = xtrue)
1319 AM_CONDITIONAL(USE_AF_ALG, test x$af_alg = xtrue)
1320 AM_CONDITIONAL(USE_NTRU, test x$ntru = xtrue)
1321
1322 #  charon plugins
1323 # ----------------
1324 AM_CONDITIONAL(USE_STROKE, test x$stroke = xtrue)
1325 AM_CONDITIONAL(USE_VICI, test x$vici = xtrue)
1326 AM_CONDITIONAL(USE_MEDSRV, test x$medsrv = xtrue)
1327 AM_CONDITIONAL(USE_MEDCLI, test x$medcli = xtrue)
1328 AM_CONDITIONAL(USE_UCI, test x$uci = xtrue)
1329 AM_CONDITIONAL(USE_OSX_ATTR, test x$osx_attr = xtrue)
1330 AM_CONDITIONAL(USE_ANDROID_DNS, test x$android_dns = xtrue)
1331 AM_CONDITIONAL(USE_ANDROID_LOG, test x$android_log = xtrue)
1332 AM_CONDITIONAL(USE_MAEMO, test x$maemo = xtrue)
1333 AM_CONDITIONAL(USE_SMP, test x$smp = xtrue)
1334 AM_CONDITIONAL(USE_SQL, test x$sql = xtrue)
1335 AM_CONDITIONAL(USE_DNSCERT, test x$dnscert = xtrue)
1336 AM_CONDITIONAL(USE_IPSECKEY, test x$ipseckey = xtrue)
1337 AM_CONDITIONAL(USE_UPDOWN, test x$updown = xtrue)
1338 AM_CONDITIONAL(USE_DHCP, test x$dhcp = xtrue)
1339 AM_CONDITIONAL(USE_UNIT_TESTS, test x$unit_tester = xtrue)
1340 AM_CONDITIONAL(USE_LOAD_TESTER, test x$load_tester = xtrue)
1341 AM_CONDITIONAL(USE_HA, test x$ha = xtrue)
1342 AM_CONDITIONAL(USE_KERNEL_LIBIPSEC, test x$kernel_libipsec = xtrue)
1343 AM_CONDITIONAL(USE_WHITELIST, test x$whitelist = xtrue)
1344 AM_CONDITIONAL(USE_LOOKIP, test x$lookip = xtrue)
1345 AM_CONDITIONAL(USE_ERROR_NOTIFY, test x$error_notify = xtrue)
1346 AM_CONDITIONAL(USE_CERTEXPIRE, test x$certexpire = xtrue)
1347 AM_CONDITIONAL(USE_SYSTIME_FIX, test x$systime_fix = xtrue)
1348 AM_CONDITIONAL(USE_LED, test x$led = xtrue)
1349 AM_CONDITIONAL(USE_DUPLICHECK, test x$duplicheck = xtrue)
1350 AM_CONDITIONAL(USE_COUPLING, test x$coupling = xtrue)
1351 AM_CONDITIONAL(USE_RADATTR, test x$radattr = xtrue)
1352 AM_CONDITIONAL(USE_EAP_SIM, test x$eap_sim = xtrue)
1353 AM_CONDITIONAL(USE_EAP_SIM_FILE, test x$eap_sim_file = xtrue)
1354 AM_CONDITIONAL(USE_EAP_SIM_PCSC, test x$eap_sim_pcsc = xtrue)
1355 AM_CONDITIONAL(USE_EAP_SIMAKA_SQL, test x$eap_simaka_sql = xtrue)
1356 AM_CONDITIONAL(USE_EAP_SIMAKA_PSEUDONYM, test x$eap_simaka_pseudonym = xtrue)
1357 AM_CONDITIONAL(USE_EAP_SIMAKA_REAUTH, test x$eap_simaka_reauth = xtrue)
1358 AM_CONDITIONAL(USE_EAP_IDENTITY, test x$eap_identity = xtrue)
1359 AM_CONDITIONAL(USE_EAP_MD5, test x$eap_md5 = xtrue)
1360 AM_CONDITIONAL(USE_EAP_GTC, test x$eap_gtc = xtrue)
1361 AM_CONDITIONAL(USE_EAP_AKA, test x$eap_aka = xtrue)
1362 AM_CONDITIONAL(USE_EAP_AKA_3GPP2, test x$eap_aka_3gpp2 = xtrue)
1363 AM_CONDITIONAL(USE_EAP_MSCHAPV2, test x$eap_mschapv2 = xtrue)
1364 AM_CONDITIONAL(USE_EAP_TLS, test x$eap_tls = xtrue)
1365 AM_CONDITIONAL(USE_EAP_TTLS, test x$eap_ttls = xtrue)
1366 AM_CONDITIONAL(USE_EAP_PEAP, test x$eap_peap = xtrue)
1367 AM_CONDITIONAL(USE_EAP_TNC, test x$eap_tnc = xtrue)
1368 AM_CONDITIONAL(USE_EAP_DYNAMIC, test x$eap_dynamic = xtrue)
1369 AM_CONDITIONAL(USE_EAP_RADIUS, test x$eap_radius = xtrue)
1370 AM_CONDITIONAL(USE_XAUTH_GENERIC, test x$xauth_generic = xtrue)
1371 AM_CONDITIONAL(USE_XAUTH_EAP, test x$xauth_eap = xtrue)
1372 AM_CONDITIONAL(USE_XAUTH_PAM, test x$xauth_pam = xtrue)
1373 AM_CONDITIONAL(USE_XAUTH_NOAUTH, test x$xauth_noauth = xtrue)
1374 AM_CONDITIONAL(USE_TNC_IFMAP, test x$tnc_ifmap = xtrue)
1375 AM_CONDITIONAL(USE_TNC_PDP, test x$tnc_pdp = xtrue)
1376 AM_CONDITIONAL(USE_TNC_IMC, test x$tnc_imc = xtrue)
1377 AM_CONDITIONAL(USE_TNC_IMV, test x$tnc_imv = xtrue)
1378 AM_CONDITIONAL(USE_TNC_TNCCS, test x$tnc_tnccs = xtrue)
1379 AM_CONDITIONAL(USE_TNCCS_11, test x$tnccs_11 = xtrue)
1380 AM_CONDITIONAL(USE_TNCCS_20, test x$tnccs_20 = xtrue)
1381 AM_CONDITIONAL(USE_TNCCS_DYNAMIC, test x$tnccs_dynamic = xtrue)
1382 AM_CONDITIONAL(USE_IMC_TEST, test x$imc_test = xtrue)
1383 AM_CONDITIONAL(USE_IMV_TEST, test x$imv_test = xtrue)
1384 AM_CONDITIONAL(USE_IMC_SCANNER, test x$imc_scanner = xtrue)
1385 AM_CONDITIONAL(USE_IMV_SCANNER, test x$imv_scanner = xtrue)
1386 AM_CONDITIONAL(USE_IMC_OS, test x$imc_os = xtrue)
1387 AM_CONDITIONAL(USE_IMV_OS, test x$imv_os = xtrue)
1388 AM_CONDITIONAL(USE_IMC_ATTESTATION, test x$imc_attestation = xtrue)
1389 AM_CONDITIONAL(USE_IMV_ATTESTATION, test x$imv_attestation = xtrue)
1390 AM_CONDITIONAL(USE_IMC_SWID, test x$imc_swid = xtrue)
1391 AM_CONDITIONAL(USE_IMV_SWID, test x$imv_swid = xtrue)
1392 AM_CONDITIONAL(USE_SOCKET_DEFAULT, test x$socket_default = xtrue)
1393 AM_CONDITIONAL(USE_SOCKET_DYNAMIC, test x$socket_dynamic = xtrue)
1394 AM_CONDITIONAL(USE_FARP, test x$farp = xtrue)
1395 AM_CONDITIONAL(USE_ADDRBLOCK, test x$addrblock = xtrue)
1396 AM_CONDITIONAL(USE_UNITY, test x$unity = xtrue)
1397
1398 #  hydra plugins
1399 # ---------------
1400 AM_CONDITIONAL(USE_ATTR, test x$attr = xtrue)
1401 AM_CONDITIONAL(USE_ATTR_SQL, test x$attr_sql = xtrue)
1402 AM_CONDITIONAL(USE_KERNEL_KLIPS, test x$kernel_klips = xtrue)
1403 AM_CONDITIONAL(USE_KERNEL_NETLINK, test x$kernel_netlink = xtrue)
1404 AM_CONDITIONAL(USE_KERNEL_PFKEY, test x$kernel_pfkey = xtrue)
1405 AM_CONDITIONAL(USE_KERNEL_PFROUTE, test x$kernel_pfroute = xtrue)
1406 AM_CONDITIONAL(USE_RESOLVE, test x$resolve = xtrue)
1407
1408 #  other options
1409 # ---------------
1410 AM_CONDITIONAL(USE_LEAK_DETECTIVE, test x$leak_detective = xtrue)
1411 AM_CONDITIONAL(USE_LOCK_PROFILER, test x$lock_profiler = xtrue)
1412 AM_CONDITIONAL(USE_DUMM, test x$dumm = xtrue)
1413 AM_CONDITIONAL(USE_FAST, test x$fast = xtrue)
1414 AM_CONDITIONAL(USE_MANAGER, test x$manager = xtrue)
1415 AM_CONDITIONAL(USE_ME, test x$mediation = xtrue)
1416 AM_CONDITIONAL(USE_INTEGRITY_TEST, test x$integrity_test = xtrue)
1417 AM_CONDITIONAL(USE_LOAD_WARNING, test x$load_warning = xtrue)
1418 AM_CONDITIONAL(USE_IKEV1, test x$ikev1 = xtrue)
1419 AM_CONDITIONAL(USE_IKEV2, test x$ikev2 = xtrue)
1420 AM_CONDITIONAL(USE_THREADS, test x$threads = xtrue)
1421 AM_CONDITIONAL(USE_ADNS, test x$adns = xtrue)
1422 AM_CONDITIONAL(USE_CHARON, test x$charon = xtrue)
1423 AM_CONDITIONAL(USE_NM, test x$nm = xtrue)
1424 AM_CONDITIONAL(USE_TOOLS, test x$tools = xtrue)
1425 AM_CONDITIONAL(USE_SCRIPTS, test x$scripts = xtrue)
1426 AM_CONDITIONAL(USE_CONFTEST, test x$conftest = xtrue)
1427 AM_CONDITIONAL(USE_LIBSTRONGSWAN, test x$charon = xtrue -o x$tools = xtrue -o x$conftest = xtrue -o x$fast = xtrue -o x$imcv = xtrue -o x$nm = xtrue -o x$tkm = xtrue -o x$cmd = xtrue -o x$tls = xtrue -o x$tnc_tnccs = xtrue -o x$aikgen = xtrue -o x$svc = xtrue)
1428 AM_CONDITIONAL(USE_LIBHYDRA, test x$charon = xtrue -o x$nm = xtrue -o x$tkm = xtrue -o x$cmd = xtrue -o x$svc = xtrue)
1429 AM_CONDITIONAL(USE_LIBCHARON, test x$charon = xtrue -o x$conftest = xtrue -o x$nm = xtrue -o x$tkm = xtrue -o x$cmd = xtrue -o x$svc = xtrue)
1430 AM_CONDITIONAL(USE_LIBIPSEC, test x$libipsec = xtrue)
1431 AM_CONDITIONAL(USE_LIBTNCIF, test x$tnc_tnccs = xtrue -o x$imcv = xtrue)
1432 AM_CONDITIONAL(USE_LIBTNCCS, test x$tnc_tnccs = xtrue)
1433 AM_CONDITIONAL(USE_LIBPTTLS, test x$tnc_tnccs = xtrue)
1434 AM_CONDITIONAL(USE_FILE_CONFIG, test x$stroke = xtrue)
1435 AM_CONDITIONAL(USE_IPSEC_SCRIPT, test x$stroke = xtrue -o x$tools = xtrue -o x$conftest = xtrue)
1436 AM_CONDITIONAL(USE_LIBCAP, test x$capabilities = xlibcap)
1437 AM_CONDITIONAL(USE_VSTR, test x$printf_hooks = xvstr)
1438 AM_CONDITIONAL(USE_BUILTIN_PRINTF, test x$printf_hooks = xbuiltin)
1439 AM_CONDITIONAL(USE_SIMAKA, test x$simaka = xtrue)
1440 AM_CONDITIONAL(USE_TLS, test x$tls = xtrue)
1441 AM_CONDITIONAL(USE_RADIUS, test x$radius = xtrue)
1442 AM_CONDITIONAL(USE_IMCV, test x$imcv = xtrue)
1443 AM_CONDITIONAL(USE_PTS, test x$pts = xtrue)
1444 AM_CONDITIONAL(USE_TROUSERS, test x$tss = xtrousers -o x$aikgen = xtrue)
1445 AM_CONDITIONAL(MONOLITHIC, test x$monolithic = xtrue)
1446 AM_CONDITIONAL(USE_SILENT_RULES, test x$enable_silent_rules = xyes)
1447 AM_CONDITIONAL(COVERAGE, test x$coverage = xtrue)
1448 AM_CONDITIONAL(USE_DBGHELP, test x$dbghelp_backtraces = xtrue)
1449 AM_CONDITIONAL(USE_TKM, test x$tkm = xtrue)
1450 AM_CONDITIONAL(USE_CMD, test x$cmd = xtrue)
1451 AM_CONDITIONAL(USE_AIKGEN, test x$aikgen = xtrue)
1452 AM_CONDITIONAL(USE_SWANCTL, test x$swanctl = xtrue)
1453 AM_CONDITIONAL(USE_SVC, test x$svc = xtrue)
1454
1455 # ========================
1456 #  set global definitions
1457 # ========================
1458
1459 if test x$mediation = xtrue; then
1460         AC_DEFINE([ME], [], [mediation extension support])
1461 fi
1462 if test x$capabilities = xlibcap -o x$capabilities = xnative; then
1463         AC_DEFINE([CAPABILITIES], [], [capability dropping support])
1464 fi
1465 if test x$monolithic = xtrue; then
1466         AC_DEFINE([MONOLITHIC], [], [monolithic build embedding plugins])
1467 fi
1468 if test x$ikev1 = xtrue; then
1469         AC_DEFINE([USE_IKEV1], [], [support for IKEv1 protocol])
1470 fi
1471 if test x$ikev2 = xtrue; then
1472         AC_DEFINE([USE_IKEV2], [], [support for IKEv2 protocol])
1473 fi
1474
1475 # ====================================================
1476 #  options for enabled modules (see conf/Makefile.am)
1477 # ====================================================
1478
1479 strongswan_options=
1480
1481 AM_COND_IF([USE_ATTR_SQL], [strongswan_options=${strongswan_options}" pool"])
1482 AM_COND_IF([USE_CHARON], [strongswan_options=${strongswan_options}" charon charon-logging"])
1483 AM_COND_IF([USE_FILE_CONFIG], [strongswan_options=${strongswan_options}" starter"])
1484 AM_COND_IF([USE_IMV_ATTESTATION], [strongswan_options=${strongswan_options}" attest"])
1485 AM_COND_IF([USE_IMCV], [strongswan_options=${strongswan_options}" imcv"])
1486 AM_COND_IF([USE_IMV_OS], [strongswan_options=${strongswan_options}" pacman"])
1487 AM_COND_IF([USE_LIBTNCCS], [strongswan_options=${strongswan_options}" tnc"])
1488 AM_COND_IF([USE_MANAGER], [strongswan_options=${strongswan_options}" manager"])
1489 AM_COND_IF([USE_MEDSRV], [strongswan_options=${strongswan_options}" medsrv"])
1490 AM_COND_IF([USE_TOOLS], [strongswan_options=${strongswan_options}" tools"])
1491
1492 AC_SUBST(strongswan_options)
1493
1494 # =================
1495 #  build Makefiles
1496 # =================
1497
1498 AC_CONFIG_FILES([
1499         Makefile
1500         conf/Makefile
1501         man/Makefile
1502         init/Makefile
1503         init/systemd/Makefile
1504         src/Makefile
1505         src/include/Makefile
1506         src/libstrongswan/Makefile
1507         src/libstrongswan/plugins/aes/Makefile
1508         src/libstrongswan/plugins/cmac/Makefile
1509         src/libstrongswan/plugins/des/Makefile
1510         src/libstrongswan/plugins/blowfish/Makefile
1511         src/libstrongswan/plugins/rc2/Makefile
1512         src/libstrongswan/plugins/md4/Makefile
1513         src/libstrongswan/plugins/md5/Makefile
1514         src/libstrongswan/plugins/sha1/Makefile
1515         src/libstrongswan/plugins/sha2/Makefile
1516         src/libstrongswan/plugins/fips_prf/Makefile
1517         src/libstrongswan/plugins/gmp/Makefile
1518         src/libstrongswan/plugins/rdrand/Makefile
1519         src/libstrongswan/plugins/random/Makefile
1520         src/libstrongswan/plugins/nonce/Makefile
1521         src/libstrongswan/plugins/hmac/Makefile
1522         src/libstrongswan/plugins/xcbc/Makefile
1523         src/libstrongswan/plugins/x509/Makefile
1524         src/libstrongswan/plugins/revocation/Makefile
1525         src/libstrongswan/plugins/constraints/Makefile
1526         src/libstrongswan/plugins/acert/Makefile
1527         src/libstrongswan/plugins/pubkey/Makefile
1528         src/libstrongswan/plugins/pkcs1/Makefile
1529         src/libstrongswan/plugins/pkcs7/Makefile
1530         src/libstrongswan/plugins/pkcs8/Makefile
1531         src/libstrongswan/plugins/pkcs12/Makefile
1532         src/libstrongswan/plugins/pgp/Makefile
1533         src/libstrongswan/plugins/dnskey/Makefile
1534         src/libstrongswan/plugins/sshkey/Makefile
1535         src/libstrongswan/plugins/pem/Makefile
1536         src/libstrongswan/plugins/curl/Makefile
1537         src/libstrongswan/plugins/unbound/Makefile
1538         src/libstrongswan/plugins/soup/Makefile
1539         src/libstrongswan/plugins/ldap/Makefile
1540         src/libstrongswan/plugins/mysql/Makefile
1541         src/libstrongswan/plugins/sqlite/Makefile
1542         src/libstrongswan/plugins/padlock/Makefile
1543         src/libstrongswan/plugins/openssl/Makefile
1544         src/libstrongswan/plugins/gcrypt/Makefile
1545         src/libstrongswan/plugins/agent/Makefile
1546         src/libstrongswan/plugins/keychain/Makefile
1547         src/libstrongswan/plugins/pkcs11/Makefile
1548         src/libstrongswan/plugins/ctr/Makefile
1549         src/libstrongswan/plugins/ccm/Makefile
1550         src/libstrongswan/plugins/gcm/Makefile
1551         src/libstrongswan/plugins/af_alg/Makefile
1552         src/libstrongswan/plugins/ntru/Makefile
1553         src/libstrongswan/plugins/test_vectors/Makefile
1554         src/libstrongswan/tests/Makefile
1555         src/libhydra/Makefile
1556         src/libhydra/plugins/attr/Makefile
1557         src/libhydra/plugins/attr_sql/Makefile
1558         src/libhydra/plugins/kernel_klips/Makefile
1559         src/libhydra/plugins/kernel_netlink/Makefile
1560         src/libhydra/plugins/kernel_pfkey/Makefile
1561         src/libhydra/plugins/kernel_pfroute/Makefile
1562         src/libhydra/plugins/resolve/Makefile
1563         src/libipsec/Makefile
1564         src/libsimaka/Makefile
1565         src/libtls/Makefile
1566         src/libtls/tests/Makefile
1567         src/libradius/Makefile
1568         src/libtncif/Makefile
1569         src/libtnccs/Makefile
1570         src/libtnccs/plugins/tnc_tnccs/Makefile
1571         src/libtnccs/plugins/tnc_imc/Makefile
1572         src/libtnccs/plugins/tnc_imv/Makefile
1573         src/libtnccs/plugins/tnccs_11/Makefile
1574         src/libtnccs/plugins/tnccs_20/Makefile
1575         src/libtnccs/plugins/tnccs_dynamic/Makefile
1576         src/libpttls/Makefile
1577         src/libpts/Makefile
1578         src/libpts/plugins/imc_attestation/Makefile
1579         src/libpts/plugins/imv_attestation/Makefile
1580         src/libpts/plugins/imc_swid/Makefile
1581         src/libpts/plugins/imv_swid/Makefile
1582         src/libimcv/Makefile
1583         src/libimcv/plugins/imc_test/Makefile
1584         src/libimcv/plugins/imv_test/Makefile
1585         src/libimcv/plugins/imc_scanner/Makefile
1586         src/libimcv/plugins/imv_scanner/Makefile
1587         src/libimcv/plugins/imc_os/Makefile
1588         src/libimcv/plugins/imv_os/Makefile
1589         src/charon/Makefile
1590         src/charon-nm/Makefile
1591         src/charon-tkm/Makefile
1592         src/charon-cmd/Makefile
1593         src/charon-svc/Makefile
1594         src/libcharon/Makefile
1595         src/libcharon/plugins/eap_aka/Makefile
1596         src/libcharon/plugins/eap_aka_3gpp2/Makefile
1597         src/libcharon/plugins/eap_dynamic/Makefile
1598         src/libcharon/plugins/eap_identity/Makefile
1599         src/libcharon/plugins/eap_md5/Makefile
1600         src/libcharon/plugins/eap_gtc/Makefile
1601         src/libcharon/plugins/eap_sim/Makefile
1602         src/libcharon/plugins/eap_sim_file/Makefile
1603         src/libcharon/plugins/eap_sim_pcsc/Makefile
1604         src/libcharon/plugins/eap_simaka_sql/Makefile
1605         src/libcharon/plugins/eap_simaka_pseudonym/Makefile
1606         src/libcharon/plugins/eap_simaka_reauth/Makefile
1607         src/libcharon/plugins/eap_mschapv2/Makefile
1608         src/libcharon/plugins/eap_tls/Makefile
1609         src/libcharon/plugins/eap_ttls/Makefile
1610         src/libcharon/plugins/eap_peap/Makefile
1611         src/libcharon/plugins/eap_tnc/Makefile
1612         src/libcharon/plugins/eap_radius/Makefile
1613         src/libcharon/plugins/xauth_generic/Makefile
1614         src/libcharon/plugins/xauth_eap/Makefile
1615         src/libcharon/plugins/xauth_pam/Makefile
1616         src/libcharon/plugins/xauth_noauth/Makefile
1617         src/libcharon/plugins/tnc_ifmap/Makefile
1618         src/libcharon/plugins/tnc_pdp/Makefile
1619         src/libcharon/plugins/socket_default/Makefile
1620         src/libcharon/plugins/socket_dynamic/Makefile
1621         src/libcharon/plugins/farp/Makefile
1622         src/libcharon/plugins/smp/Makefile
1623         src/libcharon/plugins/sql/Makefile
1624         src/libcharon/plugins/dnscert/Makefile
1625         src/libcharon/plugins/ipseckey/Makefile
1626         src/libcharon/plugins/medsrv/Makefile
1627         src/libcharon/plugins/medcli/Makefile
1628         src/libcharon/plugins/addrblock/Makefile
1629         src/libcharon/plugins/unity/Makefile
1630         src/libcharon/plugins/uci/Makefile
1631         src/libcharon/plugins/ha/Makefile
1632         src/libcharon/plugins/kernel_libipsec/Makefile
1633         src/libcharon/plugins/whitelist/Makefile
1634         src/libcharon/plugins/lookip/Makefile
1635         src/libcharon/plugins/error_notify/Makefile
1636         src/libcharon/plugins/certexpire/Makefile
1637         src/libcharon/plugins/systime_fix/Makefile
1638         src/libcharon/plugins/led/Makefile
1639         src/libcharon/plugins/duplicheck/Makefile
1640         src/libcharon/plugins/coupling/Makefile
1641         src/libcharon/plugins/radattr/Makefile
1642         src/libcharon/plugins/osx_attr/Makefile
1643         src/libcharon/plugins/android_dns/Makefile
1644         src/libcharon/plugins/android_log/Makefile
1645         src/libcharon/plugins/maemo/Makefile
1646         src/libcharon/plugins/stroke/Makefile
1647         src/libcharon/plugins/vici/Makefile
1648         src/libcharon/plugins/updown/Makefile
1649         src/libcharon/plugins/dhcp/Makefile
1650         src/libcharon/plugins/unit_tester/Makefile
1651         src/libcharon/plugins/load_tester/Makefile
1652         src/stroke/Makefile
1653         src/ipsec/Makefile
1654         src/starter/Makefile
1655         src/_updown/Makefile
1656         src/_updown_espmark/Makefile
1657         src/_copyright/Makefile
1658         src/scepclient/Makefile
1659         src/aikgen/Makefile
1660         src/pki/Makefile
1661         src/pki/man/Makefile
1662         src/pool/Makefile
1663         src/dumm/Makefile
1664         src/dumm/ext/extconf.rb
1665         src/libfast/Makefile
1666         src/manager/Makefile
1667         src/medsrv/Makefile
1668         src/checksum/Makefile
1669         src/conftest/Makefile
1670         src/pt-tls-client/Makefile
1671         src/swanctl/Makefile
1672         scripts/Makefile
1673         testing/Makefile
1674 ])
1675
1676 # =================
1677 #  build man pages
1678 # =================
1679
1680 AC_CONFIG_FILES([
1681         conf/strongswan.conf.5.head
1682         conf/strongswan.conf.5.tail
1683         man/ipsec.conf.5
1684         man/ipsec.secrets.5
1685         src/charon-cmd/charon-cmd.8
1686         src/pki/man/pki.1
1687         src/pki/man/pki---gen.1
1688         src/pki/man/pki---issue.1
1689         src/pki/man/pki---keyid.1
1690         src/pki/man/pki---pkcs7.1
1691         src/pki/man/pki---print.1
1692         src/pki/man/pki---pub.1
1693         src/pki/man/pki---req.1
1694         src/pki/man/pki---self.1
1695         src/pki/man/pki---signcrl.1
1696         src/pki/man/pki---acert.1
1697         src/pki/man/pki---verify.1
1698         src/swanctl/swanctl.8
1699         src/swanctl/swanctl.conf.5.head
1700         src/swanctl/swanctl.conf.5.tail
1701 ])
1702
1703 AC_OUTPUT
1704
1705 # ========================
1706 #  report enabled plugins
1707 # ========================
1708
1709 AC_MSG_RESULT([])
1710 AC_MSG_RESULT([ strongSwan will be built with the following plugins])
1711 AC_MSG_RESULT([-----------------------------------------------------])
1712
1713 AC_MSG_RESULT([libstrongswan:$s_plugins])
1714 AC_MSG_RESULT([libcharon:    $c_plugins])
1715 AC_MSG_RESULT([libhydra:     $h_plugins])
1716 AC_MSG_RESULT([libtnccs:     $t_plugins])
1717 AC_MSG_RESULT([])