configure: Reorder and group feature options
[strongswan.git] / configure.ac
1 #
2 # Copyright (C) 2007-2014 Tobias Brunner
3 # Copyright (C) 2006-2013 Andreas Steffen
4 # Copyright (C) 2006-2013 Martin Willi
5 # Hochschule fuer Technik Rapperswil
6 #
7 # This program is free software; you can redistribute it and/or modify it
8 # under the terms of the GNU General Public License as published by the
9 # Free Software Foundation; either version 2 of the License, or (at your
10 # option) any later version.  See <http://www.fsf.org/copyleft/gpl.txt>.
11 #
12 # This program is distributed in the hope that it will be useful, but
13 # WITHOUT ANY WARRANTY; without even the implied warranty of MERCHANTABILITY
14 # or FITNESS FOR A PARTICULAR PURPOSE.  See the GNU General Public License
15 # for more details.
16 #
17
18 # ============================
19 #  initialize & set some vars
20 # ============================
21
22 AC_INIT([strongSwan],[5.1.3dr1])
23 AM_INIT_AUTOMAKE(m4_esyscmd([
24         echo tar-ustar
25         echo subdir-objects
26         case `automake --version | head -n 1` in
27                 *" 1.9"*);;
28                 *" 1.10"*);;
29                 *" 1.11"*);;
30                 # don't use parallel test harness in 1.12 and up
31                 *) echo serial-tests;;
32         esac
33 ]))
34 m4_ifdef([AM_SILENT_RULES], [AM_SILENT_RULES])
35 AC_CONFIG_MACRO_DIR([m4/config])
36 AC_CONFIG_HEADERS([config.h])
37 AC_DEFINE([CONFIG_H_INCLUDED], [], [defined if config.h included])
38 PKG_PROG_PKG_CONFIG
39
40 m4_include(m4/macros/split-package-version.m4)
41 SPLIT_PACKAGE_VERSION
42
43 # =================================
44 #  check --enable-xxx & --with-xxx
45 # =================================
46
47 m4_include(m4/macros/with.m4)
48
49 ARG_WITH_SUBST([random-device],      [/dev/random], [set the device to read real random data from])
50 ARG_WITH_SUBST([urandom-device],     [/dev/urandom], [set the device to read pseudo random data from])
51 ARG_WITH_SUBST([strongswan-conf],    [${sysconfdir}/strongswan.conf], [set the strongswan.conf file location])
52 ARG_WITH_SUBST([resolv-conf],        [${sysconfdir}/resolv.conf], [set the file to use in DNS handler plugin])
53 ARG_WITH_SUBST([piddir],             [/var/run], [set path for PID and UNIX socket files])
54 ARG_WITH_SUBST([ipsecdir],           [${libexecdir%/}/ipsec], [set installation path for ipsec tools])
55 ARG_WITH_SUBST([ipseclibdir],        [${libdir%/}/ipsec], [set installation path for ipsec libraries])
56 ARG_WITH_SUBST([plugindir],          [${ipseclibdir%/}/plugins], [set the installation path of plugins])
57 ARG_WITH_SUBST([imcvdir],            [${ipseclibdir%/}/imcvs], [set the installation path of IMC and IMV dynamic librariers])
58 ARG_WITH_SUBST([nm-ca-dir],          [/usr/share/ca-certificates], [directory the NM backend uses to look up trusted root certificates])
59 ARG_WITH_SUBST([linux-headers],      [\${top_srcdir}/src/include], [set directory of linux header files to use])
60 ARG_WITH_SUBST([routing-table],      [220], [set routing table to use for IPsec routes])
61 ARG_WITH_SUBST([routing-table-prio], [220], [set priority for IPsec routing table])
62 ARG_WITH_SUBST([ipsec-script],       [ipsec], [change the name of the ipsec script])
63 ARG_WITH_SUBST([fips-mode],          [0], [set openssl FIPS mode: disabled(0), enabled(1), Suite B enabled(2)])
64
65 ARG_WITH_SET([tss],                  [no], [set implementation of the Trusted Computing Group's Software Stack (TSS). Currently the only supported value is "trousers"])
66 ARG_WITH_SET([capabilities],         [no], [set capability dropping library. Currently supported values are "libcap" and "native"])
67 ARG_WITH_SET([mpz_powm_sec],         [yes], [use the more side-channel resistant mpz_powm_sec in libgmp, if available])
68 ARG_WITH_SET([dev-headers],          [no], [install strongSwan development headers to directory.])
69
70 if test -n "$PKG_CONFIG"; then
71         systemdsystemunitdir_default=$($PKG_CONFIG --variable=systemdsystemunitdir systemd)
72 fi
73 ARG_WITH_SET([systemdsystemunitdir], [$systemdsystemunitdir_default], [directory for systemd service files])
74 AM_CONDITIONAL(HAVE_SYSTEMD, [test -n "$systemdsystemunitdir" -a "x$systemdsystemunitdir" != xno])
75 AC_SUBST(systemdsystemunitdir)
76
77 AC_ARG_WITH(
78         [user],
79         AS_HELP_STRING([--with-user=user],[change user of the daemons to "user" after startup (default is "root").]),
80         [AC_DEFINE_UNQUOTED([IPSEC_USER], "$withval", [username to run daemon with])
81          AC_SUBST(ipsecuser, "$withval")],
82         [AC_SUBST(ipsecuser, "root")]
83 )
84
85 AC_ARG_WITH(
86         [group],
87         AS_HELP_STRING([--with-group=group],[change group of the daemons to "group" after startup (default is "root").]),
88         [AC_DEFINE_UNQUOTED(IPSEC_GROUP, "$withval", [groupname to run daemon with])
89          AC_SUBST(ipsecgroup, "$withval")],
90         [AC_SUBST(ipsecgroup, "root")]
91 )
92
93 AC_ARG_WITH(
94         [charon-udp-port],
95         AS_HELP_STRING([--with-charon-udp-port=port],[UDP port used by charon locally (default 500). Set to 0 to allocate randomly.]),
96         [AC_DEFINE_UNQUOTED(CHARON_UDP_PORT, [$withval], [UDP port used by charon locally])
97          AC_SUBST(charon_udp_port, [$withval])],
98         [AC_SUBST(charon_udp_port, 500)]
99 )
100
101 AC_ARG_WITH(
102         [charon-natt-port],
103         AS_HELP_STRING([--with-charon-natt-port=port],[UDP port used by charon locally in case a NAT is detected (must be different from charon-udp-port, default 4500). Set to 0 to allocate randomly.]),
104         [AC_DEFINE_UNQUOTED(CHARON_NATT_PORT, [$withval], [UDP post used by charon locally in case a NAT is detected])
105          AC_SUBST(charon_natt_port, [$withval])],
106         [AC_SUBST(charon_natt_port, 4500)]
107 )
108
109 AC_MSG_CHECKING([configured UDP ports ($charon_udp_port, $charon_natt_port)])
110 if test x$charon_udp_port != x0 -a x$charon_udp_port = x$charon_natt_port; then
111         AC_MSG_ERROR(the ports have to be different)
112 else
113         AC_MSG_RESULT(ok)
114 fi
115
116 # convert script name to uppercase
117 AC_SUBST(ipsec_script_upper, [`echo -n "$ipsec_script" | tr a-z A-Z`])
118
119 m4_include(m4/macros/enable-disable.m4)
120
121 # crypto plugins
122 ARG_DISBL_SET([aes],            [disable AES software implementation plugin.])
123 ARG_ENABL_SET([af-alg],         [enable AF_ALG crypto interface to Linux Crypto API.])
124 ARG_ENABL_SET([blowfish],       [enable Blowfish software implementation plugin.])
125 ARG_ENABL_SET([ccm],            [enables the CCM AEAD wrapper crypto plugin.])
126 ARG_DISBL_SET([cmac],           [disable CMAC crypto implementation plugin.])
127 ARG_ENABL_SET([ctr],            [enables the Counter Mode wrapper crypto plugin.])
128 ARG_DISBL_SET([des],            [disable DES/3DES software implementation plugin.])
129 ARG_DISBL_SET([fips-prf],       [disable FIPS PRF software implementation plugin.])
130 ARG_ENABL_SET([gcm],            [enables the GCM AEAD wrapper crypto plugin.])
131 ARG_ENABL_SET([gcrypt],         [enables the libgcrypt plugin.])
132 ARG_DISBL_SET([gmp],            [disable GNU MP (libgmp) based crypto implementation plugin.])
133 ARG_DISBL_SET([hmac],           [disable HMAC crypto implementation plugin.])
134 ARG_ENABL_SET([md4],            [enable MD4 software implementation plugin.])
135 ARG_DISBL_SET([md5],            [disable MD5 software implementation plugin.])
136 ARG_DISBL_SET([nonce],          [disable nonce generation plugin.])
137 ARG_ENABL_SET([ntru],           [enables the NTRU crypto plugin.])
138 ARG_ENABL_SET([openssl],        [enables the OpenSSL crypto plugin.])
139 ARG_ENABL_SET([padlock],        [enables VIA Padlock crypto plugin.])
140 ARG_DISBL_SET([random],         [disable RNG implementation on top of /dev/(u)random.])
141 ARG_DISBL_SET([rc2],            [disable RC2 software implementation plugin.])
142 ARG_ENABL_SET([rdrand],         [enable Intel RDRAND random generator plugin.])
143 ARG_DISBL_SET([sha1],           [disable SHA1 software implementation plugin.])
144 ARG_DISBL_SET([sha2],           [disable SHA256/SHA384/SHA512 software implementation plugin.])
145 ARG_DISBL_SET([xcbc],           [disable xcbc crypto implementation plugin.])
146 # encoding/decoding plugins
147 ARG_DISBL_SET([dnskey],         [disable DNS RR key decoding plugin.])
148 ARG_DISBL_SET([pem],            [disable PEM decoding plugin.])
149 ARG_DISBL_SET([pgp],            [disable PGP key decoding plugin.])
150 ARG_DISBL_SET([pkcs1],          [disable PKCS1 key decoding plugin.])
151 ARG_DISBL_SET([pkcs7],          [disable PKCS7 container support plugin.])
152 ARG_DISBL_SET([pkcs8],          [disable PKCS8 private key decoding plugin.])
153 ARG_DISBL_SET([pkcs12],         [disable PKCS12 container support plugin.])
154 ARG_DISBL_SET([pubkey],         [disable RAW public key support plugin.])
155 ARG_DISBL_SET([sshkey],         [disable SSH key decoding plugin.])
156 ARG_DISBL_SET([x509],           [disable X509 certificate implementation plugin.])
157 # fetcher/resolver plugins
158 ARG_ENABL_SET([curl],           [enable CURL fetcher plugin to fetch files via libcurl. Requires libcurl.])
159 ARG_ENABL_SET([ldap],           [enable LDAP fetching plugin to fetch files via libldap. Requires openLDAP.])
160 ARG_ENABL_SET([soup],           [enable soup fetcher plugin to fetch from HTTP via libsoup. Requires libsoup.])
161 ARG_ENABL_SET([unbound],        [enable UNBOUND resolver plugin to perform DNS queries via libunbound. Requires libldns and libunbound.])
162 # database plugins
163 ARG_ENABL_SET([mysql],          [enable MySQL database support. Requires libmysqlclient_r.])
164 ARG_ENABL_SET([sqlite],         [enable SQLite database support. Requires libsqlite3.])
165 # authentication/credential plugins
166 ARG_ENABL_SET([addrblock],      [enables RFC 3779 address block constraint support.])
167 ARG_ENABL_SET([agent],          [enables the ssh-agent signing plugin.])
168 ARG_DISBL_SET([constraints],    [disable advanced X509 constraint checking plugin.])
169 ARG_ENABL_SET([coupling],       [enable IKEv2 plugin to couple peer certificates permanently to authentication.])
170 ARG_ENABL_SET([dnscert],        [enable DNSCERT authentication plugin.])
171 ARG_ENABL_SET([eap-sim],        [enable SIM authentication module for EAP.])
172 ARG_ENABL_SET([eap-sim-file],   [enable EAP-SIM backend based on a triplet file.])
173 ARG_ENABL_SET([eap-sim-pcsc],   [enable EAP-SIM backend based on a smartcard reader. Requires libpcsclite.])
174 ARG_ENABL_SET([eap-aka],        [enable EAP AKA authentication module.])
175 ARG_ENABL_SET([eap-aka-3gpp2],  [enable EAP AKA backend implementing 3GPP2 algorithms in software. Requires libgmp.])
176 ARG_ENABL_SET([eap-simaka-sql], [enable EAP-SIM/AKA backend based on a triplet/quintuplet SQL database.])
177 ARG_ENABL_SET([eap-simaka-pseudonym], [enable EAP-SIM/AKA pseudonym storage plugin.])
178 ARG_ENABL_SET([eap-simaka-reauth],    [enable EAP-SIM/AKA reauthentication data storage plugin.])
179 ARG_ENABL_SET([eap-identity],   [enable EAP module providing EAP-Identity helper.])
180 ARG_ENABL_SET([eap-md5],        [enable EAP MD5 (CHAP) authentication module.])
181 ARG_ENABL_SET([eap-gtc],        [enable EAP GTC authentication module.])
182 ARG_ENABL_SET([eap-mschapv2],   [enable EAP MS-CHAPv2 authentication module.])
183 ARG_ENABL_SET([eap-tls],        [enable EAP TLS authentication module.])
184 ARG_ENABL_SET([eap-ttls],       [enable EAP TTLS authentication module.])
185 ARG_ENABL_SET([eap-peap],       [enable EAP PEAP authentication module.])
186 ARG_ENABL_SET([eap-tnc],        [enable EAP TNC trusted network connect module.])
187 ARG_ENABL_SET([eap-dynamic],    [enable dynamic EAP proxy module.])
188 ARG_ENABL_SET([eap-radius],     [enable RADIUS proxy authentication module.])
189 ARG_ENABL_SET([ipseckey],       [enable IPSECKEY authentication plugin.])
190 ARG_ENABL_SET([keychain],       [enables OS X Keychain Services credential set.])
191 ARG_ENABL_SET([pkcs11],         [enables the PKCS11 token support plugin.])
192 ARG_DISBL_SET([revocation],     [disable X509 CRL/OCSP revocation check plugin.])
193 ARG_ENABL_SET([whitelist],      [enable peer identity whitelisting plugin.])
194 ARG_DISBL_SET([xauth-generic],  [disable generic XAuth backend.])
195 ARG_ENABL_SET([xauth-eap],      [enable XAuth backend using EAP methods to verify passwords.])
196 ARG_ENABL_SET([xauth-pam],      [enable XAuth backend using PAM to verify passwords.])
197 ARG_ENABL_SET([xauth-noauth],   [enable XAuth pseudo-backend that does not actually verify or even request any credentials.])
198 # kernel interfaces / sockets
199 ARG_DISBL_SET([kernel-netlink], [disable the netlink kernel interface.])
200 ARG_ENABL_SET([kernel-pfkey],   [enable the PF_KEY kernel interface.])
201 ARG_ENABL_SET([kernel-pfroute], [enable the PF_ROUTE kernel interface.])
202 ARG_ENABL_SET([kernel-klips],   [enable the KLIPS kernel interface.])
203 ARG_ENABL_SET([kernel-libipsec],[enable the libipsec kernel interface.])
204 ARG_DISBL_SET([socket-default], [disable default socket implementation for charon.])
205 ARG_ENABL_SET([socket-dynamic], [enable dynamic socket implementation for charon])
206 # configuration/control plugins
207 ARG_DISBL_SET([stroke],         [disable charons stroke configuration backend.])
208 ARG_ENABL_SET([smp],            [enable SMP configuration and control interface. Requires libxml.])
209 ARG_ENABL_SET([sql],            [enable SQL database configuration backend.])
210 ARG_ENABL_SET([uci],            [enable OpenWRT UCI configuration plugin.])
211 # attribute provider/consumer plugins
212 ARG_ENABL_SET([android-dns],    [enable Android specific DNS handler.])
213 ARG_DISBL_SET([attr],           [disable strongswan.conf based configuration attribute plugin.])
214 ARG_ENABL_SET([attr-sql],       [enable SQL based configuration attribute plugin.])
215 ARG_ENABL_SET([dhcp],           [enable DHCP based attribute provider plugin.])
216 ARG_ENABL_SET([osx-attr],       [enable OS X SystemConfiguration attribute handler.])
217 ARG_DISBL_SET([resolve],        [disable resolve DNS handler plugin.])
218 ARG_ENABL_SET([unity],          [enables Cisco Unity extension plugin.])
219 # TNC modules/plugins
220 ARG_ENABL_SET([imc-test],       [enable IMC test module.])
221 ARG_ENABL_SET([imv-test],       [enable IMV test module.])
222 ARG_ENABL_SET([imc-scanner],    [enable IMC port scanner module.])
223 ARG_ENABL_SET([imv-scanner],    [enable IMV port scanner module.])
224 ARG_ENABL_SET([imc-os],         [enable IMC operating system module.])
225 ARG_ENABL_SET([imv-os],         [enable IMV operating system module.])
226 ARG_ENABL_SET([imc-attestation],[enable IMC attestation module.])
227 ARG_ENABL_SET([imv-attestation],[enable IMV attestation module.])
228 ARG_ENABL_SET([imc-swid],       [enable IMC swid module.])
229 ARG_ENABL_SET([imv-swid],       [enable IMV swid module.])
230 ARG_ENABL_SET([tnc-ifmap],      [enable TNC IF-MAP module. Requires libxml])
231 ARG_ENABL_SET([tnc-imc],        [enable TNC IMC module.])
232 ARG_ENABL_SET([tnc-imv],        [enable TNC IMV module.])
233 ARG_ENABL_SET([tnc-pdp],        [enable TNC policy decision point module.])
234 ARG_ENABL_SET([tnccs-11],       [enable TNCCS 1.1 protocol module. Requires libxml])
235 ARG_ENABL_SET([tnccs-20],       [enable TNCCS 2.0 protocol module.])
236 ARG_ENABL_SET([tnccs-dynamic],  [enable dynamic TNCCS protocol discovery module.])
237 # misc plugins
238 ARG_ENABL_SET([android-log],    [enable Android specific logger plugin.])
239 ARG_ENABL_SET([certexpire],     [enable CSV export of expiration dates of used certificates.])
240 ARG_ENABL_SET([duplicheck],     [advanced duplicate checking plugin using liveness checks.])
241 ARG_ENABL_SET([error-notify],   [enable error notification plugin.])
242 ARG_ENABL_SET([farp],           [enable ARP faking plugin that responds to ARP requests to peers virtual IP])
243 ARG_ENABL_SET([ha],             [enable high availability cluster plugin.])
244 ARG_ENABL_SET([led],            [enable plugin to control LEDs on IKEv2 activity using the Linux kernel LED subsystem.])
245 ARG_ENABL_SET([load-tester],    [enable load testing plugin for IKEv2 daemon.])
246 ARG_ENABL_SET([lookip],         [enable fast virtual IP lookup and notification plugin.])
247 ARG_ENABL_SET([maemo],          [enable Maemo specific plugin.])
248 ARG_ENABL_SET([radattr],        [enable plugin to inject and process custom RADIUS attributes as IKEv2 client.])
249 ARG_ENABL_SET([systime-fix],    [enable plugin to handle cert lifetimes with invalid system time gracefully.])
250 ARG_ENABL_SET([test-vectors],   [enable plugin providing crypto test vectors.])
251 ARG_ENABL_SET([unit-tester],    [enable unit tests on IKEv2 daemon startup.])
252 ARG_DISBL_SET([updown],         [disable updown firewall script plugin.])
253 # programs/components
254 ARG_DISBL_SET([charon],         [disable the IKEv1/IKEv2 keying daemon charon.])
255 ARG_ENABL_SET([cmd],            [enable the command line IKE client charon-cmd.])
256 ARG_ENABL_SET([conftest],       [enforce Suite B conformance test framework.])
257 ARG_ENABL_SET([dumm],           [enable the DUMM UML test framework.])
258 ARG_ENABL_SET([fast],           [enable libfast (FastCGI Application Server w/ templates.])
259 ARG_ENABL_SET([libipsec],       [enable user space IPsec implementation.])
260 ARG_ENABL_SET([manager],        [enable web management console (proof of concept).])
261 ARG_ENABL_SET([medcli],         [enable mediation client configuration database plugin.])
262 ARG_ENABL_SET([medsrv],         [enable mediation server web frontend and daemon plugin.])
263 ARG_ENABL_SET([nm],             [enable NetworkManager backend.])
264 ARG_DISBL_SET([scripts],        [disable additional utilities (found in directory scripts).])
265 ARG_ENABL_SET([tkm],            [enable Trusted Key Manager support.])
266 ARG_DISBL_SET([tools],          [disable additional utilities (openac, scepclient and pki).])
267 # optional features
268 ARG_ENABL_SET([bfd-backtraces], [use binutils libbfd to resolve backtraces for memory leaks and segfaults.])
269 ARG_DISBL_SET([ikev1],          [disable IKEv1 protocol support in charon.])
270 ARG_DISBL_SET([ikev2],          [disable IKEv2 protocol support in charon.])
271 ARG_ENABL_SET([integrity-test], [enable integrity testing of libstrongswan and plugins.])
272 ARG_DISBL_SET([load-warning],   [disable the charon plugin load option warning in starter.])
273 ARG_ENABL_SET([mediation],      [enable IKEv2 Mediation Extension.])
274 ARG_ENABL_SET([unwind-backtraces],[use libunwind to create backtraces for memory leaks and segfaults.])
275 ARG_ENABL_SET([vstr],           [enforce using the Vstr string library to replace glibc-like printf hooks.])
276 # compile options
277 ARG_ENABL_SET([coverage],       [enable lcov coverage report generation.])
278 ARG_ENABL_SET([leak-detective], [enable malloc hooks to find memory leaks.])
279 ARG_ENABL_SET([lock-profiler],  [enable lock/mutex profiling code.])
280 ARG_ENABL_SET([monolithic],     [build monolithic version of libstrongswan that includes all enabled plugins. Similarly, the plugins of charon are assembled in libcharon.])
281
282 # ===================================
283 #  option to disable default options
284 # ===================================
285
286 ARG_DISBL_SET([defaults],       [disable all default plugins (they can be enabled with their respective --enable options)])
287
288 if test x$defaults = xfalse; then
289         for option in $enabled_by_default; do
290                 eval test x\${${option}_given} = xtrue && continue
291                 let $option=false
292         done
293 fi
294
295 # ===========================
296 #  set up compiler and flags
297 # ===========================
298
299 if test -z "$CFLAGS"; then
300         CFLAGS="-g -O2 -Wall -Wno-format -Wno-format-security -Wno-pointer-sign"
301 fi
302 AC_PROG_CC
303 AM_PROG_CC_C_O
304
305 AC_LIB_PREFIX
306 AC_C_BIGENDIAN
307
308 # =========================
309 #  check required programs
310 # =========================
311
312 LT_INIT
313 AC_PROG_INSTALL
314 AC_PROG_EGREP
315 AC_PROG_AWK
316 AC_PROG_LEX
317 AC_PROG_YACC
318 AM_PATH_PYTHON(,,[:])
319 AC_PATH_PROG([PERL], [perl], [], [$PATH:/bin:/usr/bin:/usr/local/bin])
320 AC_PATH_PROG([GPERF], [gperf], [], [$PATH:/bin:/usr/bin:/usr/local/bin])
321
322 # because gperf is not needed by end-users we just report it but do not abort on failure
323 AC_MSG_CHECKING([gperf version >= 3.0.0])
324 if test -x "$GPERF"; then
325         if test "`$GPERF --version | $AWK -F' ' '/^GNU gperf/ { print $3 }' | $AWK -F. '{ print $1 }'`" -ge "3"; then
326                 AC_MSG_RESULT([yes])
327         else
328                 AC_MSG_RESULT([no])
329         fi
330 else
331         AC_MSG_RESULT([not found])
332 fi
333
334 # ========================
335 #  dependency calculation
336 # ========================
337
338 if test x$xauth_generic_given = xfalse -a x$ikev1 = xfalse; then
339         xauth_generic=false;
340 fi
341
342 if test x$kernel_libipsec = xtrue; then
343         libipsec=true;
344 fi
345
346 if test x$eap_aka_3gpp2 = xtrue; then
347         gmp=true;
348 fi
349
350 if test x$eap_aka = xtrue; then
351         fips_prf=true;
352         simaka=true;
353 fi
354
355 if test x$eap_sim = xtrue; then
356         fips_prf=true;
357         simaka=true;
358 fi
359
360 if test x$eap_radius = xtrue -o x$radattr = xtrue -o x$tnc_pdp = xtrue; then
361         radius=true;
362 fi
363
364 if test x$tnc_imc = xtrue -o x$tnc_imv = xtrue -o x$tnccs_11 = xtrue -o x$tnccs_11 = xtrue -o x$tnccs_dynamic = xtrue -o x$eap_tnc = xtrue; then
365         tnc_tnccs=true;
366 fi
367
368 if test x$eap_tls = xtrue -o x$eap_ttls = xtrue -o x$eap_peap = xtrue -o x$tnc_tnccs = xtrue; then
369         tls=true;
370 fi
371
372 if test x$imc_test = xtrue -o x$imv_test = xtrue -o x$imc_scanner = xtrue -o x$imv_scanner = xtrue -o x$imc_os = xtrue -o x$imv_os = xtrue -o x$imc_attestation = xtrue -o x$imv_attestation = xtrue -o x$imc_swid = xtrue -o x$imv_swid = xtrue; then
373         imcv=true;
374 fi
375
376 if test x$imc_attestation = xtrue -o x$imv_attestation = xtrue -o x$imc_swid = xtrue -o x$imv_swid = xtrue; then
377         pts=true;
378 fi
379
380 if test x$fips_prf = xtrue; then
381         if test x$openssl = xfalse; then
382                 sha1=true;
383         fi
384 fi
385
386 if test x$smp = xtrue -o x$tnccs_11 = xtrue -o x$tnc_ifmap = xtrue; then
387         xml=true
388 fi
389
390 if test x$manager = xtrue; then
391         fast=true
392 fi
393
394 if test x$medsrv = xtrue; then
395         mediation=true
396         fast=true
397 fi
398
399 if test x$medcli = xtrue; then
400         mediation=true
401 fi
402
403 # ===========================================
404 #  check required libraries and header files
405 # ===========================================
406
407 AC_HEADER_STDBOOL
408 AC_FUNC_ALLOCA
409 AC_FUNC_STRERROR_R
410
411 #  libraries needed on some platforms but not on others
412 # ------------------------------------------------------
413 saved_LIBS=$LIBS
414
415 # FreeBSD and Mac OS X have dlopen integrated in libc, Linux needs libdl
416 LIBS=""
417 AC_SEARCH_LIBS(dlopen, dl, [DLLIB=$LIBS])
418 AC_SUBST(DLLIB)
419
420 # glibc's backtrace() can be replicated on FreeBSD with libexecinfo
421 LIBS=""
422 AC_SEARCH_LIBS(backtrace, execinfo, [BTLIB=$LIBS])
423 AC_CHECK_FUNCS(backtrace)
424 AC_SUBST(BTLIB)
425
426 # OpenSolaris needs libsocket and libnsl for socket()
427 LIBS=""
428 AC_SEARCH_LIBS(socket, socket, [SOCKLIB=$LIBS],
429         [AC_CHECK_LIB(nsl, socket, [SOCKLIB="-lsocket -lnsl"], [], [-lsocket])]
430 )
431 AC_SUBST(SOCKLIB)
432
433 # FreeBSD has clock_gettime in libc, Linux needs librt
434 LIBS=""
435 AC_SEARCH_LIBS(clock_gettime, rt, [RTLIB=$LIBS])
436 AC_CHECK_FUNCS(clock_gettime)
437 AC_SUBST(RTLIB)
438
439 # Android has pthread_* functions in bionic (libc), others need libpthread
440 LIBS=""
441 AC_SEARCH_LIBS(pthread_create, pthread, [PTHREADLIB=$LIBS])
442 AC_SUBST(PTHREADLIB)
443
444 LIBS=$saved_LIBS
445 # ------------------------------------------------------
446
447 AC_MSG_CHECKING(for dladdr)
448 AC_COMPILE_IFELSE(
449         [AC_LANG_PROGRAM(
450                 [[#define _GNU_SOURCE
451                   #include <dlfcn.h>]],
452                 [[Dl_info* info = 0;
453                   dladdr(0, info);]])],
454         [AC_MSG_RESULT([yes]); AC_DEFINE([HAVE_DLADDR], [], [have dladdr()])],
455         [AC_MSG_RESULT([no])]
456 )
457
458 # check if pthread_condattr_setclock(CLOCK_MONOTONE) is supported
459 saved_LIBS=$LIBS
460 LIBS=$PTHREADLIB
461 AC_MSG_CHECKING([for pthread_condattr_setclock(CLOCK_MONOTONE)])
462 AC_RUN_IFELSE(
463         [AC_LANG_SOURCE(
464                 [[#include <pthread.h>
465                   int main() { pthread_condattr_t attr;
466                         pthread_condattr_init(&attr);
467                         return pthread_condattr_setclock(&attr, CLOCK_MONOTONIC);}]])],
468         [AC_MSG_RESULT([yes]);
469          AC_DEFINE([HAVE_CONDATTR_CLOCK_MONOTONIC], [],
470                            [pthread_condattr_setclock supports CLOCK_MONOTONIC])],
471         [AC_MSG_RESULT([no])],
472         # Check existence of pthread_condattr_setclock if cross-compiling
473         [AC_MSG_RESULT([unknown]);
474          AC_CHECK_FUNCS(pthread_condattr_setclock,
475                 [AC_DEFINE([HAVE_CONDATTR_CLOCK_MONOTONIC], [],
476                                    [have pthread_condattr_setclock()])]
477         )]
478 )
479 # check if we actually are able to configure attributes on cond vars
480 AC_CHECK_FUNCS(pthread_condattr_init)
481 # instead of pthread_condattr_setclock Android has this function
482 AC_CHECK_FUNCS(pthread_cond_timedwait_monotonic)
483 # check if we can cancel threads
484 AC_CHECK_FUNCS(pthread_cancel)
485 # check if native rwlocks are available
486 AC_CHECK_FUNCS(pthread_rwlock_init)
487 # check if pthread spinlocks are available
488 AC_CHECK_FUNCS(pthread_spin_init)
489 # check if we have POSIX semaphore functions, including timed-wait
490 AC_CHECK_FUNCS(sem_timedwait)
491 LIBS=$saved_LIBS
492
493 AC_CHECK_FUNC(
494         [gettid],
495         [AC_DEFINE([HAVE_GETTID], [], [have gettid()])],
496         [AC_MSG_CHECKING([for SYS_gettid])
497          AC_COMPILE_IFELSE(
498                 [AC_LANG_PROGRAM(
499                         [[#define _GNU_SOURCE
500                           #include <unistd.h>
501                           #include <sys/syscall.h>]],
502                         [[int main() {
503                           return syscall(SYS_gettid);}]])],
504                 [AC_MSG_RESULT([yes]);
505                  AC_DEFINE([HAVE_GETTID], [], [have gettid()])
506                  AC_DEFINE([HAVE_SYS_GETTID], [], [have syscall(SYS_gettid)])],
507                 [AC_MSG_RESULT([no])]
508         )]
509 )
510
511 AC_CHECK_FUNC(
512         [qsort_r],
513         [
514                 AC_DEFINE([HAVE_QSORT_R], [], [have qsort_r()])
515                 # set -Werror so that we get an error for "argument ... has
516                 # incompatible pointer type" warnings
517                 save_CFLAGS="$CFLAGS"
518                 CFLAGS="$CFLAGS -Werror"
519                 AC_MSG_CHECKING([for GNU-style qsort_r])
520                 AC_COMPILE_IFELSE(
521                         [AC_LANG_PROGRAM(
522                                 [[#define _GNU_SOURCE
523                                   #include <stdlib.h>
524                                   int cmp (const void *a, const void *b, void *x) { return 0; }]],
525                                 [[int arr[] = { 0, 1 };
526                                   qsort_r(arr, 2, sizeof(int), cmp, arr);]])],
527                 [AC_MSG_RESULT([yes]);
528                  AC_DEFINE([HAVE_QSORT_R_GNU], [], [have GNU-style qsort_r()])],
529                 [
530                         AC_MSG_RESULT([no]);
531                         AC_MSG_CHECKING([for BSD-style qsort_r])
532                         AC_COMPILE_IFELSE(
533                                 [AC_LANG_PROGRAM(
534                                         [[#include <stdlib.h>
535                                           int cmp (void *x, const void *a, const void *b) { return 0; }]],
536                                         [[int arr[] = { 0, 1 };
537                                           qsort_r(arr, 2, sizeof(int), arr, cmp);]])],
538                         [AC_MSG_RESULT([yes]);
539                          AC_DEFINE([HAVE_QSORT_R_BSD], [], [have BSD-style qsort_r()])],
540                         [AC_MSG_RESULT([no]);
541                          AC_MSG_FAILURE([qsort_r has unknown semantics])])
542                 ])
543                 CFLAGS="$save_CFLAGS"
544         ]
545 )
546
547 AC_CHECK_FUNCS(prctl mallinfo getpass closefrom getpwnam_r getgrnam_r getpwuid_r)
548 AC_CHECK_FUNCS(fmemopen funopen mmap memrchr)
549
550 AC_CHECK_HEADERS(sys/sockio.h glob.h net/if_tun.h linux/fib_rules.h)
551 AC_CHECK_HEADERS(net/pfkeyv2.h netipsec/ipsec.h netinet6/ipsec.h linux/udp.h)
552 AC_CHECK_HEADERS(netinet/ip6.h, [], [],
553 [
554         #include <sys/types.h>
555         #include <netinet/in.h>
556 ])
557
558 AC_CHECK_MEMBERS([struct sockaddr.sa_len], [], [],
559 [
560         #include <sys/types.h>
561         #include <sys/socket.h>
562 ])
563
564 AC_CHECK_MEMBERS([struct sadb_x_policy.sadb_x_policy_priority], [], [],
565 [
566         #include <sys/types.h>
567         #ifdef HAVE_NET_PFKEYV2_H
568         #include <net/pfkeyv2.h>
569         #else
570         #include <stdint.h>
571         #include <linux/pfkeyv2.h>
572         #endif
573 ])
574
575 AC_MSG_CHECKING([for in6addr_any])
576 AC_COMPILE_IFELSE(
577         [AC_LANG_PROGRAM(
578                 [[#include <sys/types.h>
579                   #include <sys/socket.h>
580                   #include <netinet/in.h>]],
581                 [[struct in6_addr in6;
582                   in6 = in6addr_any;]])],
583         [AC_MSG_RESULT([yes]);
584          AC_DEFINE([HAVE_IN6ADDR_ANY], [], [have struct in6_addr in6addr_any])],
585         [AC_MSG_RESULT([no])]
586 )
587
588 AC_MSG_CHECKING([for in6_pktinfo])
589 AC_COMPILE_IFELSE(
590         [AC_LANG_PROGRAM(
591                 [[#define _GNU_SOURCE
592                   #include <sys/types.h>
593                   #include <sys/socket.h>
594                   #include <netinet/in.h>]],
595                 [[struct in6_pktinfo pi;
596                   if (pi.ipi6_ifindex)
597                   {
598                     return 0;
599                   }]])],
600         [AC_MSG_RESULT([yes]);
601          AC_DEFINE([HAVE_IN6_PKTINFO], [], [have struct in6_pktinfo.ipi6_ifindex])],
602         [AC_MSG_RESULT([no])]
603 )
604
605 AC_MSG_CHECKING([for IPSEC_MODE_BEET])
606 AC_COMPILE_IFELSE(
607         [AC_LANG_PROGRAM(
608                 [[#include <sys/types.h>
609                   #ifdef HAVE_NETIPSEC_IPSEC_H
610                   #include <netipsec/ipsec.h>
611                   #elif defined(HAVE_NETINET6_IPSEC_H)
612                   #include <netinet6/ipsec.h>
613                   #else
614                   #include <stdint.h>
615                   #include <linux/ipsec.h>
616                   #endif]],
617                 [[int mode = IPSEC_MODE_BEET;
618                   return mode;]])],
619         [AC_MSG_RESULT([yes]);
620          AC_DEFINE([HAVE_IPSEC_MODE_BEET], [], [have IPSEC_MODE_BEET defined])],
621         [AC_MSG_RESULT([no])]
622 )
623
624 AC_MSG_CHECKING([for IPSEC_DIR_FWD])
625 AC_COMPILE_IFELSE(
626         [AC_LANG_PROGRAM(
627                 [[#include <sys/types.h>
628                   #ifdef HAVE_NETIPSEC_IPSEC_H
629                   #include <netipsec/ipsec.h>
630                   #elif defined(HAVE_NETINET6_IPSEC_H)
631                   #include <netinet6/ipsec.h>
632                   #else
633                   #include <stdint.h>
634                   #include <linux/ipsec.h>
635                   #endif]],
636                 [[int dir = IPSEC_DIR_FWD;
637                   return dir;]])],
638         [AC_MSG_RESULT([yes]);
639          AC_DEFINE([HAVE_IPSEC_DIR_FWD], [], [have IPSEC_DIR_FWD defined])],
640         [AC_MSG_RESULT([no])]
641 )
642
643 AC_MSG_CHECKING([for RTA_TABLE])
644 AC_COMPILE_IFELSE(
645         [AC_LANG_PROGRAM(
646                 [[#include <sys/socket.h>
647                   #include <linux/netlink.h>
648                   #include <linux/rtnetlink.h>]],
649                 [[int rta_type = RTA_TABLE;
650                   return rta_type;]])],
651         [AC_MSG_RESULT([yes]);
652          AC_DEFINE([HAVE_RTA_TABLE], [], [have netlink RTA_TABLE defined])],
653         [AC_MSG_RESULT([no])]
654 )
655
656 AC_MSG_CHECKING([for gcc atomic operations])
657 AC_RUN_IFELSE([AC_LANG_SOURCE(
658         [[
659                         int main() {
660                         volatile int ref = 1;
661                         __sync_fetch_and_add (&ref, 1);
662                         __sync_sub_and_fetch (&ref, 1);
663                         /* Make sure test fails if operations are not supported */
664                         __sync_val_compare_and_swap(&ref, 1, 0);
665                         return ref;
666                 }
667         ]])],
668         [AC_MSG_RESULT([yes]);
669          AC_DEFINE([HAVE_GCC_ATOMIC_OPERATIONS], [],
670                    [have GCC __sync_* atomic operations])],
671         [AC_MSG_RESULT([no])],
672         [AC_MSG_RESULT([no])]
673 )
674
675 # check for the new register_printf_specifier function with len argument,
676 # or the deprecated register_printf_function without
677 AC_CHECK_FUNC(
678         [register_printf_specifier],
679         [AC_DEFINE([HAVE_PRINTF_SPECIFIER], [], [have register_printf_specifier()])],
680         [AC_CHECK_FUNC(
681                 [register_printf_function],
682                 [AC_DEFINE([HAVE_PRINTF_FUNCTION], [], [have register_printf_function()])],
683                 [
684                         AC_MSG_NOTICE([printf does not support custom format specifiers!])
685                         builtin_printf=true
686                 ]
687         )]
688 )
689
690 if test x$vstr = xtrue; then
691         AC_CHECK_LIB([vstr],[main],[LIBS="$LIBS"],[AC_MSG_ERROR([Vstr string library not found])],[])
692         AC_DEFINE([USE_VSTR], [], [use Vstr string library for printf hooks])
693         builtin_printf=false
694 fi
695
696 if test x$builtin_printf = xtrue; then
697         AC_DEFINE([USE_BUILTIN_PRINTF], [], [using builtin printf for printf hooks])
698 fi
699
700 if test x$gmp = xtrue; then
701         saved_LIBS=$LIBS
702         AC_CHECK_LIB([gmp],[main],[],[AC_MSG_ERROR([GNU Multi Precision library gmp not found])],[])
703         AC_MSG_CHECKING([mpz_powm_sec])
704         if test x$mpz_powm_sec = xyes; then
705                 AC_COMPILE_IFELSE(
706                         [AC_LANG_PROGRAM(
707                                 [[#include "gmp.h"]],
708                                 [[void *x = mpz_powm_sec;]])],
709                         [AC_MSG_RESULT([yes]);
710                          AC_DEFINE([HAVE_MPZ_POWM_SEC], [], [have mpz_mown_sec()])],
711                         [AC_MSG_RESULT([no])]
712                 )
713         else
714                 AC_MSG_RESULT([disabled])
715         fi
716         LIBS=$saved_LIBS
717         AC_MSG_CHECKING([gmp.h version >= 4.1.4])
718         AC_COMPILE_IFELSE(
719                 [AC_LANG_PROGRAM(
720                         [[#include "gmp.h"]],
721                         [[
722                                 #if (__GNU_MP_VERSION*100 +  __GNU_MP_VERSION_MINOR*10 + __GNU_MP_VERSION_PATCHLEVEL) < 414
723                                         #error bad gmp
724                                 #endif]])],
725                 [AC_MSG_RESULT([yes])],
726                 [AC_MSG_RESULT([no]); AC_MSG_ERROR([No usable gmp.h found!])]
727         )
728 fi
729
730 if test x$ldap = xtrue; then
731         AC_CHECK_LIB([ldap],[main],[LIBS="$LIBS"],[AC_MSG_ERROR([LDAP library ldap not found])],[])
732         AC_CHECK_LIB([lber],[main],[LIBS="$LIBS"],[AC_MSG_ERROR([LDAP library lber not found])],[])
733         AC_CHECK_HEADER([ldap.h],,[AC_MSG_ERROR([LDAP header ldap.h not found!])])
734 fi
735
736 if test x$curl = xtrue; then
737         AC_CHECK_LIB([curl],[main],[LIBS="$LIBS"],[AC_MSG_ERROR([CURL library curl not found])],[])
738         AC_CHECK_HEADER([curl/curl.h],,[AC_MSG_ERROR([CURL header curl/curl.h not found!])])
739 fi
740
741 if test x$unbound = xtrue; then
742         AC_HAVE_LIBRARY([ldns],[LIBS="$LIBS"],[AC_MSG_ERROR([UNBOUND library ldns not found])])
743         AC_CHECK_HEADER([ldns/ldns.h],,[AC_MSG_ERROR([UNBOUND header ldns/ldns.h not found!])])
744         AC_HAVE_LIBRARY([unbound],[LIBS="$LIBS"],[AC_MSG_ERROR([UNBOUND library libunbound not found])])
745         AC_CHECK_HEADER([unbound.h],,[AC_MSG_ERROR([UNBOUND header unbound.h not found!])])
746 fi
747
748 if test x$soup = xtrue; then
749         PKG_CHECK_MODULES(soup, [libsoup-2.4])
750         AC_SUBST(soup_CFLAGS)
751         AC_SUBST(soup_LIBS)
752 fi
753
754 if test x$xml = xtrue; then
755         PKG_CHECK_MODULES(xml, [libxml-2.0])
756         AC_SUBST(xml_CFLAGS)
757         AC_SUBST(xml_LIBS)
758 fi
759
760 if test x$tss = xtrousers; then
761         AC_CHECK_LIB([tspi],[main],[LIBS="$LIBS"],[AC_MSG_ERROR([TrouSerS library libtspi not found])],[])
762         AC_CHECK_HEADER([trousers/tss.h],,[AC_MSG_ERROR([TrouSerS header trousers/tss.h not found!])])
763         AC_DEFINE([TSS_TROUSERS], [], [use TrouSerS library libtspi as TSS implementation])
764 fi
765
766 if test x$dumm = xtrue; then
767         PKG_CHECK_MODULES(gtk, [gtk+-2.0 vte])
768         AC_SUBST(gtk_CFLAGS)
769         AC_SUBST(gtk_LIBS)
770         AC_CHECK_PROGS(RUBY, ruby)
771         AC_MSG_CHECKING([for Ruby header files])
772         if test -n "$RUBY"; then
773                 RUBYINCLUDE=
774                 RUBYDIR=`($RUBY -r rbconfig -e 'print RbConfig::CONFIG[["rubyhdrdir"]] || ""') 2>/dev/null`
775                 if test -n "$RUBYDIR" -a -r "$RUBYDIR/ruby.h"; then
776                         RUBYARCH=`($RUBY -r rbconfig -e 'print RbConfig::CONFIG[["arch"]] || ""') 2>/dev/null`
777                         if test -n "$RUBYARCH"; then
778                                 AC_MSG_RESULT([$RUBYDIR])
779                                 RUBYINCLUDE="-I$RUBYDIR -I$RUBYDIR/$RUBYARCH"
780                         fi
781                 else
782                         RUBYDIR=`($RUBY -r rbconfig -e 'print RbConfig::CONFIG[["archdir"]] || ""') 2>/dev/null`
783                         if test -n "$RUBYDIR" -a -r "$RUBYDIR/ruby.h"; then
784                                 AC_MSG_RESULT([$RUBYDIR])
785                                 RUBYINCLUDE="-I$RUBYDIR"
786                         fi
787                 fi
788                 if test -z "$RUBYINCLUDE"; then
789                         AC_MSG_ERROR([ruby.h not found])
790                 fi
791                 AC_SUBST(RUBYINCLUDE)
792         else
793                 AC_MSG_ERROR([don't know how to run ruby])
794         fi
795         AC_MSG_CHECKING([for libruby])
796         saved_LIBS=$LIBS
797         LIBS=`($RUBY -r rbconfig -e 'print RbConfig::CONFIG[["LIBRUBYARG_SHARED"]] || ""') 2>/dev/null`
798         AC_TRY_LINK_FUNC(ruby_init,
799                 [AC_MSG_RESULT([$LIBS]); RUBYLIB=$LIBS],
800                 [AC_MSG_ERROR([not found])])
801         AC_SUBST(RUBYLIB)
802         AC_CHECK_FUNCS(rb_errinfo)
803         LIBS=$saved_LIBS
804 fi
805
806 if test x$fast = xtrue; then
807         AC_CHECK_LIB([neo_cgi],[main],[LIBS="$LIBS"],[AC_MSG_ERROR([ClearSilver library neo_cgi not found!])],[])
808         AC_CHECK_LIB([neo_utl],[main],[LIBS="$LIBS"],[AC_MSG_ERROR([ClearSilver library neo_utl not found!])],[])
809         AC_MSG_CHECKING([ClearSilver requires zlib])
810         saved_CFLAGS=$CFLAGS
811         saved_LIBS=$LIBS
812         LIBS="-lneo_cgi -lneo_cs -lneo_utl"
813         CFLAGS="-I/usr/include/ClearSilver"
814         AC_LINK_IFELSE(
815                 [AC_LANG_PROGRAM(
816                         [[#include <ClearSilver.h>]],
817                         [[NEOERR *err = cgi_display(NULL, NULL);]])],
818                 [AC_MSG_RESULT([no]); clearsilver_LIBS="$LIBS"],
819                 [AC_MSG_RESULT([yes]); clearsilver_LIBS="$LIBS -lz"]
820         )
821         AC_SUBST(clearsilver_LIBS)
822         LIBS=$saved_LIBS
823         CFLAGS=$saved_CFLAGS
824 # autoconf does not like CamelCase!? How to fix this?
825 #       AC_CHECK_HEADER([ClearSilver/ClearSilver.h],,[AC_MSG_ERROR([ClearSilver header file ClearSilver/ClearSilver.h not found!])])
826
827         AC_CHECK_LIB([fcgi],[main],[LIBS="$LIBS"],[AC_MSG_ERROR([FastCGI library fcgi not found!])],[])
828         AC_CHECK_HEADER([fcgiapp.h],,[AC_MSG_ERROR([FastCGI header file fcgiapp.h not found!])])
829 fi
830
831 if test x$mysql = xtrue; then
832         AC_PATH_PROG([MYSQLCONFIG], [mysql_config], [], [$PATH:/bin:/usr/bin:/usr/local/bin])
833         if test x$MYSQLCONFIG = x; then
834                 AC_MSG_ERROR([mysql_config not found!])
835         fi
836         AC_SUBST(MYSQLLIB, `$MYSQLCONFIG --libs_r`)
837         AC_SUBST(MYSQLCFLAG, `$MYSQLCONFIG --cflags`)
838 fi
839
840 if test x$sqlite = xtrue; then
841         AC_CHECK_LIB([sqlite3],[main],[LIBS="$LIBS"],[AC_MSG_ERROR([SQLite library sqlite3 not found])],[])
842         AC_CHECK_HEADER([sqlite3.h],,[AC_MSG_ERROR([SQLite header sqlite3.h not found!])])
843         AC_MSG_CHECKING([sqlite3_prepare_v2])
844         AC_COMPILE_IFELSE(
845                 [AC_LANG_PROGRAM(
846                         [[#include <sqlite3.h>]],
847                         [[void *test = sqlite3_prepare_v2;]])],
848                 [AC_MSG_RESULT([yes]);
849                  AC_DEFINE([HAVE_SQLITE3_PREPARE_V2], [], [have sqlite3_prepare_v2()])],
850                 [AC_MSG_RESULT([no])]
851         )
852         AC_MSG_CHECKING([sqlite3.h version >= 3.3.1])
853         AC_COMPILE_IFELSE(
854                 [AC_LANG_PROGRAM(
855                         [[#include <sqlite3.h>]],
856                         [[
857                                 #if SQLITE_VERSION_NUMBER < 3003001
858                                         #error bad sqlite
859                                 #endif]])],
860                 [AC_MSG_RESULT([yes])],
861                 [AC_MSG_RESULT([no]); AC_MSG_ERROR([SQLite version >= 3.3.1 required!])]
862         )
863 fi
864
865 if test x$openssl = xtrue; then
866         AC_CHECK_LIB([crypto],[main],[LIBS="$LIBS"],[AC_MSG_ERROR([OpenSSL crypto library not found])],[])
867         AC_CHECK_HEADER([openssl/evp.h],,[AC_MSG_ERROR([OpenSSL header openssl/evp.h not found!])])
868 fi
869
870 if test x$gcrypt = xtrue; then
871         AC_CHECK_LIB([gcrypt],[main],[LIBS="$LIBS"],[AC_MSG_ERROR([gcrypt library not found])],[-lgpg-error])
872         AC_CHECK_HEADER([gcrypt.h],,[AC_MSG_ERROR([gcrypt header gcrypt.h not found!])])
873         AC_MSG_CHECKING([gcrypt CAMELLIA cipher])
874         AC_COMPILE_IFELSE(
875                 [AC_LANG_PROGRAM(
876                         [[#include <gcrypt.h>]],
877                         [[enum gcry_cipher_algos alg = GCRY_CIPHER_CAMELLIA128;]])],
878                 [AC_MSG_RESULT([yes]);
879                  AC_DEFINE([HAVE_GCRY_CIPHER_CAMELLIA], [], [have GCRY_CIPHER_CAMELLIA128])],
880                 [AC_MSG_RESULT([no])]
881         )
882 fi
883
884 if test x$uci = xtrue; then
885         AC_CHECK_LIB([uci],[main],[LIBS="$LIBS"],[AC_MSG_ERROR([UCI library libuci not found])],[])
886         AC_CHECK_HEADER([uci.h],,[AC_MSG_ERROR([UCI header uci.h not found!])])
887 fi
888
889 if test x$android_dns = xtrue; then
890         AC_CHECK_LIB([cutils],[main],[LIBS="$LIBS"],[AC_MSG_ERROR([Android library libcutils not found])],[])
891         AC_CHECK_HEADER([cutils/properties.h],,[AC_MSG_ERROR([Android header cutils/properties.h not found!])])
892         # we have to force the use of libdl here because the autodetection
893         # above does not work correctly when cross-compiling for android.
894         DLLIB="-ldl"
895         AC_SUBST(DLLIB)
896 fi
897
898 if test x$maemo = xtrue; then
899         PKG_CHECK_MODULES(maemo, [glib-2.0 gthread-2.0 libosso osso-af-settings])
900         AC_SUBST(maemo_CFLAGS)
901         AC_SUBST(maemo_LIBS)
902         dbusservicedir="/usr/share/dbus-1/system-services"
903         AC_SUBST(dbusservicedir)
904 fi
905
906 if test x$eap_sim_pcsc = xtrue; then
907         PKG_CHECK_MODULES(pcsclite, [libpcsclite])
908         AC_SUBST(pcsclite_CFLAGS)
909         AC_SUBST(pcsclite_LIBS)
910 fi
911
912 if test x$nm = xtrue; then
913         PKG_CHECK_EXISTS([libnm-glib],
914                 [PKG_CHECK_MODULES(nm, [NetworkManager gthread-2.0 libnm-util libnm-glib libnm-glib-vpn])],
915                 [PKG_CHECK_MODULES(nm, [NetworkManager gthread-2.0 libnm_util libnm_glib libnm_glib_vpn])]
916         )
917         AC_SUBST(nm_CFLAGS)
918         AC_SUBST(nm_LIBS)
919 fi
920
921 if test x$xauth_pam = xtrue; then
922         AC_CHECK_LIB([pam],[main],[LIBS="$LIBS"],[AC_MSG_ERROR([PAM library not found])],[])
923         AC_CHECK_HEADER([security/pam_appl.h],,[AC_MSG_ERROR([PAM header security/pam_appl.h not found!])])
924 fi
925
926 if test x$capabilities = xnative; then
927         AC_MSG_NOTICE([Usage of the native Linux capabilities interface is deprecated, use libcap instead])
928         # Linux requires the following for capset(), Android does not have it,
929         # but defines capset() in unistd.h instead.
930         AC_CHECK_HEADERS([sys/capability.h])
931         AC_CHECK_FUNC(capset,,[AC_MSG_ERROR([capset() not found!])])
932         AC_DEFINE([CAPABILITIES_NATIVE], [], [have native linux capset()])
933 fi
934
935 if test x$capabilities = xlibcap; then
936         AC_CHECK_LIB([cap],[main],[LIBS="$LIBS"],[AC_MSG_ERROR([libcap library not found])],[])
937         AC_CHECK_HEADER([sys/capability.h],
938                 [AC_DEFINE([HAVE_SYS_CAPABILITY_H], [], [have sys/capability.h])],
939                 [AC_MSG_ERROR([libcap header sys/capability.h not found!])])
940         AC_DEFINE([CAPABILITIES_LIBCAP], [], [have libpcap library])
941 fi
942
943 if test x$integrity_test = xtrue; then
944         AC_MSG_CHECKING([for dladdr()])
945         AC_COMPILE_IFELSE(
946                 [AC_LANG_PROGRAM(
947                         [[#define _GNU_SOURCE
948                           #include <dlfcn.h>]],
949                         [[Dl_info info; dladdr(main, &info);]])],
950                 [AC_MSG_RESULT([yes])],
951                 [AC_MSG_RESULT([no]);
952                  AC_MSG_ERROR([dladdr() not supported, required by integrity-test!])]
953         )
954         AC_MSG_CHECKING([for dl_iterate_phdr()])
955         AC_COMPILE_IFELSE(
956                 [AC_LANG_PROGRAM(
957                         [[#define _GNU_SOURCE
958                           #include <link.h>]],
959                         [[dl_iterate_phdr((void*)0, (void*)0);]])],
960                 [AC_MSG_RESULT([yes])],
961                 [AC_MSG_RESULT([no]);
962                  AC_MSG_ERROR([dl_iterate_phdr() not supported, required by integrity-test!])]
963         )
964 fi
965
966 if test x$bfd_backtraces = xtrue; then
967         AC_CHECK_LIB([bfd],[main],[LIBS="$LIBS"],[AC_MSG_ERROR([binutils libbfd not found!])],[])
968         AC_CHECK_HEADER([bfd.h],[AC_DEFINE([HAVE_BFD_H],,[have binutils bfd.h])],
969                 [AC_MSG_ERROR([binutils bfd.h header not found!])])
970         BFDLIB="-lbfd"
971         AC_SUBST(BFDLIB)
972 fi
973
974 if test x$unwind_backtraces = xtrue; then
975         AC_CHECK_LIB([unwind],[main],[LIBS="$LIBS"],[AC_MSG_ERROR([libunwind not found!])],[])
976         AC_CHECK_HEADER([libunwind.h],[AC_DEFINE([HAVE_LIBUNWIND_H],,[have libunwind.h])],
977                 [AC_MSG_ERROR([libunwind.h header not found!])])
978         UNWINDLIB="-lunwind"
979         AC_SUBST(UNWINDLIB)
980 fi
981
982 AM_CONDITIONAL(USE_DEV_HEADERS, [test "x$dev_headers" != xno])
983 if test x$dev_headers = xyes; then
984         dev_headers="$includedir/strongswan"
985 fi
986 AC_SUBST(dev_headers)
987
988 CFLAGS="$CFLAGS -include `pwd`/config.h"
989
990 if test x$tkm = xtrue; then
991         AC_PATH_PROG([GPRBUILD], [gprbuild], [], [$PATH:/bin:/usr/bin:/usr/local/bin])
992         if test x$GPRBUILD = x; then
993                 AC_MSG_ERROR([gprbuild not found])
994         fi
995 fi
996
997 if test x$coverage = xtrue; then
998         AC_PATH_PROG([LCOV], [lcov], [], [$PATH:/bin:/usr/bin:/usr/local/bin])
999         if test x$LCOV = x; then
1000                 AC_MSG_ERROR([lcov not found])
1001         fi
1002         AC_PATH_PROG([GENHTML], [genhtml], [], [$PATH:/bin:/usr/bin:/usr/local/bin])
1003         if test x$GENHTML = x; then
1004                 AC_MSG_ERROR([genhtml not found])
1005         fi
1006
1007         COVERAGE_CFLAGS="-fprofile-arcs -ftest-coverage"
1008         COVERAGE_LDFLAGS="-fprofile-arcs"
1009         AC_SUBST(COVERAGE_CFLAGS)
1010         AC_SUBST(COVERAGE_LDFLAGS)
1011
1012         AC_MSG_NOTICE([coverage enabled, adding "-g -O0" to CFLAGS])
1013         CFLAGS="${CFLAGS} -g -O0"
1014 fi
1015
1016 # ===============================================
1017 #  collect plugin list for strongSwan components
1018 # ===============================================
1019
1020 m4_include(m4/macros/add-plugin.m4)
1021
1022 # plugin lists for all components
1023 charon_plugins=
1024 starter_plugins=
1025 pool_plugins=
1026 attest_plugins=
1027 openac_plugins=
1028 scepclient_plugins=
1029 pki_plugins=
1030 scripts_plugins=
1031 manager_plugins=
1032 medsrv_plugins=
1033 nm_plugins=
1034 cmd_plugins=
1035
1036 # location specific lists for checksumming,
1037 # for src/libcharon, src/libhydra, src/libstrongswan and src/libtnccs
1038 c_plugins=
1039 h_plugins=
1040 s_plugins=
1041 t_plugins=
1042
1043 ADD_PLUGIN([test-vectors],         [s charon openac scepclient pki])
1044 ADD_PLUGIN([curl],                 [s charon scepclient scripts nm cmd])
1045 ADD_PLUGIN([soup],                 [s charon scripts nm cmd])
1046 ADD_PLUGIN([unbound],              [s charon scripts])
1047 ADD_PLUGIN([ldap],                 [s charon scepclient scripts nm cmd])
1048 ADD_PLUGIN([mysql],                [s charon pool manager medsrv attest])
1049 ADD_PLUGIN([sqlite],               [s charon pool manager medsrv attest])
1050 ADD_PLUGIN([pkcs11],               [s charon pki nm cmd])
1051 ADD_PLUGIN([aes],                  [s charon openac scepclient pki scripts nm cmd])
1052 ADD_PLUGIN([des],                  [s charon openac scepclient pki scripts nm cmd])
1053 ADD_PLUGIN([blowfish],             [s charon openac scepclient pki scripts nm cmd])
1054 ADD_PLUGIN([rc2],                  [s charon openac scepclient pki scripts nm cmd])
1055 ADD_PLUGIN([sha1],                 [s charon openac scepclient pki scripts medsrv attest nm cmd])
1056 ADD_PLUGIN([sha2],                 [s charon openac scepclient pki scripts medsrv attest nm cmd])
1057 ADD_PLUGIN([md4],                  [s charon openac manager scepclient pki nm cmd])
1058 ADD_PLUGIN([md5],                  [s charon openac scepclient pki scripts attest nm cmd])
1059 ADD_PLUGIN([rdrand],               [s charon openac scepclient pki scripts medsrv attest nm cmd])
1060 ADD_PLUGIN([random],               [s charon openac scepclient pki scripts medsrv attest nm cmd])
1061 ADD_PLUGIN([nonce],                [s charon nm cmd])
1062 ADD_PLUGIN([x509],                 [s charon openac scepclient pki scripts attest nm cmd])
1063 ADD_PLUGIN([revocation],           [s charon nm cmd])
1064 ADD_PLUGIN([constraints],          [s charon nm cmd])
1065 ADD_PLUGIN([pubkey],               [s charon cmd])
1066 ADD_PLUGIN([pkcs1],                [s charon openac scepclient pki scripts manager medsrv attest nm cmd])
1067 ADD_PLUGIN([pkcs7],                [s charon scepclient pki scripts nm cmd])
1068 ADD_PLUGIN([pkcs8],                [s charon openac scepclient pki scripts manager medsrv attest nm cmd])
1069 ADD_PLUGIN([pkcs12],               [s charon scepclient pki scripts cmd])
1070 ADD_PLUGIN([pgp],                  [s charon])
1071 ADD_PLUGIN([dnskey],               [s charon pki])
1072 ADD_PLUGIN([sshkey],               [s charon pki nm cmd])
1073 ADD_PLUGIN([dnscert],              [c charon])
1074 ADD_PLUGIN([ipseckey],             [c charon])
1075 ADD_PLUGIN([pem],                  [s charon openac scepclient pki scripts manager medsrv attest nm cmd])
1076 ADD_PLUGIN([padlock],              [s charon])
1077 ADD_PLUGIN([openssl],              [s charon openac scepclient pki scripts manager medsrv attest nm cmd])
1078 ADD_PLUGIN([gcrypt],               [s charon openac scepclient pki scripts manager medsrv attest nm cmd])
1079 ADD_PLUGIN([af-alg],               [s charon openac scepclient pki scripts medsrv attest nm cmd])
1080 ADD_PLUGIN([fips-prf],             [s charon nm cmd])
1081 ADD_PLUGIN([gmp],                  [s charon openac scepclient pki scripts manager medsrv attest nm cmd])
1082 ADD_PLUGIN([agent],                [s charon nm cmd])
1083 ADD_PLUGIN([keychain],             [s charon cmd])
1084 ADD_PLUGIN([xcbc],                 [s charon nm cmd])
1085 ADD_PLUGIN([cmac],                 [s charon nm cmd])
1086 ADD_PLUGIN([hmac],                 [s charon scripts nm cmd])
1087 ADD_PLUGIN([ctr],                  [s charon scripts nm cmd])
1088 ADD_PLUGIN([ccm],                  [s charon scripts nm cmd])
1089 ADD_PLUGIN([gcm],                  [s charon scripts nm cmd])
1090 ADD_PLUGIN([ntru],                 [s charon scripts nm cmd])
1091 ADD_PLUGIN([attr],                 [h charon])
1092 ADD_PLUGIN([attr-sql],             [h charon])
1093 ADD_PLUGIN([load-tester],          [c charon])
1094 ADD_PLUGIN([kernel-libipsec],      [c charon cmd])
1095 ADD_PLUGIN([kernel-pfkey],         [h charon starter nm cmd])
1096 ADD_PLUGIN([kernel-pfroute],       [h charon starter nm cmd])
1097 ADD_PLUGIN([kernel-klips],         [h charon starter])
1098 ADD_PLUGIN([kernel-netlink],       [h charon starter nm cmd])
1099 ADD_PLUGIN([resolve],              [h charon cmd])
1100 ADD_PLUGIN([socket-default],       [c charon nm cmd])
1101 ADD_PLUGIN([socket-dynamic],       [c charon cmd])
1102 ADD_PLUGIN([farp],                 [c charon])
1103 ADD_PLUGIN([stroke],               [c charon])
1104 ADD_PLUGIN([smp],                  [c charon])
1105 ADD_PLUGIN([sql],                  [c charon])
1106 ADD_PLUGIN([updown],               [c charon])
1107 ADD_PLUGIN([eap-identity],         [c charon nm cmd])
1108 ADD_PLUGIN([eap-sim],              [c charon])
1109 ADD_PLUGIN([eap-sim-file],         [c charon])
1110 ADD_PLUGIN([eap-sim-pcsc],         [c charon])
1111 ADD_PLUGIN([eap-aka],              [c charon])
1112 ADD_PLUGIN([eap-aka-3gpp2],        [c charon])
1113 ADD_PLUGIN([eap-simaka-sql],       [c charon])
1114 ADD_PLUGIN([eap-simaka-pseudonym], [c charon])
1115 ADD_PLUGIN([eap-simaka-reauth],    [c charon])
1116 ADD_PLUGIN([eap-md5],              [c charon nm cmd])
1117 ADD_PLUGIN([eap-gtc],              [c charon nm cmd])
1118 ADD_PLUGIN([eap-mschapv2],         [c charon nm cmd])
1119 ADD_PLUGIN([eap-dynamic],          [c charon])
1120 ADD_PLUGIN([eap-radius],           [c charon])
1121 ADD_PLUGIN([eap-tls],              [c charon nm cmd])
1122 ADD_PLUGIN([eap-ttls],             [c charon nm cmd])
1123 ADD_PLUGIN([eap-peap],             [c charon nm cmd])
1124 ADD_PLUGIN([eap-tnc],              [c charon])
1125 ADD_PLUGIN([xauth-generic],        [c charon cmd])
1126 ADD_PLUGIN([xauth-eap],            [c charon])
1127 ADD_PLUGIN([xauth-pam],            [c charon])
1128 ADD_PLUGIN([xauth-noauth],         [c charon])
1129 ADD_PLUGIN([tnc-ifmap],            [c charon])
1130 ADD_PLUGIN([tnc-pdp],              [c charon])
1131 ADD_PLUGIN([tnc-imc],              [t charon])
1132 ADD_PLUGIN([tnc-imv],              [t charon])
1133 ADD_PLUGIN([tnc-tnccs],            [t charon])
1134 ADD_PLUGIN([tnccs-20],             [t charon])
1135 ADD_PLUGIN([tnccs-11],             [t charon])
1136 ADD_PLUGIN([tnccs-dynamic],        [t charon])
1137 ADD_PLUGIN([medsrv],               [c charon])
1138 ADD_PLUGIN([medcli],               [c charon])
1139 ADD_PLUGIN([dhcp],                 [c charon])
1140 ADD_PLUGIN([osx-attr],             [c charon cmd])
1141 ADD_PLUGIN([android-dns],          [c charon])
1142 ADD_PLUGIN([android-log],          [c charon])
1143 ADD_PLUGIN([ha],                   [c charon])
1144 ADD_PLUGIN([whitelist],            [c charon])
1145 ADD_PLUGIN([lookip],               [c charon])
1146 ADD_PLUGIN([error-notify],         [c charon])
1147 ADD_PLUGIN([certexpire],           [c charon])
1148 ADD_PLUGIN([systime-fix],          [c charon])
1149 ADD_PLUGIN([led],                  [c charon])
1150 ADD_PLUGIN([duplicheck],           [c charon])
1151 ADD_PLUGIN([coupling],             [c charon])
1152 ADD_PLUGIN([radattr],              [c charon])
1153 ADD_PLUGIN([maemo],                [c charon])
1154 ADD_PLUGIN([uci],                  [c charon])
1155 ADD_PLUGIN([addrblock],            [c charon])
1156 ADD_PLUGIN([unity],                [c charon])
1157 ADD_PLUGIN([unit-tester],          [c charon])
1158
1159 AC_SUBST(charon_plugins)
1160 AC_SUBST(starter_plugins)
1161 AC_SUBST(pool_plugins)
1162 AC_SUBST(attest_plugins)
1163 AC_SUBST(openac_plugins)
1164 AC_SUBST(scepclient_plugins)
1165 AC_SUBST(pki_plugins)
1166 AC_SUBST(scripts_plugins)
1167 AC_SUBST(manager_plugins)
1168 AC_SUBST(medsrv_plugins)
1169 AC_SUBST(nm_plugins)
1170 AC_SUBST(cmd_plugins)
1171
1172 AC_SUBST(c_plugins)
1173 AC_SUBST(h_plugins)
1174 AC_SUBST(s_plugins)
1175 AC_SUBST(t_plugins)
1176
1177 # ======================
1178 #  set Makefile.am vars
1179 # ======================
1180
1181 #  libstrongswan plugins
1182 # -----------------------
1183 AM_CONDITIONAL(USE_TEST_VECTORS, test x$test_vectors = xtrue)
1184 AM_CONDITIONAL(USE_CURL, test x$curl = xtrue)
1185 AM_CONDITIONAL(USE_UNBOUND, test x$unbound = xtrue)
1186 AM_CONDITIONAL(USE_SOUP, test x$soup = xtrue)
1187 AM_CONDITIONAL(USE_LDAP, test x$ldap = xtrue)
1188 AM_CONDITIONAL(USE_AES, test x$aes = xtrue)
1189 AM_CONDITIONAL(USE_DES, test x$des = xtrue)
1190 AM_CONDITIONAL(USE_BLOWFISH, test x$blowfish = xtrue)
1191 AM_CONDITIONAL(USE_RC2, test x$rc2 = xtrue)
1192 AM_CONDITIONAL(USE_MD4, test x$md4 = xtrue)
1193 AM_CONDITIONAL(USE_MD5, test x$md5 = xtrue)
1194 AM_CONDITIONAL(USE_SHA1, test x$sha1 = xtrue)
1195 AM_CONDITIONAL(USE_SHA2, test x$sha2 = xtrue)
1196 AM_CONDITIONAL(USE_FIPS_PRF, test x$fips_prf = xtrue)
1197 AM_CONDITIONAL(USE_GMP, test x$gmp = xtrue)
1198 AM_CONDITIONAL(USE_RDRAND, test x$rdrand = xtrue)
1199 AM_CONDITIONAL(USE_RANDOM, test x$random = xtrue)
1200 AM_CONDITIONAL(USE_NONCE, test x$nonce = xtrue)
1201 AM_CONDITIONAL(USE_X509, test x$x509 = xtrue)
1202 AM_CONDITIONAL(USE_REVOCATION, test x$revocation = xtrue)
1203 AM_CONDITIONAL(USE_CONSTRAINTS, test x$constraints = xtrue)
1204 AM_CONDITIONAL(USE_PUBKEY, test x$pubkey = xtrue)
1205 AM_CONDITIONAL(USE_PKCS1, test x$pkcs1 = xtrue)
1206 AM_CONDITIONAL(USE_PKCS7, test x$pkcs7 = xtrue)
1207 AM_CONDITIONAL(USE_PKCS8, test x$pkcs8 = xtrue)
1208 AM_CONDITIONAL(USE_PKCS12, test x$pkcs12 = xtrue)
1209 AM_CONDITIONAL(USE_PGP, test x$pgp = xtrue)
1210 AM_CONDITIONAL(USE_DNSKEY, test x$dnskey = xtrue)
1211 AM_CONDITIONAL(USE_SSHKEY, test x$sshkey = xtrue)
1212 AM_CONDITIONAL(USE_PEM, test x$pem = xtrue)
1213 AM_CONDITIONAL(USE_HMAC, test x$hmac = xtrue)
1214 AM_CONDITIONAL(USE_CMAC, test x$cmac = xtrue)
1215 AM_CONDITIONAL(USE_XCBC, test x$xcbc = xtrue)
1216 AM_CONDITIONAL(USE_MYSQL, test x$mysql = xtrue)
1217 AM_CONDITIONAL(USE_SQLITE, test x$sqlite = xtrue)
1218 AM_CONDITIONAL(USE_PADLOCK, test x$padlock = xtrue)
1219 AM_CONDITIONAL(USE_OPENSSL, test x$openssl = xtrue)
1220 AM_CONDITIONAL(USE_GCRYPT, test x$gcrypt = xtrue)
1221 AM_CONDITIONAL(USE_AGENT, test x$agent = xtrue)
1222 AM_CONDITIONAL(USE_KEYCHAIN, test x$keychain = xtrue)
1223 AM_CONDITIONAL(USE_PKCS11, test x$pkcs11 = xtrue)
1224 AM_CONDITIONAL(USE_CTR, test x$ctr = xtrue)
1225 AM_CONDITIONAL(USE_CCM, test x$ccm = xtrue)
1226 AM_CONDITIONAL(USE_GCM, test x$gcm = xtrue)
1227 AM_CONDITIONAL(USE_AF_ALG, test x$af_alg = xtrue)
1228 AM_CONDITIONAL(USE_NTRU, test x$ntru = xtrue)
1229
1230 #  charon plugins
1231 # ----------------
1232 AM_CONDITIONAL(USE_STROKE, test x$stroke = xtrue)
1233 AM_CONDITIONAL(USE_MEDSRV, test x$medsrv = xtrue)
1234 AM_CONDITIONAL(USE_MEDCLI, test x$medcli = xtrue)
1235 AM_CONDITIONAL(USE_UCI, test x$uci = xtrue)
1236 AM_CONDITIONAL(USE_OSX_ATTR, test x$osx_attr = xtrue)
1237 AM_CONDITIONAL(USE_ANDROID_DNS, test x$android_dns = xtrue)
1238 AM_CONDITIONAL(USE_ANDROID_LOG, test x$android_log = xtrue)
1239 AM_CONDITIONAL(USE_MAEMO, test x$maemo = xtrue)
1240 AM_CONDITIONAL(USE_SMP, test x$smp = xtrue)
1241 AM_CONDITIONAL(USE_SQL, test x$sql = xtrue)
1242 AM_CONDITIONAL(USE_DNSCERT, test x$dnscert = xtrue)
1243 AM_CONDITIONAL(USE_IPSECKEY, test x$ipseckey = xtrue)
1244 AM_CONDITIONAL(USE_UPDOWN, test x$updown = xtrue)
1245 AM_CONDITIONAL(USE_DHCP, test x$dhcp = xtrue)
1246 AM_CONDITIONAL(USE_UNIT_TESTS, test x$unit_tester = xtrue)
1247 AM_CONDITIONAL(USE_LOAD_TESTER, test x$load_tester = xtrue)
1248 AM_CONDITIONAL(USE_HA, test x$ha = xtrue)
1249 AM_CONDITIONAL(USE_KERNEL_LIBIPSEC, test x$kernel_libipsec = xtrue)
1250 AM_CONDITIONAL(USE_WHITELIST, test x$whitelist = xtrue)
1251 AM_CONDITIONAL(USE_LOOKIP, test x$lookip = xtrue)
1252 AM_CONDITIONAL(USE_ERROR_NOTIFY, test x$error_notify = xtrue)
1253 AM_CONDITIONAL(USE_CERTEXPIRE, test x$certexpire = xtrue)
1254 AM_CONDITIONAL(USE_SYSTIME_FIX, test x$systime_fix = xtrue)
1255 AM_CONDITIONAL(USE_LED, test x$led = xtrue)
1256 AM_CONDITIONAL(USE_DUPLICHECK, test x$duplicheck = xtrue)
1257 AM_CONDITIONAL(USE_COUPLING, test x$coupling = xtrue)
1258 AM_CONDITIONAL(USE_RADATTR, test x$radattr = xtrue)
1259 AM_CONDITIONAL(USE_EAP_SIM, test x$eap_sim = xtrue)
1260 AM_CONDITIONAL(USE_EAP_SIM_FILE, test x$eap_sim_file = xtrue)
1261 AM_CONDITIONAL(USE_EAP_SIM_PCSC, test x$eap_sim_pcsc = xtrue)
1262 AM_CONDITIONAL(USE_EAP_SIMAKA_SQL, test x$eap_simaka_sql = xtrue)
1263 AM_CONDITIONAL(USE_EAP_SIMAKA_PSEUDONYM, test x$eap_simaka_pseudonym = xtrue)
1264 AM_CONDITIONAL(USE_EAP_SIMAKA_REAUTH, test x$eap_simaka_reauth = xtrue)
1265 AM_CONDITIONAL(USE_EAP_IDENTITY, test x$eap_identity = xtrue)
1266 AM_CONDITIONAL(USE_EAP_MD5, test x$eap_md5 = xtrue)
1267 AM_CONDITIONAL(USE_EAP_GTC, test x$eap_gtc = xtrue)
1268 AM_CONDITIONAL(USE_EAP_AKA, test x$eap_aka = xtrue)
1269 AM_CONDITIONAL(USE_EAP_AKA_3GPP2, test x$eap_aka_3gpp2 = xtrue)
1270 AM_CONDITIONAL(USE_EAP_MSCHAPV2, test x$eap_mschapv2 = xtrue)
1271 AM_CONDITIONAL(USE_EAP_TLS, test x$eap_tls = xtrue)
1272 AM_CONDITIONAL(USE_EAP_TTLS, test x$eap_ttls = xtrue)
1273 AM_CONDITIONAL(USE_EAP_PEAP, test x$eap_peap = xtrue)
1274 AM_CONDITIONAL(USE_EAP_TNC, test x$eap_tnc = xtrue)
1275 AM_CONDITIONAL(USE_EAP_DYNAMIC, test x$eap_dynamic = xtrue)
1276 AM_CONDITIONAL(USE_EAP_RADIUS, test x$eap_radius = xtrue)
1277 AM_CONDITIONAL(USE_XAUTH_GENERIC, test x$xauth_generic = xtrue)
1278 AM_CONDITIONAL(USE_XAUTH_EAP, test x$xauth_eap = xtrue)
1279 AM_CONDITIONAL(USE_XAUTH_PAM, test x$xauth_pam = xtrue)
1280 AM_CONDITIONAL(USE_XAUTH_NOAUTH, test x$xauth_noauth = xtrue)
1281 AM_CONDITIONAL(USE_TNC_IFMAP, test x$tnc_ifmap = xtrue)
1282 AM_CONDITIONAL(USE_TNC_PDP, test x$tnc_pdp = xtrue)
1283 AM_CONDITIONAL(USE_TNC_IMC, test x$tnc_imc = xtrue)
1284 AM_CONDITIONAL(USE_TNC_IMV, test x$tnc_imv = xtrue)
1285 AM_CONDITIONAL(USE_TNC_TNCCS, test x$tnc_tnccs = xtrue)
1286 AM_CONDITIONAL(USE_TNCCS_11, test x$tnccs_11 = xtrue)
1287 AM_CONDITIONAL(USE_TNCCS_20, test x$tnccs_20 = xtrue)
1288 AM_CONDITIONAL(USE_TNCCS_DYNAMIC, test x$tnccs_dynamic = xtrue)
1289 AM_CONDITIONAL(USE_IMC_TEST, test x$imc_test = xtrue)
1290 AM_CONDITIONAL(USE_IMV_TEST, test x$imv_test = xtrue)
1291 AM_CONDITIONAL(USE_IMC_SCANNER, test x$imc_scanner = xtrue)
1292 AM_CONDITIONAL(USE_IMV_SCANNER, test x$imv_scanner = xtrue)
1293 AM_CONDITIONAL(USE_IMC_OS, test x$imc_os = xtrue)
1294 AM_CONDITIONAL(USE_IMV_OS, test x$imv_os = xtrue)
1295 AM_CONDITIONAL(USE_IMC_ATTESTATION, test x$imc_attestation = xtrue)
1296 AM_CONDITIONAL(USE_IMV_ATTESTATION, test x$imv_attestation = xtrue)
1297 AM_CONDITIONAL(USE_IMC_SWID, test x$imc_swid = xtrue)
1298 AM_CONDITIONAL(USE_IMV_SWID, test x$imv_swid = xtrue)
1299 AM_CONDITIONAL(USE_SOCKET_DEFAULT, test x$socket_default = xtrue)
1300 AM_CONDITIONAL(USE_SOCKET_DYNAMIC, test x$socket_dynamic = xtrue)
1301 AM_CONDITIONAL(USE_FARP, test x$farp = xtrue)
1302 AM_CONDITIONAL(USE_ADDRBLOCK, test x$addrblock = xtrue)
1303 AM_CONDITIONAL(USE_UNITY, test x$unity = xtrue)
1304
1305 #  hydra plugins
1306 # ---------------
1307 AM_CONDITIONAL(USE_ATTR, test x$attr = xtrue)
1308 AM_CONDITIONAL(USE_ATTR_SQL, test x$attr_sql = xtrue)
1309 AM_CONDITIONAL(USE_KERNEL_KLIPS, test x$kernel_klips = xtrue)
1310 AM_CONDITIONAL(USE_KERNEL_NETLINK, test x$kernel_netlink = xtrue)
1311 AM_CONDITIONAL(USE_KERNEL_PFKEY, test x$kernel_pfkey = xtrue)
1312 AM_CONDITIONAL(USE_KERNEL_PFROUTE, test x$kernel_pfroute = xtrue)
1313 AM_CONDITIONAL(USE_RESOLVE, test x$resolve = xtrue)
1314
1315 #  other options
1316 # ---------------
1317 AM_CONDITIONAL(USE_LEAK_DETECTIVE, test x$leak_detective = xtrue)
1318 AM_CONDITIONAL(USE_LOCK_PROFILER, test x$lock_profiler = xtrue)
1319 AM_CONDITIONAL(USE_DUMM, test x$dumm = xtrue)
1320 AM_CONDITIONAL(USE_FAST, test x$fast = xtrue)
1321 AM_CONDITIONAL(USE_MANAGER, test x$manager = xtrue)
1322 AM_CONDITIONAL(USE_ME, test x$mediation = xtrue)
1323 AM_CONDITIONAL(USE_INTEGRITY_TEST, test x$integrity_test = xtrue)
1324 AM_CONDITIONAL(USE_LOAD_WARNING, test x$load_warning = xtrue)
1325 AM_CONDITIONAL(USE_IKEV1, test x$ikev1 = xtrue)
1326 AM_CONDITIONAL(USE_IKEV2, test x$ikev2 = xtrue)
1327 AM_CONDITIONAL(USE_THREADS, test x$threads = xtrue)
1328 AM_CONDITIONAL(USE_ADNS, test x$adns = xtrue)
1329 AM_CONDITIONAL(USE_CHARON, test x$charon = xtrue)
1330 AM_CONDITIONAL(USE_NM, test x$nm = xtrue)
1331 AM_CONDITIONAL(USE_TOOLS, test x$tools = xtrue)
1332 AM_CONDITIONAL(USE_SCRIPTS, test x$scripts = xtrue)
1333 AM_CONDITIONAL(USE_CONFTEST, test x$conftest = xtrue)
1334 AM_CONDITIONAL(USE_LIBSTRONGSWAN, test x$charon = xtrue -o x$tools = xtrue -o x$conftest = xtrue -o x$fast = xtrue -o x$imcv = xtrue -o x$nm = xtrue -o x$tkm = xtrue -o x$cmd = xtrue -o x$tls = xtrue -o x$tnc_tnccs = xtrue)
1335 AM_CONDITIONAL(USE_LIBHYDRA, test x$charon = xtrue -o x$nm = xtrue -o x$tkm = xtrue -o x$cmd = xtrue)
1336 AM_CONDITIONAL(USE_LIBCHARON, test x$charon = xtrue -o x$conftest = xtrue -o x$nm = xtrue -o x$tkm = xtrue -o x$cmd = xtrue)
1337 AM_CONDITIONAL(USE_LIBIPSEC, test x$libipsec = xtrue)
1338 AM_CONDITIONAL(USE_LIBTNCIF, test x$tnc_tnccs = xtrue -o x$imcv = xtrue)
1339 AM_CONDITIONAL(USE_LIBTNCCS, test x$tnc_tnccs = xtrue)
1340 AM_CONDITIONAL(USE_LIBPTTLS, test x$tnc_tnccs = xtrue)
1341 AM_CONDITIONAL(USE_FILE_CONFIG, test x$stroke = xtrue)
1342 AM_CONDITIONAL(USE_IPSEC_SCRIPT, test x$stroke = xtrue -o x$tools = xtrue -o x$conftest = xtrue)
1343 AM_CONDITIONAL(USE_LIBCAP, test x$capabilities = xlibcap)
1344 AM_CONDITIONAL(USE_VSTR, test x$vstr = xtrue)
1345 AM_CONDITIONAL(USE_BUILTIN_PRINTF, test x$builtin_printf = xtrue)
1346 AM_CONDITIONAL(USE_SIMAKA, test x$simaka = xtrue)
1347 AM_CONDITIONAL(USE_TLS, test x$tls = xtrue)
1348 AM_CONDITIONAL(USE_RADIUS, test x$radius = xtrue)
1349 AM_CONDITIONAL(USE_IMCV, test x$imcv = xtrue)
1350 AM_CONDITIONAL(USE_PTS, test x$pts = xtrue)
1351 AM_CONDITIONAL(USE_TROUSERS, test x$tss = xtrousers)
1352 AM_CONDITIONAL(MONOLITHIC, test x$monolithic = xtrue)
1353 AM_CONDITIONAL(USE_SILENT_RULES, test x$enable_silent_rules = xyes)
1354 AM_CONDITIONAL(COVERAGE, test x$coverage = xtrue)
1355 AM_CONDITIONAL(USE_TKM, test x$tkm = xtrue)
1356 AM_CONDITIONAL(USE_CMD, test x$cmd = xtrue)
1357
1358 # ========================
1359 #  set global definitions
1360 # ========================
1361
1362 if test x$mediation = xtrue; then
1363         AC_DEFINE([ME], [], [mediation extension support])
1364 fi
1365 if test x$capabilities = xlibcap -o x$capabilities = xnative; then
1366         AC_DEFINE([CAPABILITIES], [], [capability dropping support])
1367 fi
1368 if test x$monolithic = xtrue; then
1369         AC_DEFINE([MONOLITHIC], [], [monolithic build embedding plugins])
1370 fi
1371 if test x$ikev1 = xtrue; then
1372         AC_DEFINE([USE_IKEV1], [], [support for IKEv1 protocol])
1373 fi
1374 if test x$ikev2 = xtrue; then
1375         AC_DEFINE([USE_IKEV2], [], [support for IKEv2 protocol])
1376 fi
1377
1378 # ====================================================
1379 #  options for enabled modules (see conf/Makefile.am)
1380 # ====================================================
1381
1382 strongswan_options=
1383
1384 AM_COND_IF([USE_ATTR_SQL], [strongswan_options=${strongswan_options}" pool"])
1385 AM_COND_IF([USE_CHARON], [strongswan_options=${strongswan_options}" charon charon-logging"])
1386 AM_COND_IF([USE_FILE_CONFIG], [strongswan_options=${strongswan_options}" starter"])
1387 AM_COND_IF([USE_IMV_ATTESTATION], [strongswan_options=${strongswan_options}" attest"])
1388 AM_COND_IF([USE_IMCV], [strongswan_options=${strongswan_options}" imcv"])
1389 AM_COND_IF([USE_IMV_OS], [strongswan_options=${strongswan_options}" pacman"])
1390 AM_COND_IF([USE_LIBTNCCS], [strongswan_options=${strongswan_options}" tnc"])
1391 AM_COND_IF([USE_MANAGER], [strongswan_options=${strongswan_options}" manager"])
1392 AM_COND_IF([USE_MEDSRV], [strongswan_options=${strongswan_options}" medsrv"])
1393 AM_COND_IF([USE_TOOLS], [strongswan_options=${strongswan_options}" tools"])
1394
1395 AC_SUBST(strongswan_options)
1396
1397 # =================
1398 #  build Makefiles
1399 # =================
1400
1401 AC_CONFIG_FILES([
1402         Makefile
1403         conf/Makefile
1404         man/Makefile
1405         init/Makefile
1406         init/systemd/Makefile
1407         src/Makefile
1408         src/include/Makefile
1409         src/libstrongswan/Makefile
1410         src/libstrongswan/plugins/aes/Makefile
1411         src/libstrongswan/plugins/cmac/Makefile
1412         src/libstrongswan/plugins/des/Makefile
1413         src/libstrongswan/plugins/blowfish/Makefile
1414         src/libstrongswan/plugins/rc2/Makefile
1415         src/libstrongswan/plugins/md4/Makefile
1416         src/libstrongswan/plugins/md5/Makefile
1417         src/libstrongswan/plugins/sha1/Makefile
1418         src/libstrongswan/plugins/sha2/Makefile
1419         src/libstrongswan/plugins/fips_prf/Makefile
1420         src/libstrongswan/plugins/gmp/Makefile
1421         src/libstrongswan/plugins/rdrand/Makefile
1422         src/libstrongswan/plugins/random/Makefile
1423         src/libstrongswan/plugins/nonce/Makefile
1424         src/libstrongswan/plugins/hmac/Makefile
1425         src/libstrongswan/plugins/xcbc/Makefile
1426         src/libstrongswan/plugins/x509/Makefile
1427         src/libstrongswan/plugins/revocation/Makefile
1428         src/libstrongswan/plugins/constraints/Makefile
1429         src/libstrongswan/plugins/pubkey/Makefile
1430         src/libstrongswan/plugins/pkcs1/Makefile
1431         src/libstrongswan/plugins/pkcs7/Makefile
1432         src/libstrongswan/plugins/pkcs8/Makefile
1433         src/libstrongswan/plugins/pkcs12/Makefile
1434         src/libstrongswan/plugins/pgp/Makefile
1435         src/libstrongswan/plugins/dnskey/Makefile
1436         src/libstrongswan/plugins/sshkey/Makefile
1437         src/libstrongswan/plugins/pem/Makefile
1438         src/libstrongswan/plugins/curl/Makefile
1439         src/libstrongswan/plugins/unbound/Makefile
1440         src/libstrongswan/plugins/soup/Makefile
1441         src/libstrongswan/plugins/ldap/Makefile
1442         src/libstrongswan/plugins/mysql/Makefile
1443         src/libstrongswan/plugins/sqlite/Makefile
1444         src/libstrongswan/plugins/padlock/Makefile
1445         src/libstrongswan/plugins/openssl/Makefile
1446         src/libstrongswan/plugins/gcrypt/Makefile
1447         src/libstrongswan/plugins/agent/Makefile
1448         src/libstrongswan/plugins/keychain/Makefile
1449         src/libstrongswan/plugins/pkcs11/Makefile
1450         src/libstrongswan/plugins/ctr/Makefile
1451         src/libstrongswan/plugins/ccm/Makefile
1452         src/libstrongswan/plugins/gcm/Makefile
1453         src/libstrongswan/plugins/af_alg/Makefile
1454         src/libstrongswan/plugins/ntru/Makefile
1455         src/libstrongswan/plugins/test_vectors/Makefile
1456         src/libstrongswan/tests/Makefile
1457         src/libhydra/Makefile
1458         src/libhydra/plugins/attr/Makefile
1459         src/libhydra/plugins/attr_sql/Makefile
1460         src/libhydra/plugins/kernel_klips/Makefile
1461         src/libhydra/plugins/kernel_netlink/Makefile
1462         src/libhydra/plugins/kernel_pfkey/Makefile
1463         src/libhydra/plugins/kernel_pfroute/Makefile
1464         src/libhydra/plugins/resolve/Makefile
1465         src/libipsec/Makefile
1466         src/libsimaka/Makefile
1467         src/libtls/Makefile
1468         src/libradius/Makefile
1469         src/libtncif/Makefile
1470         src/libtnccs/Makefile
1471         src/libtnccs/plugins/tnc_tnccs/Makefile
1472         src/libtnccs/plugins/tnc_imc/Makefile
1473         src/libtnccs/plugins/tnc_imv/Makefile
1474         src/libtnccs/plugins/tnccs_11/Makefile
1475         src/libtnccs/plugins/tnccs_20/Makefile
1476         src/libtnccs/plugins/tnccs_dynamic/Makefile
1477         src/libpttls/Makefile
1478         src/libpts/Makefile
1479         src/libpts/plugins/imc_attestation/Makefile
1480         src/libpts/plugins/imv_attestation/Makefile
1481         src/libpts/plugins/imc_swid/Makefile
1482         src/libpts/plugins/imv_swid/Makefile
1483         src/libimcv/Makefile
1484         src/libimcv/plugins/imc_test/Makefile
1485         src/libimcv/plugins/imv_test/Makefile
1486         src/libimcv/plugins/imc_scanner/Makefile
1487         src/libimcv/plugins/imv_scanner/Makefile
1488         src/libimcv/plugins/imc_os/Makefile
1489         src/libimcv/plugins/imv_os/Makefile
1490         src/charon/Makefile
1491         src/charon-nm/Makefile
1492         src/charon-tkm/Makefile
1493         src/charon-cmd/Makefile
1494         src/libcharon/Makefile
1495         src/libcharon/plugins/eap_aka/Makefile
1496         src/libcharon/plugins/eap_aka_3gpp2/Makefile
1497         src/libcharon/plugins/eap_dynamic/Makefile
1498         src/libcharon/plugins/eap_identity/Makefile
1499         src/libcharon/plugins/eap_md5/Makefile
1500         src/libcharon/plugins/eap_gtc/Makefile
1501         src/libcharon/plugins/eap_sim/Makefile
1502         src/libcharon/plugins/eap_sim_file/Makefile
1503         src/libcharon/plugins/eap_sim_pcsc/Makefile
1504         src/libcharon/plugins/eap_simaka_sql/Makefile
1505         src/libcharon/plugins/eap_simaka_pseudonym/Makefile
1506         src/libcharon/plugins/eap_simaka_reauth/Makefile
1507         src/libcharon/plugins/eap_mschapv2/Makefile
1508         src/libcharon/plugins/eap_tls/Makefile
1509         src/libcharon/plugins/eap_ttls/Makefile
1510         src/libcharon/plugins/eap_peap/Makefile
1511         src/libcharon/plugins/eap_tnc/Makefile
1512         src/libcharon/plugins/eap_radius/Makefile
1513         src/libcharon/plugins/xauth_generic/Makefile
1514         src/libcharon/plugins/xauth_eap/Makefile
1515         src/libcharon/plugins/xauth_pam/Makefile
1516         src/libcharon/plugins/xauth_noauth/Makefile
1517         src/libcharon/plugins/tnc_ifmap/Makefile
1518         src/libcharon/plugins/tnc_pdp/Makefile
1519         src/libcharon/plugins/socket_default/Makefile
1520         src/libcharon/plugins/socket_dynamic/Makefile
1521         src/libcharon/plugins/farp/Makefile
1522         src/libcharon/plugins/smp/Makefile
1523         src/libcharon/plugins/sql/Makefile
1524         src/libcharon/plugins/dnscert/Makefile
1525         src/libcharon/plugins/ipseckey/Makefile
1526         src/libcharon/plugins/medsrv/Makefile
1527         src/libcharon/plugins/medcli/Makefile
1528         src/libcharon/plugins/addrblock/Makefile
1529         src/libcharon/plugins/unity/Makefile
1530         src/libcharon/plugins/uci/Makefile
1531         src/libcharon/plugins/ha/Makefile
1532         src/libcharon/plugins/kernel_libipsec/Makefile
1533         src/libcharon/plugins/whitelist/Makefile
1534         src/libcharon/plugins/lookip/Makefile
1535         src/libcharon/plugins/error_notify/Makefile
1536         src/libcharon/plugins/certexpire/Makefile
1537         src/libcharon/plugins/systime_fix/Makefile
1538         src/libcharon/plugins/led/Makefile
1539         src/libcharon/plugins/duplicheck/Makefile
1540         src/libcharon/plugins/coupling/Makefile
1541         src/libcharon/plugins/radattr/Makefile
1542         src/libcharon/plugins/osx_attr/Makefile
1543         src/libcharon/plugins/android_dns/Makefile
1544         src/libcharon/plugins/android_log/Makefile
1545         src/libcharon/plugins/maemo/Makefile
1546         src/libcharon/plugins/stroke/Makefile
1547         src/libcharon/plugins/updown/Makefile
1548         src/libcharon/plugins/dhcp/Makefile
1549         src/libcharon/plugins/unit_tester/Makefile
1550         src/libcharon/plugins/load_tester/Makefile
1551         src/stroke/Makefile
1552         src/ipsec/Makefile
1553         src/starter/Makefile
1554         src/_updown/Makefile
1555         src/_updown_espmark/Makefile
1556         src/_copyright/Makefile
1557         src/openac/Makefile
1558         src/scepclient/Makefile
1559         src/pki/Makefile
1560         src/pki/man/Makefile
1561         src/pool/Makefile
1562         src/dumm/Makefile
1563         src/dumm/ext/extconf.rb
1564         src/libfast/Makefile
1565         src/manager/Makefile
1566         src/medsrv/Makefile
1567         src/checksum/Makefile
1568         src/conftest/Makefile
1569         src/pt-tls-client/Makefile
1570         scripts/Makefile
1571         testing/Makefile
1572 ])
1573
1574 # =================
1575 #  build man pages
1576 # =================
1577
1578 AC_CONFIG_FILES([
1579         conf/strongswan.conf.5.head
1580         conf/strongswan.conf.5.tail
1581         man/ipsec.conf.5
1582         man/ipsec.secrets.5
1583         src/charon-cmd/charon-cmd.8
1584         src/pki/man/pki.1
1585         src/pki/man/pki---gen.1
1586         src/pki/man/pki---issue.1
1587         src/pki/man/pki---keyid.1
1588         src/pki/man/pki---pkcs7.1
1589         src/pki/man/pki---print.1
1590         src/pki/man/pki---pub.1
1591         src/pki/man/pki---req.1
1592         src/pki/man/pki---self.1
1593         src/pki/man/pki---signcrl.1
1594         src/pki/man/pki---verify.1
1595 ])
1596
1597 AC_OUTPUT
1598
1599 # ========================
1600 #  report enabled plugins
1601 # ========================
1602
1603 AC_MSG_RESULT([])
1604 AC_MSG_RESULT([ strongSwan will be built with the following plugins])
1605 AC_MSG_RESULT([-----------------------------------------------------])
1606
1607 AC_MSG_RESULT([libstrongswan:$s_plugins])
1608 AC_MSG_RESULT([libcharon:    $c_plugins])
1609 AC_MSG_RESULT([libhydra:     $h_plugins])
1610 AC_MSG_RESULT([libtnccs:     $t_plugins])
1611 AC_MSG_RESULT([])