e4832b391c39cf2bf32016566c704451522bd6b0
[strongswan.git] / configure.ac
1 #
2 # Copyright (C) 2007-2017 Tobias Brunner
3 # Copyright (C) 2006-2016 Andreas Steffen
4 # Copyright (C) 2006-2014 Martin Willi
5 # HSR Hochschule fuer Technik Rapperswil
6 #
7 # This program is free software; you can redistribute it and/or modify it
8 # under the terms of the GNU General Public License as published by the
9 # Free Software Foundation; either version 2 of the License, or (at your
10 # option) any later version.  See <http://www.fsf.org/copyleft/gpl.txt>.
11 #
12 # This program is distributed in the hope that it will be useful, but
13 # WITHOUT ANY WARRANTY; without even the implied warranty of MERCHANTABILITY
14 # or FITNESS FOR A PARTICULAR PURPOSE.  See the GNU General Public License
15 # for more details.
16 #
17
18 # ============================
19 #  initialize & set some vars
20 # ============================
21
22 AC_INIT([strongSwan],[5.5.3])
23 AM_INIT_AUTOMAKE(m4_esyscmd([
24         echo tar-ustar
25         echo subdir-objects
26         case `automake --version | head -n 1` in
27                 *" 1.9"*);;
28                 *" 1.10"*);;
29                 *" 1.11"*);;
30                 # don't use parallel test harness in 1.12 and up
31                 *) echo serial-tests;;
32         esac
33 ]))
34 m4_ifdef([AM_SILENT_RULES], [AM_SILENT_RULES])
35 AC_CONFIG_MACRO_DIR([m4/config])
36 AC_CONFIG_HEADERS([config.h])
37 AC_DEFINE([CONFIG_H_INCLUDED], [], [defined if config.h included])
38 AC_DISABLE_STATIC
39 PKG_PROG_PKG_CONFIG
40
41 m4_include(m4/macros/split-package-version.m4)
42 SPLIT_PACKAGE_VERSION
43
44 # =================================
45 #  check --enable-xxx & --with-xxx
46 # =================================
47
48 m4_include(m4/macros/with.m4)
49
50 ARG_WITH_SUBST([random-device],      [/dev/random], [set the device to read real random data from])
51 ARG_WITH_SUBST([urandom-device],     [/dev/urandom], [set the device to read pseudo random data from])
52 ARG_WITH_SUBST([strongswan-conf],    [${sysconfdir}/strongswan.conf], [set the strongswan.conf file location])
53 ARG_WITH_SUBST([resolv-conf],        [${sysconfdir}/resolv.conf], [set the file to use in DNS handler plugin])
54 ARG_WITH_SUBST([piddir],             [/var/run], [set path for PID and UNIX socket files])
55 ARG_WITH_SUBST([ipsecdir],           [${libexecdir%/}/ipsec], [set installation path for ipsec tools])
56 ARG_WITH_SUBST([ipseclibdir],        [${libdir%/}/ipsec], [set installation path for ipsec libraries])
57 ARG_WITH_SUBST([plugindir],          [${ipseclibdir%/}/plugins], [set the installation path of plugins])
58 ARG_WITH_SUBST([imcvdir],            [${ipseclibdir%/}/imcvs], [set the installation path of IMC and IMV dynamic librariers])
59 ARG_WITH_SUBST([nm-ca-dir],          [/usr/share/ca-certificates], [directory the NM backend uses to look up trusted root certificates])
60 ARG_WITH_SUBST([swanctldir],         [${sysconfdir}/swanctl], [base directory for swanctl configuration files and credentials])
61 ARG_WITH_SUBST([linux-headers],      [\${top_srcdir}/src/include], [set directory of linux header files to use])
62 ARG_WITH_SUBST([routing-table],      [220], [set routing table to use for IPsec routes])
63 ARG_WITH_SUBST([routing-table-prio], [220], [set priority for IPsec routing table])
64 ARG_WITH_SUBST([ipsec-script],       [ipsec], [change the name of the ipsec script])
65 ARG_WITH_SUBST([fips-mode],          [0], [set openssl FIPS mode: disabled(0), enabled(1), Suite B enabled(2)])
66 ARG_WITH_SUBST([libfuzzer],          [], [path to libFuzzer.a])
67 ARG_WITH_SET([capabilities],         [no], [set capability dropping library. Currently supported values are "libcap" and "native"])
68 ARG_WITH_SET([mpz_powm_sec],         [yes], [use the more side-channel resistant mpz_powm_sec in libgmp, if available])
69 ARG_WITH_SET([dev-headers],          [no], [install strongSwan development headers to directory.])
70 ARG_WITH_SET([printf-hooks],         [auto], [force the use of a specific printf hook implementation (auto, builtin, glibc, vstr).])
71 ARG_WITH_SET([rubygemdir],           ["gem environment gemdir"], [path to install ruby gems to])
72 ARG_WITH_SET([pythoneggdir],         ["main site-packages directory"], [path to install python eggs to to])
73
74 if test -n "$PKG_CONFIG"; then
75         systemdsystemunitdir_default=$($PKG_CONFIG --variable=systemdsystemunitdir systemd)
76 fi
77 ARG_WITH_SET([systemdsystemunitdir], [$systemdsystemunitdir_default], [directory for systemd service files])
78 AC_SUBST(systemdsystemunitdir)
79
80 AC_ARG_WITH(
81         [user],
82         AS_HELP_STRING([--with-user=user],[change user of the daemons to "user" after startup (default is "root").]),
83         [AC_DEFINE_UNQUOTED([IPSEC_USER], "$withval", [username to run daemon with])
84          AC_SUBST(ipsecuser, "$withval")],
85         [AC_SUBST(ipsecuser, "root")]
86 )
87
88 AC_ARG_WITH(
89         [group],
90         AS_HELP_STRING([--with-group=group],[change group of the daemons to "group" after startup (default is "root").]),
91         [AC_DEFINE_UNQUOTED(IPSEC_GROUP, "$withval", [groupname to run daemon with])
92          AC_SUBST(ipsecgroup, "$withval")],
93         [AC_SUBST(ipsecgroup, "root")]
94 )
95
96 AC_ARG_WITH(
97         [charon-udp-port],
98         AS_HELP_STRING([--with-charon-udp-port=port],[UDP port used by charon locally (default 500). Set to 0 to allocate randomly.]),
99         [AC_DEFINE_UNQUOTED(CHARON_UDP_PORT, [$withval], [UDP port used by charon locally])
100          AC_SUBST(charon_udp_port, [$withval])],
101         [AC_SUBST(charon_udp_port, 500)]
102 )
103
104 AC_ARG_WITH(
105         [charon-natt-port],
106         AS_HELP_STRING([--with-charon-natt-port=port],[UDP port used by charon locally in case a NAT is detected (must be different from charon-udp-port, default 4500). Set to 0 to allocate randomly.]),
107         [AC_DEFINE_UNQUOTED(CHARON_NATT_PORT, [$withval], [UDP post used by charon locally in case a NAT is detected])
108          AC_SUBST(charon_natt_port, [$withval])],
109         [AC_SUBST(charon_natt_port, 4500)]
110 )
111
112 AC_MSG_CHECKING([configured UDP ports ($charon_udp_port, $charon_natt_port)])
113 if test x$charon_udp_port != x0 -a x$charon_udp_port = x$charon_natt_port; then
114         AC_MSG_ERROR(the ports have to be different)
115 else
116         AC_MSG_RESULT(ok)
117 fi
118
119 # convert script name to uppercase
120 AC_SUBST(ipsec_script_upper, [`echo -n "$ipsec_script" | tr a-z A-Z`])
121
122 m4_include(m4/macros/enable-disable.m4)
123
124 # crypto plugins
125 ARG_DISBL_SET([aes],            [disable AES software implementation plugin.])
126 ARG_ENABL_SET([af-alg],         [enable AF_ALG crypto interface to Linux Crypto API.])
127 ARG_ENABL_SET([bliss],          [enable BLISS software implementation plugin.])
128 ARG_ENABL_SET([blowfish],       [enable Blowfish software implementation plugin.])
129 ARG_ENABL_SET([ccm],            [enables the CCM AEAD wrapper crypto plugin.])
130 ARG_ENABL_SET([chapoly],        [enables the ChaCha20/Poly1305 AEAD plugin.])
131 ARG_DISBL_SET([cmac],           [disable CMAC crypto implementation plugin.])
132 ARG_ENABL_SET([ctr],            [enables the Counter Mode wrapper crypto plugin.])
133 ARG_DISBL_SET([des],            [disable DES/3DES software implementation plugin.])
134 ARG_DISBL_SET([fips-prf],       [disable FIPS PRF software implementation plugin.])
135 ARG_ENABL_SET([gcm],            [enables the GCM AEAD wrapper crypto plugin.])
136 ARG_ENABL_SET([gcrypt],         [enables the libgcrypt plugin.])
137 ARG_DISBL_SET([gmp],            [disable GNU MP (libgmp) based crypto implementation plugin.])
138 ARG_DISBL_SET([curve25519],     [disable Curve25519 Diffie-Hellman plugin.])
139 ARG_DISBL_SET([hmac],           [disable HMAC crypto implementation plugin.])
140 ARG_ENABL_SET([md4],            [enable MD4 software implementation plugin.])
141 ARG_DISBL_SET([md5],            [disable MD5 software implementation plugin.])
142 ARG_ENABL_SET([mgf1],           [enable the MGF1 software implementation plugin.])
143 ARG_ENABL_SET([newhope],        [enable New Hope crypto plugin.])
144 ARG_DISBL_SET([nonce],          [disable nonce generation plugin.])
145 ARG_ENABL_SET([ntru],           [enables the NTRU crypto plugin.])
146 ARG_ENABL_SET([openssl],        [enables the OpenSSL crypto plugin.])
147 ARG_ENABL_SET([padlock],        [enables VIA Padlock crypto plugin.])
148 ARG_DISBL_SET([random],         [disable RNG implementation on top of /dev/(u)random.])
149 ARG_DISBL_SET([rc2],            [disable RC2 software implementation plugin.])
150 ARG_ENABL_SET([rdrand],         [enable Intel RDRAND random generator plugin.])
151 ARG_ENABL_SET([aesni],          [enable Intel AES-NI crypto plugin.])
152 ARG_DISBL_SET([sha1],           [disable SHA1 software implementation plugin.])
153 ARG_DISBL_SET([sha2],           [disable SHA256/SHA384/SHA512 software implementation plugin.])
154 ARG_ENABL_SET([sha3],           [enable SHA3_224/SHA3_256/SHA3_384/SHA3_512 software implementation plugin.])
155 ARG_DISBL_SET([xcbc],           [disable xcbc crypto implementation plugin.])
156 # encoding/decoding plugins
157 ARG_DISBL_SET([dnskey],         [disable DNS RR key decoding plugin.])
158 ARG_DISBL_SET([pem],            [disable PEM decoding plugin.])
159 ARG_DISBL_SET([pgp],            [disable PGP key decoding plugin.])
160 ARG_DISBL_SET([pkcs1],          [disable PKCS1 key decoding plugin.])
161 ARG_DISBL_SET([pkcs7],          [disable PKCS7 container support plugin.])
162 ARG_DISBL_SET([pkcs8],          [disable PKCS8 private key decoding plugin.])
163 ARG_DISBL_SET([pkcs12],         [disable PKCS12 container support plugin.])
164 ARG_DISBL_SET([pubkey],         [disable RAW public key support plugin.])
165 ARG_DISBL_SET([sshkey],         [disable SSH key decoding plugin.])
166 ARG_DISBL_SET([x509],           [disable X509 certificate implementation plugin.])
167 # fetcher/resolver plugins
168 ARG_ENABL_SET([curl],           [enable CURL fetcher plugin to fetch files via libcurl. Requires libcurl.])
169 ARG_ENABL_SET([files],          [enable simple file:// URI fetcher.])
170 ARG_ENABL_SET([ldap],           [enable LDAP fetching plugin to fetch files via libldap. Requires openLDAP.])
171 ARG_ENABL_SET([soup],           [enable soup fetcher plugin to fetch from HTTP via libsoup. Requires libsoup.])
172 ARG_ENABL_SET([unbound],        [enable UNBOUND resolver plugin to perform DNS queries via libunbound. Requires libldns and libunbound.])
173 ARG_ENABL_SET([winhttp],        [enable WinHTTP based HTTP/HTTPS fetching plugin.])
174 # database plugins
175 ARG_ENABL_SET([mysql],          [enable MySQL database support. Requires libmysqlclient_r.])
176 ARG_ENABL_SET([sqlite],         [enable SQLite database support. Requires libsqlite3.])
177 # authentication/credential plugins
178 ARG_ENABL_SET([addrblock],      [enables RFC 3779 address block constraint support.])
179 ARG_ENABL_SET([acert],          [enable X509 attribute certificate checking plugin.])
180 ARG_ENABL_SET([agent],          [enables the ssh-agent signing plugin.])
181 ARG_DISBL_SET([constraints],    [disable advanced X509 constraint checking plugin.])
182 ARG_ENABL_SET([coupling],       [enable IKEv2 plugin to couple peer certificates permanently to authentication.])
183 ARG_ENABL_SET([dnscert],        [enable DNSCERT authentication plugin.])
184 ARG_ENABL_SET([eap-sim],        [enable SIM authentication module for EAP.])
185 ARG_ENABL_SET([eap-sim-file],   [enable EAP-SIM backend based on a triplet file.])
186 ARG_ENABL_SET([eap-sim-pcsc],   [enable EAP-SIM backend based on a smartcard reader. Requires libpcsclite.])
187 ARG_ENABL_SET([eap-aka],        [enable EAP AKA authentication module.])
188 ARG_ENABL_SET([eap-aka-3gpp2],  [enable EAP AKA backend implementing 3GPP2 algorithms in software. Requires libgmp.])
189 ARG_ENABL_SET([eap-simaka-sql], [enable EAP-SIM/AKA backend based on a triplet/quintuplet SQL database.])
190 ARG_ENABL_SET([eap-simaka-pseudonym], [enable EAP-SIM/AKA pseudonym storage plugin.])
191 ARG_ENABL_SET([eap-simaka-reauth],    [enable EAP-SIM/AKA reauthentication data storage plugin.])
192 ARG_ENABL_SET([eap-identity],   [enable EAP module providing EAP-Identity helper.])
193 ARG_ENABL_SET([eap-md5],        [enable EAP MD5 (CHAP) authentication module.])
194 ARG_ENABL_SET([eap-gtc],        [enable EAP GTC authentication module.])
195 ARG_ENABL_SET([eap-mschapv2],   [enable EAP MS-CHAPv2 authentication module.])
196 ARG_ENABL_SET([eap-tls],        [enable EAP TLS authentication module.])
197 ARG_ENABL_SET([eap-ttls],       [enable EAP TTLS authentication module.])
198 ARG_ENABL_SET([eap-peap],       [enable EAP PEAP authentication module.])
199 ARG_ENABL_SET([eap-tnc],        [enable EAP TNC trusted network connect module.])
200 ARG_ENABL_SET([eap-dynamic],    [enable dynamic EAP proxy module.])
201 ARG_ENABL_SET([eap-radius],     [enable RADIUS proxy authentication module.])
202 ARG_ENABL_SET([ext-auth],       [enable plugin calling an external authorization script.])
203 ARG_ENABL_SET([ipseckey],       [enable IPSECKEY authentication plugin.])
204 ARG_ENABL_SET([keychain],       [enables OS X Keychain Services credential set.])
205 ARG_ENABL_SET([pkcs11],         [enables the PKCS11 token support plugin.])
206 ARG_ENABL_SET([tpm],            [enables the TPM plugin.])
207 ARG_DISBL_SET([revocation],     [disable X509 CRL/OCSP revocation check plugin.])
208 ARG_ENABL_SET([whitelist],      [enable peer identity whitelisting plugin.])
209 ARG_DISBL_SET([xauth-generic],  [disable generic XAuth backend.])
210 ARG_ENABL_SET([xauth-eap],      [enable XAuth backend using EAP methods to verify passwords.])
211 ARG_ENABL_SET([xauth-pam],      [enable XAuth backend using PAM to verify passwords.])
212 ARG_ENABL_SET([xauth-noauth],   [enable XAuth pseudo-backend that does not actually verify or even request any credentials.])
213 # kernel interfaces / sockets
214 ARG_DISBL_SET([kernel-netlink], [disable the netlink kernel interface.])
215 ARG_ENABL_SET([kernel-pfkey],   [enable the PF_KEY kernel interface.])
216 ARG_ENABL_SET([kernel-pfroute], [enable the PF_ROUTE kernel interface.])
217 ARG_ENABL_SET([kernel-iph],     [enable the Windows IP Helper based networking backend.])
218 ARG_ENABL_SET([kernel-libipsec],[enable the libipsec kernel interface.])
219 ARG_ENABL_SET([kernel-wfp],     [enable the Windows Filtering Platform IPsec backend.])
220 ARG_DISBL_SET([socket-default], [disable default socket implementation for charon.])
221 ARG_ENABL_SET([socket-dynamic], [enable dynamic socket implementation for charon])
222 ARG_ENABL_SET([socket-win],     [enable Winsock2 based socket implementation for charon])
223 # configuration/control plugins
224 ARG_DISBL_SET([stroke],         [disable charons stroke configuration backend.])
225 ARG_ENABL_SET([smp],            [enable SMP configuration and control interface. Requires libxml.])
226 ARG_ENABL_SET([sql],            [enable SQL database configuration backend.])
227 ARG_ENABL_SET([uci],            [enable OpenWRT UCI configuration plugin.])
228 ARG_DISBL_SET([vici],           [disable strongSwan IKE generic IPC interface plugin.])
229 # attribute provider/consumer plugins
230 ARG_ENABL_SET([android-dns],    [enable Android specific DNS handler.])
231 ARG_DISBL_SET([attr],           [disable strongswan.conf based configuration attribute plugin.])
232 ARG_ENABL_SET([attr-sql],       [enable SQL based configuration attribute plugin.])
233 ARG_ENABL_SET([dhcp],           [enable DHCP based attribute provider plugin.])
234 ARG_ENABL_SET([osx-attr],       [enable OS X SystemConfiguration attribute handler.])
235 ARG_ENABL_SET([p-cscf],         [enable plugin to request P-CSCF server addresses from an ePDG.])
236 ARG_DISBL_SET([resolve],        [disable resolve DNS handler plugin.])
237 ARG_ENABL_SET([unity],          [enables Cisco Unity extension plugin.])
238 # TNC modules/plugins
239 ARG_ENABL_SET([imc-test],       [enable IMC test module.])
240 ARG_ENABL_SET([imv-test],       [enable IMV test module.])
241 ARG_ENABL_SET([imc-scanner],    [enable IMC port scanner module.])
242 ARG_ENABL_SET([imv-scanner],    [enable IMV port scanner module.])
243 ARG_ENABL_SET([imc-os],         [enable IMC operating system module.])
244 ARG_ENABL_SET([imv-os],         [enable IMV operating system module.])
245 ARG_ENABL_SET([imc-attestation],[enable IMC attestation module.])
246 ARG_ENABL_SET([imv-attestation],[enable IMV attestation module.])
247 ARG_ENABL_SET([imc-swid],       [enable IMC swid module.])
248 ARG_ENABL_SET([imv-swid],       [enable IMV swid module.])
249 ARG_ENABL_SET([imc-hcd],        [enable IMC hcd module.])
250 ARG_ENABL_SET([imv-hcd],        [enable IMV hcd module.])
251 ARG_ENABL_SET([tnc-ifmap],      [enable TNC IF-MAP module. Requires libxml])
252 ARG_ENABL_SET([tnc-imc],        [enable TNC IMC module.])
253 ARG_ENABL_SET([tnc-imv],        [enable TNC IMV module.])
254 ARG_ENABL_SET([tnc-pdp],        [enable TNC policy decision point module.])
255 ARG_ENABL_SET([tnccs-11],       [enable TNCCS 1.1 protocol module. Requires libxml])
256 ARG_ENABL_SET([tnccs-20],       [enable TNCCS 2.0 protocol module.])
257 ARG_ENABL_SET([tnccs-dynamic],  [enable dynamic TNCCS protocol discovery module.])
258 # misc plugins
259 ARG_ENABL_SET([android-log],    [enable Android specific logger plugin.])
260 ARG_ENABL_SET([bypass-lan],     [enable plugin to install bypass policies for local subnets.])
261 ARG_ENABL_SET([certexpire],     [enable CSV export of expiration dates of used certificates.])
262 ARG_ENABL_SET([connmark],       [enable connmark plugin using conntrack based marks to select return path SA.])
263 ARG_ENABL_SET([forecast],       [enable forecast plugin forwarding broadcast/multicast messages.])
264 ARG_ENABL_SET([duplicheck],     [advanced duplicate checking plugin using liveness checks.])
265 ARG_ENABL_SET([error-notify],   [enable error notification plugin.])
266 ARG_ENABL_SET([farp],           [enable ARP faking plugin that responds to ARP requests to peers virtual IP])
267 ARG_ENABL_SET([ha],             [enable high availability cluster plugin.])
268 ARG_ENABL_SET([led],            [enable plugin to control LEDs on IKEv2 activity using the Linux kernel LED subsystem.])
269 ARG_ENABL_SET([load-tester],    [enable load testing plugin for IKEv2 daemon.])
270 ARG_ENABL_SET([lookip],         [enable fast virtual IP lookup and notification plugin.])
271 ARG_ENABL_SET([radattr],        [enable plugin to inject and process custom RADIUS attributes as IKEv2 client.])
272 ARG_ENABL_SET([systime-fix],    [enable plugin to handle cert lifetimes with invalid system time gracefully.])
273 ARG_ENABL_SET([test-vectors],   [enable plugin providing crypto test vectors.])
274 ARG_DISBL_SET([updown],         [disable updown firewall script plugin.])
275 # programs/components
276 ARG_ENABL_SET([aikgen],         [enable AIK generator for TPM 1.2.])
277 ARG_DISBL_SET([charon],         [disable the IKEv1/IKEv2 keying daemon charon.])
278 ARG_ENABL_SET([cmd],            [enable the command line IKE client charon-cmd.])
279 ARG_ENABL_SET([conftest],       [enforce Suite B conformance test framework.])
280 ARG_ENABL_SET([dumm],           [enable the DUMM UML test framework.])
281 ARG_ENABL_SET([fast],           [enable libfast (FastCGI Application Server w/ templates.])
282 ARG_ENABL_SET([fuzzing],        [enable fuzzing scripts (found in directory fuzz).])
283 ARG_ENABL_SET([libipsec],       [enable user space IPsec implementation.])
284 ARG_ENABL_SET([manager],        [enable web management console (proof of concept).])
285 ARG_ENABL_SET([medcli],         [enable mediation client configuration database plugin.])
286 ARG_ENABL_SET([medsrv],         [enable mediation server web frontend and daemon plugin.])
287 ARG_ENABL_SET([nm],             [enable NetworkManager backend.])
288 ARG_DISBL_SET([pki],            [disable pki certificate utility.])
289 ARG_DISBL_SET([scepclient],     [disable SCEP client tool.])
290 ARG_DISBL_SET([scripts],        [disable additional utilities (found in directory scripts).])
291 ARG_ENABL_SET([svc],            [enable charon Windows service.])
292 ARG_ENABL_SET([systemd],        [enable systemd specific IKE daemon charon-systemd.])
293 ARG_DISBL_SET([swanctl],        [disable swanctl configuration and control tool.])
294 ARG_ENABL_SET([tkm],            [enable Trusted Key Manager support.])
295 # optional features
296 ARG_ENABL_SET([bfd-backtraces], [use binutils libbfd to resolve backtraces for memory leaks and segfaults.])
297 ARG_ENABL_SET([dbghelp-backtraces],[use dbghlp.dll on Windows to create and print backtraces for memory leaks and segfaults.])
298 ARG_DISBL_SET([ikev1],          [disable IKEv1 protocol support in charon.])
299 ARG_DISBL_SET([ikev2],          [disable IKEv2 protocol support in charon.])
300 ARG_ENABL_SET([integrity-test], [enable integrity testing of libstrongswan and plugins.])
301 ARG_DISBL_SET([load-warning],   [disable the charon plugin load option warning in starter.])
302 ARG_ENABL_SET([mediation],      [enable IKEv2 Mediation Extension.])
303 ARG_ENABL_SET([unwind-backtraces],[use libunwind to create backtraces for memory leaks and segfaults.])
304 ARG_ENABL_SET([ruby-gems],      [enable build of provided ruby gems.])
305 ARG_ENABL_SET([ruby-gems-install],[enable installation of provided ruby gems.])
306 ARG_ENABL_SET([python-eggs],    [enable build of provided python eggs.])
307 ARG_ENABL_SET([python-eggs-install],[enable installation of provided python eggs.])
308 ARG_ENABL_SET([perl-cpan],      [enable build of provided perl CPAN module.])
309 ARG_ENABL_SET([perl-cpan-install],[enable installation of provided CPAN module.])
310 ARG_ENABL_SET([tss-trousers],   [enable the use of the TrouSerS Trusted Software Stack])
311 ARG_ENABL_SET([tss-tss2],       [enable the use of the TSS 2.0 Trusted Software Stack])
312
313 # compile options
314 ARG_ENABL_SET([coverage],       [enable lcov coverage report generation.])
315 ARG_ENABL_SET([leak-detective], [enable malloc hooks to find memory leaks.])
316 ARG_ENABL_SET([lock-profiler],  [enable lock/mutex profiling code.])
317 ARG_ENABL_SET([log-thread-ids], [use thread ID, if available, instead of an incremented value starting from 1, to identify threads.])
318 ARG_ENABL_SET([monolithic],     [build monolithic version of libstrongswan that includes all enabled plugins. Similarly, the plugins of charon are assembled in libcharon.])
319
320 # ===================================
321 #  option to disable default options
322 # ===================================
323
324 ARG_DISBL_SET([defaults],       [disable all default plugins (they can be enabled with their respective --enable options)])
325
326 if test x$defaults = xfalse; then
327         for option in $enabled_by_default; do
328                 eval test x\${${option}_given} = xtrue && continue
329                 eval $option=false
330         done
331 fi
332
333 # ==============================
334 #  option to enable all options
335 # ==============================
336
337 ARG_ENABL_SET([all],            [enable all plugins and features (they can be disabled with their respective --disable options). Mainly for testing.])
338
339 if test x$all_given = xtrue; then
340         for option in $disabled_by_default; do
341                 eval test x\${${option}_given} = xtrue && continue
342                 eval $option=true
343         done
344 fi
345
346 # ===========================
347 #  set up compiler and flags
348 # ===========================
349
350 if test -z "$CFLAGS"; then
351         CFLAGS="-g -O2 -Wall -Wno-format -Wno-format-security -Wno-pointer-sign"
352 fi
353 AC_PROG_CC
354 AM_PROG_CC_C_O
355
356 AC_LIB_PREFIX
357 AC_C_BIGENDIAN
358
359 # =========================
360 #  check required programs
361 # =========================
362
363 LT_INIT
364 AC_PROG_INSTALL
365 AC_PROG_EGREP
366 AC_PROG_AWK
367 AC_PROG_LEX
368 AC_PROG_YACC
369 AM_PATH_PYTHON(,,[:])
370 AC_PATH_PROG([PERL], [perl], [], [$PATH:/bin:/usr/bin:/usr/local/bin])
371 AC_PATH_PROG([GPERF], [gperf], [], [$PATH:/bin:/usr/bin:/usr/local/bin])
372
373 # because gperf is not needed by end-users we just report it but do not abort on failure
374 AC_MSG_CHECKING([gperf version >= 3.0.0])
375 if test -x "$GPERF"; then
376         if test "`$GPERF --version | $AWK -F' ' '/^GNU gperf/ { print $3 }' | $AWK -F. '{ print $1 }'`" -ge "3"; then
377                 AC_MSG_RESULT([yes])
378         else
379                 AC_MSG_RESULT([no])
380         fi
381 else
382         AC_MSG_RESULT([not found])
383 fi
384
385 # ========================
386 #  dependency calculation
387 # ========================
388
389 if test x$xauth_generic_given = xfalse -a x$ikev1 = xfalse; then
390         xauth_generic=false;
391 fi
392
393 if test x$kernel_libipsec = xtrue; then
394         libipsec=true;
395 fi
396
397 if test x$eap_aka_3gpp2 = xtrue; then
398         gmp=true;
399 fi
400
401 if test x$eap_aka = xtrue; then
402         fips_prf=true;
403         simaka=true;
404 fi
405
406 if test x$eap_sim = xtrue; then
407         fips_prf=true;
408         simaka=true;
409 fi
410
411 if test x$eap_radius = xtrue -o x$radattr = xtrue -o x$tnc_pdp = xtrue; then
412         radius=true;
413 fi
414
415 if test x$tnc_imc = xtrue -o x$tnc_imv = xtrue -o x$tnccs_11 = xtrue -o x$tnccs_11 = xtrue -o x$tnccs_dynamic = xtrue -o x$eap_tnc = xtrue; then
416         tnc_tnccs=true;
417 fi
418
419 if test x$eap_tls = xtrue -o x$eap_ttls = xtrue -o x$eap_peap = xtrue -o x$tnc_tnccs = xtrue; then
420         tls=true;
421 fi
422
423 if test x$imc_test = xtrue -o x$imv_test = xtrue -o x$imc_scanner = xtrue -o x$imv_scanner = xtrue -o x$imc_os = xtrue -o x$imv_os = xtrue -o x$imc_attestation = xtrue -o x$imv_attestation = xtrue -o x$imc_swid = xtrue -o x$imv_swid = xtrue -o x$imc_hcd = xtrue -o x$imv_hcd = xtrue; then
424         imcv=true;
425 fi
426
427 if test x$fips_prf = xtrue; then
428         if test x$openssl = xfalse; then
429                 sha1=true;
430         fi
431 fi
432
433 if test x$swanctl = xtrue; then
434         vici=true
435 fi
436
437 if test x$smp = xtrue -o x$tnccs_11 = xtrue -o x$tnc_ifmap = xtrue; then
438         xml=true
439 fi
440
441 if test x$manager = xtrue; then
442         fast=true
443 fi
444
445 if test x$medsrv = xtrue; then
446         mediation=true
447         fast=true
448 fi
449
450 if test x$medcli = xtrue; then
451         mediation=true
452 fi
453
454 if test x$ruby_gems_install = xtrue; then
455         ruby_gems=true
456 fi
457
458 if test x$python_eggs_install = xtrue; then
459         python_eggs=true
460 fi
461
462 if test x$perl_cpan_install = xtrue; then
463         perl_cpan=true
464 fi
465
466 if test x$aikgen = xtrue; then
467         tss_trousers=true
468 fi
469
470 if test x$ntru = xtrue -o x$bliss = xtrue; then
471         mgf1=true
472 fi
473
474 # ===========================================
475 #  check required libraries and header files
476 # ===========================================
477
478 AC_HEADER_STDBOOL
479 AC_FUNC_ALLOCA
480 AC_FUNC_STRERROR_R
481
482 #  libraries needed on some platforms but not on others
483 # ------------------------------------------------------
484 saved_LIBS=$LIBS
485
486 # FreeBSD and Mac OS X have dlopen integrated in libc, Linux needs libdl
487 LIBS=""
488 AC_SEARCH_LIBS(dlopen, dl, [DLLIB=$LIBS])
489 AC_SUBST(DLLIB)
490
491 # glibc's backtrace() can be replicated on FreeBSD with libexecinfo
492 LIBS=""
493 AC_SEARCH_LIBS(backtrace, execinfo, [BTLIB=$LIBS])
494 AC_CHECK_FUNCS(backtrace)
495 AC_SUBST(BTLIB)
496
497 # OpenSolaris needs libsocket and libnsl for socket()
498 LIBS=""
499 AC_SEARCH_LIBS(socket, socket, [SOCKLIB=$LIBS],
500         [AC_CHECK_LIB(nsl, socket, [SOCKLIB="-lsocket -lnsl"], [], [-lsocket])]
501 )
502 AC_SUBST(SOCKLIB)
503
504 # Android has pthread_* functions in bionic (libc), others need libpthread
505 LIBS=$DLLIB
506 AC_SEARCH_LIBS(pthread_create, pthread, [PTHREADLIB=$LIBS])
507 AC_SUBST(PTHREADLIB)
508
509 # Some architectures require explicit -latomic for __atomic_* operations
510 # AC_SEARCH_LIBS() does not work when checking built-ins due to conflicting types
511 LIBS=""
512 AC_MSG_CHECKING(for library containing __atomic_and_fetch)
513 AC_LINK_IFELSE(
514         [AC_LANG_PROGRAM([[]], [[int x; __atomic_and_fetch(&x, 1, __ATOMIC_RELAXED);]])],
515         [AC_MSG_RESULT([none required])],
516         [LIBS="-latomic";
517          AC_LINK_IFELSE(
518                 [AC_LANG_PROGRAM([[]], [[int x; __atomic_and_fetch(&x, 1, __ATOMIC_RELAXED);]])],
519                 [AC_MSG_RESULT([-latomic]); ATOMICLIB=$LIBS],
520                 [AC_MSG_RESULT([no])])
521         ]
522 )
523 AC_SUBST(ATOMICLIB)
524
525 LIBS=$saved_LIBS
526 # ------------------------------------------------------
527
528 AC_MSG_CHECKING(for dladdr)
529 AC_COMPILE_IFELSE(
530         [AC_LANG_PROGRAM(
531                 [[#define _GNU_SOURCE
532                   #include <dlfcn.h>]],
533                 [[Dl_info* info = 0;
534                   dladdr(0, info);]])],
535         [AC_MSG_RESULT([yes]); AC_DEFINE([HAVE_DLADDR], [], [have dladdr()])],
536         [AC_MSG_RESULT([no])]
537 )
538
539 # check if pthread_condattr_setclock(CLOCK_MONOTONIC) is supported
540 saved_LIBS=$LIBS
541 LIBS=$PTHREADLIB
542 AC_MSG_CHECKING([for pthread_condattr_setclock(CLOCK_MONOTONIC)])
543 AC_RUN_IFELSE(
544         [AC_LANG_SOURCE(
545                 [[#include <pthread.h>
546                   int main() { pthread_condattr_t attr;
547                         pthread_condattr_init(&attr);
548                         return pthread_condattr_setclock(&attr, CLOCK_MONOTONIC);}]])],
549         [AC_MSG_RESULT([yes]);
550          AC_DEFINE([HAVE_CONDATTR_CLOCK_MONOTONIC], [],
551                            [pthread_condattr_setclock supports CLOCK_MONOTONIC])],
552         [AC_MSG_RESULT([no])],
553         # Check existence of pthread_condattr_setclock if cross-compiling
554         [AC_MSG_RESULT([unknown]);
555          AC_CHECK_FUNCS(pthread_condattr_setclock,
556                 [AC_DEFINE([HAVE_CONDATTR_CLOCK_MONOTONIC], [],
557                                    [have pthread_condattr_setclock()])]
558         )]
559 )
560 # check if we actually are able to configure attributes on cond vars
561 AC_CHECK_FUNCS(pthread_condattr_init)
562 # instead of pthread_condattr_setclock Android has this function
563 AC_CHECK_FUNCS(pthread_cond_timedwait_monotonic)
564 # check if we can cancel threads
565 AC_CHECK_FUNCS(pthread_cancel)
566 # check if native rwlocks are available
567 AC_CHECK_FUNCS(pthread_rwlock_init)
568 # check if pthread spinlocks are available
569 AC_CHECK_FUNCS(pthread_spin_init)
570 # check if we have POSIX semaphore functions, including timed-wait
571 AC_CHECK_FUNCS(sem_timedwait)
572 LIBS=$saved_LIBS
573
574 AC_CHECK_FUNC(
575         [gettid],
576         [AC_DEFINE([HAVE_GETTID], [], [have gettid()])],
577         [AC_MSG_CHECKING([for SYS_gettid])
578          AC_COMPILE_IFELSE(
579                 [AC_LANG_PROGRAM(
580                         [[#define _GNU_SOURCE
581                           #include <unistd.h>
582                           #include <sys/syscall.h>]],
583                         [[int main() {
584                           return syscall(SYS_gettid);}]])],
585                 [AC_MSG_RESULT([yes]);
586                  AC_DEFINE([HAVE_GETTID], [], [have gettid()])
587                  AC_DEFINE([HAVE_SYS_GETTID], [], [have syscall(SYS_gettid)])],
588                 [AC_MSG_RESULT([no])]
589         )]
590 )
591
592 AC_CHECK_FUNC(
593         [qsort_r],
594         [
595                 AC_DEFINE([HAVE_QSORT_R], [], [have qsort_r()])
596                 # set -Werror so that we get an error for "argument ... has
597                 # incompatible pointer type" warnings
598                 save_CFLAGS="$CFLAGS"
599                 CFLAGS="$CFLAGS -Werror -Wno-unused-parameter"
600                 AC_MSG_CHECKING([for GNU-style qsort_r])
601                 AC_COMPILE_IFELSE(
602                         [AC_LANG_PROGRAM(
603                                 [[#define _GNU_SOURCE
604                                   #include <stdlib.h>
605                                   int cmp (const void *a, const void *b, void *x) { return 0; }]],
606                                 [[int arr[] = { 0, 1 };
607                                   qsort_r(arr, 2, sizeof(int), cmp, arr);]])],
608                 [AC_MSG_RESULT([yes]);
609                  AC_DEFINE([HAVE_QSORT_R_GNU], [], [have GNU-style qsort_r()])],
610                 [
611                         AC_MSG_RESULT([no]);
612                         AC_MSG_CHECKING([for BSD-style qsort_r])
613                         AC_COMPILE_IFELSE(
614                                 [AC_LANG_PROGRAM(
615                                         [[#include <stdlib.h>
616                                           int cmp (void *x, const void *a, const void *b) { return 0; }]],
617                                         [[int arr[] = { 0, 1 };
618                                           qsort_r(arr, 2, sizeof(int), arr, cmp);]])],
619                         [AC_MSG_RESULT([yes]);
620                          AC_DEFINE([HAVE_QSORT_R_BSD], [], [have BSD-style qsort_r()])],
621                         [AC_MSG_RESULT([no]);
622                          AC_MSG_FAILURE([qsort_r has unknown semantics])])
623                 ])
624                 CFLAGS="$save_CFLAGS"
625         ]
626 )
627
628 AC_CHECK_FUNCS(prctl mallinfo getpass closefrom getpwnam_r getgrnam_r getpwuid_r)
629 AC_CHECK_FUNCS(fmemopen funopen mmap memrchr setlinebuf strptime dirfd sigwaitinfo)
630
631 AC_CHECK_FUNC([syslog], [
632         AC_DEFINE([HAVE_SYSLOG], [], [have syslog(3) and friends])
633         syslog=true
634 ])
635 AM_CONDITIONAL(USE_SYSLOG, [test "x$syslog" = xtrue])
636
637 AC_CHECK_HEADERS(sys/sockio.h sys/syscall.h sys/param.h glob.h net/if_tun.h)
638 AC_CHECK_HEADERS(net/pfkeyv2.h netipsec/ipsec.h netinet6/ipsec.h linux/udp.h)
639 AC_CHECK_HEADERS([netinet/ip6.h linux/fib_rules.h], [], [],
640 [
641         #include <sys/types.h>
642         #include <netinet/in.h>
643 ])
644
645 AC_CHECK_MEMBERS([struct sockaddr.sa_len], [], [],
646 [
647         #include <sys/types.h>
648         #include <sys/socket.h>
649 ])
650
651 AC_CHECK_MEMBERS([struct sadb_x_policy.sadb_x_policy_priority], [], [],
652 [
653         #include <sys/types.h>
654         #ifdef HAVE_NET_PFKEYV2_H
655         #include <net/pfkeyv2.h>
656         #else
657         #include <stdint.h>
658         #include <linux/pfkeyv2.h>
659         #endif
660 ])
661
662 AC_MSG_CHECKING([for in6addr_any])
663 AC_COMPILE_IFELSE(
664         [AC_LANG_PROGRAM(
665                 [[#include <sys/types.h>
666                   #include <sys/socket.h>
667                   #include <netinet/in.h>]],
668                 [[struct in6_addr in6 __attribute__((unused));
669                   in6 = in6addr_any;]])],
670         [AC_MSG_RESULT([yes]);
671          AC_DEFINE([HAVE_IN6ADDR_ANY], [], [have struct in6_addr in6addr_any])],
672         [AC_MSG_RESULT([no])]
673 )
674
675 AC_MSG_CHECKING([for in6_pktinfo])
676 AC_COMPILE_IFELSE(
677         [AC_LANG_PROGRAM(
678                 [[#define _GNU_SOURCE
679                   #include <sys/types.h>
680                   #include <sys/socket.h>
681                   #include <netinet/in.h>]],
682                 [[struct in6_pktinfo pi;
683                   if (pi.ipi6_ifindex)
684                   {
685                     return 0;
686                   }]])],
687         [AC_MSG_RESULT([yes]);
688          AC_DEFINE([HAVE_IN6_PKTINFO], [], [have struct in6_pktinfo.ipi6_ifindex])],
689         [AC_MSG_RESULT([no])]
690 )
691
692 AC_MSG_CHECKING([for RTM_IFANNOUNCE])
693 AC_COMPILE_IFELSE(
694         [AC_LANG_PROGRAM(
695                 [[#include <sys/socket.h>
696                   #include <net/if.h>
697                   #include <net/route.h>]],
698                 [[return RTM_IFANNOUNCE;]])],
699         [AC_MSG_RESULT([yes]);
700          AC_DEFINE([HAVE_RTM_IFANNOUNCE], [], [have PF_ROUTE RTM_IFANNOUNCE defined])],
701         [AC_MSG_RESULT([no])]
702 )
703
704 AC_MSG_CHECKING([for IPSEC_MODE_BEET])
705 AC_COMPILE_IFELSE(
706         [AC_LANG_PROGRAM(
707                 [[#include <sys/types.h>
708                   #ifdef HAVE_NETIPSEC_IPSEC_H
709                   #include <netipsec/ipsec.h>
710                   #elif defined(HAVE_NETINET6_IPSEC_H)
711                   #include <netinet6/ipsec.h>
712                   #else
713                   #include <stdint.h>
714                   #include <linux/ipsec.h>
715                   #endif]],
716                 [[int mode = IPSEC_MODE_BEET;
717                   return mode;]])],
718         [AC_MSG_RESULT([yes]);
719          AC_DEFINE([HAVE_IPSEC_MODE_BEET], [], [have IPSEC_MODE_BEET defined])],
720         [AC_MSG_RESULT([no])]
721 )
722
723 AC_MSG_CHECKING([for IPSEC_DIR_FWD])
724 AC_COMPILE_IFELSE(
725         [AC_LANG_PROGRAM(
726                 [[#include <sys/types.h>
727                   #ifdef HAVE_NETIPSEC_IPSEC_H
728                   #include <netipsec/ipsec.h>
729                   #elif defined(HAVE_NETINET6_IPSEC_H)
730                   #include <netinet6/ipsec.h>
731                   #else
732                   #include <stdint.h>
733                   #include <linux/ipsec.h>
734                   #endif]],
735                 [[int dir = IPSEC_DIR_FWD;
736                   return dir;]])],
737         [AC_MSG_RESULT([yes]);
738          AC_DEFINE([HAVE_IPSEC_DIR_FWD], [], [have IPSEC_DIR_FWD defined])],
739         [AC_MSG_RESULT([no])]
740 )
741
742 AC_MSG_CHECKING([for RTA_TABLE])
743 AC_COMPILE_IFELSE(
744         [AC_LANG_PROGRAM(
745                 [[#include <sys/socket.h>
746                   #include <linux/netlink.h>
747                   #include <linux/rtnetlink.h>]],
748                 [[int rta_type = RTA_TABLE;
749                   return rta_type;]])],
750         [AC_MSG_RESULT([yes]);
751          AC_DEFINE([HAVE_RTA_TABLE], [], [have netlink RTA_TABLE defined])],
752         [AC_MSG_RESULT([no])]
753 )
754
755 AC_MSG_CHECKING([for __int128])
756 AC_COMPILE_IFELSE(
757         [AC_LANG_PROGRAM(
758                 [[#include <sys/types.h>]],
759                 [[__int128 x = 0;
760                   return x;]])],
761         [AC_MSG_RESULT([yes]);
762          AC_DEFINE([HAVE_INT128], [], [have __int128 type support])],
763         [AC_MSG_RESULT([no])]
764 )
765
766 AC_MSG_CHECKING([for GCC __sync operations])
767 AC_RUN_IFELSE([AC_LANG_SOURCE(
768         [[
769                         int main() {
770                         int ref = 1;
771                         __sync_fetch_and_add (&ref, 1);
772                         __sync_sub_and_fetch (&ref, 1);
773                         __sync_val_compare_and_swap(&ref, 1, 0);
774                         return ref;
775                 }
776         ]])],
777         [AC_MSG_RESULT([yes]);
778          AC_DEFINE([HAVE_GCC_SYNC_OPERATIONS], [],
779                    [have GCC __sync_* operations])],
780         [AC_MSG_RESULT([no])],
781         [AC_MSG_RESULT([no])]
782 )
783
784 case "$printf_hooks" in
785 auto|builtin|glibc|vstr)
786         ;;
787 *)
788         AC_MSG_NOTICE([invalid printf hook implementation, defaulting to 'auto'])
789         printf_hooks=auto
790         ;;
791 esac
792
793 if test x$printf_hooks = xauto -o x$printf_hooks = xglibc; then
794         # check for the new register_printf_specifier function with len argument,
795         # or the deprecated register_printf_function without
796         AC_CHECK_FUNC(
797                 [register_printf_specifier],
798                 [AC_DEFINE([HAVE_PRINTF_SPECIFIER], [], [have register_printf_specifier()])],
799                 [AC_CHECK_FUNC(
800                         [register_printf_function],
801                         [AC_DEFINE([HAVE_PRINTF_FUNCTION], [], [have register_printf_function()])],
802                         [
803                                 AC_MSG_NOTICE([printf(3) does not support custom format specifiers!])
804                                 if test x$printf_hooks = xglibc; then
805                                         AC_MSG_ERROR([please select a different printf hook implementation])
806                                 else
807                                         # fallback to builtin printf hook implementation
808                                         printf_hooks=builtin
809                                 fi
810                         ]
811                 )]
812         )
813 fi
814
815 AC_MSG_CHECKING([for Windows target])
816 AC_COMPILE_IFELSE(
817         [AC_LANG_PROGRAM(
818                 [[#include <windows.h>]],
819                 [[#ifndef WIN32
820                   # error WIN32 undefined
821                   #endif
822                 ]])],
823         [
824                 AC_MSG_RESULT([yes])
825                 windows=true
826                 openssl_lib=eay32
827                 AC_SUBST(PTHREADLIB, "")
828                 # explicitly disable ms-bitfields, as it breaks __attribute__((packed))
829                 case "$CFLAGS" in
830                         *ms-bitfields*) ;;
831                         *) CFLAGS="$CFLAGS -mno-ms-bitfields" ;;
832                 esac
833         ],
834         [
835                 AC_MSG_RESULT([no])
836                 openssl_lib=crypto
837
838                 # check for clock_gettime() on non-Windows only. Otherwise this
839                 # check might find clock_gettime() in libwinpthread, but we don't want
840                 # to link against it.
841                 saved_LIBS=$LIBS
842                 # FreeBSD has clock_gettime in libc, Linux needs librt
843                 LIBS=""
844                 AC_SEARCH_LIBS(clock_gettime, rt, [RTLIB=$LIBS])
845                 AC_CHECK_FUNCS(clock_gettime)
846                 AC_SUBST(RTLIB)
847                 LIBS=$saved_LIBS
848         ]
849 )
850 AC_SUBST(OPENSSL_LIB, [-l$openssl_lib])
851 AM_CONDITIONAL(USE_WINDOWS, [test "x$windows" = xtrue])
852
853 AC_MSG_CHECKING([for working __attribute__((packed))])
854 AC_COMPILE_IFELSE(
855         [AC_LANG_PROGRAM([], [[
856                 struct test { char a; short b; } __attribute__((packed));
857                 char x[sizeof(struct test) == sizeof(char) + sizeof(short) ? 1 : -1]
858                         __attribute__((unused));
859                 return 0;
860         ]])],
861         [AC_MSG_RESULT([yes])],
862         [AC_MSG_RESULT([no]); AC_MSG_ERROR([__attribute__((packed)) does not work])]
863 )
864
865 AC_MSG_CHECKING([clang])
866 AC_COMPILE_IFELSE(
867         [AC_LANG_PROGRAM(
868                 [], [[
869                  #ifndef __clang__
870                  # error not using LLVM clang
871                  #endif
872                 ]])],
873         [
874                 AC_MSG_RESULT([yes])
875         ],
876         [
877                 AC_MSG_RESULT([no])
878                 # GCC, but not MinGW requires -rdynamic for plugins
879                 if test x$windows != xtrue; then
880                         AC_SUBST(PLUGIN_CFLAGS, [-rdynamic])
881                 fi
882         ]
883 )
884
885 AC_MSG_CHECKING([x86/x64 target])
886 AC_COMPILE_IFELSE(
887         [AC_LANG_PROGRAM(
888                 [], [[
889                  #if !defined(__i386__) && !defined(__x86_64__)
890                  # error not on x86/x64
891                  #endif
892                 ]])],
893         [
894                 x86x64=true
895                 AC_MSG_RESULT([yes])
896         ],
897         [AC_MSG_RESULT([no])]
898 )
899 AM_CONDITIONAL(USE_X86X64, [test "x$x86x64" = xtrue])
900
901 if test x$printf_hooks = xvstr; then
902         AC_CHECK_LIB([vstr],[vstr_init],[LIBS="$LIBS"],[AC_MSG_ERROR([Vstr string library not found])],[])
903         AC_DEFINE([USE_VSTR], [], [use Vstr string library for printf hooks])
904 fi
905
906 if test x$printf_hooks = xbuiltin; then
907         AC_DEFINE([USE_BUILTIN_PRINTF], [], [using builtin printf for printf hooks])
908 fi
909
910 if test x$gmp = xtrue; then
911         saved_LIBS=$LIBS
912         AC_CHECK_LIB([gmp],[__gmpz_init],[],[AC_MSG_ERROR([GNU Multi Precision library gmp not found])],[])
913         AC_MSG_CHECKING([mpz_powm_sec])
914         if test x$mpz_powm_sec = xyes; then
915                 AC_COMPILE_IFELSE(
916                         [AC_LANG_PROGRAM(
917                                 [[#include "gmp.h"]],
918                                 [[void *x = mpz_powm_sec;]])],
919                         [AC_MSG_RESULT([yes]);
920                          AC_DEFINE([HAVE_MPZ_POWM_SEC], [], [have mpz_mown_sec()])],
921                         [AC_MSG_RESULT([no])]
922                 )
923         else
924                 AC_MSG_RESULT([disabled])
925         fi
926         LIBS=$saved_LIBS
927         AC_MSG_CHECKING([gmp.h version >= 4.1.4])
928         AC_COMPILE_IFELSE(
929                 [AC_LANG_PROGRAM(
930                         [[#include "gmp.h"]],
931                         [[
932                                 #if (__GNU_MP_VERSION*100 +  __GNU_MP_VERSION_MINOR*10 + __GNU_MP_VERSION_PATCHLEVEL) < 414
933                                         #error bad gmp
934                                 #endif]])],
935                 [AC_MSG_RESULT([yes])],
936                 [AC_MSG_RESULT([no]); AC_MSG_ERROR([No usable gmp.h found!])]
937         )
938 fi
939
940 if test x$ldap = xtrue; then
941         AC_CHECK_LIB([ldap],[ldap_init],[LIBS="$LIBS"],[AC_MSG_ERROR([LDAP library ldap not found])],[])
942         AC_CHECK_LIB([lber],[ber_free],[LIBS="$LIBS"],[AC_MSG_ERROR([LDAP library lber not found])],[])
943         AC_CHECK_HEADER([ldap.h],,[AC_MSG_ERROR([LDAP header ldap.h not found!])])
944 fi
945
946 if test x$curl = xtrue; then
947         AC_CHECK_LIB([curl],[curl_global_init],[LIBS="$LIBS"],[AC_MSG_ERROR([CURL library curl not found])],[])
948         AC_CHECK_HEADER([curl/curl.h],,[AC_MSG_ERROR([CURL header curl/curl.h not found!])])
949 fi
950
951 if test x$unbound = xtrue; then
952         AC_CHECK_LIB([ldns],[ldns_rr_get_type],[LIBS="$LIBS"],[AC_MSG_ERROR([UNBOUND library ldns not found])],[])
953         AC_CHECK_HEADER([ldns/ldns.h],,[AC_MSG_ERROR([UNBOUND header ldns/ldns.h not found!])])
954         AC_CHECK_LIB([unbound],[ub_ctx_create],[LIBS="$LIBS"],[AC_MSG_ERROR([UNBOUND library libunbound not found])],[])
955         AC_CHECK_HEADER([unbound.h],,[AC_MSG_ERROR([UNBOUND header unbound.h not found!])])
956 fi
957
958 if test x$soup = xtrue; then
959         PKG_CHECK_MODULES(soup, [libsoup-2.4])
960         AC_SUBST(soup_CFLAGS)
961         AC_SUBST(soup_LIBS)
962 fi
963
964 if test x$xml = xtrue; then
965         PKG_CHECK_MODULES(xml, [libxml-2.0])
966         AC_SUBST(xml_CFLAGS)
967         AC_SUBST(xml_LIBS)
968 fi
969
970 if test x$systemd = xtrue; then
971         AC_MSG_CHECKING([for systemd system unit directory])
972         if test -n "$systemdsystemunitdir" -a "x$systemdsystemunitdir" != xno; then
973                 AC_MSG_RESULT([$systemdsystemunitdir])
974         else
975                 AC_MSG_ERROR([not found (try --with-systemdsystemunitdir)])
976         fi
977
978         PKG_CHECK_MODULES(systemd, [libsystemd >= 209],
979                 [AC_SUBST(systemd_CFLAGS)
980                  AC_SUBST(systemd_LIBS)],
981                 [PKG_CHECK_MODULES(systemd_daemon, [libsystemd-daemon])
982                  AC_SUBST(systemd_daemon_CFLAGS)
983                  AC_SUBST(systemd_daemon_LIBS)
984                  PKG_CHECK_MODULES(systemd_journal, [libsystemd-journal])
985                  AC_SUBST(systemd_journal_CFLAGS)
986                  AC_SUBST(systemd_journal_LIBS)]
987         )
988 fi
989
990 if test x$tss_trousers = xtrue; then
991         AC_CHECK_LIB([tspi],[Tspi_Context_Create],[LIBS="$LIBS"],[AC_MSG_ERROR([TrouSerS library libtspi not found])],[])
992         AC_CHECK_HEADER([trousers/tss.h],,[AC_MSG_ERROR([TrouSerS header trousers/tss.h not found!])])
993         AC_DEFINE([TSS_TROUSERS], [], [use TrouSerS library libtspi])
994 fi
995
996 if test x$tss_tss2 = xtrue; then
997         PKG_CHECK_MODULES(tss2, [tcti-socket], [AC_DEFINE([TSS_TSS2], [], [use TSS 2.0 libraries])])
998         AC_SUBST(tss2_CFLAGS)
999         AC_SUBST(tss2_LIBS)
1000 fi
1001
1002 if test x$imv_swid = xtrue; then
1003         PKG_CHECK_MODULES(json, [json-c], [],
1004                 [PKG_CHECK_MODULES(json, [json])])
1005         AC_SUBST(json_CFLAGS)
1006         AC_SUBST(json_LIBS)
1007 fi
1008
1009 if test x$dumm = xtrue; then
1010         PKG_CHECK_MODULES(gtk, [gtk+-2.0 vte])
1011         AC_SUBST(gtk_CFLAGS)
1012         AC_SUBST(gtk_LIBS)
1013         AC_CHECK_PROGS(RUBY, ruby)
1014         PKG_CHECK_MODULES(ruby, [ruby])
1015         saved_LIBS=$LIBS
1016         LIBS=$ruby_LIBS
1017         AC_CHECK_FUNCS(rb_errinfo)
1018         LIBS=$saved_LIBS
1019 fi
1020
1021 if test x$fast = xtrue; then
1022         AC_CHECK_LIB([neo_utl],[hdf_init],[LIBS="$LIBS"],[AC_MSG_ERROR([ClearSilver library neo_utl not found!])],[])
1023         AC_MSG_CHECKING([for -lneo_cgi and dependencies])
1024         saved_CFLAGS=$CFLAGS
1025         saved_LIBS=$LIBS
1026         LIBS="-lneo_cgi -lneo_cs -lneo_utl"
1027         CFLAGS="-I/usr/include/ClearSilver"
1028         AC_LINK_IFELSE(
1029                 [AC_LANG_PROGRAM(
1030                         [[#include <cgi/cgi.h>]],
1031                         [[NEOERR *err = cgi_display(NULL, NULL);]])],
1032                 [AC_MSG_RESULT([yes])],
1033                 [LIBS="$LIBS -lz";
1034                  AC_LINK_IFELSE(
1035                         [AC_LANG_PROGRAM(
1036                                 [[#include <cgi/cgi.h>]],
1037                                 [[NEOERR *err = cgi_display(NULL, NULL);]])],
1038                         [AC_MSG_RESULT([yes, zlib required])],
1039                         [AC_MSG_ERROR([not found])]
1040                  )]
1041         )
1042         clearsilver_LIBS="$LIBS"
1043         AC_SUBST(clearsilver_LIBS)
1044         LIBS=$saved_LIBS
1045         CFLAGS=$saved_CFLAGS
1046
1047         AC_CHECK_LIB([fcgi],[FCGX_Init],[LIBS="$LIBS"],[AC_MSG_ERROR([FastCGI library fcgi not found!])],[])
1048         AC_CHECK_HEADER([fcgiapp.h],,[AC_MSG_ERROR([FastCGI header file fcgiapp.h not found!])])
1049 fi
1050
1051 if test x$mysql = xtrue; then
1052         if test "x$windows" = xtrue; then
1053                 AC_CHECK_HEADER([mysql.h],,[AC_MSG_ERROR([MySQL header file mysql.h not found!])])
1054                 AC_CHECK_LIB([mysql],[mysql_database_init],[LIBS="$LIBS"],[AC_MSG_ERROR([MySQL library not found!])],[])
1055                 AC_SUBST(MYSQLLIB, -lmysql)
1056         else
1057                 AC_PATH_PROG([MYSQLCONFIG], [mysql_config], [], [$PATH:/bin:/usr/bin:/usr/local/bin])
1058                 if test x$MYSQLCONFIG = x; then
1059                         AC_MSG_ERROR([mysql_config not found!])
1060                 fi
1061                 AC_SUBST(MYSQLLIB, `$MYSQLCONFIG --libs_r`)
1062                 AC_SUBST(MYSQLCFLAG, `$MYSQLCONFIG --cflags`)
1063         fi
1064 fi
1065
1066 if test x$sqlite = xtrue; then
1067         AC_CHECK_LIB([sqlite3],[sqlite3_open],[LIBS="$LIBS"],[AC_MSG_ERROR([SQLite library sqlite3 not found])],[])
1068         AC_CHECK_HEADER([sqlite3.h],,[AC_MSG_ERROR([SQLite header sqlite3.h not found!])])
1069         AC_MSG_CHECKING([sqlite3_prepare_v2])
1070         AC_COMPILE_IFELSE(
1071                 [AC_LANG_PROGRAM(
1072                         [[#include <sqlite3.h>]],
1073                         [[void *test = sqlite3_prepare_v2;]])],
1074                 [AC_MSG_RESULT([yes]);
1075                  AC_DEFINE([HAVE_SQLITE3_PREPARE_V2], [], [have sqlite3_prepare_v2()])],
1076                 [AC_MSG_RESULT([no])]
1077         )
1078         AC_MSG_CHECKING([sqlite3.h version >= 3.3.1])
1079         AC_COMPILE_IFELSE(
1080                 [AC_LANG_PROGRAM(
1081                         [[#include <sqlite3.h>]],
1082                         [[
1083                                 #if SQLITE_VERSION_NUMBER < 3003001
1084                                         #error bad sqlite
1085                                 #endif]])],
1086                 [AC_MSG_RESULT([yes])],
1087                 [AC_MSG_RESULT([no]); AC_MSG_ERROR([SQLite version >= 3.3.1 required!])]
1088         )
1089 fi
1090
1091 if test x$openssl = xtrue; then
1092         AC_CHECK_LIB([$openssl_lib],[EVP_CIPHER_CTX_new],[LIBS="$LIBS"],
1093                                  [AC_MSG_ERROR([OpenSSL lib$openssl_lib not found])],[$DLLIB])
1094         AC_CHECK_HEADER([openssl/evp.h],,[AC_MSG_ERROR([OpenSSL header openssl/evp.h not found!])])
1095 fi
1096
1097 if test x$gcrypt = xtrue; then
1098         AC_CHECK_LIB([gcrypt],[gcry_control],[LIBS="$LIBS"],[AC_MSG_ERROR([gcrypt library not found])],[-lgpg-error])
1099         AC_CHECK_HEADER([gcrypt.h],,[AC_MSG_ERROR([gcrypt header gcrypt.h not found!])])
1100         AC_MSG_CHECKING([gcrypt CAMELLIA cipher])
1101         AC_COMPILE_IFELSE(
1102                 [AC_LANG_PROGRAM(
1103                         [[#include <gcrypt.h>]],
1104                         [[enum gcry_cipher_algos alg = GCRY_CIPHER_CAMELLIA128;]])],
1105                 [AC_MSG_RESULT([yes]);
1106                  AC_DEFINE([HAVE_GCRY_CIPHER_CAMELLIA], [], [have GCRY_CIPHER_CAMELLIA128])],
1107                 [AC_MSG_RESULT([no])]
1108         )
1109 fi
1110
1111 if test x$uci = xtrue; then
1112         AC_CHECK_LIB([uci],[uci_alloc_context],[LIBS="$LIBS"],[AC_MSG_ERROR([UCI library libuci not found])],[])
1113         AC_CHECK_HEADER([uci.h],,[AC_MSG_ERROR([UCI header uci.h not found!])])
1114 fi
1115
1116 if test x$android_dns = xtrue; then
1117         AC_CHECK_LIB([cutils],[property_get],[LIBS="$LIBS"],[AC_MSG_ERROR([Android library libcutils not found])],[])
1118         AC_CHECK_HEADER([cutils/properties.h],,[AC_MSG_ERROR([Android header cutils/properties.h not found!])])
1119         # we have to force the use of libdl here because the autodetection
1120         # above does not work correctly when cross-compiling for android.
1121         DLLIB="-ldl"
1122         AC_SUBST(DLLIB)
1123 fi
1124
1125 if test x$eap_sim_pcsc = xtrue; then
1126         PKG_CHECK_MODULES(pcsclite, [libpcsclite])
1127         AC_SUBST(pcsclite_CFLAGS)
1128         AC_SUBST(pcsclite_LIBS)
1129 fi
1130
1131 if test x$nm = xtrue; then
1132         PKG_CHECK_EXISTS([libnm-glib],
1133                 [PKG_CHECK_MODULES(nm, [NetworkManager gthread-2.0 libnm-util libnm-glib libnm-glib-vpn])],
1134                 [PKG_CHECK_MODULES(nm, [NetworkManager gthread-2.0 libnm_util libnm_glib libnm_glib_vpn])]
1135         )
1136         AC_SUBST(nm_CFLAGS)
1137         AC_SUBST(nm_LIBS)
1138 fi
1139
1140 if test x$xauth_pam = xtrue; then
1141         AC_CHECK_LIB([pam],[pam_start],[LIBS="$LIBS"],[AC_MSG_ERROR([PAM library not found])],[])
1142         AC_CHECK_HEADER([security/pam_appl.h],,[AC_MSG_ERROR([PAM header security/pam_appl.h not found!])])
1143 fi
1144
1145 if test x$connmark = xtrue -o x$forecast = xtrue; then
1146         PKG_CHECK_MODULES(libiptc, [libiptc])
1147         AC_SUBST(libiptc_CFLAGS)
1148         AC_SUBST(libiptc_LIBS)
1149 fi
1150
1151 if test x$capabilities = xnative; then
1152         AC_MSG_NOTICE([Usage of the native Linux capabilities interface is deprecated, use libcap instead])
1153         # Linux requires the following for capset(), Android does not have it,
1154         # but defines capset() in unistd.h instead.
1155         AC_CHECK_HEADERS([sys/capability.h])
1156         AC_CHECK_FUNC(capset,,[AC_MSG_ERROR([capset() not found!])])
1157         AC_DEFINE([CAPABILITIES_NATIVE], [], [have native linux capset()])
1158 fi
1159
1160 if test x$capabilities = xlibcap; then
1161         AC_CHECK_LIB([cap],[cap_init],[LIBS="$LIBS"],[AC_MSG_ERROR([libcap library not found])],[])
1162         AC_CHECK_HEADER([sys/capability.h],
1163                 [AC_DEFINE([HAVE_SYS_CAPABILITY_H], [], [have sys/capability.h])],
1164                 [AC_MSG_ERROR([libcap header sys/capability.h not found!])])
1165         AC_DEFINE([CAPABILITIES_LIBCAP], [], [have libpcap library])
1166 fi
1167
1168 if test x$integrity_test = xtrue; then
1169         AC_MSG_CHECKING([for dladdr()])
1170         AC_COMPILE_IFELSE(
1171                 [AC_LANG_PROGRAM(
1172                         [[#define _GNU_SOURCE
1173                           #include <dlfcn.h>]],
1174                         [[Dl_info info; dladdr(main, &info);]])],
1175                 [AC_MSG_RESULT([yes])],
1176                 [AC_MSG_RESULT([no]);
1177                  AC_MSG_ERROR([dladdr() not supported, required by integrity-test!])]
1178         )
1179         AC_MSG_CHECKING([for dl_iterate_phdr()])
1180         AC_COMPILE_IFELSE(
1181                 [AC_LANG_PROGRAM(
1182                         [[#define _GNU_SOURCE
1183                           #include <link.h>]],
1184                         [[dl_iterate_phdr((void*)0, (void*)0);]])],
1185                 [AC_MSG_RESULT([yes])],
1186                 [AC_MSG_RESULT([no]);
1187                  AC_MSG_ERROR([dl_iterate_phdr() not supported, required by integrity-test!])]
1188         )
1189 fi
1190
1191 if test x$bfd_backtraces = xtrue; then
1192         AC_CHECK_LIB([bfd],[bfd_init],[LIBS="$LIBS"],[AC_MSG_ERROR([binutils libbfd not found!])],[])
1193         AC_CHECK_HEADER([bfd.h],[AC_DEFINE([HAVE_BFD_H],,[have binutils bfd.h])],
1194                 [AC_MSG_ERROR([binutils bfd.h header not found!])])
1195         BFDLIB="-lbfd"
1196         AC_SUBST(BFDLIB)
1197 fi
1198
1199 if test x$unwind_backtraces = xtrue; then
1200         AC_CHECK_LIB([unwind],[unw_backtrace],[LIBS="$LIBS"],[AC_MSG_ERROR([libunwind not found!])],[])
1201         AC_CHECK_HEADER([libunwind.h],[AC_DEFINE([HAVE_LIBUNWIND_H],,[have libunwind.h])],
1202                 [AC_MSG_ERROR([libunwind.h header not found!])])
1203         UNWINDLIB="-lunwind"
1204         AC_SUBST(UNWINDLIB)
1205 fi
1206
1207 AM_CONDITIONAL(USE_DEV_HEADERS, [test "x$dev_headers" != xno])
1208 if test x$dev_headers = xyes; then
1209         dev_headers="$includedir/strongswan"
1210 fi
1211 AC_SUBST(dev_headers)
1212
1213 CFLAGS="$CFLAGS -include `pwd`/config.h"
1214
1215 if test x$tkm = xtrue; then
1216         AC_PATH_PROG([GPRBUILD], [gprbuild], [], [$PATH:/bin:/usr/bin:/usr/local/bin])
1217         if test x$GPRBUILD = x; then
1218                 AC_MSG_ERROR([gprbuild not found])
1219         fi
1220 fi
1221
1222 if test x$coverage = xtrue; then
1223         AC_PATH_PROG([LCOV], [lcov], [], [$PATH:/bin:/usr/bin:/usr/local/bin])
1224         if test x$LCOV = x; then
1225                 AC_MSG_ERROR([lcov not found])
1226         fi
1227         AC_PATH_PROG([GENHTML], [genhtml], [], [$PATH:/bin:/usr/bin:/usr/local/bin])
1228         if test x$GENHTML = x; then
1229                 AC_MSG_ERROR([genhtml not found])
1230         fi
1231
1232         COVERAGE_CFLAGS="-fprofile-arcs -ftest-coverage"
1233         COVERAGE_LDFLAGS="-fprofile-arcs"
1234         AC_SUBST(COVERAGE_CFLAGS)
1235         AC_SUBST(COVERAGE_LDFLAGS)
1236
1237         AC_MSG_NOTICE([coverage enabled, adding "-g -O0" to CFLAGS])
1238         CFLAGS="${CFLAGS} -g -O0"
1239 fi
1240
1241 if test x$ruby_gems = xtrue; then
1242         AC_PATH_PROG([GEM], [gem], [], [$PATH:/bin:/usr/bin:/usr/local/bin])
1243         if test x$GEM = x; then
1244                 AC_MSG_ERROR(RubyGems package manager not found)
1245         fi
1246         if test "x$rubygemdir" = "xgem environment gemdir"; then
1247                 rubygemdir=$($GEM environment gemdir)
1248         fi
1249         AC_SUBST(RUBYGEMDIR, "$rubygemdir")
1250 fi
1251 AM_CONDITIONAL(RUBY_GEMS_INSTALL, [test "x$ruby_gems_install" = xtrue])
1252
1253 if test x$python_eggs = xtrue; then
1254         PYTHON_PACKAGE_VERSION=`echo "$PACKAGE_VERSION" | $SED 's/dr/dev/'`
1255         AC_SUBST([PYTHON_PACKAGE_VERSION])
1256         if test x$python_eggs_install = xtrue; then
1257                 AC_PATH_PROG([EASY_INSTALL], [easy_install], [], [$PATH:/bin:/usr/bin:/usr/local/bin])
1258                 if test x$EASY_INSTALL = x; then
1259                         AC_MSG_ERROR(Python easy_install not found)
1260                 fi
1261         fi
1262         if test "x$pythoneggdir" = "xmain site-packages directory"; then
1263                 AC_SUBST(PYTHONEGGINSTALLDIR, "")
1264         else
1265                 AC_SUBST(PYTHONEGGINSTALLDIR, "--install-dir $pythoneggdir")
1266         fi
1267         AC_PATH_PROG([PY_TEST], [py.test], [], [$PATH:/bin:/usr/bin:/usr/local/bin])
1268 fi
1269 AM_CONDITIONAL(PYTHON_EGGS_INSTALL, [test "x$python_eggs_install" = xtrue])
1270
1271 AM_CONDITIONAL(PERL_CPAN_INSTALL, [test "x$perl_cpan_install" = xtrue])
1272
1273 AC_CACHE_CHECK(
1274         [if plugin constructors should be resolved statically],
1275         [ss_cv_static_plugin_constructors],
1276         [if test x$monolithic = xtrue -a x$enable_static = xyes; then
1277                 ss_cv_static_plugin_constructors=yes
1278          else
1279                 ss_cv_static_plugin_constructors="no (enabled for static, monolithic builds)"
1280          fi]
1281 )
1282 if test "x$ss_cv_static_plugin_constructors" = xyes; then
1283         static_plugin_constructors=true
1284 fi
1285
1286 # ===============================================
1287 #  collect plugin list for strongSwan components
1288 # ===============================================
1289
1290 m4_include(m4/macros/add-plugin.m4)
1291
1292 # plugin lists for all components
1293 charon_plugins=
1294 starter_plugins=
1295 pool_plugins=
1296 attest_plugins=
1297 scepclient_plugins=
1298 pki_plugins=
1299 scripts_plugins=
1300 fuzz_plugins=
1301 manager_plugins=
1302 medsrv_plugins=
1303 nm_plugins=
1304 cmd_plugins=
1305 aikgen_plugins=
1306
1307 # location specific lists for checksumming,
1308 # for src/libcharon, src/libstrongswan, src/libtnccs and src/libtpmtss
1309 c_plugins=
1310 s_plugins=
1311 t_plugins=
1312 p_plugins=
1313
1314 ADD_PLUGIN([test-vectors],         [s charon scepclient pki])
1315 ADD_PLUGIN([unbound],              [s charon scripts])
1316 ADD_PLUGIN([ldap],                 [s charon scepclient scripts nm cmd])
1317 ADD_PLUGIN([pkcs11],               [s charon pki nm cmd])
1318 ADD_PLUGIN([tpm],                  [p charon pki nm cmd])
1319 ADD_PLUGIN([aesni],                [s charon scepclient pki scripts medsrv attest nm cmd aikgen])
1320 ADD_PLUGIN([aes],                  [s charon scepclient pki scripts nm cmd])
1321 ADD_PLUGIN([des],                  [s charon scepclient pki scripts nm cmd])
1322 ADD_PLUGIN([blowfish],             [s charon scepclient pki scripts nm cmd])
1323 ADD_PLUGIN([rc2],                  [s charon scepclient pki scripts nm cmd])
1324 ADD_PLUGIN([sha2],                 [s charon scepclient pki scripts medsrv attest nm cmd aikgen fuzz])
1325 ADD_PLUGIN([sha3],                 [s charon scepclient pki scripts medsrv attest nm cmd aikgen fuzz])
1326 ADD_PLUGIN([sha1],                 [s charon scepclient pki scripts manager medsrv attest nm cmd aikgen fuzz])
1327 ADD_PLUGIN([md4],                  [s charon scepclient pki nm cmd])
1328 ADD_PLUGIN([md5],                  [s charon scepclient pki scripts attest nm cmd aikgen])
1329 ADD_PLUGIN([mgf1],                 [s charon scepclient pki scripts medsrv attest nm cmd aikgen])
1330 ADD_PLUGIN([rdrand],               [s charon scepclient pki scripts medsrv attest nm cmd aikgen])
1331 ADD_PLUGIN([random],               [s charon scepclient pki scripts manager medsrv attest nm cmd aikgen])
1332 ADD_PLUGIN([nonce],                [s charon nm cmd aikgen])
1333 ADD_PLUGIN([x509],                 [s charon scepclient pki scripts attest nm cmd aikgen fuzz])
1334 ADD_PLUGIN([revocation],           [s charon pki nm cmd])
1335 ADD_PLUGIN([constraints],          [s charon nm cmd])
1336 ADD_PLUGIN([acert],                [s charon])
1337 ADD_PLUGIN([pubkey],               [s charon cmd aikgen])
1338 ADD_PLUGIN([pkcs1],                [s charon scepclient pki scripts manager medsrv attest nm cmd aikgen fuzz])
1339 ADD_PLUGIN([pkcs7],                [s charon scepclient pki scripts nm cmd])
1340 ADD_PLUGIN([pkcs8],                [s charon scepclient pki scripts manager medsrv attest nm cmd])
1341 ADD_PLUGIN([pkcs12],               [s charon scepclient pki scripts cmd])
1342 ADD_PLUGIN([pgp],                  [s charon])
1343 ADD_PLUGIN([dnskey],               [s charon pki])
1344 ADD_PLUGIN([sshkey],               [s charon pki nm cmd])
1345 ADD_PLUGIN([dnscert],              [c charon])
1346 ADD_PLUGIN([ipseckey],             [c charon])
1347 ADD_PLUGIN([pem],                  [s charon scepclient pki scripts manager medsrv attest nm cmd aikgen fuzz])
1348 ADD_PLUGIN([padlock],              [s charon])
1349 ADD_PLUGIN([openssl],              [s charon scepclient pki scripts manager medsrv attest nm cmd aikgen])
1350 ADD_PLUGIN([gcrypt],               [s charon scepclient pki scripts manager medsrv attest nm cmd aikgen])
1351 ADD_PLUGIN([af-alg],               [s charon scepclient pki scripts medsrv attest nm cmd aikgen])
1352 ADD_PLUGIN([fips-prf],             [s charon nm cmd])
1353 ADD_PLUGIN([gmp],                  [s charon scepclient pki scripts manager medsrv attest nm cmd aikgen fuzz])
1354 ADD_PLUGIN([curve25519],           [s charon pki scripts nm cmd])
1355 ADD_PLUGIN([agent],                [s charon nm cmd])
1356 ADD_PLUGIN([keychain],             [s charon cmd])
1357 ADD_PLUGIN([chapoly],              [s charon scripts nm cmd])
1358 ADD_PLUGIN([xcbc],                 [s charon nm cmd])
1359 ADD_PLUGIN([cmac],                 [s charon nm cmd])
1360 ADD_PLUGIN([hmac],                 [s charon pki scripts nm cmd])
1361 ADD_PLUGIN([ctr],                  [s charon scripts nm cmd])
1362 ADD_PLUGIN([ccm],                  [s charon scripts nm cmd])
1363 ADD_PLUGIN([gcm],                  [s charon scripts nm cmd])
1364 ADD_PLUGIN([ntru],                 [s charon scripts nm cmd])
1365 ADD_PLUGIN([newhope],              [s charon scripts nm cmd])
1366 ADD_PLUGIN([bliss],                [s charon pki scripts nm cmd])
1367 ADD_PLUGIN([curl],                 [s charon scepclient pki scripts nm cmd])
1368 ADD_PLUGIN([files],                [s charon scepclient pki scripts nm cmd])
1369 ADD_PLUGIN([winhttp],              [s charon pki scripts])
1370 ADD_PLUGIN([soup],                 [s charon pki scripts nm cmd])
1371 ADD_PLUGIN([mysql],                [s charon pool manager medsrv attest])
1372 ADD_PLUGIN([sqlite],               [s charon pool manager medsrv attest])
1373 ADD_PLUGIN([attr],                 [c charon])
1374 ADD_PLUGIN([attr-sql],             [c charon])
1375 ADD_PLUGIN([load-tester],          [c charon])
1376 ADD_PLUGIN([kernel-libipsec],      [c charon cmd])
1377 ADD_PLUGIN([kernel-wfp],           [c charon])
1378 ADD_PLUGIN([kernel-iph],           [c charon])
1379 ADD_PLUGIN([kernel-pfkey],         [c charon starter nm cmd])
1380 ADD_PLUGIN([kernel-pfroute],       [c charon starter nm cmd])
1381 ADD_PLUGIN([kernel-netlink],       [c charon starter nm cmd])
1382 ADD_PLUGIN([resolve],              [c charon cmd])
1383 ADD_PLUGIN([socket-default],       [c charon nm cmd])
1384 ADD_PLUGIN([socket-dynamic],       [c charon cmd])
1385 ADD_PLUGIN([socket-win],           [c charon])
1386 ADD_PLUGIN([bypass-lan],           [c charon nm cmd])
1387 ADD_PLUGIN([connmark],             [c charon])
1388 ADD_PLUGIN([forecast],             [c charon])
1389 ADD_PLUGIN([farp],                 [c charon])
1390 ADD_PLUGIN([stroke],               [c charon])
1391 ADD_PLUGIN([vici],                 [c charon])
1392 ADD_PLUGIN([smp],                  [c charon])
1393 ADD_PLUGIN([sql],                  [c charon])
1394 ADD_PLUGIN([updown],               [c charon])
1395 ADD_PLUGIN([eap-identity],         [c charon nm cmd])
1396 ADD_PLUGIN([eap-sim],              [c charon])
1397 ADD_PLUGIN([eap-sim-file],         [c charon])
1398 ADD_PLUGIN([eap-sim-pcsc],         [c charon])
1399 ADD_PLUGIN([eap-aka],              [c charon])
1400 ADD_PLUGIN([eap-aka-3gpp2],        [c charon])
1401 ADD_PLUGIN([eap-simaka-sql],       [c charon])
1402 ADD_PLUGIN([eap-simaka-pseudonym], [c charon])
1403 ADD_PLUGIN([eap-simaka-reauth],    [c charon])
1404 ADD_PLUGIN([eap-md5],              [c charon nm cmd])
1405 ADD_PLUGIN([eap-gtc],              [c charon nm cmd])
1406 ADD_PLUGIN([eap-mschapv2],         [c charon nm cmd])
1407 ADD_PLUGIN([eap-dynamic],          [c charon])
1408 ADD_PLUGIN([eap-radius],           [c charon])
1409 ADD_PLUGIN([eap-tls],              [c charon nm cmd])
1410 ADD_PLUGIN([eap-ttls],             [c charon nm cmd])
1411 ADD_PLUGIN([eap-peap],             [c charon nm cmd])
1412 ADD_PLUGIN([eap-tnc],              [c charon])
1413 ADD_PLUGIN([xauth-generic],        [c charon cmd])
1414 ADD_PLUGIN([xauth-eap],            [c charon])
1415 ADD_PLUGIN([xauth-pam],            [c charon])
1416 ADD_PLUGIN([xauth-noauth],         [c charon])
1417 ADD_PLUGIN([tnc-ifmap],            [c charon])
1418 ADD_PLUGIN([tnc-pdp],              [c charon])
1419 ADD_PLUGIN([tnc-imc],              [t charon])
1420 ADD_PLUGIN([tnc-imv],              [t charon])
1421 ADD_PLUGIN([tnc-tnccs],            [t charon])
1422 ADD_PLUGIN([tnccs-20],             [t charon])
1423 ADD_PLUGIN([tnccs-11],             [t charon])
1424 ADD_PLUGIN([tnccs-dynamic],        [t charon])
1425 ADD_PLUGIN([medsrv],               [c charon])
1426 ADD_PLUGIN([medcli],               [c charon])
1427 ADD_PLUGIN([dhcp],                 [c charon])
1428 ADD_PLUGIN([osx-attr],             [c charon cmd])
1429 ADD_PLUGIN([p-cscf],               [c charon cmd])
1430 ADD_PLUGIN([android-dns],          [c charon])
1431 ADD_PLUGIN([android-log],          [c charon])
1432 ADD_PLUGIN([ha],                   [c charon])
1433 ADD_PLUGIN([whitelist],            [c charon])
1434 ADD_PLUGIN([ext-auth],             [c charon])
1435 ADD_PLUGIN([lookip],               [c charon])
1436 ADD_PLUGIN([error-notify],         [c charon])
1437 ADD_PLUGIN([certexpire],           [c charon])
1438 ADD_PLUGIN([systime-fix],          [c charon])
1439 ADD_PLUGIN([led],                  [c charon])
1440 ADD_PLUGIN([duplicheck],           [c charon])
1441 ADD_PLUGIN([coupling],             [c charon])
1442 ADD_PLUGIN([radattr],              [c charon])
1443 ADD_PLUGIN([uci],                  [c charon])
1444 ADD_PLUGIN([addrblock],            [c charon])
1445 ADD_PLUGIN([unity],                [c charon])
1446
1447 AC_SUBST(charon_plugins)
1448 AC_SUBST(starter_plugins)
1449 AC_SUBST(pool_plugins)
1450 AC_SUBST(attest_plugins)
1451 AC_SUBST(scepclient_plugins)
1452 AC_SUBST(pki_plugins)
1453 AC_SUBST(scripts_plugins)
1454 AC_SUBST(fuzz_plugins)
1455 AC_SUBST(manager_plugins)
1456 AC_SUBST(medsrv_plugins)
1457 AC_SUBST(nm_plugins)
1458 AC_SUBST(cmd_plugins)
1459 AC_SUBST(aikgen_plugins)
1460
1461 AC_SUBST(c_plugins)
1462 AC_SUBST(p_plugins)
1463 AC_SUBST(s_plugins)
1464 AC_SUBST(t_plugins)
1465
1466 # ======================
1467 #  set Makefile.am vars
1468 # ======================
1469
1470 #  libstrongswan plugins
1471 # -----------------------
1472 AM_CONDITIONAL(USE_TEST_VECTORS, test x$test_vectors = xtrue)
1473 AM_CONDITIONAL(USE_CURL, test x$curl = xtrue)
1474 AM_CONDITIONAL(USE_FILES, test x$files = xtrue)
1475 AM_CONDITIONAL(USE_WINHTTP, test x$winhttp = xtrue)
1476 AM_CONDITIONAL(USE_UNBOUND, test x$unbound = xtrue)
1477 AM_CONDITIONAL(USE_SOUP, test x$soup = xtrue)
1478 AM_CONDITIONAL(USE_LDAP, test x$ldap = xtrue)
1479 AM_CONDITIONAL(USE_AES, test x$aes = xtrue)
1480 AM_CONDITIONAL(USE_DES, test x$des = xtrue)
1481 AM_CONDITIONAL(USE_BLOWFISH, test x$blowfish = xtrue)
1482 AM_CONDITIONAL(USE_RC2, test x$rc2 = xtrue)
1483 AM_CONDITIONAL(USE_MD4, test x$md4 = xtrue)
1484 AM_CONDITIONAL(USE_MD5, test x$md5 = xtrue)
1485 AM_CONDITIONAL(USE_SHA1, test x$sha1 = xtrue)
1486 AM_CONDITIONAL(USE_SHA2, test x$sha2 = xtrue)
1487 AM_CONDITIONAL(USE_SHA3, test x$sha3 = xtrue)
1488 AM_CONDITIONAL(USE_MGF1, test x$mgf1 = xtrue)
1489 AM_CONDITIONAL(USE_FIPS_PRF, test x$fips_prf = xtrue)
1490 AM_CONDITIONAL(USE_GMP, test x$gmp = xtrue)
1491 AM_CONDITIONAL(USE_CURVE25519, test x$curve25519 = xtrue)
1492 AM_CONDITIONAL(USE_RDRAND, test x$rdrand = xtrue)
1493 AM_CONDITIONAL(USE_AESNI, test x$aesni = xtrue)
1494 AM_CONDITIONAL(USE_RANDOM, test x$random = xtrue)
1495 AM_CONDITIONAL(USE_NONCE, test x$nonce = xtrue)
1496 AM_CONDITIONAL(USE_X509, test x$x509 = xtrue)
1497 AM_CONDITIONAL(USE_REVOCATION, test x$revocation = xtrue)
1498 AM_CONDITIONAL(USE_CONSTRAINTS, test x$constraints = xtrue)
1499 AM_CONDITIONAL(USE_ACERT, test x$acert = xtrue)
1500 AM_CONDITIONAL(USE_PUBKEY, test x$pubkey = xtrue)
1501 AM_CONDITIONAL(USE_PKCS1, test x$pkcs1 = xtrue)
1502 AM_CONDITIONAL(USE_PKCS7, test x$pkcs7 = xtrue)
1503 AM_CONDITIONAL(USE_PKCS8, test x$pkcs8 = xtrue)
1504 AM_CONDITIONAL(USE_PKCS12, test x$pkcs12 = xtrue)
1505 AM_CONDITIONAL(USE_PGP, test x$pgp = xtrue)
1506 AM_CONDITIONAL(USE_DNSKEY, test x$dnskey = xtrue)
1507 AM_CONDITIONAL(USE_SSHKEY, test x$sshkey = xtrue)
1508 AM_CONDITIONAL(USE_PEM, test x$pem = xtrue)
1509 AM_CONDITIONAL(USE_HMAC, test x$hmac = xtrue)
1510 AM_CONDITIONAL(USE_CMAC, test x$cmac = xtrue)
1511 AM_CONDITIONAL(USE_XCBC, test x$xcbc = xtrue)
1512 AM_CONDITIONAL(USE_MYSQL, test x$mysql = xtrue)
1513 AM_CONDITIONAL(USE_SQLITE, test x$sqlite = xtrue)
1514 AM_CONDITIONAL(USE_PADLOCK, test x$padlock = xtrue)
1515 AM_CONDITIONAL(USE_OPENSSL, test x$openssl = xtrue)
1516 AM_CONDITIONAL(USE_GCRYPT, test x$gcrypt = xtrue)
1517 AM_CONDITIONAL(USE_AGENT, test x$agent = xtrue)
1518 AM_CONDITIONAL(USE_KEYCHAIN, test x$keychain = xtrue)
1519 AM_CONDITIONAL(USE_PKCS11, test x$pkcs11 = xtrue)
1520 AM_CONDITIONAL(USE_TPM, test x$tpm = xtrue)
1521 AM_CONDITIONAL(USE_CHAPOLY, test x$chapoly = xtrue)
1522 AM_CONDITIONAL(USE_CTR, test x$ctr = xtrue)
1523 AM_CONDITIONAL(USE_CCM, test x$ccm = xtrue)
1524 AM_CONDITIONAL(USE_GCM, test x$gcm = xtrue)
1525 AM_CONDITIONAL(USE_AF_ALG, test x$af_alg = xtrue)
1526 AM_CONDITIONAL(USE_NTRU, test x$ntru = xtrue)
1527 AM_CONDITIONAL(USE_NEWHOPE, test x$newhope = xtrue)
1528 AM_CONDITIONAL(USE_BLISS, test x$bliss = xtrue)
1529
1530 #  charon plugins
1531 # ----------------
1532 AM_CONDITIONAL(USE_STROKE, test x$stroke = xtrue)
1533 AM_CONDITIONAL(USE_VICI, test x$vici = xtrue)
1534 AM_CONDITIONAL(USE_MEDSRV, test x$medsrv = xtrue)
1535 AM_CONDITIONAL(USE_MEDCLI, test x$medcli = xtrue)
1536 AM_CONDITIONAL(USE_UCI, test x$uci = xtrue)
1537 AM_CONDITIONAL(USE_OSX_ATTR, test x$osx_attr = xtrue)
1538 AM_CONDITIONAL(USE_P_CSCF, test x$p_cscf = xtrue)
1539 AM_CONDITIONAL(USE_ANDROID_DNS, test x$android_dns = xtrue)
1540 AM_CONDITIONAL(USE_ANDROID_LOG, test x$android_log = xtrue)
1541 AM_CONDITIONAL(USE_SMP, test x$smp = xtrue)
1542 AM_CONDITIONAL(USE_SQL, test x$sql = xtrue)
1543 AM_CONDITIONAL(USE_DNSCERT, test x$dnscert = xtrue)
1544 AM_CONDITIONAL(USE_IPSECKEY, test x$ipseckey = xtrue)
1545 AM_CONDITIONAL(USE_UPDOWN, test x$updown = xtrue)
1546 AM_CONDITIONAL(USE_DHCP, test x$dhcp = xtrue)
1547 AM_CONDITIONAL(USE_LOAD_TESTER, test x$load_tester = xtrue)
1548 AM_CONDITIONAL(USE_HA, test x$ha = xtrue)
1549 AM_CONDITIONAL(USE_KERNEL_NETLINK, test x$kernel_netlink = xtrue)
1550 AM_CONDITIONAL(USE_KERNEL_PFKEY, test x$kernel_pfkey = xtrue)
1551 AM_CONDITIONAL(USE_KERNEL_PFROUTE, test x$kernel_pfroute = xtrue)
1552 AM_CONDITIONAL(USE_KERNEL_LIBIPSEC, test x$kernel_libipsec = xtrue)
1553 AM_CONDITIONAL(USE_KERNEL_WFP, test x$kernel_wfp = xtrue)
1554 AM_CONDITIONAL(USE_KERNEL_IPH, test x$kernel_iph = xtrue)
1555 AM_CONDITIONAL(USE_WHITELIST, test x$whitelist = xtrue)
1556 AM_CONDITIONAL(USE_EXT_AUTH, test x$ext_auth = xtrue)
1557 AM_CONDITIONAL(USE_LOOKIP, test x$lookip = xtrue)
1558 AM_CONDITIONAL(USE_ERROR_NOTIFY, test x$error_notify = xtrue)
1559 AM_CONDITIONAL(USE_CERTEXPIRE, test x$certexpire = xtrue)
1560 AM_CONDITIONAL(USE_SYSTIME_FIX, test x$systime_fix = xtrue)
1561 AM_CONDITIONAL(USE_LED, test x$led = xtrue)
1562 AM_CONDITIONAL(USE_DUPLICHECK, test x$duplicheck = xtrue)
1563 AM_CONDITIONAL(USE_COUPLING, test x$coupling = xtrue)
1564 AM_CONDITIONAL(USE_RADATTR, test x$radattr = xtrue)
1565 AM_CONDITIONAL(USE_EAP_SIM, test x$eap_sim = xtrue)
1566 AM_CONDITIONAL(USE_EAP_SIM_FILE, test x$eap_sim_file = xtrue)
1567 AM_CONDITIONAL(USE_EAP_SIM_PCSC, test x$eap_sim_pcsc = xtrue)
1568 AM_CONDITIONAL(USE_EAP_SIMAKA_SQL, test x$eap_simaka_sql = xtrue)
1569 AM_CONDITIONAL(USE_EAP_SIMAKA_PSEUDONYM, test x$eap_simaka_pseudonym = xtrue)
1570 AM_CONDITIONAL(USE_EAP_SIMAKA_REAUTH, test x$eap_simaka_reauth = xtrue)
1571 AM_CONDITIONAL(USE_EAP_IDENTITY, test x$eap_identity = xtrue)
1572 AM_CONDITIONAL(USE_EAP_MD5, test x$eap_md5 = xtrue)
1573 AM_CONDITIONAL(USE_EAP_GTC, test x$eap_gtc = xtrue)
1574 AM_CONDITIONAL(USE_EAP_AKA, test x$eap_aka = xtrue)
1575 AM_CONDITIONAL(USE_EAP_AKA_3GPP2, test x$eap_aka_3gpp2 = xtrue)
1576 AM_CONDITIONAL(USE_EAP_MSCHAPV2, test x$eap_mschapv2 = xtrue)
1577 AM_CONDITIONAL(USE_EAP_TLS, test x$eap_tls = xtrue)
1578 AM_CONDITIONAL(USE_EAP_TTLS, test x$eap_ttls = xtrue)
1579 AM_CONDITIONAL(USE_EAP_PEAP, test x$eap_peap = xtrue)
1580 AM_CONDITIONAL(USE_EAP_TNC, test x$eap_tnc = xtrue)
1581 AM_CONDITIONAL(USE_EAP_DYNAMIC, test x$eap_dynamic = xtrue)
1582 AM_CONDITIONAL(USE_EAP_RADIUS, test x$eap_radius = xtrue)
1583 AM_CONDITIONAL(USE_XAUTH_GENERIC, test x$xauth_generic = xtrue)
1584 AM_CONDITIONAL(USE_XAUTH_EAP, test x$xauth_eap = xtrue)
1585 AM_CONDITIONAL(USE_XAUTH_PAM, test x$xauth_pam = xtrue)
1586 AM_CONDITIONAL(USE_XAUTH_NOAUTH, test x$xauth_noauth = xtrue)
1587 AM_CONDITIONAL(USE_TNC_IFMAP, test x$tnc_ifmap = xtrue)
1588 AM_CONDITIONAL(USE_TNC_PDP, test x$tnc_pdp = xtrue)
1589 AM_CONDITIONAL(USE_TNC_IMC, test x$tnc_imc = xtrue)
1590 AM_CONDITIONAL(USE_TNC_IMV, test x$tnc_imv = xtrue)
1591 AM_CONDITIONAL(USE_TNC_TNCCS, test x$tnc_tnccs = xtrue)
1592 AM_CONDITIONAL(USE_TNCCS_11, test x$tnccs_11 = xtrue)
1593 AM_CONDITIONAL(USE_TNCCS_20, test x$tnccs_20 = xtrue)
1594 AM_CONDITIONAL(USE_TNCCS_DYNAMIC, test x$tnccs_dynamic = xtrue)
1595 AM_CONDITIONAL(USE_IMC_TEST, test x$imc_test = xtrue)
1596 AM_CONDITIONAL(USE_IMV_TEST, test x$imv_test = xtrue)
1597 AM_CONDITIONAL(USE_IMC_SCANNER, test x$imc_scanner = xtrue)
1598 AM_CONDITIONAL(USE_IMV_SCANNER, test x$imv_scanner = xtrue)
1599 AM_CONDITIONAL(USE_IMC_OS, test x$imc_os = xtrue)
1600 AM_CONDITIONAL(USE_IMV_OS, test x$imv_os = xtrue)
1601 AM_CONDITIONAL(USE_IMC_ATTESTATION, test x$imc_attestation = xtrue)
1602 AM_CONDITIONAL(USE_IMV_ATTESTATION, test x$imv_attestation = xtrue)
1603 AM_CONDITIONAL(USE_IMC_SWID, test x$imc_swid = xtrue)
1604 AM_CONDITIONAL(USE_IMV_SWID, test x$imv_swid = xtrue)
1605 AM_CONDITIONAL(USE_IMC_HCD, test x$imc_hcd = xtrue)
1606 AM_CONDITIONAL(USE_IMV_HCD, test x$imv_hcd = xtrue)
1607 AM_CONDITIONAL(USE_SOCKET_DEFAULT, test x$socket_default = xtrue)
1608 AM_CONDITIONAL(USE_SOCKET_DYNAMIC, test x$socket_dynamic = xtrue)
1609 AM_CONDITIONAL(USE_SOCKET_WIN, test x$socket_win = xtrue)
1610 AM_CONDITIONAL(USE_BYPASS_LAN, test x$bypass_lan = xtrue)
1611 AM_CONDITIONAL(USE_CONNMARK, test x$connmark = xtrue)
1612 AM_CONDITIONAL(USE_FORECAST, test x$forecast = xtrue)
1613 AM_CONDITIONAL(USE_FARP, test x$farp = xtrue)
1614 AM_CONDITIONAL(USE_ADDRBLOCK, test x$addrblock = xtrue)
1615 AM_CONDITIONAL(USE_UNITY, test x$unity = xtrue)
1616 AM_CONDITIONAL(USE_RESOLVE, test x$resolve = xtrue)
1617 AM_CONDITIONAL(USE_ATTR, test x$attr = xtrue)
1618 AM_CONDITIONAL(USE_ATTR_SQL, test x$attr_sql = xtrue)
1619
1620 #  other options
1621 # ---------------
1622 AM_CONDITIONAL(USE_LEAK_DETECTIVE, test x$leak_detective = xtrue)
1623 AM_CONDITIONAL(USE_LOCK_PROFILER, test x$lock_profiler = xtrue)
1624 AM_CONDITIONAL(USE_DUMM, test x$dumm = xtrue)
1625 AM_CONDITIONAL(USE_FAST, test x$fast = xtrue)
1626 AM_CONDITIONAL(USE_MANAGER, test x$manager = xtrue)
1627 AM_CONDITIONAL(USE_ME, test x$mediation = xtrue)
1628 AM_CONDITIONAL(USE_INTEGRITY_TEST, test x$integrity_test = xtrue)
1629 AM_CONDITIONAL(USE_LOAD_WARNING, test x$load_warning = xtrue)
1630 AM_CONDITIONAL(USE_IKEV1, test x$ikev1 = xtrue)
1631 AM_CONDITIONAL(USE_IKEV2, test x$ikev2 = xtrue)
1632 AM_CONDITIONAL(USE_THREADS, test x$threads = xtrue)
1633 AM_CONDITIONAL(USE_ADNS, test x$adns = xtrue)
1634 AM_CONDITIONAL(USE_CHARON, test x$charon = xtrue)
1635 AM_CONDITIONAL(USE_NM, test x$nm = xtrue)
1636 AM_CONDITIONAL(USE_PKI, test x$pki = xtrue)
1637 AM_CONDITIONAL(USE_SCEPCLIENT, test x$scepclient = xtrue)
1638 AM_CONDITIONAL(USE_SCRIPTS, test x$scripts = xtrue)
1639 AM_CONDITIONAL(USE_FUZZING, test x$fuzzing = xtrue)
1640 AM_CONDITIONAL(USE_CONFTEST, test x$conftest = xtrue)
1641 AM_CONDITIONAL(USE_LIBSTRONGSWAN, test x$charon = xtrue -o x$pki = xtrue -o x$scepclient = xtrue -o x$conftest = xtrue -o x$fast = xtrue -o x$imcv = xtrue -o x$nm = xtrue -o x$tkm = xtrue -o x$cmd = xtrue -o x$tls = xtrue -o x$tnc_tnccs = xtrue -o x$aikgen = xtrue -o x$svc = xtrue -o x$systemd = xtrue)
1642 AM_CONDITIONAL(USE_LIBCHARON, test x$charon = xtrue -o x$conftest = xtrue -o x$nm = xtrue -o x$tkm = xtrue -o x$cmd = xtrue -o x$svc = xtrue -o x$systemd = xtrue)
1643 AM_CONDITIONAL(USE_LIBIPSEC, test x$libipsec = xtrue)
1644 AM_CONDITIONAL(USE_LIBNTTFFT, test x$bliss = xtrue -o x$newhope = xtrue)
1645 AM_CONDITIONAL(USE_LIBTNCIF, test x$tnc_tnccs = xtrue -o x$imcv = xtrue)
1646 AM_CONDITIONAL(USE_LIBTNCCS, test x$tnc_tnccs = xtrue)
1647 AM_CONDITIONAL(USE_LIBPTTLS, test x$tnc_tnccs = xtrue)
1648 AM_CONDITIONAL(USE_LIBTPMTSS, test x$tss_trousers = xtrue -o x$tss_tss2 = xtrue -o x$tpm -o x$aikgen = xtrue -o x$imcv = xtrue)
1649 AM_CONDITIONAL(USE_FILE_CONFIG, test x$stroke = xtrue)
1650 AM_CONDITIONAL(USE_IPSEC_SCRIPT, test x$stroke = xtrue -o x$scepclient = xtrue -o x$conftest = xtrue)
1651 AM_CONDITIONAL(USE_LIBCAP, test x$capabilities = xlibcap)
1652 AM_CONDITIONAL(USE_VSTR, test x$printf_hooks = xvstr)
1653 AM_CONDITIONAL(USE_BUILTIN_PRINTF, test x$printf_hooks = xbuiltin)
1654 AM_CONDITIONAL(USE_SIMAKA, test x$simaka = xtrue)
1655 AM_CONDITIONAL(USE_TLS, test x$tls = xtrue)
1656 AM_CONDITIONAL(USE_RADIUS, test x$radius = xtrue)
1657 AM_CONDITIONAL(USE_IMCV, test x$imcv = xtrue)
1658 AM_CONDITIONAL(USE_TROUSERS, test x$tss_trousers = xtrue)
1659 AM_CONDITIONAL(USE_TSS2, test x$tss_tss2 = xtrue)
1660 AM_CONDITIONAL(MONOLITHIC, test x$monolithic = xtrue)
1661 AM_CONDITIONAL(STATIC_PLUGIN_CONSTRUCTORS, test x$static_plugin_constructors = xtrue)
1662 AM_CONDITIONAL(USE_SILENT_RULES, test x$enable_silent_rules = xyes)
1663 AM_CONDITIONAL(COVERAGE, test x$coverage = xtrue)
1664 AM_CONDITIONAL(USE_DBGHELP, test x$dbghelp_backtraces = xtrue)
1665 AM_CONDITIONAL(USE_TKM, test x$tkm = xtrue)
1666 AM_CONDITIONAL(USE_CMD, test x$cmd = xtrue)
1667 AM_CONDITIONAL(USE_AIKGEN, test x$aikgen = xtrue)
1668 AM_CONDITIONAL(USE_SWANCTL, test x$swanctl = xtrue)
1669 AM_CONDITIONAL(USE_SVC, test x$svc = xtrue)
1670 AM_CONDITIONAL(USE_SYSTEMD, test x$systemd = xtrue)
1671 AM_CONDITIONAL(USE_LEGACY_SYSTEMD, test -n "$systemdsystemunitdir" -a "x$systemdsystemunitdir" != xno)
1672 AM_CONDITIONAL(USE_RUBY_GEMS, test x$ruby_gems = xtrue)
1673 AM_CONDITIONAL(USE_PYTHON_EGGS, test x$python_eggs = xtrue)
1674 AM_CONDITIONAL(USE_PERL_CPAN, test x$perl_cpan = xtrue)
1675 AM_CONDITIONAL(USE_PY_TEST, test "x$PY_TEST" != x)
1676
1677 # ========================
1678 #  set global definitions
1679 # ========================
1680
1681 if test x$mediation = xtrue; then
1682         AC_DEFINE([ME], [], [mediation extension support])
1683 fi
1684 if test x$capabilities = xlibcap -o x$capabilities = xnative; then
1685         AC_DEFINE([CAPABILITIES], [], [capability dropping support])
1686 fi
1687 if test x$log_thread_ids = xtrue; then
1688         AC_DEFINE([USE_THREAD_IDS], [], [use thread ID for thread identification, if available])
1689 fi
1690 if test x$monolithic = xtrue; then
1691         AC_DEFINE([MONOLITHIC], [], [monolithic build embedding plugins])
1692 fi
1693 if test x$static_plugin_constructors = xtrue; then
1694         AC_DEFINE([STATIC_PLUGIN_CONSTRUCTORS], [], [static plugin constructors])
1695 fi
1696 if test x$ikev1 = xtrue; then
1697         AC_DEFINE([USE_IKEV1], [], [support for IKEv1 protocol])
1698 fi
1699 if test x$ikev2 = xtrue; then
1700         AC_DEFINE([USE_IKEV2], [], [support for IKEv2 protocol])
1701 fi
1702 if test x$fuzzing = xtrue; then
1703         AC_DEFINE([USE_FUZZING], [], [build code for fuzzing])
1704 fi
1705
1706 # ====================================================
1707 #  options for enabled modules (see conf/Makefile.am)
1708 # ====================================================
1709
1710 strongswan_options=
1711
1712 AM_COND_IF([USE_AIKGEN], [strongswan_options=${strongswan_options}" aikgen"])
1713 AM_COND_IF([USE_ATTR_SQL], [strongswan_options=${strongswan_options}" pool"])
1714 AM_COND_IF([USE_CHARON], [strongswan_options=${strongswan_options}" charon charon-logging"])
1715 AM_COND_IF([USE_FILE_CONFIG], [strongswan_options=${strongswan_options}" starter"])
1716 AM_COND_IF([USE_IMV_ATTESTATION], [strongswan_options=${strongswan_options}" attest"])
1717 AM_COND_IF([USE_IMCV], [strongswan_options=${strongswan_options}" imcv"])
1718 AM_COND_IF([USE_IMV_OS], [strongswan_options=${strongswan_options}" pacman"])
1719 AM_COND_IF([USE_LIBTNCCS], [strongswan_options=${strongswan_options}" tnc"])
1720 AM_COND_IF([USE_MANAGER], [strongswan_options=${strongswan_options}" manager"])
1721 AM_COND_IF([USE_MEDSRV], [strongswan_options=${strongswan_options}" medsrv"])
1722 AM_COND_IF([USE_SCEPCLIENT], [strongswan_options=${strongswan_options}" scepclient"])
1723 AM_COND_IF([USE_PKI], [strongswan_options=${strongswan_options}" pki"])
1724 AM_COND_IF([USE_SWANCTL], [strongswan_options=${strongswan_options}" swanctl"])
1725
1726 AC_SUBST(strongswan_options)
1727
1728 # =================
1729 #  build Makefiles
1730 # =================
1731
1732 AC_CONFIG_FILES([
1733         Makefile
1734         conf/Makefile
1735         fuzz/Makefile
1736         man/Makefile
1737         init/Makefile
1738         init/systemd/Makefile
1739         init/systemd-swanctl/Makefile
1740         src/Makefile
1741         src/include/Makefile
1742         src/libstrongswan/Makefile
1743         src/libstrongswan/math/libnttfft/Makefile
1744         src/libstrongswan/math/libnttfft/tests/Makefile
1745         src/libstrongswan/plugins/aes/Makefile
1746         src/libstrongswan/plugins/cmac/Makefile
1747         src/libstrongswan/plugins/des/Makefile
1748         src/libstrongswan/plugins/blowfish/Makefile
1749         src/libstrongswan/plugins/rc2/Makefile
1750         src/libstrongswan/plugins/md4/Makefile
1751         src/libstrongswan/plugins/md5/Makefile
1752         src/libstrongswan/plugins/sha1/Makefile
1753         src/libstrongswan/plugins/sha2/Makefile
1754         src/libstrongswan/plugins/sha3/Makefile
1755         src/libstrongswan/plugins/mgf1/Makefile
1756         src/libstrongswan/plugins/fips_prf/Makefile
1757         src/libstrongswan/plugins/gmp/Makefile
1758         src/libstrongswan/plugins/curve25519/Makefile
1759         src/libstrongswan/plugins/rdrand/Makefile
1760         src/libstrongswan/plugins/aesni/Makefile
1761         src/libstrongswan/plugins/random/Makefile
1762         src/libstrongswan/plugins/nonce/Makefile
1763         src/libstrongswan/plugins/hmac/Makefile
1764         src/libstrongswan/plugins/xcbc/Makefile
1765         src/libstrongswan/plugins/x509/Makefile
1766         src/libstrongswan/plugins/revocation/Makefile
1767         src/libstrongswan/plugins/constraints/Makefile
1768         src/libstrongswan/plugins/acert/Makefile
1769         src/libstrongswan/plugins/pubkey/Makefile
1770         src/libstrongswan/plugins/pkcs1/Makefile
1771         src/libstrongswan/plugins/pkcs7/Makefile
1772         src/libstrongswan/plugins/pkcs8/Makefile
1773         src/libstrongswan/plugins/pkcs12/Makefile
1774         src/libstrongswan/plugins/pgp/Makefile
1775         src/libstrongswan/plugins/dnskey/Makefile
1776         src/libstrongswan/plugins/sshkey/Makefile
1777         src/libstrongswan/plugins/pem/Makefile
1778         src/libstrongswan/plugins/curl/Makefile
1779         src/libstrongswan/plugins/files/Makefile
1780         src/libstrongswan/plugins/winhttp/Makefile
1781         src/libstrongswan/plugins/unbound/Makefile
1782         src/libstrongswan/plugins/soup/Makefile
1783         src/libstrongswan/plugins/ldap/Makefile
1784         src/libstrongswan/plugins/mysql/Makefile
1785         src/libstrongswan/plugins/sqlite/Makefile
1786         src/libstrongswan/plugins/padlock/Makefile
1787         src/libstrongswan/plugins/openssl/Makefile
1788         src/libstrongswan/plugins/gcrypt/Makefile
1789         src/libstrongswan/plugins/agent/Makefile
1790         src/libstrongswan/plugins/keychain/Makefile
1791         src/libstrongswan/plugins/pkcs11/Makefile
1792         src/libstrongswan/plugins/chapoly/Makefile
1793         src/libstrongswan/plugins/ctr/Makefile
1794         src/libstrongswan/plugins/ccm/Makefile
1795         src/libstrongswan/plugins/gcm/Makefile
1796         src/libstrongswan/plugins/af_alg/Makefile
1797         src/libstrongswan/plugins/ntru/Makefile
1798         src/libstrongswan/plugins/bliss/Makefile
1799         src/libstrongswan/plugins/bliss/tests/Makefile
1800         src/libstrongswan/plugins/newhope/Makefile
1801         src/libstrongswan/plugins/newhope/tests/Makefile
1802         src/libstrongswan/plugins/test_vectors/Makefile
1803         src/libstrongswan/tests/Makefile
1804         src/libipsec/Makefile
1805         src/libipsec/tests/Makefile
1806         src/libsimaka/Makefile
1807         src/libtls/Makefile
1808         src/libtls/tests/Makefile
1809         src/libradius/Makefile
1810         src/libtncif/Makefile
1811         src/libtnccs/Makefile
1812         src/libtnccs/plugins/tnc_tnccs/Makefile
1813         src/libtnccs/plugins/tnc_imc/Makefile
1814         src/libtnccs/plugins/tnc_imv/Makefile
1815         src/libtnccs/plugins/tnccs_11/Makefile
1816         src/libtnccs/plugins/tnccs_20/Makefile
1817         src/libtnccs/plugins/tnccs_dynamic/Makefile
1818         src/libpttls/Makefile
1819         src/libimcv/Makefile
1820         src/libimcv/plugins/imc_test/Makefile
1821         src/libimcv/plugins/imv_test/Makefile
1822         src/libimcv/plugins/imc_scanner/Makefile
1823         src/libimcv/plugins/imv_scanner/Makefile
1824         src/libimcv/plugins/imc_os/Makefile
1825         src/libimcv/plugins/imv_os/Makefile
1826         src/libimcv/plugins/imc_attestation/Makefile
1827         src/libimcv/plugins/imv_attestation/Makefile
1828         src/libimcv/plugins/imc_swid/Makefile
1829         src/libimcv/plugins/imv_swid/Makefile
1830         src/libimcv/plugins/imc_hcd/Makefile
1831         src/libimcv/plugins/imv_hcd/Makefile
1832         src/charon/Makefile
1833         src/charon-nm/Makefile
1834         src/charon-tkm/Makefile
1835         src/charon-cmd/Makefile
1836         src/charon-svc/Makefile
1837         src/charon-systemd/Makefile
1838         src/libcharon/Makefile
1839         src/libcharon/plugins/eap_aka/Makefile
1840         src/libcharon/plugins/eap_aka_3gpp2/Makefile
1841         src/libcharon/plugins/eap_dynamic/Makefile
1842         src/libcharon/plugins/eap_identity/Makefile
1843         src/libcharon/plugins/eap_md5/Makefile
1844         src/libcharon/plugins/eap_gtc/Makefile
1845         src/libcharon/plugins/eap_sim/Makefile
1846         src/libcharon/plugins/eap_sim_file/Makefile
1847         src/libcharon/plugins/eap_sim_pcsc/Makefile
1848         src/libcharon/plugins/eap_simaka_sql/Makefile
1849         src/libcharon/plugins/eap_simaka_pseudonym/Makefile
1850         src/libcharon/plugins/eap_simaka_reauth/Makefile
1851         src/libcharon/plugins/eap_mschapv2/Makefile
1852         src/libcharon/plugins/eap_tls/Makefile
1853         src/libcharon/plugins/eap_ttls/Makefile
1854         src/libcharon/plugins/eap_peap/Makefile
1855         src/libcharon/plugins/eap_tnc/Makefile
1856         src/libcharon/plugins/eap_radius/Makefile
1857         src/libcharon/plugins/xauth_generic/Makefile
1858         src/libcharon/plugins/xauth_eap/Makefile
1859         src/libcharon/plugins/xauth_pam/Makefile
1860         src/libcharon/plugins/xauth_noauth/Makefile
1861         src/libcharon/plugins/tnc_ifmap/Makefile
1862         src/libcharon/plugins/tnc_pdp/Makefile
1863         src/libcharon/plugins/socket_default/Makefile
1864         src/libcharon/plugins/socket_dynamic/Makefile
1865         src/libcharon/plugins/socket_win/Makefile
1866         src/libcharon/plugins/bypass_lan/Makefile
1867         src/libcharon/plugins/connmark/Makefile
1868         src/libcharon/plugins/forecast/Makefile
1869         src/libcharon/plugins/farp/Makefile
1870         src/libcharon/plugins/smp/Makefile
1871         src/libcharon/plugins/sql/Makefile
1872         src/libcharon/plugins/dnscert/Makefile
1873         src/libcharon/plugins/ipseckey/Makefile
1874         src/libcharon/plugins/medsrv/Makefile
1875         src/libcharon/plugins/medcli/Makefile
1876         src/libcharon/plugins/addrblock/Makefile
1877         src/libcharon/plugins/unity/Makefile
1878         src/libcharon/plugins/uci/Makefile
1879         src/libcharon/plugins/ha/Makefile
1880         src/libcharon/plugins/kernel_netlink/Makefile
1881         src/libcharon/plugins/kernel_pfkey/Makefile
1882         src/libcharon/plugins/kernel_pfroute/Makefile
1883         src/libcharon/plugins/kernel_libipsec/Makefile
1884         src/libcharon/plugins/kernel_wfp/Makefile
1885         src/libcharon/plugins/kernel_iph/Makefile
1886         src/libcharon/plugins/whitelist/Makefile
1887         src/libcharon/plugins/ext_auth/Makefile
1888         src/libcharon/plugins/lookip/Makefile
1889         src/libcharon/plugins/error_notify/Makefile
1890         src/libcharon/plugins/certexpire/Makefile
1891         src/libcharon/plugins/systime_fix/Makefile
1892         src/libcharon/plugins/led/Makefile
1893         src/libcharon/plugins/duplicheck/Makefile
1894         src/libcharon/plugins/coupling/Makefile
1895         src/libcharon/plugins/radattr/Makefile
1896         src/libcharon/plugins/osx_attr/Makefile
1897         src/libcharon/plugins/p_cscf/Makefile
1898         src/libcharon/plugins/android_dns/Makefile
1899         src/libcharon/plugins/android_log/Makefile
1900         src/libcharon/plugins/stroke/Makefile
1901         src/libcharon/plugins/vici/Makefile
1902         src/libcharon/plugins/vici/ruby/Makefile
1903         src/libcharon/plugins/vici/perl/Makefile
1904         src/libcharon/plugins/vici/python/Makefile
1905         src/libcharon/plugins/updown/Makefile
1906         src/libcharon/plugins/dhcp/Makefile
1907         src/libcharon/plugins/load_tester/Makefile
1908         src/libcharon/plugins/resolve/Makefile
1909         src/libcharon/plugins/attr/Makefile
1910         src/libcharon/plugins/attr_sql/Makefile
1911         src/libcharon/tests/Makefile
1912         src/libtpmtss/Makefile
1913         src/libtpmtss/plugins/tpm/Makefile
1914         src/stroke/Makefile
1915         src/ipsec/Makefile
1916         src/starter/Makefile
1917         src/starter/tests/Makefile
1918         src/_updown/Makefile
1919         src/_copyright/Makefile
1920         src/scepclient/Makefile
1921         src/aikgen/Makefile
1922         src/pki/Makefile
1923         src/pki/man/Makefile
1924         src/pool/Makefile
1925         src/dumm/Makefile
1926         src/dumm/ext/extconf.rb
1927         src/libfast/Makefile
1928         src/manager/Makefile
1929         src/medsrv/Makefile
1930         src/checksum/Makefile
1931         src/conftest/Makefile
1932         src/pt-tls-client/Makefile
1933         src/swanctl/Makefile
1934         scripts/Makefile
1935         testing/Makefile
1936 ])
1937
1938 # =================
1939 #  build man pages
1940 # =================
1941
1942 AC_CONFIG_FILES([
1943         conf/strongswan.conf.5.head
1944         conf/strongswan.conf.5.tail
1945         man/ipsec.conf.5
1946         man/ipsec.secrets.5
1947         src/charon-cmd/charon-cmd.8
1948         src/pki/man/pki.1
1949         src/pki/man/pki---acert.1
1950         src/pki/man/pki---dn.1
1951         src/pki/man/pki---gen.1
1952         src/pki/man/pki---issue.1
1953         src/pki/man/pki---keyid.1
1954         src/pki/man/pki---pkcs12.1
1955         src/pki/man/pki---pkcs7.1
1956         src/pki/man/pki---print.1
1957         src/pki/man/pki---pub.1
1958         src/pki/man/pki---req.1
1959         src/pki/man/pki---self.1
1960         src/pki/man/pki---signcrl.1
1961         src/pki/man/pki---verify.1
1962         src/swanctl/swanctl.8
1963         src/swanctl/swanctl.conf.5.head
1964         src/swanctl/swanctl.conf.5.tail
1965 ])
1966
1967 AC_OUTPUT
1968
1969 # ========================
1970 #  report enabled plugins
1971 # ========================
1972
1973 AC_MSG_RESULT([])
1974 AC_MSG_RESULT([ strongSwan will be built with the following plugins])
1975 AC_MSG_RESULT([-----------------------------------------------------])
1976
1977 AC_MSG_RESULT([libstrongswan:$s_plugins])
1978 AC_MSG_RESULT([libcharon:    $c_plugins])
1979 AC_MSG_RESULT([libtnccs:     $t_plugins])
1980 AC_MSG_RESULT([libtpmtss:    $p_plugins])
1981 AC_MSG_RESULT([])